GHC/IOBase.lhs

   1 \begin{code}
   2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.IOBase
   6 -- Copyright   :  (c) The University of Glasgow 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- Definitions for the 'IO' monad and its friends.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 -- #hide
  18 module GHC.IOBase(
  19     IO(..), unIO, failIO, liftIO, bindIO, thenIO, returnIO,
  20     unsafePerformIO, unsafeInterleaveIO,
  21
  22         -- To and from from ST
  23     stToIO, ioToST, unsafeIOToST,
  24
  25         -- References
  26     IORef(..), newIORef, readIORef, writeIORef,
  27     IOArray(..), newIOArray, readIOArray, writeIOArray, unsafeReadIOArray, unsafeWriteIOArray,
  28     MVar(..),
  29
  30         -- Handles, file descriptors,
  31     FilePath,
  32     Handle(..), Handle__(..), HandleType(..), IOMode(..), FD,
  33     isReadableHandleType, isWritableHandleType, showHandle,
  34
  35         -- Buffers
  36     Buffer(..), RawBuffer, BufferState(..), BufferList(..), BufferMode(..),
  37     bufferIsWritable, bufferEmpty, bufferFull,
  38
  39         -- Exceptions
  40     Exception(..), ArithException(..), AsyncException(..), ArrayException(..),
  41     stackOverflow, heapOverflow, throw, throwIO, ioException,
  42     IOError, IOException(..), IOErrorType(..), ioError, userError,
  43     ExitCode(..)
  44   ) where
  45
  46 import GHC.ST
  47 import GHC.Arr  -- to derive Ix class
  48 import GHC.Enum -- to derive Enum class
  49 import GHC.STRef
  50 import GHC.Base
  51 --  import GHC.Num      -- To get fromInteger etc, needed because of -fno-implicit-prelude
  52 import Data.Maybe  ( Maybe(..) )
  53 import GHC.Show
  54 import GHC.List
  55 import GHC.Read
  56
  57 #ifndef __HADDOCK__
  58 import {-# SOURCE #-} Data.Dynamic
  59 #endif
  60
  61 -- ---------------------------------------------------------------------------
  62 -- The IO Monad
  63
  64 {-
  65 The IO Monad is just an instance of the ST monad, where the state is
  66 the real world.  We use the exception mechanism (in GHC.Exception) to
  67 implement IO exceptions.
  68
  69 NOTE: The IO representation is deeply wired in to various parts of the
  70 system.  The following list may or may not be exhaustive:
  71
  72 Compiler  - types of various primitives in PrimOp.lhs
  73
  74 RTS       - forceIO (StgMiscClosures.hc)
  75           - catchzh_fast, (un)?blockAsyncExceptionszh_fast, raisezh_fast
  76             (Exceptions.hc)
  77           - raiseAsync (Schedule.c)
  78
  79 Prelude   - GHC.IOBase.lhs, and several other places including
  80             GHC.Exception.lhs.
  81
  82 Libraries - parts of hslibs/lang.
  83
  84 --SDM
  85 -}
  86
  87 {-|
  88 A value of type @'IO' a@ is a computation which, when performed,
  89 does some I\/O before returning a value of type @a@.
  90
  91 There is really only one way to \"perform\" an I\/O action: bind it to
  92 @Main.main@ in your program.  When your program is run, the I\/O will
  93 be performed.  It isn't possible to perform I\/O from an arbitrary
  94 function, unless that function is itself in the 'IO' monad and called
  95 at some point, directly or indirectly, from @Main.main@.
  96
  97 'IO' is a monad, so 'IO' actions can be combined using either the do-notation
  98 or the '>>' and '>>=' operations from the 'Monad' class.
  99 -}
 100 newtype IO a = IO (State# RealWorld -> (# State# RealWorld, a #))
 101
 102 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
 103 unIO (IO a) = a
 104
 105 instance  Functor IO where
 106    fmap f x = x >>= (return . f)
 107
 108 instance  Monad IO  where
 109     {-# INLINE return #-}
 110     {-# INLINE (>>)   #-}
 111     {-# INLINE (>>=)  #-}
 112     m >> k      =  m >>= \ _ -> k
 113     return x    = returnIO x
 114
 115     m >>= k     = bindIO m k
 116     fail s      = failIO s
 117
 118 failIO :: String -> IO a
 119 failIO s = ioError (userError s)
 120
 121 liftIO :: IO a -> State# RealWorld -> STret RealWorld a
 122 liftIO (IO m) = \s -> case m s of (# s', r #) -> STret s' r
 123
 124 bindIO :: IO a -> (a -> IO b) -> IO b
 125 bindIO (IO m) k = IO ( \ s ->
 126   case m s of
 127     (# new_s, a #) -> unIO (k a) new_s
 128   )
 129
 130 thenIO :: IO a -> IO b -> IO b
 131 thenIO (IO m) k = IO ( \ s ->
 132   case m s of
 133     (# new_s, a #) -> unIO k new_s
 134   )
 135
 136 returnIO :: a -> IO a
 137 returnIO x = IO (\ s -> (# s, x #))
 138
 139 -- ---------------------------------------------------------------------------
 140 -- Coercions between IO and ST
 141
 142 -- | A monad transformer embedding strict state transformers in the 'IO'
 143 -- monad.  The 'RealWorld' parameter indicates that the internal state
 144 -- used by the 'ST' computation is a special one supplied by the 'IO'
 145 -- monad, and thus distinct from those used by invocations of 'runST'.
 146 stToIO        :: ST RealWorld a -> IO a
 147 stToIO (ST m) = IO m
 148
 149 ioToST        :: IO a -> ST RealWorld a
 150 ioToST (IO m) = (ST m)
 151
 152 -- This relies on IO and ST having the same representation modulo the
 153 -- constraint on the type of the state
 154 --
 155 unsafeIOToST        :: IO a -> ST s a
 156 unsafeIOToST (IO io) = ST $ \ s -> (unsafeCoerce# io) s
 157
 158 -- ---------------------------------------------------------------------------
 159 -- Unsafe IO operations
 160
 161 {-|
 162 This is the \"back door\" into the 'IO' monad, allowing
 163 'IO' computation to be performed at any time.  For
 164 this to be safe, the 'IO' computation should be
 165 free of side effects and independent of its environment.
 166
 167 If the I\/O computation wrapped in 'unsafePerformIO'
 168 performs side effects, then the relative order in which those side
 169 effects take place (relative to the main I\/O trunk, or other calls to
 170 'unsafePerformIO') is indeterminate.  You have to be careful when
 171 writing and compiling modules that use 'unsafePerformIO':
 172
 173   * Use @{\-\# NOINLINE foo \#-\}@ as a pragma on any function @foo@
 174         that calls 'unsafePerformIO'.  If the call is inlined,
 175         the I\/O may be performed more than once.
 176
 177   * Use the compiler flag @-fno-cse@ to prevent common sub-expression
 178         elimination being performed on the module, which might combine
 179         two side effects that were meant to be separate.  A good example
 180         is using multiple global variables (like @test@ in the example below).
 181
 182   * Make sure that the either you switch off let-floating, or that the
 183         call to 'unsafePerformIO' cannot float outside a lambda.  For example,
 184         if you say:
 185         @
 186            f x = unsafePerformIO (newIORef [])
 187         @
 188         you may get only one reference cell shared between all calls to @f@.
 189         Better would be
 190         @
 191            f x = unsafePerformIO (newIORef [x])
 192         @
 193         because now it can't float outside the lambda.
 194
 195 It is less well known that
 196 'unsafePerformIO' is not type safe.  For example:
 197
 198 >     test :: IORef [a]
 199 >     test = unsafePerformIO $ newIORef []
 200 >
 201 >     main = do
 202 >             writeIORef test [42]
 203 >             bang <- readIORef test
 204 >             print (bang :: [Char])
 205
 206 This program will core dump.  This problem with polymorphic references
 207 is well known in the ML community, and does not arise with normal
 208 monadic use of references.  There is no easy way to make it impossible
 209 once you use 'unsafePerformIO'.  Indeed, it is
 210 possible to write @coerce :: a -> b@ with the
 211 help of 'unsafePerformIO'.  So be careful!
 212 -}
 213 {-# NOINLINE unsafePerformIO #-}
 214 unsafePerformIO :: IO a -> a
 215 unsafePerformIO (IO m) = case m realWorld# of (# _, r #)   -> r
 216
 217 -- Why do we NOINLINE unsafePerformIO?  See the comment with
 218 -- GHC.ST.runST.  Essentially the issue is that the IO computation
 219 -- inside unsafePerformIO must be atomic: it must either all run, or
 220 -- not at all.  If we let the compiler see the application of the IO
 221 -- to realWorld#, it might float out part of the IO.
 222
 223 {-|
 224 'unsafeInterleaveIO' allows 'IO' computation to be deferred lazily.
 225 When passed a value of type @IO a@, the 'IO' will only be performed
 226 when the value of the @a@ is demanded.  This is used to implement lazy
 227 file reading, see 'System.IO.hGetContents'.
 228 -}
 229 {-# INLINE unsafeInterleaveIO #-}
 230 unsafeInterleaveIO :: IO a -> IO a
 231 unsafeInterleaveIO (IO m)
 232   = IO ( \ s -> let
 233                    r = case m s of (# _, res #) -> res
 234                 in
 235                 (# s, r #))
 236
 237 -- We believe that INLINE on unsafeInterleaveIO is safe, because the
 238 -- state from this IO thread is passed explicitly to the interleaved
 239 -- IO, so it cannot be floated out and shared.
 240
 241 -- ---------------------------------------------------------------------------
 242 -- Handle type
 243
 244 data MVar a = MVar (MVar# RealWorld a)
 245 {- ^
 246 An 'MVar' (pronounced \"em-var\") is a synchronising variable, used
 247 for communication between concurrent threads.  It can be thought of
 248 as a a box, which may be empty or full.
 249 -}
 250
 251 -- pull in Eq (Mvar a) too, to avoid GHC.Conc being an orphan-instance module
 252 instance Eq (MVar a) where
 253         (MVar mvar1#) == (MVar mvar2#) = sameMVar# mvar1# mvar2#
 254
 255 --  A Handle is represented by (a reference to) a record
 256 --  containing the state of the I/O port/device. We record
 257 --  the following pieces of info:
 258
 259 --    * type (read,write,closed etc.)
 260 --    * the underlying file descriptor
 261 --    * buffering mode
 262 --    * buffer, and spare buffers
 263 --    * user-friendly name (usually the
 264 --      FilePath used when IO.openFile was called)
 265
 266 -- Note: when a Handle is garbage collected, we want to flush its buffer
 267 -- and close the OS file handle, so as to free up a (precious) resource.
 268
 269 -- | Haskell defines operations to read and write characters from and to files,
 270 -- represented by values of type @Handle@.  Each value of this type is a
 271 -- /handle/: a record used by the Haskell run-time system to /manage/ I\/O
 272 -- with file system objects.  A handle has at least the following properties:
 273 --
 274 --  * whether it manages input or output or both;
 275 --
 276 --  * whether it is /open/, /closed/ or /semi-closed/;
 277 --
 278 --  * whether the object is seekable;
 279 --
 280 --  * whether buffering is disabled, or enabled on a line or block basis;
 281 --
 282 --  * a buffer (whose length may be zero).
 283 --
 284 -- Most handles will also have a current I\/O position indicating where the next
 285 -- input or output operation will occur.  A handle is /readable/ if it
 286 -- manages only input or both input and output; likewise, it is /writable/ if
 287 -- it manages only output or both input and output.  A handle is /open/ when
 288 -- first allocated.
 289 -- Once it is closed it can no longer be used for either input or output,
 290 -- though an implementation cannot re-use its storage while references
 291 -- remain to it.  Handles are in the 'Show' and 'Eq' classes.  The string
 292 -- produced by showing a handle is system dependent; it should include
 293 -- enough information to identify the handle for debugging.  A handle is
 294 -- equal according to '==' only to itself; no attempt
 295 -- is made to compare the internal state of different handles for equality.
 296 --
 297 -- GHC note: a 'Handle' will be automatically closed when the garbage
 298 -- collector detects that it has become unreferenced by the program.
 299 -- However, relying on this behaviour is not generally recommended:
 300 -- the garbage collector is unpredictable.  If possible, use explicit
 301 -- an explicit 'hClose' to close 'Handle's when they are no longer
 302 -- required.  GHC does not currently attempt to free up file
 303 -- descriptors when they have run out, it is your responsibility to
 304 -- ensure that this doesn't happen.
 305
 306 data Handle
 307   = FileHandle                          -- A normal handle to a file
 308         FilePath                        -- the file (invariant)
 309         !(MVar Handle__)
 310
 311   | DuplexHandle                        -- A handle to a read/write stream
 312         FilePath                        -- file for a FIFO, otherwise some
 313                                         --   descriptive string.
 314         !(MVar Handle__)                -- The read side
 315         !(MVar Handle__)                -- The write side
 316
 317 -- NOTES:
 318 --    * A 'FileHandle' is seekable.  A 'DuplexHandle' may or may not be
 319 --      seekable.
 320
 321 instance Eq Handle where
 322  (FileHandle _ h1)     == (FileHandle _ h2)     = h1 == h2
 323  (DuplexHandle _ h1 _) == (DuplexHandle _ h2 _) = h1 == h2
 324  _ == _ = False
 325
 326 type FD = Int -- XXX ToDo: should be CInt
 327
 328 data Handle__
 329   = Handle__ {
 330       haFD          :: !FD,                  -- file descriptor
 331       haType        :: HandleType,           -- type (read/write/append etc.)
 332       haIsBin       :: Bool,                 -- binary mode?
 333       haIsStream    :: Bool,                 -- is this a stream handle?
 334       haBufferMode  :: BufferMode,           -- buffer contains read/write data?
 335       haBuffer      :: !(IORef Buffer),      -- the current buffer
 336       haBuffers     :: !(IORef BufferList),  -- spare buffers
 337       haOtherSide   :: Maybe (MVar Handle__) -- ptr to the write side of a
 338                                              -- duplex handle.
 339     }
 340
 341 -- ---------------------------------------------------------------------------
 342 -- Buffers
 343
 344 -- The buffer is represented by a mutable variable containing a
 345 -- record, where the record contains the raw buffer and the start/end
 346 -- points of the filled portion.  We use a mutable variable so that
 347 -- the common operation of writing (or reading) some data from (to)
 348 -- the buffer doesn't need to modify, and hence copy, the handle
 349 -- itself, it just updates the buffer.
 350
 351 -- There will be some allocation involved in a simple hPutChar in
 352 -- order to create the new Buffer structure (below), but this is
 353 -- relatively small, and this only has to be done once per write
 354 -- operation.
 355
 356 -- The buffer contains its size - we could also get the size by
 357 -- calling sizeOfMutableByteArray# on the raw buffer, but that tends
 358 -- to be rounded up to the nearest Word.
 359
 360 type RawBuffer = MutableByteArray# RealWorld
 361
 362 -- INVARIANTS on a Buffer:
 363 --
 364 --   * A handle *always* has a buffer, even if it is only 1 character long
 365 --     (an unbuffered handle needs a 1 character buffer in order to support
 366 --      hLookAhead and hIsEOF).
 367 --   * r <= w
 368 --   * if r == w, then r == 0 && w == 0
 369 --   * if state == WriteBuffer, then r == 0
 370 --   * a write buffer is never full.  If an operation
 371 --     fills up the buffer, it will always flush it before
 372 --     returning.
 373 --   * a read buffer may be full as a result of hLookAhead.  In normal
 374 --     operation, a read buffer always has at least one character of space.
 375
 376 data Buffer
 377   = Buffer {
 378         bufBuf   :: RawBuffer,
 379         bufRPtr  :: !Int,
 380         bufWPtr  :: !Int,
 381         bufSize  :: !Int,
 382         bufState :: BufferState
 383   }
 384
 385 data BufferState = ReadBuffer | WriteBuffer deriving (Eq)
 386
 387 -- we keep a few spare buffers around in a handle to avoid allocating
 388 -- a new one for each hPutStr.  These buffers are *guaranteed* to be the
 389 -- same size as the main buffer.
 390 data BufferList
 391   = BufferListNil
 392   | BufferListCons RawBuffer BufferList
 393
 394
 395 bufferIsWritable :: Buffer -> Bool
 396 bufferIsWritable Buffer{ bufState=WriteBuffer } = True
 397 bufferIsWritable _other = False
 398
 399 bufferEmpty :: Buffer -> Bool
 400 bufferEmpty Buffer{ bufRPtr=r, bufWPtr=w } = r == w
 401
 402 -- only makes sense for a write buffer
 403 bufferFull :: Buffer -> Bool
 404 bufferFull b@Buffer{ bufWPtr=w } = w >= bufSize b
 405
 406 --  Internally, we classify handles as being one
 407 --  of the following:
 408
 409 data HandleType
 410  = ClosedHandle
 411  | SemiClosedHandle
 412  | ReadHandle
 413  | WriteHandle
 414  | AppendHandle
 415  | ReadWriteHandle
 416
 417 isReadableHandleType ReadHandle         = True
 418 isReadableHandleType ReadWriteHandle    = True
 419 isReadableHandleType _                  = False
 420
 421 isWritableHandleType AppendHandle    = True
 422 isWritableHandleType WriteHandle     = True
 423 isWritableHandleType ReadWriteHandle = True
 424 isWritableHandleType _               = False
 425
 426 -- | File and directory names are values of type 'String', whose precise
 427 -- meaning is operating system dependent. Files can be opened, yielding a
 428 -- handle which can then be used to operate on the contents of that file.
 429
 430 type FilePath = String
 431
 432 -- ---------------------------------------------------------------------------
 433 -- Buffering modes
 434
 435 -- | Three kinds of buffering are supported: line-buffering,
 436 -- block-buffering or no-buffering.  These modes have the following
 437 -- effects. For output, items are written out, or /flushed/,
 438 -- from the internal buffer according to the buffer mode:
 439 --
 440 --  * /line-buffering/: the entire output buffer is flushed
 441 --    whenever a newline is output, the buffer overflows,
 442 --    a 'System.IO.hFlush' is issued, or the handle is closed.
 443 --
 444 --  * /block-buffering/: the entire buffer is written out whenever it
 445 --    overflows, a 'System.IO.hFlush' is issued, or the handle is closed.
 446 --
 447 --  * /no-buffering/: output is written immediately, and never stored
 448 --    in the buffer.
 449 --
 450 -- An implementation is free to flush the buffer more frequently,
 451 -- but not less frequently, than specified above.
 452 -- The output buffer is emptied as soon as it has been written out.
 453 --
 454 -- Similarly, input occurs according to the buffer mode for the handle:
 455 --
 456 --  * /line-buffering/: when the buffer for the handle is not empty,
 457 --    the next item is obtained from the buffer; otherwise, when the
 458 --    buffer is empty, characters up to and including the next newline
 459 --    character are read into the buffer.  No characters are available
 460 --    until the newline character is available or the buffer is full.
 461 --
 462 --  * /block-buffering/: when the buffer for the handle becomes empty,
 463 --    the next block of data is read into the buffer.
 464 --
 465 --  * /no-buffering/: the next input item is read and returned.
 466 --    The 'System.IO.hLookAhead' operation implies that even a no-buffered
 467 --    handle may require a one-character buffer.
 468 --
 469 -- The default buffering mode when a handle is opened is
 470 -- implementation-dependent and may depend on the file system object
 471 -- which is attached to that handle.
 472 -- For most implementations, physical files will normally be block-buffered
 473 -- and terminals will normally be line-buffered.
 474
 475 data BufferMode
 476  = NoBuffering  -- ^ buffering is disabled if possible.
 477  | LineBuffering
 478                 -- ^ line-buffering should be enabled if possible.
 479  | BlockBuffering (Maybe Int)
 480                 -- ^ block-buffering should be enabled if possible.
 481                 -- The size of the buffer is @n@ items if the argument
 482                 -- is 'Just' @n@ and is otherwise implementation-dependent.
 483    deriving (Eq, Ord, Read, Show)
 484
 485 -- ---------------------------------------------------------------------------
 486 -- IORefs
 487
 488 -- |A mutable variable in the 'IO' monad
 489 newtype IORef a = IORef (STRef RealWorld a)
 490
 491 -- explicit instance because Haddock can't figure out a derived one
 492 instance Eq (IORef a) where
 493   IORef x == IORef y = x == y
 494
 495 -- |Build a new 'IORef'
 496 newIORef    :: a -> IO (IORef a)
 497 newIORef v = stToIO (newSTRef v) >>= \ var -> return (IORef var)
 498
 499 -- |Read the value of an 'IORef'
 500 readIORef   :: IORef a -> IO a
 501 readIORef  (IORef var) = stToIO (readSTRef var)
 502
 503 -- |Write a new value into an 'IORef'
 504 writeIORef  :: IORef a -> a -> IO ()
 505 writeIORef (IORef var) v = stToIO (writeSTRef var v)
 506
 507 -- ---------------------------------------------------------------------------
 508 -- | An 'IOArray' is a mutable, boxed, non-strict array in the 'IO' monad.
 509 -- The type arguments are as follows:
 510 --
 511 --  * @i@: the index type of the array (should be an instance of 'Ix')
 512 --
 513 --  * @e@: the element type of the array.
 514 --
 515 --
 516
 517 newtype IOArray i e = IOArray (STArray RealWorld i e)
 518
 519 -- explicit instance because Haddock can't figure out a derived one
 520 instance Eq (IOArray i e) where
 521   IOArray x == IOArray y = x == y
 522
 523 -- |Build a new 'IOArray'
 524 newIOArray :: Ix i => (i,i) -> e -> IO (IOArray i e)
 525 {-# INLINE newIOArray #-}
 526 newIOArray lu init  = stToIO $ do {marr <- newSTArray lu init; return (IOArray marr)}
 527
 528 -- | Read a value from an 'IOArray'
 529 unsafeReadIOArray  :: Ix i => IOArray i e -> Int -> IO e
 530 {-# INLINE unsafeReadIOArray #-}
 531 unsafeReadIOArray (IOArray marr) i = stToIO (unsafeReadSTArray marr i)
 532
 533 -- | Write a new value into an 'IOArray'
 534 unsafeWriteIOArray :: Ix i => IOArray i e -> Int -> e -> IO ()
 535 {-# INLINE unsafeWriteIOArray #-}
 536 unsafeWriteIOArray (IOArray marr) i e = stToIO (unsafeWriteSTArray marr i e)
 537
 538 -- | Read a value from an 'IOArray'
 539 readIOArray  :: Ix i => IOArray i e -> i -> IO e
 540 readIOArray (IOArray marr) i = stToIO (readSTArray marr i)
 541
 542 -- | Write a new value into an 'IOArray'
 543 writeIOArray :: Ix i => IOArray i e -> i -> e -> IO ()
 544 writeIOArray (IOArray marr) i e = stToIO (writeSTArray marr i e)
 545
 546
 547 -- ---------------------------------------------------------------------------
 548 -- Show instance for Handles
 549
 550 -- handle types are 'show'n when printing error msgs, so
 551 -- we provide a more user-friendly Show instance for it
 552 -- than the derived one.
 553
 554 instance Show HandleType where
 555   showsPrec p t =
 556     case t of
 557       ClosedHandle      -> showString "closed"
 558       SemiClosedHandle  -> showString "semi-closed"
 559       ReadHandle        -> showString "readable"
 560       WriteHandle       -> showString "writable"
 561       AppendHandle      -> showString "writable (append)"
 562       ReadWriteHandle   -> showString "read-writable"
 563
 564 instance Show Handle where
 565   showsPrec p (FileHandle   file _)   = showHandle file
 566   showsPrec p (DuplexHandle file _ _) = showHandle file
 567
 568 showHandle file = showString "{handle: " . showString file . showString "}"
 569
 570 -- ------------------------------------------------------------------------
 571 -- Exception datatype and operations
 572
 573 -- |The type of exceptions.  Every kind of system-generated exception
 574 -- has a constructor in the 'Exception' type, and values of other
 575 -- types may be injected into 'Exception' by coercing them to
 576 -- 'Data.Dynamic.Dynamic' (see the section on Dynamic Exceptions:
 577 -- "Control.Exception\#DynamicExceptions").
 578 data Exception
 579   = ArithException      ArithException
 580         -- ^Exceptions raised by arithmetic
 581         -- operations.  (NOTE: GHC currently does not throw
 582         -- 'ArithException's except for 'DivideByZero').
 583   | ArrayException      ArrayException
 584         -- ^Exceptions raised by array-related
 585         -- operations.  (NOTE: GHC currently does not throw
 586         -- 'ArrayException's).
 587   | AssertionFailed     String
 588         -- ^This exception is thrown by the
 589         -- 'assert' operation when the condition
 590         -- fails.  The 'String' argument contains the
 591         -- location of the assertion in the source program.
 592   | AsyncException      AsyncException
 593         -- ^Asynchronous exceptions (see section on Asynchronous Exceptions: "Control.Exception\#AsynchronousExceptions").
 594   | BlockedOnDeadMVar
 595         -- ^The current thread was executing a call to
 596         -- 'Control.Concurrent.MVar.takeMVar' that could never return,
 597         -- because there are no other references to this 'MVar'.
 598   | BlockedIndefinitely
 599         -- ^The current thread was waiting to retry an atomic memory transaction
 600         -- that could never become possible to complete because there are no other
 601         -- threads referring to any of teh TVars involved.
 602   | Deadlock
 603         -- ^There are no runnable threads, so the program is
 604         -- deadlocked.  The 'Deadlock' exception is
 605         -- raised in the main thread only (see also: "Control.Concurrent").
 606   | DynException        Dynamic
 607         -- ^Dynamically typed exceptions (see section on Dynamic Exceptions: "Control.Exception\#DynamicExceptions").
 608   | ErrorCall           String
 609         -- ^The 'ErrorCall' exception is thrown by 'error'.  The 'String'
 610         -- argument of 'ErrorCall' is the string passed to 'error' when it was
 611         -- called.
 612   | ExitException       ExitCode
 613         -- ^The 'ExitException' exception is thrown by 'System.Exit.exitWith' (and
 614         -- 'System.Exit.exitFailure').  The 'ExitCode' argument is the value passed
 615         -- to 'System.Exit.exitWith'.  An unhandled 'ExitException' exception in the
 616         -- main thread will cause the program to be terminated with the given
 617         -- exit code.
 618   | IOException         IOException
 619         -- ^These are the standard IO exceptions generated by
 620         -- Haskell\'s @IO@ operations.  See also "System.IO.Error".
 621   | NoMethodError       String
 622         -- ^An attempt was made to invoke a class method which has
 623         -- no definition in this instance, and there was no default
 624         -- definition given in the class declaration.  GHC issues a
 625         -- warning when you compile an instance which has missing
 626         -- methods.
 627   | NonTermination
 628         -- ^The current thread is stuck in an infinite loop.  This
 629         -- exception may or may not be thrown when the program is
 630         -- non-terminating.
 631   | PatternMatchFail    String
 632         -- ^A pattern matching failure.  The 'String' argument should contain a
 633         -- descriptive message including the function name, source file
 634         -- and line number.
 635   | RecConError         String
 636         -- ^An attempt was made to evaluate a field of a record
 637         -- for which no value was given at construction time.  The
 638         -- 'String' argument gives the location of the
 639         -- record construction in the source program.
 640   | RecSelError         String
 641         -- ^A field selection was attempted on a constructor that
 642         -- doesn\'t have the requested field.  This can happen with
 643         -- multi-constructor records when one or more fields are
 644         -- missing from some of the constructors.  The
 645         -- 'String' argument gives the location of the
 646         -- record selection in the source program.
 647   | RecUpdError         String
 648         -- ^An attempt was made to update a field in a record,
 649         -- where the record doesn\'t have the requested field.  This can
 650         -- only occur with multi-constructor records, when one or more
 651         -- fields are missing from some of the constructors.  The
 652         -- 'String' argument gives the location of the
 653         -- record update in the source program.
 654
 655 -- |The type of arithmetic exceptions
 656 data ArithException
 657   = Overflow
 658   | Underflow
 659   | LossOfPrecision
 660   | DivideByZero
 661   | Denormal
 662   deriving (Eq, Ord)
 663
 664
 665 -- |Asynchronous exceptions
 666 data AsyncException
 667   = StackOverflow
 668         -- ^The current thread\'s stack exceeded its limit.
 669         -- Since an exception has been raised, the thread\'s stack
 670         -- will certainly be below its limit again, but the
 671         -- programmer should take remedial action
 672         -- immediately.
 673   | HeapOverflow
 674         -- ^The program\'s heap is reaching its limit, and
 675         -- the program should take action to reduce the amount of
 676         -- live data it has. Notes:
 677         --
 678         --      * It is undefined which thread receives this exception.
 679         --
 680         --      * GHC currently does not throw 'HeapOverflow' exceptions.
 681   | ThreadKilled
 682         -- ^This exception is raised by another thread
 683         -- calling 'Control.Concurrent.killThread', or by the system
 684         -- if it needs to terminate the thread for some
 685         -- reason.
 686   deriving (Eq, Ord)
 687
 688 -- | Exceptions generated by array operations
 689 data ArrayException
 690   = IndexOutOfBounds    String
 691         -- ^An attempt was made to index an array outside
 692         -- its declared bounds.
 693   | UndefinedElement    String
 694         -- ^An attempt was made to evaluate an element of an
 695         -- array that had not been initialized.
 696   deriving (Eq, Ord)
 697
 698 stackOverflow, heapOverflow :: Exception -- for the RTS
 699 stackOverflow = AsyncException StackOverflow
 700 heapOverflow  = AsyncException HeapOverflow
 701
 702 instance Show ArithException where
 703   showsPrec _ Overflow        = showString "arithmetic overflow"
 704   showsPrec _ Underflow       = showString "arithmetic underflow"
 705   showsPrec _ LossOfPrecision = showString "loss of precision"
 706   showsPrec _ DivideByZero    = showString "divide by zero"
 707   showsPrec _ Denormal        = showString "denormal"
 708
 709 instance Show AsyncException where
 710   showsPrec _ StackOverflow   = showString "stack overflow"
 711   showsPrec _ HeapOverflow    = showString "heap overflow"
 712   showsPrec _ ThreadKilled    = showString "thread killed"
 713
 714 instance Show ArrayException where
 715   showsPrec _ (IndexOutOfBounds s)
 716         = showString "array index out of range"
 717         . (if not (null s) then showString ": " . showString s
 718                            else id)
 719   showsPrec _ (UndefinedElement s)
 720         = showString "undefined array element"
 721         . (if not (null s) then showString ": " . showString s
 722                            else id)
 723
 724 instance Show Exception where
 725   showsPrec _ (IOException err)          = shows err
 726   showsPrec _ (ArithException err)       = shows err
 727   showsPrec _ (ArrayException err)       = shows err
 728   showsPrec _ (ErrorCall err)            = showString err
 729   showsPrec _ (ExitException err)        = showString "exit: " . shows err
 730   showsPrec _ (NoMethodError err)        = showString err
 731   showsPrec _ (PatternMatchFail err)     = showString err
 732   showsPrec _ (RecSelError err)          = showString err
 733   showsPrec _ (RecConError err)          = showString err
 734   showsPrec _ (RecUpdError err)          = showString err
 735   showsPrec _ (AssertionFailed err)      = showString err
 736   showsPrec _ (DynException _err)        = showString "unknown exception"
 737   showsPrec _ (AsyncException e)         = shows e
 738   showsPrec _ (BlockedOnDeadMVar)        = showString "thread blocked indefinitely"
 739   showsPrec _ (BlockedIndefinitely)      = showString "thread blocked indefinitely"
 740   showsPrec _ (NonTermination)           = showString "<<loop>>"
 741   showsPrec _ (Deadlock)                 = showString "<<deadlock>>"
 742
 743 instance Eq Exception where
 744   IOException e1      == IOException e2      = e1 == e2
 745   ArithException e1   == ArithException e2   = e1 == e2
 746   ArrayException e1   == ArrayException e2   = e1 == e2
 747   ErrorCall e1        == ErrorCall e2        = e1 == e2
 748   ExitException e1    == ExitException e2    = e1 == e2
 749   NoMethodError e1    == NoMethodError e2    = e1 == e2
 750   PatternMatchFail e1 == PatternMatchFail e2 = e1 == e2
 751   RecSelError e1      == RecSelError e2      = e1 == e2
 752   RecConError e1      == RecConError e2      = e1 == e2
 753   RecUpdError e1      == RecUpdError e2      = e1 == e2
 754   AssertionFailed e1  == AssertionFailed e2  = e1 == e2
 755   DynException _      == DynException _      = False -- incomparable
 756   AsyncException e1   == AsyncException e2   = e1 == e2
 757   BlockedOnDeadMVar   == BlockedOnDeadMVar   = True
 758   NonTermination      == NonTermination      = True
 759   Deadlock            == Deadlock            = True
 760   _                   == _                   = False
 761
 762 -- -----------------------------------------------------------------------------
 763 -- The ExitCode type
 764
 765 -- We need it here because it is used in ExitException in the
 766 -- Exception datatype (above).
 767
 768 data ExitCode
 769   = ExitSuccess -- ^ indicates successful termination;
 770   | ExitFailure Int
 771                 -- ^ indicates program failure with an exit code.
 772                 -- The exact interpretation of the code is
 773                 -- operating-system dependent.  In particular, some values
 774                 -- may be prohibited (e.g. 0 on a POSIX-compliant system).
 775   deriving (Eq, Ord, Read, Show)
 776
 777 -- --------------------------------------------------------------------------
 778 -- Primitive throw
 779
 780 -- | Throw an exception.  Exceptions may be thrown from purely
 781 -- functional code, but may only be caught within the 'IO' monad.
 782 throw :: Exception -> a
 783 throw exception = raise# exception
 784
 785 -- | A variant of 'throw' that can be used within the 'IO' monad.
 786 --
 787 -- Although 'throwIO' has a type that is an instance of the type of 'throw', the
 788 -- two functions are subtly different:
 789 --
 790 -- > throw e   `seq` return ()  ===> throw e
 791 -- > throwIO e `seq` return ()  ===> return ()
 792 --
 793 -- The first example will cause the exception @e@ to be raised,
 794 -- whereas the second one won\'t.  In fact, 'throwIO' will only cause
 795 -- an exception to be raised when it is used within the 'IO' monad.
 796 -- The 'throwIO' variant should be used in preference to 'throw' to
 797 -- raise an exception within the 'IO' monad because it guarantees
 798 -- ordering with respect to other 'IO' operations, whereas 'throw'
 799 -- does not.
 800 throwIO         :: Exception -> IO a
 801 throwIO err     =  IO $ raiseIO# err
 802
 803 ioException     :: IOException -> IO a
 804 ioException err =  IO $ raiseIO# (IOException err)
 805
 806 -- | Raise an 'IOError' in the 'IO' monad.
 807 ioError         :: IOError -> IO a
 808 ioError         =  ioException
 809
 810 -- ---------------------------------------------------------------------------
 811 -- IOError type
 812
 813 -- | The Haskell 98 type for exceptions in the 'IO' monad.
 814 -- Any I\/O operation may raise an 'IOError' instead of returning a result.
 815 -- For a more general type of exception, including also those that arise
 816 -- in pure code, see 'Control.Exception.Exception'.
 817 --
 818 -- In Haskell 98, this is an opaque type.
 819 type IOError = IOException
 820
 821 -- |Exceptions that occur in the @IO@ monad.
 822 -- An @IOException@ records a more specific error type, a descriptive
 823 -- string and maybe the handle that was used when the error was
 824 -- flagged.
 825 data IOException
 826  = IOError {
 827      ioe_handle   :: Maybe Handle,   -- the handle used by the action flagging
 828                                      -- the error.
 829      ioe_type     :: IOErrorType,    -- what it was.
 830      ioe_location :: String,         -- location.
 831      ioe_description :: String,      -- error type specific information.
 832      ioe_filename :: Maybe FilePath  -- filename the error is related to.
 833    }
 834
 835 instance Eq IOException where
 836   (IOError h1 e1 loc1 str1 fn1) == (IOError h2 e2 loc2 str2 fn2) =
 837     e1==e2 && str1==str2 && h1==h2 && loc1==loc2 && fn1==fn2
 838
 839 -- | An abstract type that contains a value for each variant of 'IOError'.
 840 data IOErrorType
 841   -- Haskell 98:
 842   = AlreadyExists
 843   | NoSuchThing
 844   | ResourceBusy
 845   | ResourceExhausted
 846   | EOF
 847   | IllegalOperation
 848   | PermissionDenied
 849   | UserError
 850   -- GHC only:
 851   | UnsatisfiedConstraints
 852   | SystemError
 853   | ProtocolError
 854   | OtherError
 855   | InvalidArgument
 856   | InappropriateType
 857   | HardwareFault
 858   | UnsupportedOperation
 859   | TimeExpired
 860   | ResourceVanished
 861   | Interrupted
 862   | DynIOError Dynamic -- cheap&cheerful extensible IO error type.
 863
 864 instance Eq IOErrorType where
 865    x == y =
 866      case x of
 867        DynIOError{} -> False -- from a strictness POV, compatible with a derived Eq inst?
 868        _ -> getTag x ==# getTag y
 869
 870 instance Show IOErrorType where
 871   showsPrec _ e =
 872     showString $
 873     case e of
 874       AlreadyExists     -> "already exists"
 875       NoSuchThing       -> "does not exist"
 876       ResourceBusy      -> "resource busy"
 877       ResourceExhausted -> "resource exhausted"
 878       EOF               -> "end of file"
 879       IllegalOperation  -> "illegal operation"
 880       PermissionDenied  -> "permission denied"
 881       UserError         -> "user error"
 882       HardwareFault     -> "hardware fault"
 883       InappropriateType -> "inappropriate type"
 884       Interrupted       -> "interrupted"
 885       InvalidArgument   -> "invalid argument"
 886       OtherError        -> "failed"
 887       ProtocolError     -> "protocol error"
 888       ResourceVanished  -> "resource vanished"
 889       SystemError       -> "system error"
 890       TimeExpired       -> "timeout"
 891       UnsatisfiedConstraints -> "unsatisified constraints" -- ultra-precise!
 892       UnsupportedOperation -> "unsupported operation"
 893       DynIOError{}      -> "unknown IO error"
 894
 895 -- | Construct an 'IOError' value with a string describing the error.
 896 -- The 'fail' method of the 'IO' instance of the 'Monad' class raises a
 897 -- 'userError', thus:
 898 --
 899 -- > instance Monad IO where
 900 -- >   ...
 901 -- >   fail s = ioError (userError s)
 902 --
 903 userError       :: String  -> IOError
 904 userError str   =  IOError Nothing UserError "" str Nothing
 905
 906 -- ---------------------------------------------------------------------------
 907 -- Showing IOErrors
 908
 909 instance Show IOException where
 910     showsPrec p (IOError hdl iot loc s fn) =
 911       (case fn of
 912          Nothing -> case hdl of
 913                         Nothing -> id
 914                         Just h  -> showsPrec p h . showString ": "
 915          Just name -> showString name . showString ": ") .
 916       (case loc of
 917          "" -> id
 918          _  -> showString loc . showString ": ") .
 919       showsPrec p iot .
 920       (case s of
 921          "" -> id
 922          _  -> showString " (" . showString s . showString ")")
 923
 924 -- -----------------------------------------------------------------------------
 925 -- IOMode type
 926
 927 data IOMode      =  ReadMode | WriteMode | AppendMode | ReadWriteMode
 928                     deriving (Eq, Ord, Ix, Enum, Read, Show)
 929 \end{code}