GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_HADDOCK hide #-}
  67 -----------------------------------------------------------------------------
  68 -- |
  69 -- Module      :  GHC.Base
  70 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  71 -- License     :  see libraries/base/LICENSE
  72 --
  73 -- Maintainer  :  cvs-ghc@haskell.org
  74 -- Stability   :  internal
  75 -- Portability :  non-portable (GHC extensions)
  76 --
  77 -- Basic data types and classes.
  78 --
  79 -----------------------------------------------------------------------------
  80
  81 #include "MachDeps.h"
  82
  83 -- #hide
  84 module GHC.Base
  85         (
  86         module GHC.Base,
  87         module GHC.Bool,
  88         module GHC.Generics,
  89         module GHC.Ordering,
  90         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  91         module GHC.Err          -- of people having to import it explicitly
  92   )
  93         where
  94
  95 import GHC.Bool
  96 import GHC.Generics
  97 import GHC.Ordering
  98 import GHC.Prim
  99 import {-# SOURCE #-} GHC.Err
 100
 101 infixr 9  .
 102 infixr 5  ++, :
 103 infix  4  ==, /=, <, <=, >=, >
 104 infixr 3  &&
 105 infixr 2  ||
 106 infixl 1  >>, >>=
 107 infixr 0  $
 108
 109 default ()              -- Double isn't available yet
 110 \end{code}
 111
 112
 113 %*********************************************************
 114 %*                                                      *
 115 \subsection{DEBUGGING STUFF}
 116 %*  (for use when compiling GHC.Base itself doesn't work)
 117 %*                                                      *
 118 %*********************************************************
 119
 120 \begin{code}
 121 {-
 122 data  Bool  =  False | True
 123 data Ordering = LT | EQ | GT
 124 data Char = C# Char#
 125 type  String = [Char]
 126 data Int = I# Int#
 127 data  ()  =  ()
 128 data [] a = MkNil
 129
 130 not True = False
 131 (&&) True True = True
 132 otherwise = True
 133
 134 build = error "urk"
 135 foldr = error "urk"
 136
 137 unpackCString# :: Addr# -> [Char]
 138 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 139 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 140 unpackCStringUtf8# :: Addr# -> [Char]
 141 unpackCString# a = error "urk"
 142 unpackFoldrCString# a = error "urk"
 143 unpackAppendCString# a = error "urk"
 144 unpackCStringUtf8# a = error "urk"
 145 -}
 146 \end{code}
 147
 148
 149 %*********************************************************
 150 %*                                                      *
 151 \subsection{Standard classes @Eq@, @Ord@}
 152 %*                                                      *
 153 %*********************************************************
 154
 155 \begin{code}
 156
 157 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 158 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 159 -- and 'Eq' may be derived for any datatype whose constituents are also
 160 -- instances of 'Eq'.
 161 --
 162 -- Minimal complete definition: either '==' or '/='.
 163 --
 164 class  Eq a  where
 165     (==), (/=)           :: a -> a -> Bool
 166
 167     x /= y               = not (x == y)
 168     x == y               = not (x /= y)
 169
 170 -- | The 'Ord' class is used for totally ordered datatypes.
 171 --
 172 -- Instances of 'Ord' can be derived for any user-defined
 173 -- datatype whose constituent types are in 'Ord'.  The declared order
 174 -- of the constructors in the data declaration determines the ordering
 175 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 176 -- comparison to determine the precise ordering of two objects.
 177 --
 178 -- Minimal complete definition: either 'compare' or '<='.
 179 -- Using 'compare' can be more efficient for complex types.
 180 --
 181 class  (Eq a) => Ord a  where
 182     compare              :: a -> a -> Ordering
 183     (<), (<=), (>), (>=) :: a -> a -> Bool
 184     max, min             :: a -> a -> a
 185
 186     compare x y
 187         | x == y    = EQ
 188         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 189                                 -- above claim about the minimal things that
 190                                 -- can be defined for an instance of Ord
 191         | otherwise = GT
 192
 193     x <  y = case compare x y of { LT -> True;  _other -> False }
 194     x <= y = case compare x y of { GT -> False; _other -> True }
 195     x >  y = case compare x y of { GT -> True;  _other -> False }
 196     x >= y = case compare x y of { LT -> False; _other -> True }
 197
 198         -- These two default methods use '<=' rather than 'compare'
 199         -- because the latter is often more expensive
 200     max x y = if x <= y then y else x
 201     min x y = if x <= y then x else y
 202 \end{code}
 203
 204 %*********************************************************
 205 %*                                                      *
 206 \subsection{Monadic classes @Functor@, @Monad@ }
 207 %*                                                      *
 208 %*********************************************************
 209
 210 \begin{code}
 211 {- | The 'Functor' class is used for types that can be mapped over.
 212 Instances of 'Functor' should satisfy the following laws:
 213
 214 > fmap id  ==  id
 215 > fmap (f . g)  ==  fmap f . fmap g
 216
 217 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 218 defined in the "Prelude" satisfy these laws.
 219 -}
 220
 221 class  Functor f  where
 222     fmap        :: (a -> b) -> f a -> f b
 223
 224 {- | The 'Monad' class defines the basic operations over a /monad/,
 225 a concept from a branch of mathematics known as /category theory/.
 226 From the perspective of a Haskell programmer, however, it is best to
 227 think of a monad as an /abstract datatype/ of actions.
 228 Haskell's @do@ expressions provide a convenient syntax for writing
 229 monadic expressions.
 230
 231 Minimal complete definition: '>>=' and 'return'.
 232
 233 Instances of 'Monad' should satisfy the following laws:
 234
 235 > return a >>= k  ==  k a
 236 > m >>= return  ==  m
 237 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 238
 239 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 240
 241 > fmap f xs  ==  xs >>= return . f
 242
 243 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 244 defined in the "Prelude" satisfy these laws.
 245 -}
 246
 247 class  Monad m  where
 248     -- | Sequentially compose two actions, passing any value produced
 249     -- by the first as an argument to the second.
 250     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 251     -- | Sequentially compose two actions, discarding any value produced
 252     -- by the first, like sequencing operators (such as the semicolon)
 253     -- in imperative languages.
 254     (>>)        :: forall a b. m a -> m b -> m b
 255         -- Explicit for-alls so that we know what order to
 256         -- give type arguments when desugaring
 257
 258     -- | Inject a value into the monadic type.
 259     return      :: a -> m a
 260     -- | Fail with a message.  This operation is not part of the
 261     -- mathematical definition of a monad, but is invoked on pattern-match
 262     -- failure in a @do@ expression.
 263     fail        :: String -> m a
 264
 265     m >> k      = m >>= \_ -> k
 266     fail s      = error s
 267 \end{code}
 268
 269
 270 %*********************************************************
 271 %*                                                      *
 272 \subsection{The list type}
 273 %*                                                      *
 274 %*********************************************************
 275
 276 \begin{code}
 277 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
 278                           -- to avoid weird names like con2tag_[]#
 279
 280
 281 instance (Eq a) => Eq [a] where
 282     {-# SPECIALISE instance Eq [Char] #-}
 283     []     == []     = True
 284     (x:xs) == (y:ys) = x == y && xs == ys
 285     _xs    == _ys    = False
 286
 287 instance (Ord a) => Ord [a] where
 288     {-# SPECIALISE instance Ord [Char] #-}
 289     compare []     []     = EQ
 290     compare []     (_:_)  = LT
 291     compare (_:_)  []     = GT
 292     compare (x:xs) (y:ys) = case compare x y of
 293                                 EQ    -> compare xs ys
 294                                 other -> other
 295
 296 instance Functor [] where
 297     fmap = map
 298
 299 instance  Monad []  where
 300     m >>= k             = foldr ((++) . k) [] m
 301     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 302     return x            = [x]
 303     fail _              = []
 304 \end{code}
 305
 306 A few list functions that appear here because they are used here.
 307 The rest of the prelude list functions are in GHC.List.
 308
 309 ----------------------------------------------
 310 --      foldr/build/augment
 311 ----------------------------------------------
 312
 313 \begin{code}
 314 -- | 'foldr', applied to a binary operator, a starting value (typically
 315 -- the right-identity of the operator), and a list, reduces the list
 316 -- using the binary operator, from right to left:
 317 --
 318 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 319
 320 foldr            :: (a -> b -> b) -> b -> [a] -> b
 321 -- foldr _ z []     =  z
 322 -- foldr f z (x:xs) =  f x (foldr f z xs)
 323 {-# INLINE [0] foldr #-}
 324 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 325 foldr k z xs = go xs
 326              where
 327                go []     = z
 328                go (y:ys) = y `k` go ys
 329
 330 -- | A list producer that can be fused with 'foldr'.
 331 -- This function is merely
 332 --
 333 -- >    build g = g (:) []
 334 --
 335 -- but GHC's simplifier will transform an expression of the form
 336 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 337 -- which avoids producing an intermediate list.
 338
 339 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 340 {-# INLINE [1] build #-}
 341         -- The INLINE is important, even though build is tiny,
 342         -- because it prevents [] getting inlined in the version that
 343         -- appears in the interface file.  If [] *is* inlined, it
 344         -- won't match with [] appearing in rules in an importing module.
 345         --
 346         -- The "1" says to inline in phase 1
 347
 348 build g = g (:) []
 349
 350 -- | A list producer that can be fused with 'foldr'.
 351 -- This function is merely
 352 --
 353 -- >    augment g xs = g (:) xs
 354 --
 355 -- but GHC's simplifier will transform an expression of the form
 356 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 357 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 358
 359 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 360 {-# INLINE [1] augment #-}
 361 augment g xs = g (:) xs
 362
 363 {-# RULES
 364 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 365                 foldr k z (build g) = g k z
 366
 367 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 368                 foldr k z (augment g xs) = g k (foldr k z xs)
 369
 370 "foldr/id"                        foldr (:) [] = \x  -> x
 371 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 372         -- Only activate this from phase 1, because that's
 373         -- when we disable the rule that expands (++) into foldr
 374
 375 -- The foldr/cons rule looks nice, but it can give disastrously
 376 -- bloated code when commpiling
 377 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 378 -- i.e. when there are very very long literal lists
 379 -- So I've disabled it for now. We could have special cases
 380 -- for short lists, I suppose.
 381 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 382
 383 "foldr/single"  forall k z x. foldr k z [x] = k x z
 384 "foldr/nil"     forall k z.   foldr k z []  = z
 385
 386 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 387                        (h::forall b. (a->b->b) -> b -> b) .
 388                        augment g (build h) = build (\c n -> g c (h c n))
 389 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 390                         augment g [] = build g
 391  #-}
 392
 393 -- This rule is true, but not (I think) useful:
 394 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 395 \end{code}
 396
 397
 398 ----------------------------------------------
 399 --              map
 400 ----------------------------------------------
 401
 402 \begin{code}
 403 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 404 -- of @xs@, i.e.,
 405 --
 406 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 407 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 408
 409 map :: (a -> b) -> [a] -> [b]
 410 map _ []     = []
 411 map f (x:xs) = f x : map f xs
 412
 413 -- Note eta expanded
 414 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 415 {-# INLINE [0] mapFB #-}
 416 mapFB c f x ys = c (f x) ys
 417
 418 -- The rules for map work like this.
 419 --
 420 -- Up to (but not including) phase 1, we use the "map" rule to
 421 -- rewrite all saturated applications of map with its build/fold
 422 -- form, hoping for fusion to happen.
 423 -- In phase 1 and 0, we switch off that rule, inline build, and
 424 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 425 -- thing back into plain map.
 426 --
 427 -- It's important that these two rules aren't both active at once
 428 -- (along with build's unfolding) else we'd get an infinite loop
 429 -- in the rules.  Hence the activation control below.
 430 --
 431 -- The "mapFB" rule optimises compositions of map.
 432 --
 433 -- This same pattern is followed by many other functions:
 434 -- e.g. append, filter, iterate, repeat, etc.
 435
 436 {-# RULES
 437 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 438 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 439 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 440   #-}
 441 \end{code}
 442
 443
 444 ----------------------------------------------
 445 --              append
 446 ----------------------------------------------
 447 \begin{code}
 448 -- | Append two lists, i.e.,
 449 --
 450 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 451 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 452 --
 453 -- If the first list is not finite, the result is the first list.
 454
 455 (++) :: [a] -> [a] -> [a]
 456 (++) []     ys = ys
 457 (++) (x:xs) ys = x : xs ++ ys
 458
 459 {-# RULES
 460 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 461   #-}
 462
 463 \end{code}
 464
 465
 466 %*********************************************************
 467 %*                                                      *
 468 \subsection{Type @Bool@}
 469 %*                                                      *
 470 %*********************************************************
 471
 472 \begin{code}
 473 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 474 -- first so that the corresponding 'Prelude.Enum' instance will give
 475 -- 'Prelude.fromEnum' 'False' the value zero, and
 476 -- 'Prelude.fromEnum' 'True' the value 1.
 477 -- The actual definition is in the ghc-prim package.
 478
 479 -- XXX These don't work:
 480 -- deriving instance Eq Bool
 481 -- deriving instance Ord Bool
 482 -- <wired into compiler>:
 483 --     Illegal binding of built-in syntax: con2tag_Bool#
 484
 485 instance Eq Bool where
 486     True  == True  = True
 487     False == False = True
 488     _     == _     = False
 489
 490 instance Ord Bool where
 491     compare False True  = LT
 492     compare True  False = GT
 493     compare _     _     = EQ
 494
 495 -- Read is in GHC.Read, Show in GHC.Show
 496
 497 -- Boolean functions
 498
 499 -- | Boolean \"and\"
 500 (&&)                    :: Bool -> Bool -> Bool
 501 True  && x              =  x
 502 False && _              =  False
 503
 504 -- | Boolean \"or\"
 505 (||)                    :: Bool -> Bool -> Bool
 506 True  || _              =  True
 507 False || x              =  x
 508
 509 -- | Boolean \"not\"
 510 not                     :: Bool -> Bool
 511 not True                =  False
 512 not False               =  True
 513
 514 -- |'otherwise' is defined as the value 'True'.  It helps to make
 515 -- guards more readable.  eg.
 516 --
 517 -- >  f x | x < 0     = ...
 518 -- >      | otherwise = ...
 519 otherwise               :: Bool
 520 otherwise               =  True
 521 \end{code}
 522
 523 %*********************************************************
 524 %*                                                      *
 525 \subsection{Type @Ordering@}
 526 %*                                                      *
 527 %*********************************************************
 528
 529 \begin{code}
 530 -- | Represents an ordering relationship between two values: less
 531 -- than, equal to, or greater than.  An 'Ordering' is returned by
 532 -- 'compare'.
 533 -- XXX These don't work:
 534 -- deriving instance Eq Ordering
 535 -- deriving instance Ord Ordering
 536 -- Illegal binding of built-in syntax: con2tag_Ordering#
 537 instance Eq Ordering where
 538     EQ == EQ = True
 539     LT == LT = True
 540     GT == GT = True
 541     _  == _  = False
 542         -- Read in GHC.Read, Show in GHC.Show
 543
 544 instance Ord Ordering where
 545     LT <= _  = True
 546     _  <= LT = False
 547     EQ <= _  = True
 548     _  <= EQ = False
 549     GT <= GT = True
 550 \end{code}
 551
 552
 553 %*********************************************************
 554 %*                                                      *
 555 \subsection{Type @Char@ and @String@}
 556 %*                                                      *
 557 %*********************************************************
 558
 559 \begin{code}
 560 -- | A 'String' is a list of characters.  String constants in Haskell are values
 561 -- of type 'String'.
 562 --
 563 type String = [Char]
 564
 565 {-| The character type 'Char' is an enumeration whose values represent
 566 Unicode (or equivalently ISO\/IEC 10646) characters
 567 (see <http://www.unicode.org/> for details).
 568 This set extends the ISO 8859-1 (Latin-1) character set
 569 (the first 256 charachers), which is itself an extension of the ASCII
 570 character set (the first 128 characters).
 571 A character literal in Haskell has type 'Char'.
 572
 573 To convert a 'Char' to or from the corresponding 'Int' value defined
 574 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 575 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 576 -}
 577 data Char = C# Char#
 578
 579 -- We don't use deriving for Eq and Ord, because for Ord the derived
 580 -- instance defines only compare, which takes two primops.  Then
 581 -- '>' uses compare, and therefore takes two primops instead of one.
 582
 583 instance Eq Char where
 584     (C# c1) == (C# c2) = c1 `eqChar#` c2
 585     (C# c1) /= (C# c2) = c1 `neChar#` c2
 586
 587 instance Ord Char where
 588     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 589     (C# c1) >= (C# c2) = c1 `geChar#` c2
 590     (C# c1) <= (C# c2) = c1 `leChar#` c2
 591     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 592
 593 {-# RULES
 594 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 595 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 596 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 597 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 598 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 599 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 600   #-}
 601
 602 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 603 chr :: Int -> Char
 604 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 605             | otherwise                                  = error "Prelude.chr: bad argument"
 606
 607 unsafeChr :: Int -> Char
 608 unsafeChr (I# i#) = C# (chr# i#)
 609
 610 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 611 ord :: Char -> Int
 612 ord (C# c#) = I# (ord# c#)
 613 \end{code}
 614
 615 String equality is used when desugaring pattern-matches against strings.
 616
 617 \begin{code}
 618 eqString :: String -> String -> Bool
 619 eqString []       []       = True
 620 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 621 eqString cs1      cs2      = False
 622
 623 {-# RULES "eqString" (==) = eqString #-}
 624 -- eqString also has a BuiltInRule in PrelRules.lhs:
 625 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 626 \end{code}
 627
 628
 629 %*********************************************************
 630 %*                                                      *
 631 \subsection{Type @Int@}
 632 %*                                                      *
 633 %*********************************************************
 634
 635 \begin{code}
 636 data Int = I# Int#
 637 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
 638 -- The exact range for a given implementation can be determined by using
 639 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
 640
 641 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 642 zeroInt = I# 0#
 643 oneInt  = I# 1#
 644 twoInt  = I# 2#
 645
 646 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 647 #if WORD_SIZE_IN_BITS == 31
 648 minInt  = I# (-0x40000000#)
 649 maxInt  = I# 0x3FFFFFFF#
 650 #elif WORD_SIZE_IN_BITS == 32
 651 minInt  = I# (-0x80000000#)
 652 maxInt  = I# 0x7FFFFFFF#
 653 #else
 654 minInt  = I# (-0x8000000000000000#)
 655 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 656 #endif
 657
 658 instance Eq Int where
 659     (==) = eqInt
 660     (/=) = neInt
 661
 662 instance Ord Int where
 663     compare = compareInt
 664     (<)     = ltInt
 665     (<=)    = leInt
 666     (>=)    = geInt
 667     (>)     = gtInt
 668
 669 compareInt :: Int -> Int -> Ordering
 670 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 671
 672 compareInt# :: Int# -> Int# -> Ordering
 673 compareInt# x# y#
 674     | x# <#  y# = LT
 675     | x# ==# y# = EQ
 676     | otherwise = GT
 677 \end{code}
 678
 679
 680 %*********************************************************
 681 %*                                                      *
 682 \subsection{The function type}
 683 %*                                                      *
 684 %*********************************************************
 685
 686 \begin{code}
 687 -- | Identity function.
 688 id                      :: a -> a
 689 id x                    =  x
 690
 691 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 692 -- magical strictness property: it is lazy in its first argument,
 693 -- even though its semantics is strict.
 694 lazy :: a -> a
 695 lazy x = x
 696 -- Implementation note: its strictness and unfolding are over-ridden
 697 -- by the definition in MkId.lhs; in both cases to nothing at all.
 698 -- That way, 'lazy' does not get inlined, and the strictness analyser
 699 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 700 -- Result: happiness
 701
 702
 703 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 704 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 705 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 706 -- hence eliminated) late in compilation, after the rule has had
 707 -- a god chance to fire.
 708 inline :: a -> a
 709 {-# NOINLINE[0] inline #-}
 710 inline x = x
 711
 712 -- Assertion function.  This simply ignores its boolean argument.
 713 -- The compiler may rewrite it to @('assertError' line)@.
 714
 715 -- | If the first argument evaluates to 'True', then the result is the
 716 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 717 -- containing a 'String' with the source file and line number of the
 718 -- call to 'assert'.
 719 --
 720 -- Assertions can normally be turned on or off with a compiler flag
 721 -- (for GHC, assertions are normally on unless optimisation is turned on
 722 -- with @-O@ or the @-fignore-asserts@
 723 -- option is given).  When assertions are turned off, the first
 724 -- argument to 'assert' is ignored, and the second argument is
 725 -- returned as the result.
 726
 727 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 728 --      but from Template Haskell onwards it's simply
 729 --      defined here in Base.lhs
 730 assert :: Bool -> a -> a
 731 assert pred r = r
 732
 733 breakpoint :: a -> a
 734 breakpoint r = r
 735
 736 breakpointCond :: Bool -> a -> a
 737 breakpointCond _ r = r
 738
 739 data Opaque = forall a. O a
 740
 741 -- | Constant function.
 742 const                   :: a -> b -> a
 743 const x _               =  x
 744
 745 -- | Function composition.
 746 {-# INLINE (.) #-}
 747 (.)       :: (b -> c) -> (a -> b) -> a -> c
 748 (.) f g x = f (g x)
 749
 750 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 751 flip                    :: (a -> b -> c) -> b -> a -> c
 752 flip f x y              =  f y x
 753
 754 -- | Application operator.  This operator is redundant, since ordinary
 755 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 756 -- low, right-associative binding precedence, so it sometimes allows
 757 -- parentheses to be omitted; for example:
 758 --
 759 -- >     f $ g $ h x  =  f (g (h x))
 760 --
 761 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 762 -- or @'Data.List.zipWith' ('$') fs xs@.
 763 {-# INLINE ($) #-}
 764 ($)                     :: (a -> b) -> a -> b
 765 f $ x                   =  f x
 766
 767 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 768 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 769 until p f x | p x       =  x
 770             | otherwise =  until p f (f x)
 771
 772 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 773 -- used as an infix operator, and its typing forces its first argument
 774 -- (which is usually overloaded) to have the same type as the second.
 775 asTypeOf                :: a -> a -> a
 776 asTypeOf                =  const
 777 \end{code}
 778
 779 %*********************************************************
 780 %*                                                      *
 781 \subsection{@getTag@}
 782 %*                                                      *
 783 %*********************************************************
 784
 785 Returns the 'tag' of a constructor application; this function is used
 786 by the deriving code for Eq, Ord and Enum.
 787
 788 The primitive dataToTag# requires an evaluated constructor application
 789 as its argument, so we provide getTag as a wrapper that performs the
 790 evaluation before calling dataToTag#.  We could have dataToTag#
 791 evaluate its argument, but we prefer to do it this way because (a)
 792 dataToTag# can be an inline primop if it doesn't need to do any
 793 evaluation, and (b) we want to expose the evaluation to the
 794 simplifier, because it might be possible to eliminate the evaluation
 795 in the case when the argument is already known to be evaluated.
 796
 797 \begin{code}
 798 {-# INLINE getTag #-}
 799 getTag :: a -> Int#
 800 getTag x = x `seq` dataToTag# x
 801 \end{code}
 802
 803 %*********************************************************
 804 %*                                                      *
 805 \subsection{Numeric primops}
 806 %*                                                      *
 807 %*********************************************************
 808
 809 \begin{code}
 810 divInt# :: Int# -> Int# -> Int#
 811 x# `divInt#` y#
 812         -- Be careful NOT to overflow if we do any additional arithmetic
 813         -- on the arguments...  the following  previous version of this
 814         -- code has problems with overflow:
 815 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 816 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 817     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 818     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 819     | otherwise                = x# `quotInt#` y#
 820
 821 modInt# :: Int# -> Int# -> Int#
 822 x# `modInt#` y#
 823     | (x# ># 0#) && (y# <# 0#) ||
 824       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 825     | otherwise                   = r#
 826     where
 827     r# = x# `remInt#` y#
 828 \end{code}
 829
 830 Definitions of the boxed PrimOps; these will be
 831 used in the case of partial applications, etc.
 832
 833 \begin{code}
 834 {-# INLINE eqInt #-}
 835 {-# INLINE neInt #-}
 836 {-# INLINE gtInt #-}
 837 {-# INLINE geInt #-}
 838 {-# INLINE ltInt #-}
 839 {-# INLINE leInt #-}
 840 {-# INLINE plusInt #-}
 841 {-# INLINE minusInt #-}
 842 {-# INLINE timesInt #-}
 843 {-# INLINE quotInt #-}
 844 {-# INLINE remInt #-}
 845 {-# INLINE negateInt #-}
 846
 847 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 848 (I# x) `plusInt`  (I# y) = I# (x +# y)
 849 (I# x) `minusInt` (I# y) = I# (x -# y)
 850 (I# x) `timesInt` (I# y) = I# (x *# y)
 851 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 852 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 853 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 854 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 855
 856 {-# RULES
 857 "x# +# 0#" forall x#. x# +# 0# = x#
 858 "0# +# x#" forall x#. 0# +# x# = x#
 859 "x# -# 0#" forall x#. x# -# 0# = x#
 860 "x# -# x#" forall x#. x# -# x# = 0#
 861 "x# *# 0#" forall x#. x# *# 0# = 0#
 862 "0# *# x#" forall x#. 0# *# x# = 0#
 863 "x# *# 1#" forall x#. x# *# 1# = x#
 864 "1# *# x#" forall x#. 1# *# x# = x#
 865   #-}
 866
 867 gcdInt (I# a) (I# b) = g a b
 868    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 869          g 0# _  = I# absB
 870          g _  0# = I# absA
 871          g _  _  = I# (gcdInt# absA absB)
 872
 873          absInt x = if x <# 0# then negateInt# x else x
 874
 875          absA     = absInt a
 876          absB     = absInt b
 877
 878 negateInt :: Int -> Int
 879 negateInt (I# x) = I# (negateInt# x)
 880
 881 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 882 (I# x) `gtInt` (I# y) = x >#  y
 883 (I# x) `geInt` (I# y) = x >=# y
 884 (I# x) `eqInt` (I# y) = x ==# y
 885 (I# x) `neInt` (I# y) = x /=# y
 886 (I# x) `ltInt` (I# y) = x <#  y
 887 (I# x) `leInt` (I# y) = x <=# y
 888
 889 {-# RULES
 890 "x# ># x#"  forall x#. x# >#  x# = False
 891 "x# >=# x#" forall x#. x# >=# x# = True
 892 "x# ==# x#" forall x#. x# ==# x# = True
 893 "x# /=# x#" forall x#. x# /=# x# = False
 894 "x# <# x#"  forall x#. x# <#  x# = False
 895 "x# <=# x#" forall x#. x# <=# x# = True
 896   #-}
 897
 898 {-# RULES
 899 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 900 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 901 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 902 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 903 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 904 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 905 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 906 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 907 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 908   #-}
 909
 910 {-# RULES
 911 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 912 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 913 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 914 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 915 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 916 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 917   #-}
 918
 919 {-
 920 We'd like to have more rules, but for example:
 921
 922 This gives wrong answer (0) for NaN - NaN (should be NaN):
 923     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 924
 925 This gives wrong answer (0) for 0 * NaN (should be NaN):
 926     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 927
 928 This gives wrong answer (0) for NaN * 0 (should be NaN):
 929     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 930
 931 These are tested by num014.
 932 -}
 933
 934 -- Wrappers for the shift operations.  The uncheckedShift# family are
 935 -- undefined when the amount being shifted by is greater than the size
 936 -- in bits of Int#, so these wrappers perform a check and return
 937 -- either zero or -1 appropriately.
 938 --
 939 -- Note that these wrappers still produce undefined results when the
 940 -- second argument (the shift amount) is negative.
 941
 942 -- | Shift the argument left by the specified number of bits
 943 -- (which must be non-negative).
 944 shiftL# :: Word# -> Int# -> Word#
 945 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 946                 | otherwise                = a `uncheckedShiftL#` b
 947
 948 -- | Shift the argument right by the specified number of bits
 949 -- (which must be non-negative).
 950 shiftRL# :: Word# -> Int# -> Word#
 951 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 952                 | otherwise                = a `uncheckedShiftRL#` b
 953
 954 -- | Shift the argument left by the specified number of bits
 955 -- (which must be non-negative).
 956 iShiftL# :: Int# -> Int# -> Int#
 957 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 958                 | otherwise                = a `uncheckedIShiftL#` b
 959
 960 -- | Shift the argument right (signed) by the specified number of bits
 961 -- (which must be non-negative).
 962 iShiftRA# :: Int# -> Int# -> Int#
 963 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 964                 | otherwise                = a `uncheckedIShiftRA#` b
 965
 966 -- | Shift the argument right (unsigned) by the specified number of bits
 967 -- (which must be non-negative).
 968 iShiftRL# :: Int# -> Int# -> Int#
 969 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 970                 | otherwise                = a `uncheckedIShiftRL#` b
 971
 972 #if WORD_SIZE_IN_BITS == 32
 973 {-# RULES
 974 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 975 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 976    #-}
 977 #endif
 978
 979 {-# RULES
 980 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 981 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 982   #-}
 983 \end{code}
 984
 985
 986 %********************************************************
 987 %*                                                      *
 988 \subsection{Unpacking C strings}
 989 %*                                                      *
 990 %********************************************************
 991
 992 This code is needed for virtually all programs, since it's used for
 993 unpacking the strings of error messages.
 994
 995 \begin{code}
 996 unpackCString# :: Addr# -> [Char]
 997 {-# NOINLINE [1] unpackCString# #-}
 998 unpackCString# addr
 999   = unpack 0#
1000   where
1001     unpack nh
1002       | ch `eqChar#` '\0'# = []
1003       | otherwise          = C# ch : unpack (nh +# 1#)
1004       where
1005         ch = indexCharOffAddr# addr nh
1006
1007 unpackAppendCString# :: Addr# -> [Char] -> [Char]
1008 unpackAppendCString# addr rest
1009   = unpack 0#
1010   where
1011     unpack nh
1012       | ch `eqChar#` '\0'# = rest
1013       | otherwise          = C# ch : unpack (nh +# 1#)
1014       where
1015         ch = indexCharOffAddr# addr nh
1016
1017 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
1018 {-# NOINLINE [0] unpackFoldrCString# #-}
1019 -- Don't inline till right at the end;
1020 -- usually the unpack-list rule turns it into unpackCStringList
1021 -- It also has a BuiltInRule in PrelRules.lhs:
1022 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
1023 --        =  unpackFoldrCString# "foobaz" c n
1024 unpackFoldrCString# addr f z
1025   = unpack 0#
1026   where
1027     unpack nh
1028       | ch `eqChar#` '\0'# = z
1029       | otherwise          = C# ch `f` unpack (nh +# 1#)
1030       where
1031         ch = indexCharOffAddr# addr nh
1032
1033 unpackCStringUtf8# :: Addr# -> [Char]
1034 unpackCStringUtf8# addr
1035   = unpack 0#
1036   where
1037     unpack nh
1038       | ch `eqChar#` '\0'#   = []
1039       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1040       | ch `leChar#` '\xDF'# =
1041           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1042                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1043           unpack (nh +# 2#)
1044       | ch `leChar#` '\xEF'# =
1045           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1046                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1047                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1048           unpack (nh +# 3#)
1049       | otherwise            =
1050           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1051                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1052                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1053                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1054           unpack (nh +# 4#)
1055       where
1056         ch = indexCharOffAddr# addr nh
1057
1058 unpackNBytes# :: Addr# -> Int# -> [Char]
1059 unpackNBytes# _addr 0#   = []
1060 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1061     where
1062      unpack acc i#
1063       | i# <# 0#  = acc
1064       | otherwise =
1065          case indexCharOffAddr# addr i# of
1066             ch -> unpack (C# ch : acc) (i# -# 1#)
1067
1068 {-# RULES
1069 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1070 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1071 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1072
1073 -- There's a built-in rule (in PrelRules.lhs) for
1074 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1075
1076   #-}
1077 \end{code}
1078
1079 #ifdef __HADDOCK__
1080 \begin{code}
1081 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1082 -- indexing a state embedded in the 'Prelude.IO' monad by
1083 -- 'Control.Monad.ST.stToIO'.
1084 data RealWorld
1085 \end{code}
1086 #endif