GHC/List.lhs

   1 \begin{code}
   2 {-# OPTIONS -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.List
   6 -- Copyright   :  (c) The University of Glasgow 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- The List data type and its operations
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 module GHC.List (
  18    -- [] (..),          -- Not Haskell 98; built in syntax
  19
  20    map, (++), filter, concat,
  21    head, last, tail, init, null, length, (!!),
  22    foldl, scanl, scanl1, foldr, foldr1, scanr, scanr1,
  23    iterate, repeat, replicate, cycle,
  24    take, drop, splitAt, takeWhile, dropWhile, span, break,
  25    reverse, and, or,
  26    any, all, elem, notElem, lookup,
  27    concatMap,
  28    zip, zip3, zipWith, zipWith3, unzip, unzip3,
  29    errorEmptyList,
  30
  31 #ifndef USE_REPORT_PRELUDE
  32    -- non-standard, but hidden when creating the Prelude
  33    -- export list.
  34    takeUInt_append
  35 #endif
  36
  37  ) where
  38
  39 import {-# SOURCE #-} GHC.Err ( error )
  40 import Data.Tuple
  41 import Data.Maybe
  42 import GHC.Base
  43
  44 infixl 9  !!
  45 infix  4 `elem`, `notElem`
  46 \end{code}
  47
  48 %*********************************************************
  49 %*                                                      *
  50 \subsection{List-manipulation functions}
  51 %*                                                      *
  52 %*********************************************************
  53
  54 \begin{code}
  55 -- | Extract the first element of a list, which must be non-empty.
  56 head                    :: [a] -> a
  57 head (x:_)              =  x
  58 head []                 =  badHead
  59
  60 badHead = errorEmptyList "head"
  61
  62 -- This rule is useful in cases like
  63 --      head [y | (x,y) <- ps, x==t]
  64 {-# RULES
  65 "head/build"    forall (g::forall b.(Bool->b->b)->b->b) .
  66                 head (build g) = g (\x _ -> x) badHead
  67 "head/augment"  forall xs (g::forall b. (a->b->b) -> b -> b) .
  68                 head (augment g xs) = g (\x _ -> x) (head xs)
  69  #-}
  70
  71 -- | Extract the elements after the head of a list, which must be non-empty.
  72 tail                    :: [a] -> [a]
  73 tail (_:xs)             =  xs
  74 tail []                 =  errorEmptyList "tail"
  75
  76 -- | Extract the last element of a list, which must be finite and non-empty.
  77 last                    :: [a] -> a
  78 #ifdef USE_REPORT_PRELUDE
  79 last [x]                =  x
  80 last (_:xs)             =  last xs
  81 last []                 =  errorEmptyList "last"
  82 #else
  83 -- eliminate repeated cases
  84 last []                 =  errorEmptyList "last"
  85 last (x:xs)             =  last' x xs
  86   where last' y []     = y
  87         last' _ (y:ys) = last' y ys
  88 #endif
  89
  90 -- | Return all the elements of a list except the last one.
  91 -- The list must be finite and non-empty.
  92 init                    :: [a] -> [a]
  93 #ifdef USE_REPORT_PRELUDE
  94 init [x]                =  []
  95 init (x:xs)             =  x : init xs
  96 init []                 =  errorEmptyList "init"
  97 #else
  98 -- eliminate repeated cases
  99 init []                 =  errorEmptyList "init"
 100 init (x:xs)             =  init' x xs
 101   where init' _ []     = []
 102         init' y (z:zs) = y : init' z zs
 103 #endif
 104
 105 -- | Test whether a list is empty.
 106 null                    :: [a] -> Bool
 107 null []                 =  True
 108 null (_:_)              =  False
 109
 110 -- | 'length' returns the length of a finite list as an 'Int'.
 111 -- It is an instance of the more general 'Data.List.genericLength',
 112 -- the result type of which may be any kind of number.
 113 length                  :: [a] -> Int
 114 length l                =  len l 0#
 115   where
 116     len :: [a] -> Int# -> Int
 117     len []     a# = I# a#
 118     len (_:xs) a# = len xs (a# +# 1#)
 119
 120 -- | 'filter', applied to a predicate and a list, returns the list of
 121 -- those elements that satisfy the predicate; i.e.,
 122 --
 123 -- > filter p xs = [ x | x <- xs, p x]
 124
 125 filter :: (a -> Bool) -> [a] -> [a]
 126 filter _pred []    = []
 127 filter pred (x:xs)
 128   | pred x         = x : filter pred xs
 129   | otherwise      = filter pred xs
 130
 131 {-# NOINLINE [0] filterFB #-}
 132 filterFB c p x r | p x       = x `c` r
 133                  | otherwise = r
 134
 135 {-# RULES
 136 "filter"     [~1] forall p xs.  filter p xs = build (\c n -> foldr (filterFB c p) n xs)
 137 "filterList" [1]  forall p.     foldr (filterFB (:) p) [] = filter p
 138 "filterFB"        forall c p q. filterFB (filterFB c p) q = filterFB c (\x -> q x && p x)
 139  #-}
 140
 141 -- Note the filterFB rule, which has p and q the "wrong way round" in the RHS.
 142 --     filterFB (filterFB c p) q a b
 143 --   = if q a then filterFB c p a b else b
 144 --   = if q a then (if p a then c a b else b) else b
 145 --   = if q a && p a then c a b else b
 146 --   = filterFB c (\x -> q x && p x) a b
 147 -- I originally wrote (\x -> p x && q x), which is wrong, and actually
 148 -- gave rise to a live bug report.  SLPJ.
 149
 150
 151 -- | 'foldl', applied to a binary operator, a starting value (typically
 152 -- the left-identity of the operator), and a list, reduces the list
 153 -- using the binary operator, from left to right:
 154 --
 155 -- > foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn
 156 --
 157 -- The list must be finite.
 158
 159 -- We write foldl as a non-recursive thing, so that it
 160 -- can be inlined, and then (often) strictness-analysed,
 161 -- and hence the classic space leak on foldl (+) 0 xs
 162
 163 foldl        :: (a -> b -> a) -> a -> [b] -> a
 164 foldl f z xs = lgo z xs
 165              where
 166                 lgo z []     =  z
 167                 lgo z (x:xs) = lgo (f z x) xs
 168
 169 -- | 'scanl' is similar to 'foldl', but returns a list of successive
 170 -- reduced values from the left:
 171 --
 172 -- > scanl f z [x1, x2, ...] == [z, z `f` x1, (z `f` x1) `f` x2, ...]
 173 --
 174 -- Note that
 175 --
 176 -- > last (scanl f z xs) == foldl f z xs.
 177
 178 scanl                   :: (a -> b -> a) -> a -> [b] -> [a]
 179 scanl f q ls            =  q : (case ls of
 180                                 []   -> []
 181                                 x:xs -> scanl f (f q x) xs)
 182
 183 -- | 'scanl1' is a variant of 'scanl' that has no starting value argument:
 184 --
 185 -- > scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
 186
 187 scanl1                  :: (a -> a -> a) -> [a] -> [a]
 188 scanl1 f (x:xs)         =  scanl f x xs
 189 scanl1 _ []             =  []
 190
 191 -- foldr, foldr1, scanr, and scanr1 are the right-to-left duals of the
 192 -- above functions.
 193
 194 -- | 'foldr1' is a variant of 'foldr' that has no starting value argument,
 195 -- and thus must be applied to non-empty lists.
 196
 197 foldr1                  :: (a -> a -> a) -> [a] -> a
 198 foldr1 _ [x]            =  x
 199 foldr1 f (x:xs)         =  f x (foldr1 f xs)
 200 foldr1 _ []             =  errorEmptyList "foldr1"
 201
 202 -- | 'scanr' is the right-to-left dual of 'scanl'.
 203 -- Note that
 204 --
 205 -- > head (scanr f z xs) == foldr f z xs.
 206
 207 scanr                   :: (a -> b -> b) -> b -> [a] -> [b]
 208 scanr _ q0 []           =  [q0]
 209 scanr f q0 (x:xs)       =  f x q : qs
 210                            where qs@(q:_) = scanr f q0 xs
 211
 212 -- | 'scanr1' is a variant of 'scanr' that has no starting value argument.
 213
 214 scanr1                  :: (a -> a -> a) -> [a] -> [a]
 215 scanr1 f []             =  []
 216 scanr1 f [x]            =  [x]
 217 scanr1 f (x:xs)         =  f x q : qs
 218                            where qs@(q:_) = scanr1 f xs
 219
 220 -- | 'iterate' @f x@ returns an infinite list of repeated applications
 221 -- of @f@ to @x@:
 222 --
 223 -- > iterate f x == [x, f x, f (f x), ...]
 224
 225 iterate :: (a -> a) -> a -> [a]
 226 iterate f x =  x : iterate f (f x)
 227
 228 iterateFB c f x = x `c` iterateFB c f (f x)
 229
 230
 231 {-# RULES
 232 "iterate"    [~1] forall f x.   iterate f x = build (\c _n -> iterateFB c f x)
 233 "iterateFB"  [1]                iterateFB (:) = iterate
 234  #-}
 235
 236
 237 -- | 'repeat' @x@ is an infinite list, with @x@ the value of every element.
 238 repeat :: a -> [a]
 239 {-# INLINE [0] repeat #-}
 240 -- The pragma just gives the rules more chance to fire
 241 repeat x = xs where xs = x : xs
 242
 243 {-# INLINE [0] repeatFB #-}     -- ditto
 244 repeatFB c x = xs where xs = x `c` xs
 245
 246
 247 {-# RULES
 248 "repeat"    [~1] forall x. repeat x = build (\c _n -> repeatFB c x)
 249 "repeatFB"  [1]  repeatFB (:)       = repeat
 250  #-}
 251
 252 -- | 'replicate' @n x@ is a list of length @n@ with @x@ the value of
 253 -- every element.
 254 -- It is an instance of the more general 'Data.List.genericReplicate',
 255 -- in which @n@ may be of any integral type.
 256 replicate               :: Int -> a -> [a]
 257 replicate n x           =  take n (repeat x)
 258
 259 -- | 'cycle' ties a finite list into a circular one, or equivalently,
 260 -- the infinite repetition of the original list.  It is the identity
 261 -- on infinite lists.
 262
 263 cycle                   :: [a] -> [a]
 264 cycle []                = error "Prelude.cycle: empty list"
 265 cycle xs                = xs' where xs' = xs ++ xs'
 266
 267 -- | 'takeWhile', applied to a predicate @p@ and a list @xs@, returns the
 268 -- longest prefix (possibly empty) of @xs@ of elements that satisfy @p@.
 269
 270 takeWhile               :: (a -> Bool) -> [a] -> [a]
 271 takeWhile _ []          =  []
 272 takeWhile p (x:xs)
 273             | p x       =  x : takeWhile p xs
 274             | otherwise =  []
 275
 276 -- | 'dropWhile' @p xs@ returns the suffix remaining after 'takeWhile' @p xs@.
 277
 278 dropWhile               :: (a -> Bool) -> [a] -> [a]
 279 dropWhile _ []          =  []
 280 dropWhile p xs@(x:xs')
 281             | p x       =  dropWhile p xs'
 282             | otherwise =  xs
 283
 284 -- | 'take' @n@, applied to a list @xs@, returns the prefix of @xs@
 285 -- of length @n@, or @xs@ itself if @n > 'length' xs@.
 286 -- It is an instance of the more general 'Data.List.genericTake',
 287 -- in which @n@ may be of any integral type.
 288 take                   :: Int -> [a] -> [a]
 289
 290 -- | 'drop' @n xs@ returns the suffix of @xs@
 291 -- after the first @n@ elements, or @[]@ if @n > 'length' xs@.
 292 -- It is an instance of the more general 'Data.List.genericDrop',
 293 -- in which @n@ may be of any integral type.
 294 drop                   :: Int -> [a] -> [a]
 295
 296 -- | 'splitAt' @n xs@ is equivalent to @('take' n xs, 'drop' n xs)@.
 297 -- It is an instance of the more general 'Data.List.genericSplitAt',
 298 -- in which @n@ may be of any integral type.
 299 splitAt                :: Int -> [a] -> ([a],[a])
 300
 301 #ifdef USE_REPORT_PRELUDE
 302 take n _      | n <= 0 =  []
 303 take _ []              =  []
 304 take n (x:xs)          =  x : take (n-1) xs
 305
 306 drop n xs     | n <= 0 =  xs
 307 drop _ []              =  []
 308 drop n (_:xs)          =  drop (n-1) xs
 309
 310 splitAt n xs           =  (take n xs, drop n xs)
 311
 312 #else /* hack away */
 313 take (I# n#) xs = takeUInt n# xs
 314
 315 -- The general code for take, below, checks n <= maxInt
 316 -- No need to check for maxInt overflow when specialised
 317 -- at type Int or Int# since the Int must be <= maxInt
 318
 319 takeUInt :: Int# -> [b] -> [b]
 320 takeUInt n xs
 321   | n >=# 0#  =  take_unsafe_UInt n xs
 322   | otherwise =  []
 323
 324 take_unsafe_UInt :: Int# -> [b] -> [b]
 325 take_unsafe_UInt 0#  _  = []
 326 take_unsafe_UInt m   ls =
 327   case ls of
 328     []     -> []
 329     (x:xs) -> x : take_unsafe_UInt (m -# 1#) xs
 330
 331 takeUInt_append :: Int# -> [b] -> [b] -> [b]
 332 takeUInt_append n xs rs
 333   | n >=# 0#  =  take_unsafe_UInt_append n xs rs
 334   | otherwise =  []
 335
 336 take_unsafe_UInt_append :: Int# -> [b] -> [b] -> [b]
 337 take_unsafe_UInt_append 0#  _ rs  = rs
 338 take_unsafe_UInt_append m  ls rs  =
 339   case ls of
 340     []     -> rs
 341     (x:xs) -> x : take_unsafe_UInt_append (m -# 1#) xs rs
 342
 343 drop (I# n#) ls
 344   | n# <# 0#    = ls
 345   | otherwise   = drop# n# ls
 346     where
 347         drop# :: Int# -> [a] -> [a]
 348         drop# 0# xs      = xs
 349         drop# _  xs@[]   = xs
 350         drop# m# (_:xs)  = drop# (m# -# 1#) xs
 351
 352 splitAt (I# n#) ls
 353   | n# <# 0#    = ([], ls)
 354   | otherwise   = splitAt# n# ls
 355     where
 356         splitAt# :: Int# -> [a] -> ([a], [a])
 357         splitAt# 0# xs     = ([], xs)
 358         splitAt# _  xs@[]  = (xs, xs)
 359         splitAt# m# (x:xs) = (x:xs', xs'')
 360           where
 361             (xs', xs'') = splitAt# (m# -# 1#) xs
 362
 363 #endif /* USE_REPORT_PRELUDE */
 364
 365 -- | 'span' @p xs@ is equivalent to @('takeWhile' p xs, 'dropWhile' p xs)@
 366
 367 span                    :: (a -> Bool) -> [a] -> ([a],[a])
 368 span _ xs@[]            =  (xs, xs)
 369 span p xs@(x:xs')
 370          | p x          =  let (ys,zs) = span p xs' in (x:ys,zs)
 371          | otherwise    =  ([],xs)
 372
 373 -- | 'break' @p@ is equivalent to @'span' ('not' . p)@.
 374
 375 break                   :: (a -> Bool) -> [a] -> ([a],[a])
 376 #ifdef USE_REPORT_PRELUDE
 377 break p                 =  span (not . p)
 378 #else
 379 -- HBC version (stolen)
 380 break _ xs@[]           =  (xs, xs)
 381 break p xs@(x:xs')
 382            | p x        =  ([],xs)
 383            | otherwise  =  let (ys,zs) = break p xs' in (x:ys,zs)
 384 #endif
 385
 386 -- | 'reverse' @xs@ returns the elements of @xs@ in reverse order.
 387 -- @xs@ must be finite.
 388 reverse                 :: [a] -> [a]
 389 #ifdef USE_REPORT_PRELUDE
 390 reverse                 =  foldl (flip (:)) []
 391 #else
 392 reverse l =  rev l []
 393   where
 394     rev []     a = a
 395     rev (x:xs) a = rev xs (x:a)
 396 #endif
 397
 398 -- | 'and' returns the conjunction of a Boolean list.  For the result to be
 399 -- 'True', the list must be finite; 'False', however, results from a 'False'
 400 -- value at a finite index of a finite or infinite list.
 401 and                     :: [Bool] -> Bool
 402
 403 -- | 'or' returns the disjunction of a Boolean list.  For the result to be
 404 -- 'False', the list must be finite; 'True', however, results from a 'True'
 405 -- value at a finite index of a finite or infinite list.
 406 or                      :: [Bool] -> Bool
 407 #ifdef USE_REPORT_PRELUDE
 408 and                     =  foldr (&&) True
 409 or                      =  foldr (||) False
 410 #else
 411 and []          =  True
 412 and (x:xs)      =  x && and xs
 413 or []           =  False
 414 or (x:xs)       =  x || or xs
 415
 416 {-# RULES
 417 "and/build"     forall (g::forall b.(Bool->b->b)->b->b) .
 418                 and (build g) = g (&&) True
 419 "or/build"      forall (g::forall b.(Bool->b->b)->b->b) .
 420                 or (build g) = g (||) False
 421  #-}
 422 #endif
 423
 424 -- | Applied to a predicate and a list, 'any' determines if any element
 425 -- of the list satisfies the predicate.
 426 any                     :: (a -> Bool) -> [a] -> Bool
 427
 428 -- | Applied to a predicate and a list, 'all' determines if all elements
 429 -- of the list satisfy the predicate.
 430 all                     :: (a -> Bool) -> [a] -> Bool
 431 #ifdef USE_REPORT_PRELUDE
 432 any p                   =  or . map p
 433 all p                   =  and . map p
 434 #else
 435 any _ []        = False
 436 any p (x:xs)    = p x || any p xs
 437
 438 all _ []        =  True
 439 all p (x:xs)    =  p x && all p xs
 440 {-# RULES
 441 "any/build"     forall p (g::forall b.(a->b->b)->b->b) .
 442                 any p (build g) = g ((||) . p) False
 443 "all/build"     forall p (g::forall b.(a->b->b)->b->b) .
 444                 all p (build g) = g ((&&) . p) True
 445  #-}
 446 #endif
 447
 448 -- | 'elem' is the list membership predicate, usually written in infix form,
 449 -- e.g., @x `elem` xs@.
 450 elem                    :: (Eq a) => a -> [a] -> Bool
 451
 452 -- | 'notElem' is the negation of 'elem'.
 453 notElem                 :: (Eq a) => a -> [a] -> Bool
 454 #ifdef USE_REPORT_PRELUDE
 455 elem x                  =  any (== x)
 456 notElem x               =  all (/= x)
 457 #else
 458 elem _ []       = False
 459 elem x (y:ys)   = x==y || elem x ys
 460
 461 notElem _ []    =  True
 462 notElem x (y:ys)=  x /= y && notElem x ys
 463 #endif
 464
 465 -- | 'lookup' @key assocs@ looks up a key in an association list.
 466 lookup                  :: (Eq a) => a -> [(a,b)] -> Maybe b
 467 lookup _key []          =  Nothing
 468 lookup  key ((x,y):xys)
 469     | key == x          =  Just y
 470     | otherwise         =  lookup key xys
 471
 472 -- | Map a function over a list and concatenate the results.
 473 concatMap               :: (a -> [b]) -> [a] -> [b]
 474 concatMap f             =  foldr ((++) . f) []
 475
 476 -- | Concatenate a list of lists.
 477 concat :: [[a]] -> [a]
 478 concat = foldr (++) []
 479
 480 {-# RULES
 481   "concat" forall xs. concat xs = build (\c n -> foldr (\x y -> foldr c y x) n xs)
 482 -- We don't bother to turn non-fusible applications of concat back into concat
 483  #-}
 484
 485 \end{code}
 486
 487
 488 \begin{code}
 489 -- | List index (subscript) operator, starting from 0.
 490 -- It is an instance of the more general 'Data.List.genericIndex',
 491 -- which takes an index of any integral type.
 492 (!!)                    :: [a] -> Int -> a
 493 #ifdef USE_REPORT_PRELUDE
 494 xs     !! n | n < 0 =  error "Prelude.!!: negative index"
 495 []     !! _         =  error "Prelude.!!: index too large"
 496 (x:_)  !! 0         =  x
 497 (_:xs) !! n         =  xs !! (n-1)
 498 #else
 499 -- HBC version (stolen), then unboxified
 500 -- The semantics is not quite the same for error conditions
 501 -- in the more efficient version.
 502 --
 503 xs !! (I# n) | n <# 0#   =  error "Prelude.(!!): negative index\n"
 504              | otherwise =  sub xs n
 505                          where
 506                             sub :: [a] -> Int# -> a
 507                             sub []     _ = error "Prelude.(!!): index too large\n"
 508                             sub (y:ys) n = if n ==# 0#
 509                                            then y
 510                                            else sub ys (n -# 1#)
 511 #endif
 512 \end{code}
 513
 514
 515 %*********************************************************
 516 %*                                                      *
 517 \subsection{The zip family}
 518 %*                                                      *
 519 %*********************************************************
 520
 521 \begin{code}
 522 foldr2 _k z []    _ys    = z
 523 foldr2 _k z _xs   []     = z
 524 foldr2 k z (x:xs) (y:ys) = k x y (foldr2 k z xs ys)
 525
 526 foldr2_left _k  z _x _r []     = z
 527 foldr2_left  k _z  x  r (y:ys) = k x y (r ys)
 528
 529 foldr2_right _k z  _y _r []     = z
 530 foldr2_right  k _z  y  r (x:xs) = k x y (r xs)
 531
 532 -- foldr2 k z xs ys = foldr (foldr2_left k z)  (\_ -> z) xs ys
 533 -- foldr2 k z xs ys = foldr (foldr2_right k z) (\_ -> z) ys xs
 534 {-# RULES
 535 "foldr2/left"   forall k z ys (g::forall b.(a->b->b)->b->b) .
 536                   foldr2 k z (build g) ys = g (foldr2_left  k z) (\_ -> z) ys
 537
 538 "foldr2/right"  forall k z xs (g::forall b.(a->b->b)->b->b) .
 539                   foldr2 k z xs (build g) = g (foldr2_right k z) (\_ -> z) xs
 540  #-}
 541 \end{code}
 542
 543 The foldr2/right rule isn't exactly right, because it changes
 544 the strictness of foldr2 (and thereby zip)
 545
 546 E.g. main = print (null (zip nonobviousNil (build undefined)))
 547           where   nonobviousNil = f 3
 548                   f n = if n == 0 then [] else f (n-1)
 549
 550 I'm going to leave it though.
 551
 552
 553 Zips for larger tuples are in the List module.
 554
 555 \begin{code}
 556 ----------------------------------------------
 557 -- | 'zip' takes two lists and returns a list of corresponding pairs.
 558 -- If one input list is short, excess elements of the longer list are
 559 -- discarded.
 560 zip :: [a] -> [b] -> [(a,b)]
 561 zip (a:as) (b:bs) = (a,b) : zip as bs
 562 zip _      _      = []
 563
 564 {-# INLINE [0] zipFB #-}
 565 zipFB c x y r = (x,y) `c` r
 566
 567 {-# RULES
 568 "zip"      [~1] forall xs ys. zip xs ys = build (\c n -> foldr2 (zipFB c) n xs ys)
 569 "zipList"  [1]  foldr2 (zipFB (:)) []   = zip
 570  #-}
 571 \end{code}
 572
 573 \begin{code}
 574 ----------------------------------------------
 575 -- | 'zip3' takes three lists and returns a list of triples, analogous to
 576 -- 'zip'.
 577 zip3 :: [a] -> [b] -> [c] -> [(a,b,c)]
 578 -- Specification
 579 -- zip3 =  zipWith3 (,,)
 580 zip3 (a:as) (b:bs) (c:cs) = (a,b,c) : zip3 as bs cs
 581 zip3 _      _      _      = []
 582 \end{code}
 583
 584
 585 -- The zipWith family generalises the zip family by zipping with the
 586 -- function given as the first argument, instead of a tupling function.
 587
 588 \begin{code}
 589 ----------------------------------------------
 590 -- | 'zipWith' generalises 'zip' by zipping with the function given
 591 -- as the first argument, instead of a tupling function.
 592 -- For example, @'zipWith' (+)@ is applied to two lists to produce the
 593 -- list of corresponding sums.
 594 zipWith :: (a->b->c) -> [a]->[b]->[c]
 595 zipWith f (a:as) (b:bs) = f a b : zipWith f as bs
 596 zipWith _ _      _      = []
 597
 598 {-# INLINE [0] zipWithFB #-}
 599 zipWithFB c f x y r = (x `f` y) `c` r
 600
 601 {-# RULES
 602 "zipWith"       [~1] forall f xs ys.    zipWith f xs ys = build (\c n -> foldr2 (zipWithFB c f) n xs ys)
 603 "zipWithList"   [1]  forall f.  foldr2 (zipWithFB (:) f) [] = zipWith f
 604   #-}
 605 \end{code}
 606
 607 \begin{code}
 608 -- | The 'zipWith3' function takes a function which combines three
 609 -- elements, as well as three lists and returns a list of their point-wise
 610 -- combination, analogous to 'zipWith'.
 611 zipWith3                :: (a->b->c->d) -> [a]->[b]->[c]->[d]
 612 zipWith3 z (a:as) (b:bs) (c:cs)
 613                         =  z a b c : zipWith3 z as bs cs
 614 zipWith3 _ _ _ _        =  []
 615
 616 -- | 'unzip' transforms a list of pairs into a list of first components
 617 -- and a list of second components.
 618 unzip    :: [(a,b)] -> ([a],[b])
 619 {-# INLINE unzip #-}
 620 unzip    =  foldr (\(a,b) ~(as,bs) -> (a:as,b:bs)) ([],[])
 621
 622 -- | The 'unzip3' function takes a list of triples and returns three
 623 -- lists, analogous to 'unzip'.
 624 unzip3   :: [(a,b,c)] -> ([a],[b],[c])
 625 {-# INLINE unzip3 #-}
 626 unzip3   =  foldr (\(a,b,c) ~(as,bs,cs) -> (a:as,b:bs,c:cs))
 627                   ([],[],[])
 628 \end{code}
 629
 630
 631 %*********************************************************
 632 %*                                                      *
 633 \subsection{Error code}
 634 %*                                                      *
 635 %*********************************************************
 636
 637 Common up near identical calls to `error' to reduce the number
 638 constant strings created when compiled:
 639
 640 \begin{code}
 641 errorEmptyList :: String -> a
 642 errorEmptyList fun =
 643   error (prel_list_str ++ fun ++ ": empty list")
 644
 645 prel_list_str :: String
 646 prel_list_str = "Prelude."
 647 \end{code}