GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_GHC -fno-warn-orphans #-}
  67 {-# OPTIONS_HADDOCK hide #-}
  68 -----------------------------------------------------------------------------
  69 -- |
  70 -- Module      :  GHC.Base
  71 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  72 -- License     :  see libraries/base/LICENSE
  73 --
  74 -- Maintainer  :  cvs-ghc@haskell.org
  75 -- Stability   :  internal
  76 -- Portability :  non-portable (GHC extensions)
  77 --
  78 -- Basic data types and classes.
  79 --
  80 -----------------------------------------------------------------------------
  81
  82 #include "MachDeps.h"
  83
  84 -- #hide
  85 module GHC.Base
  86         (
  87         module GHC.Base,
  88         module GHC.Bool,
  89         module GHC.Classes,
  90         module GHC.Generics,
  91         module GHC.Ordering,
  92         module GHC.Types,
  93         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  94         module GHC.Err          -- of people having to import it explicitly
  95   )
  96         where
  97
  98 import GHC.Types
  99 import GHC.Bool
 100 import GHC.Classes
 101 import GHC.Generics
 102 import GHC.Ordering
 103 import GHC.Prim
 104 import {-# SOURCE #-} GHC.Show
 105 import {-# SOURCE #-} GHC.Err
 106 import {-# SOURCE #-} GHC.IO (failIO)
 107
 108 -- These two are not strictly speaking required by this module, but they are
 109 -- implicit dependencies whenever () or tuples are mentioned, so adding them
 110 -- as imports here helps to get the dependencies right in the new build system.
 111 import GHC.Tuple ()
 112 import GHC.Unit ()
 113
 114 infixr 9  .
 115 infixr 5  ++
 116 infixl 4  <$
 117 infixl 1  >>, >>=
 118 infixr 0  $
 119
 120 default ()              -- Double isn't available yet
 121 \end{code}
 122
 123
 124 %*********************************************************
 125 %*                                                      *
 126 \subsection{DEBUGGING STUFF}
 127 %*  (for use when compiling GHC.Base itself doesn't work)
 128 %*                                                      *
 129 %*********************************************************
 130
 131 \begin{code}
 132 {-
 133 data  Bool  =  False | True
 134 data Ordering = LT | EQ | GT
 135 data Char = C# Char#
 136 type  String = [Char]
 137 data Int = I# Int#
 138 data  ()  =  ()
 139 data [] a = MkNil
 140
 141 not True = False
 142 (&&) True True = True
 143 otherwise = True
 144
 145 build = error "urk"
 146 foldr = error "urk"
 147
 148 unpackCString# :: Addr# -> [Char]
 149 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 150 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 151 unpackCStringUtf8# :: Addr# -> [Char]
 152 unpackCString# a = error "urk"
 153 unpackFoldrCString# a = error "urk"
 154 unpackAppendCString# a = error "urk"
 155 unpackCStringUtf8# a = error "urk"
 156 -}
 157 \end{code}
 158
 159
 160 %*********************************************************
 161 %*                                                      *
 162 \subsection{Monadic classes @Functor@, @Monad@ }
 163 %*                                                      *
 164 %*********************************************************
 165
 166 \begin{code}
 167 {- | The 'Functor' class is used for types that can be mapped over.
 168 Instances of 'Functor' should satisfy the following laws:
 169
 170 > fmap id  ==  id
 171 > fmap (f . g)  ==  fmap f . fmap g
 172
 173 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 174 defined in the "Prelude" satisfy these laws.
 175 -}
 176
 177 class  Functor f  where
 178     fmap        :: (a -> b) -> f a -> f b
 179
 180     -- | Replace all locations in the input with the same value.
 181     -- The default definition is @'fmap' . 'const'@, but this may be
 182     -- overridden with a more efficient version.
 183     (<$)        :: a -> f b -> f a
 184     (<$)        =  fmap . const
 185
 186 {- | The 'Monad' class defines the basic operations over a /monad/,
 187 a concept from a branch of mathematics known as /category theory/.
 188 From the perspective of a Haskell programmer, however, it is best to
 189 think of a monad as an /abstract datatype/ of actions.
 190 Haskell's @do@ expressions provide a convenient syntax for writing
 191 monadic expressions.
 192
 193 Minimal complete definition: '>>=' and 'return'.
 194
 195 Instances of 'Monad' should satisfy the following laws:
 196
 197 > return a >>= k  ==  k a
 198 > m >>= return  ==  m
 199 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 200
 201 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 202
 203 > fmap f xs  ==  xs >>= return . f
 204
 205 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 206 defined in the "Prelude" satisfy these laws.
 207 -}
 208
 209 class  Monad m  where
 210     -- | Sequentially compose two actions, passing any value produced
 211     -- by the first as an argument to the second.
 212     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 213     -- | Sequentially compose two actions, discarding any value produced
 214     -- by the first, like sequencing operators (such as the semicolon)
 215     -- in imperative languages.
 216     (>>)        :: forall a b. m a -> m b -> m b
 217         -- Explicit for-alls so that we know what order to
 218         -- give type arguments when desugaring
 219
 220     -- | Inject a value into the monadic type.
 221     return      :: a -> m a
 222     -- | Fail with a message.  This operation is not part of the
 223     -- mathematical definition of a monad, but is invoked on pattern-match
 224     -- failure in a @do@ expression.
 225     fail        :: String -> m a
 226
 227     {-# INLINE (>>) #-}
 228     m >> k      = m >>= \_ -> k
 229     fail s      = error s
 230 \end{code}
 231
 232
 233 %*********************************************************
 234 %*                                                      *
 235 \subsection{The list type}
 236 %*                                                      *
 237 %*********************************************************
 238
 239 \begin{code}
 240 -- do explicitly: deriving (Eq, Ord)
 241 -- to avoid weird names like con2tag_[]#
 242
 243 instance (Eq a) => Eq [a] where
 244     {-# SPECIALISE instance Eq [Char] #-}
 245     []     == []     = True
 246     (x:xs) == (y:ys) = x == y && xs == ys
 247     _xs    == _ys    = False
 248
 249 instance (Ord a) => Ord [a] where
 250     {-# SPECIALISE instance Ord [Char] #-}
 251     compare []     []     = EQ
 252     compare []     (_:_)  = LT
 253     compare (_:_)  []     = GT
 254     compare (x:xs) (y:ys) = case compare x y of
 255                                 EQ    -> compare xs ys
 256                                 other -> other
 257
 258 instance Functor [] where
 259     fmap = map
 260
 261 instance  Monad []  where
 262     m >>= k             = foldr ((++) . k) [] m
 263     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 264     return x            = [x]
 265     fail _              = []
 266 \end{code}
 267
 268 A few list functions that appear here because they are used here.
 269 The rest of the prelude list functions are in GHC.List.
 270
 271 ----------------------------------------------
 272 --      foldr/build/augment
 273 ----------------------------------------------
 274
 275 \begin{code}
 276 -- | 'foldr', applied to a binary operator, a starting value (typically
 277 -- the right-identity of the operator), and a list, reduces the list
 278 -- using the binary operator, from right to left:
 279 --
 280 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 281
 282 foldr            :: (a -> b -> b) -> b -> [a] -> b
 283 -- foldr _ z []     =  z
 284 -- foldr f z (x:xs) =  f x (foldr f z xs)
 285 {-# INLINE [0] foldr #-}
 286 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 287 -- Also note that we inline it when it has *two* parameters, which are the
 288 -- ones we are keen about specialising!
 289 foldr k z = go
 290           where
 291             go []     = z
 292             go (y:ys) = y `k` go ys
 293
 294 -- | A list producer that can be fused with 'foldr'.
 295 -- This function is merely
 296 --
 297 -- >    build g = g (:) []
 298 --
 299 -- but GHC's simplifier will transform an expression of the form
 300 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 301 -- which avoids producing an intermediate list.
 302
 303 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 304 {-# INLINE [1] build #-}
 305         -- The INLINE is important, even though build is tiny,
 306         -- because it prevents [] getting inlined in the version that
 307         -- appears in the interface file.  If [] *is* inlined, it
 308         -- won't match with [] appearing in rules in an importing module.
 309         --
 310         -- The "1" says to inline in phase 1
 311
 312 build g = g (:) []
 313
 314 -- | A list producer that can be fused with 'foldr'.
 315 -- This function is merely
 316 --
 317 -- >    augment g xs = g (:) xs
 318 --
 319 -- but GHC's simplifier will transform an expression of the form
 320 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 321 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 322
 323 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 324 {-# INLINE [1] augment #-}
 325 augment g xs = g (:) xs
 326
 327 {-# RULES
 328 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 329                 foldr k z (build g) = g k z
 330
 331 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 332                 foldr k z (augment g xs) = g k (foldr k z xs)
 333
 334 "foldr/id"                        foldr (:) [] = \x  -> x
 335 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 336         -- Only activate this from phase 1, because that's
 337         -- when we disable the rule that expands (++) into foldr
 338
 339 -- The foldr/cons rule looks nice, but it can give disastrously
 340 -- bloated code when commpiling
 341 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 342 -- i.e. when there are very very long literal lists
 343 -- So I've disabled it for now. We could have special cases
 344 -- for short lists, I suppose.
 345 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 346
 347 "foldr/single"  forall k z x. foldr k z [x] = k x z
 348 "foldr/nil"     forall k z.   foldr k z []  = z
 349
 350 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 351                        (h::forall b. (a->b->b) -> b -> b) .
 352                        augment g (build h) = build (\c n -> g c (h c n))
 353 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 354                         augment g [] = build g
 355  #-}
 356
 357 -- This rule is true, but not (I think) useful:
 358 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 359 \end{code}
 360
 361
 362 ----------------------------------------------
 363 --              map
 364 ----------------------------------------------
 365
 366 \begin{code}
 367 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 368 -- of @xs@, i.e.,
 369 --
 370 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 371 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 372
 373 map :: (a -> b) -> [a] -> [b]
 374 map _ []     = []
 375 map f (x:xs) = f x : map f xs
 376
 377 -- Note eta expanded
 378 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 379 {-# INLINE [0] mapFB #-}
 380 mapFB c f x ys = c (f x) ys
 381
 382 -- The rules for map work like this.
 383 --
 384 -- Up to (but not including) phase 1, we use the "map" rule to
 385 -- rewrite all saturated applications of map with its build/fold
 386 -- form, hoping for fusion to happen.
 387 -- In phase 1 and 0, we switch off that rule, inline build, and
 388 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 389 -- thing back into plain map.
 390 --
 391 -- It's important that these two rules aren't both active at once
 392 -- (along with build's unfolding) else we'd get an infinite loop
 393 -- in the rules.  Hence the activation control below.
 394 --
 395 -- The "mapFB" rule optimises compositions of map.
 396 --
 397 -- This same pattern is followed by many other functions:
 398 -- e.g. append, filter, iterate, repeat, etc.
 399
 400 {-# RULES
 401 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 402 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 403 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 404   #-}
 405 \end{code}
 406
 407
 408 ----------------------------------------------
 409 --              append
 410 ----------------------------------------------
 411 \begin{code}
 412 -- | Append two lists, i.e.,
 413 --
 414 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 415 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 416 --
 417 -- If the first list is not finite, the result is the first list.
 418
 419 (++) :: [a] -> [a] -> [a]
 420 (++) []     ys = ys
 421 (++) (x:xs) ys = x : xs ++ ys
 422
 423 {-# RULES
 424 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 425   #-}
 426
 427 \end{code}
 428
 429
 430 %*********************************************************
 431 %*                                                      *
 432 \subsection{Type @Bool@}
 433 %*                                                      *
 434 %*********************************************************
 435
 436 \begin{code}
 437 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 438 -- first so that the corresponding 'Prelude.Enum' instance will give
 439 -- 'Prelude.fromEnum' 'False' the value zero, and
 440 -- 'Prelude.fromEnum' 'True' the value 1.
 441 -- The actual definition is in the ghc-prim package.
 442
 443 -- XXX These don't work:
 444 -- deriving instance Eq Bool
 445 -- deriving instance Ord Bool
 446 -- <wired into compiler>:
 447 --     Illegal binding of built-in syntax: con2tag_Bool#
 448
 449 instance Eq Bool where
 450     True  == True  = True
 451     False == False = True
 452     _     == _     = False
 453
 454 instance Ord Bool where
 455     compare False True  = LT
 456     compare True  False = GT
 457     compare _     _     = EQ
 458
 459 -- Read is in GHC.Read, Show in GHC.Show
 460
 461 -- |'otherwise' is defined as the value 'True'.  It helps to make
 462 -- guards more readable.  eg.
 463 --
 464 -- >  f x | x < 0     = ...
 465 -- >      | otherwise = ...
 466 otherwise               :: Bool
 467 otherwise               =  True
 468 \end{code}
 469
 470 %*********************************************************
 471 %*                                                      *
 472 \subsection{Type @Ordering@}
 473 %*                                                      *
 474 %*********************************************************
 475
 476 \begin{code}
 477 -- | Represents an ordering relationship between two values: less
 478 -- than, equal to, or greater than.  An 'Ordering' is returned by
 479 -- 'compare'.
 480 -- XXX These don't work:
 481 -- deriving instance Eq Ordering
 482 -- deriving instance Ord Ordering
 483 -- Illegal binding of built-in syntax: con2tag_Ordering#
 484 instance Eq Ordering where
 485     EQ == EQ = True
 486     LT == LT = True
 487     GT == GT = True
 488     _  == _  = False
 489         -- Read in GHC.Read, Show in GHC.Show
 490
 491 instance Ord Ordering where
 492     LT <= _  = True
 493     _  <= LT = False
 494     EQ <= _  = True
 495     _  <= EQ = False
 496     GT <= GT = True
 497 \end{code}
 498
 499
 500 %*********************************************************
 501 %*                                                      *
 502 \subsection{Type @Char@ and @String@}
 503 %*                                                      *
 504 %*********************************************************
 505
 506 \begin{code}
 507 -- | A 'String' is a list of characters.  String constants in Haskell are values
 508 -- of type 'String'.
 509 --
 510 type String = [Char]
 511
 512 {-| The character type 'Char' is an enumeration whose values represent
 513 Unicode (or equivalently ISO\/IEC 10646) characters
 514 (see <http://www.unicode.org/> for details).
 515 This set extends the ISO 8859-1 (Latin-1) character set
 516 (the first 256 charachers), which is itself an extension of the ASCII
 517 character set (the first 128 characters).
 518 A character literal in Haskell has type 'Char'.
 519
 520 To convert a 'Char' to or from the corresponding 'Int' value defined
 521 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 522 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 523 -}
 524
 525 -- We don't use deriving for Eq and Ord, because for Ord the derived
 526 -- instance defines only compare, which takes two primops.  Then
 527 -- '>' uses compare, and therefore takes two primops instead of one.
 528
 529 instance Eq Char where
 530     (C# c1) == (C# c2) = c1 `eqChar#` c2
 531     (C# c1) /= (C# c2) = c1 `neChar#` c2
 532
 533 instance Ord Char where
 534     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 535     (C# c1) >= (C# c2) = c1 `geChar#` c2
 536     (C# c1) <= (C# c2) = c1 `leChar#` c2
 537     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 538
 539 {-# RULES
 540 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 541 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 542 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 543 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 544 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 545 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 546   #-}
 547
 548 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 549 chr :: Int -> Char
 550 chr i@(I# i#)
 551  | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 552  | otherwise
 553     = error ("Prelude.chr: bad argument: " ++ showSignedInt (I# 9#) i "")
 554
 555 unsafeChr :: Int -> Char
 556 unsafeChr (I# i#) = C# (chr# i#)
 557
 558 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 559 ord :: Char -> Int
 560 ord (C# c#) = I# (ord# c#)
 561 \end{code}
 562
 563 String equality is used when desugaring pattern-matches against strings.
 564
 565 \begin{code}
 566 eqString :: String -> String -> Bool
 567 eqString []       []       = True
 568 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 569 eqString _        _        = False
 570
 571 {-# RULES "eqString" (==) = eqString #-}
 572 -- eqString also has a BuiltInRule in PrelRules.lhs:
 573 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 574 \end{code}
 575
 576
 577 %*********************************************************
 578 %*                                                      *
 579 \subsection{Type @Int@}
 580 %*                                                      *
 581 %*********************************************************
 582
 583 \begin{code}
 584 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 585 zeroInt = I# 0#
 586 oneInt  = I# 1#
 587 twoInt  = I# 2#
 588
 589 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 590 #if WORD_SIZE_IN_BITS == 31
 591 minInt  = I# (-0x40000000#)
 592 maxInt  = I# 0x3FFFFFFF#
 593 #elif WORD_SIZE_IN_BITS == 32
 594 minInt  = I# (-0x80000000#)
 595 maxInt  = I# 0x7FFFFFFF#
 596 #else
 597 minInt  = I# (-0x8000000000000000#)
 598 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 599 #endif
 600
 601 instance Eq Int where
 602     (==) = eqInt
 603     (/=) = neInt
 604
 605 instance Ord Int where
 606     compare = compareInt
 607     (<)     = ltInt
 608     (<=)    = leInt
 609     (>=)    = geInt
 610     (>)     = gtInt
 611
 612 compareInt :: Int -> Int -> Ordering
 613 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 614
 615 compareInt# :: Int# -> Int# -> Ordering
 616 compareInt# x# y#
 617     | x# <#  y# = LT
 618     | x# ==# y# = EQ
 619     | otherwise = GT
 620 \end{code}
 621
 622
 623 %*********************************************************
 624 %*                                                      *
 625 \subsection{The function type}
 626 %*                                                      *
 627 %*********************************************************
 628
 629 \begin{code}
 630 -- | Identity function.
 631 id                      :: a -> a
 632 id x                    =  x
 633
 634 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 635 -- magical strictness property: it is lazy in its first argument,
 636 -- even though its semantics is strict.
 637 lazy :: a -> a
 638 lazy x = x
 639 -- Implementation note: its strictness and unfolding are over-ridden
 640 -- by the definition in MkId.lhs; in both cases to nothing at all.
 641 -- That way, 'lazy' does not get inlined, and the strictness analyser
 642 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 643 -- Result: happiness
 644
 645
 646 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 647 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 648 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 649 -- hence eliminated) late in compilation, after the rule has had
 650 -- a god chance to fire.
 651 inline :: a -> a
 652 {-# NOINLINE[0] inline #-}
 653 inline x = x
 654
 655 -- Assertion function.  This simply ignores its boolean argument.
 656 -- The compiler may rewrite it to @('assertError' line)@.
 657
 658 -- | If the first argument evaluates to 'True', then the result is the
 659 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 660 -- containing a 'String' with the source file and line number of the
 661 -- call to 'assert'.
 662 --
 663 -- Assertions can normally be turned on or off with a compiler flag
 664 -- (for GHC, assertions are normally on unless optimisation is turned on
 665 -- with @-O@ or the @-fignore-asserts@
 666 -- option is given).  When assertions are turned off, the first
 667 -- argument to 'assert' is ignored, and the second argument is
 668 -- returned as the result.
 669
 670 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 671 --      but from Template Haskell onwards it's simply
 672 --      defined here in Base.lhs
 673 assert :: Bool -> a -> a
 674 assert _pred r = r
 675
 676 breakpoint :: a -> a
 677 breakpoint r = r
 678
 679 breakpointCond :: Bool -> a -> a
 680 breakpointCond _ r = r
 681
 682 data Opaque = forall a. O a
 683
 684 -- | Constant function.
 685 const                   :: a -> b -> a
 686 const x _               =  x
 687
 688 -- | Function composition.
 689 {-# INLINE (.) #-}
 690 -- Make sure it has TWO args only on the left, so that it inlines
 691 -- when applied to two functions, even if there is no final argument
 692 (.)    :: (b -> c) -> (a -> b) -> a -> c
 693 (.) f g = \x -> f (g x)
 694
 695 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 696 flip                    :: (a -> b -> c) -> b -> a -> c
 697 flip f x y              =  f y x
 698
 699 -- | Application operator.  This operator is redundant, since ordinary
 700 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 701 -- low, right-associative binding precedence, so it sometimes allows
 702 -- parentheses to be omitted; for example:
 703 --
 704 -- >     f $ g $ h x  =  f (g (h x))
 705 --
 706 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 707 -- or @'Data.List.zipWith' ('$') fs xs@.
 708 {-# INLINE ($) #-}
 709 ($)                     :: (a -> b) -> a -> b
 710 f $ x                   =  f x
 711
 712 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 713 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 714 until p f x | p x       =  x
 715             | otherwise =  until p f (f x)
 716
 717 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 718 -- used as an infix operator, and its typing forces its first argument
 719 -- (which is usually overloaded) to have the same type as the second.
 720 asTypeOf                :: a -> a -> a
 721 asTypeOf                =  const
 722 \end{code}
 723
 724 %*********************************************************
 725 %*                                                      *
 726 \subsection{@Functor@ and @Monad@ instances for @IO@}
 727 %*                                                      *
 728 %*********************************************************
 729
 730 \begin{code}
 731 instance  Functor IO where
 732    fmap f x = x >>= (return . f)
 733
 734 instance  Monad IO  where
 735     {-# INLINE return #-}
 736     {-# INLINE (>>)   #-}
 737     {-# INLINE (>>=)  #-}
 738     m >> k    = m >>= \ _ -> k
 739     return    = returnIO
 740     (>>=)     = bindIO
 741     fail s    = GHC.IO.failIO s
 742
 743 returnIO :: a -> IO a
 744 returnIO x = IO $ \ s -> (# s, x #)
 745
 746 bindIO :: IO a -> (a -> IO b) -> IO b
 747 bindIO (IO m) k = IO $ \ s -> case m s of (# new_s, a #) -> unIO (k a) new_s
 748
 749 thenIO :: IO a -> IO b -> IO b
 750 thenIO (IO m) k = IO $ \ s -> case m s of (# new_s, _ #) -> unIO k new_s
 751
 752 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 753 unIO (IO a) = a
 754 \end{code}
 755
 756 %*********************************************************
 757 %*                                                      *
 758 \subsection{@getTag@}
 759 %*                                                      *
 760 %*********************************************************
 761
 762 Returns the 'tag' of a constructor application; this function is used
 763 by the deriving code for Eq, Ord and Enum.
 764
 765 The primitive dataToTag# requires an evaluated constructor application
 766 as its argument, so we provide getTag as a wrapper that performs the
 767 evaluation before calling dataToTag#.  We could have dataToTag#
 768 evaluate its argument, but we prefer to do it this way because (a)
 769 dataToTag# can be an inline primop if it doesn't need to do any
 770 evaluation, and (b) we want to expose the evaluation to the
 771 simplifier, because it might be possible to eliminate the evaluation
 772 in the case when the argument is already known to be evaluated.
 773
 774 \begin{code}
 775 {-# INLINE getTag #-}
 776 getTag :: a -> Int#
 777 getTag x = x `seq` dataToTag# x
 778 \end{code}
 779
 780 %*********************************************************
 781 %*                                                      *
 782 \subsection{Numeric primops}
 783 %*                                                      *
 784 %*********************************************************
 785
 786 \begin{code}
 787 divInt# :: Int# -> Int# -> Int#
 788 x# `divInt#` y#
 789         -- Be careful NOT to overflow if we do any additional arithmetic
 790         -- on the arguments...  the following  previous version of this
 791         -- code has problems with overflow:
 792 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 793 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 794     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 795     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 796     | otherwise                = x# `quotInt#` y#
 797
 798 modInt# :: Int# -> Int# -> Int#
 799 x# `modInt#` y#
 800     | (x# ># 0#) && (y# <# 0#) ||
 801       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 802     | otherwise                   = r#
 803     where
 804     !r# = x# `remInt#` y#
 805 \end{code}
 806
 807 Definitions of the boxed PrimOps; these will be
 808 used in the case of partial applications, etc.
 809
 810 \begin{code}
 811 {-# INLINE eqInt #-}
 812 {-# INLINE neInt #-}
 813 {-# INLINE gtInt #-}
 814 {-# INLINE geInt #-}
 815 {-# INLINE ltInt #-}
 816 {-# INLINE leInt #-}
 817 {-# INLINE plusInt #-}
 818 {-# INLINE minusInt #-}
 819 {-# INLINE timesInt #-}
 820 {-# INLINE quotInt #-}
 821 {-# INLINE remInt #-}
 822 {-# INLINE negateInt #-}
 823
 824 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt :: Int -> Int -> Int
 825 (I# x) `plusInt`  (I# y) = I# (x +# y)
 826 (I# x) `minusInt` (I# y) = I# (x -# y)
 827 (I# x) `timesInt` (I# y) = I# (x *# y)
 828 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 829 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 830 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 831 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 832
 833 {-# RULES
 834 "x# +# 0#" forall x#. x# +# 0# = x#
 835 "0# +# x#" forall x#. 0# +# x# = x#
 836 "x# -# 0#" forall x#. x# -# 0# = x#
 837 "x# -# x#" forall x#. x# -# x# = 0#
 838 "x# *# 0#" forall x#. x# *# 0# = 0#
 839 "0# *# x#" forall x#. 0# *# x# = 0#
 840 "x# *# 1#" forall x#. x# *# 1# = x#
 841 "1# *# x#" forall x#. 1# *# x# = x#
 842   #-}
 843
 844 negateInt :: Int -> Int
 845 negateInt (I# x) = I# (negateInt# x)
 846
 847 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 848 (I# x) `gtInt` (I# y) = x >#  y
 849 (I# x) `geInt` (I# y) = x >=# y
 850 (I# x) `eqInt` (I# y) = x ==# y
 851 (I# x) `neInt` (I# y) = x /=# y
 852 (I# x) `ltInt` (I# y) = x <#  y
 853 (I# x) `leInt` (I# y) = x <=# y
 854
 855 {-# RULES
 856 "x# ># x#"  forall x#. x# >#  x# = False
 857 "x# >=# x#" forall x#. x# >=# x# = True
 858 "x# ==# x#" forall x#. x# ==# x# = True
 859 "x# /=# x#" forall x#. x# /=# x# = False
 860 "x# <# x#"  forall x#. x# <#  x# = False
 861 "x# <=# x#" forall x#. x# <=# x# = True
 862   #-}
 863
 864 {-# RULES
 865 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 866 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 867 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 868 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 869 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 870 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 871 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 872 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 873 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 874   #-}
 875
 876 {-# RULES
 877 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 878 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 879 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 880 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 881 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 882 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 883   #-}
 884
 885 {-
 886 We'd like to have more rules, but for example:
 887
 888 This gives wrong answer (0) for NaN - NaN (should be NaN):
 889     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 890
 891 This gives wrong answer (0) for 0 * NaN (should be NaN):
 892     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 893
 894 This gives wrong answer (0) for NaN * 0 (should be NaN):
 895     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 896
 897 These are tested by num014.
 898 -}
 899
 900 -- Wrappers for the shift operations.  The uncheckedShift# family are
 901 -- undefined when the amount being shifted by is greater than the size
 902 -- in bits of Int#, so these wrappers perform a check and return
 903 -- either zero or -1 appropriately.
 904 --
 905 -- Note that these wrappers still produce undefined results when the
 906 -- second argument (the shift amount) is negative.
 907
 908 -- | Shift the argument left by the specified number of bits
 909 -- (which must be non-negative).
 910 shiftL# :: Word# -> Int# -> Word#
 911 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 912                 | otherwise                = a `uncheckedShiftL#` b
 913
 914 -- | Shift the argument right by the specified number of bits
 915 -- (which must be non-negative).
 916 shiftRL# :: Word# -> Int# -> Word#
 917 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 918                 | otherwise                = a `uncheckedShiftRL#` b
 919
 920 -- | Shift the argument left by the specified number of bits
 921 -- (which must be non-negative).
 922 iShiftL# :: Int# -> Int# -> Int#
 923 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 924                 | otherwise                = a `uncheckedIShiftL#` b
 925
 926 -- | Shift the argument right (signed) by the specified number of bits
 927 -- (which must be non-negative).
 928 iShiftRA# :: Int# -> Int# -> Int#
 929 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 930                 | otherwise                = a `uncheckedIShiftRA#` b
 931
 932 -- | Shift the argument right (unsigned) by the specified number of bits
 933 -- (which must be non-negative).
 934 iShiftRL# :: Int# -> Int# -> Int#
 935 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 936                 | otherwise                = a `uncheckedIShiftRL#` b
 937
 938 #if WORD_SIZE_IN_BITS == 32
 939 {-# RULES
 940 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 941 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 942    #-}
 943 #endif
 944
 945 {-# RULES
 946 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 947 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 948   #-}
 949 \end{code}
 950
 951
 952 %********************************************************
 953 %*                                                      *
 954 \subsection{Unpacking C strings}
 955 %*                                                      *
 956 %********************************************************
 957
 958 This code is needed for virtually all programs, since it's used for
 959 unpacking the strings of error messages.
 960
 961 \begin{code}
 962 unpackCString# :: Addr# -> [Char]
 963 {-# NOINLINE unpackCString# #-}
 964     -- There's really no point in inlining this, ever, cos
 965     -- the loop doesn't specialise in an interesting
 966     -- But it's pretty small, so there's a danger that
 967     -- it'll be inlined at every literal, which is a waste
 968 unpackCString# addr
 969   = unpack 0#
 970   where
 971     unpack nh
 972       | ch `eqChar#` '\0'# = []
 973       | otherwise          = C# ch : unpack (nh +# 1#)
 974       where
 975         !ch = indexCharOffAddr# addr nh
 976
 977 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 978 {-# NOINLINE unpackAppendCString# #-}
 979      -- See the NOINLINE note on unpackCString#
 980 unpackAppendCString# addr rest
 981   = unpack 0#
 982   where
 983     unpack nh
 984       | ch `eqChar#` '\0'# = rest
 985       | otherwise          = C# ch : unpack (nh +# 1#)
 986       where
 987         !ch = indexCharOffAddr# addr nh
 988
 989 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 990 {-# NOINLINE [0] unpackFoldrCString# #-}
 991 -- Unlike unpackCString#, there *is* some point in inlining unpackFoldrCString#,
 992 -- because we get better code for the function call.
 993 -- However, don't inline till right at the end;
 994 -- usually the unpack-list rule turns it into unpackCStringList
 995 -- It also has a BuiltInRule in PrelRules.lhs:
 996 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
 997 --        =  unpackFoldrCString# "foobaz" c n
 998 unpackFoldrCString# addr f z
 999   = unpack 0#
1000   where
1001     unpack nh
1002       | ch `eqChar#` '\0'# = z
1003       | otherwise          = C# ch `f` unpack (nh +# 1#)
1004       where
1005         !ch = indexCharOffAddr# addr nh
1006
1007 unpackCStringUtf8# :: Addr# -> [Char]
1008 unpackCStringUtf8# addr
1009   = unpack 0#
1010   where
1011     unpack nh
1012       | ch `eqChar#` '\0'#   = []
1013       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1014       | ch `leChar#` '\xDF'# =
1015           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1016                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1017           unpack (nh +# 2#)
1018       | ch `leChar#` '\xEF'# =
1019           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1020                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1021                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1022           unpack (nh +# 3#)
1023       | otherwise            =
1024           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1025                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1026                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1027                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1028           unpack (nh +# 4#)
1029       where
1030         !ch = indexCharOffAddr# addr nh
1031
1032 unpackNBytes# :: Addr# -> Int# -> [Char]
1033 unpackNBytes# _addr 0#   = []
1034 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1035     where
1036      unpack acc i#
1037       | i# <# 0#  = acc
1038       | otherwise =
1039          case indexCharOffAddr# addr i# of
1040             ch -> unpack (C# ch : acc) (i# -# 1#)
1041
1042 {-# RULES
1043 "unpack"       [~1] forall a   . unpackCString# a             = build (unpackFoldrCString# a)
1044 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1045 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1046
1047 -- There's a built-in rule (in PrelRules.lhs) for
1048 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1049
1050   #-}
1051 \end{code}
1052
1053 #ifdef __HADDOCK__
1054 \begin{code}
1055 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1056 -- indexing a state embedded in the 'Prelude.IO' monad by
1057 -- 'Control.Monad.ST.stToIO'.
1058 data RealWorld
1059 \end{code}
1060 #endif