System/IO.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  System.IO
   5 -- Copyright   :  (c) The University of Glasgow 2001
   6 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   7 --
   8 -- Maintainer  :  libraries@haskell.org
   9 -- Stability   :  stable
  10 -- Portability :  portable
  11 --
  12 -- The standard IO library.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module System.IO (
  17     -- * The IO monad
  18
  19     IO,                        -- instance MonadFix
  20     fixIO,                     -- :: (a -> IO a) -> IO a
  21
  22     -- * Files and handles
  23
  24     FilePath,                  -- :: String
  25
  26     Handle,             -- abstract, instance of: Eq, Show.
  27
  28     -- ** Standard handles
  29
  30     -- | Three handles are allocated during program initialisation,
  31     -- and are initially open.
  32
  33     stdin, stdout, stderr,   -- :: Handle
  34
  35     -- * Opening and closing files
  36
  37     -- ** Opening files
  38
  39     withFile,
  40     openFile,                  -- :: FilePath -> IOMode -> IO Handle
  41     IOMode(ReadMode,WriteMode,AppendMode,ReadWriteMode),
  42
  43     -- ** Closing files
  44
  45     hClose,                    -- :: Handle -> IO ()
  46
  47     -- ** Special cases
  48
  49     -- | These functions are also exported by the "Prelude".
  50
  51     readFile,                  -- :: FilePath -> IO String
  52     writeFile,                 -- :: FilePath -> String -> IO ()
  53     appendFile,                -- :: FilePath -> String -> IO ()
  54
  55     -- ** File locking
  56
  57     -- $locking
  58
  59     -- * Operations on handles
  60
  61     -- ** Determining and changing the size of a file
  62
  63     hFileSize,                 -- :: Handle -> IO Integer
  64 #ifdef __GLASGOW_HASKELL__
  65     hSetFileSize,              -- :: Handle -> Integer -> IO ()
  66 #endif
  67
  68     -- ** Detecting the end of input
  69
  70     hIsEOF,                    -- :: Handle -> IO Bool
  71     isEOF,                     -- :: IO Bool
  72
  73     -- ** Buffering operations
  74
  75     BufferMode(NoBuffering,LineBuffering,BlockBuffering),
  76     hSetBuffering,             -- :: Handle -> BufferMode -> IO ()
  77     hGetBuffering,             -- :: Handle -> IO BufferMode
  78     hFlush,                    -- :: Handle -> IO ()
  79
  80     -- ** Repositioning handles
  81
  82     hGetPosn,                  -- :: Handle -> IO HandlePosn
  83     hSetPosn,                  -- :: HandlePosn -> IO ()
  84     HandlePosn,                -- abstract, instance of: Eq, Show.
  85
  86     hSeek,                     -- :: Handle -> SeekMode -> Integer -> IO ()
  87     SeekMode(AbsoluteSeek,RelativeSeek,SeekFromEnd),
  88 #if !defined(__NHC__)
  89     hTell,                     -- :: Handle -> IO Integer
  90 #endif
  91
  92     -- ** Handle properties
  93
  94     hIsOpen, hIsClosed,        -- :: Handle -> IO Bool
  95     hIsReadable, hIsWritable,  -- :: Handle -> IO Bool
  96     hIsSeekable,               -- :: Handle -> IO Bool
  97
  98     -- ** Terminal operations (not portable: GHC\/Hugs only)
  99
 100 #if !defined(__NHC__)
 101     hIsTerminalDevice,          -- :: Handle -> IO Bool
 102
 103     hSetEcho,                   -- :: Handle -> Bool -> IO ()
 104     hGetEcho,                   -- :: Handle -> IO Bool
 105 #endif
 106
 107     -- ** Showing handle state (not portable: GHC only)
 108
 109 #ifdef __GLASGOW_HASKELL__
 110     hShow,                      -- :: Handle -> IO String
 111 #endif
 112
 113     -- * Text input and output
 114
 115     -- ** Text input
 116
 117     hWaitForInput,             -- :: Handle -> Int -> IO Bool
 118     hReady,                    -- :: Handle -> IO Bool
 119     hGetChar,                  -- :: Handle -> IO Char
 120     hGetLine,                  -- :: Handle -> IO [Char]
 121     hLookAhead,                -- :: Handle -> IO Char
 122     hGetContents,              -- :: Handle -> IO [Char]
 123
 124     -- ** Text output
 125
 126     hPutChar,                  -- :: Handle -> Char -> IO ()
 127     hPutStr,                   -- :: Handle -> [Char] -> IO ()
 128     hPutStrLn,                 -- :: Handle -> [Char] -> IO ()
 129     hPrint,                    -- :: Show a => Handle -> a -> IO ()
 130
 131     -- ** Special cases for standard input and output
 132
 133     -- | These functions are also exported by the "Prelude".
 134
 135     interact,                  -- :: (String -> String) -> IO ()
 136     putChar,                   -- :: Char   -> IO ()
 137     putStr,                    -- :: String -> IO ()
 138     putStrLn,                  -- :: String -> IO ()
 139     print,                     -- :: Show a => a -> IO ()
 140     getChar,                   -- :: IO Char
 141     getLine,                   -- :: IO String
 142     getContents,               -- :: IO String
 143     readIO,                    -- :: Read a => String -> IO a
 144     readLn,                    -- :: Read a => IO a
 145
 146     -- * Binary input and output
 147
 148     withBinaryFile,
 149     openBinaryFile,            -- :: FilePath -> IOMode -> IO Handle
 150     hSetBinaryMode,            -- :: Handle -> Bool -> IO ()
 151     hPutBuf,                   -- :: Handle -> Ptr a -> Int -> IO ()
 152     hGetBuf,                   -- :: Handle -> Ptr a -> Int -> IO Int
 153 #if !defined(__NHC__) && !defined(__HUGS__)
 154     hPutBufNonBlocking,        -- :: Handle -> Ptr a -> Int -> IO Int
 155     hGetBufNonBlocking,        -- :: Handle -> Ptr a -> Int -> IO Int
 156 #endif
 157
 158     -- * Temporary files
 159
 160     openTempFile,
 161     openBinaryTempFile,
 162   ) where
 163
 164 import Control.Exception.Base
 165
 166 #ifndef __NHC__
 167 import Data.Bits
 168 import Data.List
 169 import Data.Maybe
 170 import Foreign.C.Error
 171 import Foreign.C.Types
 172 import System.Posix.Internals
 173 #endif
 174
 175 #ifdef __GLASGOW_HASKELL__
 176 import GHC.Base
 177 import GHC.IO hiding ( onException )
 178 import GHC.IO.IOMode
 179 import GHC.IO.Handle.FD
 180 import GHC.IO.Handle
 181 import GHC.IORef
 182 import GHC.IO.Exception ( userError )
 183 -- import GHC.Exception
 184 import GHC.Num
 185 import Text.Read
 186 import GHC.Show
 187 #endif
 188
 189 #ifdef __HUGS__
 190 import Hugs.IO
 191 import Hugs.IOExts
 192 import Hugs.IORef
 193 import System.IO.Unsafe ( unsafeInterleaveIO )
 194 #endif
 195
 196 #ifdef __NHC__
 197 import IO
 198   ( Handle ()
 199   , HandlePosn ()
 200   , IOMode (ReadMode,WriteMode,AppendMode,ReadWriteMode)
 201   , BufferMode (NoBuffering,LineBuffering,BlockBuffering)
 202   , SeekMode (AbsoluteSeek,RelativeSeek,SeekFromEnd)
 203   , stdin, stdout, stderr
 204   , openFile                  -- :: FilePath -> IOMode -> IO Handle
 205   , hClose                    -- :: Handle -> IO ()
 206   , hFileSize                 -- :: Handle -> IO Integer
 207   , hIsEOF                    -- :: Handle -> IO Bool
 208   , isEOF                     -- :: IO Bool
 209   , hSetBuffering             -- :: Handle -> BufferMode -> IO ()
 210   , hGetBuffering             -- :: Handle -> IO BufferMode
 211   , hFlush                    -- :: Handle -> IO ()
 212   , hGetPosn                  -- :: Handle -> IO HandlePosn
 213   , hSetPosn                  -- :: HandlePosn -> IO ()
 214   , hSeek                     -- :: Handle -> SeekMode -> Integer -> IO ()
 215   , hWaitForInput             -- :: Handle -> Int -> IO Bool
 216   , hGetChar                  -- :: Handle -> IO Char
 217   , hGetLine                  -- :: Handle -> IO [Char]
 218   , hLookAhead                -- :: Handle -> IO Char
 219   , hGetContents              -- :: Handle -> IO [Char]
 220   , hPutChar                  -- :: Handle -> Char -> IO ()
 221   , hPutStr                   -- :: Handle -> [Char] -> IO ()
 222   , hPutStrLn                 -- :: Handle -> [Char] -> IO ()
 223   , hPrint                    -- :: Handle -> [Char] -> IO ()
 224   , hReady                    -- :: Handle -> [Char] -> IO ()
 225   , hIsOpen, hIsClosed        -- :: Handle -> IO Bool
 226   , hIsReadable, hIsWritable  -- :: Handle -> IO Bool
 227   , hIsSeekable               -- :: Handle -> IO Bool
 228   , bracket
 229
 230   , IO ()
 231   , FilePath                  -- :: String
 232   )
 233 import NHC.IOExtras (fixIO, hPutBuf, hGetBuf)
 234 import NHC.FFI (Ptr)
 235 #endif
 236
 237 -- -----------------------------------------------------------------------------
 238 -- Standard IO
 239
 240 #ifdef __GLASGOW_HASKELL__
 241 -- | Write a character to the standard output device
 242 -- (same as 'hPutChar' 'stdout').
 243
 244 putChar         :: Char -> IO ()
 245 putChar c       =  hPutChar stdout c
 246
 247 -- | Write a string to the standard output device
 248 -- (same as 'hPutStr' 'stdout').
 249
 250 putStr          :: String -> IO ()
 251 putStr s        =  hPutStr stdout s
 252
 253 -- | The same as 'putStr', but adds a newline character.
 254
 255 putStrLn        :: String -> IO ()
 256 putStrLn s      =  do putStr s
 257                       putChar '\n'
 258
 259 -- | The 'print' function outputs a value of any printable type to the
 260 -- standard output device.
 261 -- Printable types are those that are instances of class 'Show'; 'print'
 262 -- converts values to strings for output using the 'show' operation and
 263 -- adds a newline.
 264 --
 265 -- For example, a program to print the first 20 integers and their
 266 -- powers of 2 could be written as:
 267 --
 268 -- > main = print ([(n, 2^n) | n <- [0..19]])
 269
 270 print           :: Show a => a -> IO ()
 271 print x         =  putStrLn (show x)
 272
 273 -- | Read a character from the standard input device
 274 -- (same as 'hGetChar' 'stdin').
 275
 276 getChar         :: IO Char
 277 getChar         =  hGetChar stdin
 278
 279 -- | Read a line from the standard input device
 280 -- (same as 'hGetLine' 'stdin').
 281
 282 getLine         :: IO String
 283 getLine         =  hGetLine stdin
 284
 285 -- | The 'getContents' operation returns all user input as a single string,
 286 -- which is read lazily as it is needed
 287 -- (same as 'hGetContents' 'stdin').
 288
 289 getContents     :: IO String
 290 getContents     =  hGetContents stdin
 291
 292 -- | The 'interact' function takes a function of type @String->String@
 293 -- as its argument.  The entire input from the standard input device is
 294 -- passed to this function as its argument, and the resulting string is
 295 -- output on the standard output device.
 296
 297 interact        ::  (String -> String) -> IO ()
 298 interact f      =   do s <- getContents
 299                        putStr (f s)
 300
 301 -- | The 'readFile' function reads a file and
 302 -- returns the contents of the file as a string.
 303 -- The file is read lazily, on demand, as with 'getContents'.
 304
 305 readFile        :: FilePath -> IO String
 306 readFile name   =  openFile name ReadMode >>= hGetContents
 307
 308 -- | The computation 'writeFile' @file str@ function writes the string @str@,
 309 -- to the file @file@.
 310 writeFile :: FilePath -> String -> IO ()
 311 writeFile f txt = withFile f WriteMode (\ hdl -> hPutStr hdl txt)
 312
 313 -- | The computation 'appendFile' @file str@ function appends the string @str@,
 314 -- to the file @file@.
 315 --
 316 -- Note that 'writeFile' and 'appendFile' write a literal string
 317 -- to a file.  To write a value of any printable type, as with 'print',
 318 -- use the 'show' function to convert the value to a string first.
 319 --
 320 -- > main = appendFile "squares" (show [(x,x*x) | x <- [0,0.1..2]])
 321
 322 appendFile      :: FilePath -> String -> IO ()
 323 appendFile f txt = withFile f AppendMode (\ hdl -> hPutStr hdl txt)
 324
 325 -- | The 'readLn' function combines 'getLine' and 'readIO'.
 326
 327 readLn          :: Read a => IO a
 328 readLn          =  do l <- getLine
 329                       r <- readIO l
 330                       return r
 331
 332 -- | The 'readIO' function is similar to 'read' except that it signals
 333 -- parse failure to the 'IO' monad instead of terminating the program.
 334
 335 readIO          :: Read a => String -> IO a
 336 readIO s        =  case (do { (x,t) <- reads s ;
 337                               ("","") <- lex t ;
 338                               return x }) of
 339                         [x]    -> return x
 340                         []     -> ioError (userError "Prelude.readIO: no parse")
 341                         _      -> ioError (userError "Prelude.readIO: ambiguous parse")
 342 #endif  /* __GLASGOW_HASKELL__ */
 343
 344 #ifndef __NHC__
 345 -- | Computation 'hReady' @hdl@ indicates whether at least one item is
 346 -- available for input from handle @hdl@.
 347 --
 348 -- This operation may fail with:
 349 --
 350 --  * 'System.IO.Error.isEOFError' if the end of file has been reached.
 351
 352 hReady          :: Handle -> IO Bool
 353 hReady h        =  hWaitForInput h 0
 354
 355 -- | The same as 'hPutStr', but adds a newline character.
 356
 357 hPutStrLn       :: Handle -> String -> IO ()
 358 hPutStrLn hndl str = do
 359  hPutStr  hndl str
 360  hPutChar hndl '\n'
 361
 362 -- | Computation 'hPrint' @hdl t@ writes the string representation of @t@
 363 -- given by the 'shows' function to the file or channel managed by @hdl@
 364 -- and appends a newline.
 365 --
 366 -- This operation may fail with:
 367 --
 368 --  * 'System.IO.Error.isFullError' if the device is full; or
 369 --
 370 --  * 'System.IO.Error.isPermissionError' if another system resource limit would be exceeded.
 371
 372 hPrint          :: Show a => Handle -> a -> IO ()
 373 hPrint hdl      =  hPutStrLn hdl . show
 374 #endif /* !__NHC__ */
 375
 376 -- | @'withFile' name mode act@ opens a file using 'openFile' and passes
 377 -- the resulting handle to the computation @act@.  The handle will be
 378 -- closed on exit from 'withFile', whether by normal termination or by
 379 -- raising an exception.
 380 withFile :: FilePath -> IOMode -> (Handle -> IO r) -> IO r
 381 withFile name mode = bracket (openFile name mode) hClose
 382
 383 -- | @'withBinaryFile' name mode act@ opens a file using 'openBinaryFile'
 384 -- and passes the resulting handle to the computation @act@.  The handle
 385 -- will be closed on exit from 'withBinaryFile', whether by normal
 386 -- termination or by raising an exception.
 387 withBinaryFile :: FilePath -> IOMode -> (Handle -> IO r) -> IO r
 388 withBinaryFile name mode = bracket (openBinaryFile name mode) hClose
 389
 390 -- ---------------------------------------------------------------------------
 391 -- fixIO
 392
 393 #if defined(__GLASGOW_HASKELL__) || defined(__HUGS__)
 394 fixIO :: (a -> IO a) -> IO a
 395 fixIO k = do
 396     ref <- newIORef (throw NonTermination)
 397     ans <- unsafeInterleaveIO (readIORef ref)
 398     result <- k ans
 399     writeIORef ref result
 400     return result
 401
 402 -- NOTE: we do our own explicit black holing here, because GHC's lazy
 403 -- blackholing isn't enough.  In an infinite loop, GHC may run the IO
 404 -- computation a few times before it notices the loop, which is wrong.
 405 #endif
 406
 407 #if defined(__NHC__)
 408 -- Assume a unix platform, where text and binary I/O are identical.
 409 openBinaryFile = openFile
 410 hSetBinaryMode _ _ = return ()
 411 #endif
 412
 413 -- | The function creates a temporary file in ReadWrite mode.
 414 -- The created file isn\'t deleted automatically, so you need to delete it manually.
 415 --
 416 -- The file is creates with permissions such that only the current
 417 -- user can read\/write it.
 418 --
 419 -- With some exceptions (see below), the file will be created securely
 420 -- in the sense that an attacker should not be able to cause
 421 -- openTempFile to overwrite another file on the filesystem using your
 422 -- credentials, by putting symbolic links (on Unix) in the place where
 423 -- the temporary file is to be created.  On Unix the @O_CREAT@ and
 424 -- @O_EXCL@ flags are used to prevent this attack, but note that
 425 -- @O_EXCL@ is sometimes not supported on NFS filesystems, so if you
 426 -- rely on this behaviour it is best to use local filesystems only.
 427 --
 428 openTempFile :: FilePath   -- ^ Directory in which to create the file
 429              -> String     -- ^ File name template. If the template is \"foo.ext\" then
 430                            -- the created file will be \"fooXXX.ext\" where XXX is some
 431                            -- random number.
 432              -> IO (FilePath, Handle)
 433 openTempFile tmp_dir template = openTempFile' "openTempFile" tmp_dir template False
 434
 435 -- | Like 'openTempFile', but opens the file in binary mode. See 'openBinaryFile' for more comments.
 436 openBinaryTempFile :: FilePath -> String -> IO (FilePath, Handle)
 437 openBinaryTempFile tmp_dir template = openTempFile' "openBinaryTempFile" tmp_dir template True
 438
 439 openTempFile' :: String -> FilePath -> String -> Bool -> IO (FilePath, Handle)
 440 openTempFile' loc tmp_dir template binary = do
 441   pid <- c_getpid
 442   findTempName pid
 443   where
 444     -- We split off the last extension, so we can use .foo.ext files
 445     -- for temporary files (hidden on Unix OSes). Unfortunately we're
 446     -- below filepath in the hierarchy here.
 447     (prefix,suffix) =
 448        case break (== '.') $ reverse template of
 449          -- First case: template contains no '.'s. Just re-reverse it.
 450          (rev_suffix, "")       -> (reverse rev_suffix, "")
 451          -- Second case: template contains at least one '.'. Strip the
 452          -- dot from the prefix and prepend it to the suffix (if we don't
 453          -- do this, the unique number will get added after the '.' and
 454          -- thus be part of the extension, which is wrong.)
 455          (rev_suffix, '.':rest) -> (reverse rest, '.':reverse rev_suffix)
 456          -- Otherwise, something is wrong, because (break (== '.')) should
 457          -- always return a pair with either the empty string or a string
 458          -- beginning with '.' as the second component.
 459          _                      -> error "bug in System.IO.openTempFile"
 460
 461 #ifndef __NHC__
 462     oflags1 = rw_flags .|. o_EXCL
 463
 464     binary_flags
 465       | binary    = o_BINARY
 466       | otherwise = 0
 467
 468     oflags = oflags1 .|. binary_flags
 469 #endif
 470
 471 #ifdef __NHC__
 472     findTempName x = do h <- openFile filepath ReadWriteMode
 473                         return (filepath, h)
 474 #else
 475     findTempName x = do
 476       fd <- withFilePath filepath $ \ f ->
 477               c_open f oflags 0o600
 478       if fd < 0
 479        then do
 480          errno <- getErrno
 481          if errno == eEXIST
 482            then findTempName (x+1)
 483            else ioError (errnoToIOError loc errno Nothing (Just tmp_dir))
 484        else do
 485          -- XXX We want to tell fdToHandle what the filepath is,
 486          -- as any exceptions etc will only be able to report the
 487          -- fd currently
 488          h <- fdToHandle fd `onException` c_close fd
 489          return (filepath, h)
 490 #endif
 491       where
 492         filename        = prefix ++ show x ++ suffix
 493         filepath        = tmp_dir `combine` filename
 494
 495         -- XXX bits copied from System.FilePath, since that's not available here
 496         combine a b
 497                   | null b = a
 498                   | null a = b
 499                   | last a == pathSeparator = a ++ b
 500                   | otherwise = a ++ [pathSeparator] ++ b
 501
 502 #if __HUGS__
 503         fdToHandle fd   = openFd (fromIntegral fd) False ReadWriteMode binary
 504 #endif
 505
 506 -- XXX Should use filepath library
 507 pathSeparator :: Char
 508 #ifdef mingw32_HOST_OS
 509 pathSeparator = '\\'
 510 #else
 511 pathSeparator = '/'
 512 #endif
 513
 514 #ifndef __NHC__
 515 -- XXX Copied from GHC.Handle
 516 std_flags, output_flags, rw_flags :: CInt
 517 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 518 output_flags = std_flags    .|. o_CREAT
 519 rw_flags     = output_flags .|. o_RDWR
 520 #endif
 521
 522 #ifdef __NHC__
 523 foreign import ccall "getpid" c_getpid :: IO Int
 524 #endif
 525
 526 -- $locking
 527 -- Implementations should enforce as far as possible, at least locally to the
 528 -- Haskell process, multiple-reader single-writer locking on files.
 529 -- That is, /there may either be many handles on the same file which manage
 530 -- input, or just one handle on the file which manages output/.  If any
 531 -- open or semi-closed handle is managing a file for output, no new
 532 -- handle can be allocated for that file.  If any open or semi-closed
 533 -- handle is managing a file for input, new handles can only be allocated
 534 -- if they do not manage output.  Whether two files are the same is
 535 -- implementation-dependent, but they should normally be the same if they
 536 -- have the same absolute path name and neither has been renamed, for
 537 -- example.
 538 --
 539 -- /Warning/: the 'readFile' operation holds a semi-closed handle on
 540 -- the file until the entire contents of the file have been consumed.
 541 -- It follows that an attempt to write to a file (using 'writeFile', for
 542 -- example) that was earlier opened by 'readFile' will usually result in
 543 -- failure with 'System.IO.Error.isAlreadyInUseError'.