GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_GHC -fno-warn-orphans #-}
  67 {-# OPTIONS_HADDOCK hide #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Bool,
  89         module GHC.Classes,
  90         module GHC.Generics,
  91         module GHC.Ordering,
  92         module GHC.Types,
  93         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  94         module GHC.Err          -- of people having to import it explicitly
  95   )
  96         where
  97
  98 import GHC.Types
  99 import GHC.Bool
 100 import GHC.Classes
 101 import GHC.Generics
 102 import GHC.Ordering
 103 import GHC.Prim
 104 import {-# SOURCE #-} GHC.Show
 105 import {-# SOURCE #-} GHC.Err
 106 import {-# SOURCE #-} GHC.IO (failIO)
 107
 108 -- These two are not strictly speaking required by this module, but they are
 109 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 110 -- as imports here helps to get the dependencies right in the new build system.
 111 import GHC.Tuple ()
 112 import GHC.Unit ()
 113
 114 infixr 9  .
 115 infixr 5  ++
 116 infixl 4  <$
 117 infixl 1  >>, >>=
 118 infixr 0  $
 119
 120 default ()              -- Double isn't available yet
 121 \end{code}
 122
 123
 124 %*********************************************************
 125 %*                                                      *
 126 \subsection{DEBUGGING STUFF}
 127 %*  (for use when compiling GHC.Base itself doesn't work)
 128 %*                                                      *
 129 %*********************************************************
 130
 131 \begin{code}
 132 {-
 133 data  Bool  =  False | True
 134 data Ordering = LT | EQ | GT
 135 data Char = C# Char#
 136 type  String = [Char]
 137 data Int = I# Int#
 138 data  ()  =  ()
 139 data [] a = MkNil
 140
 141 not True = False
 142 (&&) True True = True
 143 otherwise = True
 144
 145 build = error "urk"
 146 foldr = error "urk"
 147
 148 unpackCString# :: Addr# -> [Char]
 149 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 150 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 151 unpackCStringUtf8# :: Addr# -> [Char]
 152 unpackCString# a = error "urk"
 153 unpackFoldrCString# a = error "urk"
 154 unpackAppendCString# a = error "urk"
 155 unpackCStringUtf8# a = error "urk"
 156 -}
 157 \end{code}
 158
 159
 160 %*********************************************************
 161 %*                                                      *
 162 \subsection{Monadic classes @Functor@, @Monad@ }
 163 %*                                                      *
 164 %*********************************************************
 165
 166 \begin{code}
 167 {- | The 'Functor' class is used for types that can be mapped over.
 168 Instances of 'Functor' should satisfy the following laws:
 169
 170 > fmap id  ==  id
 171 > fmap (f . g)  ==  fmap f . fmap g
 172
 173 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 174 defined in the "Prelude" satisfy these laws.
 175 -}
 176
 177 class  Functor f  where
 178     fmap        :: (a -> b) -> f a -> f b
 179
 180     -- | Replace all locations in the input with the same value.
 181     -- The default definition is @'fmap' . 'const'@, but this may be
 182     -- overridden with a more efficient version.
 183     (<$)        :: a -> f b -> f a
 184     (<$)        =  fmap . const
 185
 186 {- | The 'Monad' class defines the basic operations over a /monad/,
 187 a concept from a branch of mathematics known as /category theory/.
 188 From the perspective of a Haskell programmer, however, it is best to
 189 think of a monad as an /abstract datatype/ of actions.
 190 Haskell's @do@ expressions provide a convenient syntax for writing
 191 monadic expressions.
 192
 193 Minimal complete definition: '>>=' and 'return'.
 194
 195 Instances of 'Monad' should satisfy the following laws:
 196
 197 > return a >>= k  ==  k a
 198 > m >>= return  ==  m
 199 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 200
 201 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 202
 203 > fmap f xs  ==  xs >>= return . f
 204
 205 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 206 defined in the "Prelude" satisfy these laws.
 207 -}
 208
 209 class  Monad m  where
 210     -- | Sequentially compose two actions, passing any value produced
 211     -- by the first as an argument to the second.
 212     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 213     -- | Sequentially compose two actions, discarding any value produced
 214     -- by the first, like sequencing operators (such as the semicolon)
 215     -- in imperative languages.
 216     (>>)        :: forall a b. m a -> m b -> m b
 217         -- Explicit for-alls so that we know what order to
 218         -- give type arguments when desugaring
 219
 220     -- | Inject a value into the monadic type.
 221     return      :: a -> m a
 222     -- | Fail with a message.  This operation is not part of the
 223     -- mathematical definition of a monad, but is invoked on pattern-match
 224     -- failure in a @do@ expression.
 225     fail        :: String -> m a
 226
 227     {-# INLINE (>>) #-}
 228     m >> k      = m >>= \_ -> k
 229     fail s      = error s
 230 \end{code}
 231
 232
 233 %*********************************************************
 234 %*                                                      *
 235 \subsection{The list type}
 236 %*                                                      *
 237 %*********************************************************
 238
 239 \begin{code}
 240 -- do explicitly: deriving (Eq, Ord)
 241 -- to avoid weird names like con2tag_[]#
 242
 243 instance (Eq a) => Eq [a] where
 244     {-# SPECIALISE instance Eq [Char] #-}
 245     []     == []     = True
 246     (x:xs) == (y:ys) = x == y && xs == ys
 247     _xs    == _ys    = False
 248
 249 instance (Ord a) => Ord [a] where
 250     {-# SPECIALISE instance Ord [Char] #-}
 251     compare []     []     = EQ
 252     compare []     (_:_)  = LT
 253     compare (_:_)  []     = GT
 254     compare (x:xs) (y:ys) = case compare x y of
 255                                 EQ    -> compare xs ys
 256                                 other -> other
 257
 258 instance Functor [] where
 259     fmap = map
 260
 261 instance  Monad []  where
 262     m >>= k             = foldr ((++) . k) [] m
 263     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 264     return x            = [x]
 265     fail _              = []
 266 \end{code}
 267
 268 A few list functions that appear here because they are used here.
 269 The rest of the prelude list functions are in GHC.List.
 270
 271 ----------------------------------------------
 272 --      foldr/build/augment
 273 ----------------------------------------------
 274
 275 \begin{code}
 276 -- | 'foldr', applied to a binary operator, a starting value (typically
 277 -- the right-identity of the operator), and a list, reduces the list
 278 -- using the binary operator, from right to left:
 279 --
 280 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 281
 282 foldr            :: (a -> b -> b) -> b -> [a] -> b
 283 -- foldr _ z []     =  z
 284 -- foldr f z (x:xs) =  f x (foldr f z xs)
 285 {-# INLINE [0] foldr #-}
 286 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 287 -- Also note that we inline it when it has *two* parameters, which are the
 288 -- ones we are keen about specialising!
 289 foldr k z = go
 290           where
 291             go []     = z
 292             go (y:ys) = y `k` go ys
 293
 294 -- | A list producer that can be fused with 'foldr'.
 295 -- This function is merely
 296 --
 297 -- >    build g = g (:) []
 298 --
 299 -- but GHC's simplifier will transform an expression of the form
 300 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 301 -- which avoids producing an intermediate list.
 302
 303 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 304 {-# INLINE [1] build #-}
 305         -- The INLINE is important, even though build is tiny,
 306         -- because it prevents [] getting inlined in the version that
 307         -- appears in the interface file.  If [] *is* inlined, it
 308         -- won't match with [] appearing in rules in an importing module.
 309         --
 310         -- The "1" says to inline in phase 1
 311
 312 build g = g (:) []
 313
 314 -- | A list producer that can be fused with 'foldr'.
 315 -- This function is merely
 316 --
 317 -- >    augment g xs = g (:) xs
 318 --
 319 -- but GHC's simplifier will transform an expression of the form
 320 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 321 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 322
 323 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 324 {-# INLINE [1] augment #-}
 325 augment g xs = g (:) xs
 326
 327 {-# RULES
 328 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 329                 foldr k z (build g) = g k z
 330
 331 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 332                 foldr k z (augment g xs) = g k (foldr k z xs)
 333
 334 "foldr/id"                        foldr (:) [] = \x  -> x
 335 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 336         -- Only activate this from phase 1, because that's
 337         -- when we disable the rule that expands (++) into foldr
 338
 339 -- The foldr/cons rule looks nice, but it can give disastrously
 340 -- bloated code when commpiling
 341 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 342 -- i.e. when there are very very long literal lists
 343 -- So I've disabled it for now. We could have special cases
 344 -- for short lists, I suppose.
 345 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 346
 347 "foldr/single"  forall k z x. foldr k z [x] = k x z
 348 "foldr/nil"     forall k z.   foldr k z []  = z
 349
 350 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 351                        (h::forall b. (a->b->b) -> b -> b) .
 352                        augment g (build h) = build (\c n -> g c (h c n))
 353 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 354                         augment g [] = build g
 355  #-}
 356
 357 -- This rule is true, but not (I think) useful:
 358 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 359 \end{code}
 360
 361
 362 ----------------------------------------------
 363 --              map
 364 ----------------------------------------------
 365
 366 \begin{code}
 367 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 368 -- of @xs@, i.e.,
 369 --
 370 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 371 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 372
 373 map :: (a -> b) -> [a] -> [b]
 374 map _ []     = []
 375 map f (x:xs) = f x : map f xs
 376
 377 -- Note eta expanded
 378 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 379 {-# INLINE [0] mapFB #-}
 380 mapFB c f x ys = c (f x) ys
 381
 382 -- The rules for map work like this.
 383 --
 384 -- Up to (but not including) phase 1, we use the "map" rule to
 385 -- rewrite all saturated applications of map with its build/fold
 386 -- form, hoping for fusion to happen.
 387 -- In phase 1 and 0, we switch off that rule, inline build, and
 388 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 389 -- thing back into plain map.
 390 --
 391 -- It's important that these two rules aren't both active at once
 392 -- (along with build's unfolding) else we'd get an infinite loop
 393 -- in the rules.  Hence the activation control below.
 394 --
 395 -- The "mapFB" rule optimises compositions of map.
 396 --
 397 -- This same pattern is followed by many other functions:
 398 -- e.g. append, filter, iterate, repeat, etc.
 399
 400 {-# RULES
 401 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 402 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 403 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 404   #-}
 405 \end{code}
 406
 407
 408 ----------------------------------------------
 409 --              append
 410 ----------------------------------------------
 411 \begin{code}
 412 -- | Append two lists, i.e.,
 413 --
 414 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 415 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 416 --
 417 -- If the first list is not finite, the result is the first list.
 418
 419 (++) :: [a] -> [a] -> [a]
 420 (++) []     ys = ys
 421 (++) (x:xs) ys = x : xs ++ ys
 422
 423 {-# RULES
 424 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 425   #-}
 426
 427 \end{code}
 428
 429
 430 %*********************************************************
 431 %*                                                      *
 432 \subsection{Type @Bool@}
 433 %*                                                      *
 434 %*********************************************************
 435
 436 \begin{code}
 437 -- |'otherwise' is defined as the value 'True'.  It helps to make
 438 -- guards more readable.  eg.
 439 --
 440 -- >  f x | x < 0     = ...
 441 -- >      | otherwise = ...
 442 otherwise               :: Bool
 443 otherwise               =  True
 444 \end{code}
 445
 446 %*********************************************************
 447 %*                                                      *
 448 \subsection{Type @Char@ and @String@}
 449 %*                                                      *
 450 %*********************************************************
 451
 452 \begin{code}
 453 -- | A 'String' is a list of characters.  String constants in Haskell are values
 454 -- of type 'String'.
 455 --
 456 type String = [Char]
 457
 458 {-| The character type 'Char' is an enumeration whose values represent
 459 Unicode (or equivalently ISO\/IEC 10646) characters
 460 (see <http://www.unicode.org/> for details).
 461 This set extends the ISO 8859-1 (Latin-1) character set
 462 (the first 256 charachers), which is itself an extension of the ASCII
 463 character set (the first 128 characters).
 464 A character literal in Haskell has type 'Char'.
 465
 466 To convert a 'Char' to or from the corresponding 'Int' value defined
 467 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 468 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 469 -}
 470
 471 -- We don't use deriving for Eq and Ord, because for Ord the derived
 472 -- instance defines only compare, which takes two primops.  Then
 473 -- '>' uses compare, and therefore takes two primops instead of one.
 474
 475 instance Eq Char where
 476     (C# c1) == (C# c2) = c1 `eqChar#` c2
 477     (C# c1) /= (C# c2) = c1 `neChar#` c2
 478
 479 instance Ord Char where
 480     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 481     (C# c1) >= (C# c2) = c1 `geChar#` c2
 482     (C# c1) <= (C# c2) = c1 `leChar#` c2
 483     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 484
 485 {-# RULES
 486 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 487 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 488 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 489 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 490 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 491 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 492   #-}
 493
 494 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 495 chr :: Int -> Char
 496 chr i@(I# i#)
 497  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 498  | otherwise
 499     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 500
 501 unsafeChr :: Int -> Char
 502 unsafeChr (I# i#) = C# (chr# i#)
 503
 504 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 505 ord :: Char -> Int
 506 ord (C# c#) = I# (ord# c#)
 507 \end{code}
 508
 509 String equality is used when desugaring pattern-matches against strings.
 510
 511 \begin{code}
 512 eqString :: String -> String -> Bool
 513 eqString []       []       = True
 514 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 515 eqString _        _        = False
 516
 517 {-# RULES "eqString" (==) = eqString #-}
 518 -- eqString also has a BuiltInRule in PrelRules.lhs:
 519 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 520 \end{code}
 521
 522
 523 %*********************************************************
 524 %*                                                      *
 525 \subsection{Type @Int@}
 526 %*                                                      *
 527 %*********************************************************
 528
 529 \begin{code}
 530 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 531 zeroInt = I# 0#
 532 oneInt  = I# 1#
 533 twoInt  = I# 2#
 534
 535 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 536 #if WORD_SIZE_IN_BITS == 31
 537 minInt  = I# (-0x40000000#)
 538 maxInt  = I# 0x3FFFFFFF#
 539 #elif WORD_SIZE_IN_BITS == 32
 540 minInt  = I# (-0x80000000#)
 541 maxInt  = I# 0x7FFFFFFF#
 542 #else
 543 minInt  = I# (-0x8000000000000000#)
 544 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 545 #endif
 546
 547 instance Eq Int where
 548     (==) = eqInt
 549     (/=) = neInt
 550
 551 instance Ord Int where
 552     compare = compareInt
 553     (<)     = ltInt
 554     (<=)    = leInt
 555     (>=)    = geInt
 556     (>)     = gtInt
 557
 558 compareInt :: Int -> Int -> Ordering
 559 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 560
 561 compareInt# :: Int# -> Int# -> Ordering
 562 compareInt# x# y#
 563     | x# <#  y# = LT
 564     | x# ==# y# = EQ
 565     | otherwise = GT
 566 \end{code}
 567
 568
 569 %*********************************************************
 570 %*                                                      *
 571 \subsection{The function type}
 572 %*                                                      *
 573 %*********************************************************
 574
 575 \begin{code}
 576 -- | Identity function.
 577 id                      :: a -> a
 578 id x                    =  x
 579
 580 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 581 -- magical strictness property: it is lazy in its first argument,
 582 -- even though its semantics is strict.
 583 lazy :: a -> a
 584 lazy x = x
 585 -- Implementation note: its strictness and unfolding are over-ridden
 586 -- by the definition in MkId.lhs; in both cases to nothing at all.
 587 -- That way, 'lazy' does not get inlined, and the strictness analyser
 588 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 589 -- Result: happiness
 590
 591 -- Assertion function.  This simply ignores its boolean argument.
 592 -- The compiler may rewrite it to @('assertError' line)@.
 593
 594 -- | If the first argument evaluates to 'True', then the result is the
 595 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 596 -- containing a 'String' with the source file and line number of the
 597 -- call to 'assert'.
 598 --
 599 -- Assertions can normally be turned on or off with a compiler flag
 600 -- (for GHC, assertions are normally on unless optimisation is turned on
 601 -- with @-O@ or the @-fignore-asserts@
 602 -- option is given).  When assertions are turned off, the first
 603 -- argument to 'assert' is ignored, and the second argument is
 604 -- returned as the result.
 605
 606 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 607 --      but from Template Haskell onwards it's simply
 608 --      defined here in Base.lhs
 609 assert :: Bool -> a -> a
 610 assert _pred r = r
 611
 612 breakpoint :: a -> a
 613 breakpoint r = r
 614
 615 breakpointCond :: Bool -> a -> a
 616 breakpointCond _ r = r
 617
 618 data Opaque = forall a. O a
 619
 620 -- | Constant function.
 621 const                   :: a -> b -> a
 622 const x _               =  x
 623
 624 -- | Function composition.
 625 {-# INLINE (.) #-}
 626 -- Make sure it has TWO args only on the left, so that it inlines
 627 -- when applied to two functions, even if there is no final argument
 628 (.)    :: (b -> c) -> (a -> b) -> a -> c
 629 (.) f g = \x -> f (g x)
 630
 631 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 632 flip                    :: (a -> b -> c) -> b -> a -> c
 633 flip f x y              =  f y x
 634
 635 -- | Application operator.  This operator is redundant, since ordinary
 636 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 637 -- low, right-associative binding precedence, so it sometimes allows
 638 -- parentheses to be omitted; for example:
 639 --
 640 -- >     f $ g $ h x  =  f (g (h x))
 641 --
 642 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 643 -- or @'Data.List.zipWith' ('$') fs xs@.
 644 {-# INLINE ($) #-}
 645 ($)                     :: (a -> b) -> a -> b
 646 f $ x                   =  f x
 647
 648 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 649 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 650 until p f x | p x       =  x
 651             | otherwise =  until p f (f x)
 652
 653 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 654 -- used as an infix operator, and its typing forces its first argument
 655 -- (which is usually overloaded) to have the same type as the second.
 656 asTypeOf                :: a -> a -> a
 657 asTypeOf                =  const
 658 \end{code}
 659
 660 %*********************************************************
 661 %*                                                      *
 662 \subsection{@Functor@ and @Monad@ instances for @IO@}
 663 %*                                                      *
 664 %*********************************************************
 665
 666 \begin{code}
 667 instance  Functor IO where
 668    fmap f x = x >>= (return . f)
 669
 670 instance  Monad IO  where
 671     {-# INLINE return #-}
 672     {-# INLINE (>>)   #-}
 673     {-# INLINE (>>=)  #-}
 674     m >> k    = m >>= \ _ -> k
 675     return    = returnIO
 676     (>>=)     = bindIO
 677     fail s    = GHC.IO.failIO s
 678
 679 returnIO :: a -> IO a
 680 returnIO x = IO $ \ s -> (# s, x #)
 681
 682 bindIO :: IO a -> (a -> IO b) -> IO b
 683 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 684
 685 thenIO :: IO a -> IO b -> IO b
 686 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 687
 688 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 689 unIO (IO a) = a
 690 \end{code}
 691
 692 %*********************************************************
 693 %*                                                      *
 694 \subsection{@getTag@}
 695 %*                                                      *
 696 %*********************************************************
 697
 698 Returns the 'tag' of a constructor application; this function is used
 699 by the deriving code for Eq, Ord and Enum.
 700
 701 The primitive dataToTag# requires an evaluated constructor application
 702 as its argument, so we provide getTag as a wrapper that performs the
 703 evaluation before calling dataToTag#.  We could have dataToTag#
 704 evaluate its argument, but we prefer to do it this way because (a)
 705 dataToTag# can be an inline primop if it doesn't need to do any
 706 evaluation, and (b) we want to expose the evaluation to the
 707 simplifier, because it might be possible to eliminate the evaluation
 708 in the case when the argument is already known to be evaluated.
 709
 710 \begin{code}
 711 {-# INLINE getTag #-}
 712 getTag :: a -> Int#
 713 getTag x = x `seq` dataToTag# x
 714 \end{code}
 715
 716 %*********************************************************
 717 %*                                                      *
 718 \subsection{Numeric primops}
 719 %*                                                      *
 720 %*********************************************************
 721
 722 \begin{code}
 723 divInt# :: Int# -> Int# -> Int#
 724 x# `divInt#` y#
 725         -- Be careful NOT to overflow if we do any additional arithmetic
 726         -- on the arguments...  the following  previous version of this
 727         -- code has problems with overflow:
 728 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 729 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 730     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 731     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 732     | otherwise                = x# `quotInt#` y#
 733
 734 modInt# :: Int# -> Int# -> Int#
 735 x# `modInt#` y#
 736     | (x# ># 0#) && (y# <# 0#) ||
 737       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 738     | otherwise                   = r#
 739     where
 740     !r# = x# `remInt#` y#
 741 \end{code}
 742
 743 Definitions of the boxed PrimOps; these will be
 744 used in the case of partial applications, etc.
 745
 746 \begin{code}
 747 {-# INLINE eqInt #-}
 748 {-# INLINE neInt #-}
 749 {-# INLINE gtInt #-}
 750 {-# INLINE geInt #-}
 751 {-# INLINE ltInt #-}
 752 {-# INLINE leInt #-}
 753 {-# INLINE plusInt #-}
 754 {-# INLINE minusInt #-}
 755 {-# INLINE timesInt #-}
 756 {-# INLINE quotInt #-}
 757 {-# INLINE remInt #-}
 758 {-# INLINE negateInt #-}
 759
 760 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 761 (I# x) `plusInt`  (I# y) = I# (x +# y)
 762 (I# x) `minusInt` (I# y) = I# (x -# y)
 763 (I# x) `timesInt` (I# y) = I# (x *# y)
 764 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 765 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 766 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 767 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 768
 769 {-# RULES
 770 "x# +# 0#" forall x#. x# +# 0# = x#
 771 "0# +# x#" forall x#. 0# +# x# = x#
 772 "x# -# 0#" forall x#. x# -# 0# = x#
 773 "x# -# x#" forall x#. x# -# x# = 0#
 774 "x# *# 0#" forall x#. x# *# 0# = 0#
 775 "0# *# x#" forall x#. 0# *# x# = 0#
 776 "x# *# 1#" forall x#. x# *# 1# = x#
 777 "1# *# x#" forall x#. 1# *# x# = x#
 778   #-}
 779
 780 negateInt :: Int -> Int
 781 negateInt (I# x) = I# (negateInt# x)
 782
 783 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 784 (I# x) `gtInt` (I# y) = x >#  y
 785 (I# x) `geInt` (I# y) = x >=# y
 786 (I# x) `eqInt` (I# y) = x ==# y
 787 (I# x) `neInt` (I# y) = x /=# y
 788 (I# x) `ltInt` (I# y) = x <#  y
 789 (I# x) `leInt` (I# y) = x <=# y
 790
 791 {-# RULES
 792 "x# ># x#"  forall x#. x# >#  x# = False
 793 "x# >=# x#" forall x#. x# >=# x# = True
 794 "x# ==# x#" forall x#. x# ==# x# = True
 795 "x# /=# x#" forall x#. x# /=# x# = False
 796 "x# <# x#"  forall x#. x# <#  x# = False
 797 "x# <=# x#" forall x#. x# <=# x# = True
 798   #-}
 799
 800 {-# RULES
 801 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 802 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 803 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 804 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 805 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 806 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 807 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 808 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 809 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 810   #-}
 811
 812 {-# RULES
 813 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 814 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 815 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 816 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 817 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 818 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 819   #-}
 820
 821 {-
 822 We'd like to have more rules, but for example:
 823
 824 This gives wrong answer (0) for NaN - NaN (should be NaN):
 825     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 826
 827 This gives wrong answer (0) for 0 * NaN (should be NaN):
 828     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 829
 830 This gives wrong answer (0) for NaN * 0 (should be NaN):
 831     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 832
 833 These are tested by num014.
 834 -}
 835
 836 -- Wrappers for the shift operations.  The uncheckedShift# family are
 837 -- undefined when the amount being shifted by is greater than the size
 838 -- in bits of Int#, so these wrappers perform a check and return
 839 -- either zero or -1 appropriately.
 840 --
 841 -- Note that these wrappers still produce undefined results when the
 842 -- second argument (the shift amount) is negative.
 843
 844 -- | Shift the argument left by the specified number of bits
 845 -- (which must be non-negative).
 846 shiftL# :: Word# -> Int# -> Word#
 847 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 848                 | otherwise                = a `uncheckedShiftL#` b
 849
 850 -- | Shift the argument right by the specified number of bits
 851 -- (which must be non-negative).
 852 shiftRL# :: Word# -> Int# -> Word#
 853 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 854                 | otherwise                = a `uncheckedShiftRL#` b
 855
 856 -- | Shift the argument left by the specified number of bits
 857 -- (which must be non-negative).
 858 iShiftL# :: Int# -> Int# -> Int#
 859 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 860                 | otherwise                = a `uncheckedIShiftL#` b
 861
 862 -- | Shift the argument right (signed) by the specified number of bits
 863 -- (which must be non-negative).
 864 iShiftRA# :: Int# -> Int# -> Int#
 865 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 866                 | otherwise                = a `uncheckedIShiftRA#` b
 867
 868 -- | Shift the argument right (unsigned) by the specified number of bits
 869 -- (which must be non-negative).
 870 iShiftRL# :: Int# -> Int# -> Int#
 871 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 872                 | otherwise                = a `uncheckedIShiftRL#` b
 873
 874 #if WORD_SIZE_IN_BITS == 32
 875 {-# RULES
 876 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 877 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 878    #-}
 879 #endif
 880
 881 {-# RULES
 882 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 883 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 884   #-}
 885 \end{code}
 886
 887
 888 %********************************************************
 889 %*                                                      *
 890 \subsection{Unpacking C strings}
 891 %*                                                      *
 892 %********************************************************
 893
 894 This code is needed for virtually all programs, since it's used for
 895 unpacking the strings of error messages.
 896
 897 \begin{code}
 898 unpackCString# :: Addr# -> [Char]
 899 {-# NOINLINE unpackCString# #-}
 900     -- There's really no point in inlining this, ever, cos
 901     -- the loop doesn't specialise in an interesting
 902     -- But it's pretty small, so there's a danger that
 903     -- it'll be inlined at every literal, which is a waste
 904 unpackCString# addr
 905   = unpack 0#
 906   where
 907     unpack nh
 908       | ch `eqChar#` '\0'# = []
 909       | otherwise          = C# ch : unpack (nh +# 1#)
 910       where
 911         !ch = indexCharOffAddr# addr nh
 912
 913 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 914 {-# NOINLINE unpackAppendCString# #-}
 915      -- See the NOINLINE note on unpackCString#
 916 unpackAppendCString# addr rest
 917   = unpack 0#
 918   where
 919     unpack nh
 920       | ch `eqChar#` '\0'# = rest
 921       | otherwise          = C# ch : unpack (nh +# 1#)
 922       where
 923         !ch = indexCharOffAddr# addr nh
 924
 925 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 926
 927 -- Usually the unpack-list rule turns unpackFoldrCString# into unpackCString#
 928
 929 -- It also has a BuiltInRule in PrelRules.lhs:
 930 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 931 --        =  unpackFoldrCString# "foobaz" c n
 932
 933 {-# NOINLINE unpackFoldrCString# #-}
 934 -- At one stage I had NOINLINE [0] on the grounds that, unlike
 935 -- unpackCString#, there *is* some point in inlining
 936 -- unpackFoldrCString#, because we get better code for the
 937 -- higher-order function call.  BUT there may be a lot of
 938 -- literal strings, and making a separate 'unpack' loop for
 939 -- each is highly gratuitous.  See nofib/real/anna/PrettyPrint.
 940
 941 unpackFoldrCString# addr f z
 942   = unpack 0#
 943   where
 944     unpack nh
 945       | ch `eqChar#` '\0'# = z
 946       | otherwise          = C# ch `f` unpack (nh +# 1#)
 947       where
 948         !ch = indexCharOffAddr# addr nh
 949
 950 unpackCStringUtf8# :: Addr# -> [Char]
 951 unpackCStringUtf8# addr
 952   = unpack 0#
 953   where
 954     unpack nh
 955       | ch `eqChar#` '\0'#   = []
 956       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
 957       | ch `leChar#` '\xDF'# =
 958           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
 959                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
 960           unpack (nh +# 2#)
 961       | ch `leChar#` '\xEF'# =
 962           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
 963                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 964                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
 965           unpack (nh +# 3#)
 966       | otherwise            =
 967           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
 968                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
 969                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
 970                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
 971           unpack (nh +# 4#)
 972       where
 973         !ch = indexCharOffAddr# addr nh
 974
 975 unpackNBytes# :: Addr# -> Int# -> [Char]
 976 unpackNBytes# _addr 0#   = []
 977 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
 978     where
 979      unpack acc i#
 980       | i# <# 0#  = acc
 981       | otherwise =
 982          case indexCharOffAddr# addr i# of
 983             ch -> unpack (C# ch : acc) (i# -# 1#)
 984
 985 {-# RULES
 986 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
 987 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
 988 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
 989
 990 -- There's a built-in rule (in PrelRules.lhs) for
 991 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
 992
 993   #-}
 994 \end{code}
 995
 996 #ifdef __HADDOCK__
 997 \begin{code}
 998 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
 999 -- indexing a state embedded in the 'Prelude.IO' monad by
1000 -- 'Control.Monad.ST.stToIO'.
1001 data RealWorld
1002 \end{code}
1003 #endif