GHC/Handle.hs

   1 {-# OPTIONS_GHC -fno-implicit-prelude -#include "HsBase.h" #-}
   2
   3 #undef DEBUG_DUMP
   4 #undef DEBUG
   5
   6 -----------------------------------------------------------------------------
   7 -- |
   8 -- Module      :  GHC.Handle
   9 -- Copyright   :  (c) The University of Glasgow, 1994-2001
  10 -- License     :  see libraries/base/LICENSE
  11 --
  12 -- Maintainer  :  libraries@haskell.org
  13 -- Stability   :  internal
  14 -- Portability :  non-portable
  15 --
  16 -- This module defines the basic operations on I\/O \"handles\".
  17 --
  18 -----------------------------------------------------------------------------
  19
  20 -- #hide
  21 module GHC.Handle (
  22   withHandle, withHandle', withHandle_,
  23   wantWritableHandle, wantReadableHandle, wantSeekableHandle,
  24
  25   newEmptyBuffer, allocateBuffer, readCharFromBuffer, writeCharIntoBuffer,
  26   flushWriteBufferOnly, flushWriteBuffer, flushReadBuffer,
  27   fillReadBuffer, fillReadBufferWithoutBlocking,
  28   readRawBuffer, readRawBufferPtr,
  29   writeRawBuffer, writeRawBufferPtr,
  30
  31 #ifndef mingw32_HOST_OS
  32   unlockFile,
  33 #endif
  34
  35   ioe_closedHandle, ioe_EOF, ioe_notReadable, ioe_notWritable,
  36
  37   stdin, stdout, stderr,
  38   IOMode(..), openFile, openBinaryFile, openTempFile, openBinaryTempFile, fdToHandle', fdToHandle,
  39   hFileSize, hSetFileSize, hIsEOF, isEOF, hLookAhead, hSetBuffering, hSetBinaryMode,
  40   hFlush, hDuplicate, hDuplicateTo,
  41
  42   hClose, hClose_help,
  43
  44   HandlePosition, HandlePosn(..), hGetPosn, hSetPosn,
  45   SeekMode(..), hSeek, hTell,
  46
  47   hIsOpen, hIsClosed, hIsReadable, hIsWritable, hGetBuffering, hIsSeekable,
  48   hSetEcho, hGetEcho, hIsTerminalDevice,
  49
  50   hShow,
  51
  52 #ifdef DEBUG_DUMP
  53   puts,
  54 #endif
  55
  56  ) where
  57
  58 import Control.Monad
  59 import Data.Bits
  60 import Data.Maybe
  61 import Foreign
  62 import Foreign.C
  63 import System.IO.Error
  64 import System.Posix.Internals
  65
  66 import GHC.Real
  67
  68 import GHC.Arr
  69 import GHC.Base
  70 import GHC.Read         ( Read )
  71 import GHC.List
  72 import GHC.IOBase
  73 import GHC.Exception
  74 import GHC.Enum
  75 import GHC.Num          ( Integer(..), Num(..) )
  76 import GHC.Show
  77 import GHC.Real         ( toInteger )
  78 #if defined(DEBUG_DUMP)
  79 import GHC.Pack
  80 #endif
  81
  82 import GHC.Conc
  83
  84 -- -----------------------------------------------------------------------------
  85 -- TODO:
  86
  87 -- hWaitForInput blocks (should use a timeout)
  88
  89 -- unbuffered hGetLine is a bit dodgy
  90
  91 -- hSetBuffering: can't change buffering on a stream,
  92 --      when the read buffer is non-empty? (no way to flush the buffer)
  93
  94 -- ---------------------------------------------------------------------------
  95 -- Are files opened by default in text or binary mode, if the user doesn't
  96 -- specify?
  97
  98 dEFAULT_OPEN_IN_BINARY_MODE = False :: Bool
  99
 100 -- ---------------------------------------------------------------------------
 101 -- Creating a new handle
 102
 103 newFileHandle :: FilePath -> (MVar Handle__ -> IO ()) -> Handle__ -> IO Handle
 104 newFileHandle filepath finalizer hc = do
 105   m <- newMVar hc
 106   addMVarFinalizer m (finalizer m)
 107   return (FileHandle filepath m)
 108
 109 -- ---------------------------------------------------------------------------
 110 -- Working with Handles
 111
 112 {-
 113 In the concurrent world, handles are locked during use.  This is done
 114 by wrapping an MVar around the handle which acts as a mutex over
 115 operations on the handle.
 116
 117 To avoid races, we use the following bracketing operations.  The idea
 118 is to obtain the lock, do some operation and replace the lock again,
 119 whether the operation succeeded or failed.  We also want to handle the
 120 case where the thread receives an exception while processing the IO
 121 operation: in these cases we also want to relinquish the lock.
 122
 123 There are three versions of @withHandle@: corresponding to the three
 124 possible combinations of:
 125
 126         - the operation may side-effect the handle
 127         - the operation may return a result
 128
 129 If the operation generates an error or an exception is raised, the
 130 original handle is always replaced [ this is the case at the moment,
 131 but we might want to revisit this in the future --SDM ].
 132 -}
 133
 134 {-# INLINE withHandle #-}
 135 withHandle :: String -> Handle -> (Handle__ -> IO (Handle__,a)) -> IO a
 136 withHandle fun h@(FileHandle _ m)     act = withHandle' fun h m act
 137 withHandle fun h@(DuplexHandle _ m _) act = withHandle' fun h m act
 138
 139 withHandle' :: String -> Handle -> MVar Handle__
 140    -> (Handle__ -> IO (Handle__,a)) -> IO a
 141 withHandle' fun h m act =
 142    block $ do
 143    h_ <- takeMVar m
 144    checkBufferInvariants h_
 145    (h',v)  <- catchException (act h_)
 146                 (\ err -> putMVar m h_ >>
 147                           case err of
 148                              IOException ex -> ioError (augmentIOError ex fun h)
 149                              _ -> throw err)
 150    checkBufferInvariants h'
 151    putMVar m h'
 152    return v
 153
 154 {-# INLINE withHandle_ #-}
 155 withHandle_ :: String -> Handle -> (Handle__ -> IO a) -> IO a
 156 withHandle_ fun h@(FileHandle _ m)     act = withHandle_' fun h m act
 157 withHandle_ fun h@(DuplexHandle _ m _) act = withHandle_' fun h m act
 158
 159 withHandle_' :: String -> Handle -> MVar Handle__ -> (Handle__ -> IO a) -> IO a
 160 withHandle_' fun h m act =
 161    block $ do
 162    h_ <- takeMVar m
 163    checkBufferInvariants h_
 164    v  <- catchException (act h_)
 165                 (\ err -> putMVar m h_ >>
 166                           case err of
 167                              IOException ex -> ioError (augmentIOError ex fun h)
 168                              _ -> throw err)
 169    checkBufferInvariants h_
 170    putMVar m h_
 171    return v
 172
 173 withAllHandles__ :: String -> Handle -> (Handle__ -> IO Handle__) -> IO ()
 174 withAllHandles__ fun h@(FileHandle _ m)     act = withHandle__' fun h m act
 175 withAllHandles__ fun h@(DuplexHandle _ r w) act = do
 176   withHandle__' fun h r act
 177   withHandle__' fun h w act
 178
 179 withHandle__' fun h m act =
 180    block $ do
 181    h_ <- takeMVar m
 182    checkBufferInvariants h_
 183    h'  <- catchException (act h_)
 184                 (\ err -> putMVar m h_ >>
 185                           case err of
 186                              IOException ex -> ioError (augmentIOError ex fun h)
 187                              _ -> throw err)
 188    checkBufferInvariants h'
 189    putMVar m h'
 190    return ()
 191
 192 augmentIOError (IOError _ iot _ str fp) fun h
 193   = IOError (Just h) iot fun str filepath
 194   where filepath
 195           | Just _ <- fp = fp
 196           | otherwise = case h of
 197                           FileHandle fp _     -> Just fp
 198                           DuplexHandle fp _ _ -> Just fp
 199
 200 -- ---------------------------------------------------------------------------
 201 -- Wrapper for write operations.
 202
 203 wantWritableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 204 wantWritableHandle fun h@(FileHandle _ m) act
 205   = wantWritableHandle' fun h m act
 206 wantWritableHandle fun h@(DuplexHandle _ _ m) act
 207   = wantWritableHandle' fun h m act
 208   -- ToDo: in the Duplex case, we don't need to checkWritableHandle
 209
 210 wantWritableHandle'
 211         :: String -> Handle -> MVar Handle__
 212         -> (Handle__ -> IO a) -> IO a
 213 wantWritableHandle' fun h m act
 214    = withHandle_' fun h m (checkWritableHandle act)
 215
 216 checkWritableHandle act handle_
 217   = case haType handle_ of
 218       ClosedHandle         -> ioe_closedHandle
 219       SemiClosedHandle     -> ioe_closedHandle
 220       ReadHandle           -> ioe_notWritable
 221       ReadWriteHandle      -> do
 222                 let ref = haBuffer handle_
 223                 buf <- readIORef ref
 224                 new_buf <-
 225                   if not (bufferIsWritable buf)
 226                      then do b <- flushReadBuffer (haFD handle_) buf
 227                              return b{ bufState=WriteBuffer }
 228                      else return buf
 229                 writeIORef ref new_buf
 230                 act handle_
 231       _other               -> act handle_
 232
 233 -- ---------------------------------------------------------------------------
 234 -- Wrapper for read operations.
 235
 236 wantReadableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 237 wantReadableHandle fun h@(FileHandle  _ m)   act
 238   = wantReadableHandle' fun h m act
 239 wantReadableHandle fun h@(DuplexHandle _ m _) act
 240   = wantReadableHandle' fun h m act
 241   -- ToDo: in the Duplex case, we don't need to checkReadableHandle
 242
 243 wantReadableHandle'
 244         :: String -> Handle -> MVar Handle__
 245         -> (Handle__ -> IO a) -> IO a
 246 wantReadableHandle' fun h m act
 247   = withHandle_' fun h m (checkReadableHandle act)
 248
 249 checkReadableHandle act handle_ =
 250     case haType handle_ of
 251       ClosedHandle         -> ioe_closedHandle
 252       SemiClosedHandle     -> ioe_closedHandle
 253       AppendHandle         -> ioe_notReadable
 254       WriteHandle          -> ioe_notReadable
 255       ReadWriteHandle      -> do
 256         let ref = haBuffer handle_
 257         buf <- readIORef ref
 258         when (bufferIsWritable buf) $ do
 259            new_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
 260            writeIORef ref new_buf{ bufState=ReadBuffer }
 261         act handle_
 262       _other               -> act handle_
 263
 264 -- ---------------------------------------------------------------------------
 265 -- Wrapper for seek operations.
 266
 267 wantSeekableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 268 wantSeekableHandle fun h@(DuplexHandle _ _ _) _act =
 269   ioException (IOError (Just h) IllegalOperation fun
 270                    "handle is not seekable" Nothing)
 271 wantSeekableHandle fun h@(FileHandle _ m) act =
 272   withHandle_' fun h m (checkSeekableHandle act)
 273
 274 checkSeekableHandle act handle_ =
 275     case haType handle_ of
 276       ClosedHandle      -> ioe_closedHandle
 277       SemiClosedHandle  -> ioe_closedHandle
 278       AppendHandle      -> ioe_notSeekable
 279       _  | haIsBin handle_ || tEXT_MODE_SEEK_ALLOWED -> act handle_
 280          | otherwise                                 -> ioe_notSeekable_notBin
 281
 282 -- -----------------------------------------------------------------------------
 283 -- Handy IOErrors
 284
 285 ioe_closedHandle, ioe_EOF,
 286   ioe_notReadable, ioe_notWritable,
 287   ioe_notSeekable, ioe_notSeekable_notBin :: IO a
 288
 289 ioe_closedHandle = ioException
 290    (IOError Nothing IllegalOperation ""
 291         "handle is closed" Nothing)
 292 ioe_EOF = ioException
 293    (IOError Nothing EOF "" "" Nothing)
 294 ioe_notReadable = ioException
 295    (IOError Nothing IllegalOperation ""
 296         "handle is not open for reading" Nothing)
 297 ioe_notWritable = ioException
 298    (IOError Nothing IllegalOperation ""
 299         "handle is not open for writing" Nothing)
 300 ioe_notSeekable = ioException
 301    (IOError Nothing IllegalOperation ""
 302         "handle is not seekable" Nothing)
 303 ioe_notSeekable_notBin = ioException
 304    (IOError Nothing IllegalOperation ""
 305       "seek operations on text-mode handles are not allowed on this platform"
 306         Nothing)
 307
 308 ioe_finalizedHandle fp = throw (IOException
 309    (IOError Nothing IllegalOperation ""
 310         "handle is finalized" (Just fp)))
 311
 312 ioe_bufsiz :: Int -> IO a
 313 ioe_bufsiz n = ioException
 314    (IOError Nothing InvalidArgument "hSetBuffering"
 315         ("illegal buffer size " ++ showsPrec 9 n []) Nothing)
 316                                 -- 9 => should be parens'ified.
 317
 318 -- -----------------------------------------------------------------------------
 319 -- Handle Finalizers
 320
 321 -- For a duplex handle, we arrange that the read side points to the write side
 322 -- (and hence keeps it alive if the read side is alive).  This is done by
 323 -- having the haOtherSide field of the read side point to the read side.
 324 -- The finalizer is then placed on the write side, and the handle only gets
 325 -- finalized once, when both sides are no longer required.
 326
 327 -- NOTE about finalized handles: It's possible that a handle can be
 328 -- finalized and then we try to use it later, for example if the
 329 -- handle is referenced from another finalizer, or from a thread that
 330 -- has become unreferenced and then resurrected (arguably in the
 331 -- latter case we shouldn't finalize the Handle...).  Anyway,
 332 -- we try to emit a helpful message which is better than nothing.
 333
 334 stdHandleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 335 stdHandleFinalizer fp m = do
 336   h_ <- takeMVar m
 337   flushWriteBufferOnly h_
 338   putMVar m (ioe_finalizedHandle fp)
 339
 340 handleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 341 handleFinalizer fp m = do
 342   handle_ <- takeMVar m
 343   case haType handle_ of
 344       ClosedHandle -> return ()
 345       _ -> do flushWriteBufferOnly handle_ `catchException` \_ -> return ()
 346                 -- ignore errors and async exceptions, and close the
 347                 -- descriptor anyway...
 348               hClose_handle_ handle_
 349               return ()
 350   putMVar m (ioe_finalizedHandle fp)
 351
 352 -- ---------------------------------------------------------------------------
 353 -- Grimy buffer operations
 354
 355 #ifdef DEBUG
 356 checkBufferInvariants h_ = do
 357  let ref = haBuffer h_
 358  Buffer{ bufWPtr=w, bufRPtr=r, bufSize=size, bufState=state } <- readIORef ref
 359  if not (
 360         size > 0
 361         && r <= w
 362         && w <= size
 363         && ( r /= w || (r == 0 && w == 0) )
 364         && ( state /= WriteBuffer || r == 0 )
 365         && ( state /= WriteBuffer || w < size ) -- write buffer is never full
 366      )
 367    then error "buffer invariant violation"
 368    else return ()
 369 #else
 370 checkBufferInvariants h_ = return ()
 371 #endif
 372
 373 newEmptyBuffer :: RawBuffer -> BufferState -> Int -> Buffer
 374 newEmptyBuffer b state size
 375   = Buffer{ bufBuf=b, bufRPtr=0, bufWPtr=0, bufSize=size, bufState=state }
 376
 377 allocateBuffer :: Int -> BufferState -> IO Buffer
 378 allocateBuffer sz@(I# size) state = IO $ \s ->
 379 #ifdef mingw32_HOST_OS
 380    -- To implement asynchronous I/O under Win32, we have to pass
 381    -- buffer references to external threads that handles the
 382    -- filling/emptying of their contents. Hence, the buffer cannot
 383    -- be moved around by the GC.
 384   case newPinnedByteArray# size s of { (# s, b #) ->
 385 #else
 386   case newByteArray# size s of { (# s, b #) ->
 387 #endif
 388   (# s, newEmptyBuffer b state sz #) }
 389
 390 writeCharIntoBuffer :: RawBuffer -> Int -> Char -> IO Int
 391 writeCharIntoBuffer slab (I# off) (C# c)
 392   = IO $ \s -> case writeCharArray# slab off c s of
 393                  s -> (# s, I# (off +# 1#) #)
 394
 395 readCharFromBuffer :: RawBuffer -> Int -> IO (Char, Int)
 396 readCharFromBuffer slab (I# off)
 397   = IO $ \s -> case readCharArray# slab off s of
 398                  (# s, c #) -> (# s, (C# c, I# (off +# 1#)) #)
 399
 400 getBuffer :: FD -> BufferState -> IO (IORef Buffer, BufferMode)
 401 getBuffer fd state = do
 402   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE state
 403   ioref  <- newIORef buffer
 404   is_tty <- fdIsTTY fd
 405
 406   let buffer_mode
 407          | is_tty    = LineBuffering
 408          | otherwise = BlockBuffering Nothing
 409
 410   return (ioref, buffer_mode)
 411
 412 mkUnBuffer :: IO (IORef Buffer)
 413 mkUnBuffer = do
 414   buffer <- allocateBuffer 1 ReadBuffer
 415   newIORef buffer
 416
 417 -- flushWriteBufferOnly flushes the buffer iff it contains pending write data.
 418 flushWriteBufferOnly :: Handle__ -> IO ()
 419 flushWriteBufferOnly h_ = do
 420   let fd = haFD h_
 421       ref = haBuffer h_
 422   buf <- readIORef ref
 423   new_buf <- if bufferIsWritable buf
 424                 then flushWriteBuffer fd (haIsStream h_) buf
 425                 else return buf
 426   writeIORef ref new_buf
 427
 428 -- flushBuffer syncs the file with the buffer, including moving the
 429 -- file pointer backwards in the case of a read buffer.
 430 flushBuffer :: Handle__ -> IO ()
 431 flushBuffer h_ = do
 432   let ref = haBuffer h_
 433   buf <- readIORef ref
 434
 435   flushed_buf <-
 436     case bufState buf of
 437       ReadBuffer  -> flushReadBuffer  (haFD h_) buf
 438       WriteBuffer -> flushWriteBuffer (haFD h_) (haIsStream h_) buf
 439
 440   writeIORef ref flushed_buf
 441
 442 -- When flushing a read buffer, we seek backwards by the number of
 443 -- characters in the buffer.  The file descriptor must therefore be
 444 -- seekable: attempting to flush the read buffer on an unseekable
 445 -- handle is not allowed.
 446
 447 flushReadBuffer :: FD -> Buffer -> IO Buffer
 448 flushReadBuffer fd buf
 449   | bufferEmpty buf = return buf
 450   | otherwise = do
 451      let off = negate (bufWPtr buf - bufRPtr buf)
 452 #    ifdef DEBUG_DUMP
 453      puts ("flushReadBuffer: new file offset = " ++ show off ++ "\n")
 454 #    endif
 455      throwErrnoIfMinus1Retry "flushReadBuffer"
 456          (c_lseek fd (fromIntegral off) sEEK_CUR)
 457      return buf{ bufWPtr=0, bufRPtr=0 }
 458
 459 flushWriteBuffer :: FD -> Bool -> Buffer -> IO Buffer
 460 flushWriteBuffer fd is_stream buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w }  =
 461   seq fd $ do -- strictness hack
 462   let bytes = w - r
 463 #ifdef DEBUG_DUMP
 464   puts ("flushWriteBuffer, fd=" ++ show fd ++ ", bytes=" ++ show bytes ++ "\n")
 465 #endif
 466   if bytes == 0
 467      then return (buf{ bufRPtr=0, bufWPtr=0 })
 468      else do
 469   res <- writeRawBuffer "flushWriteBuffer" fd is_stream b
 470                         (fromIntegral r) (fromIntegral bytes)
 471   let res' = fromIntegral res
 472   if res' < bytes
 473      then flushWriteBuffer fd is_stream (buf{ bufRPtr = r + res' })
 474      else return buf{ bufRPtr=0, bufWPtr=0 }
 475
 476 fillReadBuffer :: FD -> Bool -> Bool -> Buffer -> IO Buffer
 477 fillReadBuffer fd is_line is_stream
 478       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 479   -- buffer better be empty:
 480   assert (r == 0 && w == 0) $ do
 481   fillReadBufferLoop fd is_line is_stream buf b w size
 482
 483 -- For a line buffer, we just get the first chunk of data to arrive,
 484 -- and don't wait for the whole buffer to be full (but we *do* wait
 485 -- until some data arrives).  This isn't really line buffering, but it
 486 -- appears to be what GHC has done for a long time, and I suspect it
 487 -- is more useful than line buffering in most cases.
 488
 489 fillReadBufferLoop fd is_line is_stream buf b w size = do
 490   let bytes = size - w
 491   if bytes == 0  -- buffer full?
 492      then return buf{ bufRPtr=0, bufWPtr=w }
 493      else do
 494 #ifdef DEBUG_DUMP
 495   puts ("fillReadBufferLoop: bytes = " ++ show bytes ++ "\n")
 496 #endif
 497   res <- readRawBuffer "fillReadBuffer" fd is_stream b
 498                        (fromIntegral w) (fromIntegral bytes)
 499   let res' = fromIntegral res
 500 #ifdef DEBUG_DUMP
 501   puts ("fillReadBufferLoop:  res' = " ++ show res' ++ "\n")
 502 #endif
 503   if res' == 0
 504      then if w == 0
 505              then ioe_EOF
 506              else return buf{ bufRPtr=0, bufWPtr=w }
 507      else if res' < bytes && not is_line
 508              then fillReadBufferLoop fd is_line is_stream buf b (w+res') size
 509              else return buf{ bufRPtr=0, bufWPtr=w+res' }
 510
 511
 512 fillReadBufferWithoutBlocking :: FD -> Bool -> Buffer -> IO Buffer
 513 fillReadBufferWithoutBlocking fd is_stream
 514       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 515   -- buffer better be empty:
 516   assert (r == 0 && w == 0) $ do
 517 #ifdef DEBUG_DUMP
 518   puts ("fillReadBufferLoopNoBlock: bytes = " ++ show size ++ "\n")
 519 #endif
 520   res <- readRawBufferNoBlock "fillReadBuffer" fd is_stream b
 521                        0 (fromIntegral size)
 522   let res' = fromIntegral res
 523 #ifdef DEBUG_DUMP
 524   puts ("fillReadBufferLoopNoBlock:  res' = " ++ show res' ++ "\n")
 525 #endif
 526   return buf{ bufRPtr=0, bufWPtr=res' }
 527
 528 -- Low level routines for reading/writing to (raw)buffers:
 529
 530 #ifndef mingw32_HOST_OS
 531
 532 {-
 533 NOTE [nonblock]:
 534
 535 Unix has broken semantics when it comes to non-blocking I/O: you can
 536 set the O_NONBLOCK flag on an FD, but it applies to the all other FDs
 537 attached to the same underlying file, pipe or TTY; there's no way to
 538 have private non-blocking behaviour for an FD.  See bug #724.
 539
 540 We fix this by only setting O_NONBLOCK on FDs that we create; FDs that
 541 come from external sources or are exposed externally are left in
 542 blocking mode.  This solution has some problems though.  We can't
 543 completely simulate a non-blocking read without O_NONBLOCK: several
 544 cases are wrong here.  The cases that are wrong:
 545
 546   * reading/writing to a blocking FD in non-threaded mode.
 547     In threaded mode, we just make a safe call to read().
 548     In non-threaded mode we call select() before attempting to read,
 549     but that leaves a small race window where the data can be read
 550     from the file descriptor before we issue our blocking read().
 551   * readRawBufferNoBlock for a blocking FD
 552 -}
 553
 554 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 555 readRawBuffer loc fd is_nonblock buf off len
 556   | is_nonblock  = unsafe_read
 557   | threaded     = safe_read
 558   | otherwise    = do r <- throwErrnoIfMinus1 loc
 559                                 (fdReady (fromIntegral fd) 0 0 False)
 560                       if r /= 0
 561                         then unsafe_read
 562                         else do threadWaitRead (fromIntegral fd); unsafe_read
 563   where
 564     do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 565                             (threadWaitRead (fromIntegral fd))
 566     unsafe_read = do_read (read_rawBuffer fd buf off len)
 567     safe_read   = do_read (safe_read_rawBuffer fd buf off len)
 568
 569 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 570 readRawBufferPtr loc fd is_nonblock buf off len
 571   | is_nonblock  = unsafe_read
 572   | threaded     = safe_read
 573   | otherwise    = do r <- throwErrnoIfMinus1 loc
 574                                 (fdReady (fromIntegral fd) 0 0 False)
 575                       if r /= 0
 576                         then unsafe_read
 577                         else do threadWaitRead (fromIntegral fd); unsafe_read
 578   where
 579         do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 580                                 (threadWaitRead (fromIntegral fd))
 581         unsafe_read = do_read (read_off fd buf off len)
 582         safe_read   = do_read (safe_read_off fd buf off len)
 583
 584 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 585 readRawBufferNoBlock loc fd is_nonblock buf off len
 586   | is_nonblock  = unsafe_read
 587   | otherwise    = do r <- fdReady (fromIntegral fd) 0 0 False
 588                       if r /= 0 then safe_read
 589                                 else return 0
 590        -- XXX see note [nonblock]
 591  where
 592    do_read call = throwErrnoIfMinus1RetryOnBlock loc call (return 0)
 593    unsafe_read  = do_read (read_rawBuffer fd buf off len)
 594    safe_read    = do_read (safe_read_rawBuffer fd buf off len)
 595
 596 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 597 writeRawBuffer loc fd is_nonblock buf off len
 598   | is_nonblock = unsafe_write
 599   | threaded    = safe_write
 600   | otherwise   = do r <- fdReady (fromIntegral fd) 1 0 False
 601                      if r /= 0
 602                         then safe_write
 603                         else do threadWaitWrite (fromIntegral fd); unsafe_write
 604   where
 605     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 606                         (threadWaitWrite (fromIntegral fd))
 607     unsafe_write = do_write (write_rawBuffer fd buf off len)
 608     safe_write   = do_write (safe_write_rawBuffer (fromIntegral fd) buf off len)
 609
 610 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 611 writeRawBufferPtr loc fd is_nonblock buf off len
 612   | is_nonblock = unsafe_write
 613   | threaded    = safe_write
 614   | otherwise   = do r <- fdReady (fromIntegral fd) 1 0 False
 615                      if r /= 0
 616                         then safe_write
 617                         else do threadWaitWrite (fromIntegral fd); unsafe_write
 618   where
 619     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 620                         (threadWaitWrite (fromIntegral fd))
 621     unsafe_write  = do_write (write_off fd buf off len)
 622     safe_write    = do_write (safe_write_off (fromIntegral fd) buf off len)
 623
 624 foreign import ccall unsafe "__hscore_PrelHandle_read"
 625    read_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 626
 627 foreign import ccall unsafe "__hscore_PrelHandle_read"
 628    read_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 629
 630 foreign import ccall unsafe "__hscore_PrelHandle_write"
 631    write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 632
 633 foreign import ccall unsafe "__hscore_PrelHandle_write"
 634    write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 635
 636 foreign import ccall safe "fdReady"
 637   fdReady :: CInt -> CInt -> CInt -> Bool -> IO CInt
 638
 639 #else /* mingw32_HOST_OS.... */
 640
 641 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 642 readRawBuffer loc fd is_stream buf off len
 643   | threaded  = blockingReadRawBuffer loc fd is_stream buf off len
 644   | otherwise = asyncReadRawBuffer loc fd is_stream buf off len
 645
 646 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 647 readRawBufferPtr loc fd is_stream buf off len
 648   | threaded  = blockingReadRawBufferPtr loc fd is_stream buf off len
 649   | otherwise = asyncReadRawBufferPtr loc fd is_stream buf off len
 650
 651 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 652 writeRawBuffer loc fd is_stream buf off len
 653   | threaded =  blockingWriteRawBuffer loc fd is_stream buf off len
 654   | otherwise = asyncWriteRawBuffer    loc fd is_stream buf off len
 655
 656 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 657 writeRawBufferPtr loc fd is_stream buf off len
 658   | threaded  = blockingWriteRawBufferPtr loc fd is_stream buf off len
 659   | otherwise = asyncWriteRawBufferPtr    loc fd is_stream buf off len
 660
 661 -- ToDo: we don't have a non-blocking primitve read on Win32
 662 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 663 readRawBufferNoBlock = readRawBuffer
 664
 665 -- Async versions of the read/write primitives, for the non-threaded RTS
 666
 667 asyncReadRawBuffer loc fd is_stream buf off len = do
 668     (l, rc) <- asyncReadBA (fromIntegral fd) (if is_stream then 1 else 0)
 669                  (fromIntegral len) off buf
 670     if l == (-1)
 671       then
 672         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 673       else return (fromIntegral l)
 674
 675 asyncReadRawBufferPtr loc fd is_stream buf off len = do
 676     (l, rc) <- asyncRead (fromIntegral fd) (if is_stream then 1 else 0)
 677                         (fromIntegral len) (buf `plusPtr` off)
 678     if l == (-1)
 679       then
 680         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 681       else return (fromIntegral l)
 682
 683 asyncWriteRawBuffer loc fd is_stream buf off len = do
 684     (l, rc) <- asyncWriteBA (fromIntegral fd) (if is_stream then 1 else 0)
 685                         (fromIntegral len) off buf
 686     if l == (-1)
 687       then
 688         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 689       else return (fromIntegral l)
 690
 691 asyncWriteRawBufferPtr loc fd is_stream buf off len = do
 692     (l, rc) <- asyncWrite (fromIntegral fd) (if is_stream then 1 else 0)
 693                   (fromIntegral len) (buf `plusPtr` off)
 694     if l == (-1)
 695       then
 696         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 697       else return (fromIntegral l)
 698
 699 -- Blocking versions of the read/write primitives, for the threaded RTS
 700
 701 blockingReadRawBuffer loc fd True buf off len =
 702   throwErrnoIfMinus1Retry loc $
 703     safe_recv_rawBuffer fd buf off len
 704 blockingReadRawBuffer loc fd False buf off len =
 705   throwErrnoIfMinus1Retry loc $
 706     safe_read_rawBuffer fd buf off len
 707
 708 blockingReadRawBufferPtr loc fd True buf off len =
 709   throwErrnoIfMinus1Retry loc $
 710     safe_recv_off fd buf off len
 711 blockingReadRawBufferPtr loc fd False buf off len =
 712   throwErrnoIfMinus1Retry loc $
 713     safe_read_off fd buf off len
 714
 715 blockingWriteRawBuffer loc fd True buf off len =
 716   throwErrnoIfMinus1Retry loc $
 717     safe_send_rawBuffer fd buf off len
 718 blockingWriteRawBuffer loc fd False buf off len =
 719   throwErrnoIfMinus1Retry loc $
 720     safe_write_rawBuffer fd buf off len
 721
 722 blockingWriteRawBufferPtr loc fd True buf off len =
 723   throwErrnoIfMinus1Retry loc $
 724     safe_send_off fd buf off len
 725 blockingWriteRawBufferPtr loc fd False buf off len =
 726   throwErrnoIfMinus1Retry loc $
 727     safe_write_off fd buf off len
 728
 729 -- NOTE: "safe" versions of the read/write calls for use by the threaded RTS.
 730 -- These calls may block, but that's ok.
 731
 732 foreign import ccall safe "__hscore_PrelHandle_recv"
 733    safe_recv_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 734
 735 foreign import ccall safe "__hscore_PrelHandle_recv"
 736    safe_recv_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 737
 738 foreign import ccall safe "__hscore_PrelHandle_send"
 739    safe_send_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 740
 741 foreign import ccall safe "__hscore_PrelHandle_send"
 742    safe_send_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 743
 744 #endif
 745
 746 foreign import ccall "rtsSupportsBoundThreads" threaded :: Bool
 747
 748 foreign import ccall safe "__hscore_PrelHandle_read"
 749    safe_read_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 750
 751 foreign import ccall safe "__hscore_PrelHandle_read"
 752    safe_read_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 753
 754 foreign import ccall safe "__hscore_PrelHandle_write"
 755    safe_write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 756
 757 foreign import ccall safe "__hscore_PrelHandle_write"
 758    safe_write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 759
 760 -- ---------------------------------------------------------------------------
 761 -- Standard Handles
 762
 763 -- Three handles are allocated during program initialisation.  The first
 764 -- two manage input or output from the Haskell program's standard input
 765 -- or output channel respectively.  The third manages output to the
 766 -- standard error channel. These handles are initially open.
 767
 768 fd_stdin  = 0 :: FD
 769 fd_stdout = 1 :: FD
 770 fd_stderr = 2 :: FD
 771
 772 -- | A handle managing input from the Haskell program's standard input channel.
 773 stdin :: Handle
 774 stdin = unsafePerformIO $ do
 775    -- ToDo: acquire lock
 776    -- We don't set non-blocking mode on standard handles, because it may
 777    -- confuse other applications attached to the same TTY/pipe
 778    -- see Note [nonblock]
 779    (buf, bmode) <- getBuffer fd_stdin ReadBuffer
 780    mkStdHandle fd_stdin "<stdin>" ReadHandle buf bmode
 781
 782 -- | A handle managing output to the Haskell program's standard output channel.
 783 stdout :: Handle
 784 stdout = unsafePerformIO $ do
 785    -- ToDo: acquire lock
 786    -- We don't set non-blocking mode on standard handles, because it may
 787    -- confuse other applications attached to the same TTY/pipe
 788    -- see Note [nonblock]
 789    (buf, bmode) <- getBuffer fd_stdout WriteBuffer
 790    mkStdHandle fd_stdout "<stdout>" WriteHandle buf bmode
 791
 792 -- | A handle managing output to the Haskell program's standard error channel.
 793 stderr :: Handle
 794 stderr = unsafePerformIO $ do
 795     -- ToDo: acquire lock
 796    -- We don't set non-blocking mode on standard handles, because it may
 797    -- confuse other applications attached to the same TTY/pipe
 798    -- see Note [nonblock]
 799    buf <- mkUnBuffer
 800    mkStdHandle fd_stderr "<stderr>" WriteHandle buf NoBuffering
 801
 802 -- ---------------------------------------------------------------------------
 803 -- Opening and Closing Files
 804
 805 addFilePathToIOError fun fp (IOError h iot _ str _)
 806   = IOError h iot fun str (Just fp)
 807
 808 -- | Computation 'openFile' @file mode@ allocates and returns a new, open
 809 -- handle to manage the file @file@.  It manages input if @mode@
 810 -- is 'ReadMode', output if @mode@ is 'WriteMode' or 'AppendMode',
 811 -- and both input and output if mode is 'ReadWriteMode'.
 812 --
 813 -- If the file does not exist and it is opened for output, it should be
 814 -- created as a new file.  If @mode@ is 'WriteMode' and the file
 815 -- already exists, then it should be truncated to zero length.
 816 -- Some operating systems delete empty files, so there is no guarantee
 817 -- that the file will exist following an 'openFile' with @mode@
 818 -- 'WriteMode' unless it is subsequently written to successfully.
 819 -- The handle is positioned at the end of the file if @mode@ is
 820 -- 'AppendMode', and otherwise at the beginning (in which case its
 821 -- internal position is 0).
 822 -- The initial buffer mode is implementation-dependent.
 823 --
 824 -- This operation may fail with:
 825 --
 826 --  * 'isAlreadyInUseError' if the file is already open and cannot be reopened;
 827 --
 828 --  * 'isDoesNotExistError' if the file does not exist; or
 829 --
 830 --  * 'isPermissionError' if the user does not have permission to open the file.
 831 --
 832 -- Note: if you will be working with files containing binary data, you'll want to
 833 -- be using 'openBinaryFile'.
 834 openFile :: FilePath -> IOMode -> IO Handle
 835 openFile fp im =
 836   catch
 837     (openFile' fp im dEFAULT_OPEN_IN_BINARY_MODE)
 838     (\e -> ioError (addFilePathToIOError "openFile" fp e))
 839
 840 -- | Like 'openFile', but open the file in binary mode.
 841 -- On Windows, reading a file in text mode (which is the default)
 842 -- will translate CRLF to LF, and writing will translate LF to CRLF.
 843 -- This is usually what you want with text files.  With binary files
 844 -- this is undesirable; also, as usual under Microsoft operating systems,
 845 -- text mode treats control-Z as EOF.  Binary mode turns off all special
 846 -- treatment of end-of-line and end-of-file characters.
 847 -- (See also 'hSetBinaryMode'.)
 848
 849 openBinaryFile :: FilePath -> IOMode -> IO Handle
 850 openBinaryFile fp m =
 851   catch
 852     (openFile' fp m True)
 853     (\e -> ioError (addFilePathToIOError "openBinaryFile" fp e))
 854
 855 openFile' filepath mode binary =
 856   withCString filepath $ \ f ->
 857
 858     let
 859       oflags1 = case mode of
 860                   ReadMode      -> read_flags
 861 #ifdef mingw32_HOST_OS
 862                   WriteMode     -> write_flags .|. o_TRUNC
 863 #else
 864                   WriteMode     -> write_flags
 865 #endif
 866                   ReadWriteMode -> rw_flags
 867                   AppendMode    -> append_flags
 868
 869       binary_flags
 870           | binary    = o_BINARY
 871           | otherwise = 0
 872
 873       oflags = oflags1 .|. binary_flags
 874     in do
 875
 876     -- the old implementation had a complicated series of three opens,
 877     -- which is perhaps because we have to be careful not to open
 878     -- directories.  However, the man pages I've read say that open()
 879     -- always returns EISDIR if the file is a directory and was opened
 880     -- for writing, so I think we're ok with a single open() here...
 881     fd <- throwErrnoIfMinus1Retry "openFile"
 882                 (c_open f (fromIntegral oflags) 0o666)
 883
 884     fd_type <- fdType fd
 885
 886     h <- fdToHandle' fd (Just fd_type) False filepath mode binary
 887             `catchException` \e -> do c_close fd; throw e
 888         -- NB. don't forget to close the FD if fdToHandle' fails, otherwise
 889         -- this FD leaks.
 890         -- ASSERT: if we just created the file, then fdToHandle' won't fail
 891         -- (so we don't need to worry about removing the newly created file
 892         --  in the event of an error).
 893
 894 #ifndef mingw32_HOST_OS
 895         -- we want to truncate() if this is an open in WriteMode, but only
 896         -- if the target is a RegularFile.  ftruncate() fails on special files
 897         -- like /dev/null.
 898     if mode == WriteMode && fd_type == RegularFile
 899       then throwErrnoIf (/=0) "openFile"
 900               (c_ftruncate fd 0)
 901       else return 0
 902 #endif
 903     return h
 904
 905
 906 -- | The function creates a temporary file in ReadWrite mode.
 907 -- The created file isn\'t deleted automatically, so you need to delete it manually.
 908 openTempFile :: FilePath   -- ^ Directory in which to create the file
 909              -> String     -- ^ File name template. If the template is \"foo.ext\" then
 910                            -- the create file will be \"fooXXX.ext\" where XXX is some
 911                            -- random number.
 912              -> IO (FilePath, Handle)
 913 openTempFile tmp_dir template = openTempFile' "openTempFile" tmp_dir template dEFAULT_OPEN_IN_BINARY_MODE
 914
 915 -- | Like 'openTempFile', but opens the file in binary mode. See 'openBinaryFile' for more comments.
 916 openBinaryTempFile :: FilePath -> String -> IO (FilePath, Handle)
 917 openBinaryTempFile tmp_dir template = openTempFile' "openBinaryTempFile" tmp_dir template True
 918
 919 openTempFile' :: String -> FilePath -> String -> Bool -> IO (FilePath, Handle)
 920 openTempFile' loc tmp_dir template binary = do
 921   pid <- c_getpid
 922   findTempName pid
 923   where
 924     (prefix,suffix) = break (=='.') template
 925
 926     oflags1 = rw_flags .|. o_EXCL
 927
 928     binary_flags
 929       | binary    = o_BINARY
 930       | otherwise = 0
 931
 932     oflags = oflags1 .|. binary_flags
 933
 934     findTempName x = do
 935       fd <- withCString filepath $ \ f ->
 936               c_open f oflags 0o666
 937       if fd < 0
 938        then do
 939          errno <- getErrno
 940          if errno == eEXIST
 941            then findTempName (x+1)
 942            else ioError (errnoToIOError loc errno Nothing (Just tmp_dir))
 943        else do
 944          h <- fdToHandle' fd Nothing False filepath ReadWriteMode True
 945                 `catchException` \e -> do c_close fd; throw e
 946          return (filepath, h)
 947       where
 948         filename        = prefix ++ show x ++ suffix
 949         filepath        = tmp_dir ++ [pathSeparator] ++ filename
 950
 951 pathSeparator :: Char
 952 #ifdef mingw32_HOST_OS
 953 pathSeparator = '\\'
 954 #else
 955 pathSeparator = '/'
 956 #endif
 957
 958 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 959 output_flags = std_flags    .|. o_CREAT
 960 read_flags   = std_flags    .|. o_RDONLY
 961 write_flags  = output_flags .|. o_WRONLY
 962 rw_flags     = output_flags .|. o_RDWR
 963 append_flags = write_flags  .|. o_APPEND
 964
 965 -- ---------------------------------------------------------------------------
 966 -- fdToHandle'
 967
 968 fdToHandle' :: FD -> Maybe FDType -> Bool -> FilePath -> IOMode -> Bool -> IO Handle
 969 fdToHandle' fd mb_fd_type is_socket filepath mode binary = do
 970     -- turn on non-blocking mode
 971     setNonBlockingFD fd
 972
 973 #ifdef mingw32_HOST_OS
 974     -- On Windows, the is_stream flag indicates that the Handle is a socket
 975     let is_stream = is_socket
 976 #else
 977     -- On Unix, the is_stream flag indicates that the FD is non-blocking
 978     let is_stream = True
 979 #endif
 980
 981     let (ha_type, write) =
 982           case mode of
 983             ReadMode      -> ( ReadHandle,      False )
 984             WriteMode     -> ( WriteHandle,     True )
 985             ReadWriteMode -> ( ReadWriteHandle, True )
 986             AppendMode    -> ( AppendHandle,    True )
 987
 988     -- open() won't tell us if it was a directory if we only opened for
 989     -- reading, so check again.
 990     fd_type <-
 991       case mb_fd_type of
 992         Just x  -> return x
 993         Nothing -> fdType fd
 994
 995     case fd_type of
 996         Directory ->
 997            ioException (IOError Nothing InappropriateType "openFile"
 998                            "is a directory" Nothing)
 999
1000         -- regular files need to be locked
1001         RegularFile -> do
1002 #ifndef mingw32_HOST_OS
1003            r <- lockFile fd (fromBool write) 1{-exclusive-}
1004            when (r == -1)  $
1005                 ioException (IOError Nothing ResourceBusy "openFile"
1006                                    "file is locked" Nothing)
1007 #endif
1008            mkFileHandle fd is_stream filepath ha_type binary
1009
1010         Stream
1011            -- only *Streams* can be DuplexHandles.  Other read/write
1012            -- Handles must share a buffer.
1013            | ReadWriteHandle <- ha_type ->
1014                 mkDuplexHandle fd is_stream filepath binary
1015            | otherwise ->
1016                 mkFileHandle   fd is_stream filepath ha_type binary
1017
1018         RawDevice ->
1019                 mkFileHandle fd is_stream filepath ha_type binary
1020
1021 fdToHandle :: FD -> IO Handle
1022 fdToHandle fd = do
1023    mode <- fdGetMode fd
1024    let fd_str = "<file descriptor: " ++ show fd ++ ">"
1025    fdToHandle' fd Nothing False{-XXX!-} fd_str mode True{-bin mode-}
1026
1027
1028 #ifndef mingw32_HOST_OS
1029 foreign import ccall unsafe "lockFile"
1030   lockFile :: CInt -> CInt -> CInt -> IO CInt
1031
1032 foreign import ccall unsafe "unlockFile"
1033   unlockFile :: CInt -> IO CInt
1034 #endif
1035
1036 mkStdHandle :: FD -> FilePath -> HandleType -> IORef Buffer -> BufferMode
1037         -> IO Handle
1038 mkStdHandle fd filepath ha_type buf bmode = do
1039    spares <- newIORef BufferListNil
1040    newFileHandle filepath (stdHandleFinalizer filepath)
1041             (Handle__ { haFD = fd,
1042                         haType = ha_type,
1043                         haIsBin = dEFAULT_OPEN_IN_BINARY_MODE,
1044                         haIsStream = False, -- means FD is blocking on Unix
1045                         haBufferMode = bmode,
1046                         haBuffer = buf,
1047                         haBuffers = spares,
1048                         haOtherSide = Nothing
1049                       })
1050
1051 mkFileHandle :: FD -> Bool -> FilePath -> HandleType -> Bool -> IO Handle
1052 mkFileHandle fd is_stream filepath ha_type binary = do
1053   (buf, bmode) <- getBuffer fd (initBufferState ha_type)
1054
1055 #ifdef mingw32_HOST_OS
1056   -- On Windows, if this is a read/write handle and we are in text mode,
1057   -- turn off buffering.  We don't correctly handle the case of switching
1058   -- from read mode to write mode on a buffered text-mode handle, see bug
1059   -- \#679.
1060   bmode <- case ha_type of
1061                 ReadWriteHandle | not binary -> return NoBuffering
1062                 _other                       -> return bmode
1063 #endif
1064
1065   spares <- newIORef BufferListNil
1066   newFileHandle filepath (handleFinalizer filepath)
1067             (Handle__ { haFD = fd,
1068                         haType = ha_type,
1069                         haIsBin = binary,
1070                         haIsStream = is_stream,
1071                         haBufferMode = bmode,
1072                         haBuffer = buf,
1073                         haBuffers = spares,
1074                         haOtherSide = Nothing
1075                       })
1076
1077 mkDuplexHandle :: FD -> Bool -> FilePath -> Bool -> IO Handle
1078 mkDuplexHandle fd is_stream filepath binary = do
1079   (w_buf, w_bmode) <- getBuffer fd WriteBuffer
1080   w_spares <- newIORef BufferListNil
1081   let w_handle_ =
1082              Handle__ { haFD = fd,
1083                         haType = WriteHandle,
1084                         haIsBin = binary,
1085                         haIsStream = is_stream,
1086                         haBufferMode = w_bmode,
1087                         haBuffer = w_buf,
1088                         haBuffers = w_spares,
1089                         haOtherSide = Nothing
1090                       }
1091   write_side <- newMVar w_handle_
1092
1093   (r_buf, r_bmode) <- getBuffer fd ReadBuffer
1094   r_spares <- newIORef BufferListNil
1095   let r_handle_ =
1096              Handle__ { haFD = fd,
1097                         haType = ReadHandle,
1098                         haIsBin = binary,
1099                         haIsStream = is_stream,
1100                         haBufferMode = r_bmode,
1101                         haBuffer = r_buf,
1102                         haBuffers = r_spares,
1103                         haOtherSide = Just write_side
1104                       }
1105   read_side <- newMVar r_handle_
1106
1107   addMVarFinalizer write_side (handleFinalizer filepath write_side)
1108   return (DuplexHandle filepath read_side write_side)
1109
1110
1111 initBufferState ReadHandle = ReadBuffer
1112 initBufferState _          = WriteBuffer
1113
1114 -- ---------------------------------------------------------------------------
1115 -- Closing a handle
1116
1117 -- | Computation 'hClose' @hdl@ makes handle @hdl@ closed.  Before the
1118 -- computation finishes, if @hdl@ is writable its buffer is flushed as
1119 -- for 'hFlush'.
1120 -- Performing 'hClose' on a handle that has already been closed has no effect;
1121 -- doing so not an error.  All other operations on a closed handle will fail.
1122 -- If 'hClose' fails for any reason, any further operations (apart from
1123 -- 'hClose') on the handle will still fail as if @hdl@ had been successfully
1124 -- closed.
1125
1126 hClose :: Handle -> IO ()
1127 hClose h@(FileHandle _ m)     = hClose' h m
1128 hClose h@(DuplexHandle _ r w) = hClose' h w >> hClose' h r
1129
1130 hClose' h m = withHandle__' "hClose" h m $ hClose_help
1131
1132 -- hClose_help is also called by lazyRead (in PrelIO) when EOF is read
1133 -- or an IO error occurs on a lazy stream.  The semi-closed Handle is
1134 -- then closed immediately.  We have to be careful with DuplexHandles
1135 -- though: we have to leave the closing to the finalizer in that case,
1136 -- because the write side may still be in use.
1137 hClose_help :: Handle__ -> IO Handle__
1138 hClose_help handle_ =
1139   case haType handle_ of
1140       ClosedHandle -> return handle_
1141       _ -> do flushWriteBufferOnly handle_ -- interruptible
1142               hClose_handle_ handle_
1143
1144 hClose_handle_ handle_ = do
1145     let fd = haFD handle_
1146
1147     -- close the file descriptor, but not when this is the read
1148     -- side of a duplex handle.
1149     case haOtherSide handle_ of
1150       Nothing ->
1151                   throwErrnoIfMinus1Retry_ "hClose"
1152 #ifdef mingw32_HOST_OS
1153                                 (closeFd (haIsStream handle_) fd)
1154 #else
1155                                 (c_close fd)
1156 #endif
1157       Just _  -> return ()
1158
1159     -- free the spare buffers
1160     writeIORef (haBuffers handle_) BufferListNil
1161     writeIORef (haBuffer  handle_) noBuffer
1162
1163 #ifndef mingw32_HOST_OS
1164     -- unlock it
1165     unlockFile fd
1166 #endif
1167
1168     -- we must set the fd to -1, because the finalizer is going
1169     -- to run eventually and try to close/unlock it.
1170     return (handle_{ haFD        = -1,
1171                      haType      = ClosedHandle
1172                    })
1173
1174 {-# NOINLINE noBuffer #-}
1175 noBuffer = unsafePerformIO $ allocateBuffer 1 ReadBuffer
1176
1177 -----------------------------------------------------------------------------
1178 -- Detecting and changing the size of a file
1179
1180 -- | For a handle @hdl@ which attached to a physical file,
1181 -- 'hFileSize' @hdl@ returns the size of that file in 8-bit bytes.
1182
1183 hFileSize :: Handle -> IO Integer
1184 hFileSize handle =
1185     withHandle_ "hFileSize" handle $ \ handle_ -> do
1186     case haType handle_ of
1187       ClosedHandle              -> ioe_closedHandle
1188       SemiClosedHandle          -> ioe_closedHandle
1189       _ -> do flushWriteBufferOnly handle_
1190               r <- fdFileSize (haFD handle_)
1191               if r /= -1
1192                  then return r
1193                  else ioException (IOError Nothing InappropriateType "hFileSize"
1194                                    "not a regular file" Nothing)
1195
1196
1197 -- | 'hSetFileSize' @hdl@ @size@ truncates the physical file with handle @hdl@ to @size@ bytes.
1198
1199 hSetFileSize :: Handle -> Integer -> IO ()
1200 hSetFileSize handle size =
1201     withHandle_ "hSetFileSize" handle $ \ handle_ -> do
1202     case haType handle_ of
1203       ClosedHandle              -> ioe_closedHandle
1204       SemiClosedHandle          -> ioe_closedHandle
1205       _ -> do flushWriteBufferOnly handle_
1206               throwErrnoIf (/=0) "hSetFileSize"
1207                  (c_ftruncate (haFD handle_) (fromIntegral size))
1208               return ()
1209
1210 -- ---------------------------------------------------------------------------
1211 -- Detecting the End of Input
1212
1213 -- | For a readable handle @hdl@, 'hIsEOF' @hdl@ returns
1214 -- 'True' if no further input can be taken from @hdl@ or for a
1215 -- physical file, if the current I\/O position is equal to the length of
1216 -- the file.  Otherwise, it returns 'False'.
1217
1218 hIsEOF :: Handle -> IO Bool
1219 hIsEOF handle =
1220   catch
1221      (do hLookAhead handle; return False)
1222      (\e -> if isEOFError e then return True else ioError e)
1223
1224 -- | The computation 'isEOF' is identical to 'hIsEOF',
1225 -- except that it works only on 'stdin'.
1226
1227 isEOF :: IO Bool
1228 isEOF = hIsEOF stdin
1229
1230 -- ---------------------------------------------------------------------------
1231 -- Looking ahead
1232
1233 -- | Computation 'hLookAhead' returns the next character from the handle
1234 -- without removing it from the input buffer, blocking until a character
1235 -- is available.
1236 --
1237 -- This operation may fail with:
1238 --
1239 --  * 'isEOFError' if the end of file has been reached.
1240
1241 hLookAhead :: Handle -> IO Char
1242 hLookAhead handle = do
1243   wantReadableHandle "hLookAhead"  handle $ \handle_ -> do
1244   let ref     = haBuffer handle_
1245       fd      = haFD handle_
1246       is_line = haBufferMode handle_ == LineBuffering
1247   buf <- readIORef ref
1248
1249   -- fill up the read buffer if necessary
1250   new_buf <- if bufferEmpty buf
1251                 then fillReadBuffer fd True (haIsStream handle_) buf
1252                 else return buf
1253
1254   writeIORef ref new_buf
1255
1256   (c,_) <- readCharFromBuffer (bufBuf buf) (bufRPtr buf)
1257   return c
1258
1259 -- ---------------------------------------------------------------------------
1260 -- Buffering Operations
1261
1262 -- Three kinds of buffering are supported: line-buffering,
1263 -- block-buffering or no-buffering.  See GHC.IOBase for definition and
1264 -- further explanation of what the type represent.
1265
1266 -- | Computation 'hSetBuffering' @hdl mode@ sets the mode of buffering for
1267 -- handle @hdl@ on subsequent reads and writes.
1268 --
1269 -- If the buffer mode is changed from 'BlockBuffering' or
1270 -- 'LineBuffering' to 'NoBuffering', then
1271 --
1272 --  * if @hdl@ is writable, the buffer is flushed as for 'hFlush';
1273 --
1274 --  * if @hdl@ is not writable, the contents of the buffer is discarded.
1275 --
1276 -- This operation may fail with:
1277 --
1278 --  * 'isPermissionError' if the handle has already been used for reading
1279 --    or writing and the implementation does not allow the buffering mode
1280 --    to be changed.
1281
1282 hSetBuffering :: Handle -> BufferMode -> IO ()
1283 hSetBuffering handle mode =
1284   withAllHandles__ "hSetBuffering" handle $ \ handle_ -> do
1285   case haType handle_ of
1286     ClosedHandle -> ioe_closedHandle
1287     _ -> do
1288          {- Note:
1289             - we flush the old buffer regardless of whether
1290               the new buffer could fit the contents of the old buffer
1291               or not.
1292             - allow a handle's buffering to change even if IO has
1293               occurred (ANSI C spec. does not allow this, nor did
1294               the previous implementation of IO.hSetBuffering).
1295             - a non-standard extension is to allow the buffering
1296               of semi-closed handles to change [sof 6/98]
1297           -}
1298           flushBuffer handle_
1299
1300           let state = initBufferState (haType handle_)
1301           new_buf <-
1302             case mode of
1303                 -- we always have a 1-character read buffer for
1304                 -- unbuffered  handles: it's needed to
1305                 -- support hLookAhead.
1306               NoBuffering            -> allocateBuffer 1 ReadBuffer
1307               LineBuffering          -> allocateBuffer dEFAULT_BUFFER_SIZE state
1308               BlockBuffering Nothing -> allocateBuffer dEFAULT_BUFFER_SIZE state
1309               BlockBuffering (Just n) | n <= 0    -> ioe_bufsiz n
1310                                       | otherwise -> allocateBuffer n state
1311           writeIORef (haBuffer handle_) new_buf
1312
1313           -- for input terminals we need to put the terminal into
1314           -- cooked or raw mode depending on the type of buffering.
1315           is_tty <- fdIsTTY (haFD handle_)
1316           when (is_tty && isReadableHandleType (haType handle_)) $
1317                 case mode of
1318 #ifndef mingw32_HOST_OS
1319         -- 'raw' mode under win32 is a bit too specialised (and troublesome
1320         -- for most common uses), so simply disable its use here.
1321                   NoBuffering -> setCooked (haFD handle_) False
1322 #else
1323                   NoBuffering -> return ()
1324 #endif
1325                   _           -> setCooked (haFD handle_) True
1326
1327           -- throw away spare buffers, they might be the wrong size
1328           writeIORef (haBuffers handle_) BufferListNil
1329
1330           return (handle_{ haBufferMode = mode })
1331
1332 -- -----------------------------------------------------------------------------
1333 -- hFlush
1334
1335 -- | The action 'hFlush' @hdl@ causes any items buffered for output
1336 -- in handle @hdl@ to be sent immediately to the operating system.
1337 --
1338 -- This operation may fail with:
1339 --
1340 --  * 'isFullError' if the device is full;
1341 --
1342 --  * 'isPermissionError' if a system resource limit would be exceeded.
1343 --    It is unspecified whether the characters in the buffer are discarded
1344 --    or retained under these circumstances.
1345
1346 hFlush :: Handle -> IO ()
1347 hFlush handle =
1348    wantWritableHandle "hFlush" handle $ \ handle_ -> do
1349    buf <- readIORef (haBuffer handle_)
1350    if bufferIsWritable buf && not (bufferEmpty buf)
1351         then do flushed_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
1352                 writeIORef (haBuffer handle_) flushed_buf
1353         else return ()
1354
1355
1356 -- -----------------------------------------------------------------------------
1357 -- Repositioning Handles
1358
1359 data HandlePosn = HandlePosn Handle HandlePosition
1360
1361 instance Eq HandlePosn where
1362     (HandlePosn h1 p1) == (HandlePosn h2 p2) = p1==p2 && h1==h2
1363
1364 instance Show HandlePosn where
1365    showsPrec p (HandlePosn h pos) =
1366         showsPrec p h . showString " at position " . shows pos
1367
1368   -- HandlePosition is the Haskell equivalent of POSIX' off_t.
1369   -- We represent it as an Integer on the Haskell side, but
1370   -- cheat slightly in that hGetPosn calls upon a C helper
1371   -- that reports the position back via (merely) an Int.
1372 type HandlePosition = Integer
1373
1374 -- | Computation 'hGetPosn' @hdl@ returns the current I\/O position of
1375 -- @hdl@ as a value of the abstract type 'HandlePosn'.
1376
1377 hGetPosn :: Handle -> IO HandlePosn
1378 hGetPosn handle = do
1379     posn <- hTell handle
1380     return (HandlePosn handle posn)
1381
1382 -- | If a call to 'hGetPosn' @hdl@ returns a position @p@,
1383 -- then computation 'hSetPosn' @p@ sets the position of @hdl@
1384 -- to the position it held at the time of the call to 'hGetPosn'.
1385 --
1386 -- This operation may fail with:
1387 --
1388 --  * 'isPermissionError' if a system resource limit would be exceeded.
1389
1390 hSetPosn :: HandlePosn -> IO ()
1391 hSetPosn (HandlePosn h i) = hSeek h AbsoluteSeek i
1392
1393 -- ---------------------------------------------------------------------------
1394 -- hSeek
1395
1396 -- | A mode that determines the effect of 'hSeek' @hdl mode i@, as follows:
1397 data SeekMode
1398   = AbsoluteSeek        -- ^ the position of @hdl@ is set to @i@.
1399   | RelativeSeek        -- ^ the position of @hdl@ is set to offset @i@
1400                         -- from the current position.
1401   | SeekFromEnd         -- ^ the position of @hdl@ is set to offset @i@
1402                         -- from the end of the file.
1403     deriving (Eq, Ord, Ix, Enum, Read, Show)
1404
1405 {- Note:
1406  - when seeking using `SeekFromEnd', positive offsets (>=0) means
1407    seeking at or past EOF.
1408
1409  - we possibly deviate from the report on the issue of seeking within
1410    the buffer and whether to flush it or not.  The report isn't exactly
1411    clear here.
1412 -}
1413
1414 -- | Computation 'hSeek' @hdl mode i@ sets the position of handle
1415 -- @hdl@ depending on @mode@.
1416 -- The offset @i@ is given in terms of 8-bit bytes.
1417 --
1418 -- If @hdl@ is block- or line-buffered, then seeking to a position which is not
1419 -- in the current buffer will first cause any items in the output buffer to be
1420 -- written to the device, and then cause the input buffer to be discarded.
1421 -- Some handles may not be seekable (see 'hIsSeekable'), or only support a
1422 -- subset of the possible positioning operations (for instance, it may only
1423 -- be possible to seek to the end of a tape, or to a positive offset from
1424 -- the beginning or current position).
1425 -- It is not possible to set a negative I\/O position, or for
1426 -- a physical file, an I\/O position beyond the current end-of-file.
1427 --
1428 -- This operation may fail with:
1429 --
1430 --  * 'isPermissionError' if a system resource limit would be exceeded.
1431
1432 hSeek :: Handle -> SeekMode -> Integer -> IO ()
1433 hSeek handle mode offset =
1434     wantSeekableHandle "hSeek" handle $ \ handle_ -> do
1435 #   ifdef DEBUG_DUMP
1436     puts ("hSeek " ++ show (mode,offset) ++ "\n")
1437 #   endif
1438     let ref = haBuffer handle_
1439     buf <- readIORef ref
1440     let r = bufRPtr buf
1441         w = bufWPtr buf
1442         fd = haFD handle_
1443
1444     let do_seek =
1445           throwErrnoIfMinus1Retry_ "hSeek"
1446             (c_lseek (haFD handle_) (fromIntegral offset) whence)
1447
1448         whence :: CInt
1449         whence = case mode of
1450                    AbsoluteSeek -> sEEK_SET
1451                    RelativeSeek -> sEEK_CUR
1452                    SeekFromEnd  -> sEEK_END
1453
1454     if bufferIsWritable buf
1455         then do new_buf <- flushWriteBuffer fd (haIsStream handle_) buf
1456                 writeIORef ref new_buf
1457                 do_seek
1458         else do
1459
1460     if mode == RelativeSeek && offset >= 0 && offset < fromIntegral (w - r)
1461         then writeIORef ref buf{ bufRPtr = r + fromIntegral offset }
1462         else do
1463
1464     new_buf <- flushReadBuffer (haFD handle_) buf
1465     writeIORef ref new_buf
1466     do_seek
1467
1468
1469 hTell :: Handle -> IO Integer
1470 hTell handle =
1471     wantSeekableHandle "hGetPosn" handle $ \ handle_ -> do
1472
1473 #if defined(mingw32_HOST_OS)
1474         -- urgh, on Windows we have to worry about \n -> \r\n translation,
1475         -- so we can't easily calculate the file position using the
1476         -- current buffer size.  Just flush instead.
1477       flushBuffer handle_
1478 #endif
1479       let fd = haFD handle_
1480       posn <- fromIntegral `liftM`
1481                 throwErrnoIfMinus1Retry "hGetPosn"
1482                    (c_lseek fd 0 sEEK_CUR)
1483
1484       let ref = haBuffer handle_
1485       buf <- readIORef ref
1486
1487       let real_posn
1488            | bufferIsWritable buf = posn + fromIntegral (bufWPtr buf)
1489            | otherwise = posn - fromIntegral (bufWPtr buf - bufRPtr buf)
1490 #     ifdef DEBUG_DUMP
1491       puts ("\nhGetPosn: (fd, posn, real_posn) = " ++ show (fd, posn, real_posn) ++ "\n")
1492       puts ("   (bufWPtr, bufRPtr) = " ++ show (bufWPtr buf, bufRPtr buf) ++ "\n")
1493 #     endif
1494       return real_posn
1495
1496 -- -----------------------------------------------------------------------------
1497 -- Handle Properties
1498
1499 -- A number of operations return information about the properties of a
1500 -- handle.  Each of these operations returns `True' if the handle has
1501 -- the specified property, and `False' otherwise.
1502
1503 hIsOpen :: Handle -> IO Bool
1504 hIsOpen handle =
1505     withHandle_ "hIsOpen" handle $ \ handle_ -> do
1506     case haType handle_ of
1507       ClosedHandle         -> return False
1508       SemiClosedHandle     -> return False
1509       _                    -> return True
1510
1511 hIsClosed :: Handle -> IO Bool
1512 hIsClosed handle =
1513     withHandle_ "hIsClosed" handle $ \ handle_ -> do
1514     case haType handle_ of
1515       ClosedHandle         -> return True
1516       _                    -> return False
1517
1518 {- not defined, nor exported, but mentioned
1519    here for documentation purposes:
1520
1521     hSemiClosed :: Handle -> IO Bool
1522     hSemiClosed h = do
1523        ho <- hIsOpen h
1524        hc <- hIsClosed h
1525        return (not (ho || hc))
1526 -}
1527
1528 hIsReadable :: Handle -> IO Bool
1529 hIsReadable (DuplexHandle _ _ _) = return True
1530 hIsReadable handle =
1531     withHandle_ "hIsReadable" handle $ \ handle_ -> do
1532     case haType handle_ of
1533       ClosedHandle         -> ioe_closedHandle
1534       SemiClosedHandle     -> ioe_closedHandle
1535       htype                -> return (isReadableHandleType htype)
1536
1537 hIsWritable :: Handle -> IO Bool
1538 hIsWritable (DuplexHandle _ _ _) = return True
1539 hIsWritable handle =
1540     withHandle_ "hIsWritable" handle $ \ handle_ -> do
1541     case haType handle_ of
1542       ClosedHandle         -> ioe_closedHandle
1543       SemiClosedHandle     -> ioe_closedHandle
1544       htype                -> return (isWritableHandleType htype)
1545
1546 -- | Computation 'hGetBuffering' @hdl@ returns the current buffering mode
1547 -- for @hdl@.
1548
1549 hGetBuffering :: Handle -> IO BufferMode
1550 hGetBuffering handle =
1551     withHandle_ "hGetBuffering" handle $ \ handle_ -> do
1552     case haType handle_ of
1553       ClosedHandle         -> ioe_closedHandle
1554       _ ->
1555            -- We're being non-standard here, and allow the buffering
1556            -- of a semi-closed handle to be queried.   -- sof 6/98
1557           return (haBufferMode handle_)  -- could be stricter..
1558
1559 hIsSeekable :: Handle -> IO Bool
1560 hIsSeekable handle =
1561     withHandle_ "hIsSeekable" handle $ \ handle_ -> do
1562     case haType handle_ of
1563       ClosedHandle         -> ioe_closedHandle
1564       SemiClosedHandle     -> ioe_closedHandle
1565       AppendHandle         -> return False
1566       _                    -> do t <- fdType (haFD handle_)
1567                                  return ((t == RegularFile    || t == RawDevice)
1568                                          && (haIsBin handle_  || tEXT_MODE_SEEK_ALLOWED))
1569
1570 -- -----------------------------------------------------------------------------
1571 -- Changing echo status (Non-standard GHC extensions)
1572
1573 -- | Set the echoing status of a handle connected to a terminal.
1574
1575 hSetEcho :: Handle -> Bool -> IO ()
1576 hSetEcho handle on = do
1577     isT   <- hIsTerminalDevice handle
1578     if not isT
1579      then return ()
1580      else
1581       withHandle_ "hSetEcho" handle $ \ handle_ -> do
1582       case haType handle_ of
1583          ClosedHandle -> ioe_closedHandle
1584          _            -> setEcho (haFD handle_) on
1585
1586 -- | Get the echoing status of a handle connected to a terminal.
1587
1588 hGetEcho :: Handle -> IO Bool
1589 hGetEcho handle = do
1590     isT   <- hIsTerminalDevice handle
1591     if not isT
1592      then return False
1593      else
1594        withHandle_ "hGetEcho" handle $ \ handle_ -> do
1595        case haType handle_ of
1596          ClosedHandle -> ioe_closedHandle
1597          _            -> getEcho (haFD handle_)
1598
1599 -- | Is the handle connected to a terminal?
1600
1601 hIsTerminalDevice :: Handle -> IO Bool
1602 hIsTerminalDevice handle = do
1603     withHandle_ "hIsTerminalDevice" handle $ \ handle_ -> do
1604      case haType handle_ of
1605        ClosedHandle -> ioe_closedHandle
1606        _            -> fdIsTTY (haFD handle_)
1607
1608 -- -----------------------------------------------------------------------------
1609 -- hSetBinaryMode
1610
1611 -- | Select binary mode ('True') or text mode ('False') on a open handle.
1612 -- (See also 'openBinaryFile'.)
1613
1614 hSetBinaryMode :: Handle -> Bool -> IO ()
1615 hSetBinaryMode handle bin =
1616   withAllHandles__ "hSetBinaryMode" handle $ \ handle_ ->
1617     do throwErrnoIfMinus1_ "hSetBinaryMode"
1618           (setmode (haFD handle_) bin)
1619        return handle_{haIsBin=bin}
1620
1621 foreign import ccall unsafe "__hscore_setmode"
1622   setmode :: CInt -> Bool -> IO CInt
1623
1624 -- -----------------------------------------------------------------------------
1625 -- Duplicating a Handle
1626
1627 -- | Returns a duplicate of the original handle, with its own buffer.
1628 -- The two Handles will share a file pointer, however.  The original
1629 -- handle's buffer is flushed, including discarding any input data,
1630 -- before the handle is duplicated.
1631
1632 hDuplicate :: Handle -> IO Handle
1633 hDuplicate h@(FileHandle path m) = do
1634   new_h_ <- withHandle' "hDuplicate" h m (dupHandle h Nothing)
1635   newFileHandle path (handleFinalizer path) new_h_
1636 hDuplicate h@(DuplexHandle path r w) = do
1637   new_w_ <- withHandle' "hDuplicate" h w (dupHandle h Nothing)
1638   new_w <- newMVar new_w_
1639   new_r_ <- withHandle' "hDuplicate" h r (dupHandle h (Just new_w))
1640   new_r <- newMVar new_r_
1641   addMVarFinalizer new_w (handleFinalizer path new_w)
1642   return (DuplexHandle path new_r new_w)
1643
1644 dupHandle :: Handle -> Maybe (MVar Handle__) -> Handle__
1645           -> IO (Handle__, Handle__)
1646 dupHandle h other_side h_ = do
1647   -- flush the buffer first, so we don't have to copy its contents
1648   flushBuffer h_
1649   new_fd <- case other_side of
1650                 Nothing -> throwErrnoIfMinus1 "dupHandle" $ c_dup (haFD h_)
1651                 Just r -> withHandle_' "dupHandle" h r (return . haFD)
1652   dupHandle_ other_side h_ new_fd
1653
1654 dupHandleTo other_side hto_ h_ = do
1655   flushBuffer h_
1656   -- Windows' dup2 does not return the new descriptor, unlike Unix
1657   throwErrnoIfMinus1 "dupHandleTo" $
1658         c_dup2 (haFD h_) (haFD hto_)
1659   dupHandle_ other_side h_ (haFD hto_)
1660
1661 dupHandle_ :: Maybe (MVar Handle__) -> Handle__ -> FD
1662            -> IO (Handle__, Handle__)
1663 dupHandle_ other_side h_ new_fd = do
1664   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE (initBufferState (haType h_))
1665   ioref <- newIORef buffer
1666   ioref_buffers <- newIORef BufferListNil
1667
1668   let new_handle_ = h_{ haFD = new_fd,
1669                         haBuffer = ioref,
1670                         haBuffers = ioref_buffers,
1671                         haOtherSide = other_side }
1672   return (h_, new_handle_)
1673
1674 -- -----------------------------------------------------------------------------
1675 -- Replacing a Handle
1676
1677 {- |
1678 Makes the second handle a duplicate of the first handle.  The second
1679 handle will be closed first, if it is not already.
1680
1681 This can be used to retarget the standard Handles, for example:
1682
1683 > do h <- openFile "mystdout" WriteMode
1684 >    hDuplicateTo h stdout
1685 -}
1686
1687 hDuplicateTo :: Handle -> Handle -> IO ()
1688 hDuplicateTo h1@(FileHandle _ m1) h2@(FileHandle _ m2)  = do
1689  withHandle__' "hDuplicateTo" h2 m2 $ \h2_ -> do
1690    _ <- hClose_help h2_
1691    withHandle' "hDuplicateTo" h1 m1 (dupHandleTo Nothing h2_)
1692 hDuplicateTo h1@(DuplexHandle _ r1 w1) h2@(DuplexHandle _ r2 w2)  = do
1693  withHandle__' "hDuplicateTo" h2 w2  $ \w2_ -> do
1694    _ <- hClose_help w2_
1695    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo Nothing w2_)
1696  withHandle__' "hDuplicateTo" h2 r2  $ \r2_ -> do
1697    _ <- hClose_help r2_
1698    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo (Just w1) r2_)
1699 hDuplicateTo h1 _ =
1700    ioException (IOError (Just h1) IllegalOperation "hDuplicateTo"
1701                 "handles are incompatible" Nothing)
1702
1703 -- ---------------------------------------------------------------------------
1704 -- showing Handles.
1705 --
1706 -- | 'hShow' is in the 'IO' monad, and gives more comprehensive output
1707 -- than the (pure) instance of 'Show' for 'Handle'.
1708
1709 hShow :: Handle -> IO String
1710 hShow h@(FileHandle path _) = showHandle' path False h
1711 hShow h@(DuplexHandle path _ _) = showHandle' path True h
1712
1713 showHandle' filepath is_duplex h =
1714   withHandle_ "showHandle" h $ \hdl_ ->
1715     let
1716      showType | is_duplex = showString "duplex (read-write)"
1717               | otherwise = shows (haType hdl_)
1718     in
1719     return
1720       (( showChar '{' .
1721         showHdl (haType hdl_)
1722             (showString "loc=" . showString filepath . showChar ',' .
1723              showString "type=" . showType . showChar ',' .
1724              showString "binary=" . shows (haIsBin hdl_) . showChar ',' .
1725              showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
1726       ) "")
1727    where
1728
1729     showHdl :: HandleType -> ShowS -> ShowS
1730     showHdl ht cont =
1731        case ht of
1732         ClosedHandle  -> shows ht . showString "}"
1733         _ -> cont
1734
1735     showBufMode :: Buffer -> BufferMode -> ShowS
1736     showBufMode buf bmo =
1737       case bmo of
1738         NoBuffering   -> showString "none"
1739         LineBuffering -> showString "line"
1740         BlockBuffering (Just n) -> showString "block " . showParen True (shows n)
1741         BlockBuffering Nothing  -> showString "block " . showParen True (shows def)
1742       where
1743        def :: Int
1744        def = bufSize buf
1745
1746 -- ---------------------------------------------------------------------------
1747 -- debugging
1748
1749 #if defined(DEBUG_DUMP)
1750 puts :: String -> IO ()
1751 puts s = do write_rawBuffer 1 (unsafeCoerce# (packCString# s)) 0 (fromIntegral (length s))
1752             return ()
1753 #endif
1754
1755 -- -----------------------------------------------------------------------------
1756 -- utils
1757
1758 throwErrnoIfMinus1RetryOnBlock  :: String -> IO CInt -> IO CInt -> IO CInt
1759 throwErrnoIfMinus1RetryOnBlock loc f on_block  =
1760   do
1761     res <- f
1762     if (res :: CInt) == -1
1763       then do
1764         err <- getErrno
1765         if err == eINTR
1766           then throwErrnoIfMinus1RetryOnBlock loc f on_block
1767           else if err == eWOULDBLOCK || err == eAGAIN
1768                  then do on_block
1769                  else throwErrno loc
1770       else return res
1771
1772 -- -----------------------------------------------------------------------------
1773 -- wrappers to platform-specific constants:
1774
1775 foreign import ccall unsafe "__hscore_supportsTextMode"
1776   tEXT_MODE_SEEK_ALLOWED :: Bool
1777
1778 foreign import ccall unsafe "__hscore_bufsiz"   dEFAULT_BUFFER_SIZE :: Int
1779 foreign import ccall unsafe "__hscore_seek_cur" sEEK_CUR :: CInt
1780 foreign import ccall unsafe "__hscore_seek_set" sEEK_SET :: CInt
1781 foreign import ccall unsafe "__hscore_seek_end" sEEK_END :: CInt