configure.ac

   1 AC_INIT([Haskell base package], [1.0], [libraries@haskell.org], [base])
   2
   3 # Safety check: Ensure that we are in the correct source directory.
   4 AC_CONFIG_SRCDIR([include/HsBase.h])
   5
   6 AC_CONFIG_HEADERS([include/HsBaseConfig.h include/EventConfig.h])
   7
   8 AC_ARG_WITH([cc],
   9             [C compiler],
  10             [CC=$withval])
  11 AC_PROG_CC()
  12
  13 # do we have long longs?
  14 AC_CHECK_TYPES([long long])
  15
  16 dnl ** check for full ANSI header (.h) files
  17 AC_HEADER_STDC
  18
  19 # check for specific header (.h) files that we are interested in
  20 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h inttypes.h limits.h signal.h sys/resource.h sys/select.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/wait.h termios.h time.h unistd.h utime.h windows.h winsock.h langinfo.h poll.h sys/epoll.h sys/event.h sys/eventfd.h])
  21
  22 # Enable large file support. Do this before testing the types ino_t, off_t, and
  23 # rlim_t, because it will affect the result of that test.
  24 AC_SYS_LARGEFILE
  25
  26 dnl ** check for wide-char classifications
  27 dnl FreeBSD has an emtpy wctype.h, so test one of the affected
  28 dnl functions if it's really there.
  29 AC_CHECK_HEADERS([wctype.h], [AC_CHECK_FUNCS(iswspace)])
  30
  31 AC_CHECK_FUNCS([lstat])
  32 AC_CHECK_FUNCS([getclock getrusage times])
  33 AC_CHECK_FUNCS([_chsize ftruncate])
  34
  35 AC_CHECK_FUNCS([epoll_ctl eventfd kevent kevent64 kqueue poll])
  36
  37 # event-related fun
  38
  39 if test "$ac_cv_header_sys_epoll_h" = yes -a "$ac_cv_func_epoll_ctl" = yes; then
  40   AC_DEFINE([HAVE_EPOLL], [1], [Define if you have epoll support.])
  41 fi
  42
  43 if test "$ac_cv_header_sys_event_h" = yes -a "$ac_cv_func_kqueue" = yes; then
  44   AC_DEFINE([HAVE_KQUEUE], [1], [Define if you have kqueue support.])
  45 fi
  46
  47 if test "$ac_cv_header_poll_h" = yes -a "$ac_cv_func_poll" = yes; then
  48   AC_DEFINE([HAVE_POLL], [1], [Define if you have poll support.])
  49 fi
  50
  51 dnl--------------------------------------------------------------------
  52 dnl * Deal with arguments telling us iconv is somewhere odd
  53 dnl--------------------------------------------------------------------
  54
  55 AC_ARG_WITH([iconv-includes],
  56   [AC_HELP_STRING([--with-iconv-includes],
  57     [directory containing iconv.h])],
  58     [ICONV_INCLUDE_DIRS=$withval; CPPFLAGS="-I$withval"],
  59     [ICONV_INCLUDE_DIRS=])
  60
  61 AC_ARG_WITH([iconv-libraries],
  62   [AC_HELP_STRING([--with-iconv-libraries],
  63     [directory containing iconv library])],
  64     [ICONV_LIB_DIRS=$withval; LDFLAGS="-L$withval"],
  65     [ICONV_LIB_DIRS=])
  66
  67 AC_SUBST(ICONV_INCLUDE_DIRS)
  68 AC_SUBST(ICONV_LIB_DIRS)
  69
  70 # map standard C types and ISO types to Haskell types
  71 FPTOOLS_CHECK_HTYPE(char)
  72 FPTOOLS_CHECK_HTYPE(signed char)
  73 FPTOOLS_CHECK_HTYPE(unsigned char)
  74 FPTOOLS_CHECK_HTYPE(short)
  75 FPTOOLS_CHECK_HTYPE(unsigned short)
  76 FPTOOLS_CHECK_HTYPE(int)
  77 FPTOOLS_CHECK_HTYPE(unsigned int)
  78 FPTOOLS_CHECK_HTYPE(long)
  79 FPTOOLS_CHECK_HTYPE(unsigned long)
  80 if test "$ac_cv_type_long_long" = yes; then
  81 FPTOOLS_CHECK_HTYPE(long long)
  82 FPTOOLS_CHECK_HTYPE(unsigned long long)
  83 fi
  84 FPTOOLS_CHECK_HTYPE(float)
  85 FPTOOLS_CHECK_HTYPE(double)
  86 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
  87 FPTOOLS_CHECK_HTYPE(size_t)
  88 FPTOOLS_CHECK_HTYPE(wchar_t)
  89 FPTOOLS_CHECK_HTYPE(sig_atomic_t)
  90 FPTOOLS_CHECK_HTYPE(clock_t)
  91 FPTOOLS_CHECK_HTYPE(time_t)
  92 FPTOOLS_CHECK_HTYPE(useconds_t)
  93 FPTOOLS_CHECK_HTYPE(suseconds_t)
  94 FPTOOLS_CHECK_HTYPE(dev_t)
  95 FPTOOLS_CHECK_HTYPE(ino_t)
  96 FPTOOLS_CHECK_HTYPE(mode_t)
  97 FPTOOLS_CHECK_HTYPE(off_t)
  98 FPTOOLS_CHECK_HTYPE(pid_t)
  99 FPTOOLS_CHECK_HTYPE(gid_t)
 100 FPTOOLS_CHECK_HTYPE(uid_t)
 101 FPTOOLS_CHECK_HTYPE(cc_t)
 102 FPTOOLS_CHECK_HTYPE(speed_t)
 103 FPTOOLS_CHECK_HTYPE(tcflag_t)
 104 FPTOOLS_CHECK_HTYPE(nlink_t)
 105 FPTOOLS_CHECK_HTYPE(ssize_t)
 106 FPTOOLS_CHECK_HTYPE(rlim_t)
 107
 108 FPTOOLS_CHECK_HTYPE(intptr_t)
 109 FPTOOLS_CHECK_HTYPE(uintptr_t)
 110 FPTOOLS_CHECK_HTYPE(intmax_t)
 111 FPTOOLS_CHECK_HTYPE(uintmax_t)
 112
 113 # test errno values
 114 FP_CHECK_CONSTS([E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV ENOCIGAR], [#include <stdio.h>
 115 #include <errno.h>])
 116
 117 # we need SIGINT in TopHandler.lhs
 118 FP_CHECK_CONSTS([SIGINT], [
 119 #if HAVE_SIGNAL_H
 120 #include <signal.h>
 121 #endif])
 122
 123 dnl ** can we open files in binary mode?
 124 FP_CHECK_CONST([O_BINARY], [#include <fcntl.h>], [0])
 125
 126 # We can't just use AC_SEARCH_LIBS for this, as on OpenBSD the iconv.h
 127 # header needs to be included as iconv_open is #define'd to something
 128 # else. We therefore use our own FP_SEARCH_LIBS_PROTO, which allows us
 129 # to give prototype text.
 130 FP_SEARCH_LIBS_PROTO(iconv,
 131                      [
 132 #include <stddef.h>
 133 #include <iconv.h>
 134                       ],
 135                      [iconv_t cd;
 136                       cd = iconv_open("", "");
 137                       iconv(cd,NULL,NULL,NULL,NULL);
 138                       iconv_close(cd);],
 139                      iconv,
 140                      [EXTRA_LIBS="$EXTRA_LIBS $ac_lib"],
 141                      [case `uname -s` in
 142                         MINGW*|CYGWIN*) ;;
 143                         *)
 144                              AC_MSG_ERROR([iconv is required on non-Windows platforms]);;
 145                       esac])
 146
 147 # If possible, we use libcharset instead of nl_langinfo(CODESET) to
 148 # determine the current locale's character encoding.
 149 FP_SEARCH_LIBS_PROTO(
 150     [locale_charset],
 151     [#include <libcharset.h>],
 152     [const char* charset = locale_charset();],
 153     [charset],
 154     [AC_DEFINE([HAVE_LIBCHARSET], [1], [Define to 1 if you have libcharset.])
 155      EXTRA_LIBS="$EXTRA_LIBS $ac_lib"])
 156
 157
 158 AC_SUBST(EXTRA_LIBS)
 159 AC_CONFIG_FILES([base.buildinfo])
 160
 161 AC_OUTPUT