GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_GHC -fno-warn-orphans #-}
  67 {-# OPTIONS_HADDOCK hide #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Bool,
  89         module GHC.Classes,
  90         module GHC.Generics,
  91         module GHC.Ordering,
  92         module GHC.Types,
  93         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  94         module GHC.Err          -- of people having to import it explicitly
  95   )
  96         where
  97
  98 import GHC.Types
  99 import GHC.Bool
 100 import GHC.Classes
 101 import GHC.Generics
 102 import GHC.Ordering
 103 import GHC.Prim
 104 import {-# SOURCE #-} GHC.Show
 105 import {-# SOURCE #-} GHC.Err
 106 import {-# SOURCE #-} GHC.IO (failIO)
 107
 108 -- These two are not strictly speaking required by this module, but they are
 109 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 110 -- as imports here helps to get the dependencies right in the new build system.
 111 import GHC.Tuple ()
 112 import GHC.Unit ()
 113
 114 infixr 9  .
 115 infixr 5  ++
 116 infixl 4  <$
 117 infixl 1  >>, >>=
 118 infixr 0  $
 119
 120 default ()              -- Double isn't available yet
 121 \end{code}
 122
 123
 124 %*********************************************************
 125 %*                                                      *
 126 \subsection{DEBUGGING STUFF}
 127 %*  (for use when compiling GHC.Base itself doesn't work)
 128 %*                                                      *
 129 %*********************************************************
 130
 131 \begin{code}
 132 {-
 133 data  Bool  =  False | True
 134 data Ordering = LT | EQ | GT
 135 data Char = C# Char#
 136 type  String = [Char]
 137 data Int = I# Int#
 138 data  ()  =  ()
 139 data [] a = MkNil
 140
 141 not True = False
 142 (&&) True True = True
 143 otherwise = True
 144
 145 build = error "urk"
 146 foldr = error "urk"
 147
 148 unpackCString# :: Addr# -> [Char]
 149 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 150 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 151 unpackCStringUtf8# :: Addr# -> [Char]
 152 unpackCString# a = error "urk"
 153 unpackFoldrCString# a = error "urk"
 154 unpackAppendCString# a = error "urk"
 155 unpackCStringUtf8# a = error "urk"
 156 -}
 157 \end{code}
 158
 159
 160 %*********************************************************
 161 %*                                                      *
 162 \subsection{Monadic classes @Functor@, @Monad@ }
 163 %*                                                      *
 164 %*********************************************************
 165
 166 \begin{code}
 167 {- | The 'Functor' class is used for types that can be mapped over.
 168 Instances of 'Functor' should satisfy the following laws:
 169
 170 > fmap id  ==  id
 171 > fmap (f . g)  ==  fmap f . fmap g
 172
 173 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 174 defined in the "Prelude" satisfy these laws.
 175 -}
 176
 177 class  Functor f  where
 178     fmap        :: (a -> b) -> f a -> f b
 179
 180     -- | Replace all locations in the input with the same value.
 181     -- The default definition is @'fmap' . 'const'@, but this may be
 182     -- overridden with a more efficient version.
 183     (<$)        :: a -> f b -> f a
 184     (<$)        =  fmap . const
 185
 186 {- | The 'Monad' class defines the basic operations over a /monad/,
 187 a concept from a branch of mathematics known as /category theory/.
 188 From the perspective of a Haskell programmer, however, it is best to
 189 think of a monad as an /abstract datatype/ of actions.
 190 Haskell's @do@ expressions provide a convenient syntax for writing
 191 monadic expressions.
 192
 193 Minimal complete definition: '>>=' and 'return'.
 194
 195 Instances of 'Monad' should satisfy the following laws:
 196
 197 > return a >>= k  ==  k a
 198 > m >>= return  ==  m
 199 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 200
 201 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 202
 203 > fmap f xs  ==  xs >>= return . f
 204
 205 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 206 defined in the "Prelude" satisfy these laws.
 207 -}
 208
 209 class  Monad m  where
 210     -- | Sequentially compose two actions, passing any value produced
 211     -- by the first as an argument to the second.
 212     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 213     -- | Sequentially compose two actions, discarding any value produced
 214     -- by the first, like sequencing operators (such as the semicolon)
 215     -- in imperative languages.
 216     (>>)        :: forall a b. m a -> m b -> m b
 217         -- Explicit for-alls so that we know what order to
 218         -- give type arguments when desugaring
 219
 220     -- | Inject a value into the monadic type.
 221     return      :: a -> m a
 222     -- | Fail with a message.  This operation is not part of the
 223     -- mathematical definition of a monad, but is invoked on pattern-match
 224     -- failure in a @do@ expression.
 225     fail        :: String -> m a
 226
 227     m >> k      = m >>= \_ -> k
 228     fail s      = error s
 229 \end{code}
 230
 231
 232 %*********************************************************
 233 %*                                                      *
 234 \subsection{The list type}
 235 %*                                                      *
 236 %*********************************************************
 237
 238 \begin{code}
 239 -- do explicitly: deriving (Eq, Ord)
 240 -- to avoid weird names like con2tag_[]#
 241
 242 instance (Eq a) => Eq [a] where
 243     {-# SPECIALISE instance Eq [Char] #-}
 244     []     == []     = True
 245     (x:xs) == (y:ys) = x == y && xs == ys
 246     _xs    == _ys    = False
 247
 248 instance (Ord a) => Ord [a] where
 249     {-# SPECIALISE instance Ord [Char] #-}
 250     compare []     []     = EQ
 251     compare []     (_:_)  = LT
 252     compare (_:_)  []     = GT
 253     compare (x:xs) (y:ys) = case compare x y of
 254                                 EQ    -> compare xs ys
 255                                 other -> other
 256
 257 instance Functor [] where
 258     fmap = map
 259
 260 instance  Monad []  where
 261     m >>= k             = foldr ((++) . k) [] m
 262     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 263     return x            = [x]
 264     fail _              = []
 265 \end{code}
 266
 267 A few list functions that appear here because they are used here.
 268 The rest of the prelude list functions are in GHC.List.
 269
 270 ----------------------------------------------
 271 --      foldr/build/augment
 272 ----------------------------------------------
 273
 274 \begin{code}
 275 -- | 'foldr', applied to a binary operator, a starting value (typically
 276 -- the right-identity of the operator), and a list, reduces the list
 277 -- using the binary operator, from right to left:
 278 --
 279 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 280
 281 foldr            :: (a -> b -> b) -> b -> [a] -> b
 282 -- foldr _ z []     =  z
 283 -- foldr f z (x:xs) =  f x (foldr f z xs)
 284 {-# INLINE [0] foldr #-}
 285 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 286 foldr k z xs = go xs
 287              where
 288                go []     = z
 289                go (y:ys) = y `k` go ys
 290
 291 -- | A list producer that can be fused with 'foldr'.
 292 -- This function is merely
 293 --
 294 -- >    build g = g (:) []
 295 --
 296 -- but GHC's simplifier will transform an expression of the form
 297 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 298 -- which avoids producing an intermediate list.
 299
 300 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 301 {-# INLINE [1] build #-}
 302         -- The INLINE is important, even though build is tiny,
 303         -- because it prevents [] getting inlined in the version that
 304         -- appears in the interface file.  If [] *is* inlined, it
 305         -- won't match with [] appearing in rules in an importing module.
 306         --
 307         -- The "1" says to inline in phase 1
 308
 309 build g = g (:) []
 310
 311 -- | A list producer that can be fused with 'foldr'.
 312 -- This function is merely
 313 --
 314 -- >    augment g xs = g (:) xs
 315 --
 316 -- but GHC's simplifier will transform an expression of the form
 317 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 318 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 319
 320 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 321 {-# INLINE [1] augment #-}
 322 augment g xs = g (:) xs
 323
 324 {-# RULES
 325 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 326                 foldr k z (build g) = g k z
 327
 328 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 329                 foldr k z (augment g xs) = g k (foldr k z xs)
 330
 331 "foldr/id"                        foldr (:) [] = \x  -> x
 332 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 333         -- Only activate this from phase 1, because that's
 334         -- when we disable the rule that expands (++) into foldr
 335
 336 -- The foldr/cons rule looks nice, but it can give disastrously
 337 -- bloated code when commpiling
 338 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 339 -- i.e. when there are very very long literal lists
 340 -- So I've disabled it for now. We could have special cases
 341 -- for short lists, I suppose.
 342 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 343
 344 "foldr/single"  forall k z x. foldr k z [x] = k x z
 345 "foldr/nil"     forall k z.   foldr k z []  = z
 346
 347 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 348                        (h::forall b. (a->b->b) -> b -> b) .
 349                        augment g (build h) = build (\c n -> g c (h c n))
 350 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 351                         augment g [] = build g
 352  #-}
 353
 354 -- This rule is true, but not (I think) useful:
 355 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 356 \end{code}
 357
 358
 359 ----------------------------------------------
 360 --              map
 361 ----------------------------------------------
 362
 363 \begin{code}
 364 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 365 -- of @xs@, i.e.,
 366 --
 367 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 368 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 369
 370 map :: (a -> b) -> [a] -> [b]
 371 map _ []     = []
 372 map f (x:xs) = f x : map f xs
 373
 374 -- Note eta expanded
 375 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 376 {-# INLINE [0] mapFB #-}
 377 mapFB c f x ys = c (f x) ys
 378
 379 -- The rules for map work like this.
 380 --
 381 -- Up to (but not including) phase 1, we use the "map" rule to
 382 -- rewrite all saturated applications of map with its build/fold
 383 -- form, hoping for fusion to happen.
 384 -- In phase 1 and 0, we switch off that rule, inline build, and
 385 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 386 -- thing back into plain map.
 387 --
 388 -- It's important that these two rules aren't both active at once
 389 -- (along with build's unfolding) else we'd get an infinite loop
 390 -- in the rules.  Hence the activation control below.
 391 --
 392 -- The "mapFB" rule optimises compositions of map.
 393 --
 394 -- This same pattern is followed by many other functions:
 395 -- e.g. append, filter, iterate, repeat, etc.
 396
 397 {-# RULES
 398 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 399 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 400 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 401   #-}
 402 \end{code}
 403
 404
 405 ----------------------------------------------
 406 --              append
 407 ----------------------------------------------
 408 \begin{code}
 409 -- | Append two lists, i.e.,
 410 --
 411 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 412 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 413 --
 414 -- If the first list is not finite, the result is the first list.
 415
 416 (++) :: [a] -> [a] -> [a]
 417 (++) []     ys = ys
 418 (++) (x:xs) ys = x : xs ++ ys
 419
 420 {-# RULES
 421 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 422   #-}
 423
 424 \end{code}
 425
 426
 427 %*********************************************************
 428 %*                                                      *
 429 \subsection{Type @Bool@}
 430 %*                                                      *
 431 %*********************************************************
 432
 433 \begin{code}
 434 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 435 -- first so that the corresponding 'Prelude.Enum' instance will give
 436 -- 'Prelude.fromEnum' 'False' the value zero, and
 437 -- 'Prelude.fromEnum' 'True' the value 1.
 438 -- The actual definition is in the ghc-prim package.
 439
 440 -- XXX These don't work:
 441 -- deriving instance Eq Bool
 442 -- deriving instance Ord Bool
 443 -- <wired into compiler>:
 444 --     Illegal binding of built-in syntax: con2tag_Bool#
 445
 446 instance Eq Bool where
 447     True  == True  = True
 448     False == False = True
 449     _     == _     = False
 450
 451 instance Ord Bool where
 452     compare False True  = LT
 453     compare True  False = GT
 454     compare _     _     = EQ
 455
 456 -- Read is in GHC.Read, Show in GHC.Show
 457
 458 -- |'otherwise' is defined as the value 'True'.  It helps to make
 459 -- guards more readable.  eg.
 460 --
 461 -- >  f x | x < 0     = ...
 462 -- >      | otherwise = ...
 463 otherwise               :: Bool
 464 otherwise               =  True
 465 \end{code}
 466
 467 %*********************************************************
 468 %*                                                      *
 469 \subsection{Type @Ordering@}
 470 %*                                                      *
 471 %*********************************************************
 472
 473 \begin{code}
 474 -- | Represents an ordering relationship between two values: less
 475 -- than, equal to, or greater than.  An 'Ordering' is returned by
 476 -- 'compare'.
 477 -- XXX These don't work:
 478 -- deriving instance Eq Ordering
 479 -- deriving instance Ord Ordering
 480 -- Illegal binding of built-in syntax: con2tag_Ordering#
 481 instance Eq Ordering where
 482     EQ == EQ = True
 483     LT == LT = True
 484     GT == GT = True
 485     _  == _  = False
 486         -- Read in GHC.Read, Show in GHC.Show
 487
 488 instance Ord Ordering where
 489     LT <= _  = True
 490     _  <= LT = False
 491     EQ <= _  = True
 492     _  <= EQ = False
 493     GT <= GT = True
 494 \end{code}
 495
 496
 497 %*********************************************************
 498 %*                                                      *
 499 \subsection{Type @Char@ and @String@}
 500 %*                                                      *
 501 %*********************************************************
 502
 503 \begin{code}
 504 -- | A 'String' is a list of characters.  String constants in Haskell are values
 505 -- of type 'String'.
 506 --
 507 type String = [Char]
 508
 509 {-| The character type 'Char' is an enumeration whose values represent
 510 Unicode (or equivalently ISO\/IEC 10646) characters
 511 (see <http://www.unicode.org/> for details).
 512 This set extends the ISO 8859-1 (Latin-1) character set
 513 (the first 256 charachers), which is itself an extension of the ASCII
 514 character set (the first 128 characters).
 515 A character literal in Haskell has type 'Char'.
 516
 517 To convert a 'Char' to or from the corresponding 'Int' value defined
 518 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 519 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 520 -}
 521
 522 -- We don't use deriving for Eq and Ord, because for Ord the derived
 523 -- instance defines only compare, which takes two primops.  Then
 524 -- '>' uses compare, and therefore takes two primops instead of one.
 525
 526 instance Eq Char where
 527     (C# c1) == (C# c2) = c1 `eqChar#` c2
 528     (C# c1) /= (C# c2) = c1 `neChar#` c2
 529
 530 instance Ord Char where
 531     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 532     (C# c1) >= (C# c2) = c1 `geChar#` c2
 533     (C# c1) <= (C# c2) = c1 `leChar#` c2
 534     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 535
 536 {-# RULES
 537 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 538 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 539 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 540 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 541 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 542 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 543   #-}
 544
 545 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 546 chr :: Int -> Char
 547 chr i@(I# i#)
 548  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 549  | otherwise
 550     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 551
 552 unsafeChr :: Int -> Char
 553 unsafeChr (I# i#) = C# (chr# i#)
 554
 555 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 556 ord :: Char -> Int
 557 ord (C# c#) = I# (ord# c#)
 558 \end{code}
 559
 560 String equality is used when desugaring pattern-matches against strings.
 561
 562 \begin{code}
 563 eqString :: String -> String -> Bool
 564 eqString []       []       = True
 565 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 566 eqString _        _        = False
 567
 568 {-# RULES "eqString" (==) = eqString #-}
 569 -- eqString also has a BuiltInRule in PrelRules.lhs:
 570 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 571 \end{code}
 572
 573
 574 %*********************************************************
 575 %*                                                      *
 576 \subsection{Type @Int@}
 577 %*                                                      *
 578 %*********************************************************
 579
 580 \begin{code}
 581 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 582 zeroInt = I# 0#
 583 oneInt  = I# 1#
 584 twoInt  = I# 2#
 585
 586 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 587 #if WORD_SIZE_IN_BITS == 31
 588 minInt  = I# (-0x40000000#)
 589 maxInt  = I# 0x3FFFFFFF#
 590 #elif WORD_SIZE_IN_BITS == 32
 591 minInt  = I# (-0x80000000#)
 592 maxInt  = I# 0x7FFFFFFF#
 593 #else
 594 minInt  = I# (-0x8000000000000000#)
 595 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 596 #endif
 597
 598 instance Eq Int where
 599     (==) = eqInt
 600     (/=) = neInt
 601
 602 instance Ord Int where
 603     compare = compareInt
 604     (<)     = ltInt
 605     (<=)    = leInt
 606     (>=)    = geInt
 607     (>)     = gtInt
 608
 609 compareInt :: Int -> Int -> Ordering
 610 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 611
 612 compareInt# :: Int# -> Int# -> Ordering
 613 compareInt# x# y#
 614     | x# <#  y# = LT
 615     | x# ==# y# = EQ
 616     | otherwise = GT
 617 \end{code}
 618
 619
 620 %*********************************************************
 621 %*                                                      *
 622 \subsection{The function type}
 623 %*                                                      *
 624 %*********************************************************
 625
 626 \begin{code}
 627 -- | Identity function.
 628 id                      :: a -> a
 629 id x                    =  x
 630
 631 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 632 -- magical strictness property: it is lazy in its first argument,
 633 -- even though its semantics is strict.
 634 lazy :: a -> a
 635 lazy x = x
 636 -- Implementation note: its strictness and unfolding are over-ridden
 637 -- by the definition in MkId.lhs; in both cases to nothing at all.
 638 -- That way, 'lazy' does not get inlined, and the strictness analyser
 639 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 640 -- Result: happiness
 641
 642
 643 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 644 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 645 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 646 -- hence eliminated) late in compilation, after the rule has had
 647 -- a god chance to fire.
 648 inline :: a -> a
 649 {-# NOINLINE[0] inline #-}
 650 inline x = x
 651
 652 -- Assertion function.  This simply ignores its boolean argument.
 653 -- The compiler may rewrite it to @('assertError' line)@.
 654
 655 -- | If the first argument evaluates to 'True', then the result is the
 656 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 657 -- containing a 'String' with the source file and line number of the
 658 -- call to 'assert'.
 659 --
 660 -- Assertions can normally be turned on or off with a compiler flag
 661 -- (for GHC, assertions are normally on unless optimisation is turned on
 662 -- with @-O@ or the @-fignore-asserts@
 663 -- option is given).  When assertions are turned off, the first
 664 -- argument to 'assert' is ignored, and the second argument is
 665 -- returned as the result.
 666
 667 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 668 --      but from Template Haskell onwards it's simply
 669 --      defined here in Base.lhs
 670 assert :: Bool -> a -> a
 671 assert _pred r = r
 672
 673 breakpoint :: a -> a
 674 breakpoint r = r
 675
 676 breakpointCond :: Bool -> a -> a
 677 breakpointCond _ r = r
 678
 679 data Opaque = forall a. O a
 680
 681 -- | Constant function.
 682 const                   :: a -> b -> a
 683 const x _               =  x
 684
 685 -- | Function composition.
 686 {-# INLINE (.) #-}
 687 (.)       :: (b -> c) -> (a -> b) -> a -> c
 688 (.) f g x = f (g x)
 689
 690 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 691 flip                    :: (a -> b -> c) -> b -> a -> c
 692 flip f x y              =  f y x
 693
 694 -- | Application operator.  This operator is redundant, since ordinary
 695 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 696 -- low, right-associative binding precedence, so it sometimes allows
 697 -- parentheses to be omitted; for example:
 698 --
 699 -- >     f $ g $ h x  =  f (g (h x))
 700 --
 701 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 702 -- or @'Data.List.zipWith' ('$') fs xs@.
 703 {-# INLINE ($) #-}
 704 ($)                     :: (a -> b) -> a -> b
 705 f $ x                   =  f x
 706
 707 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 708 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 709 until p f x | p x       =  x
 710             | otherwise =  until p f (f x)
 711
 712 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 713 -- used as an infix operator, and its typing forces its first argument
 714 -- (which is usually overloaded) to have the same type as the second.
 715 asTypeOf                :: a -> a -> a
 716 asTypeOf                =  const
 717 \end{code}
 718
 719 %*********************************************************
 720 %*                                                      *
 721 \subsection{@Functor@ and @Monad@ instances for @IO@}
 722 %*                                                      *
 723 %*********************************************************
 724
 725 \begin{code}
 726 instance  Functor IO where
 727    fmap f x = x >>= (return . f)
 728
 729 instance  Monad IO  where
 730     {-# INLINE return #-}
 731     {-# INLINE (>>)   #-}
 732     {-# INLINE (>>=)  #-}
 733     m >> k    = m >>= \ _ -> k
 734     return    = returnIO
 735     (>>=)     = bindIO
 736     fail s    = GHC.IO.failIO s
 737
 738 returnIO :: a -> IO a
 739 returnIO x = IO $ \ s -> (# s, x #)
 740
 741 bindIO :: IO a -> (a -> IO b) -> IO b
 742 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 743
 744 thenIO :: IO a -> IO b -> IO b
 745 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 746
 747 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 748 unIO (IO a) = a
 749 \end{code}
 750
 751 %*********************************************************
 752 %*                                                      *
 753 \subsection{@getTag@}
 754 %*                                                      *
 755 %*********************************************************
 756
 757 Returns the 'tag' of a constructor application; this function is used
 758 by the deriving code for Eq, Ord and Enum.
 759
 760 The primitive dataToTag# requires an evaluated constructor application
 761 as its argument, so we provide getTag as a wrapper that performs the
 762 evaluation before calling dataToTag#.  We could have dataToTag#
 763 evaluate its argument, but we prefer to do it this way because (a)
 764 dataToTag# can be an inline primop if it doesn't need to do any
 765 evaluation, and (b) we want to expose the evaluation to the
 766 simplifier, because it might be possible to eliminate the evaluation
 767 in the case when the argument is already known to be evaluated.
 768
 769 \begin{code}
 770 {-# INLINE getTag #-}
 771 getTag :: a -> Int#
 772 getTag x = x `seq` dataToTag# x
 773 \end{code}
 774
 775 %*********************************************************
 776 %*                                                      *
 777 \subsection{Numeric primops}
 778 %*                                                      *
 779 %*********************************************************
 780
 781 \begin{code}
 782 divInt# :: Int# -> Int# -> Int#
 783 x# `divInt#` y#
 784         -- Be careful NOT to overflow if we do any additional arithmetic
 785         -- on the arguments...  the following  previous version of this
 786         -- code has problems with overflow:
 787 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 788 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 789     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 790     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 791     | otherwise                = x# `quotInt#` y#
 792
 793 modInt# :: Int# -> Int# -> Int#
 794 x# `modInt#` y#
 795     | (x# ># 0#) && (y# <# 0#) ||
 796       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 797     | otherwise                   = r#
 798     where
 799     !r# = x# `remInt#` y#
 800 \end{code}
 801
 802 Definitions of the boxed PrimOps; these will be
 803 used in the case of partial applications, etc.
 804
 805 \begin{code}
 806 {-# INLINE eqInt #-}
 807 {-# INLINE neInt #-}
 808 {-# INLINE gtInt #-}
 809 {-# INLINE geInt #-}
 810 {-# INLINE ltInt #-}
 811 {-# INLINE leInt #-}
 812 {-# INLINE plusInt #-}
 813 {-# INLINE minusInt #-}
 814 {-# INLINE timesInt #-}
 815 {-# INLINE quotInt #-}
 816 {-# INLINE remInt #-}
 817 {-# INLINE negateInt #-}
 818
 819 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 820 (I# x) `plusInt`  (I# y) = I# (x +# y)
 821 (I# x) `minusInt` (I# y) = I# (x -# y)
 822 (I# x) `timesInt` (I# y) = I# (x *# y)
 823 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 824 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 825 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 826 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 827
 828 {-# RULES
 829 "x# +# 0#" forall x#. x# +# 0# = x#
 830 "0# +# x#" forall x#. 0# +# x# = x#
 831 "x# -# 0#" forall x#. x# -# 0# = x#
 832 "x# -# x#" forall x#. x# -# x# = 0#
 833 "x# *# 0#" forall x#. x# *# 0# = 0#
 834 "0# *# x#" forall x#. 0# *# x# = 0#
 835 "x# *# 1#" forall x#. x# *# 1# = x#
 836 "1# *# x#" forall x#. 1# *# x# = x#
 837   #-}
 838
 839 negateInt :: Int -> Int
 840 negateInt (I# x) = I# (negateInt# x)
 841
 842 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 843 (I# x) `gtInt` (I# y) = x >#  y
 844 (I# x) `geInt` (I# y) = x >=# y
 845 (I# x) `eqInt` (I# y) = x ==# y
 846 (I# x) `neInt` (I# y) = x /=# y
 847 (I# x) `ltInt` (I# y) = x <#  y
 848 (I# x) `leInt` (I# y) = x <=# y
 849
 850 {-# RULES
 851 "x# ># x#"  forall x#. x# >#  x# = False
 852 "x# >=# x#" forall x#. x# >=# x# = True
 853 "x# ==# x#" forall x#. x# ==# x# = True
 854 "x# /=# x#" forall x#. x# /=# x# = False
 855 "x# <# x#"  forall x#. x# <#  x# = False
 856 "x# <=# x#" forall x#. x# <=# x# = True
 857   #-}
 858
 859 {-# RULES
 860 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 861 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 862 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 863 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 864 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 865 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 866 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 867 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 868 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 869   #-}
 870
 871 {-# RULES
 872 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 873 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 874 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 875 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 876 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 877 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 878   #-}
 879
 880 {-
 881 We'd like to have more rules, but for example:
 882
 883 This gives wrong answer (0) for NaN - NaN (should be NaN):
 884     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 885
 886 This gives wrong answer (0) for 0 * NaN (should be NaN):
 887     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 888
 889 This gives wrong answer (0) for NaN * 0 (should be NaN):
 890     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 891
 892 These are tested by num014.
 893 -}
 894
 895 -- Wrappers for the shift operations.  The uncheckedShift# family are
 896 -- undefined when the amount being shifted by is greater than the size
 897 -- in bits of Int#, so these wrappers perform a check and return
 898 -- either zero or -1 appropriately.
 899 --
 900 -- Note that these wrappers still produce undefined results when the
 901 -- second argument (the shift amount) is negative.
 902
 903 -- | Shift the argument left by the specified number of bits
 904 -- (which must be non-negative).
 905 shiftL# :: Word# -> Int# -> Word#
 906 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 907                 | otherwise                = a `uncheckedShiftL#` b
 908
 909 -- | Shift the argument right by the specified number of bits
 910 -- (which must be non-negative).
 911 shiftRL# :: Word# -> Int# -> Word#
 912 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 913                 | otherwise                = a `uncheckedShiftRL#` b
 914
 915 -- | Shift the argument left by the specified number of bits
 916 -- (which must be non-negative).
 917 iShiftL# :: Int# -> Int# -> Int#
 918 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 919                 | otherwise                = a `uncheckedIShiftL#` b
 920
 921 -- | Shift the argument right (signed) by the specified number of bits
 922 -- (which must be non-negative).
 923 iShiftRA# :: Int# -> Int# -> Int#
 924 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 925                 | otherwise                = a `uncheckedIShiftRA#` b
 926
 927 -- | Shift the argument right (unsigned) by the specified number of bits
 928 -- (which must be non-negative).
 929 iShiftRL# :: Int# -> Int# -> Int#
 930 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 931                 | otherwise                = a `uncheckedIShiftRL#` b
 932
 933 #if WORD_SIZE_IN_BITS == 32
 934 {-# RULES
 935 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 936 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 937    #-}
 938 #endif
 939
 940 {-# RULES
 941 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 942 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 943   #-}
 944 \end{code}
 945
 946
 947 %********************************************************
 948 %*                                                      *
 949 \subsection{Unpacking C strings}
 950 %*                                                      *
 951 %********************************************************
 952
 953 This code is needed for virtually all programs, since it's used for
 954 unpacking the strings of error messages.
 955
 956 \begin{code}
 957 unpackCString# :: Addr# -> [Char]
 958 {-# NOINLINE unpackCString# #-}
 959     -- There's really no point in inlining this, ever, cos
 960     -- the loop doesn't specialise in an interesting
 961     -- But it's pretty small, so there's a danger that
 962     -- it'll be inlined at every literal, which is a waste
 963 unpackCString# addr
 964   = unpack 0#
 965   where
 966     unpack nh
 967       | ch `eqChar#` '\0'# = []
 968       | otherwise          = C# ch : unpack (nh +# 1#)
 969       where
 970         !ch = indexCharOffAddr# addr nh
 971
 972 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 973 {-# NOINLINE unpackAppendCString# #-}
 974      -- See the NOINLINE note on unpackCString#
 975 unpackAppendCString# addr rest
 976   = unpack 0#
 977   where
 978     unpack nh
 979       | ch `eqChar#` '\0'# = rest
 980       | otherwise          = C# ch : unpack (nh +# 1#)
 981       where
 982         !ch = indexCharOffAddr# addr nh
 983
 984 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 985 {-# NOINLINE [0] unpackFoldrCString# #-}
 986 -- Unlike unpackCString#, there *is* some point in inlining unpackFoldrCString#,
 987 -- because we get better code for the function call.
 988 -- However, don't inline till right at the end;
 989 -- usually the unpack-list rule turns it into unpackCStringList
 990 -- It also has a BuiltInRule in PrelRules.lhs:
 991 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 992 --        =  unpackFoldrCString# "foobaz" c n
 993 unpackFoldrCString# addr f z
 994   = unpack 0#
 995   where
 996     unpack nh
 997       | ch `eqChar#` '\0'# = z
 998       | otherwise          = C# ch `f` unpack (nh +# 1#)
 999       where
1000         !ch = indexCharOffAddr# addr nh
1001
1002 unpackCStringUtf8# :: Addr# -> [Char]
1003 unpackCStringUtf8# addr
1004   = unpack 0#
1005   where
1006     unpack nh
1007       | ch `eqChar#` '\0'#   = []
1008       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1009       | ch `leChar#` '\xDF'# =
1010           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1011                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1012           unpack (nh +# 2#)
1013       | ch `leChar#` '\xEF'# =
1014           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1015                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1016                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1017           unpack (nh +# 3#)
1018       | otherwise            =
1019           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1020                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1021                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1022                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1023           unpack (nh +# 4#)
1024       where
1025         !ch = indexCharOffAddr# addr nh
1026
1027 unpackNBytes# :: Addr# -> Int# -> [Char]
1028 unpackNBytes# _addr 0#   = []
1029 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1030     where
1031      unpack acc i#
1032       | i# <# 0#  = acc
1033       | otherwise =
1034          case indexCharOffAddr# addr i# of
1035             ch -> unpack (C# ch : acc) (i# -# 1#)
1036
1037 {-# RULES
1038 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
1039 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1040 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1041
1042 -- There's a built-in rule (in PrelRules.lhs) for
1043 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1044
1045   #-}
1046 \end{code}
1047
1048 #ifdef __HADDOCK__
1049 \begin{code}
1050 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1051 -- indexing a state embedded in the 'Prelude.IO' monad by
1052 -- 'Control.Monad.ST.stToIO'.
1053 data RealWorld
1054 \end{code}
1055 #endif