GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tup        Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.Num         Class: Num, plus instances for Int
  31                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  32
  33                 Integer is needed here because it is mentioned in the signature
  34                 of 'fromInteger' in class Num
  35
  36 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  37                          plus instances for Int, Integer
  38                 Types:  Ratio, Rational
  39                         plus intances for classes so far
  40
  41                 Rational is needed here because it is mentioned in the signature
  42                 of 'toRational' in class Real
  43
  44 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  45
  46 GHC.Arr         Types: Array, MutableArray, MutableVar
  47
  48                 Does *not* contain any ByteArray stuff (see GHC.ByteArr)
  49                 Arrays are used by a function in GHC.Float
  50
  51 GHC.Float       Classes: Floating, RealFloat
  52                 Types:   Float, Double, plus instances of all classes so far
  53
  54                 This module contains everything to do with floating point.
  55                 It is a big module (900 lines)
  56                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  57
  58 GHC.ByteArr     Types: ByteArray, MutableByteArray
  59
  60                 We want this one to be after GHC.Float, because it defines arrays
  61                 of unboxed floats.
  62
  63
  64 Other Prelude modules are much easier with fewer complex dependencies.
  65
  66 \begin{code}
  67 {-# OPTIONS_GHC -fno-implicit-prelude #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  89         module GHC.Err          -- of people having to import it explicitly
  90   )
  91         where
  92
  93 import GHC.Prim
  94 import {-# SOURCE #-} GHC.Err
  95
  96 infixr 9  .
  97 infixr 5  ++, :
  98 infix  4  ==, /=, <, <=, >=, >
  99 infixr 3  &&
 100 infixr 2  ||
 101 infixl 1  >>, >>=
 102 infixr 0  $
 103
 104 default ()              -- Double isn't available yet
 105 \end{code}
 106
 107
 108 %*********************************************************
 109 %*                                                      *
 110 \subsection{DEBUGGING STUFF}
 111 %*  (for use when compiling GHC.Base itself doesn't work)
 112 %*                                                      *
 113 %*********************************************************
 114
 115 \begin{code}
 116 {-
 117 data  Bool  =  False | True
 118 data Ordering = LT | EQ | GT
 119 data Char = C# Char#
 120 type  String = [Char]
 121 data Int = I# Int#
 122 data  ()  =  ()
 123 data [] a = MkNil
 124
 125 not True = False
 126 (&&) True True = True
 127 otherwise = True
 128
 129 build = error "urk"
 130 foldr = error "urk"
 131
 132 unpackCString# :: Addr# -> [Char]
 133 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 134 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 135 unpackCStringUtf8# :: Addr# -> [Char]
 136 unpackCString# a = error "urk"
 137 unpackFoldrCString# a = error "urk"
 138 unpackAppendCString# a = error "urk"
 139 unpackCStringUtf8# a = error "urk"
 140 -}
 141 \end{code}
 142
 143
 144 %*********************************************************
 145 %*                                                      *
 146 \subsection{Standard classes @Eq@, @Ord@}
 147 %*                                                      *
 148 %*********************************************************
 149
 150 \begin{code}
 151
 152 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 153 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 154 -- and 'Eq' may be derived for any datatype whose constituents are also
 155 -- instances of 'Eq'.
 156 --
 157 -- Minimal complete definition: either '==' or '/='.
 158 --
 159 class  Eq a  where
 160     (==), (/=)           :: a -> a -> Bool
 161
 162     x /= y               = not (x == y)
 163     x == y               = not (x /= y)
 164
 165 -- | The 'Ord' class is used for totally ordered datatypes.
 166 --
 167 -- Instances of 'Ord' can be derived for any user-defined
 168 -- datatype whose constituent types are in 'Ord'.  The declared order
 169 -- of the constructors in the data declaration determines the ordering
 170 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 171 -- comparison to determine the precise ordering of two objects.
 172 --
 173 -- Minimal complete definition: either 'compare' or '<='.
 174 -- Using 'compare' can be more efficient for complex types.
 175 --
 176 class  (Eq a) => Ord a  where
 177     compare              :: a -> a -> Ordering
 178     (<), (<=), (>), (>=) :: a -> a -> Bool
 179     max, min             :: a -> a -> a
 180
 181     compare x y
 182         | x == y    = EQ
 183         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 184                                 -- above claim about the minimal things that
 185                                 -- can be defined for an instance of Ord
 186         | otherwise = GT
 187
 188     x <  y = case compare x y of { LT -> True;  _other -> False }
 189     x <= y = case compare x y of { GT -> False; _other -> True }
 190     x >  y = case compare x y of { GT -> True;  _other -> False }
 191     x >= y = case compare x y of { LT -> False; _other -> True }
 192
 193         -- These two default methods use '<=' rather than 'compare'
 194         -- because the latter is often more expensive
 195     max x y = if x <= y then y else x
 196     min x y = if x <= y then x else y
 197 \end{code}
 198
 199 %*********************************************************
 200 %*                                                      *
 201 \subsection{Monadic classes @Functor@, @Monad@ }
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 {- | The 'Functor' class is used for types that can be mapped over.
 207 Instances of 'Functor' should satisfy the following laws:
 208
 209 > fmap id  ==  id
 210 > fmap (f . g)  ==  fmap f . fmap g
 211
 212 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 213 defined in the "Prelude" satisfy these laws.
 214 -}
 215
 216 class  Functor f  where
 217     fmap        :: (a -> b) -> f a -> f b
 218
 219 {- | The 'Monad' class defines the basic operations over a /monad/,
 220 a concept from a branch of mathematics known as /category theory/.
 221 From the perspective of a Haskell programmer, however, it is best to
 222 think of a monad as an /abstract datatype/ of actions.
 223 Haskell's @do@ expressions provide a convenient syntax for writing
 224 monadic expressions.
 225
 226 Minimal complete definition: '>>=' and 'return'.
 227
 228 Instances of 'Monad' should satisfy the following laws:
 229
 230 > return a >>= k  ==  k a
 231 > m >>= return  ==  m
 232 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 233
 234 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 235
 236 > fmap f xs  ==  xs >>= return . f
 237
 238 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 239 defined in the "Prelude" satisfy these laws.
 240 -}
 241
 242 class  Monad m  where
 243     -- | Sequentially compose two actions, passing any value produced
 244     -- by the first as an argument to the second.
 245     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 246     -- | Sequentially compose two actions, discarding any value produced
 247     -- by the first, like sequencing operators (such as the semicolon)
 248     -- in imperative languages.
 249     (>>)        :: forall a b. m a -> m b -> m b
 250         -- Explicit for-alls so that we know what order to
 251         -- give type arguments when desugaring
 252
 253     -- | Inject a value into the monadic type.
 254     return      :: a -> m a
 255     -- | Fail with a message.  This operation is not part of the
 256     -- mathematical definition of a monad, but is invoked on pattern-match
 257     -- failure in a @do@ expression.
 258     fail        :: String -> m a
 259
 260     m >> k      = m >>= \_ -> k
 261     fail s      = error s
 262 \end{code}
 263
 264
 265 %*********************************************************
 266 %*                                                      *
 267 \subsection{The list type}
 268 %*                                                      *
 269 %*********************************************************
 270
 271 \begin{code}
 272 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 273                           -- to avoid weird names like con2tag_[]#
 274
 275
 276 instance (Eq a) => Eq [a] where
 277     {-# SPECIALISE instance Eq [Char] #-}
 278     []     == []     = True
 279     (x:xs) == (y:ys) = x == y && xs == ys
 280     _xs    == _ys    = False
 281
 282 instance (Ord a) => Ord [a] where
 283     {-# SPECIALISE instance Ord [Char] #-}
 284     compare []     []     = EQ
 285     compare []     (_:_)  = LT
 286     compare (_:_)  []     = GT
 287     compare (x:xs) (y:ys) = case compare x y of
 288                                 EQ    -> compare xs ys
 289                                 other -> other
 290
 291 instance Functor [] where
 292     fmap = map
 293
 294 instance  Monad []  where
 295     m >>= k             = foldr ((++) . k) [] m
 296     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 297     return x            = [x]
 298     fail _              = []
 299 \end{code}
 300
 301 A few list functions that appear here because they are used here.
 302 The rest of the prelude list functions are in GHC.List.
 303
 304 ----------------------------------------------
 305 --      foldr/build/augment
 306 ----------------------------------------------
 307
 308 \begin{code}
 309 -- | 'foldr', applied to a binary operator, a starting value (typically
 310 -- the right-identity of the operator), and a list, reduces the list
 311 -- using the binary operator, from right to left:
 312 --
 313 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 314
 315 foldr            :: (a -> b -> b) -> b -> [a] -> b
 316 -- foldr _ z []     =  z
 317 -- foldr f z (x:xs) =  f x (foldr f z xs)
 318 {-# INLINE [0] foldr #-}
 319 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 320 foldr k z xs = go xs
 321              where
 322                go []     = z
 323                go (y:ys) = y `k` go ys
 324
 325 -- | A list producer that can be fused with 'foldr'.
 326 -- This function is merely
 327 --
 328 -- >    build g = g (:) []
 329 --
 330 -- but GHC's simplifier will transform an expression of the form
 331 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 332 -- which avoids producing an intermediate list.
 333
 334 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 335 {-# INLINE [1] build #-}
 336         -- The INLINE is important, even though build is tiny,
 337         -- because it prevents [] getting inlined in the version that
 338         -- appears in the interface file.  If [] *is* inlined, it
 339         -- won't match with [] appearing in rules in an importing module.
 340         --
 341         -- The "1" says to inline in phase 1
 342
 343 build g = g (:) []
 344
 345 -- | A list producer that can be fused with 'foldr'.
 346 -- This function is merely
 347 --
 348 -- >    augment g xs = g (:) xs
 349 --
 350 -- but GHC's simplifier will transform an expression of the form
 351 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 352 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 353
 354 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 355 {-# INLINE [1] augment #-}
 356 augment g xs = g (:) xs
 357
 358 {-# RULES
 359 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 360                 foldr k z (build g) = g k z
 361
 362 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 363                 foldr k z (augment g xs) = g k (foldr k z xs)
 364
 365 "foldr/id"                        foldr (:) [] = \x->x
 366 "foldr/app"     [1] forall xs ys. foldr (:) ys xs = xs ++ ys
 367         -- Only activate this from phase 1, because that's
 368         -- when we disable the rule that expands (++) into foldr
 369
 370 -- The foldr/cons rule looks nice, but it can give disastrously
 371 -- bloated code when commpiling
 372 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 373 -- i.e. when there are very very long literal lists
 374 -- So I've disabled it for now. We could have special cases
 375 -- for short lists, I suppose.
 376 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 377
 378 "foldr/single"  forall k z x. foldr k z [x] = k x z
 379 "foldr/nil"     forall k z.   foldr k z []  = z
 380
 381 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 382                        (h::forall b. (a->b->b) -> b -> b) .
 383                        augment g (build h) = build (\c n -> g c (h c n))
 384 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 385                         augment g [] = build g
 386  #-}
 387
 388 -- This rule is true, but not (I think) useful:
 389 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 390 \end{code}
 391
 392
 393 ----------------------------------------------
 394 --              map
 395 ----------------------------------------------
 396
 397 \begin{code}
 398 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 399 -- of @xs@, i.e.,
 400 --
 401 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 402 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 403
 404 map :: (a -> b) -> [a] -> [b]
 405 map _ []     = []
 406 map f (x:xs) = f x : map f xs
 407
 408 -- Note eta expanded
 409 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 410 {-# INLINE [0] mapFB #-}
 411 mapFB c f x ys = c (f x) ys
 412
 413 -- The rules for map work like this.
 414 --
 415 -- Up to (but not including) phase 1, we use the "map" rule to
 416 -- rewrite all saturated applications of map with its build/fold
 417 -- form, hoping for fusion to happen.
 418 -- In phase 1 and 0, we switch off that rule, inline build, and
 419 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 420 -- thing back into plain map.
 421 --
 422 -- It's important that these two rules aren't both active at once
 423 -- (along with build's unfolding) else we'd get an infinite loop
 424 -- in the rules.  Hence the activation control below.
 425 --
 426 -- The "mapFB" rule optimises compositions of map.
 427 --
 428 -- This same pattern is followed by many other functions:
 429 -- e.g. append, filter, iterate, repeat, etc.
 430
 431 {-# RULES
 432 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 433 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 434 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 435   #-}
 436 \end{code}
 437
 438
 439 ----------------------------------------------
 440 --              append
 441 ----------------------------------------------
 442 \begin{code}
 443 -- | Append two lists, i.e.,
 444 --
 445 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 446 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 447 --
 448 -- If the first list is not finite, the result is the first list.
 449
 450 (++) :: [a] -> [a] -> [a]
 451 (++) []     ys = ys
 452 (++) (x:xs) ys = x : xs ++ ys
 453
 454 {-# RULES
 455 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 456   #-}
 457
 458 \end{code}
 459
 460
 461 %*********************************************************
 462 %*                                                      *
 463 \subsection{Type @Bool@}
 464 %*                                                      *
 465 %*********************************************************
 466
 467 \begin{code}
 468 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 469 -- first so that the corresponding 'Prelude.Enum' instance will give
 470 -- 'Prelude.fromEnum' 'False' the value zero, and
 471 -- 'Prelude.fromEnum' 'True' the value 1.
 472 data  Bool  =  False | True  deriving (Eq, Ord)
 473         -- Read in GHC.Read, Show in GHC.Show
 474
 475 -- Boolean functions
 476
 477 -- | Boolean \"and\"
 478 (&&)                    :: Bool -> Bool -> Bool
 479 True  && x              =  x
 480 False && _              =  False
 481
 482 -- | Boolean \"or\"
 483 (||)                    :: Bool -> Bool -> Bool
 484 True  || _              =  True
 485 False || x              =  x
 486
 487 -- | Boolean \"not\"
 488 not                     :: Bool -> Bool
 489 not True                =  False
 490 not False               =  True
 491
 492 -- |'otherwise' is defined as the value 'True'.  It helps to make
 493 -- guards more readable.  eg.
 494 --
 495 -- >  f x | x < 0     = ...
 496 -- >      | otherwise = ...
 497 otherwise               :: Bool
 498 otherwise               =  True
 499 \end{code}
 500
 501
 502 %*********************************************************
 503 %*                                                      *
 504 \subsection{The @()@ type}
 505 %*                                                      *
 506 %*********************************************************
 507
 508 The Unit type is here because virtually any program needs it (whereas
 509 some programs may get away without consulting GHC.Tup).  Furthermore,
 510 the renamer currently *always* asks for () to be in scope, so that
 511 ccalls can use () as their default type; so when compiling GHC.Base we
 512 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 513 it here seems more direct.)
 514
 515 \begin{code}
 516 -- | The unit datatype @()@ has one non-undefined member, the nullary
 517 -- constructor @()@.
 518 data () = ()
 519
 520 instance Eq () where
 521     () == () = True
 522     () /= () = False
 523
 524 instance Ord () where
 525     () <= () = True
 526     () <  () = False
 527     () >= () = True
 528     () >  () = False
 529     max () () = ()
 530     min () () = ()
 531     compare () () = EQ
 532 \end{code}
 533
 534
 535 %*********************************************************
 536 %*                                                      *
 537 \subsection{Type @Ordering@}
 538 %*                                                      *
 539 %*********************************************************
 540
 541 \begin{code}
 542 -- | Represents an ordering relationship between two values: less
 543 -- than, equal to, or greater than.  An 'Ordering' is returned by
 544 -- 'compare'.
 545 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 546         -- Read in GHC.Read, Show in GHC.Show
 547 \end{code}
 548
 549
 550 %*********************************************************
 551 %*                                                      *
 552 \subsection{Type @Char@ and @String@}
 553 %*                                                      *
 554 %*********************************************************
 555
 556 \begin{code}
 557 -- | A 'String' is a list of characters.  String constants in Haskell are values
 558 -- of type 'String'.
 559 --
 560 type String = [Char]
 561
 562 {-| The character type 'Char' is an enumeration whose values represent
 563 Unicode (or equivalently ISO\/IEC 10646) characters
 564 (see <http://www.unicode.org/> for details).
 565 This set extends the ISO 8859-1 (Latin-1) character set
 566 (the first 256 charachers), which is itself an extension of the ASCII
 567 character set (the first 128 characters).
 568 A character literal in Haskell has type 'Char'.
 569
 570 To convert a 'Char' to or from the corresponding 'Int' value defined
 571 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 572 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 573 -}
 574 data Char = C# Char#
 575
 576 -- We don't use deriving for Eq and Ord, because for Ord the derived
 577 -- instance defines only compare, which takes two primops.  Then
 578 -- '>' uses compare, and therefore takes two primops instead of one.
 579
 580 instance Eq Char where
 581     (C# c1) == (C# c2) = c1 `eqChar#` c2
 582     (C# c1) /= (C# c2) = c1 `neChar#` c2
 583
 584 instance Ord Char where
 585     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 586     (C# c1) >= (C# c2) = c1 `geChar#` c2
 587     (C# c1) <= (C# c2) = c1 `leChar#` c2
 588     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 589
 590 {-# RULES
 591 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 592 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 593 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 594 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 595 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 596 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 597   #-}
 598
 599 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 600 chr :: Int -> Char
 601 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 602             | otherwise                                  = error "Prelude.chr: bad argument"
 603
 604 unsafeChr :: Int -> Char
 605 unsafeChr (I# i#) = C# (chr# i#)
 606
 607 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 608 ord :: Char -> Int
 609 ord (C# c#) = I# (ord# c#)
 610 \end{code}
 611
 612 String equality is used when desugaring pattern-matches against strings.
 613
 614 \begin{code}
 615 eqString :: String -> String -> Bool
 616 eqString []       []       = True
 617 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 618 eqString cs1      cs2      = False
 619
 620 {-# RULES "eqString" (==) = eqString #-}
 621 \end{code}
 622
 623
 624 %*********************************************************
 625 %*                                                      *
 626 \subsection{Type @Int@}
 627 %*                                                      *
 628 %*********************************************************
 629
 630 \begin{code}
 631 data Int = I# Int#
 632 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
 633 -- The exact range for a given implementation can be determined by using
 634 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
 635
 636 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 637 zeroInt = I# 0#
 638 oneInt  = I# 1#
 639 twoInt  = I# 2#
 640
 641 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 642 #if WORD_SIZE_IN_BITS == 31
 643 minInt  = I# (-0x40000000#)
 644 maxInt  = I# 0x3FFFFFFF#
 645 #elif WORD_SIZE_IN_BITS == 32
 646 minInt  = I# (-0x80000000#)
 647 maxInt  = I# 0x7FFFFFFF#
 648 #else
 649 minInt  = I# (-0x8000000000000000#)
 650 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 651 #endif
 652
 653 instance Eq Int where
 654     (==) = eqInt
 655     (/=) = neInt
 656
 657 instance Ord Int where
 658     compare = compareInt
 659     (<)     = ltInt
 660     (<=)    = leInt
 661     (>=)    = geInt
 662     (>)     = gtInt
 663
 664 compareInt :: Int -> Int -> Ordering
 665 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 666
 667 compareInt# :: Int# -> Int# -> Ordering
 668 compareInt# x# y#
 669     | x# <#  y# = LT
 670     | x# ==# y# = EQ
 671     | otherwise = GT
 672 \end{code}
 673
 674
 675 %*********************************************************
 676 %*                                                      *
 677 \subsection{The function type}
 678 %*                                                      *
 679 %*********************************************************
 680
 681 \begin{code}
 682 -- | Identity function.
 683 id                      :: a -> a
 684 id x                    =  x
 685
 686 -- lazy function; this is just the same as id, but its unfolding
 687 -- and strictness are over-ridden by the definition in MkId.lhs
 688 -- That way, it does not get inlined, and the strictness analyser
 689 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 690 -- Result: happiness
 691 lazy :: a -> a
 692 lazy x = x
 693
 694 -- Assertion function.  This simply ignores its boolean argument.
 695 -- The compiler may rewrite it to @('assertError' line)@.
 696
 697 -- | If the first argument evaluates to 'True', then the result is the
 698 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 699 -- containing a 'String' with the source file and line number of the
 700 -- call to 'assert'.
 701 --
 702 -- Assertions can normally be turned on or off with a compiler flag
 703 -- (for GHC, assertions are normally on unless the @-fignore-asserts@
 704 -- option is given).  When assertions are turned off, the first
 705 -- argument to 'assert' is ignored, and the second argument is
 706 -- returned as the result.
 707
 708 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 709 --      but from Template Haskell onwards it's simply
 710 --      defined here in Base.lhs
 711 assert :: Bool -> a -> a
 712 assert pred r = r
 713
 714 -- | Constant function.
 715 const                   :: a -> b -> a
 716 const x _               =  x
 717
 718 -- | Function composition.
 719 {-# INLINE (.) #-}
 720 (.)       :: (b -> c) -> (a -> b) -> a -> c
 721 (.) f g x = f (g x)
 722
 723 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 724 flip                    :: (a -> b -> c) -> b -> a -> c
 725 flip f x y              =  f y x
 726
 727 -- | Application operator.  This operator is redundant, since ordinary
 728 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 729 -- low, right-associative binding precedence, so it sometimes allows
 730 -- parentheses to be omitted; for example:
 731 --
 732 -- >     f $ g $ h x  =  f (g (h x))
 733 --
 734 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 735 -- or @'Data.List.zipWith' ('$') fs xs@.
 736 {-# INLINE ($) #-}
 737 ($)                     :: (a -> b) -> a -> b
 738 f $ x                   =  f x
 739
 740 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 741 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 742 until p f x | p x       =  x
 743             | otherwise =  until p f (f x)
 744
 745 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 746 -- used as an infix operator, and its typing forces its first argument
 747 -- (which is usually overloaded) to have the same type as the second.
 748 asTypeOf                :: a -> a -> a
 749 asTypeOf                =  const
 750 \end{code}
 751
 752 %*********************************************************
 753 %*                                                      *
 754 \subsection{Generics}
 755 %*                                                      *
 756 %*********************************************************
 757
 758 \begin{code}
 759 data Unit = Unit
 760 #ifndef __HADDOCK__
 761 data (:+:) a b = Inl a | Inr b
 762 data (:*:) a b = a :*: b
 763 #endif
 764 \end{code}
 765
 766 %*********************************************************
 767 %*                                                      *
 768 \subsection{@getTag@}
 769 %*                                                      *
 770 %*********************************************************
 771
 772 Returns the 'tag' of a constructor application; this function is used
 773 by the deriving code for Eq, Ord and Enum.
 774
 775 The primitive dataToTag# requires an evaluated constructor application
 776 as its argument, so we provide getTag as a wrapper that performs the
 777 evaluation before calling dataToTag#.  We could have dataToTag#
 778 evaluate its argument, but we prefer to do it this way because (a)
 779 dataToTag# can be an inline primop if it doesn't need to do any
 780 evaluation, and (b) we want to expose the evaluation to the
 781 simplifier, because it might be possible to eliminate the evaluation
 782 in the case when the argument is already known to be evaluated.
 783
 784 \begin{code}
 785 {-# INLINE getTag #-}
 786 getTag :: a -> Int#
 787 getTag x = x `seq` dataToTag# x
 788 \end{code}
 789
 790 %*********************************************************
 791 %*                                                      *
 792 \subsection{Numeric primops}
 793 %*                                                      *
 794 %*********************************************************
 795
 796 \begin{code}
 797 divInt# :: Int# -> Int# -> Int#
 798 x# `divInt#` y#
 799         -- Be careful NOT to overflow if we do any additional arithmetic
 800         -- on the arguments...  the following  previous version of this
 801         -- code has problems with overflow:
 802 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 803 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 804     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 805     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 806     | otherwise                = x# `quotInt#` y#
 807
 808 modInt# :: Int# -> Int# -> Int#
 809 x# `modInt#` y#
 810     | (x# ># 0#) && (y# <# 0#) ||
 811       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 812     | otherwise                   = r#
 813     where
 814     r# = x# `remInt#` y#
 815 \end{code}
 816
 817 Definitions of the boxed PrimOps; these will be
 818 used in the case of partial applications, etc.
 819
 820 \begin{code}
 821 {-# INLINE eqInt #-}
 822 {-# INLINE neInt #-}
 823 {-# INLINE gtInt #-}
 824 {-# INLINE geInt #-}
 825 {-# INLINE ltInt #-}
 826 {-# INLINE leInt #-}
 827 {-# INLINE plusInt #-}
 828 {-# INLINE minusInt #-}
 829 {-# INLINE timesInt #-}
 830 {-# INLINE quotInt #-}
 831 {-# INLINE remInt #-}
 832 {-# INLINE negateInt #-}
 833
 834 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 835 (I# x) `plusInt`  (I# y) = I# (x +# y)
 836 (I# x) `minusInt` (I# y) = I# (x -# y)
 837 (I# x) `timesInt` (I# y) = I# (x *# y)
 838 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 839 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 840 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 841 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 842
 843 {-# RULES
 844 "x# +# 0#" forall x#. x# +# 0# = x#
 845 "0# +# x#" forall x#. 0# +# x# = x#
 846 "x# -# 0#" forall x#. x# -# 0# = x#
 847 "x# -# x#" forall x#. x# -# x# = 0#
 848 "x# *# 0#" forall x#. x# *# 0# = 0#
 849 "0# *# x#" forall x#. 0# *# x# = 0#
 850 "x# *# 1#" forall x#. x# *# 1# = x#
 851 "1# *# x#" forall x#. 1# *# x# = x#
 852   #-}
 853
 854 gcdInt (I# a) (I# b) = g a b
 855    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 856          g 0# _  = I# absB
 857          g _  0# = I# absA
 858          g _  _  = I# (gcdInt# absA absB)
 859
 860          absInt x = if x <# 0# then negateInt# x else x
 861
 862          absA     = absInt a
 863          absB     = absInt b
 864
 865 negateInt :: Int -> Int
 866 negateInt (I# x) = I# (negateInt# x)
 867
 868 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 869 (I# x) `gtInt` (I# y) = x >#  y
 870 (I# x) `geInt` (I# y) = x >=# y
 871 (I# x) `eqInt` (I# y) = x ==# y
 872 (I# x) `neInt` (I# y) = x /=# y
 873 (I# x) `ltInt` (I# y) = x <#  y
 874 (I# x) `leInt` (I# y) = x <=# y
 875
 876 {-# RULES
 877 "x# ># x#"  forall x#. x# >#  x# = False
 878 "x# >=# x#" forall x#. x# >=# x# = True
 879 "x# ==# x#" forall x#. x# ==# x# = True
 880 "x# /=# x#" forall x#. x# /=# x# = False
 881 "x# <# x#"  forall x#. x# <#  x# = False
 882 "x# <=# x#" forall x#. x# <=# x# = True
 883   #-}
 884
 885 {-# RULES
 886 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 887 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 888 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 889 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 890 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 891 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 892 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 893 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 894 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 895   #-}
 896
 897 {-# RULES
 898 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 899 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 900 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 901 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 902 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 903 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 904 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 905 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 906 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 907   #-}
 908
 909 -- Wrappers for the shift operations.  The uncheckedShift# family are
 910 -- undefined when the amount being shifted by is greater than the size
 911 -- in bits of Int#, so these wrappers perform a check and return
 912 -- either zero or -1 appropriately.
 913 --
 914 -- Note that these wrappers still produce undefined results when the
 915 -- second argument (the shift amount) is negative.
 916
 917 -- | Shift the argument left by the specified number of bits
 918 -- (which must be non-negative).
 919 shiftL# :: Word# -> Int# -> Word#
 920 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 921                 | otherwise                = a `uncheckedShiftL#` b
 922
 923 -- | Shift the argument right by the specified number of bits
 924 -- (which must be non-negative).
 925 shiftRL# :: Word# -> Int# -> Word#
 926 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 927                 | otherwise                = a `uncheckedShiftRL#` b
 928
 929 -- | Shift the argument left by the specified number of bits
 930 -- (which must be non-negative).
 931 iShiftL# :: Int# -> Int# -> Int#
 932 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 933                 | otherwise                = a `uncheckedIShiftL#` b
 934
 935 -- | Shift the argument right (signed) by the specified number of bits
 936 -- (which must be non-negative).
 937 iShiftRA# :: Int# -> Int# -> Int#
 938 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 939                 | otherwise                = a `uncheckedIShiftRA#` b
 940
 941 -- | Shift the argument right (unsigned) by the specified number of bits
 942 -- (which must be non-negative).
 943 iShiftRL# :: Int# -> Int# -> Int#
 944 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 945                 | otherwise                = a `uncheckedIShiftRL#` b
 946
 947 #if WORD_SIZE_IN_BITS == 32
 948 {-# RULES
 949 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 950 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 951    #-}
 952 #endif
 953
 954 {-# RULES
 955 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 956 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 957   #-}
 958 \end{code}
 959
 960
 961 %********************************************************
 962 %*                                                      *
 963 \subsection{Unpacking C strings}
 964 %*                                                      *
 965 %********************************************************
 966
 967 This code is needed for virtually all programs, since it's used for
 968 unpacking the strings of error messages.
 969
 970 \begin{code}
 971 unpackCString# :: Addr# -> [Char]
 972 {-# NOINLINE [1] unpackCString# #-}
 973 unpackCString# addr
 974   = unpack 0#
 975   where
 976     unpack nh
 977       | ch `eqChar#` '\0'# = []
 978       | otherwise          = C# ch : unpack (nh +# 1#)
 979       where
 980         ch = indexCharOffAddr# addr nh
 981
 982 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 983 unpackAppendCString# addr rest
 984   = unpack 0#
 985   where
 986     unpack nh
 987       | ch `eqChar#` '\0'# = rest
 988       | otherwise          = C# ch : unpack (nh +# 1#)
 989       where
 990         ch = indexCharOffAddr# addr nh
 991
 992 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 993 {-# NOINLINE [0] unpackFoldrCString# #-}
 994 -- Don't inline till right at the end;
 995 -- usually the unpack-list rule turns it into unpackCStringList
 996 unpackFoldrCString# addr f z
 997   = unpack 0#
 998   where
 999     unpack nh
1000       | ch `eqChar#` '\0'# = z
1001       | otherwise          = C# ch `f` unpack (nh +# 1#)
1002       where
1003         ch = indexCharOffAddr# addr nh
1004
1005 unpackCStringUtf8# :: Addr# -> [Char]
1006 unpackCStringUtf8# addr
1007   = unpack 0#
1008   where
1009     unpack nh
1010       | ch `eqChar#` '\0'#   = []
1011       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1012       | ch `leChar#` '\xDF'# =
1013           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1014                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1015           unpack (nh +# 2#)
1016       | ch `leChar#` '\xEF'# =
1017           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1018                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1019                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1020           unpack (nh +# 3#)
1021       | otherwise            =
1022           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1023                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1024                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1025                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1026           unpack (nh +# 4#)
1027       where
1028         ch = indexCharOffAddr# addr nh
1029
1030 unpackNBytes# :: Addr# -> Int# -> [Char]
1031 unpackNBytes# _addr 0#   = []
1032 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1033     where
1034      unpack acc i#
1035       | i# <# 0#  = acc
1036       | otherwise =
1037          case indexCharOffAddr# addr i# of
1038             ch -> unpack (C# ch : acc) (i# -# 1#)
1039
1040 {-# RULES
1041 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1042 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1043 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1044
1045 -- There's a built-in rule (in PrelRules.lhs) for
1046 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1047
1048   #-}
1049 \end{code}
1050
1051 #ifdef __HADDOCK__
1052 \begin{code}
1053 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1054 -- indexing a state embedded in the 'Prelude.IO' monad by
1055 -- 'Control.Monad.ST.stToIO'.
1056 data RealWorld
1057 \end{code}
1058 #endif