aclocal.m4

   1 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
   2 # --------------------------------------------------------
   3 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
   4 # compilation. Execute IF-FAILS when unable to determine the value. Works for
   5 # cross-compilation, too.
   6 #
   7 # Implementation note: We are lazy and use an internal autoconf macro, but it
   8 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
   9 # little risk.
  10 AC_DEFUN([FP_COMPUTE_INT],
  11 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  12 ])# FP_COMPUTE_INT
  13
  14
  15 # FP_CHECK_CONST(EXPRESSION, [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
  16 # -------------------------------------------------------------------------------
  17 # Defines CONST_EXPRESSION to the value of the compile-time EXPRESSION, using
  18 # INCLUDES. If the value cannot be determined, use VALUE-IF-FAIL.
  19 AC_DEFUN([FP_CHECK_CONST],
  20 [AS_VAR_PUSHDEF([fp_Cache], [fp_cv_const_$1])[]dnl
  21 AC_CACHE_CHECK([value of $1], fp_Cache,
  22 [FP_COMPUTE_INT([$1], fp_check_const_result, [AC_INCLUDES_DEFAULT([$2])],
  23                 [fp_check_const_result=m4_default([$3], ['-1'])])
  24 AS_VAR_SET(fp_Cache, [$fp_check_const_result])])[]dnl
  25 AC_DEFINE_UNQUOTED(AS_TR_CPP([CONST_$1]), AS_VAR_GET(fp_Cache), [The value of $1.])[]dnl
  26 AS_VAR_POPDEF([fp_Cache])[]dnl
  27 ])# FP_CHECK_CONST
  28
  29
  30 # FP_CHECK_CONSTS_TEMPLATE(EXPRESSION...)
  31 # ---------------------------------------
  32 # autoheader helper for FP_CHECK_CONSTS
  33 m4_define([FP_CHECK_CONSTS_TEMPLATE],
  34 [AC_FOREACH([fp_Const], [$1],
  35   [AH_TEMPLATE(AS_TR_CPP(CONST_[]fp_Const),
  36                [The value of ]fp_Const[.])])[]dnl
  37 ])# FP_CHECK_CONSTS_TEMPLATE
  38
  39
  40 # FP_CHECK_CONSTS(EXPRESSION..., [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
  41 # -----------------------------------------------------------------------------------
  42 # List version of FP_CHECK_CONST
  43 AC_DEFUN([FP_CHECK_CONSTS],
  44 [FP_CHECK_CONSTS_TEMPLATE([$1])dnl
  45 for fp_const_name in $1
  46 do
  47 FP_CHECK_CONST([$fp_const_name], [$2], [$3])
  48 done
  49 ])# FP_CHECK_CONSTS
  50
  51
  52 dnl ** Map an arithmetic C type to a Haskell type.
  53 dnl    Based on autconf's AC_CHECK_SIZEOF.
  54
  55 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
  56 AC_DEFUN([FPTOOLS_CHECK_HTYPE],
  57 [changequote(<<, >>)dnl
  58 dnl The name to #define.
  59 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
  60 dnl The cache variable name.
  61 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
  62 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
  63 changequote([, ])dnl
  64 AC_MSG_CHECKING(Haskell type for $1)
  65 AC_CACHE_VAL(AC_CV_NAME,
  66 [AC_CV_NAME_supported=yes
  67 fp_check_htype_save_cppflags="$CPPFLAGS"
  68 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  69 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
  70 #include <stddef.h>
  71
  72 #if HAVE_SYS_TYPES_H
  73 # include <sys/types.h>
  74 #endif
  75
  76 #if HAVE_UNISTD_H
  77 # include <unistd.h>
  78 #endif
  79
  80 #if HAVE_SYS_STAT_H
  81 # include <sys/stat.h>
  82 #endif
  83
  84 #if HAVE_FCNTL_H
  85 # include <fcntl.h>
  86 #endif
  87
  88 #if HAVE_SIGNAL_H
  89 # include <signal.h>
  90 #endif
  91
  92 #if HAVE_TIME_H
  93 # include <time.h>
  94 #endif
  95
  96 #if HAVE_TERMIOS_H
  97 # include <termios.h>
  98 #endif
  99
 100 #if HAVE_STRING_H
 101 # include <string.h>
 102 #endif
 103
 104 #if HAVE_CTYPE_H
 105 # include <ctype.h>
 106 #endif
 107
 108 #if HAVE_INTTYPES_H
 109 # include <inttypes.h>
 110 #else
 111 # if HAVE_STDINT_H
 112 #  include <stdint.h>
 113 # endif
 114 #endif
 115
 116 #if HAVE_SYS_RESOURCE_H
 117 # include <sys/resource.h>
 118 #endif
 119
 120 #include <stdlib.h>
 121
 122 typedef $1 testing;
 123
 124 int main(void) {
 125   FILE *f=fopen("conftestval", "w");
 126   if (!f) exit(1);
 127   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 128     fprintf(f, "%s%d\n",
 129            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 130            (int)(sizeof(testing)*8));
 131   } else {
 132     fprintf(f,"%s\n",
 133            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 134            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 135   }
 136   fclose(f);
 137   exit(0);
 138 }]])],[AC_CV_NAME=`cat conftestval`],
 139 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 140 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])
 141 CPPFLAGS="$fp_check_htype_save_cppflags"]) dnl
 142 if test "$AC_CV_NAME_supported" = yes; then
 143   AC_MSG_RESULT($AC_CV_NAME)
 144   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 145 else
 146   AC_MSG_RESULT([not supported])
 147 fi
 148 undefine([AC_TYPE_NAME])dnl
 149 undefine([AC_CV_NAME])dnl
 150 undefine([AC_CV_NAME_supported])dnl
 151 ])
 152
 153
 154 # FP_SEARCH_LIBS_PROTO(WHAT, PROTOTYPE, FUNCTION, SEARCH-LIBS,
 155 #                [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
 156 #                [OTHER-LIBRARIES])
 157 # --------------------------------------------------------
 158 # Search for a library defining FUNC, if it's not already available.
 159 # This is a copy of the AC_SEARCH_LIBS definition, but extended to take
 160 # the name of the thing we are looking for as its first argument, and
 161 # prototype text as its second argument. It also calls AC_LANG_PROGRAM
 162 # instead of AC_LANG_CALL
 163 AC_DEFUN([FP_SEARCH_LIBS_PROTO],
 164 [AS_VAR_PUSHDEF([ac_Search], [ac_cv_search_$1])dnl
 165 AC_CACHE_CHECK([for library containing $1], [ac_Search],
 166 [ac_func_search_save_LIBS=$LIBS
 167 AC_LANG_CONFTEST([AC_LANG_PROGRAM([$2], [$3])])
 168 for ac_lib in '' $4; do
 169   if test -z "$ac_lib"; then
 170     ac_res="none required"
 171   else
 172     ac_res=-l$ac_lib
 173     LIBS="-l$ac_lib $7 $ac_func_search_save_LIBS"
 174   fi
 175   AC_LINK_IFELSE([], [AS_VAR_SET([ac_Search], [$ac_res])])
 176   AS_VAR_SET_IF([ac_Search], [break])
 177 done
 178 AS_VAR_SET_IF([ac_Search], , [AS_VAR_SET([ac_Search], [no])])
 179 rm conftest.$ac_ext
 180 LIBS=$ac_func_search_save_LIBS])
 181 ac_res=AS_VAR_GET([ac_Search])
 182 AS_IF([test "$ac_res" != no],
 183   [test "$ac_res" = "none required" || LIBS="$ac_res $LIBS"
 184   $5],
 185       [$6])dnl
 186 AS_VAR_POPDEF([ac_Search])dnl
 187 ])