System/Time.hsc

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  System.Time
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/core/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  provisional
   9 -- Portability :  portable
  10 --
  11 -- $Id: Time.hsc,v 1.12 2002/04/24 16:31:45 simonmar Exp $
  12 --
  13 -- The standard Time library.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 {-
  18 Haskell 98 Time of Day Library
  19 ------------------------------
  20
  21 The Time library provides standard functionality for clock times,
  22 including timezone information (i.e, the functionality of "time.h",
  23 adapted to the Haskell environment), It follows RFC 1129 in its use of
  24 Coordinated Universal Time (UTC).
  25
  26 2000/06/17 <michael.weber@post.rwth-aachen.de>:
  27 RESTRICTIONS:
  28   * min./max. time diff currently is restricted to
  29     [minBound::Int, maxBound::Int]
  30
  31   * surely other restrictions wrt. min/max bounds
  32
  33
  34 NOTES:
  35   * printing times
  36
  37     `showTime' (used in `instance Show ClockTime') always prints time
  38     converted to the local timezone (even if it is taken from
  39     `(toClockTime . toUTCTime)'), whereas `calendarTimeToString'
  40     honors the tzone & tz fields and prints UTC or whatever timezone
  41     is stored inside CalendarTime.
  42
  43     Maybe `showTime' should be changed to use UTC, since it would
  44     better correspond to the actual representation of `ClockTime'
  45     (can be done by replacing localtime(3) by gmtime(3)).
  46
  47
  48 BUGS:
  49   * add proper handling of microsecs, currently, they're mostly
  50     ignored
  51
  52   * `formatFOO' case of `%s' is currently broken...
  53
  54
  55 TODO:
  56   * check for unusual date cases, like 1970/1/1 00:00h, and conversions
  57     between different timezone's etc.
  58
  59   * check, what needs to be in the IO monad, the current situation
  60     seems to be a bit inconsistent to me
  61
  62   * check whether `isDst = -1' works as expected on other arch's
  63     (Solaris anyone?)
  64
  65   * add functions to parse strings to `CalendarTime' (some day...)
  66
  67   * implement padding capabilities ("%_", "%-") in `formatFOO'
  68
  69   * add rfc822 timezone (+0200 is CEST) representation ("%z") in `formatFOO'
  70 -}
  71
  72 module System.Time
  73      (
  74         Month(..)
  75      ,  Day(..)
  76
  77      ,  ClockTime(..) -- non-standard, lib. report gives this as abstract
  78         -- instance Eq, Ord
  79         -- instance Show (non-standard)
  80
  81      ,  getClockTime
  82
  83      ,  TimeDiff(..)
  84      ,  noTimeDiff      -- non-standard (but useful when constructing TimeDiff vals.)
  85      ,  diffClockTimes
  86      ,  addToClockTime
  87
  88      ,  normalizeTimeDiff -- non-standard
  89      ,  timeDiffToString  -- non-standard
  90      ,  formatTimeDiff    -- non-standard
  91
  92      ,  CalendarTime(..)
  93      ,  toCalendarTime
  94      ,  toUTCTime
  95      ,  toClockTime
  96      ,  calendarTimeToString
  97      ,  formatCalendarTime
  98
  99      ) where
 100
 101 #include "HsBase.h"
 102
 103 import Prelude
 104
 105 import Data.Ix
 106 import System.Locale
 107 import System.IO.Unsafe
 108
 109 import Foreign
 110 import Foreign.C
 111
 112 -- One way to partition and give name to chunks of a year and a week:
 113
 114 data Month
 115  = January   | February | March    | April
 116  | May       | June     | July     | August
 117  | September | October  | November | December
 118  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 119
 120 data Day
 121  = Sunday   | Monday | Tuesday | Wednesday
 122  | Thursday | Friday | Saturday
 123  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 124
 125 -- @ClockTime@ is an abstract type, used for the internal clock time.
 126 -- Clock times may be compared, converted to strings, or converted to an
 127 -- external calendar time @CalendarTime@.
 128
 129 data ClockTime = TOD Integer            -- Seconds since 00:00:00 on 1 Jan 1970
 130                      Integer            -- Picoseconds with the specified second
 131                deriving (Eq, Ord)
 132
 133 -- When a ClockTime is shown, it is converted to a CalendarTime in the current
 134 -- timezone and then printed.  FIXME: This is arguably wrong, since we can't
 135 -- get the current timezone without being in the IO monad.
 136
 137 instance Show ClockTime where
 138     showsPrec _ t = showString (calendarTimeToString
 139                                  (unsafePerformIO (toCalendarTime t)))
 140
 141 {-
 142 @CalendarTime@ is a user-readable and manipulable
 143 representation of the internal $ClockTime$ type.  The
 144 numeric fields have the following ranges.
 145
 146 \begin{verbatim}
 147 Value         Range             Comments
 148 -----         -----             --------
 149
 150 year    -maxInt .. maxInt       [Pre-Gregorian dates are inaccurate]
 151 mon           0 .. 11           [Jan = 0, Dec = 11]
 152 day           1 .. 31
 153 hour          0 .. 23
 154 min           0 .. 59
 155 sec           0 .. 61           [Allows for two leap seconds]
 156 picosec       0 .. (10^12)-1    [This could be over-precise?]
 157 wday          0 .. 6            [Sunday = 0, Saturday = 6]
 158 yday          0 .. 365          [364 in non-Leap years]
 159 tz       -43200 .. 43200        [Variation from UTC in seconds]
 160 \end{verbatim}
 161
 162 The {\em tzname} field is the name of the time zone.  The {\em isdst}
 163 field indicates whether Daylight Savings Time would be in effect.
 164 -}
 165
 166 data CalendarTime
 167  = CalendarTime  {
 168      ctYear    :: Int,
 169      ctMonth   :: Month,
 170      ctDay     :: Int,
 171      ctHour    :: Int,
 172      ctMin     :: Int,
 173      ctSec     :: Int,
 174      ctPicosec :: Integer,
 175      ctWDay    :: Day,
 176      ctYDay    :: Int,
 177      ctTZName  :: String,
 178      ctTZ      :: Int,
 179      ctIsDST   :: Bool
 180  }
 181  deriving (Eq,Ord,Read,Show)
 182
 183 -- The @TimeDiff@ type records the difference between two clock times in
 184 -- a user-readable way.
 185
 186 data TimeDiff
 187  = TimeDiff {
 188      tdYear    :: Int,
 189      tdMonth   :: Int,
 190      tdDay     :: Int,
 191      tdHour    :: Int,
 192      tdMin     :: Int,
 193      tdSec     :: Int,
 194      tdPicosec :: Integer -- not standard
 195    }
 196    deriving (Eq,Ord,Read,Show)
 197
 198 noTimeDiff :: TimeDiff
 199 noTimeDiff = TimeDiff 0 0 0 0 0 0 0
 200
 201 -- -----------------------------------------------------------------------------
 202 -- getClockTime returns the current time in its internal representation.
 203
 204 #if HAVE_GETTIMEOFDAY
 205 getClockTime = do
 206   allocaBytes (#const sizeof(struct timeval)) $ \ p_timeval -> do
 207     throwErrnoIfMinus1_ "getClockTime" $ gettimeofday p_timeval nullPtr
 208     sec  <- (#peek struct timeval,tv_sec)  p_timeval :: IO CTime
 209     usec <- (#peek struct timeval,tv_usec) p_timeval :: IO CTime
 210     return (TOD (fromIntegral sec) ((fromIntegral usec) * 1000000))
 211
 212 #elif HAVE_FTIME
 213 getClockTime = do
 214   allocaBytes (#const sizeof(struct timeb)) $ \ p_timeb -> do
 215   ftime p_timeb
 216   sec  <- (#peek struct timeb,time) p_timeb :: IO CTime
 217   msec <- (#peek struct timeb,millitm) p_timeb :: IO CUShort
 218   return (TOD (fromIntegral sec) (fromIntegral msec * 1000000000))
 219
 220 #else /* use POSIX time() */
 221 getClockTime = do
 222     secs <- time nullPtr -- can't fail, according to POSIX
 223     return (TOD (fromIntegral secs) 0)
 224
 225 #endif
 226
 227 -- -----------------------------------------------------------------------------
 228 -- addToClockTime d t adds a time difference d and a
 229 -- clock time t to yield a new clock time.  The difference d
 230 -- may be either positive or negative.  diffClockTimes t1 t2 returns
 231 -- the difference between two clock times t1 and t2 as a TimeDiff.
 232
 233 addToClockTime  :: TimeDiff  -> ClockTime -> ClockTime
 234 addToClockTime (TimeDiff year mon day hour min sec psec)
 235                (TOD c_sec c_psec) =
 236         let
 237           sec_diff = toInteger sec +
 238                      60 * toInteger min +
 239                      3600 * toInteger hour +
 240                      24 * 3600 * toInteger day
 241           cal      = toUTCTime (TOD (c_sec + sec_diff) (c_psec + psec))
 242                                                        -- FIXME! ^^^^
 243           new_mon  = fromEnum (ctMonth cal) + r_mon
 244           (month', yr_diff)
 245             | new_mon < 0  = (toEnum (12 + new_mon), (-1))
 246             | new_mon > 11 = (toEnum (new_mon `mod` 12), 1)
 247             | otherwise    = (toEnum new_mon, 0)
 248
 249           (r_yr, r_mon) = mon `quotRem` 12
 250
 251           year' = ctYear cal + year + r_yr + yr_diff
 252         in
 253         toClockTime cal{ctMonth=month', ctYear=year'}
 254
 255 diffClockTimes  :: ClockTime -> ClockTime -> TimeDiff
 256 -- diffClockTimes is meant to be the dual to `addToClockTime'.
 257 -- If you want to have the TimeDiff properly splitted, use
 258 -- `normalizeTimeDiff' on this function's result
 259 --
 260 -- CAVEAT: see comment of normalizeTimeDiff
 261 diffClockTimes (TOD sa pa) (TOD sb pb) =
 262     noTimeDiff{ tdSec     = fromIntegral (sa - sb)
 263                 -- FIXME: can handle just 68 years...
 264               , tdPicosec = pa - pb
 265               }
 266
 267
 268 normalizeTimeDiff :: TimeDiff -> TimeDiff
 269 -- FIXME: handle psecs properly
 270 -- FIXME: ?should be called by formatTimeDiff automagically?
 271 --
 272 -- when applied to something coming out of `diffClockTimes', you loose
 273 -- the duality to `addToClockTime', since a year does not always have
 274 -- 365 days, etc.
 275 --
 276 -- apply this function as late as possible to prevent those "rounding"
 277 -- errors
 278 normalizeTimeDiff td =
 279   let
 280       rest0 = tdSec td
 281                + 60 * (tdMin td
 282                     + 60 * (tdHour td
 283                          + 24 * (tdDay td
 284                               + 30 * (tdMonth td
 285                                    + 365 * tdYear td))))
 286
 287       (diffYears,  rest1)    = rest0 `quotRem` (365 * 24 * 3600)
 288       (diffMonths, rest2)    = rest1 `quotRem` (30 * 24 * 3600)
 289       (diffDays,   rest3)    = rest2 `quotRem` (24 * 3600)
 290       (diffHours,  rest4)    = rest3 `quotRem` 3600
 291       (diffMins,   diffSecs) = rest4 `quotRem` 60
 292   in
 293       td{ tdYear = diffYears
 294         , tdMonth = diffMonths
 295         , tdDay   = diffDays
 296         , tdHour  = diffHours
 297         , tdMin   = diffMins
 298         , tdSec   = diffSecs
 299         }
 300
 301 -- -----------------------------------------------------------------------------
 302 -- How do we deal with timezones on this architecture?
 303
 304 -- The POSIX way to do it is through the global variable tzname[].
 305 -- But that's crap, so we do it The BSD Way if we can: namely use the
 306 -- tm_zone and tm_gmtoff fields of struct tm, if they're available.
 307
 308 zone   :: Ptr CTm -> IO (Ptr CChar)
 309 gmtoff :: Ptr CTm -> IO CLong
 310 #if HAVE_TM_ZONE
 311 zone x      = (#peek struct tm,tm_zone) x
 312 gmtoff x    = (#peek struct tm,tm_gmtoff) x
 313
 314 #else /* ! HAVE_TM_ZONE */
 315 # if HAVE_TZNAME || defined(_WIN32)
 316 #  if cygwin32_TARGET_OS
 317 #   define tzname _tzname
 318 #  endif
 319 #  ifndef mingw32_TARGET_OS
 320 foreign import ccall unsafe "&tzname" tzname :: Ptr (Ptr CChar)
 321 foreign import ccall unsafe "timezone" timezone :: Ptr CLong
 322 #  else
 323 foreign import ccall unsafe "__hscore_timezone" timezone :: Ptr CLong
 324 foreign import ccall unsafe "__hscore_tzname"   tzname :: Ptr (Ptr CChar)
 325 #  endif
 326 zone x = do
 327   dst <- (#peek struct tm,tm_isdst) x
 328   if dst then peekElemOff tzname 1 else peekElemOff tzname 0
 329 # else /* ! HAVE_TZNAME */
 330 -- We're in trouble. If you should end up here, please report this as a bug.
 331 #  error "Don't know how to get at timezone name on your OS."
 332 # endif /* ! HAVE_TZNAME */
 333
 334 -- Get the offset in secs from UTC, if (struct tm) doesn't supply it. */
 335 #if defined(mingw32_TARGET_OS)
 336 #define timezone _timezone
 337 #endif
 338
 339 # if HAVE_ALTZONE
 340 foreign import ccall "&altzone"  :: Ptr CTime
 341 foreign import ccall "&timezone" :: Ptr CTime
 342 gmtoff x = do
 343   dst <- (#peek struct tm,tm_isdst) x
 344   tz <- if dst then peek altzone else peek timezone
 345   return (fromIntegral tz)
 346 #  define GMTOFF(x)      (((struct tm *)x)->tm_isdst ? altzone : timezone )
 347 # else /* ! HAVE_ALTZONE */
 348 -- Assume that DST offset is 1 hour ...
 349 gmtoff x = do
 350   dst <- (#peek struct tm,tm_isdst) x
 351   tz  <- peek timezone
 352   if dst then return (fromIntegral tz - 3600) else return tz
 353 # endif /* ! HAVE_ALTZONE */
 354 #endif  /* ! HAVE_TM_ZONE */
 355
 356 -- -----------------------------------------------------------------------------
 357 -- toCalendarTime t converts t to a local time, modified by
 358 -- the current timezone and daylight savings time settings.  toUTCTime
 359 -- t converts t into UTC time.  toClockTime l converts l into the
 360 -- corresponding internal ClockTime.  The wday, yday, tzname, and isdst fields
 361 -- are ignored.
 362
 363
 364 toCalendarTime :: ClockTime -> IO CalendarTime
 365 #if HAVE_LOCALTIME_R
 366 toCalendarTime =  clockToCalendarTime_reentrant (throwAwayReturnPointer localtime_r) False
 367 #else
 368 toCalendarTime =  clockToCalendarTime_static localtime False
 369 #endif
 370
 371 toUTCTime      :: ClockTime -> CalendarTime
 372 #if HAVE_GMTIME_R
 373 toUTCTime      =  unsafePerformIO . clockToCalendarTime_reentrant (throwAwayReturnPointer gmtime_r) True
 374 #else
 375 toUTCTime      =  unsafePerformIO . clockToCalendarTime_static gmtime True
 376 #endif
 377
 378 throwAwayReturnPointer :: (Ptr CTime -> Ptr CTm -> IO (Ptr CTm))
 379                        -> (Ptr CTime -> Ptr CTm -> IO (       ))
 380 throwAwayReturnPointer fun x y = fun x y >> return ()
 381
 382 clockToCalendarTime_static :: (Ptr CTime -> IO (Ptr CTm)) -> Bool -> ClockTime
 383          -> IO CalendarTime
 384 clockToCalendarTime_static fun is_utc (TOD secs psec) = do
 385   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 386     p_tm <- fun p_timer         -- can't fail, according to POSIX
 387     clockToCalendarTime_aux is_utc p_tm psec
 388
 389 clockToCalendarTime_reentrant :: (Ptr CTime -> Ptr CTm -> IO ()) -> Bool -> ClockTime
 390          -> IO CalendarTime
 391 clockToCalendarTime_reentrant fun is_utc (TOD secs psec) = do
 392   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 393     allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 394       fun p_timer p_tm
 395       clockToCalendarTime_aux is_utc p_tm psec
 396
 397 clockToCalendarTime_aux :: Bool -> Ptr CTm -> Integer -> IO CalendarTime
 398 clockToCalendarTime_aux is_utc p_tm psec = do
 399     sec   <-  (#peek struct tm,tm_sec  ) p_tm :: IO CInt
 400     min   <-  (#peek struct tm,tm_min  ) p_tm :: IO CInt
 401     hour  <-  (#peek struct tm,tm_hour ) p_tm :: IO CInt
 402     mday  <-  (#peek struct tm,tm_mday ) p_tm :: IO CInt
 403     mon   <-  (#peek struct tm,tm_mon  ) p_tm :: IO CInt
 404     year  <-  (#peek struct tm,tm_year ) p_tm :: IO CInt
 405     wday  <-  (#peek struct tm,tm_wday ) p_tm :: IO CInt
 406     yday  <-  (#peek struct tm,tm_yday ) p_tm :: IO CInt
 407     isdst <-  (#peek struct tm,tm_isdst) p_tm :: IO CInt
 408     zone  <-  zone p_tm
 409     tz    <-  gmtoff p_tm
 410
 411     tzname <- peekCString zone
 412
 413     let month  | mon >= 0 && mon <= 11 = toEnum (fromIntegral mon)
 414                | otherwise             = error ("toCalendarTime: illegal month value: " ++ show mon)
 415
 416     return (CalendarTime
 417                 (1900 + fromIntegral year)
 418                 month
 419                 (fromIntegral mday)
 420                 (fromIntegral hour)
 421                 (fromIntegral min)
 422                 (fromIntegral sec)
 423                 psec
 424                 (toEnum (fromIntegral wday))
 425                 (fromIntegral yday)
 426                 (if is_utc then "UTC" else tzname)
 427                 (if is_utc then 0     else fromIntegral tz)
 428                 (if is_utc then False else isdst /= 0))
 429
 430
 431 toClockTime :: CalendarTime -> ClockTime
 432 toClockTime (CalendarTime year mon mday hour min sec psec
 433                           _wday _yday _tzname tz isdst) =
 434
 435      -- `isDst' causes the date to be wrong by one hour...
 436      -- FIXME: check, whether this works on other arch's than Linux, too...
 437      --
 438      -- so we set it to (-1) (means `unknown') and let `mktime' determine
 439      -- the real value...
 440     let isDst = -1 :: CInt in   -- if isdst then (1::Int) else 0
 441
 442     if psec < 0 || psec > 999999999999 then
 443         error "Time.toClockTime: picoseconds out of range"
 444     else if tz < -43200 || tz > 43200 then
 445         error "Time.toClockTime: timezone offset out of range"
 446     else
 447       unsafePerformIO $ do
 448       allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 449         (#poke struct tm,tm_sec  ) p_tm (fromIntegral sec  :: CInt)
 450         (#poke struct tm,tm_min  ) p_tm (fromIntegral min  :: CInt)
 451         (#poke struct tm,tm_hour ) p_tm (fromIntegral hour :: CInt)
 452         (#poke struct tm,tm_mday ) p_tm (fromIntegral mday :: CInt)
 453         (#poke struct tm,tm_mon  ) p_tm (fromIntegral (fromEnum mon) :: CInt)
 454         (#poke struct tm,tm_year ) p_tm (fromIntegral year - 1900 :: CInt)
 455         (#poke struct tm,tm_isdst) p_tm isDst
 456         t <- throwIf (== -1) (\_ -> "Time.toClockTime: invalid input")
 457                 (mktime p_tm)
 458         --
 459         -- mktime expects its argument to be in the local timezone, but
 460         -- toUTCTime makes UTC-encoded CalendarTime's ...
 461         --
 462         -- Since there is no any_tz_struct_tm-to-time_t conversion
 463         -- function, we have to fake one... :-) If not in all, it works in
 464         -- most cases (before, it was the other way round...)
 465         --
 466         -- Luckily, mktime tells us, what it *thinks* the timezone is, so,
 467         -- to compensate, we add the timezone difference to mktime's
 468         -- result.
 469         --
 470         gmtoff <- gmtoff p_tm
 471         let res = fromIntegral t - tz + fromIntegral gmtoff
 472         return (TOD (fromIntegral res) psec)
 473
 474 -- -----------------------------------------------------------------------------
 475 -- Converting time values to strings.
 476
 477 calendarTimeToString  :: CalendarTime -> String
 478 calendarTimeToString  =  formatCalendarTime defaultTimeLocale "%c"
 479
 480 formatCalendarTime :: TimeLocale -> String -> CalendarTime -> String
 481 formatCalendarTime l fmt (CalendarTime year mon day hour min sec _
 482                                        wday yday tzname _ _) =
 483         doFmt fmt
 484   where doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 485         doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 486         doFmt ('%':c:cs)   = decode c ++ doFmt cs
 487         doFmt (c:cs) = c : doFmt cs
 488         doFmt "" = ""
 489
 490         decode 'A' = fst (wDays l  !! fromEnum wday) -- day of the week, full name
 491         decode 'a' = snd (wDays l  !! fromEnum wday) -- day of the week, abbrev.
 492         decode 'B' = fst (months l !! fromEnum mon)  -- month, full name
 493         decode 'b' = snd (months l !! fromEnum mon)  -- month, abbrev
 494         decode 'h' = snd (months l !! fromEnum mon)  -- ditto
 495         decode 'C' = show2 (year `quot` 100)         -- century
 496         decode 'c' = doFmt (dateTimeFmt l)           -- locale's data and time format.
 497         decode 'D' = doFmt "%m/%d/%y"
 498         decode 'd' = show2 day                       -- day of the month
 499         decode 'e' = show2' day                      -- ditto, padded
 500         decode 'H' = show2 hour                      -- hours, 24-hour clock, padded
 501         decode 'I' = show2 (to12 hour)               -- hours, 12-hour clock
 502         decode 'j' = show3 yday                      -- day of the year
 503         decode 'k' = show2' hour                     -- hours, 24-hour clock, no padding
 504         decode 'l' = show2' (to12 hour)              -- hours, 12-hour clock, no padding
 505         decode 'M' = show2 min                       -- minutes
 506         decode 'm' = show2 (fromEnum mon+1)          -- numeric month
 507         decode 'n' = "\n"
 508         decode 'p' = (if hour < 12 then fst else snd) (amPm l) -- am or pm
 509         decode 'R' = doFmt "%H:%M"
 510         decode 'r' = doFmt (time12Fmt l)
 511         decode 'T' = doFmt "%H:%M:%S"
 512         decode 't' = "\t"
 513         decode 'S' = show2 sec                       -- seconds
 514         decode 's' = show2 sec                       -- number of secs since Epoch. (ToDo.)
 515         decode 'U' = show2 ((yday + 7 - fromEnum wday) `div` 7) -- week number, starting on Sunday.
 516         decode 'u' = show (let n = fromEnum wday in  -- numeric day of the week (1=Monday, 7=Sunday)
 517                            if n == 0 then 7 else n)
 518         decode 'V' =                                 -- week number (as per ISO-8601.)
 519             let (week, days) =                       -- [yep, I've always wanted to be able to display that too.]
 520                    (yday + 7 - if fromEnum wday > 0 then
 521                                fromEnum wday - 1 else 6) `divMod` 7
 522             in  show2 (if days >= 4 then
 523                           week+1
 524                        else if week == 0 then 53 else week)
 525
 526         decode 'W' =                                 -- week number, weeks starting on monday
 527             show2 ((yday + 7 - if fromEnum wday > 0 then
 528                                fromEnum wday - 1 else 6) `div` 7)
 529         decode 'w' = show (fromEnum wday)            -- numeric day of the week, weeks starting on Sunday.
 530         decode 'X' = doFmt (timeFmt l)               -- locale's preferred way of printing time.
 531         decode 'x' = doFmt (dateFmt l)               -- locale's preferred way of printing dates.
 532         decode 'Y' = show year                       -- year, including century.
 533         decode 'y' = show2 (year `rem` 100)          -- year, within century.
 534         decode 'Z' = tzname                          -- timezone name
 535         decode '%' = "%"
 536         decode c   = [c]
 537
 538
 539 show2, show2', show3 :: Int -> String
 540 show2 x
 541  | x' < 10   = '0': show x'
 542  | otherwise = show x'
 543  where x' = x `rem` 100
 544
 545 show2' x
 546  | x' < 10   = ' ': show x'
 547  | otherwise = show x'
 548  where x' = x `rem` 100
 549
 550 show3 x = show (x `quot` 100) ++ show2 (x `rem` 100)
 551  where x' = x `rem` 1000
 552
 553 to12 :: Int -> Int
 554 to12 h = let h' = h `mod` 12 in if h' == 0 then 12 else h'
 555
 556 -- Useful extensions for formatting TimeDiffs.
 557
 558 timeDiffToString :: TimeDiff -> String
 559 timeDiffToString = formatTimeDiff defaultTimeLocale "%c"
 560
 561 formatTimeDiff :: TimeLocale -> String -> TimeDiff -> String
 562 formatTimeDiff l fmt td@(TimeDiff year month day hour min sec _)
 563  = doFmt fmt
 564   where
 565    doFmt ""         = ""
 566    doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 567    doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 568    doFmt ('%':c:cs) = decode c ++ doFmt cs
 569    doFmt (c:cs)     = c : doFmt cs
 570
 571    decode spec =
 572     case spec of
 573       'B' -> fst (months l !! fromEnum month)
 574       'b' -> snd (months l !! fromEnum month)
 575       'h' -> snd (months l !! fromEnum month)
 576       'c' -> defaultTimeDiffFmt td
 577       'C' -> show2 (year `quot` 100)
 578       'D' -> doFmt "%m/%d/%y"
 579       'd' -> show2 day
 580       'e' -> show2' day
 581       'H' -> show2 hour
 582       'I' -> show2 (to12 hour)
 583       'k' -> show2' hour
 584       'l' -> show2' (to12 hour)
 585       'M' -> show2 min
 586       'm' -> show2 (fromEnum month + 1)
 587       'n' -> "\n"
 588       'p' -> (if hour < 12 then fst else snd) (amPm l)
 589       'R' -> doFmt "%H:%M"
 590       'r' -> doFmt (time12Fmt l)
 591       'T' -> doFmt "%H:%M:%S"
 592       't' -> "\t"
 593       'S' -> show2 sec
 594       's' -> show2 sec -- Implementation-dependent, sez the lib doc..
 595       'X' -> doFmt (timeFmt l)
 596       'x' -> doFmt (dateFmt l)
 597       'Y' -> show year
 598       'y' -> show2 (year `rem` 100)
 599       '%' -> "%"
 600       c   -> [c]
 601
 602    defaultTimeDiffFmt (TimeDiff year month day hour min sec _) =
 603        foldr (\ (v,s) rest ->
 604                   (if v /= 0
 605                      then show v ++ ' ':(addS v s)
 606                        ++ if null rest then "" else ", "
 607                      else "") ++ rest
 608              )
 609              ""
 610              (zip [year, month, day, hour, min, sec] (intervals l))
 611
 612    addS v s = if abs v == 1 then fst s else snd s
 613
 614
 615 -- -----------------------------------------------------------------------------
 616 -- Foreign time interface (POSIX)
 617
 618 type CTm = () -- struct tm
 619
 620 #if HAVE_LOCALTIME_R
 621 foreign import ccall unsafe localtime_r :: Ptr CTime -> Ptr CTm -> IO (Ptr CTm)
 622 #else
 623 foreign import ccall unsafe localtime   :: Ptr CTime -> IO (Ptr CTm)
 624 #endif
 625 #if HAVE_GMTIME_R
 626 foreign import ccall unsafe gmtime_r    :: Ptr CTime -> Ptr CTm -> IO (Ptr CTm)
 627 #else
 628 foreign import ccall unsafe gmtime      :: Ptr CTime -> IO (Ptr CTm)
 629 #endif
 630 foreign import ccall unsafe mktime      :: Ptr CTm   -> IO CTime
 631 foreign import ccall unsafe time        :: Ptr CTime -> IO CTime
 632
 633 #if HAVE_GETTIMEOFDAY
 634 type CTimeVal = ()
 635 foreign import ccall unsafe gettimeofday :: Ptr CTimeVal -> Ptr () -> IO CInt
 636 #endif
 637
 638 #if HAVE_FTIME
 639 type CTimeB = ()
 640 #ifndef mingw32_TARGET_OS
 641 foreign import ccall unsafe ftime :: Ptr CTimeB -> IO CInt
 642 #else
 643 foreign import ccall unsafe ftime :: Ptr CTimeB -> IO ()
 644 #endif
 645 #endif