GHC/Unicode.hs

   1 {-# OPTIONS -fno-implicit-prelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  GHC.Unicde
   5 -- Copyright   :  (c) The University of Glasgow, 2003
   6 -- License     :  see libraries/base/LICENSE
   7 --
   8 -- Maintainer  :  cvs-ghc@haskell.org
   9 -- Stability   :  internal
  10 -- Portability :  non-portable (GHC extensions)
  11 --
  12 -- Implementations for the character predicates (isLower, isUpper, etc.)
  13 -- and the conversions (toUpper, toLower).  The implementation uses
  14 -- libunicode on Unix systems if that is available.
  15 --
  16 -----------------------------------------------------------------------------
  17
  18 module GHC.Unicode (
  19     isAscii, isLatin1, isControl,
  20     isAsciiUpper, isAsciiLower,
  21     isPrint, isSpace,  isUpper,
  22     isLower, isAlpha,  isDigit,
  23     isOctDigit, isHexDigit, isAlphaNum,
  24     toUpper, toLower,
  25   ) where
  26
  27 import GHC.Base
  28 import GHC.Real  (fromIntegral)
  29 import GHC.Int
  30 import GHC.Word
  31 import GHC.Num   (fromInteger)
  32
  33 #include "config.h"
  34
  35 -- | Selects the first 128 characters of the Unicode character set,
  36 -- corresponding to the ASCII character set.
  37 isAscii                 :: Char -> Bool
  38 isAscii c               =  c <  '\x80'
  39
  40 -- | Selects the first 256 characters of the Unicode character set,
  41 -- corresponding to the ISO 8859-1 (Latin-1) character set.
  42 isLatin1                :: Char -> Bool
  43 isLatin1 c              =  c <= '\xff'
  44
  45 isAsciiUpper, isAsciiLower :: Char -> Bool
  46 isAsciiLower c          =  c >= 'a' && c <= 'z'
  47 isAsciiUpper c          =  c >= 'A' && c <= 'Z'
  48
  49 -- | Selects control characters, which are the non-printing characters of
  50 -- the Latin-1 subset of Unicode.
  51 isControl               :: Char -> Bool
  52
  53 -- | Selects printable Unicode characters
  54 -- (letters, numbers, marks, punctuation, symbols and spaces).
  55 isPrint                 :: Char -> Bool
  56
  57 -- | Selects white-space characters in the Latin-1 range.
  58 -- (In Unicode terms, this includes spaces and some control characters.)
  59 isSpace                 :: Char -> Bool
  60 -- isSpace includes non-breaking space
  61 -- Done with explicit equalities both for efficiency, and to avoid a tiresome
  62 -- recursion with GHC.List elem
  63 isSpace c               =  c == ' '     ||
  64                            c == '\t'    ||
  65                            c == '\n'    ||
  66                            c == '\r'    ||
  67                            c == '\f'    ||
  68                            c == '\v'    ||
  69                            c == '\xa0'
  70
  71 -- | Selects alphabetic Unicode characters (letters) that are not lower-case.
  72 -- (In Unicode terms, this includes letters in upper and title cases,
  73 -- as well as modifier letters and other letters.)
  74 isUpper                 :: Char -> Bool
  75
  76 -- | Selects lower-case alphabetic Unicode characters (letters).
  77 isLower                 :: Char -> Bool
  78
  79 -- | Selects alphabetic Unicode characters (letters).
  80 isAlpha                 :: Char -> Bool
  81
  82 -- | Selects alphabetic or numeric digit Unicode characters.
  83 --
  84 -- Note that numeric digits outside the ASCII range are selected by this
  85 -- function but not by 'isDigit'.  Such digits may be part of identifiers
  86 -- but are not used by the printer and reader to represent numbers.
  87 isAlphaNum              :: Char -> Bool
  88
  89 -- | Selects ASCII digits, i.e. @\'0\'@..@\'9\'@.
  90 isDigit                 :: Char -> Bool
  91
  92 -- | Selects ASCII octal digits, i.e. @\'0\'@..@\'7\'@.
  93 isOctDigit              :: Char -> Bool
  94 isOctDigit c            =  c >= '0' && c <= '7'
  95
  96 -- | Selects ASCII hexadecimal digits,
  97 -- i.e. @\'0\'@..@\'9\'@, @\'a\'@..@\'f\'@, @\'A\'@..@\'F\'@.
  98 isHexDigit              :: Char -> Bool
  99 isHexDigit c            =  isDigit c || c >= 'A' && c <= 'F' ||
 100                                         c >= 'a' && c <= 'f'
 101
 102 -- | Convert a letter to the corresponding upper-case letter, leaving any
 103 -- other character unchanged.  Any Unicode letter which has an upper-case
 104 -- equivalent is transformed.
 105 toUpper                 :: Char -> Char
 106
 107 -- | Convert a letter to the corresponding lower-case letter, leaving any
 108 -- other character unchanged.  Any Unicode letter which has a lower-case
 109 -- equivalent is transformed.
 110 toLower                 :: Char -> Char
 111
 112 -- -----------------------------------------------------------------------------
 113 -- Win32 implementation
 114
 115 #if (defined(HAVE_WCTYPE_H) && HAVE_ISWSPACE && defined(HTYPE_WINT_T)) || mingw32_TARGET_OS
 116
 117 -- Use the wide-char classification functions if available.  Glibc
 118 -- seems to implement these properly, even for chars > 0xffff, as long
 119 -- as you call setlocale() to set the locale to something other than
 120 -- "C".  Therefore, we call setlocale() in hs_init().
 121
 122 -- Win32 uses UTF-16, so presumably the system-supplied iswlower() and
 123 -- friends won't work properly with characters > 0xffff.  These
 124 -- characters are represented as surrogate pairs in UTF-16.
 125
 126 type WInt = HTYPE_WINT_T
 127 type CInt = HTYPE_INT
 128
 129 isDigit    c = iswdigit (fromIntegral (ord c)) /= 0
 130 isAlpha    c = iswalpha (fromIntegral (ord c)) /= 0
 131 isAlphaNum c = iswalnum (fromIntegral (ord c)) /= 0
 132 --isSpace    c = iswspace (fromIntegral (ord c)) /= 0
 133 isControl  c = iswcntrl (fromIntegral (ord c)) /= 0
 134 isPrint    c = iswprint (fromIntegral (ord c)) /= 0
 135 isUpper    c = iswupper (fromIntegral (ord c)) /= 0
 136 isLower    c = iswlower (fromIntegral (ord c)) /= 0
 137
 138 toLower c = chr (fromIntegral (towlower (fromIntegral (ord c))))
 139 toUpper c = chr (fromIntegral (towupper (fromIntegral (ord c))))
 140
 141 foreign import ccall unsafe "iswdigit"
 142   iswdigit :: WInt -> CInt
 143
 144 foreign import ccall unsafe "iswalpha"
 145   iswalpha :: WInt -> CInt
 146
 147 foreign import ccall unsafe "iswalnum"
 148   iswalnum :: WInt -> CInt
 149
 150 foreign import ccall unsafe "iswcntrl"
 151   iswcntrl :: WInt -> CInt
 152
 153 foreign import ccall unsafe "iswspace"
 154   iswspace :: WInt -> CInt
 155
 156 foreign import ccall unsafe "iswprint"
 157   iswprint :: WInt -> CInt
 158
 159 foreign import ccall unsafe "iswlower"
 160   iswlower :: WInt -> CInt
 161
 162 foreign import ccall unsafe "iswupper"
 163   iswupper :: WInt -> CInt
 164
 165 foreign import ccall unsafe "towlower"
 166   towlower :: WInt -> WInt
 167
 168 foreign import ccall unsafe "towupper"
 169   towupper :: WInt -> WInt
 170
 171 -- -----------------------------------------------------------------------------
 172 -- No libunicode, so fall back to the ASCII-only implementation
 173
 174 #else
 175
 176 isControl c             =  c < ' ' || c >= '\DEL' && c <= '\x9f'
 177 isPrint c               =  not (isControl c)
 178
 179 -- The upper case ISO characters have the multiplication sign dumped
 180 -- randomly in the middle of the range.  Go figure.
 181 isUpper c               =  c >= 'A' && c <= 'Z' ||
 182                            c >= '\xC0' && c <= '\xD6' ||
 183                            c >= '\xD8' && c <= '\xDE'
 184 -- The lower case ISO characters have the division sign dumped
 185 -- randomly in the middle of the range.  Go figure.
 186 isLower c               =  c >= 'a' && c <= 'z' ||
 187                            c >= '\xDF' && c <= '\xF6' ||
 188                            c >= '\xF8' && c <= '\xFF'
 189
 190 isAlpha c               =  isLower c || isUpper c
 191 isDigit c               =  c >= '0' && c <= '9'
 192 isAlphaNum c            =  isAlpha c || isDigit c
 193
 194 -- Case-changing operations
 195
 196 toUpper c@(C# c#)
 197   | isAsciiLower c    = C# (chr# (ord# c# -# 32#))
 198   | isAscii c         = c
 199     -- fall-through to the slower stuff.
 200   | isLower c   && c /= '\xDF' && c /= '\xFF'
 201   = unsafeChr (ord c `minusInt` ord 'a' `plusInt` ord 'A')
 202   | otherwise
 203   = c
 204
 205
 206 toLower c@(C# c#)
 207   | isAsciiUpper c = C# (chr# (ord# c# +# 32#))
 208   | isAscii c      = c
 209   | isUpper c      = unsafeChr (ord c `minusInt` ord 'A' `plusInt` ord 'a')
 210   | otherwise      =  c
 211
 212 #endif
 213