GHC/Num.lhs

   1 \begin{code}
   2 {-# OPTIONS -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.Num
   6 -- Copyright   :  (c) The University of Glasgow 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- The 'Num' class and the 'Integer' type.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 #include "MachDeps.h"
  18 #if SIZEOF_HSWORD == 4
  19 #define LEFTMOST_BIT 2147483648
  20 #elif SIZEOF_HSWORD == 8
  21 #define LEFTMOST_BIT 9223372036854775808
  22 #else
  23 #error Please define LEFTMOST_BIT to be 2^(SIZEOF_HSWORD*8-1)
  24 #endif
  25
  26 module GHC.Num where
  27
  28 import {-# SOURCE #-} GHC.Err
  29 import GHC.Base
  30 import GHC.List
  31 import GHC.Enum
  32 import GHC.Show
  33
  34 infixl 7  *
  35 infixl 6  +, -
  36
  37 default ()              -- Double isn't available yet,
  38                         -- and we shouldn't be using defaults anyway
  39 \end{code}
  40
  41 %*********************************************************
  42 %*                                                      *
  43 \subsection{Standard numeric class}
  44 %*                                                      *
  45 %*********************************************************
  46
  47 \begin{code}
  48 class  (Eq a, Show a) => Num a  where
  49     (+), (-), (*)       :: a -> a -> a
  50     negate              :: a -> a
  51     abs, signum         :: a -> a
  52     fromInteger         :: Integer -> a
  53
  54     x - y               = x + negate y
  55     negate x            = 0 - x
  56
  57 {-# INLINE subtract #-}
  58 subtract :: (Num a) => a -> a -> a
  59 subtract x y = y - x
  60 \end{code}
  61
  62
  63 %*********************************************************
  64 %*                                                      *
  65 \subsection{Instances for @Int@}
  66 %*                                                      *
  67 %*********************************************************
  68
  69 \begin{code}
  70 instance  Num Int  where
  71     (+)    = plusInt
  72     (-)    = minusInt
  73     negate = negateInt
  74     (*)    = timesInt
  75     abs n  = if n `geInt` 0 then n else negateInt n
  76
  77     signum n | n `ltInt` 0 = negateInt 1
  78              | n `eqInt` 0 = 0
  79              | otherwise   = 1
  80
  81     fromInteger = integer2Int
  82 \end{code}
  83
  84
  85 \begin{code}
  86 -- These can't go in GHC.Base with the defn of Int, because
  87 -- we don't have pairs defined at that time!
  88
  89 quotRemInt :: Int -> Int -> (Int, Int)
  90 a@(I# _) `quotRemInt` b@(I# _) = (a `quotInt` b, a `remInt` b)
  91     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
  92
  93 divModInt ::  Int -> Int -> (Int, Int)
  94 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
  95     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
  96 \end{code}
  97
  98
  99 %*********************************************************
 100 %*                                                      *
 101 \subsection{The @Integer@ type}
 102 %*                                                      *
 103 %*********************************************************
 104
 105 \begin{code}
 106 data Integer
 107    = S# Int#                            -- small integers
 108 #ifndef ILX
 109    | J# Int# ByteArray#                 -- large integers
 110 #else
 111    | J# Void BigInteger                 -- .NET big ints
 112
 113 foreign type dotnet "BigInteger" BigInteger
 114 #endif
 115 \end{code}
 116
 117 Convenient boxed Integer PrimOps.
 118
 119 \begin{code}
 120 zeroInteger :: Integer
 121 zeroInteger = S# 0#
 122
 123 int2Integer :: Int -> Integer
 124 {-# INLINE int2Integer #-}
 125 int2Integer (I# i) = S# i
 126
 127 integer2Int :: Integer -> Int
 128 integer2Int (S# i)   = I# i
 129 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
 130
 131 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
 132 toBig i@(J# _ _) = i
 133 \end{code}
 134
 135
 136 %*********************************************************
 137 %*                                                      *
 138 \subsection{Dividing @Integers@}
 139 %*                                                      *
 140 %*********************************************************
 141
 142 \begin{code}
 143 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
 144 quotRemInteger a@(S# (-LEFTMOST_BIT#)) b = quotRemInteger (toBig a) b
 145 quotRemInteger (S# i) (S# j)
 146   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j )
 147 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
 148 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
 149 quotRemInteger (J# s1 d1) (J# s2 d2)
 150   = case (quotRemInteger# s1 d1 s2 d2) of
 151           (# s3, d3, s4, d4 #)
 152             -> (J# s3 d3, J# s4 d4)
 153
 154 divModInteger a@(S# (-LEFTMOST_BIT#)) b = divModInteger (toBig a) b
 155 divModInteger (S# i) (S# j)
 156   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j)
 157 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
 158 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
 159 divModInteger (J# s1 d1) (J# s2 d2)
 160   = case (divModInteger# s1 d1 s2 d2) of
 161           (# s3, d3, s4, d4 #)
 162             -> (J# s3 d3, J# s4 d4)
 163
 164 remInteger :: Integer -> Integer -> Integer
 165 remInteger ia 0
 166   = error "Prelude.Integral.rem{Integer}: divide by 0"
 167 remInteger a@(S# (-LEFTMOST_BIT#)) b = remInteger (toBig a) b
 168 remInteger (S# a) (S# b) = S# (remInt# a b)
 169 {- Special case doesn't work, because a 1-element J# has the range
 170    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
 171 remInteger ia@(S# a) (J# sb b)
 172   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
 173   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
 174   | 0# <# sb   = ia
 175   | otherwise  = S# (0# -# a)
 176 -}
 177 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
 178 remInteger (J# sa a) (S# b)
 179   = case int2Integer# b of { (# sb, b #) ->
 180     case remInteger# sa a sb b of { (# sr, r #) ->
 181     S# (integer2Int# sr r) }}
 182 remInteger (J# sa a) (J# sb b)
 183   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
 184
 185 quotInteger :: Integer -> Integer -> Integer
 186 quotInteger ia 0
 187   = error "Prelude.Integral.quot{Integer}: divide by 0"
 188 quotInteger a@(S# (-LEFTMOST_BIT#)) b = quotInteger (toBig a) b
 189 quotInteger (S# a) (S# b) = S# (quotInt# a b)
 190 {- Special case disabled, see remInteger above
 191 quotInteger (S# a) (J# sb b)
 192   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
 193   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
 194   | otherwise  = zeroInteger
 195 -}
 196 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
 197 quotInteger (J# sa a) (S# b)
 198   = case int2Integer# b of { (# sb, b #) ->
 199     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
 200 quotInteger (J# sa a) (J# sb b)
 201   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
 202 \end{code}
 203
 204
 205
 206 \begin{code}
 207 gcdInteger :: Integer -> Integer -> Integer
 208 -- SUP: Do we really need the first two cases?
 209 gcdInteger a@(S# (-LEFTMOST_BIT#)) b = gcdInteger (toBig a) b
 210 gcdInteger a b@(S# (-LEFTMOST_BIT#)) = gcdInteger a (toBig b)
 211 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
 212 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
 213 gcdInteger ia@(S# a)  ib@(J# sb b)
 214   | a  ==# 0#  = abs ib
 215   | sb ==# 0#  = abs ia
 216   | otherwise  = S# (gcdIntegerInt# absSb b absA)
 217        where absA  = if a  <# 0# then negateInt# a  else a
 218              absSb = if sb <# 0# then negateInt# sb else sb
 219 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
 220 gcdInteger (J# 0# _) (J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
 221 gcdInteger (J# sa a) (J# sb b)
 222   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
 223
 224 lcmInteger :: Integer -> Integer -> Integer
 225 lcmInteger a 0
 226   = zeroInteger
 227 lcmInteger 0 b
 228   = zeroInteger
 229 lcmInteger a b
 230   = (divExact aa (gcdInteger aa ab)) * ab
 231   where aa = abs a
 232         ab = abs b
 233
 234 divExact :: Integer -> Integer -> Integer
 235 divExact a@(S# (-LEFTMOST_BIT#)) b = divExact (toBig a) b
 236 divExact (S# a) (S# b) = S# (quotInt# a b)
 237 divExact (S# a) (J# sb b)
 238   = S# (quotInt# a (integer2Int# sb b))
 239 divExact (J# sa a) (S# b)
 240   = case int2Integer# b of
 241      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 242 divExact (J# sa a) (J# sb b)
 243   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 244 \end{code}
 245
 246
 247 %*********************************************************
 248 %*                                                      *
 249 \subsection{The @Integer@ instances for @Eq@, @Ord@}
 250 %*                                                      *
 251 %*********************************************************
 252
 253 \begin{code}
 254 instance  Eq Integer  where
 255     (S# i)     ==  (S# j)     = i ==# j
 256     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
 257     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
 258     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
 259
 260     (S# i)     /=  (S# j)     = i /=# j
 261     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
 262     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
 263     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
 264
 265 ------------------------------------------------------------------------
 266 instance  Ord Integer  where
 267     (S# i)     <=  (S# j)     = i <=# j
 268     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
 269     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
 270     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
 271
 272     (S# i)     >   (S# j)     = i ># j
 273     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
 274     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
 275     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
 276
 277     (S# i)     <   (S# j)     = i <# j
 278     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
 279     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
 280     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
 281
 282     (S# i)     >=  (S# j)     = i >=# j
 283     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
 284     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
 285     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
 286
 287     compare (S# i)  (S# j)
 288        | i ==# j = EQ
 289        | i <=# j = LT
 290        | otherwise = GT
 291     compare (J# s d) (S# i)
 292        = case cmpIntegerInt# s d i of { res# ->
 293          if res# <# 0# then LT else
 294          if res# ># 0# then GT else EQ
 295          }
 296     compare (S# i) (J# s d)
 297        = case cmpIntegerInt# s d i of { res# ->
 298          if res# ># 0# then LT else
 299          if res# <# 0# then GT else EQ
 300          }
 301     compare (J# s1 d1) (J# s2 d2)
 302        = case cmpInteger# s1 d1 s2 d2 of { res# ->
 303          if res# <# 0# then LT else
 304          if res# ># 0# then GT else EQ
 305          }
 306 \end{code}
 307
 308
 309 %*********************************************************
 310 %*                                                      *
 311 \subsection{The @Integer@ instances for @Num@}
 312 %*                                                      *
 313 %*********************************************************
 314
 315 \begin{code}
 316 instance  Num Integer  where
 317     (+) = plusInteger
 318     (-) = minusInteger
 319     (*) = timesInteger
 320     negate         = negateInteger
 321     fromInteger x  =  x
 322
 323     -- ORIG: abs n = if n >= 0 then n else -n
 324     abs (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
 325     abs (S# i) = case abs (I# i) of I# j -> S# j
 326     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
 327
 328     signum (S# i) = case signum (I# i) of I# j -> S# j
 329     signum (J# s d)
 330       = let
 331             cmp = cmpIntegerInt# s d 0#
 332         in
 333         if      cmp >#  0# then S# 1#
 334         else if cmp ==# 0# then S# 0#
 335         else                    S# (negateInt# 1#)
 336
 337 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
 338                                    if c ==# 0# then S# r
 339                                    else toBig i1 + toBig i2 }
 340 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
 341 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
 342 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 343
 344 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
 345                                      if c ==# 0# then S# r
 346                                      else toBig i1 - toBig i2 }
 347 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
 348 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
 349 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 350
 351 timesInteger i1@(S# i) i2@(S# j)   = if   mulIntMayOflo# i j ==# 0#
 352                                      then S# (i *# j)
 353                                      else toBig i1 * toBig i2
 354 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
 355 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
 356 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 357
 358 negateInteger (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
 359 negateInteger (S# i)              = S# (negateInt# i)
 360 negateInteger (J# s d)            = J# (negateInt# s) d
 361 \end{code}
 362
 363
 364 %*********************************************************
 365 %*                                                      *
 366 \subsection{The @Integer@ instance for @Enum@}
 367 %*                                                      *
 368 %*********************************************************
 369
 370 \begin{code}
 371 instance  Enum Integer  where
 372     succ x               = x + 1
 373     pred x               = x - 1
 374     toEnum n             = int2Integer n
 375     fromEnum n           = integer2Int n
 376
 377     {-# INLINE enumFrom #-}
 378     {-# INLINE enumFromThen #-}
 379     {-# INLINE enumFromTo #-}
 380     {-# INLINE enumFromThenTo #-}
 381     enumFrom x             = enumDeltaInteger  x 1
 382     enumFromThen x y       = enumDeltaInteger  x (y-x)
 383     enumFromTo x lim       = enumDeltaToInteger x 1     lim
 384     enumFromThenTo x y lim = enumDeltaToInteger x (y-x) lim
 385
 386 {-# RULES
 387 "enumDeltaInteger"      [~1] forall x y.  enumDeltaInteger x y     = build (\c _ -> enumDeltaIntegerFB c x y)
 388 "efdtInteger"           [~1] forall x y l.enumDeltaToInteger x y l = build (\c n -> enumDeltaToIntegerFB c n x y l)
 389 "enumDeltaInteger"      [1] enumDeltaIntegerFB   (:)    = enumDeltaInteger
 390 "enumDeltaToInteger"    [1] enumDeltaToIntegerFB (:) [] = enumDeltaToInteger
 391  #-}
 392
 393 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
 394 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
 395
 396 enumDeltaInteger :: Integer -> Integer -> [Integer]
 397 enumDeltaInteger x d = x : enumDeltaInteger (x+d) d
 398
 399 enumDeltaToIntegerFB c n x delta lim
 400   | delta >= 0 = up_fb c n x delta lim
 401   | otherwise  = dn_fb c n x delta lim
 402
 403 enumDeltaToInteger x delta lim
 404   | delta >= 0 = up_list x delta lim
 405   | otherwise  = dn_list x delta lim
 406
 407 up_fb c n x delta lim = go (x::Integer)
 408                       where
 409                         go x | x > lim   = n
 410                              | otherwise = x `c` go (x+delta)
 411 dn_fb c n x delta lim = go (x::Integer)
 412                       where
 413                         go x | x < lim   = n
 414                              | otherwise = x `c` go (x+delta)
 415
 416 up_list x delta lim = go (x::Integer)
 417                     where
 418                         go x | x > lim   = []
 419                              | otherwise = x : go (x+delta)
 420 dn_list x delta lim = go (x::Integer)
 421                     where
 422                         go x | x < lim   = []
 423                              | otherwise = x : go (x+delta)
 424
 425 \end{code}
 426
 427
 428 %*********************************************************
 429 %*                                                      *
 430 \subsection{The @Integer@ instances for @Show@}
 431 %*                                                      *
 432 %*********************************************************
 433
 434 \begin{code}
 435 instance Show Integer where
 436     showsPrec p n r
 437         | p > 6 && n < 0 = '(' : jtos n (')' : r)
 438                 -- Minor point: testing p first gives better code
 439                 -- in the not-uncommon case where the p argument
 440                 -- is a constant
 441         | otherwise      = jtos n r
 442     showList = showList__ (showsPrec 0)
 443
 444 jtos :: Integer -> String -> String
 445 jtos n cs
 446     | n < 0     = '-' : jtos' (-n) cs
 447     | otherwise = jtos' n cs
 448     where
 449     jtos' :: Integer -> String -> String
 450     jtos' n' cs'
 451         | n' < 10    = case unsafeChr (ord '0' + fromInteger n') of
 452             c@(C# _) -> c:cs'
 453         | otherwise = case unsafeChr (ord '0' + fromInteger r) of
 454             c@(C# _) -> jtos' q (c:cs')
 455         where
 456         (q,r) = n' `quotRemInteger` 10
 457 \end{code}