aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN([FP_CHECK_FLAG],
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
  79 # --------------------------------------------------------
  80 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
  81 # compilation. Execute IF-FAILS when unable to determine the value. Works for
  82 # cross-compilation, too.
  83 #
  84 # Implementation note: We are lazy and use an internal autoconf macro, but it
  85 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
  86 # little risk.
  87 AC_DEFUN([FP_COMPUTE_INT],
  88 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  89 ])# FP_COMPUTE_INT
  90
  91
  92 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
  93 # ------------------------------------------------------------------
  94 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
  95 # given type. Defines ALIGNMENT_TYPE.
  96 AC_DEFUN([FP_CHECK_ALIGNMENT],
  97 [AS_LITERAL_IF([$1], [],
  98                [AC_FATAL([$0: requires literal arguments])])[]dnl
  99 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 100 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 101 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 102 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 103   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 104                  [fp_Cache],
 105                  [AC_INCLUDES_DEFAULT([$3])],
 106                  [AC_MSG_ERROR([cannot compute alignment ($1)
 107 See `config.log' for more details.], [77])])
 108 else
 109   fp_Cache=0
 110 fi])[]dnl
 111 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 112 m4_popdef([fp_Cache])[]dnl
 113 ])# FP_CHECK_ALIGNMENT
 114
 115
 116 # FP_LEADING_UNDERSCORE
 117 # ---------------------
 118 # Test for determining whether symbol names have a leading underscore. We assume
 119 # that they _haven't_ if anything goes wrong. Sets the output variable
 120 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 121 #
 122 # Some nlist implementations seem to try to be compatible by ignoring a leading
 123 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 124 # checking for *no* leading underscore first. Sigh.  --SDM
 125 #
 126 # Similarly on OpenBSD, but this test doesn't help. -- dons
 127 AC_DEFUN([FP_LEADING_UNDERSCORE],
 128 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 129 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 130 # Hack!: nlist() under Digital UNIX insist on there being an _,
 131 # but symbol table listings shows none. What is going on here?!?
 132 #
 133 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 134 # the underscoredness of that "platform"
 135 case $HostPlatform in
 136 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 137   case $build in
 138     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 139     *) fptools_cv_leading_underscore=no ;;
 140   esac ;;
 141 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 142 *cygwin32) fptools_cv_leading_underscore=yes;;
 143 *mingw32) fptools_cv_leading_underscore=yes;;
 144 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 145 #include <nlist.h>
 146 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 147 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 148 #endif
 149
 150 int main(argc, argv)
 151 int argc;
 152 char **argv;
 153 {
 154 #ifdef HAVE_NLIST_H
 155     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 156         exit(1);
 157     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 158         exit(0);
 159 #endif
 160     exit(1);
 161 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 162 ;;
 163 esac]);
 164 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 165 if test x"$fptools_cv_leading_underscore" = xyes; then
 166    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 167 fi])# FP_LEADING_UNDERSCORE
 168
 169
 170 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 171 # ----------------------------------------------------------------------------------
 172 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 173 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 174 AC_DEFUN([FP_COMPARE_VERSIONS],
 175 [fp_version1=$1; fp_version2=$3
 176 fp_save_IFS=$IFS; IFS='.'
 177 while test x"$fp_version1" != x || test x"$fp_version2" != x
 178 do
 179
 180   set dummy $fp_version1; shift
 181   fp_num1=""
 182   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 183   test x"$fp_num1" = x && fp_num1="0"
 184   fp_version1="[$]*"
 185
 186   set dummy $fp_version2; shift
 187   fp_num2=""
 188   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 189   test x"$fp_num2" = x && fp_num2="0"
 190   fp_version2="[$]*"
 191
 192   test "$fp_num1" = "$fp_num2" || break;
 193 done
 194 IFS=$fp_save_IFS
 195 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 196 ])# FP_COMPARE_VERSIONS
 197
 198
 199 dnl
 200 dnl Check for GreenCard and version.
 201 dnl
 202 AC_DEFUN([FPTOOLS_GREENCARD],
 203 [
 204 AC_PATH_PROG(GreenCardCmd,greencard)
 205 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 206 changequote(, )dnl
 207 [if test x"$GreenCardCmd" != x; then
 208    fptools_cv_greencard_version="`$GreenCardCmd --version |
 209                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 210 else
 211    fptools_cv_greencard_version=""
 212 fi
 213 changequote([, ])dnl
 214 ])
 215 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 216   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 217 GreenCardVersion=$fptools_cv_greencard_version
 218 AC_SUBST(GreenCardVersion)
 219 ])
 220
 221 dnl
 222 dnl Check for Happy and version.  If we're building GHC, then we need
 223 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 224 dnl for a happy source tree and point the build system at that instead.
 225 dnl
 226 AC_DEFUN([FPTOOLS_HAPPY],
 227 [AC_PATH_PROG(HappyCmd,happy,)
 228 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 229 changequote(, )dnl
 230 [if test x"$HappyCmd" != x; then
 231    fptools_cv_happy_version="`$HappyCmd -v |
 232                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 233 else
 234    fptools_cv_happy_version="";
 235 fi;
 236 changequote([, ])dnl
 237 ])
 238 FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 239   [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 240 HappyVersion=$fptools_cv_happy_version;
 241 AC_SUBST(HappyVersion)
 242 ])
 243
 244 dnl
 245 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 246 dnl for a haddock source tree and point the build system at that instead.
 247 dnl
 248 AC_DEFUN([FPTOOLS_HADDOCK],
 249 [AC_PATH_PROG(HaddockCmd,haddock,)
 250 dnl Darn, I forgot to make Haddock print out its version number when
 251 dnl invoked with -v.  We could try generating some HTML and grepping
 252 dnl through that to find the version number, but I think we'll make
 253 dnl do without it for now.
 254 ])
 255
 256 dnl
 257 dnl Check for Alex and version.  If we're building GHC, then we need
 258 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 259 dnl for a alex source tree and point the build system at that instead.
 260 dnl
 261 AC_DEFUN([FPTOOLS_ALEX],
 262 [
 263 AC_PATH_PROG(AlexCmd,alex,)
 264 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 265 changequote(, )dnl
 266 [if test x"$AlexCmd" != x; then
 267    fptools_cv_alex_version="`$AlexCmd -v |
 268                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 269 else
 270    fptools_cv_alex_version="";
 271 fi;
 272 changequote([, ])dnl
 273 ])
 274 FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 275   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 276 AlexVersion=$fptools_cv_alex_version;
 277 AC_SUBST(AlexVersion)
 278 ])
 279
 280
 281 # FP_PROG_LD
 282 # ----------
 283 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 284 # of ld. Exits if no ld can be found
 285 AC_DEFUN([FP_PROG_LD],
 286 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 287 if test -z "$fp_prog_ld_raw"; then
 288   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 289 fi
 290 LdCmd=$fp_prog_ld_raw
 291 case $HostPlatform in
 292   *mingw32) if test x${OSTYPE} != xmsys; then
 293               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 294               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 295             fi
 296             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 297             # the generation of relocatable object files with large amounts
 298             # of relocations correctly. (cf. HSbase.o splittage-hack)
 299             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 300             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 301                                 [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 302             ;;
 303 esac
 304 AC_SUBST([LdCmd])
 305 ])# FP_PROG_LD
 306
 307
 308 # FP_PROG_LD_X
 309 # ------------
 310 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 311 # variable's value is empty.
 312 AC_DEFUN([FP_PROG_LD_X],
 313 [AC_REQUIRE([FP_PROG_LD])
 314 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 315 [echo 'foo() {}' > conftest.c
 316 ${CC-cc} -c conftest.c
 317 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 318    fp_cv_ld_x=yes
 319 else
 320    fp_cv_ld_x=no
 321 fi
 322 rm -rf conftest*])
 323 if test "$fp_cv_ld_x" = yes; then
 324   LdXFlag=-x
 325 else
 326   LdXFlag=
 327 fi
 328 AC_SUBST([LdXFlag])
 329 ])# FP_PROG_LD_X
 330
 331
 332 # FP_PROG_LD_IS_GNU
 333 # -----------------
 334 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 335 # GNU ld or not.
 336 AC_DEFUN([FP_PROG_LD_IS_GNU],
 337 [AC_REQUIRE([FP_PROG_LD])
 338 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 339 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 340   fp_cv_gnu_ld=yes
 341 else
 342   fp_cv_gnu_ld=no
 343 fi])
 344 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 345 ])# FP_PROG_LD_IS_GNU
 346
 347
 348 # FP_PROG_AR
 349 # ----------
 350 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 351 # version of it. Exits if no ar can be found
 352 AC_DEFUN([FP_PROG_AR],
 353 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 354 if test -z "$fp_prog_ar_raw"; then
 355   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 356 fi
 357 fp_prog_ar=$fp_prog_ar_raw
 358 case $HostPlatform in
 359   *mingw32) if test x${OSTYPE} != xmsys; then
 360               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 361               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 362             fi
 363             ;;
 364 esac
 365 ])# FP_PROG_AR
 366
 367
 368 # FP_PROG_AR_IS_GNU
 369 # -----------------
 370 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 371 AC_DEFUN([FP_PROG_AR_IS_GNU],
 372 [AC_REQUIRE([FP_PROG_AR])
 373 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 374 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 375   fp_cv_prog_ar_is_gnu=yes
 376 else
 377   fp_cv_prog_ar_is_gnu=no
 378 fi])
 379 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 380 ])# FP_PROG_AR_IS_GNU
 381
 382
 383 # FP_PROG_AR_ARGS
 384 # ---------------
 385 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 386 # to a non-Cygwin invocation of ar including these arguments.
 387 AC_DEFUN([FP_PROG_AR_ARGS],
 388 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 389 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 390 [
 391 # GNU ar needs special treatment: it appears to have problems with
 392 # object files with the same name if you use the 's' modifier, but
 393 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 394 if test $fp_prog_ar_is_gnu = yes; then
 395   fp_cv_prog_ar_args="q"
 396 else
 397   touch conftest.dummy
 398   for fp_var in clqsZ clqs cqs clq cq ; do
 399      rm -f conftest.a
 400      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 401         fp_cv_prog_ar_args=$fp_var
 402         break
 403      fi
 404   done
 405   rm -f conftest*
 406   if test -z "$fp_cv_prog_ar_args"; then
 407     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 408   fi
 409 fi])
 410 fp_prog_ar_args=$fp_cv_prog_ar_args
 411 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 412
 413 ])# FP_PROG_AR_ARGS
 414
 415
 416 # FP_PROG_AR_NEEDS_RANLIB
 417 # -----------------------
 418 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 419 # to ":" otherwise.
 420 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 421 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 422 AC_REQUIRE([FP_PROG_AR_ARGS])
 423 AC_REQUIRE([AC_PROG_CC])
 424 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 425 [if test $fp_prog_ar_is_gnu = yes; then
 426   fp_cv_prog_ar_needs_ranlib=no
 427 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 428   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 429   # so we hardcode it.
 430   fp_cv_prog_ar_needs_ranlib=yes
 431 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 432   fp_cv_prog_ar_needs_ranlib=no
 433 else
 434   fp_cv_prog_ar_needs_ranlib=yes
 435 fi])
 436 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 437    AC_PROG_RANLIB
 438 else
 439   RANLIB=":"
 440   AC_SUBST([RANLIB])
 441 fi
 442 ])# FP_PROG_AR_NEEDS_RANLIB
 443
 444
 445 # FP_PROG_AR_SUPPORTS_INPUT
 446 # -------------------------
 447 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 448 # whether ar supports -input flag is supported or not.
 449 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 450 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 451 AC_REQUIRE([FP_PROG_AR_ARGS])
 452 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 453 [fp_cv_prog_ar_supports_input=no
 454 if test $fp_prog_ar_is_gnu = no; then
 455   rm -f conftest*
 456   touch conftest.lst
 457   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 458     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 459   fi
 460   rm -f conftest*
 461 fi])
 462 if test $fp_cv_prog_ar_supports_input = yes; then
 463     ArSupportsInput="-input"
 464 else
 465     ArSupportsInput=""
 466 fi
 467 AC_SUBST([ArSupportsInput])
 468 ])# FP_PROG_AR_SUPPORTS_INPUT
 469
 470
 471 dnl
 472 dnl AC_SHEBANG_PERL - can we she-bang perl?
 473 dnl
 474 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 475 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 476 [echo "#!$PerlCmd"'
 477 exit $1;
 478 ' > conftest
 479 chmod u+x conftest
 480 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 481 if test $? -ne 69; then
 482    fptools_cv_shebang_perl=yes
 483 else
 484    fptools_cv_shebang_perl=no
 485 fi
 486 rm -f conftest
 487 ])])
 488
 489
 490 # FP_HAVE_GCC
 491 # -----------
 492 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 493 # output variables HaveGcc and GccVersion.
 494 AC_DEFUN([FP_HAVE_GCC],
 495 [AC_REQUIRE([AC_PROG_CC])
 496 if test -z "$GCC"; then
 497    fp_have_gcc=NO
 498 else
 499    fp_have_gcc=YES
 500 fi
 501 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 502   AC_MSG_ERROR([gcc is required])
 503 fi
 504 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 505 [if test "$fp_have_gcc" = "YES"; then
 506    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 507    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 508      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 509  else
 510    fp_gcc_version="not-installed"
 511  fi
 512 ])
 513 AC_SUBST([HaveGcc], [$fp_have_gcc])
 514 AC_SUBST([GccVersion], [$fp_gcc_version])
 515 ])# FP_HAVE_GCC
 516
 517 AC_DEFUN([FP_MINGW_GCC],
 518 [
 519   case $HostOS_CPP in
 520     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 521              if $CC -v 2>&1 | grep mingw >/dev/null; then
 522                 AC_MSG_RESULT([yes])
 523              else
 524                 AC_MSG_RESULT([no])
 525                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 526              fi;;
 527     *) ;;
 528   esac
 529 ])
 530
 531 dnl Small feature test for perl version. Assumes PerlCmd
 532 dnl contains path to perl binary
 533 dnl
 534 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 535 [$PerlCmd -v >conftest.out 2>&1
 536    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 537       :
 538    else
 539       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 540          :
 541       else
 542          if grep "version 6" conftest.out >/dev/null 2>&1; then
 543             :
 544          else
 545             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 546          fi
 547       fi
 548    fi
 549 rm -fr conftest*
 550 ])
 551
 552
 553 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 554 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 555 # -----------------------------------------------------
 556 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 557 # of PROG-TO-CHECK-FOR when found.
 558 AC_DEFUN([FP_CHECK_PROG],
 559 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 560 )# FP_CHECK_PROC
 561
 562
 563 # FP_PROG_FIND
 564 # ------------
 565 # Find a non-WinDoze version of the "find" utility.
 566 AC_DEFUN([FP_PROG_FIND],
 567 [AC_PATH_PROG([fp_prog_find], [find])
 568 echo foo > conftest.txt
 569 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 570 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 571   # OK, looks like a real "find".
 572   FindCmd="$fp_prog_find"
 573 else
 574   # Found a poor WinDoze version of "find", ignore it.
 575   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 576   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 577 fi
 578 rm -f conftest.txt conftest.out
 579 AC_SUBST([FindCmd])[]dnl
 580 ])# FP_PROG_FIND
 581
 582
 583 # FP_PROG_SORT
 584 # ------------
 585 # Find a Unix-like sort
 586 AC_DEFUN([FP_PROG_SORT],
 587 [AC_PATH_PROG([fp_prog_sort], [sort])
 588 echo conwip > conftest.txt
 589 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 590 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 591   # The goods
 592   SortCmd="$fp_prog_sort"
 593 else
 594   # Summink else..pick next one.
 595   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 596   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 597 fi
 598 rm -f conftest.txt conftest.out
 599 AC_SUBST([SortCmd])[]dnl
 600 ])# FP_PROG_SORT
 601
 602 dnl
 603 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 604 dnl values of the second argument to the result of running
 605 dnl the commands given by the third. It does not cache its
 606 dnl result, so it is suitable for checks which should be
 607 dnl run every time.
 608 dnl
 609 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 610 [AC_MSG_CHECKING([$1])
 611  $3
 612  AC_MSG_RESULT([$][$2])
 613 ])
 614
 615 dnl
 616 dnl FPTOOLS_GHC_VERSION(version)
 617 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 618 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 619 dnl
 620 dnl Test for version of installed ghc.  Uses $GHC.
 621 dnl [original version pinched from c2hs]
 622 dnl
 623 AC_DEFUN([FPTOOLS_GHC_VERSION],
 624 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 625 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 626   cat conftestghc >&AS_MESSAGE_LOG_FD
 627 #Useless Use Of cat award...
 628   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 629   rm -fr conftest*
 630   if test "[$]fptools_version_of_ghc" = ""
 631   then
 632     fptools_version_of_ghc='unknown'
 633   fi
 634 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 635 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 636 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 637 #
 638 if test "[$]fptools_version_of_ghc[_pl]" = ""
 639 then
 640   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 641   fptools_version_of_ghc[_pl]="0"
 642 else
 643   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 644 fi
 645 #
 646 ifelse($#, [1], [dnl
 647 [$1]="[$]fptools_version_of_ghc[_all]"
 648 ], $#, [2], [dnl
 649 [$1]="[$]fptools_version_of_ghc[_major]"
 650 [$2]="[$]fptools_version_of_ghc[_minor]"
 651 ], $#, [3], [dnl
 652 [$1]="[$]fptools_version_of_ghc[_major]"
 653 [$2]="[$]fptools_version_of_ghc[_minor]"
 654 [$3]="[$]fptools_version_of_ghc[_pl]"
 655 ], $#, [4], [dnl
 656 [$1]="[$]fptools_version_of_ghc[_all]"
 657 [$2]="[$]fptools_version_of_ghc[_major]"
 658 [$3]="[$]fptools_version_of_ghc[_minor]"
 659 [$4]="[$]fptools_version_of_ghc[_pl]"
 660 ])
 661 ])
 662 ])dnl
 663
 664
 665 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 666 # ---------------------------------------------------------------------------------
 667 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 668 # additional flexibility of specifying the PROLOGUE and BODY.
 669 AC_DEFUN([FP_CHECK_FUNC],
 670 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 671 AC_CACHE_CHECK([for $1], fp_func,
 672 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 673                 [AS_VAR_SET(fp_func, yes)],
 674                 [AS_VAR_SET(fp_func, no)])])
 675 AS_IF([test AS_VAR_GET(fp_func) = yes],
 676       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 677                 [Define to 1 if you have the `]$1[' function.]) $4],
 678       [$5])dnl
 679 AS_VAR_POPDEF([fp_func])dnl
 680 ])# FP_CHECK_FUNC
 681
 682
 683 # FP_GEN_DOCBOOK_XML
 684 # ------------------
 685 # Generates a DocBook XML V4.2 document in conftest.xml.
 686 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 687 [rm -f conftest.xml
 688 cat > conftest.xml << EOF
 689 <?xml version="1.0" encoding="iso-8859-1"?>
 690 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 691    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 692 <book id="test">
 693   <title>A DocBook Test Document</title>
 694   <chapter id="id-one">
 695     <title>A Chapter Title</title>
 696     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 697   </chapter>
 698   <chapter id="id-two">
 699     <title>Another Chapter Title</title>
 700     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 701   </chapter>
 702 </book>
 703 EOF
 704 ]) # FP_GEN_DOCBOOK_XML
 705
 706
 707 # FP_PROG_XSLTPROC
 708 # ----------------
 709 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 710 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 711 AC_DEFUN([FP_PROG_XSLTPROC],
 712 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 713 if test -z "$XsltprocCmd"; then
 714   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 715 fi
 716 ])# FP_PROG_XSLTPROC
 717
 718
 719 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 720 # ----------------------------
 721 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 722 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 723 # will be empty if none could be found.
 724 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 725 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 726 if test -n "$XsltprocCmd"; then
 727   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 728   [FP_GEN_DOCBOOK_XML
 729   fp_cv_dir_docbook_xsl=no
 730   for fp_var in $1; do
 731      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 732         fp_cv_dir_docbook_xsl=$fp_var
 733         break
 734      fi
 735   done
 736   rm -rf conftest*])
 737 fi
 738 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 739   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 740   DIR_DOCBOOK_XSL=
 741 else
 742   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 743 fi
 744 AC_SUBST([DIR_DOCBOOK_XSL])
 745 ])# FP_DIR_DOCBOOK_XSL
 746
 747
 748 # FP_PROG_XMLLINT
 749 # ----------------
 750 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 751 # xmllint. XmllintCmd is empty if xmllint could not be found.
 752 AC_DEFUN([FP_PROG_XMLLINT],
 753 [AC_PATH_PROG([XmllintCmd], [xmllint])
 754 if test -z "$XmllintCmd"; then
 755   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 756 fi
 757 ])# FP_PROG_XMLLINT
 758
 759
 760 # FP_CHECK_DOCBOOK_DTD
 761 # --------------------
 762 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 763 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 764 if test -n "$XmllintCmd"; then
 765   AC_MSG_CHECKING([for DocBook DTD])
 766   FP_GEN_DOCBOOK_XML
 767   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 768     AC_MSG_RESULT([ok])
 769   else
 770     AC_MSG_RESULT([failed])
 771     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 772     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 773   fi
 774   rm -rf conftest*
 775 fi
 776 ])# FP_CHECK_DOCBOOK_DTD
 777
 778
 779 # FP_GEN_FO
 780 # ------------------
 781 # Generates a formatting objects document in conftest.fo.
 782 AC_DEFUN([FP_GEN_FO],
 783 [rm -f conftest.fo
 784 cat > conftest.fo << EOF
 785 <?xml version="1.0"?>
 786 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 787   <fo:layout-master-set>
 788     <fo:simple-page-master master-name="blank">
 789       <fo:region-body/>
 790     </fo:simple-page-master>
 791   </fo:layout-master-set>
 792   <fo:page-sequence master-reference="blank">
 793     <fo:flow flow-name="xsl-region-body">
 794       <fo:block>
 795         Test!
 796       </fo:block>
 797     </fo:flow>
 798   </fo:page-sequence>
 799 </fo:root>
 800 EOF
 801 ]) # FP_GEN_FO
 802
 803
 804 # FP_PROG_FOP
 805 # -----------
 806 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 807 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 808 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 809 AC_DEFUN([FP_PROG_FOP],
 810 [AC_PATH_PROGS([FopCmd1], [fop])
 811 if test -n "$FopCmd1"; then
 812   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 813     [FP_GEN_FO
 814     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 815       fp_cv_fop_usability=yes
 816     else
 817       fp_cv_fop_usability=no
 818     fi
 819     rm -rf conftest*])
 820   if test x"$fp_cv_fop_usability" = xyes; then
 821      FopCmd=$FopCmd1
 822   fi
 823 fi
 824 if test -z "$FopCmd"; then
 825   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 826   FopCmd=$FopCmd2
 827 fi
 828 AC_SUBST([FopCmd])
 829 ])# FP_PROG_FOP
 830
 831
 832 # FP_PROG_FO_PROCESSOR
 833 # --------------------
 834 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 835 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 836 # PdfxmltexCmd.
 837 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 838 [AC_REQUIRE([FP_PROG_FOP])
 839 AC_PATH_PROG([XmltexCmd], [xmltex])
 840 AC_PATH_PROG([DvipsCmd], [dvips])
 841 if test -z "$FopCmd"; then
 842   if test -z "$XmltexCmd"; then
 843     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 844   else
 845     if test -z "$DvipsCmd"; then
 846       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 847     fi
 848   fi
 849   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 850   if test -z "$PdfxmltexCmd"; then
 851     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 852   fi
 853 elif test -z "$XmltexCmd"; then
 854   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 855 fi
 856 ])# FP_PROG_FO_PROCESSOR
 857
 858
 859 # FP_PROG_GHC_PKG
 860 # ----------------
 861 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 862 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 863 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 864 AC_DEFUN([FP_PROG_GHC_PKG],
 865 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 866 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 867 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 868   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 869 else
 870   fp_cv_matching_ghc_pkg=no
 871 fi])
 872 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 873   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 874 else
 875   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 876 fi])# FP_PROG_GHC_PKG
 877
 878
 879 # FP_GHC_HAS_READLINE
 880 # -------------------
 881 AC_DEFUN([FP_GHC_HAS_READLINE],
 882 [AC_REQUIRE([FP_PROG_GHC_PKG])
 883 AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
 884 [if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
 885   fp_cv_ghc_has_readline=yes
 886 else
 887   fp_cv_ghc_has_readline=no
 888  fi])
 889 AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
 890 ])# FP_GHC_HAS_READLINE
 891
 892
 893 # FP_GCC_NEEDS_NO_OMIT_LFPTR
 894 # --------------------------
 895 # Some OSs (Mandrake Linux, in particular) configure GCC with
 896 # -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
 897 # it off for mangling to work. The test is currently a bit crude, using only the
 898 # version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
 899 AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
 900 [AC_REQUIRE([FP_HAVE_GCC])
 901 AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
 902 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
 903   [fp_cv_gcc_needs_no_omit_lfptr=yes],
 904   [fp_cv_gcc_needs_no_omit_lfptr=no])])
 905 if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 906    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
 907 fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR
 908
 909 # FP_GCC_HAS_NO_UNIT_AT_A_TIME
 910 # --------------------------
 911 AC_DEFUN([FP_GCC_HAS_NO_UNIT_AT_A_TIME],
 912 [AC_REQUIRE([FP_HAVE_GCC])
 913 AC_CACHE_CHECK([whether gcc has -fno-unit-at-a-time], [fp_cv_gcc_has_no_unit_at_a_time],
 914 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 915   [fp_cv_gcc_has_no_unit_at_a_time=yes],
 916   [fp_cv_gcc_has_no_unit_at_a_time=no])])
 917 if test "$fp_cv_gcc_has_no_unit_at_a_time" = "yes"; then
 918    AC_DEFINE([HAVE_GCC_HAS_NO_UNIT_AT_A_TIME], [1], [Define to 1 if gcc supports -fno-unit-at-a-time.])
 919 fi])
 920
 921 # FP_SETUP_PROJECT_VERSION
 922 # ---------------------
 923 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
 924 [# Some renamings
 925 AC_SUBST([ProjectName], [$PACKAGE_NAME])
 926 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
 927
 928 # Split PACKAGE_VERSION into (possibly empty) parts
 929 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 930 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 931 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
 932 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
 933
 934 # Calculate project version as an integer, using 2 digits for minor version
 935 case $VERSION_MINOR in
 936   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
 937   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
 938   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
 939 esac
 940 AC_SUBST([ProjectVersionInt])
 941
 942 # The project patchlevel is zero unless stated otherwise
 943 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
 944
 945 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
 946 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
 947
 948 AC_SUBST([ProjectPatchLevel])
 949 ])# FP_SETUP_PROJECT_VERSION
 950
 951 # LocalWords:  fi