configure.ac

   1 AC_INIT([Haskell base package], [1.0], [libraries@haskell.org], [base])
   2
   3 # Safety check: Ensure that we are in the correct source directory.
   4 AC_CONFIG_SRCDIR([include/HsBase.h])
   5
   6 AC_CONFIG_HEADERS([include/HsBaseConfig.h include/EventConfig.h])
   7
   8 AC_ARG_WITH([cc],
   9             [C compiler],
  10             [CC=$withval])
  11 AC_PROG_CC()
  12
  13 case `uname -s` in
  14     MINGW*|CYGWIN*)
  15         WINDOWS=YES;;
  16     *)
  17         WINDOWS=NO;;
  18 esac
  19
  20 # do we have long longs?
  21 AC_CHECK_TYPES([long long])
  22
  23 dnl ** check for full ANSI header (.h) files
  24 AC_HEADER_STDC
  25
  26 # check for specific header (.h) files that we are interested in
  27 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h inttypes.h limits.h signal.h sys/resource.h sys/select.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/wait.h termios.h time.h unistd.h utime.h windows.h winsock.h langinfo.h poll.h sys/epoll.h sys/event.h sys/eventfd.h])
  28
  29 # Enable large file support. Do this before testing the types ino_t, off_t, and
  30 # rlim_t, because it will affect the result of that test.
  31 AC_SYS_LARGEFILE
  32
  33 dnl ** check for wide-char classifications
  34 dnl FreeBSD has an emtpy wctype.h, so test one of the affected
  35 dnl functions if it's really there.
  36 AC_CHECK_HEADERS([wctype.h], [AC_CHECK_FUNCS(iswspace)])
  37
  38 AC_CHECK_FUNCS([lstat])
  39 AC_CHECK_FUNCS([getclock getrusage times])
  40 AC_CHECK_FUNCS([_chsize ftruncate])
  41
  42 AC_CHECK_FUNCS([epoll_ctl eventfd kevent kevent64 kqueue poll])
  43
  44 # event-related fun
  45
  46 if test "$ac_cv_header_sys_epoll_h" = yes -a "$ac_cv_func_epoll_ctl" = yes; then
  47   AC_DEFINE([HAVE_EPOLL], [1], [Define if you have epoll support.])
  48 fi
  49
  50 if test "$ac_cv_header_sys_event_h" = yes -a "$ac_cv_func_kqueue" = yes; then
  51   AC_DEFINE([HAVE_KQUEUE], [1], [Define if you have kqueue support.])
  52 fi
  53
  54 if test "$ac_cv_header_poll_h" = yes -a "$ac_cv_func_poll" = yes; then
  55   AC_DEFINE([HAVE_POLL], [1], [Define if you have poll support.])
  56 fi
  57
  58 dnl--------------------------------------------------------------------
  59 dnl * Deal with arguments telling us iconv is somewhere odd
  60 dnl--------------------------------------------------------------------
  61
  62 AC_ARG_WITH([iconv-includes],
  63   [AC_HELP_STRING([--with-iconv-includes],
  64     [directory containing iconv.h])],
  65     [ICONV_INCLUDE_DIRS=$withval; CPPFLAGS="-I$withval"],
  66     [ICONV_INCLUDE_DIRS=])
  67
  68 AC_ARG_WITH([iconv-libraries],
  69   [AC_HELP_STRING([--with-iconv-libraries],
  70     [directory containing iconv library])],
  71     [ICONV_LIB_DIRS=$withval; LDFLAGS="-L$withval"],
  72     [ICONV_LIB_DIRS=])
  73
  74 AC_SUBST(ICONV_INCLUDE_DIRS)
  75 AC_SUBST(ICONV_LIB_DIRS)
  76
  77 # map standard C types and ISO types to Haskell types
  78 FPTOOLS_CHECK_HTYPE(char)
  79 FPTOOLS_CHECK_HTYPE(signed char)
  80 FPTOOLS_CHECK_HTYPE(unsigned char)
  81 FPTOOLS_CHECK_HTYPE(short)
  82 FPTOOLS_CHECK_HTYPE(unsigned short)
  83 FPTOOLS_CHECK_HTYPE(int)
  84 FPTOOLS_CHECK_HTYPE(unsigned int)
  85 FPTOOLS_CHECK_HTYPE(long)
  86 FPTOOLS_CHECK_HTYPE(unsigned long)
  87 if test "$ac_cv_type_long_long" = yes; then
  88 FPTOOLS_CHECK_HTYPE(long long)
  89 FPTOOLS_CHECK_HTYPE(unsigned long long)
  90 fi
  91 FPTOOLS_CHECK_HTYPE(float)
  92 FPTOOLS_CHECK_HTYPE(double)
  93 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
  94 FPTOOLS_CHECK_HTYPE(size_t)
  95 FPTOOLS_CHECK_HTYPE(wchar_t)
  96 FPTOOLS_CHECK_HTYPE(sig_atomic_t)
  97 FPTOOLS_CHECK_HTYPE(clock_t)
  98 FPTOOLS_CHECK_HTYPE(time_t)
  99 FPTOOLS_CHECK_HTYPE(useconds_t)
 100 FPTOOLS_CHECK_HTYPE_ELSE(suseconds_t,
 101                          [if test "$WINDOWS" = "YES"
 102                           then
 103                               AC_CV_NAME=Int32
 104                               AC_CV_NAME_supported=yes
 105                               AC_MSG_RESULT([not found...on Windows, so using Int32])
 106                           else
 107                               AC_MSG_ERROR([type not found])
 108                           fi])
 109 FPTOOLS_CHECK_HTYPE(dev_t)
 110 FPTOOLS_CHECK_HTYPE(ino_t)
 111 FPTOOLS_CHECK_HTYPE(mode_t)
 112 FPTOOLS_CHECK_HTYPE(off_t)
 113 FPTOOLS_CHECK_HTYPE(pid_t)
 114 FPTOOLS_CHECK_HTYPE(gid_t)
 115 FPTOOLS_CHECK_HTYPE(uid_t)
 116 FPTOOLS_CHECK_HTYPE(cc_t)
 117 FPTOOLS_CHECK_HTYPE(speed_t)
 118 FPTOOLS_CHECK_HTYPE(tcflag_t)
 119 FPTOOLS_CHECK_HTYPE(nlink_t)
 120 FPTOOLS_CHECK_HTYPE(ssize_t)
 121 FPTOOLS_CHECK_HTYPE(rlim_t)
 122
 123 FPTOOLS_CHECK_HTYPE(intptr_t)
 124 FPTOOLS_CHECK_HTYPE(uintptr_t)
 125 FPTOOLS_CHECK_HTYPE(intmax_t)
 126 FPTOOLS_CHECK_HTYPE(uintmax_t)
 127
 128 # test errno values
 129 FP_CHECK_CONSTS([E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV ENOCIGAR], [#include <stdio.h>
 130 #include <errno.h>])
 131
 132 # we need SIGINT in TopHandler.lhs
 133 FP_CHECK_CONSTS([SIGINT], [
 134 #if HAVE_SIGNAL_H
 135 #include <signal.h>
 136 #endif])
 137
 138 dnl ** can we open files in binary mode?
 139 FP_CHECK_CONST([O_BINARY], [#include <fcntl.h>], [0])
 140
 141 # We can't just use AC_SEARCH_LIBS for this, as on OpenBSD the iconv.h
 142 # header needs to be included as iconv_open is #define'd to something
 143 # else. We therefore use our own FP_SEARCH_LIBS_PROTO, which allows us
 144 # to give prototype text.
 145 FP_SEARCH_LIBS_PROTO(iconv,
 146                      [
 147 #include <stddef.h>
 148 #include <iconv.h>
 149                       ],
 150                      [iconv_t cd;
 151                       cd = iconv_open("", "");
 152                       iconv(cd,NULL,NULL,NULL,NULL);
 153                       iconv_close(cd);],
 154                      iconv,
 155                      [EXTRA_LIBS="$EXTRA_LIBS $ac_lib"],
 156                      [if test "$WINDOWS" = "NO"
 157                       then
 158                           AC_MSG_ERROR([iconv is required on non-Windows platforms])
 159                       fi])
 160
 161 # If possible, we use libcharset instead of nl_langinfo(CODESET) to
 162 # determine the current locale's character encoding.
 163 FP_SEARCH_LIBS_PROTO(
 164     [locale_charset],
 165     [#include <libcharset.h>],
 166     [const char* charset = locale_charset();],
 167     [charset],
 168     [AC_DEFINE([HAVE_LIBCHARSET], [1], [Define to 1 if you have libcharset.])
 169      EXTRA_LIBS="$EXTRA_LIBS $ac_lib"])
 170
 171
 172 AC_SUBST(EXTRA_LIBS)
 173 AC_CONFIG_FILES([base.buildinfo])
 174
 175 AC_OUTPUT