GHC/Conc.lhs

   1 \begin{code}
   2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.Conc
   6 -- Copyright   :  (c) The University of Glasgow, 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC extensions)
  12 --
  13 -- Basic concurrency stuff.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 module GHC.Conc
  18         ( ThreadId(..)
  19
  20         -- Forking and suchlike
  21         , myThreadId    -- :: IO ThreadId
  22         , killThread    -- :: ThreadId -> IO ()
  23         , throwTo       -- :: ThreadId -> Exception -> IO ()
  24         , par           -- :: a -> b -> b
  25         , pseq          -- :: a -> b -> b
  26         , yield         -- :: IO ()
  27         , labelThread   -- :: ThreadId -> String -> IO ()
  28
  29         -- Waiting
  30         , threadDelay           -- :: Int -> IO ()
  31         , threadWaitRead        -- :: Int -> IO ()
  32         , threadWaitWrite       -- :: Int -> IO ()
  33
  34         -- MVars
  35         , MVar          -- abstract
  36         , newMVar       -- :: a -> IO (MVar a)
  37         , newEmptyMVar  -- :: IO (MVar a)
  38         , takeMVar      -- :: MVar a -> IO a
  39         , putMVar       -- :: MVar a -> a -> IO ()
  40         , tryTakeMVar   -- :: MVar a -> IO (Maybe a)
  41         , tryPutMVar    -- :: MVar a -> a -> IO Bool
  42         , isEmptyMVar   -- :: MVar a -> IO Bool
  43         , addMVarFinalizer -- :: MVar a -> IO () -> IO ()
  44
  45         -- TVars
  46         , STM           -- abstract
  47         , atomically    -- :: STM a -> IO a
  48         , retry         -- :: STM a
  49         , orElse        -- :: STM a -> STM a -> STM a
  50         , catchSTM      -- :: STM a -> (Exception -> STM a) -> STM a
  51         , TVar          -- abstract
  52         , newTVar       -- :: a -> STM (TVar a)
  53         , readTVar      -- :: TVar a -> STM a
  54         , writeTVar     -- :: a -> TVar a -> STM ()
  55         , unsafeIOToSTM -- :: IO a -> STM a
  56
  57 #ifdef mingw32_HOST_OS
  58         , asyncRead     -- :: Int -> Int -> Int -> Ptr a -> IO (Int, Int)
  59         , asyncWrite    -- :: Int -> Int -> Int -> Ptr a -> IO (Int, Int)
  60         , asyncDoProc   -- :: FunPtr (Ptr a -> IO Int) -> Ptr a -> IO Int
  61
  62         , asyncReadBA   -- :: Int -> Int -> Int -> Int -> MutableByteArray# RealWorld -> IO (Int, Int)
  63         , asyncWriteBA  -- :: Int -> Int -> Int -> Int -> MutableByteArray# RealWorld -> IO (Int, Int)
  64 #endif
  65         ) where
  66
  67 import System.Posix.Types
  68 import System.Posix.Internals
  69 import Foreign
  70 import Foreign.C
  71
  72 import Data.Maybe
  73
  74 import GHC.Base
  75 import GHC.IOBase
  76 import GHC.Num          ( Num(..) )
  77 import GHC.Real         ( fromIntegral, quot )
  78 import GHC.Base         ( Int(..) )
  79 import GHC.Exception    ( Exception(..), AsyncException(..) )
  80 import GHC.Pack         ( packCString# )
  81 import GHC.Ptr          ( Ptr(..), plusPtr, FunPtr(..) )
  82 import GHC.STRef
  83 import Data.Typeable
  84
  85 infixr 0 `par`, `pseq`
  86 \end{code}
  87
  88 %************************************************************************
  89 %*                                                                      *
  90 \subsection{@ThreadId@, @par@, and @fork@}
  91 %*                                                                      *
  92 %************************************************************************
  93
  94 \begin{code}
  95 data ThreadId = ThreadId ThreadId# deriving( Typeable )
  96 -- ToDo: data ThreadId = ThreadId (Weak ThreadId#)
  97 -- But since ThreadId# is unlifted, the Weak type must use open
  98 -- type variables.
  99 {- ^
 100 A 'ThreadId' is an abstract type representing a handle to a thread.
 101 'ThreadId' is an instance of 'Eq', 'Ord' and 'Show', where
 102 the 'Ord' instance implements an arbitrary total ordering over
 103 'ThreadId's. The 'Show' instance lets you convert an arbitrary-valued
 104 'ThreadId' to string form; showing a 'ThreadId' value is occasionally
 105 useful when debugging or diagnosing the behaviour of a concurrent
 106 program.
 107
 108 /Note/: in GHC, if you have a 'ThreadId', you essentially have
 109 a pointer to the thread itself.  This means the thread itself can\'t be
 110 garbage collected until you drop the 'ThreadId'.
 111 This misfeature will hopefully be corrected at a later date.
 112
 113 /Note/: Hugs does not provide any operations on other threads;
 114 it defines 'ThreadId' as a synonym for ().
 115 -}
 116
 117 --forkIO has now been hoisted out into the Concurrent library.
 118
 119 {- | 'killThread' terminates the given thread (GHC only).
 120 Any work already done by the thread isn\'t
 121 lost: the computation is suspended until required by another thread.
 122 The memory used by the thread will be garbage collected if it isn\'t
 123 referenced from anywhere.  The 'killThread' function is defined in
 124 terms of 'throwTo':
 125
 126 > killThread tid = throwTo tid (AsyncException ThreadKilled)
 127
 128 -}
 129 killThread :: ThreadId -> IO ()
 130 killThread tid = throwTo tid (AsyncException ThreadKilled)
 131
 132 {- | 'throwTo' raises an arbitrary exception in the target thread (GHC only).
 133
 134 'throwTo' does not return until the exception has been raised in the
 135 target thread.  The calling thread can thus be certain that the target
 136 thread has received the exception.  This is a useful property to know
 137 when dealing with race conditions: eg. if there are two threads that
 138 can kill each other, it is guaranteed that only one of the threads
 139 will get to kill the other. -}
 140 throwTo :: ThreadId -> Exception -> IO ()
 141 throwTo (ThreadId id) ex = IO $ \ s ->
 142    case (killThread# id ex s) of s1 -> (# s1, () #)
 143
 144 -- | Returns the 'ThreadId' of the calling thread (GHC only).
 145 myThreadId :: IO ThreadId
 146 myThreadId = IO $ \s ->
 147    case (myThreadId# s) of (# s1, id #) -> (# s1, ThreadId id #)
 148
 149
 150 -- |The 'yield' action allows (forces, in a co-operative multitasking
 151 -- implementation) a context-switch to any other currently runnable
 152 -- threads (if any), and is occasionally useful when implementing
 153 -- concurrency abstractions.
 154 yield :: IO ()
 155 yield = IO $ \s ->
 156    case (yield# s) of s1 -> (# s1, () #)
 157
 158 {- | 'labelThread' stores a string as identifier for this thread if
 159 you built a RTS with debugging support. This identifier will be used in
 160 the debugging output to make distinction of different threads easier
 161 (otherwise you only have the thread state object\'s address in the heap).
 162
 163 Other applications like the graphical Concurrent Haskell Debugger
 164 (<http://www.informatik.uni-kiel.de/~fhu/chd/>) may choose to overload
 165 'labelThread' for their purposes as well.
 166 -}
 167
 168 labelThread :: ThreadId -> String -> IO ()
 169 labelThread (ThreadId t) str = IO $ \ s ->
 170    let ps  = packCString# str
 171        adr = byteArrayContents# ps in
 172      case (labelThread# t adr s) of s1 -> (# s1, () #)
 173
 174 --      Nota Bene: 'pseq' used to be 'seq'
 175 --                 but 'seq' is now defined in PrelGHC
 176 --
 177 -- "pseq" is defined a bit weirdly (see below)
 178 --
 179 -- The reason for the strange "lazy" call is that
 180 -- it fools the compiler into thinking that pseq  and par are non-strict in
 181 -- their second argument (even if it inlines pseq at the call site).
 182 -- If it thinks pseq is strict in "y", then it often evaluates
 183 -- "y" before "x", which is totally wrong.
 184
 185 {-# INLINE pseq  #-}
 186 pseq :: a -> b -> b
 187 pseq  x y = x `seq` lazy y
 188
 189 {-# INLINE par  #-}
 190 par :: a -> b -> b
 191 par  x y = case (par# x) of { _ -> lazy y }
 192 \end{code}
 193
 194
 195 %************************************************************************
 196 %*                                                                      *
 197 \subsection[stm]{Transactional heap operations}
 198 %*                                                                      *
 199 %************************************************************************
 200
 201 TVars are shared memory locations which support atomic memory
 202 transactions.
 203
 204 \begin{code}
 205 newtype STM a = STM (State# RealWorld -> (# State# RealWorld, a #)) deriving( Typeable )
 206
 207 unSTM :: STM a -> (State# RealWorld -> (# State# RealWorld, a #))
 208 unSTM (STM a) = a
 209
 210 instance  Functor STM where
 211    fmap f x = x >>= (return . f)
 212
 213 instance  Monad STM  where
 214     {-# INLINE return #-}
 215     {-# INLINE (>>)   #-}
 216     {-# INLINE (>>=)  #-}
 217     m >> k      = thenSTM m k
 218     return x    = returnSTM x
 219     m >>= k     = bindSTM m k
 220
 221 bindSTM :: STM a -> (a -> STM b) -> STM b
 222 bindSTM (STM m) k = STM ( \s ->
 223   case m s of
 224     (# new_s, a #) -> unSTM (k a) new_s
 225   )
 226
 227 thenSTM :: STM a -> STM b -> STM b
 228 thenSTM (STM m) k = STM ( \s ->
 229   case m s of
 230     (# new_s, a #) -> unSTM k new_s
 231   )
 232
 233 returnSTM :: a -> STM a
 234 returnSTM x = STM (\s -> (# s, x #))
 235
 236 -- | Unsafely performs IO in the STM monad.
 237 unsafeIOToSTM :: IO a -> STM a
 238 unsafeIOToSTM (IO m) = STM m
 239
 240 -- |Perform a series of STM actions atomically.
 241 atomically :: STM a -> IO a
 242 atomically (STM m) = IO (\s -> (atomically# m) s )
 243
 244 -- |Retry execution of the current memory transaction because it has seen
 245 -- values in TVars which mean that it should not continue (e.g. the TVars
 246 -- represent a shared buffer that is now empty).  The implementation may
 247 -- block the thread until one of the TVars that it has read from has been
 248 -- udpated.
 249 retry :: STM a
 250 retry = STM $ \s# -> retry# s#
 251
 252 -- |Compose two alternative STM actions.  If the first action completes without
 253 -- retrying then it forms the result of the orElse.  Otherwise, if the first
 254 -- action retries, then the second action is tried in its place.  If both actions
 255 -- retry then the orElse as a whole retries.
 256 orElse :: STM a -> STM a -> STM a
 257 orElse (STM m) e = STM $ \s -> catchRetry# m (unSTM e) s
 258
 259 -- |Exception handling within STM actions.
 260 catchSTM :: STM a -> (Exception -> STM a) -> STM a
 261 catchSTM (STM m) k = STM $ \s -> catchSTM# m (\ex -> unSTM (k ex)) s
 262
 263 data TVar a = TVar (TVar# RealWorld a) deriving( Typeable )
 264
 265 instance Eq (TVar a) where
 266         (TVar tvar1#) == (TVar tvar2#) = sameTVar# tvar1# tvar2#
 267
 268 -- |Create a new TVar holding a value supplied
 269 newTVar :: a -> STM (TVar a)
 270 newTVar val = STM $ \s1# ->
 271     case newTVar# val s1# of
 272          (# s2#, tvar# #) -> (# s2#, TVar tvar# #)
 273
 274 -- |Return the current value stored in a TVar
 275 readTVar :: TVar a -> STM a
 276 readTVar (TVar tvar#) = STM $ \s# -> readTVar# tvar# s#
 277
 278 -- |Write the supplied value into a TVar
 279 writeTVar :: TVar a -> a -> STM ()
 280 writeTVar (TVar tvar#) val = STM $ \s1# ->
 281     case writeTVar# tvar# val s1# of
 282          s2# -> (# s2#, () #)
 283
 284 \end{code}
 285
 286 %************************************************************************
 287 %*                                                                      *
 288 \subsection[mvars]{M-Structures}
 289 %*                                                                      *
 290 %************************************************************************
 291
 292 M-Vars are rendezvous points for concurrent threads.  They begin
 293 empty, and any attempt to read an empty M-Var blocks.  When an M-Var
 294 is written, a single blocked thread may be freed.  Reading an M-Var
 295 toggles its state from full back to empty.  Therefore, any value
 296 written to an M-Var may only be read once.  Multiple reads and writes
 297 are allowed, but there must be at least one read between any two
 298 writes.
 299
 300 \begin{code}
 301 --Defined in IOBase to avoid cycle: data MVar a = MVar (SynchVar# RealWorld a)
 302
 303 -- |Create an 'MVar' which is initially empty.
 304 newEmptyMVar  :: IO (MVar a)
 305 newEmptyMVar = IO $ \ s# ->
 306     case newMVar# s# of
 307          (# s2#, svar# #) -> (# s2#, MVar svar# #)
 308
 309 -- |Create an 'MVar' which contains the supplied value.
 310 newMVar :: a -> IO (MVar a)
 311 newMVar value =
 312     newEmptyMVar        >>= \ mvar ->
 313     putMVar mvar value  >>
 314     return mvar
 315
 316 -- |Return the contents of the 'MVar'.  If the 'MVar' is currently
 317 -- empty, 'takeMVar' will wait until it is full.  After a 'takeMVar',
 318 -- the 'MVar' is left empty.
 319 --
 320 -- If several threads are competing to take the same 'MVar', one is chosen
 321 -- to continue at random when the 'MVar' becomes full.
 322 takeMVar :: MVar a -> IO a
 323 takeMVar (MVar mvar#) = IO $ \ s# -> takeMVar# mvar# s#
 324
 325 -- |Put a value into an 'MVar'.  If the 'MVar' is currently full,
 326 -- 'putMVar' will wait until it becomes empty.
 327 --
 328 -- If several threads are competing to fill the same 'MVar', one is
 329 -- chosen to continue at random when the 'MVar' becomes empty.
 330 putMVar  :: MVar a -> a -> IO ()
 331 putMVar (MVar mvar#) x = IO $ \ s# ->
 332     case putMVar# mvar# x s# of
 333         s2# -> (# s2#, () #)
 334
 335 -- |A non-blocking version of 'takeMVar'.  The 'tryTakeMVar' function
 336 -- returns immediately, with 'Nothing' if the 'MVar' was empty, or
 337 -- @'Just' a@ if the 'MVar' was full with contents @a@.  After 'tryTakeMVar',
 338 -- the 'MVar' is left empty.
 339 tryTakeMVar :: MVar a -> IO (Maybe a)
 340 tryTakeMVar (MVar m) = IO $ \ s ->
 341     case tryTakeMVar# m s of
 342         (# s, 0#, _ #) -> (# s, Nothing #)      -- MVar is empty
 343         (# s, _,  a #) -> (# s, Just a  #)      -- MVar is full
 344
 345 -- |A non-blocking version of 'putMVar'.  The 'tryPutMVar' function
 346 -- attempts to put the value @a@ into the 'MVar', returning 'True' if
 347 -- it was successful, or 'False' otherwise.
 348 tryPutMVar  :: MVar a -> a -> IO Bool
 349 tryPutMVar (MVar mvar#) x = IO $ \ s# ->
 350     case tryPutMVar# mvar# x s# of
 351         (# s, 0# #) -> (# s, False #)
 352         (# s, _  #) -> (# s, True #)
 353
 354 -- |Check whether a given 'MVar' is empty.
 355 --
 356 -- Notice that the boolean value returned  is just a snapshot of
 357 -- the state of the MVar. By the time you get to react on its result,
 358 -- the MVar may have been filled (or emptied) - so be extremely
 359 -- careful when using this operation.   Use 'tryTakeMVar' instead if possible.
 360 isEmptyMVar :: MVar a -> IO Bool
 361 isEmptyMVar (MVar mv#) = IO $ \ s# ->
 362     case isEmptyMVar# mv# s# of
 363         (# s2#, flg #) -> (# s2#, not (flg ==# 0#) #)
 364
 365 -- |Add a finalizer to an 'MVar' (GHC only).  See "Foreign.ForeignPtr" and
 366 -- "System.Mem.Weak" for more about finalizers.
 367 addMVarFinalizer :: MVar a -> IO () -> IO ()
 368 addMVarFinalizer (MVar m) finalizer =
 369   IO $ \s -> case mkWeak# m () finalizer s of { (# s1, w #) -> (# s1, () #) }
 370 \end{code}
 371
 372
 373 %************************************************************************
 374 %*                                                                      *
 375 \subsection{Thread waiting}
 376 %*                                                                      *
 377 %************************************************************************
 378
 379 \begin{code}
 380 #ifdef mingw32_HOST_OS
 381
 382 -- Note: threadDelay, threadWaitRead and threadWaitWrite aren't really functional
 383 -- on Win32, but left in there because lib code (still) uses them (the manner
 384 -- in which they're used doesn't cause problems on a Win32 platform though.)
 385
 386 asyncRead :: Int -> Int -> Int -> Ptr a -> IO (Int, Int)
 387 asyncRead  (I# fd) (I# isSock) (I# len) (Ptr buf) =
 388   IO $ \s -> case asyncRead# fd isSock len buf s of
 389                (# s, len#, err# #) -> (# s, (I# len#, I# err#) #)
 390
 391 asyncWrite :: Int -> Int -> Int -> Ptr a -> IO (Int, Int)
 392 asyncWrite  (I# fd) (I# isSock) (I# len) (Ptr buf) =
 393   IO $ \s -> case asyncWrite# fd isSock len buf s of
 394                (# s, len#, err# #) -> (# s, (I# len#, I# err#) #)
 395
 396 asyncDoProc :: FunPtr (Ptr a -> IO Int) -> Ptr a -> IO Int
 397 asyncDoProc (FunPtr proc) (Ptr param) =
 398     -- the 'length' value is ignored; simplifies implementation of
 399     -- the async*# primops to have them all return the same result.
 400   IO $ \s -> case asyncDoProc# proc param s  of
 401                (# s, len#, err# #) -> (# s, I# err# #)
 402
 403 -- to aid the use of these primops by the IO Handle implementation,
 404 -- provide the following convenience funs:
 405
 406 -- this better be a pinned byte array!
 407 asyncReadBA :: Int -> Int -> Int -> Int -> MutableByteArray# RealWorld -> IO (Int,Int)
 408 asyncReadBA fd isSock len off bufB =
 409   asyncRead fd isSock len ((Ptr (byteArrayContents# (unsafeCoerce# bufB))) `plusPtr` off)
 410
 411 asyncWriteBA :: Int -> Int -> Int -> Int -> MutableByteArray# RealWorld -> IO (Int,Int)
 412 asyncWriteBA fd isSock len off bufB =
 413   asyncWrite fd isSock len ((Ptr (byteArrayContents# (unsafeCoerce# bufB))) `plusPtr` off)
 414
 415 #endif
 416
 417 -- -----------------------------------------------------------------------------
 418 -- Thread IO API
 419
 420 -- | Block the current thread until data is available to read on the
 421 -- given file descriptor (GHC only).
 422 threadWaitRead :: Fd -> IO ()
 423 threadWaitRead fd
 424 #ifndef mingw32_HOST_OS
 425   | threaded  = waitForReadEvent fd
 426 #endif
 427   | otherwise = IO $ \s ->
 428         case fromIntegral fd of { I# fd# ->
 429         case waitRead# fd# s of { s -> (# s, () #)
 430         }}
 431
 432 -- | Block the current thread until data can be written to the
 433 -- given file descriptor (GHC only).
 434 threadWaitWrite :: Fd -> IO ()
 435 threadWaitWrite fd
 436 #ifndef mingw32_HOST_OS
 437   | threaded  = waitForWriteEvent fd
 438 #endif
 439   | otherwise = IO $ \s ->
 440         case fromIntegral fd of { I# fd# ->
 441         case waitWrite# fd# s of { s -> (# s, () #)
 442         }}
 443
 444 -- | Suspends the current thread for a given number of microseconds
 445 -- (GHC only).
 446 --
 447 -- Note that the resolution used by the Haskell runtime system's
 448 -- internal timer is 1\/50 second, and 'threadDelay' will round its
 449 -- argument up to the nearest multiple of this resolution.
 450 --
 451 -- There is no guarantee that the thread will be rescheduled promptly
 452 -- when the delay has expired, but the thread will never continue to
 453 -- run /earlier/ than specified.
 454 --
 455 threadDelay :: Int -> IO ()
 456 threadDelay time
 457 #ifndef mingw32_HOST_OS
 458   | threaded  = waitForDelayEvent time
 459 #else
 460   | threaded  = c_Sleep (fromIntegral (time `quot` 1000))
 461 #endif
 462   | otherwise = IO $ \s ->
 463         case fromIntegral time of { I# time# ->
 464         case delay# time# s of { s -> (# s, () #)
 465         }}
 466
 467 -- On Windows, we just make a safe call to 'Sleep' to implement threadDelay.
 468 #ifdef mingw32_HOST_OS
 469 foreign import ccall safe "Sleep" c_Sleep :: CInt -> IO ()
 470 #endif
 471
 472 foreign import ccall unsafe "rtsSupportsBoundThreads" threaded :: Bool
 473
 474 -- ----------------------------------------------------------------------------
 475 -- Threaded RTS implementation of threadWaitRead, threadWaitWrite, threadDelay
 476
 477 -- In the threaded RTS, we employ a single IO Manager thread to wait
 478 -- for all outstanding IO requests (threadWaitRead,threadWaitWrite)
 479 -- and delays (threadDelay).
 480 --
 481 -- We can do this because in the threaded RTS the IO Manager can make
 482 -- a non-blocking call to select(), so we don't have to do select() in
 483 -- the scheduler as we have to in the non-threaded RTS.  We get performance
 484 -- benefits from doing it this way, because we only have to restart the select()
 485 -- when a new request arrives, rather than doing one select() each time
 486 -- around the scheduler loop.  Furthermore, the scheduler can be simplified
 487 -- by not having to check for completed IO requests.
 488
 489 -- Issues, possible problems:
 490 --
 491 --      - we might want bound threads to just do the blocking
 492 --        operation rather than communicating with the IO manager
 493 --        thread.  This would prevent simgle-threaded programs which do
 494 --        IO from requiring multiple OS threads.  However, it would also
 495 --        prevent bound threads waiting on IO from being killed or sent
 496 --        exceptions.
 497 --
 498 --      - Apprently exec() doesn't work on Linux in a multithreaded program.
 499 --        I couldn't repeat this.
 500 --
 501 --      - How do we handle signal delivery in the multithreaded RTS?
 502 --
 503 --      - forkProcess will kill the IO manager thread.  Let's just
 504 --        hope we don't need to do any blocking IO between fork & exec.
 505
 506 #ifndef mingw32_HOST_OS
 507
 508 data IOReq
 509   = Read   {-# UNPACK #-} !Fd {-# UNPACK #-} !(MVar ())
 510   | Write  {-# UNPACK #-} !Fd {-# UNPACK #-} !(MVar ())
 511
 512 data DelayReq
 513   = Delay  {-# UNPACK #-} !Int {-# UNPACK #-} !(MVar ())
 514
 515 pendingEvents :: IORef [IOReq]
 516 pendingDelays :: IORef [DelayReq]
 517         -- could use a strict list or array here
 518 {-# NOINLINE pendingEvents #-}
 519 {-# NOINLINE pendingDelays #-}
 520 (pendingEvents,pendingDelays) = unsafePerformIO $ do
 521   startIOServiceThread
 522   reqs <- newIORef []
 523   dels <- newIORef []
 524   return (reqs, dels)
 525         -- the first time we schedule an IO request, the service thread
 526         -- will be created (cool, huh?)
 527
 528 startIOServiceThread :: IO ()
 529 startIOServiceThread = do
 530         allocaArray 2 $ \fds -> do
 531         throwErrnoIfMinus1 "startIOServiceThread" (c_pipe fds)
 532         rd_end <- peekElemOff fds 0
 533         wr_end <- peekElemOff fds 1
 534         writeIORef stick (fromIntegral wr_end)
 535         quickForkIO $ do
 536             allocaBytes sizeofFdSet   $ \readfds -> do
 537             allocaBytes sizeofFdSet   $ \writefds -> do
 538             allocaBytes sizeofTimeVal $ \timeval -> do
 539             service_loop (fromIntegral rd_end) readfds writefds timeval [] []
 540         return ()
 541
 542 -- XXX: move real forkIO here from Control.Concurrent?
 543 quickForkIO action = IO $ \s ->
 544    case (fork# action s) of (# s1, id #) -> (# s1, ThreadId id #)
 545
 546 service_loop
 547    :: Fd                -- listen to this for wakeup calls
 548    -> Ptr CFdSet
 549    -> Ptr CFdSet
 550    -> Ptr CTimeVal
 551    -> [IOReq]
 552    -> [DelayReq]
 553    -> IO ()
 554 service_loop wakeup readfds writefds ptimeval old_reqs old_delays = do
 555
 556   -- pick up new IO requests
 557   new_reqs <- atomicModifyIORef pendingEvents (\a -> ([],a))
 558   let reqs = new_reqs ++ old_reqs
 559
 560   -- pick up new delay requests
 561   new_delays <- atomicModifyIORef pendingDelays (\a -> ([],a))
 562   let  delays = foldr insertDelay old_delays new_delays
 563
 564   -- build the FDSets for select()
 565   fdZero readfds
 566   fdZero writefds
 567   fdSet wakeup readfds
 568   maxfd <- buildFdSets 0 readfds writefds reqs
 569
 570   -- check the current time and wake up any thread in threadDelay whose
 571   -- timeout has expired.  Also find the timeout value for the select() call.
 572   now <- getTicksOfDay
 573   (delays', timeout) <- getDelay now ptimeval delays
 574
 575   -- perform the select()
 576   let do_select = do
 577           res <- c_select ((max wakeup maxfd)+1) readfds writefds
 578                         nullPtr timeout
 579           if (res == -1)
 580              then do
 581                 err <- getErrno
 582                 if err == eINTR
 583                         then do_select
 584                         else return res
 585              else
 586                 return res
 587   res <- do_select
 588   -- ToDo: check result
 589
 590   b <- takeMVar prodding
 591   if b then alloca $ \p -> do c_read (fromIntegral wakeup) p 1; return ()
 592        else return ()
 593   putMVar prodding False
 594
 595   reqs' <- completeRequests reqs readfds writefds []
 596   service_loop wakeup readfds writefds ptimeval reqs' delays'
 597
 598 stick :: IORef Fd
 599 {-# NOINLINE stick #-}
 600 stick = unsafePerformIO (newIORef 0)
 601
 602 prodding :: MVar Bool
 603 {-# NOINLINE prodding #-}
 604 prodding = unsafePerformIO (newMVar False)
 605
 606 prodServiceThread :: IO ()
 607 prodServiceThread = do
 608   b <- takeMVar prodding
 609   if (not b)
 610     then do fd <- readIORef stick
 611             with 42 $ \pbuf -> do c_write (fromIntegral fd) pbuf 1; return ()
 612     else return ()
 613   putMVar prodding True
 614
 615 -- -----------------------------------------------------------------------------
 616 -- IO requests
 617
 618 buildFdSets maxfd readfds writefds [] = return maxfd
 619 buildFdSets maxfd readfds writefds (Read fd m : reqs) = do
 620   fdSet fd readfds
 621   buildFdSets (max maxfd fd) readfds writefds reqs
 622 buildFdSets maxfd readfds writefds (Write fd m : reqs) = do
 623   fdSet fd writefds
 624   buildFdSets (max maxfd fd) readfds writefds reqs
 625
 626 completeRequests [] _ _ reqs' = return reqs'
 627 completeRequests (Read fd m : reqs) readfds writefds reqs' = do
 628   b <- fdIsSet fd readfds
 629   if b /= 0
 630     then do putMVar m (); completeRequests reqs readfds writefds reqs'
 631     else completeRequests reqs readfds writefds (Read fd m : reqs')
 632 completeRequests (Write fd m : reqs) readfds writefds reqs' = do
 633   b <- fdIsSet fd writefds
 634   if b /= 0
 635     then do putMVar m (); completeRequests reqs readfds writefds reqs'
 636     else completeRequests reqs readfds writefds (Write fd m : reqs')
 637
 638 waitForReadEvent :: Fd -> IO ()
 639 waitForReadEvent fd = do
 640   m <- newEmptyMVar
 641   atomicModifyIORef pendingEvents (\xs -> (Read fd m : xs, ()))
 642   prodServiceThread
 643   takeMVar m
 644
 645 waitForWriteEvent :: Fd -> IO ()
 646 waitForWriteEvent fd = do
 647   m <- newEmptyMVar
 648   atomicModifyIORef pendingEvents (\xs -> (Write fd m : xs, ()))
 649   prodServiceThread
 650   takeMVar m
 651
 652 -- XXX: move into GHC.IOBase from Data.IORef?
 653 atomicModifyIORef :: IORef a -> (a -> (a,b)) -> IO b
 654 atomicModifyIORef (IORef (STRef r#)) f = IO $ \s -> atomicModifyMutVar# r# f s
 655
 656 -- -----------------------------------------------------------------------------
 657 -- Delays
 658
 659 waitForDelayEvent :: Int -> IO ()
 660 waitForDelayEvent usecs = do
 661   m <- newEmptyMVar
 662   now <- getTicksOfDay
 663   let target = now + usecs `quot` tick_usecs
 664   atomicModifyIORef pendingDelays (\xs -> (Delay target m : xs, ()))
 665   prodServiceThread
 666   takeMVar m
 667
 668 -- Walk the queue of pending delays, waking up any that have passed
 669 -- and return the smallest delay to wait for.  The queue of pending
 670 -- delays is kept ordered.
 671 getDelay :: Ticks -> Ptr CTimeVal -> [DelayReq] -> IO ([DelayReq], Ptr CTimeVal)
 672 getDelay now ptimeval [] = return ([],nullPtr)
 673 getDelay now ptimeval all@(Delay time m : rest)
 674   | now >= time = do
 675         putMVar m ()
 676         getDelay now ptimeval rest
 677   | otherwise = do
 678         setTimevalTicks ptimeval (time - now)
 679         return (all,ptimeval)
 680
 681 insertDelay :: DelayReq -> [DelayReq] -> [DelayReq]
 682 insertDelay d@(Delay time m) [] = [d]
 683 insertDelay d1@(Delay time m) ds@(d2@(Delay time' m') : rest)
 684   | time <= time' = d1 : ds
 685   | otherwise     = d2 : insertDelay d1 rest
 686
 687 type Ticks = Int
 688 tick_freq  = 50 :: Ticks  -- accuracy of threadDelay (ticks per sec)
 689 tick_usecs = 1000000 `quot` tick_freq :: Int
 690
 691 newtype CTimeVal = CTimeVal ()
 692
 693 foreign import ccall unsafe "sizeofTimeVal"
 694   sizeofTimeVal :: Int
 695
 696 foreign import ccall unsafe "getTicksOfDay"
 697   getTicksOfDay :: IO Ticks
 698
 699 foreign import ccall unsafe "setTimevalTicks"
 700   setTimevalTicks :: Ptr CTimeVal -> Ticks -> IO ()
 701
 702 -- ----------------------------------------------------------------------------
 703 -- select() interface
 704
 705 -- ToDo: move to System.Posix.Internals?
 706
 707 newtype CFdSet = CFdSet ()
 708
 709 foreign import ccall safe "select"
 710   c_select :: Fd -> Ptr CFdSet -> Ptr CFdSet -> Ptr CFdSet -> Ptr CTimeVal
 711            -> IO CInt
 712
 713 foreign import ccall unsafe "hsFD_CLR"
 714   fdClr :: Fd -> Ptr CFdSet -> IO ()
 715
 716 foreign import ccall unsafe "hsFD_ISSET"
 717   fdIsSet :: Fd -> Ptr CFdSet -> IO CInt
 718
 719 foreign import ccall unsafe "hsFD_SET"
 720   fdSet :: Fd -> Ptr CFdSet -> IO ()
 721
 722 foreign import ccall unsafe "hsFD_ZERO"
 723   fdZero :: Ptr CFdSet -> IO ()
 724
 725 foreign import ccall unsafe "sizeof_fd_set"
 726   sizeofFdSet :: Int
 727
 728 #endif
 729 \end{code}