aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FP_EVAL_STDERR(COMMAND)
   8 # -----------------------
   9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  10 # into the file conftest.err and the exit status in the variable fp_status.
  11 AC_DEFUN([FP_EVAL_STDERR],
  12 [{ (eval $1) 2>conftest.er1
  13   fp_status=$?
  14   grep -v '^ *+' conftest.er1 >conftest.err
  15   rm -f conftest.er1
  16   (exit $fp_status); }[]dnl
  17 ])# FP_EVAL_STDERR
  18
  19
  20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
  21 # ---------------------------------------------------------------------
  22 # Check to see whether the compiler for the current language supports a
  23 # particular option.
  24 #
  25 # Implementation note: When given an unkown option, GCC issues an warning on
  26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
  27 # to check stderr *and* the exit value.
  28 #
  29 # Used by ghc.
  30 AC_DEFUN(FP_CHECK_FLAG,
  31 [AC_LANG_COMPILER_REQUIRE()dnl
  32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
  33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
  34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
  35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
  36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
  37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
  38 fp_save_flags="$fp_Flags"
  39 fp_Flags="$fp_Flags $1"
  40 fp_Cache=no
  41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  42   test -s conftest.err || fp_Cache=yes
  43 fi
  44 fp_Flags="$fp_save_flags"
  45 rm -f conftest.err conftest.$ac_ext])
  46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
  47 m4_popdef([fp_Cache])[]dnl
  48 m4_popdef([fp_Flags])[]dnl
  49 ])# FP_CHECK_FLAG
  50
  51
  52 # FP_PROG_CONTEXT_DIFF
  53 # --------------------
  54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  55 #
  56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  57 #
  58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  61 [echo foo > conftest1
  62 echo foo > conftest2
  63 fp_cv_context_diff=no
  64 for fp_var in '-C 1' '-c1'
  65 do
  66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  67     fp_cv_context_diff="diff $fp_var"
  68     break
  69   fi
  70 done])
  71 if test x"$fp_cv_context_diff" = xno; then
  72    AC_MSG_ERROR([cannot figure out how to do context diffs])
  73 fi
  74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  75 ])# FP_PROG_CONTEXT_DIFF
  76
  77
  78 # FP_DECL_ALTZONE
  79 # ---------------
  80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
  81 #
  82 # Used by base package.
  83 AC_DEFUN([FP_DECL_ALTZONE],
  84 [AC_REQUIRE([AC_HEADER_TIME])dnl
  85 AC_CHECK_HEADERS([sys/time.h])
  86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
  87 # include <sys/time.h>
  88 # include <time.h>
  89 #else
  90 # if HAVE_SYS_TIME_H
  91 #  include <sys/time.h>
  92 # else
  93 #  include <time.h>
  94 # endif
  95 #endif])
  96 ])# FP_DECL_ALTZONE
  97
  98
  99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
 100 # --------------------------------------------------------
 101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
 102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
 103 # cross-compilation, too.
 104 #
 105 # Implementation note: We are lazy and use an internal autoconf macro, but it
 106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
 107 # little risk.
 108 AC_DEFUN([FP_COMPUTE_INT],
 109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
 110 ])# FP_COMPUTE_INT
 111
 112
 113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
 114 # ------------------------------------------------------------------
 115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
 116 # given type. Defines ALIGNMENT_TYPE.
 117 AC_DEFUN([FP_CHECK_ALIGNMENT],
 118 [AS_LITERAL_IF([$1], [],
 119                [AC_FATAL([$0: requires literal arguments])])[]dnl
 120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
 121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
 122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
 123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
 124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
 125                  [fp_Cache],
 126                  [AC_INCLUDES_DEFAULT([$3])],
 127                  [AC_MSG_ERROR([cannot compute alignment ($1)
 128 See `config.log' for more details.], [77])])
 129 else
 130   fp_Cache=0
 131 fi])[]dnl
 132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 133 m4_popdef([fp_Cache])[]dnl
 134 ])# FP_CHECK_ALIGNMENT
 135
 136
 137 # FP_LEADING_UNDERSCORE
 138 # ---------------------
 139 # Test for determining whether symbol names have a leading underscore. We assume
 140 # that they _haven't_ if anything goes wrong. Sets the output variable
 141 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 142 #
 143 # Some nlist implementations seem to try to be compatible by ignoring a leading
 144 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 145 # checking for *no* leading underscore first. Sigh.  --SDM
 146 #
 147 # Similarly on OpenBSD, but this test doesn't help. -- dons
 148 AC_DEFUN([FP_LEADING_UNDERSCORE],
 149 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 150 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 151 # Hack!: nlist() under Digital UNIX insist on there being an _,
 152 # but symbol table listings shows none. What is going on here?!?
 153 #
 154 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 155 # the underscoredness of that "platform"
 156 case $HostPlatform in
 157 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 158   case $build in
 159     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 160     *) fptools_cv_leading_underscore=no ;;
 161   esac ;;
 162 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 163 *cygwin32) fptools_cv_leading_underscore=yes;;
 164 *mingw32) fptools_cv_leading_underscore=yes;;
 165 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 166 #include <nlist.h>
 167 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 168 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 169 #endif
 170
 171 int main(argc, argv)
 172 int argc;
 173 char **argv;
 174 {
 175 #ifdef HAVE_NLIST_H
 176     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 177         exit(1);
 178     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 179         exit(0);
 180 #endif
 181     exit(1);
 182 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 183 ;;
 184 esac]);
 185 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 186 if test x"$fptools_cv_leading_underscore" = xyes; then
 187    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 188 fi])# FP_LEADING_UNDERSCORE
 189
 190
 191 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 192 # ----------------------------------------------------------------------------------
 193 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 194 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 195 AC_DEFUN([FP_COMPARE_VERSIONS],
 196 [fp_version1=$1; fp_version2=$3
 197 fp_save_IFS=$IFS; IFS='.'
 198 while test x"$fp_version1" != x || test x"$fp_version2" != x
 199 do
 200
 201   set dummy $fp_version1; shift
 202   fp_num1=""
 203   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 204   test x"$fp_num1" = x && fp_num1="0"
 205   fp_version1="[$]*"
 206
 207   set dummy $fp_version2; shift
 208   fp_num2=""
 209   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 210   test x"$fp_num2" = x && fp_num2="0"
 211   fp_version2="[$]*"
 212
 213   test "$fp_num1" = "$fp_num2" || break;
 214 done
 215 IFS=$fp_save_IFS
 216 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 217 ])# FP_COMPARE_VERSIONS
 218
 219
 220 dnl
 221 dnl Check for GreenCard and version.
 222 dnl
 223 AC_DEFUN(FPTOOLS_GREENCARD,
 224 [
 225 AC_PATH_PROG(GreenCardCmd,greencard)
 226 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 227 changequote(, )dnl
 228 [if test x"$GreenCardCmd" != x; then
 229    fptools_cv_greencard_version="`$GreenCardCmd --version |
 230                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 231 else
 232    fptools_cv_greencard_version=""
 233 fi
 234 changequote([, ])dnl
 235 ])
 236 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 237   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 238 GreenCardVersion=$fptools_cv_greencard_version
 239 AC_SUBST(GreenCardVersion)
 240 ])
 241
 242 dnl
 243 dnl Check for Happy and version.  If we're building GHC, then we need
 244 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 245 dnl for a happy source tree and point the build system at that instead.
 246 dnl
 247 AC_DEFUN(FPTOOLS_HAPPY,
 248 [
 249 if test -d $srcdir/happy; then
 250    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
 251 else
 252    SrcTreeHappyCmd=""
 253 fi
 254 if test x"$UseSrcTreeHappy" = xYES; then
 255   if test x"$SrcTreeHappyCmd" != x; then
 256      HappyCmd=$SrcTreeHappyCmd
 257   else
 258      AC_MSG_ERROR([--enable-src-tree-happy given, but happy not found in source tree])
 259   fi
 260 else
 261   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
 262 fi
 263 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 264 changequote(, )dnl
 265 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
 266    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 267 elif test x"$HappyCmd" != x; then
 268    fptools_cv_happy_version="`$HappyCmd -v |
 269                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 270 else
 271    fptools_cv_happy_version="";
 272 fi;
 273 changequote([, ])dnl
 274 ])
 275 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
 276   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 277   [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 278 fi
 279 HappyVersion=$fptools_cv_happy_version;
 280 AC_SUBST(HappyVersion)
 281 ])
 282
 283 dnl
 284 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 285 dnl for a haddock source tree and point the build system at that instead.
 286 dnl
 287 AC_DEFUN(FPTOOLS_HADDOCK,
 288 [
 289 if test -d $srcdir/haddock; then
 290    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
 291 else
 292    SrcTreeHaddockCmd=""
 293 fi
 294 if test x"$UseSrcTreeHaddock" = xYES; then
 295   if test x"$SrcTreeHaddockCmd" != x; then
 296      HaddockCmd=$SrcTreeHaddockCmd
 297   else
 298      AC_MSG_ERROR([--enable-src-tree-haddock given, but haddock not found in source tree])
 299   fi
 300 else
 301   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
 302 fi
 303 dnl Darn, I forgot to make Haddock print out its version number when
 304 dnl invoked with -v.  We could try generating some HTML and grepping
 305 dnl through that to find the version number, but I think we'll make
 306 dnl do without it for now.
 307 ])
 308
 309 dnl
 310 dnl Check for Alex and version.  If we're building GHC, then we need
 311 dnl at least Alex version 2.0.  If there's no installed Alex, we look
 312 dnl for a alex source tree and point the build system at that instead.
 313 dnl
 314 AC_DEFUN(FPTOOLS_ALEX,
 315 [
 316 if test -d $srcdir/alex; then
 317    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
 318 else
 319    SrcTreeAlexCmd=""
 320 fi
 321 if test x"$UseSrcTreeAlex" = xYES; then
 322   if test x"$SrcTreeAlexCmd" != x; then
 323      AlexCmd=$SrcTreeAlexCmd
 324   else
 325      AC_MSG_ERROR([--enable-src-tree-alex given, but alex not found in source tree])
 326   fi
 327 else
 328   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
 329 fi
 330 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 331 changequote(, )dnl
 332 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
 333    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
 334 elif test x"$AlexCmd" != x; then
 335    fptools_cv_alex_version="`$AlexCmd -v |
 336                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 337 else
 338    fptools_cv_alex_version="";
 339 fi;
 340 changequote([, ])dnl
 341 ])
 342 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
 343   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
 344   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
 345 fi
 346 AlexVersion=$fptools_cv_alex_version;
 347 AC_SUBST(AlexVersion)
 348 ])
 349
 350
 351 # FP_PROG_LD
 352 # ----------
 353 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 354 # of ld. Exits if no ld can be found
 355 AC_DEFUN([FP_PROG_LD],
 356 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
 357 if test -z "$fp_prog_ld_raw"; then
 358   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 359 fi
 360 LdCmd=$fp_prog_ld_raw
 361 case $HostPlatform in
 362   *mingw32) if test x${OSTYPE} != xmsys; then
 363               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 364               AC_MSG_NOTICE([normalized ld command to $LdCmd])
 365             fi
 366             ;;
 367 esac
 368 AC_SUBST([LdCmd])
 369 ])# FP_PROG_LD
 370
 371
 372 # FP_PROG_LD_X
 373 # ------------
 374 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 375 # variable's value is empty.
 376 AC_DEFUN([FP_PROG_LD_X],
 377 [AC_REQUIRE([FP_PROG_LD])
 378 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 379 [echo 'foo() {}' > conftest.c
 380 ${CC-cc} -c conftest.c
 381 if ${LdCmd} -r -x -o conftest2.o conftest.o; then
 382    fp_cv_ld_x=yes
 383 else
 384    fp_cv_ld_x=no
 385 fi
 386 rm -rf conftest*])
 387 if test "$fp_cv_ld_x" = yes; then
 388   LdXFlag=-x
 389 else
 390   LdXFlag=
 391 fi
 392 AC_SUBST([LdXFlag])
 393 ])# FP_PROG_LD_X
 394
 395
 396 # FP_PROG_LD_IS_GNU
 397 # -----------------
 398 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 399 # GNU ld or not.
 400 AC_DEFUN([FP_PROG_LD_IS_GNU],
 401 [AC_REQUIRE([FP_PROG_LD])
 402 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 403 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 404   fp_cv_gnu_ld=yes
 405 else
 406   fp_cv_gnu_ld=no
 407 fi])
 408 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 409 ])# FP_PROG_LD_IS_GNU
 410
 411
 412 # FP_PROG_AR
 413 # ----------
 414 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 415 # version of it. Exits if no ar can be found
 416 AC_DEFUN([FP_PROG_AR],
 417 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 418 if test -z "$fp_prog_ar_raw"; then
 419   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 420 fi
 421 fp_prog_ar=$fp_prog_ar_raw
 422 case $HostPlatform in
 423   *mingw32) if test x${OSTYPE} != xmsys; then
 424               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 425               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 426             fi
 427             ;;
 428 esac
 429 ])# FP_PROG_AR
 430
 431
 432 # FP_PROG_AR_IS_GNU
 433 # -----------------
 434 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 435 AC_DEFUN([FP_PROG_AR_IS_GNU],
 436 [AC_REQUIRE([FP_PROG_AR])
 437 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 438 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 439   fp_cv_prog_ar_is_gnu=yes
 440 else
 441   fp_cv_prog_ar_is_gnu=no
 442 fi])
 443 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 444 ])# FP_PROG_AR_IS_GNU
 445
 446
 447 # FP_PROG_AR_ARGS
 448 # ---------------
 449 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 450 # to a non-Cygwin invocation of ar including these arguments.
 451 AC_DEFUN([FP_PROG_AR_ARGS],
 452 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 453 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 454 [
 455 # GNU ar needs special treatment: it appears to have problems with
 456 # object files with the same name if you use the 's' modifier, but
 457 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 458 if test $fp_prog_ar_is_gnu = yes; then
 459   fp_cv_prog_ar_args="q"
 460 else
 461   touch conftest.dummy
 462   for fp_var in clqsZ clqs cqs clq cq ; do
 463      rm -f conftest.a
 464      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 465         fp_cv_prog_ar_args=$fp_var
 466         break
 467      fi
 468   done
 469   rm -f conftest*
 470   if test -z "$fp_cv_prog_ar_args"; then
 471     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 472   fi
 473 fi])
 474 fp_prog_ar_args=$fp_cv_prog_ar_args
 475 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 476
 477 ])# FP_PROG_AR_ARGS
 478
 479
 480 # FP_PROG_AR_NEEDS_RANLIB
 481 # -----------------------
 482 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 483 # to ":" otherwise.
 484 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 485 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 486 AC_REQUIRE([FP_PROG_AR_ARGS])
 487 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 488 [if test $fp_prog_ar_is_gnu = yes; then
 489   fp_cv_prog_ar_needs_ranlib=no
 490 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 491   fp_cv_prog_ar_needs_ranlib=no
 492 else
 493   fp_cv_prog_ar_needs_ranlib=yes
 494 fi])
 495 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 496    AC_PROG_RANLIB
 497 else
 498   RANLIB=":"
 499   AC_SUBST([RANLIB])
 500 fi
 501 ])# FP_PROG_AR_NEEDS_RANLIB
 502
 503
 504 # FP_PROG_AR_SUPPORTS_INPUT
 505 # -------------------------
 506 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 507 # whether ar supports -input flag is supported or not.
 508 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 509 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 510 AC_REQUIRE([FP_PROG_AR_ARGS])
 511 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 512 [fp_cv_prog_ar_supports_input=no
 513 if test $fp_prog_ar_is_gnu = no; then
 514   rm -f conftest*
 515   touch conftest.lst
 516   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 517     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 518   fi
 519   rm -f conftest*
 520 fi])
 521 if test $fp_cv_prog_ar_supports_input = yes; then
 522     ArSupportsInput="-input"
 523 else
 524     ArSupportsInput=""
 525 fi
 526 AC_SUBST([ArSupportsInput])
 527 ])# FP_PROG_AR_SUPPORTS_INPUT
 528
 529
 530 dnl
 531 dnl AC_SHEBANG_PERL - can we she-bang perl?
 532 dnl
 533 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
 534 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 535 [echo "#!$PerlCmd"'
 536 exit $1;
 537 ' > conftest
 538 chmod u+x conftest
 539 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 540 if test $? -ne 69; then
 541    fptools_cv_shebang_perl=yes
 542 else
 543    fptools_cv_shebang_perl=no
 544 fi
 545 rm -f conftest
 546 ])])
 547
 548
 549 # FP_HAVE_GCC
 550 # -----------
 551 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 552 # output variables HaveGcc and GccVersion.
 553 AC_DEFUN([FP_HAVE_GCC],
 554 [AC_REQUIRE([AC_PROG_CC])
 555 AC_CACHE_CHECK([whether your gcc is OK], [fp_cv_have_gcc],
 556 [if test -z "$GCC"; then
 557   fp_cv_have_gcc='no'
 558   AC_MSG_WARN([You would be better off with gcc, perhaps it is already installed, but not in your PATH?])
 559 else
 560   fp_cv_have_gcc='yes'
 561   gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9]][[0-9]]*\)\.\([[0-9]][[0-9]]*\).*/\1\.\2/g' `"
 562   FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
 563     [AC_MSG_ERROR([Need at least gcc version 2.0 (2.95.3 recommend)])])
 564 fi])
 565 AC_SUBST([HaveGcc], [`echo $fp_cv_have_gcc | sed 'y/yesno/YESNO/'`])
 566 AC_SUBST([GccVersion], [`gcc --version | grep mingw | cut -f 3 -d ' '`])
 567 ])# FP_HAVE_GCC
 568
 569 AC_DEFUN([FP_MINGW_GCC],
 570 [
 571   case $HostOS_CPP in
 572     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 573              if $CC -v 2>&1 | grep mingw >/dev/null; then
 574                 AC_MSG_RESULT([yes])
 575              else
 576                 AC_MSG_RESULT([no])
 577                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 578              fi;;
 579     *) ;;
 580   esac
 581 ])
 582
 583 dnl Small feature test for perl version. Assumes PerlCmd
 584 dnl contains path to perl binary
 585 dnl
 586 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
 587 [$PerlCmd -v >conftest.out 2>&1
 588 if grep "version 5" conftest.out >/dev/null 2>&1; then
 589    :
 590 else
 591    if grep "v5.6" conftest.out >/dev/null 2>&1; then
 592       :
 593    else
 594       if grep "v5.8" conftest.out >/dev/null 2>&1; then
 595          :
 596       else
 597          if grep "version 6" conftest.out >/dev/null 2>&1; then
 598             :
 599          else
 600             echo "Your version of perl probably won't work."
 601          fi
 602       fi
 603    fi
 604 fi
 605 rm -fr conftest*
 606 ])
 607
 608
 609 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 610 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 611 # -----------------------------------------------------
 612 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 613 # of PROG-TO-CHECK-FOR when found.
 614 AC_DEFUN([FP_CHECK_PROG],
 615 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 616 )# FP_CHECK_PROC
 617
 618
 619 # FP_PROG_FIND
 620 # ------------
 621 # Find a non-WinDoze version of the "find" utility.
 622 AC_DEFUN([FP_PROG_FIND],
 623 [AC_PATH_PROG([fp_prog_find], [find])
 624 echo foo > conftest.txt
 625 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 626 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 627   # OK, looks like a real "find".
 628   FindCmd="$fp_prog_find"
 629 else
 630   # Found a poor WinDoze version of "find", ignore it.
 631   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 632   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 633 fi
 634 rm -f conftest.txt conftest.out
 635 AC_SUBST([FindCmd])[]dnl
 636 ])# FP_PROG_FIND
 637
 638
 639 dnl
 640 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 641 dnl values of the second argument to the result of running
 642 dnl the commands given by the third. It does not cache its
 643 dnl result, so it is suitable for checks which should be
 644 dnl run every time.
 645 dnl
 646 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
 647 [AC_MSG_CHECKING([$1])
 648  $3
 649  AC_MSG_RESULT([$][$2])
 650 ])
 651
 652 dnl
 653 dnl FPTOOLS_GHC_VERSION(version)
 654 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 655 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 656 dnl
 657 dnl Test for version of installed ghc.  Uses $GHC.
 658 dnl [original version pinched from c2hs]
 659 dnl
 660 AC_DEFUN(FPTOOLS_GHC_VERSION,
 661 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 662 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 663   cat conftestghc >&AS_MESSAGE_LOG_FD
 664 #Useless Use Of cat award...
 665   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 666   rm -fr conftest*
 667   if test "[$]fptools_version_of_ghc" = ""
 668   then
 669     fptools_version_of_ghc='unknown'
 670   fi
 671 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 672 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 673 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 674 #
 675 if test "[$]fptools_version_of_ghc[_pl]" = ""
 676 then
 677   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 678   fptools_version_of_ghc[_pl]="0"
 679 else
 680   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 681 fi
 682 #
 683 ifelse($#, [1], [dnl
 684 [$1]="[$]fptools_version_of_ghc[_all]"
 685 ], $#, [2], [dnl
 686 [$1]="[$]fptools_version_of_ghc[_major]"
 687 [$2]="[$]fptools_version_of_ghc[_minor]"
 688 ], $#, [3], [dnl
 689 [$1]="[$]fptools_version_of_ghc[_major]"
 690 [$2]="[$]fptools_version_of_ghc[_minor]"
 691 [$3]="[$]fptools_version_of_ghc[_pl]"
 692 ], $#, [4], [dnl
 693 [$1]="[$]fptools_version_of_ghc[_all]"
 694 [$2]="[$]fptools_version_of_ghc[_major]"
 695 [$3]="[$]fptools_version_of_ghc[_minor]"
 696 [$4]="[$]fptools_version_of_ghc[_pl]"
 697 ])
 698 ])
 699 ])dnl
 700
 701
 702 dnl ** Map an arithmetic C type to a Haskell type.
 703 dnl    Based on autconf's AC_CHECK_SIZEOF.
 704
 705 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
 706 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
 707 [changequote(<<, >>)dnl
 708 dnl The name to #define.
 709 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
 710 dnl The cache variable name.
 711 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
 712 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
 713 changequote([, ])dnl
 714 AC_MSG_CHECKING(Haskell type for $1)
 715 AC_CACHE_VAL(AC_CV_NAME,
 716 [AC_CV_NAME_supported=yes
 717 fp_check_htype_save_cppflags="$CPPFLAGS"
 718 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 719 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
 720 #include <stddef.h>
 721
 722 #if HAVE_SYS_TYPES_H
 723 # include <sys/types.h>
 724 #endif
 725
 726 #if HAVE_UNISTD_H
 727 # include <unistd.h>
 728 #endif
 729
 730 #if HAVE_SYS_STAT_H
 731 # include <sys/stat.h>
 732 #endif
 733
 734 #if HAVE_FCNTL_H
 735 # include <fcntl.h>
 736 #endif
 737
 738 #if HAVE_SIGNAL_H
 739 # include <signal.h>
 740 #endif
 741
 742 #if HAVE_TIME_H
 743 # include <time.h>
 744 #endif
 745
 746 #if HAVE_TERMIOS_H
 747 # include <termios.h>
 748 #endif
 749
 750 #if HAVE_STRING_H
 751 # include <string.h>
 752 #endif
 753
 754 #if HAVE_CTYPE_H
 755 # include <ctype.h>
 756 #endif
 757
 758 #if defined(HAVE_GL_GL_H)
 759 # include <GL/gl.h>
 760 #elif defined(HAVE_OPENGL_GL_H)
 761 # include <OpenGL/gl.h>
 762 #endif
 763
 764 #if defined(HAVE_AL_ALC_H)
 765 # include <AL/alc.h>
 766 #elif defined(HAVE_OPENAL_ALC_H)
 767 # include <OpenAL/alc.h>
 768 #endif
 769
 770 #if HAVE_SYS_RESOURCE_H
 771 # include <sys/resource.h>
 772 #endif
 773
 774 typedef $1 testing;
 775
 776 main() {
 777   FILE *f=fopen("conftestval", "w");
 778   if (!f) exit(1);
 779   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
 780     fprintf(f, "%s%d\n",
 781            ((testing)(-1) < (testing)0) ? "Int" : "Word",
 782            sizeof(testing)*8);
 783   } else {
 784     fprintf(f,"%s\n",
 785            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
 786            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
 787   }
 788   fclose(f);
 789   exit(0);
 790 }]])],[AC_CV_NAME=`cat conftestval`],
 791 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
 792 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])]) dnl
 793 CPPFLAGS="$fp_check_htype_save_cppflags"
 794 if test "$AC_CV_NAME_supported" = yes; then
 795   AC_MSG_RESULT($AC_CV_NAME)
 796   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
 797 else
 798   AC_MSG_RESULT([not supported])
 799 fi
 800 undefine([AC_TYPE_NAME])dnl
 801 undefine([AC_CV_NAME])dnl
 802 undefine([AC_CV_NAME_supported])dnl
 803 ])
 804
 805
 806 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 807 # ---------------------------------------------------------------------------------
 808 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 809 # additional flexibility of specifying the PROLOGUE and BODY.
 810 AC_DEFUN([FP_CHECK_FUNC],
 811 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 812 AC_CACHE_CHECK([for $1], fp_func,
 813 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 814                 [AS_VAR_SET(fp_func, yes)],
 815                 [AS_VAR_SET(fp_func, no)])])
 816 AS_IF([test AS_VAR_GET(fp_func) = yes],
 817       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 818                 [Define to 1 if you have the `]$1[' function.]) $4],
 819       [$5])dnl
 820 AS_VAR_POPDEF([fp_func])dnl
 821 ])# FP_CHECK_FUNC
 822
 823
 824 # FP_GEN_DOCBOOK_XML
 825 # ------------------
 826 # Generates a DocBook XML V4.2 document in conftest.xml.
 827 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 828 [rm -f conftest.xml
 829 cat > conftest.xml << EOF
 830 <?xml version="1.0" encoding="iso-8859-1"?>
 831 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 832    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 833 <book id="test">
 834   <title>A DocBook Test Document</title>
 835   <chapter id="id-one">
 836     <title>A Chapter Title</title>
 837     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 838   </chapter>
 839   <chapter id="id-two">
 840     <title>Another Chapter Title</title>
 841     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 842   </chapter>
 843 </book>
 844 EOF
 845 ]) # FP_GEN_DOCBOOK_XML
 846
 847
 848 # FP_PROG_XSLTPROC
 849 # ----------------
 850 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 851 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 852 AC_DEFUN([FP_PROG_XSLTPROC],
 853 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 854 if test -z "$XsltprocCmd"; then
 855   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 856 fi
 857 ])# FP_PROG_XSLTPROC
 858
 859
 860 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 861 # ----------------------------
 862 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 863 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 864 # will be empty if none could be found.
 865 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 866 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 867 if test -n "$XsltprocCmd"; then
 868   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 869   [FP_GEN_DOCBOOK_XML
 870   fp_cv_dir_docbook_xsl=no
 871   for fp_var in $1; do
 872      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 873         fp_cv_dir_docbook_xsl=$fp_var
 874         break
 875      fi
 876   done
 877   rm -rf conftest*])
 878 fi
 879 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 880   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 881   DIR_DOCBOOK_XSL=
 882 else
 883   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 884 fi
 885 AC_SUBST([DIR_DOCBOOK_XSL])
 886 ])# FP_DIR_DOCBOOK_XSL
 887
 888
 889 # FP_PROG_XMLLINT
 890 # ----------------
 891 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 892 # xmllint. XmllintCmd is empty if xmllint could not be found.
 893 AC_DEFUN([FP_PROG_XMLLINT],
 894 [AC_PATH_PROG([XmllintCmd], [xmllint])
 895 if test -z "$XmllintCmd"; then
 896   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 897 fi
 898 ])# FP_PROG_XMLLINT
 899
 900
 901 # FP_CHECK_DOCBOOK_DTD
 902 # --------------------
 903 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 904 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 905 if test -n "$XmllintCmd"; then
 906   AC_MSG_CHECKING([for DocBook DTD])
 907   FP_GEN_DOCBOOK_XML
 908   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 909     AC_MSG_RESULT([ok])
 910   else
 911     AC_MSG_RESULT([failed])
 912     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 913     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 914   fi
 915   rm -rf conftest*
 916 fi
 917 ])# FP_CHECK_DOCBOOK_DTD
 918
 919
 920 # FP_GEN_FO
 921 # ------------------
 922 # Generates a formatting objects document in conftest.fo.
 923 AC_DEFUN([FP_GEN_FO],
 924 [rm -f conftest.fo
 925 cat > conftest.fo << EOF
 926 <?xml version="1.0"?>
 927 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 928   <fo:layout-master-set>
 929     <fo:simple-page-master master-name="blank">
 930       <fo:region-body/>
 931     </fo:simple-page-master>
 932   </fo:layout-master-set>
 933   <fo:page-sequence master-reference="blank">
 934     <fo:flow flow-name="xsl-region-body">
 935       <fo:block>
 936         Test!
 937       </fo:block>
 938     </fo:flow>
 939   </fo:page-sequence>
 940 </fo:root>
 941 EOF
 942 ]) # FP_GEN_FO
 943
 944
 945 # FP_PROG_FOP
 946 # -----------
 947 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 948 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 949 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 950 AC_DEFUN([FP_PROG_FOP],
 951 [AC_PATH_PROGS([FopCmd1], [fop])
 952 if test -n "$FopCmd1"; then
 953   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 954     [FP_GEN_FO
 955     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 956       fp_cv_fop_usability=yes
 957     else
 958       fp_cv_fop_usability=no
 959     fi
 960     rm -rf conftest*])
 961   if test x"$fp_cv_fop_usability" = xyes; then
 962      FopCmd=$FopCmd1
 963   fi
 964 fi
 965 if test -z "$FopCmd"; then
 966   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 967   FopCmd=$FopCmd2
 968 fi
 969 AC_SUBST([FopCmd])
 970 ])# FP_PROG_FOP
 971
 972
 973 # FP_PROG_FO_PROCESSOR
 974 # --------------------
 975 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 976 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 977 # PdfxmltexCmd.
 978 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 979 [AC_REQUIRE([FP_PROG_FOP])
 980 AC_PATH_PROG([XmltexCmd], [xmltex])
 981 AC_PATH_PROG([DvipsCmd], [dvips])
 982 if test -z "$FopCmd"; then
 983   if test -z "$XmltexCmd"; then
 984     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 985   else
 986     if test -z "$DvipsCmd"; then
 987       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 988     fi
 989   fi
 990   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 991   if test -z "$PdfxmltexCmd"; then
 992     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 993   fi
 994 elif test -z "$XmltexCmd"; then
 995   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 996 fi
 997 ])# FP_PROG_FO_PROCESSOR
 998
 999
1000 # FP_PROG_GHC_PKG
1001 # ----------------
1002 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
1003 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
1004 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
1005 AC_DEFUN([FP_PROG_GHC_PKG],
1006 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
1007 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
1008 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
1009   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
1010 else
1011   fp_cv_matching_ghc_pkg=no
1012 fi])
1013 if test x"$fp_cv_matching_ghc_pkg" = xno; then
1014   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
1015 else
1016   GhcPkgCmd=$fp_cv_matching_ghc_pkg
1017 fi])# FP_PROG_GHC_PKG
1018
1019 # LocalWords:  fi