GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -fno-implicit-prelude #-}
  66 {-# OPTIONS_HADDOCK hide #-}
  67 -----------------------------------------------------------------------------
  68 -- |
  69 -- Module      :  GHC.Base
  70 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  71 -- License     :  see libraries/base/LICENSE
  72 --
  73 -- Maintainer  :  cvs-ghc@haskell.org
  74 -- Stability   :  internal
  75 -- Portability :  non-portable (GHC extensions)
  76 --
  77 -- Basic data types and classes.
  78 --
  79 -----------------------------------------------------------------------------
  80
  81 #include "MachDeps.h"
  82
  83 -- #hide
  84 module GHC.Base
  85         (
  86         module GHC.Base,
  87         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  88         module GHC.Err          -- of people having to import it explicitly
  89   )
  90         where
  91
  92 import GHC.Prim
  93 import {-# SOURCE #-} GHC.Err
  94
  95 infixr 9  .
  96 infixr 5  ++, :
  97 infix  4  ==, /=, <, <=, >=, >
  98 infixr 3  &&
  99 infixr 2  ||
 100 infixl 1  >>, >>=
 101 infixr 0  $
 102
 103 default ()              -- Double isn't available yet
 104 \end{code}
 105
 106
 107 %*********************************************************
 108 %*                                                      *
 109 \subsection{DEBUGGING STUFF}
 110 %*  (for use when compiling GHC.Base itself doesn't work)
 111 %*                                                      *
 112 %*********************************************************
 113
 114 \begin{code}
 115 {-
 116 data  Bool  =  False | True
 117 data Ordering = LT | EQ | GT
 118 data Char = C# Char#
 119 type  String = [Char]
 120 data Int = I# Int#
 121 data  ()  =  ()
 122 data [] a = MkNil
 123
 124 not True = False
 125 (&&) True True = True
 126 otherwise = True
 127
 128 build = error "urk"
 129 foldr = error "urk"
 130
 131 unpackCString# :: Addr# -> [Char]
 132 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 133 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 134 unpackCStringUtf8# :: Addr# -> [Char]
 135 unpackCString# a = error "urk"
 136 unpackFoldrCString# a = error "urk"
 137 unpackAppendCString# a = error "urk"
 138 unpackCStringUtf8# a = error "urk"
 139 -}
 140 \end{code}
 141
 142
 143 %*********************************************************
 144 %*                                                      *
 145 \subsection{Standard classes @Eq@, @Ord@}
 146 %*                                                      *
 147 %*********************************************************
 148
 149 \begin{code}
 150
 151 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 152 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 153 -- and 'Eq' may be derived for any datatype whose constituents are also
 154 -- instances of 'Eq'.
 155 --
 156 -- Minimal complete definition: either '==' or '/='.
 157 --
 158 class  Eq a  where
 159     (==), (/=)           :: a -> a -> Bool
 160
 161     x /= y               = not (x == y)
 162     x == y               = not (x /= y)
 163
 164 -- | The 'Ord' class is used for totally ordered datatypes.
 165 --
 166 -- Instances of 'Ord' can be derived for any user-defined
 167 -- datatype whose constituent types are in 'Ord'.  The declared order
 168 -- of the constructors in the data declaration determines the ordering
 169 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 170 -- comparison to determine the precise ordering of two objects.
 171 --
 172 -- Minimal complete definition: either 'compare' or '<='.
 173 -- Using 'compare' can be more efficient for complex types.
 174 --
 175 class  (Eq a) => Ord a  where
 176     compare              :: a -> a -> Ordering
 177     (<), (<=), (>), (>=) :: a -> a -> Bool
 178     max, min             :: a -> a -> a
 179
 180     compare x y
 181         | x == y    = EQ
 182         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 183                                 -- above claim about the minimal things that
 184                                 -- can be defined for an instance of Ord
 185         | otherwise = GT
 186
 187     x <  y = case compare x y of { LT -> True;  _other -> False }
 188     x <= y = case compare x y of { GT -> False; _other -> True }
 189     x >  y = case compare x y of { GT -> True;  _other -> False }
 190     x >= y = case compare x y of { LT -> False; _other -> True }
 191
 192         -- These two default methods use '<=' rather than 'compare'
 193         -- because the latter is often more expensive
 194     max x y = if x <= y then y else x
 195     min x y = if x <= y then x else y
 196 \end{code}
 197
 198 %*********************************************************
 199 %*                                                      *
 200 \subsection{Monadic classes @Functor@, @Monad@ }
 201 %*                                                      *
 202 %*********************************************************
 203
 204 \begin{code}
 205 {- | The 'Functor' class is used for types that can be mapped over.
 206 Instances of 'Functor' should satisfy the following laws:
 207
 208 > fmap id  ==  id
 209 > fmap (f . g)  ==  fmap f . fmap g
 210
 211 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 212 defined in the "Prelude" satisfy these laws.
 213 -}
 214
 215 class  Functor f  where
 216     fmap        :: (a -> b) -> f a -> f b
 217
 218 {- | The 'Monad' class defines the basic operations over a /monad/,
 219 a concept from a branch of mathematics known as /category theory/.
 220 From the perspective of a Haskell programmer, however, it is best to
 221 think of a monad as an /abstract datatype/ of actions.
 222 Haskell's @do@ expressions provide a convenient syntax for writing
 223 monadic expressions.
 224
 225 Minimal complete definition: '>>=' and 'return'.
 226
 227 Instances of 'Monad' should satisfy the following laws:
 228
 229 > return a >>= k  ==  k a
 230 > m >>= return  ==  m
 231 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 232
 233 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 234
 235 > fmap f xs  ==  xs >>= return . f
 236
 237 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 238 defined in the "Prelude" satisfy these laws.
 239 -}
 240
 241 class  Monad m  where
 242     -- | Sequentially compose two actions, passing any value produced
 243     -- by the first as an argument to the second.
 244     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 245     -- | Sequentially compose two actions, discarding any value produced
 246     -- by the first, like sequencing operators (such as the semicolon)
 247     -- in imperative languages.
 248     (>>)        :: forall a b. m a -> m b -> m b
 249         -- Explicit for-alls so that we know what order to
 250         -- give type arguments when desugaring
 251
 252     -- | Inject a value into the monadic type.
 253     return      :: a -> m a
 254     -- | Fail with a message.  This operation is not part of the
 255     -- mathematical definition of a monad, but is invoked on pattern-match
 256     -- failure in a @do@ expression.
 257     fail        :: String -> m a
 258
 259     m >> k      = m >>= \_ -> k
 260     fail s      = error s
 261 \end{code}
 262
 263
 264 %*********************************************************
 265 %*                                                      *
 266 \subsection{The list type}
 267 %*                                                      *
 268 %*********************************************************
 269
 270 \begin{code}
 271 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 272                           -- to avoid weird names like con2tag_[]#
 273
 274
 275 instance (Eq a) => Eq [a] where
 276     {-# SPECIALISE instance Eq [Char] #-}
 277     []     == []     = True
 278     (x:xs) == (y:ys) = x == y && xs == ys
 279     _xs    == _ys    = False
 280
 281 instance (Ord a) => Ord [a] where
 282     {-# SPECIALISE instance Ord [Char] #-}
 283     compare []     []     = EQ
 284     compare []     (_:_)  = LT
 285     compare (_:_)  []     = GT
 286     compare (x:xs) (y:ys) = case compare x y of
 287                                 EQ    -> compare xs ys
 288                                 other -> other
 289
 290 instance Functor [] where
 291     fmap = map
 292
 293 instance  Monad []  where
 294     m >>= k             = foldr ((++) . k) [] m
 295     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 296     return x            = [x]
 297     fail _              = []
 298 \end{code}
 299
 300 A few list functions that appear here because they are used here.
 301 The rest of the prelude list functions are in GHC.List.
 302
 303 ----------------------------------------------
 304 --      foldr/build/augment
 305 ----------------------------------------------
 306
 307 \begin{code}
 308 -- | 'foldr', applied to a binary operator, a starting value (typically
 309 -- the right-identity of the operator), and a list, reduces the list
 310 -- using the binary operator, from right to left:
 311 --
 312 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 313
 314 foldr            :: (a -> b -> b) -> b -> [a] -> b
 315 -- foldr _ z []     =  z
 316 -- foldr f z (x:xs) =  f x (foldr f z xs)
 317 {-# INLINE [0] foldr #-}
 318 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 319 foldr k z xs = go xs
 320              where
 321                go []     = z
 322                go (y:ys) = y `k` go ys
 323
 324 -- | A list producer that can be fused with 'foldr'.
 325 -- This function is merely
 326 --
 327 -- >    build g = g (:) []
 328 --
 329 -- but GHC's simplifier will transform an expression of the form
 330 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 331 -- which avoids producing an intermediate list.
 332
 333 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 334 {-# INLINE [1] build #-}
 335         -- The INLINE is important, even though build is tiny,
 336         -- because it prevents [] getting inlined in the version that
 337         -- appears in the interface file.  If [] *is* inlined, it
 338         -- won't match with [] appearing in rules in an importing module.
 339         --
 340         -- The "1" says to inline in phase 1
 341
 342 build g = g (:) []
 343
 344 -- | A list producer that can be fused with 'foldr'.
 345 -- This function is merely
 346 --
 347 -- >    augment g xs = g (:) xs
 348 --
 349 -- but GHC's simplifier will transform an expression of the form
 350 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 351 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 352
 353 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 354 {-# INLINE [1] augment #-}
 355 augment g xs = g (:) xs
 356
 357 {-# RULES
 358 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 359                 foldr k z (build g) = g k z
 360
 361 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 362                 foldr k z (augment g xs) = g k (foldr k z xs)
 363
 364 "foldr/id"                        foldr (:) [] = \x  -> x
 365 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 366         -- Only activate this from phase 1, because that's
 367         -- when we disable the rule that expands (++) into foldr
 368
 369 -- The foldr/cons rule looks nice, but it can give disastrously
 370 -- bloated code when commpiling
 371 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 372 -- i.e. when there are very very long literal lists
 373 -- So I've disabled it for now. We could have special cases
 374 -- for short lists, I suppose.
 375 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 376
 377 "foldr/single"  forall k z x. foldr k z [x] = k x z
 378 "foldr/nil"     forall k z.   foldr k z []  = z
 379
 380 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 381                        (h::forall b. (a->b->b) -> b -> b) .
 382                        augment g (build h) = build (\c n -> g c (h c n))
 383 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 384                         augment g [] = build g
 385  #-}
 386
 387 -- This rule is true, but not (I think) useful:
 388 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 389 \end{code}
 390
 391
 392 ----------------------------------------------
 393 --              map
 394 ----------------------------------------------
 395
 396 \begin{code}
 397 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 398 -- of @xs@, i.e.,
 399 --
 400 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 401 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 402
 403 map :: (a -> b) -> [a] -> [b]
 404 map _ []     = []
 405 map f (x:xs) = f x : map f xs
 406
 407 -- Note eta expanded
 408 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 409 {-# INLINE [0] mapFB #-}
 410 mapFB c f x ys = c (f x) ys
 411
 412 -- The rules for map work like this.
 413 --
 414 -- Up to (but not including) phase 1, we use the "map" rule to
 415 -- rewrite all saturated applications of map with its build/fold
 416 -- form, hoping for fusion to happen.
 417 -- In phase 1 and 0, we switch off that rule, inline build, and
 418 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 419 -- thing back into plain map.
 420 --
 421 -- It's important that these two rules aren't both active at once
 422 -- (along with build's unfolding) else we'd get an infinite loop
 423 -- in the rules.  Hence the activation control below.
 424 --
 425 -- The "mapFB" rule optimises compositions of map.
 426 --
 427 -- This same pattern is followed by many other functions:
 428 -- e.g. append, filter, iterate, repeat, etc.
 429
 430 {-# RULES
 431 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 432 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 433 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 434   #-}
 435 \end{code}
 436
 437
 438 ----------------------------------------------
 439 --              append
 440 ----------------------------------------------
 441 \begin{code}
 442 -- | Append two lists, i.e.,
 443 --
 444 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 445 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 446 --
 447 -- If the first list is not finite, the result is the first list.
 448
 449 (++) :: [a] -> [a] -> [a]
 450 (++) []     ys = ys
 451 (++) (x:xs) ys = x : xs ++ ys
 452
 453 {-# RULES
 454 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 455   #-}
 456
 457 \end{code}
 458
 459
 460 %*********************************************************
 461 %*                                                      *
 462 \subsection{Type @Bool@}
 463 %*                                                      *
 464 %*********************************************************
 465
 466 \begin{code}
 467 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 468 -- first so that the corresponding 'Prelude.Enum' instance will give
 469 -- 'Prelude.fromEnum' 'False' the value zero, and
 470 -- 'Prelude.fromEnum' 'True' the value 1.
 471 data  Bool  =  False | True  deriving (Eq, Ord)
 472         -- Read in GHC.Read, Show in GHC.Show
 473
 474 -- Boolean functions
 475
 476 -- | Boolean \"and\"
 477 (&&)                    :: Bool -> Bool -> Bool
 478 True  && x              =  x
 479 False && _              =  False
 480
 481 -- | Boolean \"or\"
 482 (||)                    :: Bool -> Bool -> Bool
 483 True  || _              =  True
 484 False || x              =  x
 485
 486 -- | Boolean \"not\"
 487 not                     :: Bool -> Bool
 488 not True                =  False
 489 not False               =  True
 490
 491 -- |'otherwise' is defined as the value 'True'.  It helps to make
 492 -- guards more readable.  eg.
 493 --
 494 -- >  f x | x < 0     = ...
 495 -- >      | otherwise = ...
 496 otherwise               :: Bool
 497 otherwise               =  True
 498 \end{code}
 499
 500 %*********************************************************
 501 %*                                                      *
 502 \subsection{The @()@ type}
 503 %*                                                      *
 504 %*********************************************************
 505
 506 The Unit type is here because virtually any program needs it (whereas
 507 some programs may get away without consulting GHC.Tup).  Furthermore,
 508 the renamer currently *always* asks for () to be in scope, so that
 509 ccalls can use () as their default type; so when compiling GHC.Base we
 510 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
 511 it here seems more direct.)
 512
 513 \begin{code}
 514 -- | The unit datatype @()@ has one non-undefined member, the nullary
 515 -- constructor @()@.
 516 data () = ()
 517
 518 instance Eq () where
 519     () == () = True
 520     () /= () = False
 521
 522 instance Ord () where
 523     () <= () = True
 524     () <  () = False
 525     () >= () = True
 526     () >  () = False
 527     max () () = ()
 528     min () () = ()
 529     compare () () = EQ
 530 \end{code}
 531
 532
 533 %*********************************************************
 534 %*                                                      *
 535 \subsection{Type @Ordering@}
 536 %*                                                      *
 537 %*********************************************************
 538
 539 \begin{code}
 540 -- | Represents an ordering relationship between two values: less
 541 -- than, equal to, or greater than.  An 'Ordering' is returned by
 542 -- 'compare'.
 543 data Ordering = LT | EQ | GT deriving (Eq, Ord)
 544         -- Read in GHC.Read, Show in GHC.Show
 545 \end{code}
 546
 547
 548 %*********************************************************
 549 %*                                                      *
 550 \subsection{Type @Char@ and @String@}
 551 %*                                                      *
 552 %*********************************************************
 553
 554 \begin{code}
 555 -- | A 'String' is a list of characters.  String constants in Haskell are values
 556 -- of type 'String'.
 557 --
 558 type String = [Char]
 559
 560 {-| The character type 'Char' is an enumeration whose values represent
 561 Unicode (or equivalently ISO\/IEC 10646) characters
 562 (see <http://www.unicode.org/> for details).
 563 This set extends the ISO 8859-1 (Latin-1) character set
 564 (the first 256 charachers), which is itself an extension of the ASCII
 565 character set (the first 128 characters).
 566 A character literal in Haskell has type 'Char'.
 567
 568 To convert a 'Char' to or from the corresponding 'Int' value defined
 569 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 570 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 571 -}
 572 data Char = C# Char#
 573
 574 -- We don't use deriving for Eq and Ord, because for Ord the derived
 575 -- instance defines only compare, which takes two primops.  Then
 576 -- '>' uses compare, and therefore takes two primops instead of one.
 577
 578 instance Eq Char where
 579     (C# c1) == (C# c2) = c1 `eqChar#` c2
 580     (C# c1) /= (C# c2) = c1 `neChar#` c2
 581
 582 instance Ord Char where
 583     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 584     (C# c1) >= (C# c2) = c1 `geChar#` c2
 585     (C# c1) <= (C# c2) = c1 `leChar#` c2
 586     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 587
 588 {-# RULES
 589 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 590 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 591 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 592 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 593 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 594 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 595   #-}
 596
 597 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 598 chr :: Int -> Char
 599 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 600             | otherwise                                  = error "Prelude.chr: bad argument"
 601
 602 unsafeChr :: Int -> Char
 603 unsafeChr (I# i#) = C# (chr# i#)
 604
 605 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 606 ord :: Char -> Int
 607 ord (C# c#) = I# (ord# c#)
 608 \end{code}
 609
 610 String equality is used when desugaring pattern-matches against strings.
 611
 612 \begin{code}
 613 eqString :: String -> String -> Bool
 614 eqString []       []       = True
 615 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 616 eqString cs1      cs2      = False
 617
 618 {-# RULES "eqString" (==) = eqString #-}
 619 -- eqString also has a BuiltInRule in PrelRules.lhs:
 620 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 621 \end{code}
 622
 623
 624 %*********************************************************
 625 %*                                                      *
 626 \subsection{Type @Int@}
 627 %*                                                      *
 628 %*********************************************************
 629
 630 \begin{code}
 631 data Int = I# Int#
 632 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
 633 -- The exact range for a given implementation can be determined by using
 634 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
 635
 636 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 637 zeroInt = I# 0#
 638 oneInt  = I# 1#
 639 twoInt  = I# 2#
 640
 641 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 642 #if WORD_SIZE_IN_BITS == 31
 643 minInt  = I# (-0x40000000#)
 644 maxInt  = I# 0x3FFFFFFF#
 645 #elif WORD_SIZE_IN_BITS == 32
 646 minInt  = I# (-0x80000000#)
 647 maxInt  = I# 0x7FFFFFFF#
 648 #else
 649 minInt  = I# (-0x8000000000000000#)
 650 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 651 #endif
 652
 653 instance Eq Int where
 654     (==) = eqInt
 655     (/=) = neInt
 656
 657 instance Ord Int where
 658     compare = compareInt
 659     (<)     = ltInt
 660     (<=)    = leInt
 661     (>=)    = geInt
 662     (>)     = gtInt
 663
 664 compareInt :: Int -> Int -> Ordering
 665 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 666
 667 compareInt# :: Int# -> Int# -> Ordering
 668 compareInt# x# y#
 669     | x# <#  y# = LT
 670     | x# ==# y# = EQ
 671     | otherwise = GT
 672 \end{code}
 673
 674
 675 %*********************************************************
 676 %*                                                      *
 677 \subsection{The function type}
 678 %*                                                      *
 679 %*********************************************************
 680
 681 \begin{code}
 682 -- | Identity function.
 683 id                      :: a -> a
 684 id x                    =  x
 685
 686 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 687 -- magical strictness property: it is lazy in its first argument,
 688 -- even though its semantics is strict.
 689 lazy :: a -> a
 690 lazy x = x
 691 -- Implementation note: its strictness and unfolding are over-ridden
 692 -- by the definition in MkId.lhs; in both cases to nothing at all.
 693 -- That way, 'lazy' does not get inlined, and the strictness analyser
 694 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 695 -- Result: happiness
 696
 697
 698 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 699 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 700 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 701 -- hence eliminated) late in compilation, after the rule has had
 702 -- a god chance to fire.
 703 inline :: a -> a
 704 {-# NOINLINE[0] inline #-}
 705 inline x = x
 706
 707 -- Assertion function.  This simply ignores its boolean argument.
 708 -- The compiler may rewrite it to @('assertError' line)@.
 709
 710 -- | If the first argument evaluates to 'True', then the result is the
 711 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 712 -- containing a 'String' with the source file and line number of the
 713 -- call to 'assert'.
 714 --
 715 -- Assertions can normally be turned on or off with a compiler flag
 716 -- (for GHC, assertions are normally on unless optimisation is turned on
 717 -- with @-O@ or the @-fignore-asserts@
 718 -- option is given).  When assertions are turned off, the first
 719 -- argument to 'assert' is ignored, and the second argument is
 720 -- returned as the result.
 721
 722 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 723 --      but from Template Haskell onwards it's simply
 724 --      defined here in Base.lhs
 725 assert :: Bool -> a -> a
 726 assert pred r = r
 727
 728 breakpoint :: a -> a
 729 breakpoint r = r
 730
 731 breakpointCond :: Bool -> a -> a
 732 breakpointCond _ r = r
 733
 734 data Opaque = forall a. O a
 735
 736 -- | Constant function.
 737 const                   :: a -> b -> a
 738 const x _               =  x
 739
 740 -- | Function composition.
 741 {-# INLINE (.) #-}
 742 (.)       :: (b -> c) -> (a -> b) -> a -> c
 743 (.) f g x = f (g x)
 744
 745 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 746 flip                    :: (a -> b -> c) -> b -> a -> c
 747 flip f x y              =  f y x
 748
 749 -- | Application operator.  This operator is redundant, since ordinary
 750 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 751 -- low, right-associative binding precedence, so it sometimes allows
 752 -- parentheses to be omitted; for example:
 753 --
 754 -- >     f $ g $ h x  =  f (g (h x))
 755 --
 756 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 757 -- or @'Data.List.zipWith' ('$') fs xs@.
 758 {-# INLINE ($) #-}
 759 ($)                     :: (a -> b) -> a -> b
 760 f $ x                   =  f x
 761
 762 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 763 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 764 until p f x | p x       =  x
 765             | otherwise =  until p f (f x)
 766
 767 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 768 -- used as an infix operator, and its typing forces its first argument
 769 -- (which is usually overloaded) to have the same type as the second.
 770 asTypeOf                :: a -> a -> a
 771 asTypeOf                =  const
 772 \end{code}
 773
 774 %*********************************************************
 775 %*                                                      *
 776 \subsection{Generics}
 777 %*                                                      *
 778 %*********************************************************
 779
 780 \begin{code}
 781 data Unit = Unit
 782 #ifndef __HADDOCK__
 783 data (:+:) a b = Inl a | Inr b
 784 data (:*:) a b = a :*: b
 785 #endif
 786 \end{code}
 787
 788 %*********************************************************
 789 %*                                                      *
 790 \subsection{@getTag@}
 791 %*                                                      *
 792 %*********************************************************
 793
 794 Returns the 'tag' of a constructor application; this function is used
 795 by the deriving code for Eq, Ord and Enum.
 796
 797 The primitive dataToTag# requires an evaluated constructor application
 798 as its argument, so we provide getTag as a wrapper that performs the
 799 evaluation before calling dataToTag#.  We could have dataToTag#
 800 evaluate its argument, but we prefer to do it this way because (a)
 801 dataToTag# can be an inline primop if it doesn't need to do any
 802 evaluation, and (b) we want to expose the evaluation to the
 803 simplifier, because it might be possible to eliminate the evaluation
 804 in the case when the argument is already known to be evaluated.
 805
 806 \begin{code}
 807 {-# INLINE getTag #-}
 808 getTag :: a -> Int#
 809 getTag x = x `seq` dataToTag# x
 810 \end{code}
 811
 812 %*********************************************************
 813 %*                                                      *
 814 \subsection{Numeric primops}
 815 %*                                                      *
 816 %*********************************************************
 817
 818 \begin{code}
 819 divInt# :: Int# -> Int# -> Int#
 820 x# `divInt#` y#
 821         -- Be careful NOT to overflow if we do any additional arithmetic
 822         -- on the arguments...  the following  previous version of this
 823         -- code has problems with overflow:
 824 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 825 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 826     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 827     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 828     | otherwise                = x# `quotInt#` y#
 829
 830 modInt# :: Int# -> Int# -> Int#
 831 x# `modInt#` y#
 832     | (x# ># 0#) && (y# <# 0#) ||
 833       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 834     | otherwise                   = r#
 835     where
 836     r# = x# `remInt#` y#
 837 \end{code}
 838
 839 Definitions of the boxed PrimOps; these will be
 840 used in the case of partial applications, etc.
 841
 842 \begin{code}
 843 {-# INLINE eqInt #-}
 844 {-# INLINE neInt #-}
 845 {-# INLINE gtInt #-}
 846 {-# INLINE geInt #-}
 847 {-# INLINE ltInt #-}
 848 {-# INLINE leInt #-}
 849 {-# INLINE plusInt #-}
 850 {-# INLINE minusInt #-}
 851 {-# INLINE timesInt #-}
 852 {-# INLINE quotInt #-}
 853 {-# INLINE remInt #-}
 854 {-# INLINE negateInt #-}
 855
 856 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 857 (I# x) `plusInt`  (I# y) = I# (x +# y)
 858 (I# x) `minusInt` (I# y) = I# (x -# y)
 859 (I# x) `timesInt` (I# y) = I# (x *# y)
 860 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 861 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 862 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 863 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 864
 865 {-# RULES
 866 "x# +# 0#" forall x#. x# +# 0# = x#
 867 "0# +# x#" forall x#. 0# +# x# = x#
 868 "x# -# 0#" forall x#. x# -# 0# = x#
 869 "x# -# x#" forall x#. x# -# x# = 0#
 870 "x# *# 0#" forall x#. x# *# 0# = 0#
 871 "0# *# x#" forall x#. 0# *# x# = 0#
 872 "x# *# 1#" forall x#. x# *# 1# = x#
 873 "1# *# x#" forall x#. 1# *# x# = x#
 874   #-}
 875
 876 gcdInt (I# a) (I# b) = g a b
 877    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 878          g 0# _  = I# absB
 879          g _  0# = I# absA
 880          g _  _  = I# (gcdInt# absA absB)
 881
 882          absInt x = if x <# 0# then negateInt# x else x
 883
 884          absA     = absInt a
 885          absB     = absInt b
 886
 887 negateInt :: Int -> Int
 888 negateInt (I# x) = I# (negateInt# x)
 889
 890 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 891 (I# x) `gtInt` (I# y) = x >#  y
 892 (I# x) `geInt` (I# y) = x >=# y
 893 (I# x) `eqInt` (I# y) = x ==# y
 894 (I# x) `neInt` (I# y) = x /=# y
 895 (I# x) `ltInt` (I# y) = x <#  y
 896 (I# x) `leInt` (I# y) = x <=# y
 897
 898 {-# RULES
 899 "x# ># x#"  forall x#. x# >#  x# = False
 900 "x# >=# x#" forall x#. x# >=# x# = True
 901 "x# ==# x#" forall x#. x# ==# x# = True
 902 "x# /=# x#" forall x#. x# /=# x# = False
 903 "x# <# x#"  forall x#. x# <#  x# = False
 904 "x# <=# x#" forall x#. x# <=# x# = True
 905   #-}
 906
 907 {-# RULES
 908 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 909 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 910 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 911 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 912 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 913 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 914 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 915 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 916 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 917   #-}
 918
 919 {-# RULES
 920 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 921 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 922 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 923 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 924 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 925 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 926   #-}
 927
 928 {-
 929 We'd like to have more rules, but for example:
 930
 931 This gives wrong answer (0) for NaN - NaN (should be NaN):
 932     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 933
 934 This gives wrong answer (0) for 0 * NaN (should be NaN):
 935     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 936
 937 This gives wrong answer (0) for NaN * 0 (should be NaN):
 938     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 939
 940 These are tested by num014.
 941 -}
 942
 943 -- Wrappers for the shift operations.  The uncheckedShift# family are
 944 -- undefined when the amount being shifted by is greater than the size
 945 -- in bits of Int#, so these wrappers perform a check and return
 946 -- either zero or -1 appropriately.
 947 --
 948 -- Note that these wrappers still produce undefined results when the
 949 -- second argument (the shift amount) is negative.
 950
 951 -- | Shift the argument left by the specified number of bits
 952 -- (which must be non-negative).
 953 shiftL# :: Word# -> Int# -> Word#
 954 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 955                 | otherwise                = a `uncheckedShiftL#` b
 956
 957 -- | Shift the argument right by the specified number of bits
 958 -- (which must be non-negative).
 959 shiftRL# :: Word# -> Int# -> Word#
 960 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 961                 | otherwise                = a `uncheckedShiftRL#` b
 962
 963 -- | Shift the argument left by the specified number of bits
 964 -- (which must be non-negative).
 965 iShiftL# :: Int# -> Int# -> Int#
 966 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 967                 | otherwise                = a `uncheckedIShiftL#` b
 968
 969 -- | Shift the argument right (signed) by the specified number of bits
 970 -- (which must be non-negative).
 971 iShiftRA# :: Int# -> Int# -> Int#
 972 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 973                 | otherwise                = a `uncheckedIShiftRA#` b
 974
 975 -- | Shift the argument right (unsigned) by the specified number of bits
 976 -- (which must be non-negative).
 977 iShiftRL# :: Int# -> Int# -> Int#
 978 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 979                 | otherwise                = a `uncheckedIShiftRL#` b
 980
 981 #if WORD_SIZE_IN_BITS == 32
 982 {-# RULES
 983 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 984 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 985    #-}
 986 #endif
 987
 988 {-# RULES
 989 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 990 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 991   #-}
 992 \end{code}
 993
 994
 995 %********************************************************
 996 %*                                                      *
 997 \subsection{Unpacking C strings}
 998 %*                                                      *
 999 %********************************************************
1000
1001 This code is needed for virtually all programs, since it's used for
1002 unpacking the strings of error messages.
1003
1004 \begin{code}
1005 unpackCString# :: Addr# -> [Char]
1006 {-# NOINLINE [1] unpackCString# #-}
1007 unpackCString# addr
1008   = unpack 0#
1009   where
1010     unpack nh
1011       | ch `eqChar#` '\0'# = []
1012       | otherwise          = C# ch : unpack (nh +# 1#)
1013       where
1014         ch = indexCharOffAddr# addr nh
1015
1016 unpackAppendCString# :: Addr# -> [Char] -> [Char]
1017 unpackAppendCString# addr rest
1018   = unpack 0#
1019   where
1020     unpack nh
1021       | ch `eqChar#` '\0'# = rest
1022       | otherwise          = C# ch : unpack (nh +# 1#)
1023       where
1024         ch = indexCharOffAddr# addr nh
1025
1026 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
1027 {-# NOINLINE [0] unpackFoldrCString# #-}
1028 -- Don't inline till right at the end;
1029 -- usually the unpack-list rule turns it into unpackCStringList
1030 -- It also has a BuiltInRule in PrelRules.lhs:
1031 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
1032 --        =  unpackFoldrCString# "foobaz" c n
1033 unpackFoldrCString# addr f z
1034   = unpack 0#
1035   where
1036     unpack nh
1037       | ch `eqChar#` '\0'# = z
1038       | otherwise          = C# ch `f` unpack (nh +# 1#)
1039       where
1040         ch = indexCharOffAddr# addr nh
1041
1042 unpackCStringUtf8# :: Addr# -> [Char]
1043 unpackCStringUtf8# addr
1044   = unpack 0#
1045   where
1046     unpack nh
1047       | ch `eqChar#` '\0'#   = []
1048       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1049       | ch `leChar#` '\xDF'# =
1050           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1051                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1052           unpack (nh +# 2#)
1053       | ch `leChar#` '\xEF'# =
1054           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1055                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1056                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1057           unpack (nh +# 3#)
1058       | otherwise            =
1059           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1060                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1061                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1062                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1063           unpack (nh +# 4#)
1064       where
1065         ch = indexCharOffAddr# addr nh
1066
1067 unpackNBytes# :: Addr# -> Int# -> [Char]
1068 unpackNBytes# _addr 0#   = []
1069 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1070     where
1071      unpack acc i#
1072       | i# <# 0#  = acc
1073       | otherwise =
1074          case indexCharOffAddr# addr i# of
1075             ch -> unpack (C# ch : acc) (i# -# 1#)
1076
1077 {-# RULES
1078 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1079 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1080 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1081
1082 -- There's a built-in rule (in PrelRules.lhs) for
1083 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1084
1085   #-}
1086 \end{code}
1087
1088 #ifdef __HADDOCK__
1089 \begin{code}
1090 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1091 -- indexing a state embedded in the 'Prelude.IO' monad by
1092 -- 'Control.Monad.ST.stToIO'.
1093 data RealWorld
1094 \end{code}
1095 #endif