GHC/Real.lhs

   1 \begin{code}
   2 {-# LANGUAGE CPP, NoImplicitPrelude, MagicHash, UnboxedTuples #-}
   3 {-# OPTIONS_HADDOCK hide #-}
   4 -----------------------------------------------------------------------------
   5 -- |
   6 -- Module      :  GHC.Real
   7 -- Copyright   :  (c) The University of Glasgow, 1994-2002
   8 -- License     :  see libraries/base/LICENSE
   9 --
  10 -- Maintainer  :  cvs-ghc@haskell.org
  11 -- Stability   :  internal
  12 -- Portability :  non-portable (GHC Extensions)
  13 --
  14 -- The types 'Ratio' and 'Rational', and the classes 'Real', 'Fractional',
  15 -- 'Integral', and 'RealFrac'.
  16 --
  17 -----------------------------------------------------------------------------
  18
  19 -- #hide
  20 module GHC.Real where
  21
  22 import GHC.Base
  23 import GHC.Num
  24 import GHC.List
  25 import GHC.Enum
  26 import GHC.Show
  27 import GHC.Err
  28
  29 infixr 8  ^, ^^
  30 infixl 7  /, `quot`, `rem`, `div`, `mod`
  31 infixl 7  %
  32
  33 default ()              -- Double isn't available yet,
  34                         -- and we shouldn't be using defaults anyway
  35 \end{code}
  36
  37
  38 %*********************************************************
  39 %*                                                      *
  40 \subsection{The @Ratio@ and @Rational@ types}
  41 %*                                                      *
  42 %*********************************************************
  43
  44 \begin{code}
  45 -- | Rational numbers, with numerator and denominator of some 'Integral' type.
  46 data  (Integral a)      => Ratio a = !a :% !a  deriving (Eq)
  47
  48 -- | Arbitrary-precision rational numbers, represented as a ratio of
  49 -- two 'Integer' values.  A rational number may be constructed using
  50 -- the '%' operator.
  51 type  Rational          =  Ratio Integer
  52
  53 ratioPrec, ratioPrec1 :: Int
  54 ratioPrec  = 7  -- Precedence of ':%' constructor
  55 ratioPrec1 = ratioPrec + 1
  56
  57 infinity, notANumber :: Rational
  58 infinity   = 1 :% 0
  59 notANumber = 0 :% 0
  60
  61 -- Use :%, not % for Inf/NaN; the latter would
  62 -- immediately lead to a runtime error, because it normalises.
  63 \end{code}
  64
  65
  66 \begin{code}
  67 -- | Forms the ratio of two integral numbers.
  68 {-# SPECIALISE (%) :: Integer -> Integer -> Rational #-}
  69 (%)                     :: (Integral a) => a -> a -> Ratio a
  70
  71 -- | Extract the numerator of the ratio in reduced form:
  72 -- the numerator and denominator have no common factor and the denominator
  73 -- is positive.
  74 numerator       :: (Integral a) => Ratio a -> a
  75
  76 -- | Extract the denominator of the ratio in reduced form:
  77 -- the numerator and denominator have no common factor and the denominator
  78 -- is positive.
  79 denominator     :: (Integral a) => Ratio a -> a
  80 \end{code}
  81
  82 \tr{reduce} is a subsidiary function used only in this module .
  83 It normalises a ratio by dividing both numerator and denominator by
  84 their greatest common divisor.
  85
  86 \begin{code}
  87 reduce ::  (Integral a) => a -> a -> Ratio a
  88 {-# SPECIALISE reduce :: Integer -> Integer -> Rational #-}
  89 reduce _ 0              =  error "Ratio.%: zero denominator"
  90 reduce x y              =  (x `quot` d) :% (y `quot` d)
  91                            where d = gcd x y
  92 \end{code}
  93
  94 \begin{code}
  95 x % y                   =  reduce (x * signum y) (abs y)
  96
  97 numerator   (x :% _)    =  x
  98 denominator (_ :% y)    =  y
  99 \end{code}
 100
 101
 102 %*********************************************************
 103 %*                                                      *
 104 \subsection{Standard numeric classes}
 105 %*                                                      *
 106 %*********************************************************
 107
 108 \begin{code}
 109 class  (Num a, Ord a) => Real a  where
 110     -- | the rational equivalent of its real argument with full precision
 111     toRational          ::  a -> Rational
 112
 113 -- | Integral numbers, supporting integer division.
 114 --
 115 -- Minimal complete definition: 'quotRem' and 'toInteger'
 116 class  (Real a, Enum a) => Integral a  where
 117     -- | integer division truncated toward zero
 118     quot                :: a -> a -> a
 119     -- | integer remainder, satisfying
 120     --
 121     -- > (x `quot` y)*y + (x `rem` y) == x
 122     rem                 :: a -> a -> a
 123     -- | integer division truncated toward negative infinity
 124     div                 :: a -> a -> a
 125     -- | integer modulus, satisfying
 126     --
 127     -- > (x `div` y)*y + (x `mod` y) == x
 128     mod                 :: a -> a -> a
 129     -- | simultaneous 'quot' and 'rem'
 130     quotRem             :: a -> a -> (a,a)
 131     -- | simultaneous 'div' and 'mod'
 132     divMod              :: a -> a -> (a,a)
 133     -- | conversion to 'Integer'
 134     toInteger           :: a -> Integer
 135
 136     {-# INLINE quot #-}
 137     {-# INLINE rem #-}
 138     {-# INLINE div #-}
 139     {-# INLINE mod #-}
 140     n `quot` d          =  q  where (q,_) = quotRem n d
 141     n `rem` d           =  r  where (_,r) = quotRem n d
 142     n `div` d           =  q  where (q,_) = divMod n d
 143     n `mod` d           =  r  where (_,r) = divMod n d
 144
 145     divMod n d          =  if signum r == negate (signum d) then (q-1, r+d) else qr
 146                            where qr@(q,r) = quotRem n d
 147
 148 -- | Fractional numbers, supporting real division.
 149 --
 150 -- Minimal complete definition: 'fromRational' and ('recip' or @('/')@)
 151 class  (Num a) => Fractional a  where
 152     -- | fractional division
 153     (/)                 :: a -> a -> a
 154     -- | reciprocal fraction
 155     recip               :: a -> a
 156     -- | Conversion from a 'Rational' (that is @'Ratio' 'Integer'@).
 157     -- A floating literal stands for an application of 'fromRational'
 158     -- to a value of type 'Rational', so such literals have type
 159     -- @('Fractional' a) => a@.
 160     fromRational        :: Rational -> a
 161
 162     {-# INLINE recip #-}
 163     {-# INLINE (/) #-}
 164     recip x             =  1 / x
 165     x / y               = x * recip y
 166
 167 -- | Extracting components of fractions.
 168 --
 169 -- Minimal complete definition: 'properFraction'
 170 class  (Real a, Fractional a) => RealFrac a  where
 171     -- | The function 'properFraction' takes a real fractional number @x@
 172     -- and returns a pair @(n,f)@ such that @x = n+f@, and:
 173     --
 174     -- * @n@ is an integral number with the same sign as @x@; and
 175     --
 176     -- * @f@ is a fraction with the same type and sign as @x@,
 177     --   and with absolute value less than @1@.
 178     --
 179     -- The default definitions of the 'ceiling', 'floor', 'truncate'
 180     -- and 'round' functions are in terms of 'properFraction'.
 181     properFraction      :: (Integral b) => a -> (b,a)
 182     -- | @'truncate' x@ returns the integer nearest @x@ between zero and @x@
 183     truncate            :: (Integral b) => a -> b
 184     -- | @'round' x@ returns the nearest integer to @x@;
 185     --   the even integer if @x@ is equidistant between two integers
 186     round               :: (Integral b) => a -> b
 187     -- | @'ceiling' x@ returns the least integer not less than @x@
 188     ceiling             :: (Integral b) => a -> b
 189     -- | @'floor' x@ returns the greatest integer not greater than @x@
 190     floor               :: (Integral b) => a -> b
 191
 192     {-# INLINE truncate #-}
 193     truncate x          =  m  where (m,_) = properFraction x
 194
 195     round x             =  let (n,r) = properFraction x
 196                                m     = if r < 0 then n - 1 else n + 1
 197                            in case signum (abs r - 0.5) of
 198                                 -1 -> n
 199                                 0  -> if even n then n else m
 200                                 1  -> m
 201                                 _  -> error "round default defn: Bad value"
 202
 203     ceiling x           =  if r > 0 then n + 1 else n
 204                            where (n,r) = properFraction x
 205
 206     floor x             =  if r < 0 then n - 1 else n
 207                            where (n,r) = properFraction x
 208 \end{code}
 209
 210
 211 These 'numeric' enumerations come straight from the Report
 212
 213 \begin{code}
 214 numericEnumFrom         :: (Fractional a) => a -> [a]
 215 numericEnumFrom n       =  n `seq` (n : numericEnumFrom (n + 1))
 216
 217 numericEnumFromThen     :: (Fractional a) => a -> a -> [a]
 218 numericEnumFromThen n m = n `seq` m `seq` (n : numericEnumFromThen m (m+m-n))
 219
 220 numericEnumFromTo       :: (Ord a, Fractional a) => a -> a -> [a]
 221 numericEnumFromTo n m   = takeWhile (<= m + 1/2) (numericEnumFrom n)
 222
 223 numericEnumFromThenTo   :: (Ord a, Fractional a) => a -> a -> a -> [a]
 224 numericEnumFromThenTo e1 e2 e3
 225     = takeWhile predicate (numericEnumFromThen e1 e2)
 226                                 where
 227                                  mid = (e2 - e1) / 2
 228                                  predicate | e2 >= e1  = (<= e3 + mid)
 229                                            | otherwise = (>= e3 + mid)
 230 \end{code}
 231
 232
 233 %*********************************************************
 234 %*                                                      *
 235 \subsection{Instances for @Int@}
 236 %*                                                      *
 237 %*********************************************************
 238
 239 \begin{code}
 240 instance  Real Int  where
 241     toRational x        =  toInteger x % 1
 242
 243 instance  Integral Int  where
 244     toInteger (I# i) = smallInteger i
 245
 246     a `quot` b
 247      | b == 0                     = divZeroError
 248      | b == (-1) && a == minBound = overflowError
 249      | otherwise                  =  a `quotInt` b
 250
 251     a `rem` b
 252      | b == 0                     = divZeroError
 253      | b == (-1) && a == minBound = overflowError
 254      | otherwise                  =  a `remInt` b
 255
 256     a `div` b
 257      | b == 0                     = divZeroError
 258      | b == (-1) && a == minBound = overflowError
 259      | otherwise                  =  a `divInt` b
 260
 261     a `mod` b
 262      | b == 0                     = divZeroError
 263      | b == (-1) && a == minBound = overflowError
 264      | otherwise                  =  a `modInt` b
 265
 266     a `quotRem` b
 267      | b == 0                     = divZeroError
 268      | b == (-1) && a == minBound = overflowError
 269      | otherwise                  =  a `quotRemInt` b
 270
 271     a `divMod` b
 272      | b == 0                     = divZeroError
 273      | b == (-1) && a == minBound = overflowError
 274      | otherwise                  =  a `divModInt` b
 275 \end{code}
 276
 277
 278 %*********************************************************
 279 %*                                                      *
 280 \subsection{Instances for @Integer@}
 281 %*                                                      *
 282 %*********************************************************
 283
 284 \begin{code}
 285 instance  Real Integer  where
 286     toRational x        =  x % 1
 287
 288 instance  Integral Integer where
 289     toInteger n      = n
 290
 291     _ `quot` 0 = divZeroError
 292     n `quot` d = n `quotInteger` d
 293
 294     _ `rem` 0 = divZeroError
 295     n `rem`  d = n `remInteger`  d
 296
 297     _ `divMod` 0 = divZeroError
 298     a `divMod` b = case a `divModInteger` b of
 299                    (# x, y #) -> (x, y)
 300
 301     _ `quotRem` 0 = divZeroError
 302     a `quotRem` b = case a `quotRemInteger` b of
 303                     (# q, r #) -> (q, r)
 304
 305     -- use the defaults for div & mod
 306 \end{code}
 307
 308
 309 %*********************************************************
 310 %*                                                      *
 311 \subsection{Instances for @Ratio@}
 312 %*                                                      *
 313 %*********************************************************
 314
 315 \begin{code}
 316 instance  (Integral a)  => Ord (Ratio a)  where
 317     {-# SPECIALIZE instance Ord Rational #-}
 318     (x:%y) <= (x':%y')  =  x * y' <= x' * y
 319     (x:%y) <  (x':%y')  =  x * y' <  x' * y
 320
 321 instance  (Integral a)  => Num (Ratio a)  where
 322     {-# SPECIALIZE instance Num Rational #-}
 323     (x:%y) + (x':%y')   =  reduce (x*y' + x'*y) (y*y')
 324     (x:%y) - (x':%y')   =  reduce (x*y' - x'*y) (y*y')
 325     (x:%y) * (x':%y')   =  reduce (x * x') (y * y')
 326     negate (x:%y)       =  (-x) :% y
 327     abs (x:%y)          =  abs x :% y
 328     signum (x:%_)       =  signum x :% 1
 329     fromInteger x       =  fromInteger x :% 1
 330
 331 {-# RULES "fromRational/id" fromRational = id :: Rational -> Rational #-}
 332 instance  (Integral a)  => Fractional (Ratio a)  where
 333     {-# SPECIALIZE instance Fractional Rational #-}
 334     (x:%y) / (x':%y')   =  (x*y') % (y*x')
 335     recip (0:%_)        = error "Ratio.%: zero denominator"
 336     recip (x:%y)
 337         | x < 0         = negate y :% negate x
 338         | otherwise     = y :% x
 339     fromRational (x:%y) =  fromInteger x % fromInteger y
 340
 341 instance  (Integral a)  => Real (Ratio a)  where
 342     {-# SPECIALIZE instance Real Rational #-}
 343     toRational (x:%y)   =  toInteger x :% toInteger y
 344
 345 instance  (Integral a)  => RealFrac (Ratio a)  where
 346     {-# SPECIALIZE instance RealFrac Rational #-}
 347     properFraction (x:%y) = (fromInteger (toInteger q), r:%y)
 348                           where (q,r) = quotRem x y
 349
 350 instance  (Integral a)  => Show (Ratio a)  where
 351     {-# SPECIALIZE instance Show Rational #-}
 352     showsPrec p (x:%y)  =  showParen (p > ratioPrec) $
 353                            showsPrec ratioPrec1 x .
 354                            showString " % " .
 355                            -- H98 report has spaces round the %
 356                            -- but we removed them [May 04]
 357                            -- and added them again for consistency with
 358                            -- Haskell 98 [Sep 08, #1920]
 359                            showsPrec ratioPrec1 y
 360
 361 instance  (Integral a)  => Enum (Ratio a)  where
 362     {-# SPECIALIZE instance Enum Rational #-}
 363     succ x              =  x + 1
 364     pred x              =  x - 1
 365
 366     toEnum n            =  fromIntegral n :% 1
 367     fromEnum            =  fromInteger . truncate
 368
 369     enumFrom            =  numericEnumFrom
 370     enumFromThen        =  numericEnumFromThen
 371     enumFromTo          =  numericEnumFromTo
 372     enumFromThenTo      =  numericEnumFromThenTo
 373 \end{code}
 374
 375
 376 %*********************************************************
 377 %*                                                      *
 378 \subsection{Coercions}
 379 %*                                                      *
 380 %*********************************************************
 381
 382 \begin{code}
 383 -- | general coercion from integral types
 384 fromIntegral :: (Integral a, Num b) => a -> b
 385 fromIntegral = fromInteger . toInteger
 386
 387 {-# RULES
 388 "fromIntegral/Int->Int" fromIntegral = id :: Int -> Int
 389     #-}
 390
 391 -- | general coercion to fractional types
 392 realToFrac :: (Real a, Fractional b) => a -> b
 393 realToFrac = fromRational . toRational
 394
 395 {-# RULES
 396 "realToFrac/Int->Int" realToFrac = id :: Int -> Int
 397     #-}
 398 \end{code}
 399
 400 %*********************************************************
 401 %*                                                      *
 402 \subsection{Overloaded numeric functions}
 403 %*                                                      *
 404 %*********************************************************
 405
 406 \begin{code}
 407 -- | Converts a possibly-negative 'Real' value to a string.
 408 showSigned :: (Real a)
 409   => (a -> ShowS)       -- ^ a function that can show unsigned values
 410   -> Int                -- ^ the precedence of the enclosing context
 411   -> a                  -- ^ the value to show
 412   -> ShowS
 413 showSigned showPos p x
 414    | x < 0     = showParen (p > 6) (showChar '-' . showPos (-x))
 415    | otherwise = showPos x
 416
 417 even, odd       :: (Integral a) => a -> Bool
 418 even n          =  n `rem` 2 == 0
 419 odd             =  not . even
 420
 421 -------------------------------------------------------
 422 -- | raise a number to a non-negative integral power
 423 {-# SPECIALISE (^) ::
 424         Integer -> Integer -> Integer,
 425         Integer -> Int -> Integer,
 426         Int -> Int -> Int #-}
 427 {-# INLINABLE (^) #-}    -- See Note [Inlining (^)]
 428 (^) :: (Num a, Integral b) => a -> b -> a
 429 x0 ^ y0 | y0 < 0    = error "Negative exponent"
 430         | y0 == 0   = 1
 431         | otherwise = f x0 y0
 432     where -- f : x0 ^ y0 = x ^ y
 433           f x y | even y    = f (x * x) (y `quot` 2)
 434                 | y == 1    = x
 435                 | otherwise = g (x * x) ((y - 1) `quot` 2) x
 436           -- g : x0 ^ y0 = (x ^ y) * z
 437           g x y z | even y = g (x * x) (y `quot` 2) z
 438                   | y == 1 = x * z
 439                   | otherwise = g (x * x) ((y - 1) `quot` 2) (x * z)
 440
 441 -- | raise a number to an integral power
 442 (^^)            :: (Fractional a, Integral b) => a -> b -> a
 443 {-# INLINABLE (^^) #-}         -- See Note [Inlining (^)
 444 x ^^ n          =  if n >= 0 then x^n else recip (x^(negate n))
 445
 446 {- Note [Inlining (^)
 447    ~~~~~~~~~~~~~~~~~~~~~
 448    The INLINABLE pragma allows (^) to be specialised at its call sites.
 449    If it is called repeatedly at the same type, that can make a huge
 450    difference, because of those constants which can be repeatedly
 451    calculated.
 452
 453    Currently the fromInteger calls are not floated because we get
 454              \d1 d2 x y -> blah
 455    after the gentle round of simplification. -}
 456
 457 -------------------------------------------------------
 458 -- Special power functions for Rational
 459 --
 460 -- see #4337
 461 --
 462 -- Rationale:
 463 -- For a legitimate Rational (n :% d), the numerator and denominator are
 464 -- coprime, i.e. they have no common prime factor.
 465 -- Therefore all powers (n ^ a) and (d ^ b) are also coprime, so it is
 466 -- not necessary to compute the greatest common divisor, which would be
 467 -- done in the default implementation at each multiplication step.
 468 -- Since exponentiation quickly leads to very large numbers and
 469 -- calculation of gcds is generally very slow for large numbers,
 470 -- avoiding the gcd leads to an order of magnitude speedup relatively
 471 -- soon (and an asymptotic improvement overall).
 472 --
 473 -- Note:
 474 -- We cannot use these functions for general Ratio a because that would
 475 -- change results in a multitude of cases.
 476 -- The cause is that if a and b are coprime, their remainders by any
 477 -- positive modulus generally aren't, so in the default implementation
 478 -- reduction occurs.
 479 --
 480 -- Example:
 481 -- (17 % 3) ^ 3 :: Ratio Word8
 482 -- Default:
 483 -- (17 % 3) ^ 3 = ((17 % 3) ^ 2) * (17 % 3)
 484 --              = ((289 `mod` 256) % 9) * (17 % 3)
 485 --              = (33 % 9) * (17 % 3)
 486 --              = (11 % 3) * (17 % 3)
 487 --              = (187 % 9)
 488 -- But:
 489 -- ((17^3) `mod` 256) % (3^3)   = (4913 `mod` 256) % 27
 490 --                              = 49 % 27
 491 --
 492 -- TODO:
 493 -- Find out whether special-casing for numerator, denominator or
 494 -- exponent = 1 (or -1, where that may apply) gains something.
 495
 496 -- Special version of (^) for Rational base
 497 {-# RULES "(^)/Rational"    (^) = (^%^) #-}
 498 (^%^)           :: Integral a => Rational -> a -> Rational
 499 (n :% d) ^%^ e
 500     | e < 0     = error "Negative exponent"
 501     | e == 0    = 1 :% 1
 502     | otherwise = (n ^ e) :% (d ^ e)
 503
 504 -- Special version of (^^) for Rational base
 505 {-# RULES "(^^)/Rational"   (^^) = (^^%^^) #-}
 506 (^^%^^)         :: Integral a => Rational -> a -> Rational
 507 (n :% d) ^^%^^ e
 508     | e > 0     = (n ^ e) :% (d ^ e)
 509     | e == 0    = 1 :% 1
 510     | n > 0     = (d ^ (negate e)) :% (n ^ (negate e))
 511     | n == 0    = error "Ratio.%: zero denominator"
 512     | otherwise = let nn = d ^ (negate e)
 513                       dd = (negate n) ^ (negate e)
 514                   in if even e then (nn :% dd) else (negate nn :% dd)
 515
 516 -------------------------------------------------------
 517 -- | @'gcd' x y@ is the greatest (positive) integer that divides both @x@
 518 -- and @y@; for example @'gcd' (-3) 6@ = @3@, @'gcd' (-3) (-6)@ = @3@,
 519 -- @'gcd' 0 4@ = @4@.  @'gcd' 0 0@ raises a runtime error.
 520 gcd             :: (Integral a) => a -> a -> a
 521 gcd 0 0         =  error "Prelude.gcd: gcd 0 0 is undefined"
 522 gcd x y         =  gcd' (abs x) (abs y)
 523                    where gcd' a 0  =  a
 524                          gcd' a b  =  gcd' b (a `rem` b)
 525
 526 -- | @'lcm' x y@ is the smallest positive integer that both @x@ and @y@ divide.
 527 lcm             :: (Integral a) => a -> a -> a
 528 {-# SPECIALISE lcm :: Int -> Int -> Int #-}
 529 lcm _ 0         =  0
 530 lcm 0 _         =  0
 531 lcm x y         =  abs ((x `quot` (gcd x y)) * y)
 532
 533 #ifdef OPTIMISE_INTEGER_GCD_LCM
 534 {-# RULES
 535 "gcd/Int->Int->Int"             gcd = gcdInt
 536 "gcd/Integer->Integer->Integer" gcd = gcdInteger'
 537 "lcm/Integer->Integer->Integer" lcm = lcmInteger
 538  #-}
 539
 540 gcdInteger' :: Integer -> Integer -> Integer
 541 gcdInteger' 0 0 = error "GHC.Real.gcdInteger': gcd 0 0 is undefined"
 542 gcdInteger' a b = gcdInteger a b
 543
 544 gcdInt :: Int -> Int -> Int
 545 gcdInt 0 0 = error "GHC.Real.gcdInt: gcd 0 0 is undefined"
 546 gcdInt a b = fromIntegral (gcdInteger (fromIntegral a) (fromIntegral b))
 547 #endif
 548
 549 integralEnumFrom :: (Integral a, Bounded a) => a -> [a]
 550 integralEnumFrom n = map fromInteger [toInteger n .. toInteger (maxBound `asTypeOf` n)]
 551
 552 integralEnumFromThen :: (Integral a, Bounded a) => a -> a -> [a]
 553 integralEnumFromThen n1 n2
 554   | i_n2 >= i_n1  = map fromInteger [i_n1, i_n2 .. toInteger (maxBound `asTypeOf` n1)]
 555   | otherwise     = map fromInteger [i_n1, i_n2 .. toInteger (minBound `asTypeOf` n1)]
 556   where
 557     i_n1 = toInteger n1
 558     i_n2 = toInteger n2
 559
 560 integralEnumFromTo :: Integral a => a -> a -> [a]
 561 integralEnumFromTo n m = map fromInteger [toInteger n .. toInteger m]
 562
 563 integralEnumFromThenTo :: Integral a => a -> a -> a -> [a]
 564 integralEnumFromThenTo n1 n2 m
 565   = map fromInteger [toInteger n1, toInteger n2 .. toInteger m]
 566 \end{code}