aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN(FP_CHECK_FLAG,
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # ---------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # --------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_CHECK_CONST(EXPRESSION, [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
 138 # -------------------------------------------------------------------------------
 139 # Defines CONST_EXPRESSION to the value of the compile-time EXPRESSION, using
 140 # INCLUDES. If the value cannot be determined, use VALUE-IF-FAIL.
 141 AC_DEFUN([FP_CHECK_CONST],
 142 [AS_VAR_PUSHDEF([fp_Cache], [fp_cv_const_$1])[]dnl
 143 AC_CACHE_CHECK([value of $1], fp_Cache,
 144 [FP_COMPUTE_INT([$1], fp_check_const_result, [AC_INCLUDES_DEFAULT([$2])],
 145                 [fp_check_const_result=m4_default([$3], ['-1'])])
 146 AS_VAR_SET(fp_Cache, [$fp_check_const_result])])[]dnl
 147 AC_DEFINE_UNQUOTED(AS_TR_CPP([CONST_$1]), AS_VAR_GET(fp_Cache), [The value of $1.])[]dnl
 148 AS_VAR_POPDEF([fp_Cache])[]dnl
 149 ])# FP_CHECK_CONST
 150
 151
 152 # FP_CHECK_CONSTS_TEMPLATE(EXPRESSION...)
 153 # ---------------------------------------
 154 # autoheader helper for FP_CHECK_CONSTS
 155 m4_define([FP_CHECK_CONSTS_TEMPLATE],
 156 [AC_FOREACH([fp_Const], [$1],
 157   [AH_TEMPLATE(AS_TR_CPP(CONST_[]fp_Const),
 158                [The value of ]fp_Const[.])])[]dnl
 159 ])# FP_CHECK_CONSTS_TEMPLATE
 160
 161
 162 # FP_CHECK_CONSTS(EXPRESSION..., [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
 163 # -----------------------------------------------------------------------------------
 164 # List version of FP_CHECK_CONST
 165 AC_DEFUN(FP_CHECK_CONSTS,
 166 [FP_CHECK_CONSTS_TEMPLATE([$1])dnl
 167 for fp_const_name in $1
 168 do
 169 FP_CHECK_CONST([$fp_const_name], [$2], [$3])
 170 done
 171 ])# FP_CHECK_CONSTS
 172
 173
 174 # FP_LEADING_UNDERSCORE
 175 # ---------------------
 176 # Test for determining whether symbol names have a leading underscore. We assume
 177 # that they _haven't_ if anything goes wrong. Sets the output variable
 178 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 179 #
 180 # Some nlist implementations seem to try to be compatible by ignoring a leading
 181 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 182 # checking for *no* leading underscore first. Sigh.  --SDM
 183 #
 184 # Similarly on OpenBSD, but this test doesn't help. -- dons
 185 AC_DEFUN([FP_LEADING_UNDERSCORE],
 186 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 187 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 188 # Hack!: nlist() under Digital UNIX insist on there being an _,
 189 # but symbol table listings shows none. What is going on here?!?
 190 #
 191 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 192 # the underscoredness of that "platform"
 193 case $HostPlatform in
 194 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 195   case $build in
 196     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 197     *) fptools_cv_leading_underscore=no ;;
 198   esac ;;
 199 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 200 *cygwin32) fptools_cv_leading_underscore=yes;;
 201 *mingw32) fptools_cv_leading_underscore=yes;;
 202 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 203 #include <nlist.h>
 204 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 205 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 206 #endif
 207
 208 int main(argc, argv)
 209 int argc;
 210 char **argv;
 211 {
 212 #ifdef HAVE_NLIST_H
 213     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 214         exit(1);
 215     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 216         exit(0);
 217 #endif
 218     exit(1);
 219 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 220 ;;
 221 esac]);
 222 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 223 if test x"$fptools_cv_leading_underscore" = xyes; then
 224    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 225 fi])# FP_LEADING_UNDERSCORE
 226
 227
 228 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 229 # ----------------------------------------------------------------------------------
 230 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 231 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 232 AC_DEFUN([FP_COMPARE_VERSIONS],
 233 [fp_version1=$1; fp_version2=$3
 234 fp_save_IFS=$IFS; IFS='.'
 235 while test x"$fp_version1" != x || test x"$fp_version2" != x
 236 do
 237
 238   set dummy $fp_version1; shift
 239   fp_num1=""
 240   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 241   test x"$fp_num1" = x && fp_num1="0"
 242   fp_version1="[$]*"
 243
 244   set dummy $fp_version2; shift
 245   fp_num2=""
 246   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 247   test x"$fp_num2" = x && fp_num2="0"
 248   fp_version2="[$]*"
 249
 250   test "$fp_num1" = "$fp_num2" || break;
 251 done
 252 IFS=$fp_save_IFS
 253 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 254 ])# FP_COMPARE_VERSIONS
 255
 256
 257 dnl
 258 dnl Check for GreenCard and version.
 259 dnl
 260 AC_DEFUN(FPTOOLS_GREENCARD,
 261 [
 262 AC_PATH_PROG(GreenCardCmd,greencard)
 263 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 264 changequote(, )dnl
 265 [if test x"$GreenCardCmd" != x; then
 266    fptools_cv_greencard_version="`$GreenCardCmd --version |
 267                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 268 else
 269    fptools_cv_greencard_version=""
 270 fi
 271 changequote([, ])dnl
 272 ])
 273 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 274   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 275 GreenCardVersion=$fptools_cv_greencard_version
 276 AC_SUBST(GreenCardVersion)
 277 ])
 278
 279 dnl
 280 dnl Check for Happy and version.  If we're building GHC, then we need
 281 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 282 dnl for a happy source tree and point the build system at that instead.
 283 dnl
 284 AC_DEFUN(FPTOOLS_HAPPY,
 285 [
 286 if test -d $srcdir/happy; then
 287    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 288 else
 289    SrcTreeHappyCmd=""
 290 fi
 291 if test x"$UseSrcTreeHappy" = xYES; then
 292   if test x"$SrcTreeHappyCmd" != x; then
 293      HappyCmd=$SrcTreeHappyCmd
 294   else
 295      AC_MSG_ERROR([--enable-src-tree-happy given, but happy not found in source tree])
 296   fi
 297 else
 298   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 299 fi
 300 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 301 changequote(, )dnl
 302 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
 303    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 304 elif test x"$HappyCmd" != x; then
 305    fptools_cv_happy_version="`$HappyCmd -v |
 306                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 307 else
 308    fptools_cv_happy_version="";
 309 fi;
 310 changequote([, ])dnl
 311 ])
 312 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 313   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.14],
 314   [AC_MSG_ERROR([Happy version 1.14 or later is required to compile GHC.])])[]dnl
 315 fi
 316 HappyVersion=$fptools_cv_happy_version;
 317 AC_SUBST(HappyVersion)
 318 ])
 319
 320 dnl
 321 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 322 dnl for a haddock source tree and point the build system at that instead.
 323 dnl
 324 AC_DEFUN(FPTOOLS_HADDOCK,
 325 [
 326 if test -d $srcdir/haddock; then
 327    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 328 else
 329    SrcTreeHaddockCmd=""
 330 fi
 331 if test x"$UseSrcTreeHaddock" = xYES; then
 332   if test x"$SrcTreeHaddockCmd" != x; then
 333      HaddockCmd=$SrcTreeHaddockCmd
 334   else
 335      AC_MSG_ERROR([--enable-src-tree-haddock given, but haddock not found in source tree])
 336   fi
 337 else
 338   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 339 fi
 340 dnl Darn, I forgot to make Haddock print out its version number when
 341 dnl invoked with -v.  We could try generating some HTML and grepping
 342 dnl through that to find the version number, but I think we'll make
 343 dnl do without it for now.
 344 ])
 345
 346 dnl
 347 dnl Check for Alex and version.  If we're building GHC, then we need
 348 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 349 dnl for a alex source tree and point the build system at that instead.
 350 dnl
 351 AC_DEFUN(FPTOOLS_ALEX,
 352 [
 353 if test -d $srcdir/alex; then
 354    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
 355 else
 356    SrcTreeAlexCmd=""
 357 fi
 358 if test x"$UseSrcTreeAlex" = xYES; then
 359   if test x"$SrcTreeAlexCmd" != x; then
 360      AlexCmd=$SrcTreeAlexCmd
 361   else
 362      AC_MSG_ERROR([--enable-src-tree-alex given, but alex not found in source tree])
 363   fi
 364 else
 365   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
 366 fi
 367 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 368 changequote(, )dnl
 369 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
 370    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 371 elif test x"$AlexCmd" != x; then
 372    fptools_cv_alex_version="`$AlexCmd -v |
 373                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 374 else
 375    fptools_cv_alex_version="";
 376 fi;
 377 changequote([, ])dnl
 378 ])
 379 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
 380   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 381   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 382 fi
 383 AlexVersion=$fptools_cv_alex_version;
 384 AC_SUBST(AlexVersion)
 385 ])
 386
 387
 388 dnl
 389 dnl Check whether ld supports -x
 390 dnl
 391 AC_DEFUN(FPTOOLS_LD_X,
 392 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
 393 [
 394 echo 'foo() {}' > conftest.c
 395 ${CC-cc} -c conftest.c
 396 if ${LdCmd} -r -x -o foo.o conftest.o; then
 397    fptools_cv_ld_x=yes
 398 else
 399    fptools_cv_ld_x=no
 400 fi
 401 rm -rf conftest.c conftest.o foo.o
 402 ])
 403 if test "$fptools_cv_ld_x" = yes; then
 404         LdXFlag=-x
 405 else
 406         LdXFlag=
 407 fi
 408 AC_SUBST(LdXFlag)
 409 ])
 410
 411
 412 # FP_PROG_AR
 413 # ----------
 414 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 415 # version of it. Exits if no ar can be found
 416 AC_DEFUN([FP_PROG_AR],
 417 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 418 if test -z "$fp_prog_ar_raw"; then
 419   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 420 fi
 421 fp_prog_ar=$fp_prog_ar_raw
 422 case $HostPlatform in
 423   *mingw32) if test x${OSTYPE} != xmsys; then
 424               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 425               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 426             fi
 427             ;;
 428 esac
 429 ])# FP_PROG_AR
 430
 431
 432 # FP_PROG_AR_IS_GNU
 433 # -----------------
 434 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 435 AC_DEFUN([FP_PROG_AR_IS_GNU],
 436 [AC_REQUIRE([FP_PROG_AR])
 437 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 438 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 439   fp_cv_prog_ar_is_gnu=yes
 440 else
 441   fp_cv_prog_ar_is_gnu=no
 442 fi])
 443 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 444 ])# FP_PROG_AR_IS_GNU
 445
 446
 447 # FP_PROG_AR_ARGS
 448 # ---------------
 449 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 450 # to a non-Cygwin invocation of ar including these arguments.
 451 AC_DEFUN([FP_PROG_AR_ARGS],
 452 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 453 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 454 [
 455 # GNU ar needs special treatment: it appears to have problems with
 456 # object files with the same name if you use the 's' modifier, but
 457 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 458 if test $fp_prog_ar_is_gnu = yes; then
 459   fp_cv_prog_ar_args="q"
 460 else
 461   touch conftest.dummy
 462   for fp_var in clqsZ clqs cqs clq cq ; do
 463      rm -f conftest.a
 464      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 465         fp_cv_prog_ar_args=$fp_var
 466         break
 467      fi
 468   done
 469   rm -f conftest*
 470   if test -z "$fp_cv_prog_ar_args"; then
 471     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 472   fi
 473 fi])
 474 fp_prog_ar_args=$fp_cv_prog_ar_args
 475 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 476
 477 ])# FP_PROG_AR_ARGS
 478
 479
 480 # FP_PROG_AR_NEEDS_RANLIB
 481 # -----------------------
 482 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 483 # to ":" otherwise.
 484 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 485 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 486 AC_REQUIRE([FP_PROG_AR_ARGS])
 487 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 488 [if test $fp_prog_ar_is_gnu = yes; then
 489   fp_cv_prog_ar_needs_ranlib=no
 490 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 491   fp_cv_prog_ar_needs_ranlib=no
 492 else
 493   fp_cv_prog_ar_needs_ranlib=yes
 494 fi])
 495 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 496    AC_PROG_RANLIB
 497 else
 498   RANLIB=":"
 499   AC_SUBST([RANLIB])
 500 fi
 501 ])# FP_PROG_AR_NEEDS_RANLIB
 502
 503
 504 # FP_PROG_AR_SUPPORTS_INPUT
 505 # -------------------------
 506 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 507 # whether ar supports -input flag is supported or not.
 508 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 509 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 510 AC_REQUIRE([FP_PROG_AR_ARGS])
 511 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 512 [fp_cv_prog_ar_supports_input=no
 513 if test $fp_prog_ar_is_gnu = no; then
 514   rm -f conftest*
 515   touch conftest.lst
 516   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 517     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 518   fi
 519   rm -f conftest*
 520 fi])
 521 if test $fp_cv_prog_ar_supports_input = yes; then
 522     ArSupportsInput="-input"
 523 else
 524     ArSupportsInput=""
 525 fi
 526 AC_SUBST([ArSupportsInput])
 527 ])# FP_PROG_AR_SUPPORTS_INPUT
 528
 529
 530 dnl
 531 dnl AC_SHEBANG_PERL - can we she-bang perl?
 532 dnl
 533 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
 534 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 535 [echo "#!$PerlCmd"'
 536 exit $1;
 537 ' > conftest
 538 chmod u+x conftest
 539 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 540 if test $? -ne 69; then
 541    fptools_cv_shebang_perl=yes
 542 else
 543    fptools_cv_shebang_perl=no
 544 fi
 545 rm -f conftest
 546 ])])
 547
 548 dnl
 549 dnl Extra testing of the result AC_PROG_CC, testing the gcc version no.
 550 dnl *Must* be called after AC_PROG_CC
 551 dnl
 552 AC_DEFUN(FPTOOLS_HAVE_GCC,
 553 [AC_CACHE_CHECK([whether you have an ok gcc], fptools_cv_have_gcc,
 554 [if test -z "$GCC"; then
 555     echo ''
 556     echo "You would be better off with gcc"
 557     echo "Perhaps it is already installed, but not in your PATH?"
 558     fptools_cv_have_gcc='no'
 559 else
 560 changequote(, )dnl
 561     gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [^0-9]*\([0-9][0-9]*\)\.\([0-9][0-9]*\).*/\1\.\2/g' `"
 562 changequote([, ])dnl
 563     fptools_cv_have_gcc='yes'
 564     FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
 565         [fptools_cv_have_gcc='no'
 566         echo ""
 567         echo "your gcc version appears to be ..."
 568         $CC --version
 569         echo "gcc prior to 2.0 and have never worked with ghc."
 570         echo "we recommend 2.95.3, although versions back to 2.7.2 should be ok."
 571         AC_MSG_ERROR([gcc 1.X has never been supported])])
 572 fi
 573 ])
 574 HaveGcc=`echo $fptools_cv_have_gcc | sed 'y/yesno/YESNO/'`
 575 AC_SUBST(HaveGcc)
 576 GccVersion=`gcc --version | grep mingw | cut -f 3 -d ' '`
 577 AC_SUBST(GccVersion)
 578 ])
 579
 580 dnl
 581 dnl Some OSs (Mandrake Linux, in particular) configure GCC with
 582 dnl -momit-leaf-frame-pointer on by default.  If this is the case, we
 583 dnl need to turn it off for mangling to work.  The test is currently a bit
 584 dnl crude, using only the version number of gcc.
 585 dnl
 586 AC_DEFUN([FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR],
 587 [AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fptools_cv_gcc_needs_no_omit_lfptr],
 588 [FP_COMPARE_VERSIONS([$gcc_version_str], [-ge], [3.2],
 589   [fptools_cv_gcc_needs_no_omit_lfptr=yes],
 590   [fptools_cv_gcc_needs_no_omit_lfptr=no])])
 591 if test "$fptools_cv_gcc_needs_no_omit_lfptr" = "yes"; then
 592    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
 593 fi])# FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR
 594
 595
 596 dnl Small feature test for perl version. Assumes PerlCmd
 597 dnl contains path to perl binary
 598 dnl
 599 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
 600 [$PerlCmd -v >conftest.out 2>&1
 601 if grep "version 5" conftest.out >/dev/null 2>&1; then
 602    :
 603 else
 604    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 605       :
 606    else
 607       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 608          :
 609       else
 610          if grep "version 6" conftest.out >/dev/null 2>&1; then
 611             :
 612          else
 613             echo "Your version of perl probably won't work."
 614          fi
 615       fi
 616    fi
 617 fi
 618 rm -fr conftest*
 619 ])
 620
 621
 622 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 623 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 624 # -----------------------------------------------------
 625 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 626 # of PROG-TO-CHECK-FOR when found.
 627 AC_DEFUN([FP_CHECK_PROG],
 628 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 629 )# FP_CHECK_PROC
 630
 631
 632 # FP_PROG_FIND
 633 # ------------
 634 # Find a non-WinDoze version of the "find" utility.
 635 AC_DEFUN([FP_PROG_FIND],
 636 [AC_PATH_PROG([fp_prog_find], [find])
 637 echo foo > conftest.txt
 638 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 639 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 640   # OK, looks like a real "find".
 641   FindCmd="$fp_prog_find"
 642 else
 643   # Found a poor WinDoze version of "find", ignore it.
 644   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 645   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 646 fi
 647 rm -f conftest.txt conftest.out
 648 AC_SUBST([FindCmd])[]dnl
 649 ])# FP_PROG_FIND
 650
 651
 652 dnl
 653 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 654 dnl values of the second argument to the result of running
 655 dnl the commands given by the third. It does not cache its
 656 dnl result, so it is suitable for checks which should be
 657 dnl run every time.
 658 dnl
 659 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
 660 [AC_MSG_CHECKING([$1])
 661  $3
 662  AC_MSG_RESULT([$][$2])
 663 ])
 664
 665 dnl
 666 dnl FPTOOLS_GHC_VERSION(version)
 667 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 668 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 669 dnl
 670 dnl Test for version of installed ghc.  Uses $GHC.
 671 dnl [original version pinched from c2hs]
 672 dnl
 673 AC_DEFUN(FPTOOLS_GHC_VERSION,
 674 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 675 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 676   cat conftestghc >&AS_MESSAGE_LOG_FD
 677 #Useless Use Of cat award...
 678   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 679   rm -fr conftest*
 680   if test "[$]fptools_version_of_ghc" = ""
 681   then
 682     fptools_version_of_ghc='unknown'
 683   fi
 684 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 685 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 686 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 687 #
 688 if test "[$]fptools_version_of_ghc[_pl]" = ""
 689 then
 690   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 691   fptools_version_of_ghc[_pl]="0"
 692 else
 693   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 694 fi
 695 #
 696 ifelse($#, [1], [dnl
 697 [$1]="[$]fptools_version_of_ghc[_all]"
 698 ], $#, [2], [dnl
 699 [$1]="[$]fptools_version_of_ghc[_major]"
 700 [$2]="[$]fptools_version_of_ghc[_minor]"
 701 ], $#, [3], [dnl
 702 [$1]="[$]fptools_version_of_ghc[_major]"
 703 [$2]="[$]fptools_version_of_ghc[_minor]"
 704 [$3]="[$]fptools_version_of_ghc[_pl]"
 705 ], $#, [4], [dnl
 706 [$1]="[$]fptools_version_of_ghc[_all]"
 707 [$2]="[$]fptools_version_of_ghc[_major]"
 708 [$3]="[$]fptools_version_of_ghc[_minor]"
 709 [$4]="[$]fptools_version_of_ghc[_pl]"
 710 ])
 711 ])
 712 ])dnl
 713
 714
 715 dnl ** Map an arithmetic C type to a Haskell type.
 716 dnl    Based on autconf's AC_CHECK_SIZEOF.
 717
 718 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 719 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
 720 [changequote(<<, >>)dnl
 721 dnl The name to #define.
 722 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 723 dnl The cache variable name.
 724 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 725 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 726 changequote([, ])dnl
 727 AC_MSG_CHECKING(Haskell type for $1)
 728 AC_CACHE_VAL(AC_CV_NAME,
 729 [AC_CV_NAME_supported=yes
 730 fp_check_htype_save_cppflags="$CPPFLAGS"
 731 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 732 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
 733 #include <stddef.h>
 734
 735 #if HAVE_SYS_TYPES_H
 736 # include <sys/types.h>
 737 #endif
 738
 739 #if HAVE_UNISTD_H
 740 # include <unistd.h>
 741 #endif
 742
 743 #if HAVE_SYS_STAT_H
 744 # include <sys/stat.h>
 745 #endif
 746
 747 #if HAVE_FCNTL_H
 748 # include <fcntl.h>
 749 #endif
 750
 751 #if HAVE_SIGNAL_H
 752 # include <signal.h>
 753 #endif
 754
 755 #if HAVE_TIME_H
 756 # include <time.h>
 757 #endif
 758
 759 #if HAVE_TERMIOS_H
 760 # include <termios.h>
 761 #endif
 762
 763 #if HAVE_STRING_H
 764 # include <string.h>
 765 #endif
 766
 767 #if HAVE_CTYPE_H
 768 # include <ctype.h>
 769 #endif
 770
 771 #if defined(HAVE_GL_GL_H)
 772 # include <GL/gl.h>
 773 #elif defined(HAVE_OPENGL_GL_H)
 774 # include <OpenGL/gl.h>
 775 #endif
 776
 777 #if defined(HAVE_AL_ALC_H)
 778 # include <AL/alc.h>
 779 #elif defined(HAVE_OPENAL_ALC_H)
 780 # include <OpenAL/alc.h>
 781 #endif
 782
 783 #if HAVE_SYS_RESOURCE_H
 784 # include <sys/resource.h>
 785 #endif
 786
 787 typedef $1 testing;
 788
 789 main() {
 790   FILE *f=fopen("conftestval", "w");
 791   if (!f) exit(1);
 792   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 793     fprintf(f, "%s%d\n",
 794            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 795            sizeof(testing)*8);
 796   } else {
 797     fprintf(f,"%s\n",
 798            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 799            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 800   }
 801   fclose(f);
 802   exit(0);
 803 }]])],[AC_CV_NAME=`cat conftestval`],
 804 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 805 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])]) dnl
 806 CPPFLAGS="$fp_check_htype_save_cppflags"
 807 if test "$AC_CV_NAME_supported" = yes; then
 808   AC_MSG_RESULT($AC_CV_NAME)
 809   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 810 else
 811   AC_MSG_RESULT([not supported])
 812 fi
 813 undefine([AC_TYPE_NAME])dnl
 814 undefine([AC_CV_NAME])dnl
 815 undefine([AC_CV_NAME_supported])dnl
 816 ])
 817
 818
 819 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 820 # ---------------------------------------------------------------------------------
 821 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 822 # additional flexibility of specifying the PROLOGUE and BODY.
 823 AC_DEFUN([FP_CHECK_FUNC],
 824 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 825 AC_CACHE_CHECK([for $1], fp_func,
 826 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 827                 [AS_VAR_SET(fp_func, yes)],
 828                 [AS_VAR_SET(fp_func, no)])])
 829 AS_IF([test AS_VAR_GET(fp_func) = yes],
 830       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 831                 [Define to 1 if you have the `]$1[' function.]) $4],
 832       [$5])dnl
 833 AS_VAR_POPDEF([fp_func])dnl
 834 ])# FP_CHECK_FUNC
 835
 836
 837 # FP_GEN_DOCBOOK_XML
 838 # ------------------
 839 # Generates a DocBook XML V4.2 document in conftest.xml.
 840 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 841 [rm -f conftest.xml
 842 cat > conftest.xml << EOF
 843 <?xml version="1.0" encoding="iso-8859-1"?>
 844 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 845    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 846 <book id="test">
 847   <title>A DocBook Test Document</title>
 848   <chapter id="id-one">
 849     <title>A Chapter Title</title>
 850     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 851   </chapter>
 852   <chapter id="id-two">
 853     <title>Another Chapter Title</title>
 854     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 855   </chapter>
 856 </book>
 857 EOF
 858 ]) # FP_GEN_DOCBOOK_XML
 859
 860
 861 # FP_PROG_XSLTPROC
 862 # ----------------
 863 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 864 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 865 AC_DEFUN([FP_PROG_XSLTPROC],
 866 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 867 if test -z "$XsltprocCmd"; then
 868   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 869 fi
 870 ])# FP_PROG_XSLTPROC
 871
 872
 873 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 874 # ----------------------------
 875 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 876 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 877 # will be empty if none could be found.
 878 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 879 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 880 if test -n "$XsltprocCmd"; then
 881   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 882   [FP_GEN_DOCBOOK_XML
 883   fp_cv_dir_docbook_xsl=no
 884   for fp_var in $1; do
 885      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 886         fp_cv_dir_docbook_xsl=$fp_var
 887         break
 888      fi
 889   done
 890   rm -rf conftest*])
 891 fi
 892 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 893   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 894   DIR_DOCBOOK_XSL=
 895 else
 896   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 897 fi
 898 AC_SUBST([DIR_DOCBOOK_XSL])
 899 ])# FP_DIR_DOCBOOK_XSL
 900
 901
 902 # FP_PROG_XMLLINT
 903 # ----------------
 904 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 905 # xmllint. XmllintCmd is empty if xmllint could not be found.
 906 AC_DEFUN([FP_PROG_XMLLINT],
 907 [AC_PATH_PROG([XmllintCmd], [xmllint])
 908 if test -z "$XmllintCmd"; then
 909   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 910 fi
 911 ])# FP_PROG_XMLLINT
 912
 913
 914 # FP_CHECK_DOCBOOK_DTD
 915 # --------------------
 916 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 917 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 918 if test -n "$XmllintCmd"; then
 919   AC_MSG_CHECKING([for DocBook DTD])
 920   FP_GEN_DOCBOOK_XML
 921   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 922     AC_MSG_RESULT([ok])
 923   else
 924     AC_MSG_RESULT([failed])
 925     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 926     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 927   fi
 928   rm -rf conftest*
 929 fi
 930 ])# FP_CHECK_DOCBOOK_DTD
 931
 932
 933 # FP_GEN_FO
 934 # ------------------
 935 # Generates a formatting objects document in conftest.fo.
 936 AC_DEFUN([FP_GEN_FO],
 937 [rm -f conftest.fo
 938 cat > conftest.fo << EOF
 939 <?xml version="1.0"?>
 940 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 941   <fo:layout-master-set>
 942     <fo:simple-page-master master-name="blank">
 943       <fo:region-body/>
 944     </fo:simple-page-master>
 945   </fo:layout-master-set>
 946   <fo:page-sequence master-reference="blank">
 947     <fo:flow flow-name="xsl-region-body">
 948       <fo:block>
 949         Test!
 950       </fo:block>
 951     </fo:flow>
 952   </fo:page-sequence>
 953 </fo:root>
 954 EOF
 955 ]) # FP_GEN_FO
 956
 957
 958 # FP_PROG_FOP
 959 # -----------
 960 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 961 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 962 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 963 AC_DEFUN([FP_PROG_FOP],
 964 [AC_PATH_PROGS([FopCmd1], [fop])
 965 if test -n "$FopCmd1"; then
 966   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 967     [FP_GEN_FO
 968     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 969       fp_cv_fop_usability=yes
 970     else
 971       fp_cv_fop_usability=no
 972     fi
 973     rm -rf conftest*])
 974   if test x"$fp_cv_fop_usability" = xyes; then
 975      FopCmd=$FopCmd1
 976   fi
 977 fi
 978 if test -z "$FopCmd"; then
 979   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 980   FopCmd=$FopCmd2
 981 fi
 982 AC_SUBST([FopCmd])
 983 ])# FP_PROG_FOP
 984
 985
 986 # FP_PROG_FO_PROCESSOR
 987 # --------------------
 988 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 989 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 990 # PdfxmltexCmd.
 991 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 992 [AC_REQUIRE([FP_PROG_FOP])
 993 AC_PATH_PROG([XmltexCmd], [xmltex])
 994 AC_PATH_PROG([DvipsCmd], [dvips])
 995 if test -z "$FopCmd"; then
 996   if test -z "$XmltexCmd"; then
 997     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 998   else
 999     if test -z "$DvipsCmd"; then
1000       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
1001     fi
1002   fi
1003   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
1004   if test -z "$PdfxmltexCmd"; then
1005     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
1006   fi
1007 elif test -z "$XmltexCmd"; then
1008   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
1009 fi
1010 ])# FP_PROG_FO_PROCESSOR
1011
1012
1013 # FP_PROG_GHC_PKG
1014 # ----------------
1015 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
1016 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
1017 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
1018 AC_DEFUN([FP_PROG_GHC_PKG],
1019 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
1020 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
1021 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
1022   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
1023 else
1024   fp_cv_matching_ghc_pkg=no
1025 fi])
1026 if test x"$fp_cv_matching_ghc_pkg" = xno; then
1027   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
1028 else
1029   GhcPkgCmd=$fp_cv_matching_ghc_pkg
1030 fi])# FP_PROG_GHC_PKG
1031
1032
1033 # FP_CHECK_WIN32
1034 # --------------
1035 # If Windows is the target platform (e.g. MinGW/MSYS or Cygwin with
1036 # -mno-cygwin), the variable "is_win32" is set to "yes", otherwise (e.g. *nix
1037 # systems or plain Cygwin) it is set to "no".
1038 AC_DEFUN([FP_CHECK_WIN32],
1039 [AC_CACHE_CHECK([for Windows environment], [fp_cv_is_win32],
1040   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1041 #if !_WIN32
1042    syntax error;
1043 #endif
1044 ])], [fp_cv_is_win32=yes], [fp_cv_is_win32=no])])
1045 is_win32="$fp_cv_is_win32"[]dnl
1046 ])# FP_CHECK_WIN32
1047
1048
1049 # FP_PATH_X
1050 # ---------
1051 # Same as AC_PATH_X, but works even for broken Cygwins which try to include the
1052 # non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
1053 AC_DEFUN([FP_PATH_X],
1054 [AC_REQUIRE([FP_CHECK_WIN32])
1055 if test x"$is_win32" = xyes; then
1056   no_x=yes
1057 else
1058   AC_PATH_X
1059 fi
1060 ])# FP_PATH_X
1061
1062
1063 # FP_PATH_XTRA
1064 # ------------
1065 # Same as AC_PATH_XTRA, but works even for broken Cygwins which try to include
1066 # the non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
1067 AC_DEFUN([FP_PATH_XTRA],
1068 [AC_REQUIRE([FP_CHECK_WIN32])
1069 if test x"$is_win32" = xyes; then
1070   no_x=yes
1071 else
1072   AC_PATH_XTRA
1073 fi
1074 ])# FP_PATH_XTRA
1075
1076
1077 # FP_CHECK_GL_HELPER(LIBNAME, LIBS, INCLUDES, FUNCTION-BODY)
1078 # ----------------------------------------------------------
1079 # Try each library in LIBS to successfully link INCLUDES plus FUNCTION-BODY,
1080 # setting LIBNAME_CFLAGS and LIBNAME_LIBS to the corresponding values. Sets
1081 # no_LIBNAME to "yes" if no suitable library was found. (LIBNAME_CFLAGS0
1082 # contains the value of LIBNAME_CFLAGS without CPPFLAGS, and LIBNAME_LIBS0
1083 # contains the value of LIBNAME_LIBS without LDFLAGS, but these are only
1084 # used internally.)
1085 AC_DEFUN([FP_CHECK_GL_HELPER],
1086 [AC_CACHE_CHECK([for $1 library], [fp_cv_check_$1_lib],
1087   [fp_cv_check_$1_lib="no"
1088   fp_save_CPPFLAGS="$CPPFLAGS"
1089   CPPFLAGS="$CPPFLAGS ${$1_CFLAGS}"
1090   fp_save_LIBS="$LIBS"
1091   for fp_try_lib in $2; do
1092     # transform "-lfoo" to "foo.lib" when using cl
1093     if test x"$CC" = xcl; then
1094       fp_try_lib=`echo $fp_try_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
1095     fi
1096     LIBS="$fp_try_lib ${$1_LIBS} $fp_save_LIBS"
1097     AC_LINK_IFELSE([AC_LANG_PROGRAM([$3], [$4])], [fp_cv_check_$1_lib="$fp_try_lib ${$1_LIBS}"; break])
1098   done
1099   LIBS="$fp_save_LIBS"
1100   CPPFLAGS="$fp_save_CPPFLAGS"])
1101
1102   if test x"$fp_cv_check_$1_lib" = xno; then
1103     no_$1=yes
1104     $1_CFLAGS=
1105     $1_LIBS=
1106   else
1107     $1_CFLAGS0="${$1_CFLAGS}"
1108     $1_CFLAGS="$CPPFLAGS ${$1_CFLAGS0}"
1109     $1_LIBS0="$fp_cv_check_$1_lib"
1110     $1_LIBS="$LDFLAGS ${$1_LIBS0}"
1111   fi
1112 ])# FP_CHECK_GL_HELPER
1113
1114
1115 # FP_CHECK_GL
1116 # -----------
1117 AC_DEFUN([FP_CHECK_GL],
1118 [AC_REQUIRE([FP_PATH_X])
1119 AC_REQUIRE([AC_CANONICAL_TARGET])
1120
1121 AC_ARG_ENABLE([hopengl],
1122   [AC_HELP_STRING([--enable-hopengl],
1123     [build a Haskell binding for OpenGL (GL/GLU). On Mac OS X, use
1124      --enable-hopengl=x11 to use X11 instead of the "native" libraries.
1125      (default=no)])],
1126   [enable_opengl=$enableval], [enable_opengl=no])
1127
1128 if test x"$enable_opengl" = xno; then
1129    no_GL=yes
1130 else
1131   use_quartz_opengl=no
1132   case $target_os in
1133   darwin*)
1134     if test x"$enable_opengl" != xx11; then
1135       AC_DEFINE([USE_QUARTZ_OPENGL], [1],
1136                 [Define to 1 if native OpenGL should be used on Mac OS X])
1137       use_quartz_opengl=yes
1138     fi
1139     ;;
1140   esac
1141
1142   if test x"$use_quartz_opengl" != xyes; then
1143     AC_CHECK_LIB([m], [atan], [GL_LIBS="-lm $GL_LIBS"])
1144
1145     if test x"$no_x" != xyes; then
1146       test -n "$x_includes" && GL_CFLAGS="-I$x_includes $GL_CFLAGS"
1147       test -n "$x_libraries" && GL_LIBS="-L$x_libraries -lX11 $GL_LIBS"
1148     fi
1149
1150     FP_CHECK_GL_HELPER([GL], [-lGL -lopengl32], [@%:@include <GL/gl.h>], [glEnd()])
1151
1152     if test x"$no_GL" != xyes; then
1153       # Ugly: To get wglGetProcAddress on Windows, we have to link with
1154       # opengl32.dll, too, even when we are using Cygwin with X11.
1155       case "$GL_LIBS" in
1156         *-lopengl32*|*opengl32.lib*) ;;
1157         *) fp_save_LIBS="$LIBS"
1158            LIBS="$LIBS -lopengl32"
1159            AC_LINK_IFELSE([AC_LANG_PROGRAM([[@%:@include <GL/gl.h>]], [[glEnd()]])],
1160              [GL_LIBS="$GL_LIBS -lopengl32"; GL_LIBS0="$GL_LIBS0 -lopengl32"])
1161            LIBS="$fp_save_LIBS"
1162            ;;
1163       esac
1164     fi
1165   fi
1166 fi
1167
1168 AC_SUBST([GL_CFLAGS])
1169 AC_SUBST([GL_LIBS])
1170 ])# FP_CHECK_GL
1171
1172
1173 # FP_CHECK_GLU
1174 # ------------
1175 AC_DEFUN([FP_CHECK_GLU],
1176 [AC_REQUIRE([FP_CHECK_GL])dnl
1177 GLU_CFLAGS="$GL_CFLAGS0"
1178 GLU_LIBS="$GL_LIBS0"
1179
1180 if test x"$enable_opengl" = xno; then
1181    no_GLU=yes
1182 elif test x"$use_quartz_opengl" != xyes; then
1183   FP_CHECK_GL_HELPER([GLU], [-lglu32 -lGLU], [@%:@include <GL/glu.h>], [gluNewQuadric()])
1184 fi
1185
1186 AC_SUBST([GLU_CFLAGS])
1187 AC_SUBST([GLU_LIBS])
1188 ])# FP_CHECK_GLU
1189
1190
1191 # FP_CHECK_GLUT
1192 # -------------
1193 AC_DEFUN([FP_CHECK_GLUT],
1194 [AC_REQUIRE([FP_CHECK_GLU])
1195 FP_PATH_XTRA
1196
1197 if test x"$enable_opengl" = xno; then
1198    no_GLUT=yes
1199 elif test x"$use_quartz_opengl" != xyes; then
1200   GLUT_CFLAGS="$GLU_CFLAGS0"
1201   GLUT_LIBS="$GLU_LIBS0"
1202
1203   if test x"$no_x" != xyes; then
1204     GLUT_LIBS="$X_PRE_LIBS -lXmu -lXi $X_EXTRA_LIBS $GLUT_LIBS"
1205   fi
1206
1207   AC_CHECK_HEADERS([windows.h GL/glut.h])
1208   # Note 1: On Cygwin with X11, GL/GLU functions use the "normal" calling
1209   # convention, but GLUT functions use stdcall. To get this right, it is
1210   # necessary to include <windows.h> first.
1211   # Note 2: MinGW/MSYS comes without a GLUT header, so we use Cygwin's one in
1212   # that case.
1213   FP_CHECK_GL_HELPER([GLUT], [-lglut32 -lglut], [
1214 #if HAVE_WINDOWS_H
1215 #include <windows.h>
1216 #endif
1217 #if HAVE_GL_GLUT_H
1218 #include <GL/glut.h>
1219 #else
1220 #include "glut_local.h"
1221 #endif
1222     ], [glutMainLoop()])
1223 fi
1224
1225 AC_SUBST([GLUT_CFLAGS])
1226 AC_SUBST([GLUT_LIBS])
1227 ])# FP_CHECK_GLUT
1228
1229
1230 # FP_EMPTY_STRUCTS
1231 # ----------------
1232 # Define output variable SUPPORTS_EMPTY_STRUCTS if empty structs are accepted by
1233 # CC.
1234 dnl
1235 AC_DEFUN(FP_EMPTY_STRUCTS,
1236 [AC_CACHE_CHECK(empty struct support, fp_cv_empty_structs,
1237 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[typedef struct { /* empty */ } StgFoo;]],
1238 [[int i;]])],
1239 [fp_cv_empty_structs=yes],
1240 [fp_cv_empty_structs=no])])
1241 if test x"$fp_cv_empty_structs" = xyes; then
1242   AC_DEFINE([SUPPORTS_EMPTY_STRUCTS], [1], [Define to 1 if C compiler supports declaration of empty structure types.])
1243 fi
1244 ])
1245
1246
1247 # LocalWords:  fi