GHC/Handle.hs

   1 {-# OPTIONS_GHC -fno-implicit-prelude -#include "HsBase.h" #-}
   2
   3 #undef DEBUG_DUMP
   4 #undef DEBUG
   5
   6 -----------------------------------------------------------------------------
   7 -- |
   8 -- Module      :  GHC.Handle
   9 -- Copyright   :  (c) The University of Glasgow, 1994-2001
  10 -- License     :  see libraries/base/LICENSE
  11 --
  12 -- Maintainer  :  libraries@haskell.org
  13 -- Stability   :  internal
  14 -- Portability :  non-portable
  15 --
  16 -- This module defines the basic operations on I\/O \"handles\".
  17 --
  18 -----------------------------------------------------------------------------
  19
  20 -- #hide
  21 module GHC.Handle (
  22   withHandle, withHandle', withHandle_,
  23   wantWritableHandle, wantReadableHandle, wantSeekableHandle,
  24
  25   newEmptyBuffer, allocateBuffer, readCharFromBuffer, writeCharIntoBuffer,
  26   flushWriteBufferOnly, flushWriteBuffer, flushReadBuffer,
  27   fillReadBuffer, fillReadBufferWithoutBlocking,
  28   readRawBuffer, readRawBufferPtr,
  29   writeRawBuffer, writeRawBufferPtr,
  30
  31 #ifndef mingw32_HOST_OS
  32   unlockFile,
  33 #endif
  34
  35   ioe_closedHandle, ioe_EOF, ioe_notReadable, ioe_notWritable,
  36
  37   stdin, stdout, stderr,
  38   IOMode(..), openFile, openBinaryFile, openTempFile, openBinaryTempFile, openFd, fdToHandle,
  39   hFileSize, hSetFileSize, hIsEOF, isEOF, hLookAhead, hSetBuffering, hSetBinaryMode,
  40   hFlush, hDuplicate, hDuplicateTo,
  41
  42   hClose, hClose_help,
  43
  44   HandlePosition, HandlePosn(..), hGetPosn, hSetPosn,
  45   SeekMode(..), hSeek, hTell,
  46
  47   hIsOpen, hIsClosed, hIsReadable, hIsWritable, hGetBuffering, hIsSeekable,
  48   hSetEcho, hGetEcho, hIsTerminalDevice,
  49
  50   hShow,
  51
  52 #ifdef DEBUG_DUMP
  53   puts,
  54 #endif
  55
  56  ) where
  57
  58 import Control.Monad
  59 import Data.Bits
  60 import Data.Maybe
  61 import Foreign
  62 import Foreign.C
  63 import System.IO.Error
  64 import System.Posix.Internals
  65
  66 import GHC.Real
  67
  68 import GHC.Arr
  69 import GHC.Base
  70 import GHC.Read         ( Read )
  71 import GHC.List
  72 import GHC.IOBase
  73 import GHC.Exception
  74 import GHC.Enum
  75 import GHC.Num          ( Integer(..), Num(..) )
  76 import GHC.Show
  77 import GHC.Real         ( toInteger )
  78 #if defined(DEBUG_DUMP)
  79 import GHC.Pack
  80 #endif
  81
  82 import GHC.Conc
  83
  84 -- -----------------------------------------------------------------------------
  85 -- TODO:
  86
  87 -- hWaitForInput blocks (should use a timeout)
  88
  89 -- unbuffered hGetLine is a bit dodgy
  90
  91 -- hSetBuffering: can't change buffering on a stream,
  92 --      when the read buffer is non-empty? (no way to flush the buffer)
  93
  94 -- ---------------------------------------------------------------------------
  95 -- Are files opened by default in text or binary mode, if the user doesn't
  96 -- specify?
  97
  98 dEFAULT_OPEN_IN_BINARY_MODE = False :: Bool
  99
 100 -- ---------------------------------------------------------------------------
 101 -- Creating a new handle
 102
 103 newFileHandle :: FilePath -> (MVar Handle__ -> IO ()) -> Handle__ -> IO Handle
 104 newFileHandle filepath finalizer hc = do
 105   m <- newMVar hc
 106   addMVarFinalizer m (finalizer m)
 107   return (FileHandle filepath m)
 108
 109 -- ---------------------------------------------------------------------------
 110 -- Working with Handles
 111
 112 {-
 113 In the concurrent world, handles are locked during use.  This is done
 114 by wrapping an MVar around the handle which acts as a mutex over
 115 operations on the handle.
 116
 117 To avoid races, we use the following bracketing operations.  The idea
 118 is to obtain the lock, do some operation and replace the lock again,
 119 whether the operation succeeded or failed.  We also want to handle the
 120 case where the thread receives an exception while processing the IO
 121 operation: in these cases we also want to relinquish the lock.
 122
 123 There are three versions of @withHandle@: corresponding to the three
 124 possible combinations of:
 125
 126         - the operation may side-effect the handle
 127         - the operation may return a result
 128
 129 If the operation generates an error or an exception is raised, the
 130 original handle is always replaced [ this is the case at the moment,
 131 but we might want to revisit this in the future --SDM ].
 132 -}
 133
 134 {-# INLINE withHandle #-}
 135 withHandle :: String -> Handle -> (Handle__ -> IO (Handle__,a)) -> IO a
 136 withHandle fun h@(FileHandle _ m)     act = withHandle' fun h m act
 137 withHandle fun h@(DuplexHandle _ m _) act = withHandle' fun h m act
 138
 139 withHandle' :: String -> Handle -> MVar Handle__
 140    -> (Handle__ -> IO (Handle__,a)) -> IO a
 141 withHandle' fun h m act =
 142    block $ do
 143    h_ <- takeMVar m
 144    checkBufferInvariants h_
 145    (h',v)  <- catchException (act h_)
 146                 (\ err -> putMVar m h_ >>
 147                           case err of
 148                              IOException ex -> ioError (augmentIOError ex fun h)
 149                              _ -> throw err)
 150    checkBufferInvariants h'
 151    putMVar m h'
 152    return v
 153
 154 {-# INLINE withHandle_ #-}
 155 withHandle_ :: String -> Handle -> (Handle__ -> IO a) -> IO a
 156 withHandle_ fun h@(FileHandle _ m)     act = withHandle_' fun h m act
 157 withHandle_ fun h@(DuplexHandle _ m _) act = withHandle_' fun h m act
 158
 159 withHandle_' :: String -> Handle -> MVar Handle__ -> (Handle__ -> IO a) -> IO a
 160 withHandle_' fun h m act =
 161    block $ do
 162    h_ <- takeMVar m
 163    checkBufferInvariants h_
 164    v  <- catchException (act h_)
 165                 (\ err -> putMVar m h_ >>
 166                           case err of
 167                              IOException ex -> ioError (augmentIOError ex fun h)
 168                              _ -> throw err)
 169    checkBufferInvariants h_
 170    putMVar m h_
 171    return v
 172
 173 withAllHandles__ :: String -> Handle -> (Handle__ -> IO Handle__) -> IO ()
 174 withAllHandles__ fun h@(FileHandle _ m)     act = withHandle__' fun h m act
 175 withAllHandles__ fun h@(DuplexHandle _ r w) act = do
 176   withHandle__' fun h r act
 177   withHandle__' fun h w act
 178
 179 withHandle__' fun h m act =
 180    block $ do
 181    h_ <- takeMVar m
 182    checkBufferInvariants h_
 183    h'  <- catchException (act h_)
 184                 (\ err -> putMVar m h_ >>
 185                           case err of
 186                              IOException ex -> ioError (augmentIOError ex fun h)
 187                              _ -> throw err)
 188    checkBufferInvariants h'
 189    putMVar m h'
 190    return ()
 191
 192 augmentIOError (IOError _ iot _ str fp) fun h
 193   = IOError (Just h) iot fun str filepath
 194   where filepath
 195           | Just _ <- fp = fp
 196           | otherwise = case h of
 197                           FileHandle fp _     -> Just fp
 198                           DuplexHandle fp _ _ -> Just fp
 199
 200 -- ---------------------------------------------------------------------------
 201 -- Wrapper for write operations.
 202
 203 wantWritableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 204 wantWritableHandle fun h@(FileHandle _ m) act
 205   = wantWritableHandle' fun h m act
 206 wantWritableHandle fun h@(DuplexHandle _ _ m) act
 207   = wantWritableHandle' fun h m act
 208   -- ToDo: in the Duplex case, we don't need to checkWritableHandle
 209
 210 wantWritableHandle'
 211         :: String -> Handle -> MVar Handle__
 212         -> (Handle__ -> IO a) -> IO a
 213 wantWritableHandle' fun h m act
 214    = withHandle_' fun h m (checkWritableHandle act)
 215
 216 checkWritableHandle act handle_
 217   = case haType handle_ of
 218       ClosedHandle         -> ioe_closedHandle
 219       SemiClosedHandle     -> ioe_closedHandle
 220       ReadHandle           -> ioe_notWritable
 221       ReadWriteHandle      -> do
 222                 let ref = haBuffer handle_
 223                 buf <- readIORef ref
 224                 new_buf <-
 225                   if not (bufferIsWritable buf)
 226                      then do b <- flushReadBuffer (haFD handle_) buf
 227                              return b{ bufState=WriteBuffer }
 228                      else return buf
 229                 writeIORef ref new_buf
 230                 act handle_
 231       _other               -> act handle_
 232
 233 -- ---------------------------------------------------------------------------
 234 -- Wrapper for read operations.
 235
 236 wantReadableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 237 wantReadableHandle fun h@(FileHandle  _ m)   act
 238   = wantReadableHandle' fun h m act
 239 wantReadableHandle fun h@(DuplexHandle _ m _) act
 240   = wantReadableHandle' fun h m act
 241   -- ToDo: in the Duplex case, we don't need to checkReadableHandle
 242
 243 wantReadableHandle'
 244         :: String -> Handle -> MVar Handle__
 245         -> (Handle__ -> IO a) -> IO a
 246 wantReadableHandle' fun h m act
 247   = withHandle_' fun h m (checkReadableHandle act)
 248
 249 checkReadableHandle act handle_ =
 250     case haType handle_ of
 251       ClosedHandle         -> ioe_closedHandle
 252       SemiClosedHandle     -> ioe_closedHandle
 253       AppendHandle         -> ioe_notReadable
 254       WriteHandle          -> ioe_notReadable
 255       ReadWriteHandle      -> do
 256         let ref = haBuffer handle_
 257         buf <- readIORef ref
 258         when (bufferIsWritable buf) $ do
 259            new_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
 260            writeIORef ref new_buf{ bufState=ReadBuffer }
 261         act handle_
 262       _other               -> act handle_
 263
 264 -- ---------------------------------------------------------------------------
 265 -- Wrapper for seek operations.
 266
 267 wantSeekableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 268 wantSeekableHandle fun h@(DuplexHandle _ _ _) _act =
 269   ioException (IOError (Just h) IllegalOperation fun
 270                    "handle is not seekable" Nothing)
 271 wantSeekableHandle fun h@(FileHandle _ m) act =
 272   withHandle_' fun h m (checkSeekableHandle act)
 273
 274 checkSeekableHandle act handle_ =
 275     case haType handle_ of
 276       ClosedHandle      -> ioe_closedHandle
 277       SemiClosedHandle  -> ioe_closedHandle
 278       AppendHandle      -> ioe_notSeekable
 279       _  | haIsBin handle_ || tEXT_MODE_SEEK_ALLOWED -> act handle_
 280          | otherwise                                 -> ioe_notSeekable_notBin
 281
 282 -- -----------------------------------------------------------------------------
 283 -- Handy IOErrors
 284
 285 ioe_closedHandle, ioe_EOF,
 286   ioe_notReadable, ioe_notWritable,
 287   ioe_notSeekable, ioe_notSeekable_notBin :: IO a
 288
 289 ioe_closedHandle = ioException
 290    (IOError Nothing IllegalOperation ""
 291         "handle is closed" Nothing)
 292 ioe_EOF = ioException
 293    (IOError Nothing EOF "" "" Nothing)
 294 ioe_notReadable = ioException
 295    (IOError Nothing IllegalOperation ""
 296         "handle is not open for reading" Nothing)
 297 ioe_notWritable = ioException
 298    (IOError Nothing IllegalOperation ""
 299         "handle is not open for writing" Nothing)
 300 ioe_notSeekable = ioException
 301    (IOError Nothing IllegalOperation ""
 302         "handle is not seekable" Nothing)
 303 ioe_notSeekable_notBin = ioException
 304    (IOError Nothing IllegalOperation ""
 305       "seek operations on text-mode handles are not allowed on this platform"
 306         Nothing)
 307
 308 ioe_finalizedHandle fp = throw (IOException
 309    (IOError Nothing IllegalOperation ""
 310         "handle is finalized" (Just fp)))
 311
 312 ioe_bufsiz :: Int -> IO a
 313 ioe_bufsiz n = ioException
 314    (IOError Nothing InvalidArgument "hSetBuffering"
 315         ("illegal buffer size " ++ showsPrec 9 n []) Nothing)
 316                                 -- 9 => should be parens'ified.
 317
 318 -- -----------------------------------------------------------------------------
 319 -- Handle Finalizers
 320
 321 -- For a duplex handle, we arrange that the read side points to the write side
 322 -- (and hence keeps it alive if the read side is alive).  This is done by
 323 -- having the haOtherSide field of the read side point to the read side.
 324 -- The finalizer is then placed on the write side, and the handle only gets
 325 -- finalized once, when both sides are no longer required.
 326
 327 -- NOTE about finalized handles: It's possible that a handle can be
 328 -- finalized and then we try to use it later, for example if the
 329 -- handle is referenced from another finalizer, or from a thread that
 330 -- has become unreferenced and then resurrected (arguably in the
 331 -- latter case we shouldn't finalize the Handle...).  Anyway,
 332 -- we try to emit a helpful message which is better than nothing.
 333
 334 stdHandleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 335 stdHandleFinalizer fp m = do
 336   h_ <- takeMVar m
 337   flushWriteBufferOnly h_
 338   putMVar m (ioe_finalizedHandle fp)
 339
 340 handleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 341 handleFinalizer fp m = do
 342   handle_ <- takeMVar m
 343   case haType handle_ of
 344       ClosedHandle -> return ()
 345       _ -> do flushWriteBufferOnly handle_ `catchException` \_ -> return ()
 346                 -- ignore errors and async exceptions, and close the
 347                 -- descriptor anyway...
 348               hClose_handle_ handle_
 349               return ()
 350   putMVar m (ioe_finalizedHandle fp)
 351
 352 -- ---------------------------------------------------------------------------
 353 -- Grimy buffer operations
 354
 355 #ifdef DEBUG
 356 checkBufferInvariants h_ = do
 357  let ref = haBuffer h_
 358  Buffer{ bufWPtr=w, bufRPtr=r, bufSize=size, bufState=state } <- readIORef ref
 359  if not (
 360         size > 0
 361         && r <= w
 362         && w <= size
 363         && ( r /= w || (r == 0 && w == 0) )
 364         && ( state /= WriteBuffer || r == 0 )
 365         && ( state /= WriteBuffer || w < size ) -- write buffer is never full
 366      )
 367    then error "buffer invariant violation"
 368    else return ()
 369 #else
 370 checkBufferInvariants h_ = return ()
 371 #endif
 372
 373 newEmptyBuffer :: RawBuffer -> BufferState -> Int -> Buffer
 374 newEmptyBuffer b state size
 375   = Buffer{ bufBuf=b, bufRPtr=0, bufWPtr=0, bufSize=size, bufState=state }
 376
 377 allocateBuffer :: Int -> BufferState -> IO Buffer
 378 allocateBuffer sz@(I# size) state = IO $ \s ->
 379 #ifdef mingw32_HOST_OS
 380    -- To implement asynchronous I/O under Win32, we have to pass
 381    -- buffer references to external threads that handles the
 382    -- filling/emptying of their contents. Hence, the buffer cannot
 383    -- be moved around by the GC.
 384   case newPinnedByteArray# size s of { (# s, b #) ->
 385 #else
 386   case newByteArray# size s of { (# s, b #) ->
 387 #endif
 388   (# s, newEmptyBuffer b state sz #) }
 389
 390 writeCharIntoBuffer :: RawBuffer -> Int -> Char -> IO Int
 391 writeCharIntoBuffer slab (I# off) (C# c)
 392   = IO $ \s -> case writeCharArray# slab off c s of
 393                  s -> (# s, I# (off +# 1#) #)
 394
 395 readCharFromBuffer :: RawBuffer -> Int -> IO (Char, Int)
 396 readCharFromBuffer slab (I# off)
 397   = IO $ \s -> case readCharArray# slab off s of
 398                  (# s, c #) -> (# s, (C# c, I# (off +# 1#)) #)
 399
 400 getBuffer :: FD -> BufferState -> IO (IORef Buffer, BufferMode)
 401 getBuffer fd state = do
 402   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE state
 403   ioref  <- newIORef buffer
 404   is_tty <- fdIsTTY fd
 405
 406   let buffer_mode
 407          | is_tty    = LineBuffering
 408          | otherwise = BlockBuffering Nothing
 409
 410   return (ioref, buffer_mode)
 411
 412 mkUnBuffer :: IO (IORef Buffer)
 413 mkUnBuffer = do
 414   buffer <- allocateBuffer 1 ReadBuffer
 415   newIORef buffer
 416
 417 -- flushWriteBufferOnly flushes the buffer iff it contains pending write data.
 418 flushWriteBufferOnly :: Handle__ -> IO ()
 419 flushWriteBufferOnly h_ = do
 420   let fd = haFD h_
 421       ref = haBuffer h_
 422   buf <- readIORef ref
 423   new_buf <- if bufferIsWritable buf
 424                 then flushWriteBuffer fd (haIsStream h_) buf
 425                 else return buf
 426   writeIORef ref new_buf
 427
 428 -- flushBuffer syncs the file with the buffer, including moving the
 429 -- file pointer backwards in the case of a read buffer.
 430 flushBuffer :: Handle__ -> IO ()
 431 flushBuffer h_ = do
 432   let ref = haBuffer h_
 433   buf <- readIORef ref
 434
 435   flushed_buf <-
 436     case bufState buf of
 437       ReadBuffer  -> flushReadBuffer  (haFD h_) buf
 438       WriteBuffer -> flushWriteBuffer (haFD h_) (haIsStream h_) buf
 439
 440   writeIORef ref flushed_buf
 441
 442 -- When flushing a read buffer, we seek backwards by the number of
 443 -- characters in the buffer.  The file descriptor must therefore be
 444 -- seekable: attempting to flush the read buffer on an unseekable
 445 -- handle is not allowed.
 446
 447 flushReadBuffer :: FD -> Buffer -> IO Buffer
 448 flushReadBuffer fd buf
 449   | bufferEmpty buf = return buf
 450   | otherwise = do
 451      let off = negate (bufWPtr buf - bufRPtr buf)
 452 #    ifdef DEBUG_DUMP
 453      puts ("flushReadBuffer: new file offset = " ++ show off ++ "\n")
 454 #    endif
 455      throwErrnoIfMinus1Retry "flushReadBuffer"
 456          (c_lseek fd (fromIntegral off) sEEK_CUR)
 457      return buf{ bufWPtr=0, bufRPtr=0 }
 458
 459 flushWriteBuffer :: FD -> Bool -> Buffer -> IO Buffer
 460 flushWriteBuffer fd is_stream buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w }  =
 461   seq fd $ do -- strictness hack
 462   let bytes = w - r
 463 #ifdef DEBUG_DUMP
 464   puts ("flushWriteBuffer, fd=" ++ show fd ++ ", bytes=" ++ show bytes ++ "\n")
 465 #endif
 466   if bytes == 0
 467      then return (buf{ bufRPtr=0, bufWPtr=0 })
 468      else do
 469   res <- writeRawBuffer "flushWriteBuffer" fd is_stream b
 470                         (fromIntegral r) (fromIntegral bytes)
 471   let res' = fromIntegral res
 472   if res' < bytes
 473      then flushWriteBuffer fd is_stream (buf{ bufRPtr = r + res' })
 474      else return buf{ bufRPtr=0, bufWPtr=0 }
 475
 476 fillReadBuffer :: FD -> Bool -> Bool -> Buffer -> IO Buffer
 477 fillReadBuffer fd is_line is_stream
 478       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 479   -- buffer better be empty:
 480   assert (r == 0 && w == 0) $ do
 481   fillReadBufferLoop fd is_line is_stream buf b w size
 482
 483 -- For a line buffer, we just get the first chunk of data to arrive,
 484 -- and don't wait for the whole buffer to be full (but we *do* wait
 485 -- until some data arrives).  This isn't really line buffering, but it
 486 -- appears to be what GHC has done for a long time, and I suspect it
 487 -- is more useful than line buffering in most cases.
 488
 489 fillReadBufferLoop fd is_line is_stream buf b w size = do
 490   let bytes = size - w
 491   if bytes == 0  -- buffer full?
 492      then return buf{ bufRPtr=0, bufWPtr=w }
 493      else do
 494 #ifdef DEBUG_DUMP
 495   puts ("fillReadBufferLoop: bytes = " ++ show bytes ++ "\n")
 496 #endif
 497   res <- readRawBuffer "fillReadBuffer" fd is_stream b
 498                        (fromIntegral w) (fromIntegral bytes)
 499   let res' = fromIntegral res
 500 #ifdef DEBUG_DUMP
 501   puts ("fillReadBufferLoop:  res' = " ++ show res' ++ "\n")
 502 #endif
 503   if res' == 0
 504      then if w == 0
 505              then ioe_EOF
 506              else return buf{ bufRPtr=0, bufWPtr=w }
 507      else if res' < bytes && not is_line
 508              then fillReadBufferLoop fd is_line is_stream buf b (w+res') size
 509              else return buf{ bufRPtr=0, bufWPtr=w+res' }
 510
 511
 512 fillReadBufferWithoutBlocking :: FD -> Bool -> Buffer -> IO Buffer
 513 fillReadBufferWithoutBlocking fd is_stream
 514       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 515   -- buffer better be empty:
 516   assert (r == 0 && w == 0) $ do
 517 #ifdef DEBUG_DUMP
 518   puts ("fillReadBufferLoopNoBlock: bytes = " ++ show size ++ "\n")
 519 #endif
 520   res <- readRawBufferNoBlock "fillReadBuffer" fd is_stream b
 521                        0 (fromIntegral size)
 522   let res' = fromIntegral res
 523 #ifdef DEBUG_DUMP
 524   puts ("fillReadBufferLoopNoBlock:  res' = " ++ show res' ++ "\n")
 525 #endif
 526   return buf{ bufRPtr=0, bufWPtr=res' }
 527
 528 -- Low level routines for reading/writing to (raw)buffers:
 529
 530 #ifndef mingw32_HOST_OS
 531
 532 {-
 533 NOTE [nonblock]:
 534
 535 Unix has broken semantics when it comes to non-blocking I/O: you can
 536 set the O_NONBLOCK flag on an FD, but it applies to the all other FDs
 537 attached to the same underlying file, pipe or TTY; there's no way to
 538 have private non-blocking behaviour for an FD.  See bug #724.
 539
 540 We fix this by only setting O_NONBLOCK on FDs that we create; FDs that
 541 come from external sources or are exposed externally are left in
 542 blocking mode.  This solution has some problems though.  We can't
 543 completely simulate a non-blocking read without O_NONBLOCK: several
 544 cases are wrong here.  The cases that are wrong:
 545
 546   * reading/writing to a blocking FD in non-threaded mode.
 547     In threaded mode, we just make a safe call to read().
 548     In non-threaded mode we call select() before attempting to read,
 549     but that leaves a small race window where the data can be read
 550     from the file descriptor before we issue our blocking read().
 551   * readRawBufferNoBlock for a blocking FD
 552 -}
 553
 554 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 555 readRawBuffer loc fd is_nonblock buf off len
 556   | is_nonblock  = unsafe_read
 557   | threaded     = safe_read
 558   | otherwise    = do r <- throwErrnoIfMinus1 loc
 559                                 (fdReady (fromIntegral fd) 0 0 False)
 560                       if r /= 0
 561                         then unsafe_read
 562                         else do threadWaitRead (fromIntegral fd); unsafe_read
 563   where
 564     do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 565                             (threadWaitRead (fromIntegral fd))
 566     unsafe_read = do_read (read_rawBuffer fd buf off len)
 567     safe_read   = do_read (safe_read_rawBuffer fd buf off len)
 568
 569 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 570 readRawBufferPtr loc fd is_nonblock buf off len
 571   | is_nonblock  = unsafe_read
 572   | threaded     = safe_read
 573   | otherwise    = do r <- throwErrnoIfMinus1 loc
 574                                 (fdReady (fromIntegral fd) 0 0 False)
 575                       if r /= 0
 576                         then unsafe_read
 577                         else do threadWaitRead (fromIntegral fd); unsafe_read
 578   where
 579         do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 580                                 (threadWaitRead (fromIntegral fd))
 581         unsafe_read = do_read (read_off fd buf off len)
 582         safe_read   = do_read (safe_read_off fd buf off len)
 583
 584 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 585 readRawBufferNoBlock loc fd is_nonblock buf off len
 586   | is_nonblock  = unsafe_read
 587   | otherwise    = do r <- fdReady (fromIntegral fd) 0 0 False
 588                       if r /= 0 then safe_read
 589                                 else return 0
 590        -- XXX see note [nonblock]
 591  where
 592    do_read call = throwErrnoIfMinus1RetryMayBlock loc call (return 0)
 593    unsafe_read  = do_read (read_rawBuffer fd buf off len)
 594    safe_read    = do_read (safe_read_rawBuffer fd buf off len)
 595
 596 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 597 writeRawBuffer loc fd is_nonblock buf off len
 598   | is_nonblock = unsafe_write
 599   | threaded    = safe_write
 600   | otherwise   = do r <- fdReady (fromIntegral fd) 1 0 False
 601                      if r /= 0 then safe_write
 602                                 else return 0
 603   where
 604     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 605                         (threadWaitWrite (fromIntegral fd))
 606     unsafe_write = do_write (write_rawBuffer fd buf off len)
 607     safe_write   = do_write (safe_write_rawBuffer (fromIntegral fd) buf off len)
 608
 609 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 610 writeRawBufferPtr loc fd is_nonblock buf off len
 611   | is_nonblock = unsafe_write
 612   | threaded    = safe_write
 613   | otherwise   = do r <- fdReady (fromIntegral fd) 1 0 False
 614                      if r /= 0 then safe_write
 615                                 else return 0
 616   where
 617     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 618                         (threadWaitWrite (fromIntegral fd))
 619     unsafe_write  = do_write (write_off fd buf off len)
 620     safe_write    = do_write (safe_write_off (fromIntegral fd) buf off len)
 621
 622 foreign import ccall unsafe "__hscore_PrelHandle_read"
 623    read_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 624
 625 foreign import ccall unsafe "__hscore_PrelHandle_read"
 626    read_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 627
 628 foreign import ccall unsafe "__hscore_PrelHandle_write"
 629    write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 630
 631 foreign import ccall unsafe "__hscore_PrelHandle_write"
 632    write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 633
 634 foreign import ccall safe "fdReady"
 635   fdReady :: CInt -> CInt -> CInt -> Bool -> IO CInt
 636
 637 #else /* mingw32_HOST_OS.... */
 638
 639 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 640 readRawBuffer loc fd is_stream buf off len
 641   | threaded  = blockingReadRawBuffer loc fd is_stream buf off len
 642   | otherwise = asyncReadRawBuffer loc fd is_stream buf off len
 643
 644 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 645 readRawBufferPtr loc fd is_stream buf off len
 646   | threaded  = blockingReadRawBufferPtr loc fd is_stream buf off len
 647   | otherwise = asyncReadRawBufferPtr loc fd is_stream buf off len
 648
 649 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 650 writeRawBuffer loc fd is_stream buf off len
 651   | threaded =  blockingWriteRawBuffer loc fd is_stream buf off len
 652   | otherwise = asyncWriteRawBuffer    loc fd is_stream buf off len
 653
 654 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 655 writeRawBufferPtr loc fd is_stream buf off len
 656   | threaded  = blockingWriteRawBufferPtr loc fd is_stream buf off len
 657   | otherwise = asyncWriteRawBufferPtr    loc fd is_stream buf off len
 658
 659 -- ToDo: we don't have a non-blocking primitve read on Win32
 660 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 661 readRawBufferNoBlock = readRawBuffer
 662
 663 -- Async versions of the read/write primitives, for the non-threaded RTS
 664
 665 asyncReadRawBuffer loc fd is_stream buf off len = do
 666     (l, rc) <- asyncReadBA (fromIntegral fd) (if is_stream then 1 else 0)
 667                  (fromIntegral len) off buf
 668     if l == (-1)
 669       then
 670         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 671       else return (fromIntegral l)
 672
 673 asyncReadRawBufferPtr loc fd is_stream buf off len = do
 674     (l, rc) <- asyncRead (fromIntegral fd) (if is_stream then 1 else 0)
 675                         (fromIntegral len) (buf `plusPtr` off)
 676     if l == (-1)
 677       then
 678         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 679       else return (fromIntegral l)
 680
 681 asyncWriteRawBuffer loc fd is_stream buf off len = do
 682     (l, rc) <- asyncWriteBA (fromIntegral fd) (if is_stream then 1 else 0)
 683                         (fromIntegral len) off buf
 684     if l == (-1)
 685       then
 686         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 687       else return (fromIntegral l)
 688
 689 asyncWriteRawBufferPtr loc fd is_stream buf off len = do
 690     (l, rc) <- asyncWrite (fromIntegral fd) (if is_stream then 1 else 0)
 691                   (fromIntegral len) (buf `plusPtr` off)
 692     if l == (-1)
 693       then
 694         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 695       else return (fromIntegral l)
 696
 697 -- Blocking versions of the read/write primitives, for the threaded RTS
 698
 699 blockingReadRawBuffer loc fd True buf off len =
 700   throwErrnoIfMinus1Retry loc $
 701     safe_recv_rawBuffer fd buf off len
 702 blockingReadRawBuffer loc fd False buf off len =
 703   throwErrnoIfMinus1Retry loc $
 704     safe_read_rawBuffer fd buf off len
 705
 706 blockingReadRawBufferPtr loc fd True buf off len =
 707   throwErrnoIfMinus1Retry loc $
 708     safe_recv_off fd buf off len
 709 blockingReadRawBufferPtr loc fd False buf off len =
 710   throwErrnoIfMinus1Retry loc $
 711     safe_read_off fd buf off len
 712
 713 blockingWriteRawBuffer loc fd True buf off len =
 714   throwErrnoIfMinus1Retry loc $
 715     safe_send_rawBuffer fd buf off len
 716 blockingWriteRawBuffer loc fd False buf off len =
 717   throwErrnoIfMinus1Retry loc $
 718     safe_write_rawBuffer fd buf off len
 719
 720 blockingWriteRawBufferPtr loc fd True buf off len =
 721   throwErrnoIfMinus1Retry loc $
 722     safe_send_off fd buf off len
 723 blockingWriteRawBufferPtr loc fd False buf off len =
 724   throwErrnoIfMinus1Retry loc $
 725     safe_write_off fd buf off len
 726
 727 -- NOTE: "safe" versions of the read/write calls for use by the threaded RTS.
 728 -- These calls may block, but that's ok.
 729
 730 foreign import ccall safe "__hscore_PrelHandle_recv"
 731    safe_recv_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 732
 733 foreign import ccall safe "__hscore_PrelHandle_recv"
 734    safe_recv_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 735
 736 foreign import ccall safe "__hscore_PrelHandle_send"
 737    safe_send_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 738
 739 foreign import ccall safe "__hscore_PrelHandle_send"
 740    safe_send_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 741
 742 #endif
 743
 744 foreign import ccall "rtsSupportsBoundThreads" threaded :: Bool
 745
 746 foreign import ccall safe "__hscore_PrelHandle_read"
 747    safe_read_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 748
 749 foreign import ccall safe "__hscore_PrelHandle_read"
 750    safe_read_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 751
 752 foreign import ccall safe "__hscore_PrelHandle_write"
 753    safe_write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 754
 755 foreign import ccall safe "__hscore_PrelHandle_write"
 756    safe_write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 757
 758 -- ---------------------------------------------------------------------------
 759 -- Standard Handles
 760
 761 -- Three handles are allocated during program initialisation.  The first
 762 -- two manage input or output from the Haskell program's standard input
 763 -- or output channel respectively.  The third manages output to the
 764 -- standard error channel. These handles are initially open.
 765
 766 fd_stdin  = 0 :: FD
 767 fd_stdout = 1 :: FD
 768 fd_stderr = 2 :: FD
 769
 770 -- | A handle managing input from the Haskell program's standard input channel.
 771 stdin :: Handle
 772 stdin = unsafePerformIO $ do
 773    -- ToDo: acquire lock
 774    -- We don't set non-blocking mode on standard handles, because it may
 775    -- confuse other applications attached to the same TTY/pipe
 776    -- see Note [nonblock]
 777    (buf, bmode) <- getBuffer fd_stdin ReadBuffer
 778    mkStdHandle fd_stdin "<stdin>" ReadHandle buf bmode
 779
 780 -- | A handle managing output to the Haskell program's standard output channel.
 781 stdout :: Handle
 782 stdout = unsafePerformIO $ do
 783    -- ToDo: acquire lock
 784    -- We don't set non-blocking mode on standard handles, because it may
 785    -- confuse other applications attached to the same TTY/pipe
 786    -- see Note [nonblock]
 787    (buf, bmode) <- getBuffer fd_stdout WriteBuffer
 788    mkStdHandle fd_stdout "<stdout>" WriteHandle buf bmode
 789
 790 -- | A handle managing output to the Haskell program's standard error channel.
 791 stderr :: Handle
 792 stderr = unsafePerformIO $ do
 793     -- ToDo: acquire lock
 794    -- We don't set non-blocking mode on standard handles, because it may
 795    -- confuse other applications attached to the same TTY/pipe
 796    -- see Note [nonblock]
 797    buf <- mkUnBuffer
 798    mkStdHandle fd_stderr "<stderr>" WriteHandle buf NoBuffering
 799
 800 -- ---------------------------------------------------------------------------
 801 -- Opening and Closing Files
 802
 803 addFilePathToIOError fun fp (IOError h iot _ str _)
 804   = IOError h iot fun str (Just fp)
 805
 806 -- | Computation 'openFile' @file mode@ allocates and returns a new, open
 807 -- handle to manage the file @file@.  It manages input if @mode@
 808 -- is 'ReadMode', output if @mode@ is 'WriteMode' or 'AppendMode',
 809 -- and both input and output if mode is 'ReadWriteMode'.
 810 --
 811 -- If the file does not exist and it is opened for output, it should be
 812 -- created as a new file.  If @mode@ is 'WriteMode' and the file
 813 -- already exists, then it should be truncated to zero length.
 814 -- Some operating systems delete empty files, so there is no guarantee
 815 -- that the file will exist following an 'openFile' with @mode@
 816 -- 'WriteMode' unless it is subsequently written to successfully.
 817 -- The handle is positioned at the end of the file if @mode@ is
 818 -- 'AppendMode', and otherwise at the beginning (in which case its
 819 -- internal position is 0).
 820 -- The initial buffer mode is implementation-dependent.
 821 --
 822 -- This operation may fail with:
 823 --
 824 --  * 'isAlreadyInUseError' if the file is already open and cannot be reopened;
 825 --
 826 --  * 'isDoesNotExistError' if the file does not exist; or
 827 --
 828 --  * 'isPermissionError' if the user does not have permission to open the file.
 829 --
 830 -- Note: if you will be working with files containing binary data, you'll want to
 831 -- be using 'openBinaryFile'.
 832 openFile :: FilePath -> IOMode -> IO Handle
 833 openFile fp im =
 834   catch
 835     (openFile' fp im dEFAULT_OPEN_IN_BINARY_MODE)
 836     (\e -> ioError (addFilePathToIOError "openFile" fp e))
 837
 838 -- | Like 'openFile', but open the file in binary mode.
 839 -- On Windows, reading a file in text mode (which is the default)
 840 -- will translate CRLF to LF, and writing will translate LF to CRLF.
 841 -- This is usually what you want with text files.  With binary files
 842 -- this is undesirable; also, as usual under Microsoft operating systems,
 843 -- text mode treats control-Z as EOF.  Binary mode turns off all special
 844 -- treatment of end-of-line and end-of-file characters.
 845 -- (See also 'hSetBinaryMode'.)
 846
 847 openBinaryFile :: FilePath -> IOMode -> IO Handle
 848 openBinaryFile fp m =
 849   catch
 850     (openFile' fp m True)
 851     (\e -> ioError (addFilePathToIOError "openBinaryFile" fp e))
 852
 853 openFile' filepath mode binary =
 854   withCString filepath $ \ f ->
 855
 856     let
 857       oflags1 = case mode of
 858                   ReadMode      -> read_flags
 859 #ifdef mingw32_HOST_OS
 860                   WriteMode     -> write_flags .|. o_TRUNC
 861 #else
 862                   WriteMode     -> write_flags
 863 #endif
 864                   ReadWriteMode -> rw_flags
 865                   AppendMode    -> append_flags
 866
 867       binary_flags
 868           | binary    = o_BINARY
 869           | otherwise = 0
 870
 871       oflags = oflags1 .|. binary_flags
 872     in do
 873
 874     -- the old implementation had a complicated series of three opens,
 875     -- which is perhaps because we have to be careful not to open
 876     -- directories.  However, the man pages I've read say that open()
 877     -- always returns EISDIR if the file is a directory and was opened
 878     -- for writing, so I think we're ok with a single open() here...
 879     fd <- throwErrnoIfMinus1Retry "openFile"
 880                 (c_open f (fromIntegral oflags) 0o666)
 881
 882     fd_type <- fdType fd
 883
 884     h <- openFd fd (Just fd_type) False filepath mode binary
 885             `catchException` \e -> do c_close fd; throw e
 886         -- NB. don't forget to close the FD if openFd fails, otherwise
 887         -- this FD leaks.
 888         -- ASSERT: if we just created the file, then openFd won't fail
 889         -- (so we don't need to worry about removing the newly created file
 890         --  in the event of an error).
 891
 892 #ifndef mingw32_HOST_OS
 893         -- we want to truncate() if this is an open in WriteMode, but only
 894         -- if the target is a RegularFile.  ftruncate() fails on special files
 895         -- like /dev/null.
 896     if mode == WriteMode && fd_type == RegularFile
 897       then throwErrnoIf (/=0) "openFile"
 898               (c_ftruncate fd 0)
 899       else return 0
 900 #endif
 901     return h
 902
 903
 904 -- | The function creates a temporary file in ReadWrite mode.
 905 -- The created file isn\'t deleted automatically, so you need to delete it manually.
 906 openTempFile :: FilePath   -- ^ Directory in which to create the file
 907              -> String     -- ^ File name template. If the template is \"foo.ext\" then
 908                            -- the create file will be \"fooXXX.ext\" where XXX is some
 909                            -- random number.
 910              -> IO (FilePath, Handle)
 911 openTempFile tmp_dir template = openTempFile' "openTempFile" tmp_dir template dEFAULT_OPEN_IN_BINARY_MODE
 912
 913 -- | Like 'openTempFile', but opens the file in binary mode. See 'openBinaryFile' for more comments.
 914 openBinaryTempFile :: FilePath -> String -> IO (FilePath, Handle)
 915 openBinaryTempFile tmp_dir template = openTempFile' "openBinaryTempFile" tmp_dir template True
 916
 917 openTempFile' :: String -> FilePath -> String -> Bool -> IO (FilePath, Handle)
 918 openTempFile' loc tmp_dir template binary = do
 919   pid <- c_getpid
 920   findTempName pid
 921   where
 922     (prefix,suffix) = break (=='.') template
 923
 924     oflags1 = rw_flags .|. o_EXCL
 925
 926     binary_flags
 927       | binary    = o_BINARY
 928       | otherwise = 0
 929
 930     oflags = oflags1 .|. binary_flags
 931
 932     findTempName x = do
 933       fd <- withCString filepath $ \ f ->
 934               c_open f oflags 0o666
 935       if fd < 0
 936        then do
 937          errno <- getErrno
 938          if errno == eEXIST
 939            then findTempName (x+1)
 940            else ioError (errnoToIOError loc errno Nothing (Just tmp_dir))
 941        else do
 942          h <- openFd fd Nothing False filepath ReadWriteMode True
 943                 `catchException` \e -> do c_close fd; throw e
 944          return (filepath, h)
 945       where
 946         filename        = prefix ++ show x ++ suffix
 947         filepath        = tmp_dir ++ [pathSeparator] ++ filename
 948
 949 pathSeparator :: Char
 950 #ifdef mingw32_HOST_OS
 951 pathSeparator = '\\'
 952 #else
 953 pathSeparator = '/'
 954 #endif
 955
 956 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 957 output_flags = std_flags    .|. o_CREAT
 958 read_flags   = std_flags    .|. o_RDONLY
 959 write_flags  = output_flags .|. o_WRONLY
 960 rw_flags     = output_flags .|. o_RDWR
 961 append_flags = write_flags  .|. o_APPEND
 962
 963 -- ---------------------------------------------------------------------------
 964 -- openFd
 965
 966 openFd :: FD -> Maybe FDType -> Bool -> FilePath -> IOMode -> Bool -> IO Handle
 967 openFd fd mb_fd_type is_socket filepath mode binary = do
 968     -- turn on non-blocking mode
 969     setNonBlockingFD fd
 970
 971 #ifdef mingw32_HOST_OS
 972     -- On Windows, the is_stream flag indicates that the Handle is a socket
 973     let is_stream = is_socket
 974 #else
 975     -- On Unix, the is_stream flag indicates that the FD is non-blocking
 976     let is_stream = True
 977 #endif
 978
 979     let (ha_type, write) =
 980           case mode of
 981             ReadMode      -> ( ReadHandle,      False )
 982             WriteMode     -> ( WriteHandle,     True )
 983             ReadWriteMode -> ( ReadWriteHandle, True )
 984             AppendMode    -> ( AppendHandle,    True )
 985
 986     -- open() won't tell us if it was a directory if we only opened for
 987     -- reading, so check again.
 988     fd_type <-
 989       case mb_fd_type of
 990         Just x  -> return x
 991         Nothing -> fdType fd
 992
 993     case fd_type of
 994         Directory ->
 995            ioException (IOError Nothing InappropriateType "openFile"
 996                            "is a directory" Nothing)
 997
 998         -- regular files need to be locked
 999         RegularFile -> do
1000 #ifndef mingw32_HOST_OS
1001            r <- lockFile fd (fromBool write) 1{-exclusive-}
1002            when (r == -1)  $
1003                 ioException (IOError Nothing ResourceBusy "openFile"
1004                                    "file is locked" Nothing)
1005 #endif
1006            mkFileHandle fd is_stream filepath ha_type binary
1007
1008         Stream
1009            -- only *Streams* can be DuplexHandles.  Other read/write
1010            -- Handles must share a buffer.
1011            | ReadWriteHandle <- ha_type ->
1012                 mkDuplexHandle fd is_stream filepath binary
1013            | otherwise ->
1014                 mkFileHandle   fd is_stream filepath ha_type binary
1015
1016         RawDevice ->
1017                 mkFileHandle fd is_stream filepath ha_type binary
1018
1019 fdToHandle :: FD -> IO Handle
1020 fdToHandle fd = do
1021    mode <- fdGetMode fd
1022    let fd_str = "<file descriptor: " ++ show fd ++ ">"
1023    openFd fd Nothing False{-XXX!-} fd_str mode True{-bin mode-}
1024
1025
1026 #ifndef mingw32_HOST_OS
1027 foreign import ccall unsafe "lockFile"
1028   lockFile :: CInt -> CInt -> CInt -> IO CInt
1029
1030 foreign import ccall unsafe "unlockFile"
1031   unlockFile :: CInt -> IO CInt
1032 #endif
1033
1034 mkStdHandle :: FD -> FilePath -> HandleType -> IORef Buffer -> BufferMode
1035         -> IO Handle
1036 mkStdHandle fd filepath ha_type buf bmode = do
1037    spares <- newIORef BufferListNil
1038    newFileHandle filepath (stdHandleFinalizer filepath)
1039             (Handle__ { haFD = fd,
1040                         haType = ha_type,
1041                         haIsBin = dEFAULT_OPEN_IN_BINARY_MODE,
1042                         haIsStream = False, -- means FD is blocking on Unix
1043                         haBufferMode = bmode,
1044                         haBuffer = buf,
1045                         haBuffers = spares,
1046                         haOtherSide = Nothing
1047                       })
1048
1049 mkFileHandle :: FD -> Bool -> FilePath -> HandleType -> Bool -> IO Handle
1050 mkFileHandle fd is_stream filepath ha_type binary = do
1051   (buf, bmode) <- getBuffer fd (initBufferState ha_type)
1052
1053 #ifdef mingw32_HOST_OS
1054   -- On Windows, if this is a read/write handle and we are in text mode,
1055   -- turn off buffering.  We don't correctly handle the case of switching
1056   -- from read mode to write mode on a buffered text-mode handle, see bug
1057   -- \#679.
1058   bmode <- case ha_type of
1059                 ReadWriteHandle | not binary -> return NoBuffering
1060                 _other                       -> return bmode
1061 #endif
1062
1063   spares <- newIORef BufferListNil
1064   newFileHandle filepath (handleFinalizer filepath)
1065             (Handle__ { haFD = fd,
1066                         haType = ha_type,
1067                         haIsBin = binary,
1068                         haIsStream = is_stream,
1069                         haBufferMode = bmode,
1070                         haBuffer = buf,
1071                         haBuffers = spares,
1072                         haOtherSide = Nothing
1073                       })
1074
1075 mkDuplexHandle :: FD -> Bool -> FilePath -> Bool -> IO Handle
1076 mkDuplexHandle fd is_stream filepath binary = do
1077   (w_buf, w_bmode) <- getBuffer fd WriteBuffer
1078   w_spares <- newIORef BufferListNil
1079   let w_handle_ =
1080              Handle__ { haFD = fd,
1081                         haType = WriteHandle,
1082                         haIsBin = binary,
1083                         haIsStream = is_stream,
1084                         haBufferMode = w_bmode,
1085                         haBuffer = w_buf,
1086                         haBuffers = w_spares,
1087                         haOtherSide = Nothing
1088                       }
1089   write_side <- newMVar w_handle_
1090
1091   (r_buf, r_bmode) <- getBuffer fd ReadBuffer
1092   r_spares <- newIORef BufferListNil
1093   let r_handle_ =
1094              Handle__ { haFD = fd,
1095                         haType = ReadHandle,
1096                         haIsBin = binary,
1097                         haIsStream = is_stream,
1098                         haBufferMode = r_bmode,
1099                         haBuffer = r_buf,
1100                         haBuffers = r_spares,
1101                         haOtherSide = Just write_side
1102                       }
1103   read_side <- newMVar r_handle_
1104
1105   addMVarFinalizer write_side (handleFinalizer filepath write_side)
1106   return (DuplexHandle filepath read_side write_side)
1107
1108
1109 initBufferState ReadHandle = ReadBuffer
1110 initBufferState _          = WriteBuffer
1111
1112 -- ---------------------------------------------------------------------------
1113 -- Closing a handle
1114
1115 -- | Computation 'hClose' @hdl@ makes handle @hdl@ closed.  Before the
1116 -- computation finishes, if @hdl@ is writable its buffer is flushed as
1117 -- for 'hFlush'.
1118 -- Performing 'hClose' on a handle that has already been closed has no effect;
1119 -- doing so not an error.  All other operations on a closed handle will fail.
1120 -- If 'hClose' fails for any reason, any further operations (apart from
1121 -- 'hClose') on the handle will still fail as if @hdl@ had been successfully
1122 -- closed.
1123
1124 hClose :: Handle -> IO ()
1125 hClose h@(FileHandle _ m)     = hClose' h m
1126 hClose h@(DuplexHandle _ r w) = hClose' h w >> hClose' h r
1127
1128 hClose' h m = withHandle__' "hClose" h m $ hClose_help
1129
1130 -- hClose_help is also called by lazyRead (in PrelIO) when EOF is read
1131 -- or an IO error occurs on a lazy stream.  The semi-closed Handle is
1132 -- then closed immediately.  We have to be careful with DuplexHandles
1133 -- though: we have to leave the closing to the finalizer in that case,
1134 -- because the write side may still be in use.
1135 hClose_help :: Handle__ -> IO Handle__
1136 hClose_help handle_ =
1137   case haType handle_ of
1138       ClosedHandle -> return handle_
1139       _ -> do flushWriteBufferOnly handle_ -- interruptible
1140               hClose_handle_ handle_
1141
1142 hClose_handle_ handle_ = do
1143     let fd = haFD handle_
1144
1145     -- close the file descriptor, but not when this is the read
1146     -- side of a duplex handle.
1147     case haOtherSide handle_ of
1148       Nothing ->
1149                   throwErrnoIfMinus1Retry_ "hClose"
1150 #ifdef mingw32_HOST_OS
1151                                 (closeFd (haIsStream handle_) fd)
1152 #else
1153                                 (c_close fd)
1154 #endif
1155       Just _  -> return ()
1156
1157     -- free the spare buffers
1158     writeIORef (haBuffers handle_) BufferListNil
1159
1160 #ifndef mingw32_HOST_OS
1161     -- unlock it
1162     unlockFile fd
1163 #endif
1164
1165     -- we must set the fd to -1, because the finalizer is going
1166     -- to run eventually and try to close/unlock it.
1167     return (handle_{ haFD        = -1,
1168                      haType      = ClosedHandle
1169                    })
1170
1171 -----------------------------------------------------------------------------
1172 -- Detecting and changing the size of a file
1173
1174 -- | For a handle @hdl@ which attached to a physical file,
1175 -- 'hFileSize' @hdl@ returns the size of that file in 8-bit bytes.
1176
1177 hFileSize :: Handle -> IO Integer
1178 hFileSize handle =
1179     withHandle_ "hFileSize" handle $ \ handle_ -> do
1180     case haType handle_ of
1181       ClosedHandle              -> ioe_closedHandle
1182       SemiClosedHandle          -> ioe_closedHandle
1183       _ -> do flushWriteBufferOnly handle_
1184               r <- fdFileSize (haFD handle_)
1185               if r /= -1
1186                  then return r
1187                  else ioException (IOError Nothing InappropriateType "hFileSize"
1188                                    "not a regular file" Nothing)
1189
1190
1191 -- | 'hSetFileSize' @hdl@ @size@ truncates the physical file with handle @hdl@ to @size@ bytes.
1192
1193 hSetFileSize :: Handle -> Integer -> IO ()
1194 hSetFileSize handle size =
1195     withHandle_ "hSetFileSize" handle $ \ handle_ -> do
1196     case haType handle_ of
1197       ClosedHandle              -> ioe_closedHandle
1198       SemiClosedHandle          -> ioe_closedHandle
1199       _ -> do flushWriteBufferOnly handle_
1200               throwErrnoIf (/=0) "hSetFileSize"
1201                  (c_ftruncate (haFD handle_) (fromIntegral size))
1202               return ()
1203
1204 -- ---------------------------------------------------------------------------
1205 -- Detecting the End of Input
1206
1207 -- | For a readable handle @hdl@, 'hIsEOF' @hdl@ returns
1208 -- 'True' if no further input can be taken from @hdl@ or for a
1209 -- physical file, if the current I\/O position is equal to the length of
1210 -- the file.  Otherwise, it returns 'False'.
1211
1212 hIsEOF :: Handle -> IO Bool
1213 hIsEOF handle =
1214   catch
1215      (do hLookAhead handle; return False)
1216      (\e -> if isEOFError e then return True else ioError e)
1217
1218 -- | The computation 'isEOF' is identical to 'hIsEOF',
1219 -- except that it works only on 'stdin'.
1220
1221 isEOF :: IO Bool
1222 isEOF = hIsEOF stdin
1223
1224 -- ---------------------------------------------------------------------------
1225 -- Looking ahead
1226
1227 -- | Computation 'hLookAhead' returns the next character from the handle
1228 -- without removing it from the input buffer, blocking until a character
1229 -- is available.
1230 --
1231 -- This operation may fail with:
1232 --
1233 --  * 'isEOFError' if the end of file has been reached.
1234
1235 hLookAhead :: Handle -> IO Char
1236 hLookAhead handle = do
1237   wantReadableHandle "hLookAhead"  handle $ \handle_ -> do
1238   let ref     = haBuffer handle_
1239       fd      = haFD handle_
1240       is_line = haBufferMode handle_ == LineBuffering
1241   buf <- readIORef ref
1242
1243   -- fill up the read buffer if necessary
1244   new_buf <- if bufferEmpty buf
1245                 then fillReadBuffer fd True (haIsStream handle_) buf
1246                 else return buf
1247
1248   writeIORef ref new_buf
1249
1250   (c,_) <- readCharFromBuffer (bufBuf buf) (bufRPtr buf)
1251   return c
1252
1253 -- ---------------------------------------------------------------------------
1254 -- Buffering Operations
1255
1256 -- Three kinds of buffering are supported: line-buffering,
1257 -- block-buffering or no-buffering.  See GHC.IOBase for definition and
1258 -- further explanation of what the type represent.
1259
1260 -- | Computation 'hSetBuffering' @hdl mode@ sets the mode of buffering for
1261 -- handle @hdl@ on subsequent reads and writes.
1262 --
1263 -- If the buffer mode is changed from 'BlockBuffering' or
1264 -- 'LineBuffering' to 'NoBuffering', then
1265 --
1266 --  * if @hdl@ is writable, the buffer is flushed as for 'hFlush';
1267 --
1268 --  * if @hdl@ is not writable, the contents of the buffer is discarded.
1269 --
1270 -- This operation may fail with:
1271 --
1272 --  * 'isPermissionError' if the handle has already been used for reading
1273 --    or writing and the implementation does not allow the buffering mode
1274 --    to be changed.
1275
1276 hSetBuffering :: Handle -> BufferMode -> IO ()
1277 hSetBuffering handle mode =
1278   withAllHandles__ "hSetBuffering" handle $ \ handle_ -> do
1279   case haType handle_ of
1280     ClosedHandle -> ioe_closedHandle
1281     _ -> do
1282          {- Note:
1283             - we flush the old buffer regardless of whether
1284               the new buffer could fit the contents of the old buffer
1285               or not.
1286             - allow a handle's buffering to change even if IO has
1287               occurred (ANSI C spec. does not allow this, nor did
1288               the previous implementation of IO.hSetBuffering).
1289             - a non-standard extension is to allow the buffering
1290               of semi-closed handles to change [sof 6/98]
1291           -}
1292           flushBuffer handle_
1293
1294           let state = initBufferState (haType handle_)
1295           new_buf <-
1296             case mode of
1297                 -- we always have a 1-character read buffer for
1298                 -- unbuffered  handles: it's needed to
1299                 -- support hLookAhead.
1300               NoBuffering            -> allocateBuffer 1 ReadBuffer
1301               LineBuffering          -> allocateBuffer dEFAULT_BUFFER_SIZE state
1302               BlockBuffering Nothing -> allocateBuffer dEFAULT_BUFFER_SIZE state
1303               BlockBuffering (Just n) | n <= 0    -> ioe_bufsiz n
1304                                       | otherwise -> allocateBuffer n state
1305           writeIORef (haBuffer handle_) new_buf
1306
1307           -- for input terminals we need to put the terminal into
1308           -- cooked or raw mode depending on the type of buffering.
1309           is_tty <- fdIsTTY (haFD handle_)
1310           when (is_tty && isReadableHandleType (haType handle_)) $
1311                 case mode of
1312 #ifndef mingw32_HOST_OS
1313         -- 'raw' mode under win32 is a bit too specialised (and troublesome
1314         -- for most common uses), so simply disable its use here.
1315                   NoBuffering -> setCooked (haFD handle_) False
1316 #else
1317                   NoBuffering -> return ()
1318 #endif
1319                   _           -> setCooked (haFD handle_) True
1320
1321           -- throw away spare buffers, they might be the wrong size
1322           writeIORef (haBuffers handle_) BufferListNil
1323
1324           return (handle_{ haBufferMode = mode })
1325
1326 -- -----------------------------------------------------------------------------
1327 -- hFlush
1328
1329 -- | The action 'hFlush' @hdl@ causes any items buffered for output
1330 -- in handle @hdl@ to be sent immediately to the operating system.
1331 --
1332 -- This operation may fail with:
1333 --
1334 --  * 'isFullError' if the device is full;
1335 --
1336 --  * 'isPermissionError' if a system resource limit would be exceeded.
1337 --    It is unspecified whether the characters in the buffer are discarded
1338 --    or retained under these circumstances.
1339
1340 hFlush :: Handle -> IO ()
1341 hFlush handle =
1342    wantWritableHandle "hFlush" handle $ \ handle_ -> do
1343    buf <- readIORef (haBuffer handle_)
1344    if bufferIsWritable buf && not (bufferEmpty buf)
1345         then do flushed_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
1346                 writeIORef (haBuffer handle_) flushed_buf
1347         else return ()
1348
1349
1350 -- -----------------------------------------------------------------------------
1351 -- Repositioning Handles
1352
1353 data HandlePosn = HandlePosn Handle HandlePosition
1354
1355 instance Eq HandlePosn where
1356     (HandlePosn h1 p1) == (HandlePosn h2 p2) = p1==p2 && h1==h2
1357
1358 instance Show HandlePosn where
1359    showsPrec p (HandlePosn h pos) =
1360         showsPrec p h . showString " at position " . shows pos
1361
1362   -- HandlePosition is the Haskell equivalent of POSIX' off_t.
1363   -- We represent it as an Integer on the Haskell side, but
1364   -- cheat slightly in that hGetPosn calls upon a C helper
1365   -- that reports the position back via (merely) an Int.
1366 type HandlePosition = Integer
1367
1368 -- | Computation 'hGetPosn' @hdl@ returns the current I\/O position of
1369 -- @hdl@ as a value of the abstract type 'HandlePosn'.
1370
1371 hGetPosn :: Handle -> IO HandlePosn
1372 hGetPosn handle = do
1373     posn <- hTell handle
1374     return (HandlePosn handle posn)
1375
1376 -- | If a call to 'hGetPosn' @hdl@ returns a position @p@,
1377 -- then computation 'hSetPosn' @p@ sets the position of @hdl@
1378 -- to the position it held at the time of the call to 'hGetPosn'.
1379 --
1380 -- This operation may fail with:
1381 --
1382 --  * 'isPermissionError' if a system resource limit would be exceeded.
1383
1384 hSetPosn :: HandlePosn -> IO ()
1385 hSetPosn (HandlePosn h i) = hSeek h AbsoluteSeek i
1386
1387 -- ---------------------------------------------------------------------------
1388 -- hSeek
1389
1390 -- | A mode that determines the effect of 'hSeek' @hdl mode i@, as follows:
1391 data SeekMode
1392   = AbsoluteSeek        -- ^ the position of @hdl@ is set to @i@.
1393   | RelativeSeek        -- ^ the position of @hdl@ is set to offset @i@
1394                         -- from the current position.
1395   | SeekFromEnd         -- ^ the position of @hdl@ is set to offset @i@
1396                         -- from the end of the file.
1397     deriving (Eq, Ord, Ix, Enum, Read, Show)
1398
1399 {- Note:
1400  - when seeking using `SeekFromEnd', positive offsets (>=0) means
1401    seeking at or past EOF.
1402
1403  - we possibly deviate from the report on the issue of seeking within
1404    the buffer and whether to flush it or not.  The report isn't exactly
1405    clear here.
1406 -}
1407
1408 -- | Computation 'hSeek' @hdl mode i@ sets the position of handle
1409 -- @hdl@ depending on @mode@.
1410 -- The offset @i@ is given in terms of 8-bit bytes.
1411 --
1412 -- If @hdl@ is block- or line-buffered, then seeking to a position which is not
1413 -- in the current buffer will first cause any items in the output buffer to be
1414 -- written to the device, and then cause the input buffer to be discarded.
1415 -- Some handles may not be seekable (see 'hIsSeekable'), or only support a
1416 -- subset of the possible positioning operations (for instance, it may only
1417 -- be possible to seek to the end of a tape, or to a positive offset from
1418 -- the beginning or current position).
1419 -- It is not possible to set a negative I\/O position, or for
1420 -- a physical file, an I\/O position beyond the current end-of-file.
1421 --
1422 -- This operation may fail with:
1423 --
1424 --  * 'isPermissionError' if a system resource limit would be exceeded.
1425
1426 hSeek :: Handle -> SeekMode -> Integer -> IO ()
1427 hSeek handle mode offset =
1428     wantSeekableHandle "hSeek" handle $ \ handle_ -> do
1429 #   ifdef DEBUG_DUMP
1430     puts ("hSeek " ++ show (mode,offset) ++ "\n")
1431 #   endif
1432     let ref = haBuffer handle_
1433     buf <- readIORef ref
1434     let r = bufRPtr buf
1435         w = bufWPtr buf
1436         fd = haFD handle_
1437
1438     let do_seek =
1439           throwErrnoIfMinus1Retry_ "hSeek"
1440             (c_lseek (haFD handle_) (fromIntegral offset) whence)
1441
1442         whence :: CInt
1443         whence = case mode of
1444                    AbsoluteSeek -> sEEK_SET
1445                    RelativeSeek -> sEEK_CUR
1446                    SeekFromEnd  -> sEEK_END
1447
1448     if bufferIsWritable buf
1449         then do new_buf <- flushWriteBuffer fd (haIsStream handle_) buf
1450                 writeIORef ref new_buf
1451                 do_seek
1452         else do
1453
1454     if mode == RelativeSeek && offset >= 0 && offset < fromIntegral (w - r)
1455         then writeIORef ref buf{ bufRPtr = r + fromIntegral offset }
1456         else do
1457
1458     new_buf <- flushReadBuffer (haFD handle_) buf
1459     writeIORef ref new_buf
1460     do_seek
1461
1462
1463 hTell :: Handle -> IO Integer
1464 hTell handle =
1465     wantSeekableHandle "hGetPosn" handle $ \ handle_ -> do
1466
1467 #if defined(mingw32_HOST_OS)
1468         -- urgh, on Windows we have to worry about \n -> \r\n translation,
1469         -- so we can't easily calculate the file position using the
1470         -- current buffer size.  Just flush instead.
1471       flushBuffer handle_
1472 #endif
1473       let fd = haFD handle_
1474       posn <- fromIntegral `liftM`
1475                 throwErrnoIfMinus1Retry "hGetPosn"
1476                    (c_lseek fd 0 sEEK_CUR)
1477
1478       let ref = haBuffer handle_
1479       buf <- readIORef ref
1480
1481       let real_posn
1482            | bufferIsWritable buf = posn + fromIntegral (bufWPtr buf)
1483            | otherwise = posn - fromIntegral (bufWPtr buf - bufRPtr buf)
1484 #     ifdef DEBUG_DUMP
1485       puts ("\nhGetPosn: (fd, posn, real_posn) = " ++ show (fd, posn, real_posn) ++ "\n")
1486       puts ("   (bufWPtr, bufRPtr) = " ++ show (bufWPtr buf, bufRPtr buf) ++ "\n")
1487 #     endif
1488       return real_posn
1489
1490 -- -----------------------------------------------------------------------------
1491 -- Handle Properties
1492
1493 -- A number of operations return information about the properties of a
1494 -- handle.  Each of these operations returns `True' if the handle has
1495 -- the specified property, and `False' otherwise.
1496
1497 hIsOpen :: Handle -> IO Bool
1498 hIsOpen handle =
1499     withHandle_ "hIsOpen" handle $ \ handle_ -> do
1500     case haType handle_ of
1501       ClosedHandle         -> return False
1502       SemiClosedHandle     -> return False
1503       _                    -> return True
1504
1505 hIsClosed :: Handle -> IO Bool
1506 hIsClosed handle =
1507     withHandle_ "hIsClosed" handle $ \ handle_ -> do
1508     case haType handle_ of
1509       ClosedHandle         -> return True
1510       _                    -> return False
1511
1512 {- not defined, nor exported, but mentioned
1513    here for documentation purposes:
1514
1515     hSemiClosed :: Handle -> IO Bool
1516     hSemiClosed h = do
1517        ho <- hIsOpen h
1518        hc <- hIsClosed h
1519        return (not (ho || hc))
1520 -}
1521
1522 hIsReadable :: Handle -> IO Bool
1523 hIsReadable (DuplexHandle _ _ _) = return True
1524 hIsReadable handle =
1525     withHandle_ "hIsReadable" handle $ \ handle_ -> do
1526     case haType handle_ of
1527       ClosedHandle         -> ioe_closedHandle
1528       SemiClosedHandle     -> ioe_closedHandle
1529       htype                -> return (isReadableHandleType htype)
1530
1531 hIsWritable :: Handle -> IO Bool
1532 hIsWritable (DuplexHandle _ _ _) = return True
1533 hIsWritable handle =
1534     withHandle_ "hIsWritable" handle $ \ handle_ -> do
1535     case haType handle_ of
1536       ClosedHandle         -> ioe_closedHandle
1537       SemiClosedHandle     -> ioe_closedHandle
1538       htype                -> return (isWritableHandleType htype)
1539
1540 -- | Computation 'hGetBuffering' @hdl@ returns the current buffering mode
1541 -- for @hdl@.
1542
1543 hGetBuffering :: Handle -> IO BufferMode
1544 hGetBuffering handle =
1545     withHandle_ "hGetBuffering" handle $ \ handle_ -> do
1546     case haType handle_ of
1547       ClosedHandle         -> ioe_closedHandle
1548       _ ->
1549            -- We're being non-standard here, and allow the buffering
1550            -- of a semi-closed handle to be queried.   -- sof 6/98
1551           return (haBufferMode handle_)  -- could be stricter..
1552
1553 hIsSeekable :: Handle -> IO Bool
1554 hIsSeekable handle =
1555     withHandle_ "hIsSeekable" handle $ \ handle_ -> do
1556     case haType handle_ of
1557       ClosedHandle         -> ioe_closedHandle
1558       SemiClosedHandle     -> ioe_closedHandle
1559       AppendHandle         -> return False
1560       _                    -> do t <- fdType (haFD handle_)
1561                                  return ((t == RegularFile    || t == RawDevice)
1562                                          && (haIsBin handle_  || tEXT_MODE_SEEK_ALLOWED))
1563
1564 -- -----------------------------------------------------------------------------
1565 -- Changing echo status (Non-standard GHC extensions)
1566
1567 -- | Set the echoing status of a handle connected to a terminal.
1568
1569 hSetEcho :: Handle -> Bool -> IO ()
1570 hSetEcho handle on = do
1571     isT   <- hIsTerminalDevice handle
1572     if not isT
1573      then return ()
1574      else
1575       withHandle_ "hSetEcho" handle $ \ handle_ -> do
1576       case haType handle_ of
1577          ClosedHandle -> ioe_closedHandle
1578          _            -> setEcho (haFD handle_) on
1579
1580 -- | Get the echoing status of a handle connected to a terminal.
1581
1582 hGetEcho :: Handle -> IO Bool
1583 hGetEcho handle = do
1584     isT   <- hIsTerminalDevice handle
1585     if not isT
1586      then return False
1587      else
1588        withHandle_ "hGetEcho" handle $ \ handle_ -> do
1589        case haType handle_ of
1590          ClosedHandle -> ioe_closedHandle
1591          _            -> getEcho (haFD handle_)
1592
1593 -- | Is the handle connected to a terminal?
1594
1595 hIsTerminalDevice :: Handle -> IO Bool
1596 hIsTerminalDevice handle = do
1597     withHandle_ "hIsTerminalDevice" handle $ \ handle_ -> do
1598      case haType handle_ of
1599        ClosedHandle -> ioe_closedHandle
1600        _            -> fdIsTTY (haFD handle_)
1601
1602 -- -----------------------------------------------------------------------------
1603 -- hSetBinaryMode
1604
1605 -- | Select binary mode ('True') or text mode ('False') on a open handle.
1606 -- (See also 'openBinaryFile'.)
1607
1608 hSetBinaryMode :: Handle -> Bool -> IO ()
1609 hSetBinaryMode handle bin =
1610   withAllHandles__ "hSetBinaryMode" handle $ \ handle_ ->
1611     do throwErrnoIfMinus1_ "hSetBinaryMode"
1612           (setmode (haFD handle_) bin)
1613        return handle_{haIsBin=bin}
1614
1615 foreign import ccall unsafe "__hscore_setmode"
1616   setmode :: CInt -> Bool -> IO CInt
1617
1618 -- -----------------------------------------------------------------------------
1619 -- Duplicating a Handle
1620
1621 -- | Returns a duplicate of the original handle, with its own buffer.
1622 -- The two Handles will share a file pointer, however.  The original
1623 -- handle's buffer is flushed, including discarding any input data,
1624 -- before the handle is duplicated.
1625
1626 hDuplicate :: Handle -> IO Handle
1627 hDuplicate h@(FileHandle path m) = do
1628   new_h_ <- withHandle' "hDuplicate" h m (dupHandle h Nothing)
1629   newFileHandle path (handleFinalizer path) new_h_
1630 hDuplicate h@(DuplexHandle path r w) = do
1631   new_w_ <- withHandle' "hDuplicate" h w (dupHandle h Nothing)
1632   new_w <- newMVar new_w_
1633   new_r_ <- withHandle' "hDuplicate" h r (dupHandle h (Just new_w))
1634   new_r <- newMVar new_r_
1635   addMVarFinalizer new_w (handleFinalizer path new_w)
1636   return (DuplexHandle path new_r new_w)
1637
1638 dupHandle :: Handle -> Maybe (MVar Handle__) -> Handle__
1639           -> IO (Handle__, Handle__)
1640 dupHandle h other_side h_ = do
1641   -- flush the buffer first, so we don't have to copy its contents
1642   flushBuffer h_
1643   new_fd <- case other_side of
1644                 Nothing -> throwErrnoIfMinus1 "dupHandle" $ c_dup (haFD h_)
1645                 Just r -> withHandle_' "dupHandle" h r (return . haFD)
1646   dupHandle_ other_side h_ new_fd
1647
1648 dupHandleTo other_side hto_ h_ = do
1649   flushBuffer h_
1650   -- Windows' dup2 does not return the new descriptor, unlike Unix
1651   throwErrnoIfMinus1 "dupHandleTo" $
1652         c_dup2 (haFD h_) (haFD hto_)
1653   dupHandle_ other_side h_ (haFD hto_)
1654
1655 dupHandle_ :: Maybe (MVar Handle__) -> Handle__ -> FD
1656            -> IO (Handle__, Handle__)
1657 dupHandle_ other_side h_ new_fd = do
1658   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE (initBufferState (haType h_))
1659   ioref <- newIORef buffer
1660   ioref_buffers <- newIORef BufferListNil
1661
1662   let new_handle_ = h_{ haFD = new_fd,
1663                         haBuffer = ioref,
1664                         haBuffers = ioref_buffers,
1665                         haOtherSide = other_side }
1666   return (h_, new_handle_)
1667
1668 -- -----------------------------------------------------------------------------
1669 -- Replacing a Handle
1670
1671 {- |
1672 Makes the second handle a duplicate of the first handle.  The second
1673 handle will be closed first, if it is not already.
1674
1675 This can be used to retarget the standard Handles, for example:
1676
1677 > do h <- openFile "mystdout" WriteMode
1678 >    hDuplicateTo h stdout
1679 -}
1680
1681 hDuplicateTo :: Handle -> Handle -> IO ()
1682 hDuplicateTo h1@(FileHandle _ m1) h2@(FileHandle _ m2)  = do
1683  withHandle__' "hDuplicateTo" h2 m2 $ \h2_ -> do
1684    _ <- hClose_help h2_
1685    withHandle' "hDuplicateTo" h1 m1 (dupHandleTo Nothing h2_)
1686 hDuplicateTo h1@(DuplexHandle _ r1 w1) h2@(DuplexHandle _ r2 w2)  = do
1687  withHandle__' "hDuplicateTo" h2 w2  $ \w2_ -> do
1688    _ <- hClose_help w2_
1689    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo Nothing w2_)
1690  withHandle__' "hDuplicateTo" h2 r2  $ \r2_ -> do
1691    _ <- hClose_help r2_
1692    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo (Just w1) r2_)
1693 hDuplicateTo h1 _ =
1694    ioException (IOError (Just h1) IllegalOperation "hDuplicateTo"
1695                 "handles are incompatible" Nothing)
1696
1697 -- ---------------------------------------------------------------------------
1698 -- showing Handles.
1699 --
1700 -- | 'hShow' is in the 'IO' monad, and gives more comprehensive output
1701 -- than the (pure) instance of 'Show' for 'Handle'.
1702
1703 hShow :: Handle -> IO String
1704 hShow h@(FileHandle path _) = showHandle' path False h
1705 hShow h@(DuplexHandle path _ _) = showHandle' path True h
1706
1707 showHandle' filepath is_duplex h =
1708   withHandle_ "showHandle" h $ \hdl_ ->
1709     let
1710      showType | is_duplex = showString "duplex (read-write)"
1711               | otherwise = shows (haType hdl_)
1712     in
1713     return
1714       (( showChar '{' .
1715         showHdl (haType hdl_)
1716             (showString "loc=" . showString filepath . showChar ',' .
1717              showString "type=" . showType . showChar ',' .
1718              showString "binary=" . shows (haIsBin hdl_) . showChar ',' .
1719              showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
1720       ) "")
1721    where
1722
1723     showHdl :: HandleType -> ShowS -> ShowS
1724     showHdl ht cont =
1725        case ht of
1726         ClosedHandle  -> shows ht . showString "}"
1727         _ -> cont
1728
1729     showBufMode :: Buffer -> BufferMode -> ShowS
1730     showBufMode buf bmo =
1731       case bmo of
1732         NoBuffering   -> showString "none"
1733         LineBuffering -> showString "line"
1734         BlockBuffering (Just n) -> showString "block " . showParen True (shows n)
1735         BlockBuffering Nothing  -> showString "block " . showParen True (shows def)
1736       where
1737        def :: Int
1738        def = bufSize buf
1739
1740 -- ---------------------------------------------------------------------------
1741 -- debugging
1742
1743 #if defined(DEBUG_DUMP)
1744 puts :: String -> IO ()
1745 puts s = do write_rawBuffer 1 (unsafeCoerce# (packCString# s)) 0 (fromIntegral (length s))
1746             return ()
1747 #endif
1748
1749 -- -----------------------------------------------------------------------------
1750 -- utils
1751
1752 throwErrnoIfMinus1RetryOnBlock  :: String -> IO CInt -> IO CInt -> IO CInt
1753 throwErrnoIfMinus1RetryOnBlock loc f on_block  =
1754   do
1755     res <- f
1756     if (res :: CInt) == -1
1757       then do
1758         err <- getErrno
1759         if err == eINTR
1760           then throwErrnoIfMinus1RetryOnBlock loc f on_block
1761           else if err == eWOULDBLOCK || err == eAGAIN
1762                  then do on_block
1763                  else throwErrno loc
1764       else return res
1765
1766 -- -----------------------------------------------------------------------------
1767 -- wrappers to platform-specific constants:
1768
1769 foreign import ccall unsafe "__hscore_supportsTextMode"
1770   tEXT_MODE_SEEK_ALLOWED :: Bool
1771
1772 foreign import ccall unsafe "__hscore_bufsiz"   dEFAULT_BUFFER_SIZE :: Int
1773 foreign import ccall unsafe "__hscore_seek_cur" sEEK_CUR :: CInt
1774 foreign import ccall unsafe "__hscore_seek_set" sEEK_SET :: CInt
1775 foreign import ccall unsafe "__hscore_seek_end" sEEK_END :: CInt