GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tup        Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.Num         Class: Num, plus instances for Int
  31                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  32
  33                 Integer is needed here because it is mentioned in the signature
  34                 of 'fromInteger' in class Num
  35
  36 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  37                          plus instances for Int, Integer
  38                 Types:  Ratio, Rational
  39                         plus intances for classes so far
  40
  41                 Rational is needed here because it is mentioned in the signature
  42                 of 'toRational' in class Real
  43
  44 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  45
  46 GHC.Arr         Types: Array, MutableArray, MutableVar
  47
  48                 Does *not* contain any ByteArray stuff (see GHC.ByteArr)
  49                 Arrays are used by a function in GHC.Float
  50
  51 GHC.Float       Classes: Floating, RealFloat
  52                 Types:   Float, Double, plus instances of all classes so far
  53
  54                 This module contains everything to do with floating point.
  55                 It is a big module (900 lines)
  56                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  57
  58 GHC.ByteArr     Types: ByteArray, MutableByteArray
  59
  60                 We want this one to be after GHC.Float, because it defines arrays
  61                 of unboxed floats.
  62
  63
  64 Other Prelude modules are much easier with fewer complex dependencies.
  65
  66 \begin{code}
  67 {-# OPTIONS -fno-implicit-prelude #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 module GHC.Base
  85         (
  86         module GHC.Base,
  87         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  88         module GHC.Err          -- of people having to import it explicitly
  89   )
  90         where
  91
  92 import GHC.Prim
  93 import {-# SOURCE #-} GHC.Err
  94
  95 infixr 9  .
  96 infixr 5  ++, :
  97 infix  4  ==, /=, <, <=, >=, >
  98 infixr 3  &&
  99 infixr 2  ||
 100 infixl 1  >>, >>=
 101 infixr 0  $
 102
 103 default ()              -- Double isn't available yet
 104 \end{code}
 105
 106
 107 %*********************************************************
 108 %*                                                      *
 109 \subsection{DEBUGGING STUFF}
 110 %*  (for use when compiling GHC.Base itself doesn't work)
 111 %*                                                      *
 112 %*********************************************************
 113
 114 \begin{code}
 115 {-
 116 data  Bool  =  False | True
 117 data Ordering = LT | EQ | GT
 118 data Char = C# Char#
 119 type  String = [Char]
 120 data Int = I# Int#
 121 data  ()  =  ()
 122 data [] a = MkNil
 123
 124 not True = False
 125 (&&) True True = True
 126 otherwise = True
 127
 128 build = error "urk"
 129 foldr = error "urk"
 130
 131 unpackCString# :: Addr# -> [Char]
 132 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 133 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 134 unpackCStringUtf8# :: Addr# -> [Char]
 135 unpackCString# a = error "urk"
 136 unpackFoldrCString# a = error "urk"
 137 unpackAppendCString# a = error "urk"
 138 unpackCStringUtf8# a = error "urk"
 139 -}
 140 \end{code}
 141
 142
 143 %*********************************************************
 144 %*                                                      *
 145 \subsection{Standard classes @Eq@, @Ord@}
 146 %*                                                      *
 147 %*********************************************************
 148
 149 \begin{code}
 150
 151 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 152 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 153 -- and 'Eq' may be derived for any datatype whose constituents are also
 154 -- instances of 'Eq'.
 155 --
 156 -- Minimal complete definition: either '==' or '/='.
 157 --
 158 class  Eq a  where
 159     (==), (/=)           :: a -> a -> Bool
 160
 161     x /= y               = not (x == y)
 162     x == y               = not (x /= y)
 163
 164 class  (Eq a) => Ord a  where
 165     compare              :: a -> a -> Ordering
 166     (<), (<=), (>), (>=) :: a -> a -> Bool
 167     max, min             :: a -> a -> a
 168
 169     -- An instance of Ord should define either 'compare' or '<='.
 170     -- Using 'compare' can be more efficient for complex types.
 171
 172     compare x y
 173         | x == y    = EQ
 174         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 175                                 -- above claim about the minimal things that
 176                                 -- can be defined for an instance of Ord
 177         | otherwise = GT
 178
 179     x <  y = case compare x y of { LT -> True;  _other -> False }
 180     x <= y = case compare x y of { GT -> False; _other -> True }
 181     x >  y = case compare x y of { GT -> True;  _other -> False }
 182     x >= y = case compare x y of { LT -> False; _other -> True }
 183
 184         -- These two default methods use '<=' rather than 'compare'
 185         -- because the latter is often more expensive
 186     max x y = if x <= y then y else x
 187     min x y = if x <= y then x else y
 188 \end{code}
 189
 190 %*********************************************************
 191 %*                                                      *
 192 \subsection{Monadic classes @Functor@, @Monad@ }
 193 %*                                                      *
 194 %*********************************************************
 195
 196 \begin{code}
 197 {- | The 'Functor' class is used for types that can be mapped over.
 198 Instances of 'Functor' should satisfy the following laws:
 199
 200 > fmap id  ==  id
 201 > fmap (f . g)  ==  fmap f . fmap g
 202
 203 The instances of 'Functor' for lists, 'Maybe' and 'IO' defined in the "Prelude"
 204 satisfy these laws.
 205 -}
 206
 207 class  Functor f  where
 208     fmap        :: (a -> b) -> f a -> f b
 209
 210 {- | The 'Monad' class defines the basic operations over a /monad/.
 211 Instances of 'Monad' should satisfy the following laws:
 212
 213 > return a >>= k  ==  k a
 214 > m >>= return  ==  m
 215 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 216
 217 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 218
 219 > fmap f xs  ==  xs >>= return . f
 220
 221 The instances of 'Monad' for lists, 'Maybe' and 'IO' defined in the "Prelude"
 222 satisfy these laws.
 223 -}
 224
 225 class  Monad m  where
 226     (>>=)       :: m a -> (a -> m b) -> m b
 227     (>>)        :: m a -> m b -> m b
 228     return      :: a -> m a
 229     fail        :: String -> m a
 230
 231     m >> k      = m >>= \_ -> k
 232     fail s      = error s
 233 \end{code}
 234
 235
 236 %*********************************************************
 237 %*                                                      *
 238 \subsection{The list type}
 239 %*                                                      *
 240 %*********************************************************
 241
 242 \begin{code}
 243 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 244                           -- to avoid weird names like con2tag_[]#
 245
 246
 247 instance (Eq a) => Eq [a] where
 248     {-# SPECIALISE instance Eq [Char] #-}
 249     []     == []     = True
 250     (x:xs) == (y:ys) = x == y && xs == ys
 251     _xs    == _ys    = False
 252
 253 instance (Ord a) => Ord [a] where
 254     {-# SPECIALISE instance Ord [Char] #-}
 255     compare []     []     = EQ
 256     compare []     (_:_)  = LT
 257     compare (_:_)  []     = GT
 258     compare (x:xs) (y:ys) = case compare x y of
 259                                 EQ    -> compare xs ys
 260                                 other -> other
 261
 262 instance Functor [] where
 263     fmap = map
 264
 265 instance  Monad []  where
 266     m >>= k             = foldr ((++) . k) [] m
 267     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 268     return x            = [x]
 269     fail _              = []
 270 \end{code}
 271
 272 A few list functions that appear here because they are used here.
 273 The rest of the prelude list functions are in GHC.List.
 274
 275 ----------------------------------------------
 276 --      foldr/build/augment
 277 ----------------------------------------------
 278
 279 \begin{code}
 280 -- | 'foldr', applied to a binary operator, a starting value (typically
 281 -- the right-identity of the operator), and a list, reduces the list
 282 -- using the binary operator, from right to left:
 283 --
 284 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 285
 286 foldr            :: (a -> b -> b) -> b -> [a] -> b
 287 -- foldr _ z []     =  z
 288 -- foldr f z (x:xs) =  f x (foldr f z xs)
 289 {-# INLINE [0] foldr #-}
 290 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 291 foldr k z xs = go xs
 292              where
 293                go []     = z
 294                go (y:ys) = y `k` go ys
 295
 296 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 297 {-# INLINE [1] build #-}
 298         -- The INLINE is important, even though build is tiny,
 299         -- because it prevents [] getting inlined in the version that
 300         -- appears in the interface file.  If [] *is* inlined, it
 301         -- won't match with [] appearing in rules in an importing module.
 302         --
 303         -- The "1" says to inline in phase 1
 304
 305 build g = g (:) []
 306
 307 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 308 {-# INLINE [1] augment #-}
 309 augment g xs = g (:) xs
 310
 311 {-# RULES
 312 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 313                 foldr k z (build g) = g k z
 314
 315 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 316                 foldr k z (augment g xs) = g k (foldr k z xs)
 317
 318 "foldr/id"                        foldr (:) [] = \x->x
 319 "foldr/app"     [1] forall xs ys. foldr (:) ys xs = xs ++ ys
 320         -- Only activate this from phase 1, because that's
 321         -- when we disable the rule that expands (++) into foldr
 322
 323 -- The foldr/cons rule looks nice, but it can give disastrously
 324 -- bloated code when commpiling
 325 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 326 -- i.e. when there are very very long literal lists
 327 -- So I've disabled it for now. We could have special cases
 328 -- for short lists, I suppose.
 329 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 330
 331 "foldr/single"  forall k z x. foldr k z [x] = k x z
 332 "foldr/nil"     forall k z.   foldr k z []  = z
 333
 334 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 335                        (h::forall b. (a->b->b) -> b -> b) .
 336                        augment g (build h) = build (\c n -> g c (h c n))
 337 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 338                         augment g [] = build g
 339  #-}
 340
 341 -- This rule is true, but not (I think) useful:
 342 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 343 \end{code}
 344
 345
 346 ----------------------------------------------
 347 --              map
 348 ----------------------------------------------
 349
 350 \begin{code}
 351 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 352 -- of @xs@, i.e.,
 353 --
 354 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 355 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 356
 357 map :: (a -> b) -> [a] -> [b]
 358 map _ []     = []
 359 map f (x:xs) = f x : map f xs
 360
 361 -- Note eta expanded
 362 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 363 {-# INLINE [0] mapFB #-}
 364 mapFB c f x ys = c (f x) ys
 365
 366 -- The rules for map work like this.
 367 --
 368 -- Up to (but not including) phase 1, we use the "map" rule to
 369 -- rewrite all saturated applications of map with its build/fold
 370 -- form, hoping for fusion to happen.
 371 -- In phase 1 and 0, we switch off that rule, inline build, and
 372 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 373 -- thing back into plain map.
 374 --
 375 -- It's important that these two rules aren't both active at once
 376 -- (along with build's unfolding) else we'd get an infinite loop
 377 -- in the rules.  Hence the activation control below.
 378 --
 379 -- The "mapFB" rule optimises compositions of map.
 380 --
 381 -- This same pattern is followed by many other functions:
 382 -- e.g. append, filter, iterate, repeat, etc.
 383
 384 {-# RULES
 385 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 386 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 387 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 388   #-}
 389 \end{code}
 390
 391
 392 ----------------------------------------------
 393 --              append
 394 ----------------------------------------------
 395 \begin{code}
 396 -- | Append two lists, i.e.,
 397 --
 398 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 399 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 400 --
 401 -- If the first list is not finite, the result is the first list.
 402
 403 (++) :: [a] -> [a] -> [a]
 404 (++) []     ys = ys
 405 (++) (x:xs) ys = x : xs ++ ys
 406
 407 {-# RULES
 408 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 409   #-}
 410
 411 \end{code}
 412
 413
 414 %*********************************************************
 415 %*                                                      *
 416 \subsection{Type @Bool@}
 417 %*                                                      *
 418 %*********************************************************
 419
 420 \begin{code}
 421 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 422 -- first so that the corresponding 'Prelude.Enum' instance will give
 423 -- 'Prelude.fromEnum' 'False' the value zero, and
 424 -- 'Prelude.fromEnum' 'True' the value 1.
 425 data  Bool  =  False | True  deriving (Eq, Ord)
 426         -- Read in GHC.Read, Show in GHC.Show
 427
 428 -- Boolean functions
 429
 430 -- | Boolean \"and\"
 431 (&&)                    :: Bool -> Bool -> Bool
 432 True  && x              =  x
 433 False && _              =  False
 434
 435 -- | Boolean \"or\"
 436 (||)                    :: Bool -> Bool -> Bool
 437 True  || _              =  True
 438 False || x              =  x
 439
 440 -- | Boolean \"not\"
 441 not                     :: Bool -> Bool
 442 not True                =  False
 443 not False               =  True
 444
 445 -- |'otherwise' is defined as the value 'True'.  It helps to make
 446 -- guards more readable.  eg.
 447 --
 448 -- >  f x | x < 0     = ...
 449 -- >      | otherwise = ...
 450 otherwise               :: Bool
 451 otherwise               =  True
 452 \end{code}
 453
 454
 455 %*********************************************************
 456 %*                                                      *
 457 \subsection{The @()@ type}
 458 %*                                                      *
 459 %*********************************************************
 460
 461 The Unit type is here because virtually any program needs it (whereas
 462 some programs may get away without consulting GHC.Tup).  Furthermore,
 463 the renamer currently *always* asks for () to be in scope, so that
 464 ccalls can use () as their default type; so when compiling GHC.Base we
 465 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 466 it here seems more direct.)
 467
 468 \begin{code}
 469 -- | The unit datatype @()@ has one non-undefined member, the nullary
 470 -- constructor @()@.
 471 data () = ()
 472
 473 instance Eq () where
 474     () == () = True
 475     () /= () = False
 476
 477 instance Ord () where
 478     () <= () = True
 479     () <  () = False
 480     () >= () = True
 481     () >  () = False
 482     max () () = ()
 483     min () () = ()
 484     compare () () = EQ
 485 \end{code}
 486
 487
 488 %*********************************************************
 489 %*                                                      *
 490 \subsection{Type @Ordering@}
 491 %*                                                      *
 492 %*********************************************************
 493
 494 \begin{code}
 495 -- | Represents an ordering relationship between two values: less
 496 -- than, equal to, or greater than.  An 'Ordering' is returned by
 497 -- 'compare'.
 498 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 499         -- Read in GHC.Read, Show in GHC.Show
 500 \end{code}
 501
 502
 503 %*********************************************************
 504 %*                                                      *
 505 \subsection{Type @Char@ and @String@}
 506 %*                                                      *
 507 %*********************************************************
 508
 509 \begin{code}
 510 -- | A 'String' is a list of characters.  String constants in Haskell are values
 511 -- of type 'String'.
 512 --
 513 type String = [Char]
 514
 515 {-| The character type 'Char' is an enumeration whose values represent
 516 Unicode (or equivalently ISO 10646) characters.
 517 This set extends the ISO 8859-1 (Latin-1) character set
 518 (the first 256 charachers), which is itself an extension of the ASCII
 519 character set (the first 128 characters).
 520 A character literal in Haskell has type 'Char'.
 521
 522 To convert a 'Char' to or from the corresponding 'Int' value defined
 523 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 524 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 525 -}
 526 data Char = C# Char#
 527
 528 -- We don't use deriving for Eq and Ord, because for Ord the derived
 529 -- instance defines only compare, which takes two primops.  Then
 530 -- '>' uses compare, and therefore takes two primops instead of one.
 531
 532 instance Eq Char where
 533     (C# c1) == (C# c2) = c1 `eqChar#` c2
 534     (C# c1) /= (C# c2) = c1 `neChar#` c2
 535
 536 instance Ord Char where
 537     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 538     (C# c1) >= (C# c2) = c1 `geChar#` c2
 539     (C# c1) <= (C# c2) = c1 `leChar#` c2
 540     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 541
 542 {-# RULES
 543 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 544 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 545 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 546 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 547 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 548 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 549   #-}
 550
 551 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 552 chr :: Int -> Char
 553 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 554             | otherwise                                  = error "Prelude.chr: bad argument"
 555
 556 unsafeChr :: Int -> Char
 557 unsafeChr (I# i#) = C# (chr# i#)
 558
 559 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 560 ord :: Char -> Int
 561 ord (C# c#) = I# (ord# c#)
 562 \end{code}
 563
 564 String equality is used when desugaring pattern-matches against strings.
 565
 566 \begin{code}
 567 eqString :: String -> String -> Bool
 568 eqString []       []       = True
 569 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 570 eqString cs1      cs2      = False
 571
 572 {-# RULES "eqString" (==) = eqString #-}
 573 \end{code}
 574
 575
 576 %*********************************************************
 577 %*                                                      *
 578 \subsection{Type @Int@}
 579 %*                                                      *
 580 %*********************************************************
 581
 582 \begin{code}
 583 data Int = I# Int#
 584 -- ^A fixed-precision integer type with at least the range @[-2^29
 585 -- .. 2^29-1]@.  The exact range for a given implementation can be
 586 -- determined by using 'minBound' and 'maxBound' from the 'Bounded'
 587 -- class.
 588
 589 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 590 zeroInt = I# 0#
 591 oneInt  = I# 1#
 592 twoInt  = I# 2#
 593
 594 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 595 #if WORD_SIZE_IN_BITS == 31
 596 minInt  = I# (-0x40000000#)
 597 maxInt  = I# 0x3FFFFFFF#
 598 #elif WORD_SIZE_IN_BITS == 32
 599 minInt  = I# (-0x80000000#)
 600 maxInt  = I# 0x7FFFFFFF#
 601 #else
 602 minInt  = I# (-0x8000000000000000#)
 603 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 604 #endif
 605
 606 instance Eq Int where
 607     (==) = eqInt
 608     (/=) = neInt
 609
 610 instance Ord Int where
 611     compare = compareInt
 612     (<)     = ltInt
 613     (<=)    = leInt
 614     (>=)    = geInt
 615     (>)     = gtInt
 616
 617 compareInt :: Int -> Int -> Ordering
 618 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 619
 620 compareInt# :: Int# -> Int# -> Ordering
 621 compareInt# x# y#
 622     | x# <#  y# = LT
 623     | x# ==# y# = EQ
 624     | otherwise = GT
 625 \end{code}
 626
 627
 628 %*********************************************************
 629 %*                                                      *
 630 \subsection{The function type}
 631 %*                                                      *
 632 %*********************************************************
 633
 634 \begin{code}
 635 -- identity function
 636 id                      :: a -> a
 637 id x                    =  x
 638
 639 -- lazy function; this is just the same as id, but its unfolding
 640 -- and strictness are over-ridden by the definition in MkId.lhs
 641 -- That way, it does not get inlined, and the strictness analyser
 642 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 643 -- Result: happiness
 644 lazy :: a -> a
 645 lazy x = x
 646
 647 -- Assertion function. This simply ignores its boolean argument.
 648 -- The compiler may rewrite it to (assertError line)
 649 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 650 --      but from Template Haskell onwards it's simply
 651 --      defined here in Base.lhs
 652 assert :: Bool -> a -> a
 653 assert pred r = r
 654
 655 -- constant function
 656 const                   :: a -> b -> a
 657 const x _               =  x
 658
 659 -- function composition
 660 {-# INLINE (.) #-}
 661 (.)       :: (b -> c) -> (a -> b) -> a -> c
 662 (.) f g x = f (g x)
 663
 664 -- flip f  takes its (first) two arguments in the reverse order of f.
 665 flip                    :: (a -> b -> c) -> b -> a -> c
 666 flip f x y              =  f y x
 667
 668 -- right-associating infix application operator (useful in continuation-
 669 -- passing style)
 670 {-# INLINE ($) #-}
 671 ($)                     :: (a -> b) -> a -> b
 672 f $ x                   =  f x
 673
 674 -- until p f  yields the result of applying f until p holds.
 675 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 676 until p f x | p x       =  x
 677             | otherwise =  until p f (f x)
 678
 679 -- asTypeOf is a type-restricted version of const.  It is usually used
 680 -- as an infix operator, and its typing forces its first argument
 681 -- (which is usually overloaded) to have the same type as the second.
 682 asTypeOf                :: a -> a -> a
 683 asTypeOf                =  const
 684 \end{code}
 685
 686 %*********************************************************
 687 %*                                                      *
 688 \subsection{Generics}
 689 %*                                                      *
 690 %*********************************************************
 691
 692 \begin{code}
 693 data Unit = Unit
 694 #ifndef __HADDOCK__
 695 data (:+:) a b = Inl a | Inr b
 696 data (:*:) a b = a :*: b
 697 #endif
 698 \end{code}
 699
 700 %*********************************************************
 701 %*                                                      *
 702 \subsection{@getTag@}
 703 %*                                                      *
 704 %*********************************************************
 705
 706 Returns the 'tag' of a constructor application; this function is used
 707 by the deriving code for Eq, Ord and Enum.
 708
 709 The primitive dataToTag# requires an evaluated constructor application
 710 as its argument, so we provide getTag as a wrapper that performs the
 711 evaluation before calling dataToTag#.  We could have dataToTag#
 712 evaluate its argument, but we prefer to do it this way because (a)
 713 dataToTag# can be an inline primop if it doesn't need to do any
 714 evaluation, and (b) we want to expose the evaluation to the
 715 simplifier, because it might be possible to eliminate the evaluation
 716 in the case when the argument is already known to be evaluated.
 717
 718 \begin{code}
 719 {-# INLINE getTag #-}
 720 getTag :: a -> Int#
 721 getTag x = x `seq` dataToTag# x
 722 \end{code}
 723
 724 %*********************************************************
 725 %*                                                      *
 726 \subsection{Numeric primops}
 727 %*                                                      *
 728 %*********************************************************
 729
 730 \begin{code}
 731 divInt# :: Int# -> Int# -> Int#
 732 x# `divInt#` y#
 733         -- Be careful NOT to overflow if we do any additional arithmetic
 734         -- on the arguments...  the following  previous version of this
 735         -- code has problems with overflow:
 736 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 737 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 738     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 739     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 740     | otherwise                = x# `quotInt#` y#
 741
 742 modInt# :: Int# -> Int# -> Int#
 743 x# `modInt#` y#
 744     | (x# ># 0#) && (y# <# 0#) ||
 745       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 746     | otherwise                   = r#
 747     where
 748     r# = x# `remInt#` y#
 749 \end{code}
 750
 751 Definitions of the boxed PrimOps; these will be
 752 used in the case of partial applications, etc.
 753
 754 \begin{code}
 755 {-# INLINE eqInt #-}
 756 {-# INLINE neInt #-}
 757 {-# INLINE gtInt #-}
 758 {-# INLINE geInt #-}
 759 {-# INLINE ltInt #-}
 760 {-# INLINE leInt #-}
 761 {-# INLINE plusInt #-}
 762 {-# INLINE minusInt #-}
 763 {-# INLINE timesInt #-}
 764 {-# INLINE quotInt #-}
 765 {-# INLINE remInt #-}
 766 {-# INLINE negateInt #-}
 767
 768 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 769 (I# x) `plusInt`  (I# y) = I# (x +# y)
 770 (I# x) `minusInt` (I# y) = I# (x -# y)
 771 (I# x) `timesInt` (I# y) = I# (x *# y)
 772 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 773 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 774 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 775 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 776
 777 {-# RULES
 778 "x# +# 0#" forall x#. x# +# 0# = x#
 779 "0# +# x#" forall x#. 0# +# x# = x#
 780 "x# -# 0#" forall x#. x# -# 0# = x#
 781 "x# -# x#" forall x#. x# -# x# = 0#
 782 "x# *# 0#" forall x#. x# *# 0# = 0#
 783 "0# *# x#" forall x#. 0# *# x# = 0#
 784 "x# *# 1#" forall x#. x# *# 1# = x#
 785 "1# *# x#" forall x#. 1# *# x# = x#
 786   #-}
 787
 788 gcdInt (I# a) (I# b) = g a b
 789    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 790          g 0# _  = I# absB
 791          g _  0# = I# absA
 792          g _  _  = I# (gcdInt# absA absB)
 793
 794          absInt x = if x <# 0# then negateInt# x else x
 795
 796          absA     = absInt a
 797          absB     = absInt b
 798
 799 negateInt :: Int -> Int
 800 negateInt (I# x) = I# (negateInt# x)
 801
 802 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 803 (I# x) `gtInt` (I# y) = x >#  y
 804 (I# x) `geInt` (I# y) = x >=# y
 805 (I# x) `eqInt` (I# y) = x ==# y
 806 (I# x) `neInt` (I# y) = x /=# y
 807 (I# x) `ltInt` (I# y) = x <#  y
 808 (I# x) `leInt` (I# y) = x <=# y
 809
 810 {-# RULES
 811 "x# ># x#"  forall x#. x# >#  x# = False
 812 "x# >=# x#" forall x#. x# >=# x# = True
 813 "x# ==# x#" forall x#. x# ==# x# = True
 814 "x# /=# x#" forall x#. x# /=# x# = False
 815 "x# <# x#"  forall x#. x# <#  x# = False
 816 "x# <=# x#" forall x#. x# <=# x# = True
 817   #-}
 818
 819 {-# RULES
 820 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 821 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 822 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 823 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 824 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 825 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 826 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 827 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 828 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 829   #-}
 830
 831 {-# RULES
 832 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 833 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 834 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 835 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 836 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 837 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 838 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 839 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 840 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 841   #-}
 842
 843 -- Wrappers for the shift operations.  The uncheckedShift# family are
 844 -- undefined when the amount being shifted by is greater than the size
 845 -- in bits of Int#, so these wrappers perform a check and return
 846 -- either zero or -1 appropriately.
 847 --
 848 -- Note that these wrappers still produce undefined results when the
 849 -- second argument (the shift amount) is negative.
 850
 851 shiftL#, shiftRL# :: Word# -> Int# -> Word#
 852
 853 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 854                 | otherwise                = a `uncheckedShiftL#` b
 855
 856 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 857                 | otherwise                = a `uncheckedShiftRL#` b
 858
 859 iShiftL#, iShiftRA#, iShiftRL# :: Int# -> Int# -> Int#
 860
 861 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 862                 | otherwise                = a `uncheckedIShiftL#` b
 863
 864 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 865                 | otherwise                = a `uncheckedIShiftRA#` b
 866
 867 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 868                 | otherwise                = a `uncheckedIShiftRL#` b
 869
 870 #if WORD_SIZE_IN_BITS == 32
 871 {-# RULES
 872 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 873 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 874    #-}
 875 #endif
 876
 877 {-# RULES
 878 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 879 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 880   #-}
 881 \end{code}
 882
 883
 884 %********************************************************
 885 %*                                                      *
 886 \subsection{Unpacking C strings}
 887 %*                                                      *
 888 %********************************************************
 889
 890 This code is needed for virtually all programs, since it's used for
 891 unpacking the strings of error messages.
 892
 893 \begin{code}
 894 unpackCString# :: Addr# -> [Char]
 895 {-# NOINLINE [1] unpackCString# #-}
 896 unpackCString# addr
 897   = unpack 0#
 898   where
 899     unpack nh
 900       | ch `eqChar#` '\0'# = []
 901       | otherwise          = C# ch : unpack (nh +# 1#)
 902       where
 903         ch = indexCharOffAddr# addr nh
 904
 905 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 906 unpackAppendCString# addr rest
 907   = unpack 0#
 908   where
 909     unpack nh
 910       | ch `eqChar#` '\0'# = rest
 911       | otherwise          = C# ch : unpack (nh +# 1#)
 912       where
 913         ch = indexCharOffAddr# addr nh
 914
 915 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 916 {-# NOINLINE [0] unpackFoldrCString# #-}
 917 -- Don't inline till right at the end;
 918 -- usually the unpack-list rule turns it into unpackCStringList
 919 unpackFoldrCString# addr f z
 920   = unpack 0#
 921   where
 922     unpack nh
 923       | ch `eqChar#` '\0'# = z
 924       | otherwise          = C# ch `f` unpack (nh +# 1#)
 925       where
 926         ch = indexCharOffAddr# addr nh
 927
 928 unpackCStringUtf8# :: Addr# -> [Char]
 929 unpackCStringUtf8# addr
 930   = unpack 0#
 931   where
 932     unpack nh
 933       | ch `eqChar#` '\0'#   = []
 934       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 935       | ch `leChar#` '\xDF'# =
 936           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 937                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 938           unpack (nh +# 2#)
 939       | ch `leChar#` '\xEF'# =
 940           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 941                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 942                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 943           unpack (nh +# 3#)
 944       | otherwise            =
 945           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 946                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 947                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 948                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 949           unpack (nh +# 4#)
 950       where
 951         ch = indexCharOffAddr# addr nh
 952
 953 unpackNBytes# :: Addr# -> Int# -> [Char]
 954 unpackNBytes# _addr 0#   = []
 955 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 956     where
 957      unpack acc i#
 958       | i# <# 0#  = acc
 959       | otherwise =
 960          case indexCharOffAddr# addr i# of
 961             ch -> unpack (C# ch : acc) (i# -# 1#)
 962
 963 {-# RULES
 964 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
 965 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 966 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 967
 968 -- There's a built-in rule (in PrelRules.lhs) for
 969 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 970
 971   #-}
 972 \end{code}
 973
 974 #ifdef __HADDOCK__
 975 \begin{code}
 976 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
 977 -- indexing a state embedded in the 'Prelude.IO' monad by
 978 -- 'Control.Monad.ST.stToIO'.
 979 data RealWorld
 980 \end{code}
 981 #endif