compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkDictFunId, mkDefaultMethodId,
  17         mkDictSelId,
  18
  19         mkDataConIds,
  20         mkRecordSelId,
  21         mkPrimOpId, mkFCallId,
  22
  23         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  24         mkUnpackCase, mkProductBox,
  25
  26         -- And some particular Ids; see below for why they are wired in
  27         wiredInIds, ghcPrimIds,
  28         unsafeCoerceId, realWorldPrimId, voidArgId, nullAddrId, seqId,
  29         lazyId, lazyIdUnfolding, lazyIdKey,
  30
  31         mkRuntimeErrorApp,
  32         rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID, rUNTIME_ERROR_ID,
  33         nON_EXHAUSTIVE_GUARDS_ERROR_ID, nO_METHOD_BINDING_ERROR_ID,
  34         pAT_ERROR_ID, eRROR_ID,
  35
  36         unsafeCoerceName
  37     ) where
  38
  39 #include "HsVersions.h"
  40
  41
  42 import BasicTypes       ( Arity, StrictnessMark(..), isMarkedUnboxed, isMarkedStrict )
  43 import Rules            ( mkSpecInfo )
  44 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  45                           realWorldStatePrimTy, addrPrimTy
  46                         )
  47 import TysWiredIn       ( charTy, mkListTy )
  48 import PrelRules        ( primOpRules )
  49 import Type             ( TyThing(..), mkForAllTy, tyVarsOfTypes, newTyConInstRhs, coreEqType,
  50                           PredType(..),
  51                           mkTopTvSubst, substTyVar )
  52 import TcGadt           ( gadtRefine, refineType, emptyRefinement )
  53 import HsBinds          ( ExprCoFn(..), isIdCoercion )
  54 import Coercion         ( mkSymCoercion, mkUnsafeCoercion,
  55                           splitNewTypeRepCo_maybe, isEqPred )
  56 import TcType           ( Type, ThetaType, mkDictTy, mkPredTys, mkPredTy,
  57                           mkTyConApp, mkTyVarTys, mkClassPred,
  58                           mkFunTys, mkFunTy, mkSigmaTy, tcSplitSigmaTy,
  59                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType,
  60                           tcSplitFunTys, tcSplitForAllTys, dataConsStupidTheta
  61                         )
  62 import CoreUtils        ( exprType, dataConOrigInstPat )
  63 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding )
  64 import Literal          ( nullAddrLit, mkStringLit )
  65 import TyCon            ( TyCon, isNewTyCon, tyConDataCons, FieldLabel,
  66                           tyConStupidTheta, isProductTyCon, isDataTyCon, isRecursiveTyCon,
  67                           newTyConCo, tyConArity )
  68 import Class            ( Class, classTyCon, classSelIds )
  69 import Var              ( Id, TyVar, Var, setIdType, mkCoVar, mkWildCoVar )
  70 import VarSet           ( isEmptyVarSet, subVarSet, varSetElems )
  71 import Name             ( mkFCallName, mkWiredInName, Name, BuiltInSyntax(..),
  72                           mkSysTvName )
  73 import OccName          ( mkOccNameFS, varName )
  74 import PrimOp           ( PrimOp, primOpSig, primOpOcc, primOpTag )
  75 import ForeignCall      ( ForeignCall )
  76 import DataCon          ( DataCon, DataConIds(..), dataConTyCon, dataConUnivTyVars,
  77                           dataConFieldLabels, dataConRepArity, dataConResTys,
  78                           dataConRepArgTys, dataConRepType, dataConFullSig,
  79                           dataConSig, dataConStrictMarks, dataConExStricts,
  80                           splitProductType, isVanillaDataCon, dataConFieldType,
  81                           dataConInstOrigArgTys, deepSplitProductType
  82                         )
  83 import Id               ( idType, mkGlobalId, mkVanillaGlobal, mkSysLocal,
  84                           mkTemplateLocals, mkTemplateLocalsNum, mkExportedLocalId,
  85                           mkTemplateLocal, idName, mkWildId
  86                         )
  87 import IdInfo           ( IdInfo, noCafIdInfo,  setUnfoldingInfo,
  88                           setArityInfo, setSpecInfo, setCafInfo,
  89                           setAllStrictnessInfo, vanillaIdInfo,
  90                           GlobalIdDetails(..), CafInfo(..)
  91                         )
  92 import NewDemand        ( mkStrictSig, DmdResult(..),
  93                           mkTopDmdType, topDmd, evalDmd, lazyDmd, retCPR,
  94                           Demand(..), Demands(..) )
  95 import DmdAnal          ( dmdAnalTopRhs )
  96 import CoreSyn
  97 import Unique           ( mkBuiltinUnique, mkPrimOpIdUnique )
  98 import Maybes
  99 import PrelNames
 100 import Util             ( dropList, isSingleton )
 101 import Outputable
 102 import FastString
 103 import ListSetOps       ( assoc, minusList )
 104 \end{code}
 105
 106 %************************************************************************
 107 %*                                                                      *
 108 \subsection{Wired in Ids}
 109 %*                                                                      *
 110 %************************************************************************
 111
 112 \begin{code}
 113 wiredInIds
 114   = [   -- These error-y things are wired in because we don't yet have
 115         -- a way to express in an interface file that the result type variable
 116         -- is 'open'; that is can be unified with an unboxed type
 117         --
 118         -- [The interface file format now carry such information, but there's
 119         -- no way yet of expressing at the definition site for these
 120         -- error-reporting functions that they have an 'open'
 121         -- result type. -- sof 1/99]
 122
 123     eRROR_ID,   -- This one isn't used anywhere else in the compiler
 124                 -- But we still need it in wiredInIds so that when GHC
 125                 -- compiles a program that mentions 'error' we don't
 126                 -- import its type from the interface file; we just get
 127                 -- the Id defined here.  Which has an 'open-tyvar' type.
 128
 129     rUNTIME_ERROR_ID,
 130     iRREFUT_PAT_ERROR_ID,
 131     nON_EXHAUSTIVE_GUARDS_ERROR_ID,
 132     nO_METHOD_BINDING_ERROR_ID,
 133     pAT_ERROR_ID,
 134     rEC_CON_ERROR_ID,
 135
 136     lazyId
 137     ] ++ ghcPrimIds
 138
 139 -- These Ids are exported from GHC.Prim
 140 ghcPrimIds
 141   = [   -- These can't be defined in Haskell, but they have
 142         -- perfectly reasonable unfoldings in Core
 143     realWorldPrimId,
 144     unsafeCoerceId,
 145     nullAddrId,
 146     seqId
 147     ]
 148 \end{code}
 149
 150 %************************************************************************
 151 %*                                                                      *
 152 \subsection{Data constructors}
 153 %*                                                                      *
 154 %************************************************************************
 155
 156 The wrapper for a constructor is an ordinary top-level binding that evaluates
 157 any strict args, unboxes any args that are going to be flattened, and calls
 158 the worker.
 159
 160 We're going to build a constructor that looks like:
 161
 162         data (Data a, C b) =>  T a b = T1 !a !Int b
 163
 164         T1 = /\ a b ->
 165              \d1::Data a, d2::C b ->
 166              \p q r -> case p of { p ->
 167                        case q of { q ->
 168                        Con T1 [a,b] [p,q,r]}}
 169
 170 Notice that
 171
 172 * d2 is thrown away --- a context in a data decl is used to make sure
 173   one *could* construct dictionaries at the site the constructor
 174   is used, but the dictionary isn't actually used.
 175
 176 * We have to check that we can construct Data dictionaries for
 177   the types a and Int.  Once we've done that we can throw d1 away too.
 178
 179 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 180   all that matters is that the arguments are evaluated.  "seq" is
 181   very careful to preserve evaluation order, which we don't need
 182   to be here.
 183
 184   You might think that we could simply give constructors some strictness
 185   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 186   But we don't do that because in the case of primops and functions strictness
 187   is a *property* not a *requirement*.  In the case of constructors we need to
 188   do something active to evaluate the argument.
 189
 190   Making an explicit case expression allows the simplifier to eliminate
 191   it in the (common) case where the constructor arg is already evaluated.
 192
 193
 194 \begin{code}
 195 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 196 mkDataConIds wrap_name wkr_name data_con
 197   | isNewTyCon tycon
 198   = NewDC nt_wrap_id
 199
 200   | any isMarkedStrict all_strict_marks         -- Algebraic, needs wrapper
 201     || not (null eq_spec)
 202   = AlgDC (Just alg_wrap_id) wrk_id
 203
 204   | otherwise                                   -- Algebraic, no wrapper
 205   = AlgDC Nothing wrk_id
 206   where
 207     (univ_tvs, ex_tvs, eq_spec, theta, orig_arg_tys) = dataConFullSig data_con
 208     tycon = dataConTyCon data_con
 209
 210         ----------- Wrapper --------------
 211         -- We used to include the stupid theta in the wrapper's args
 212         -- but now we don't.  Instead the type checker just injects these
 213         -- extra constraints where necessary.
 214     wrap_tvs = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 215     subst          = mkTopTvSubst eq_spec
 216     dict_tys       = mkPredTys theta
 217     result_ty_args = map (substTyVar subst) univ_tvs
 218     result_ty      = mkTyConApp tycon result_ty_args
 219     wrap_ty        = mkForAllTys wrap_tvs $ mkFunTys dict_tys $
 220                      mkFunTys orig_arg_tys $ result_ty
 221         -- NB: watch out here if you allow user-written equality
 222         --     constraints in data constructor signatures
 223
 224         ----------- Worker (algebraic data types only) --------------
 225         -- The *worker* for the data constructor is the function that
 226         -- takes the representation arguments and builds the constructor.
 227     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 228                         (dataConRepType data_con) wkr_info
 229
 230     wkr_arity = dataConRepArity data_con
 231     wkr_info  = noCafIdInfo
 232                 `setArityInfo`          wkr_arity
 233                 `setAllStrictnessInfo`  Just wkr_sig
 234                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 235                                                         -- even if arity = 0
 236
 237     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 238         -- Notice that we do *not* say the worker is strict
 239         -- even if the data constructor is declared strict
 240         --      e.g.    data T = MkT !(Int,Int)
 241         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 242         -- expresssions that do the evals) but the *worker* itself is not.
 243         -- If we pretend it is strict then when we see
 244         --      case x of y -> $wMkT y
 245         -- the simplifier thinks that y is "sure to be evaluated" (because
 246         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 247         --
 248         -- When the simplifer sees a pattern
 249         --      case e of MkT x -> ...
 250         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 251         -- but that's fine... dataConRepStrictness comes from the data con
 252         -- not from the worker Id.
 253
 254     cpr_info | isProductTyCon tycon &&
 255                isDataTyCon tycon    &&
 256                wkr_arity > 0        &&
 257                wkr_arity <= mAX_CPR_SIZE        = retCPR
 258              | otherwise                        = TopRes
 259         -- RetCPR is only true for products that are real data types;
 260         -- that is, not unboxed tuples or [non-recursive] newtypes
 261
 262         ----------- Wrappers for newtypes --------------
 263     nt_wrap_id   = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty nt_wrap_info
 264     nt_wrap_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 265                   `setArityInfo` 1      -- Arity 1
 266                   `setUnfoldingInfo`     newtype_unf
 267     newtype_unf  = ASSERT( isVanillaDataCon data_con &&
 268                            isSingleton orig_arg_tys )
 269                    -- No existentials on a newtype, but it can have a context
 270                    -- e.g.      newtype Eq a => T a = MkT (...)
 271                    mkCompulsoryUnfolding $
 272                    mkLams wrap_tvs $ Lam id_arg1 $
 273                    wrapNewTypeBody tycon result_ty_args
 274                        (Var id_arg1)
 275
 276     id_arg1 = mkTemplateLocal 1 (head orig_arg_tys)
 277
 278         ----------- Wrappers for algebraic data types --------------
 279     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 280     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 281                     `setArityInfo`         alg_arity
 282                         -- It's important to specify the arity, so that partial
 283                         -- applications are treated as values
 284                     `setUnfoldingInfo`     alg_unf
 285                     `setAllStrictnessInfo` Just wrap_sig
 286
 287     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 288     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 289     arg_dmds = map mk_dmd all_strict_marks
 290     mk_dmd str | isMarkedStrict str = evalDmd
 291                | otherwise          = lazyDmd
 292         -- The Cpr info can be important inside INLINE rhss, where the
 293         -- wrapper constructor isn't inlined.
 294         -- And the argument strictness can be important too; we
 295         -- may not inline a contructor when it is partially applied.
 296         -- For example:
 297         --      data W = C !Int !Int !Int
 298         --      ...(let w = C x in ...(w p q)...)...
 299         -- we want to see that w is strict in its two arguments
 300
 301     alg_unf = mkTopUnfolding $ Note InlineMe $
 302               mkLams wrap_tvs $
 303               mkLams dict_args $ mkLams id_args $
 304               foldr mk_case con_app
 305                     (zip (dict_args ++ id_args) all_strict_marks)
 306                     i3 []
 307
 308     con_app i rep_ids = Var wrk_id `mkTyApps`  result_ty_args
 309                                    `mkVarApps` ex_tvs
 310                                    `mkTyApps`  map snd eq_spec
 311                                    `mkVarApps` reverse rep_ids
 312
 313     (dict_args,i2) = mkLocals 1  dict_tys
 314     (id_args,i3)   = mkLocals i2 orig_arg_tys
 315     alg_arity      = i3-1
 316
 317     mk_case
 318            :: (Id, StrictnessMark)      -- Arg, strictness
 319            -> (Int -> [Id] -> CoreExpr) -- Body
 320            -> Int                       -- Next rep arg id
 321            -> [Id]                      -- Rep args so far, reversed
 322            -> CoreExpr
 323     mk_case (arg,strict) body i rep_args
 324           = case strict of
 325                 NotMarkedStrict -> body i (arg:rep_args)
 326                 MarkedStrict
 327                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 328                    | otherwise ->
 329                         Case (Var arg) arg result_ty [(DEFAULT,[], body i (arg:rep_args))]
 330
 331                 MarkedUnboxed
 332                    -> unboxProduct i (Var arg) (idType arg) the_body result_ty
 333                       where
 334                         the_body i con_args = body i (reverse con_args ++ rep_args)
 335
 336 mAX_CPR_SIZE :: Arity
 337 mAX_CPR_SIZE = 10
 338 -- We do not treat very big tuples as CPR-ish:
 339 --      a) for a start we get into trouble because there aren't
 340 --         "enough" unboxed tuple types (a tiresome restriction,
 341 --         but hard to fix),
 342 --      b) more importantly, big unboxed tuples get returned mainly
 343 --         on the stack, and are often then allocated in the heap
 344 --         by the caller.  So doing CPR for them may in fact make
 345 --         things worse.
 346
 347 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 348                where
 349                  n = length tys
 350 \end{code}
 351
 352
 353 %************************************************************************
 354 %*                                                                      *
 355 \subsection{Record selectors}
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 We're going to build a record selector unfolding that looks like this:
 360
 361         data T a b c = T1 { ..., op :: a, ...}
 362                      | T2 { ..., op :: a, ...}
 363                      | T3
 364
 365         sel = /\ a b c -> \ d -> case d of
 366                                     T1 ... x ... -> x
 367                                     T2 ... x ... -> x
 368                                     other        -> error "..."
 369
 370 Similarly for newtypes
 371
 372         newtype N a = MkN { unN :: a->a }
 373
 374         unN :: N a -> a -> a
 375         unN n = coerce (a->a) n
 376
 377 We need to take a little care if the field has a polymorphic type:
 378
 379         data R = R { f :: forall a. a->a }
 380
 381 Then we want
 382
 383         f :: forall a. R -> a -> a
 384         f = /\ a \ r = case r of
 385                           R f -> f a
 386
 387 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 388 problems at call sites)
 389
 390 Similarly for (recursive) newtypes
 391
 392         newtype N = MkN { unN :: forall a. a->a }
 393
 394         unN :: forall b. N -> b -> b
 395         unN = /\b -> \n:N -> (coerce (forall a. a->a) n)
 396
 397
 398 Note [Naughty record selectors]
 399 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 400 A "naughty" field is one for which we can't define a record
 401 selector, because an existential type variable would escape.  For example:
 402         data T = forall a. MkT { x,y::a }
 403 We obviously can't define
 404         x (MkT v _) = v
 405 Nevertheless we *do* put a RecordSelId into the type environment
 406 so that if the user tries to use 'x' as a selector we can bleat
 407 helpfully, rather than saying unhelpfully that 'x' is not in scope.
 408 Hence the sel_naughty flag, to identify record selectors that don't really exist.
 409
 410 In general, a field is naughty if its type mentions a type variable that
 411 isn't in the result type of the constructor.
 412
 413 Note [GADT record selectors]
 414 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 415 For GADTs, we require that all constructors with a common field 'f' have the same
 416 result type (modulo alpha conversion).  [Checked in TcTyClsDecls.checkValidTyCon]
 417 E.g.
 418         data T where
 419           T1 { f :: a } :: T [a]
 420           T2 { f :: a, y :: b  } :: T [a]
 421 and now the selector takes that type as its argument:
 422         f :: forall a. T [a] -> a
 423         f t = case t of
 424                 T1 { f = v } -> v
 425                 T2 { f = v } -> v
 426 Note the forall'd tyvars of the selector are just the free tyvars
 427 of the result type; there may be other tyvars in the constructor's
 428 type (e.g. 'b' in T2).
 429
 430 \begin{code}
 431
 432 -- Steps for handling "naughty" vs "non-naughty" selectors:
 433 --  1. Determine naughtiness by comparing field type vs result type
 434 --  2. Install naughty ones with selector_ty of type _|_ and fill in mzero for info
 435 --  3. If it's not naughty, do the normal plan.
 436
 437 mkRecordSelId :: TyCon -> FieldLabel -> Id
 438 mkRecordSelId tycon field_label
 439         -- Assumes that all fields with the same field label have the same type
 440   | is_naughty = naughty_id
 441   | otherwise  = sel_id
 442   where
 443     is_naughty = not (tyVarsOfType field_ty `subVarSet` res_tv_set)
 444     sel_id_details = RecordSelId tycon field_label is_naughty
 445
 446     -- Escapist case here for naughty construcotrs
 447     -- We give it no IdInfo, and a type of forall a.a (never looked at)
 448     naughty_id = mkGlobalId sel_id_details field_label forall_a_a noCafIdInfo
 449     forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 450
 451     -- Normal case starts here
 452     sel_id = mkGlobalId sel_id_details field_label selector_ty info
 453     data_cons         = tyConDataCons tycon
 454     data_cons_w_field = filter has_field data_cons      -- Can't be empty!
 455     has_field con     = field_label `elem` dataConFieldLabels con
 456
 457     con1        = head data_cons_w_field
 458     res_tys     = dataConResTys con1
 459     res_tv_set  = tyVarsOfTypes res_tys
 460     res_tvs     = varSetElems res_tv_set
 461     data_ty     = mkTyConApp tycon res_tys
 462     field_ty    = dataConFieldType con1 field_label
 463
 464         -- *Very* tiresomely, the selectors are (unnecessarily!) overloaded over
 465         -- just the dictionaries in the types of the constructors that contain
 466         -- the relevant field.  [The Report says that pattern matching on a
 467         -- constructor gives the same constraints as applying it.]  Urgh.
 468         --
 469         -- However, not all data cons have all constraints (because of
 470         -- BuildTyCl.mkDataConStupidTheta).  So we need to find all the data cons
 471         -- involved in the pattern match and take the union of their constraints.
 472     stupid_dict_tys = mkPredTys (dataConsStupidTheta data_cons_w_field)
 473     n_stupid_dicts  = length stupid_dict_tys
 474
 475     (field_tyvars,pre_field_theta,field_tau) = tcSplitSigmaTy field_ty
 476
 477     field_theta  = filter (not . isEqPred) pre_field_theta
 478     field_dict_tys                       = mkPredTys field_theta
 479     n_field_dict_tys                     = length field_dict_tys
 480         -- If the field has a universally quantified type we have to
 481         -- be a bit careful.  Suppose we have
 482         --      data R = R { op :: forall a. Foo a => a -> a }
 483         -- Then we can't give op the type
 484         --      op :: R -> forall a. Foo a => a -> a
 485         -- because the typechecker doesn't understand foralls to the
 486         -- right of an arrow.  The "right" type to give it is
 487         --      op :: forall a. Foo a => R -> a -> a
 488         -- But then we must generate the right unfolding too:
 489         --      op = /\a -> \dfoo -> \ r ->
 490         --           case r of
 491         --              R op -> op a dfoo
 492         -- Note that this is exactly the type we'd infer from a user defn
 493         --      op (R op) = op
 494
 495     selector_ty :: Type
 496     selector_ty  = mkForAllTys res_tvs $ mkForAllTys field_tyvars $
 497                    mkFunTys stupid_dict_tys  $  mkFunTys field_dict_tys $
 498                    mkFunTy data_ty field_tau
 499
 500     arity = 1 + n_stupid_dicts + n_field_dict_tys
 501
 502     (strict_sig, rhs_w_str) = dmdAnalTopRhs sel_rhs
 503         -- Use the demand analyser to work out strictness.
 504         -- With all this unpackery it's not easy!
 505
 506     info = noCafIdInfo
 507            `setCafInfo`           caf_info
 508            `setArityInfo`         arity
 509            `setUnfoldingInfo`     mkTopUnfolding rhs_w_str
 510            `setAllStrictnessInfo` Just strict_sig
 511
 512         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 513         -- almost always empty.  Also note that we use max_dict_tys
 514         -- rather than n_dict_tys, because the latter gives an infinite loop:
 515         -- n_dict tys depends on the_alts, which depens on arg_ids, which depends
 516         -- on arity, which depends on n_dict tys.  Sigh!  Mega sigh!
 517     stupid_dict_ids  = mkTemplateLocalsNum 1 stupid_dict_tys
 518     max_stupid_dicts = length (tyConStupidTheta tycon)
 519     field_dict_base  = max_stupid_dicts + 1
 520     field_dict_ids   = mkTemplateLocalsNum field_dict_base field_dict_tys
 521     dict_id_base     = field_dict_base + n_field_dict_tys
 522     data_id          = mkTemplateLocal dict_id_base data_ty
 523     arg_base         = dict_id_base + 1
 524
 525     the_alts :: [CoreAlt]
 526     the_alts   = map mk_alt data_cons_w_field   -- Already sorted by data-con
 527     no_default = length data_cons == length data_cons_w_field   -- No default needed
 528
 529     default_alt | no_default = []
 530                 | otherwise  = [(DEFAULT, [], error_expr)]
 531
 532         -- The default branch may have CAF refs, because it calls recSelError etc.
 533     caf_info    | no_default = NoCafRefs
 534                 | otherwise  = MayHaveCafRefs
 535
 536     sel_rhs = mkLams res_tvs $ mkLams field_tyvars $
 537               mkLams stupid_dict_ids $ mkLams field_dict_ids $
 538               Lam data_id     $ mk_result sel_body
 539
 540         -- NB: A newtype always has a vanilla DataCon; no existentials etc
 541         --     res_tys will simply be the dataConUnivTyVars
 542     sel_body | isNewTyCon tycon = unwrapNewTypeBody tycon res_tys (Var data_id)
 543              | otherwise        = Case (Var data_id) data_id field_ty (default_alt ++ the_alts)
 544
 545     mk_result poly_result = mkVarApps (mkVarApps poly_result field_tyvars) field_dict_ids
 546         -- We pull the field lambdas to the top, so we need to
 547         -- apply them in the body.  For example:
 548         --      data T = MkT { foo :: forall a. a->a }
 549         --
 550         --      foo :: forall a. T -> a -> a
 551         --      foo = /\a. \t:T. case t of { MkT f -> f a }
 552
 553     mk_alt data_con
 554       =         -- In the non-vanilla case, the pattern must bind type variables and
 555                 -- the context stuff; hence the arg_prefix binding below
 556           mkReboxingAlt uniqs data_con (arg_prefix ++ arg_ids) rhs
 557       where
 558         -- TODO: this is *not* right; Orig vs Rep tys
 559         (arg_prefix, arg_ids)
 560            | isVanillaDataCon data_con          -- Instantiate from commmon base
 561            = ([], mkTemplateLocalsNum arg_base (dataConInstOrigArgTys data_con res_tys))
 562            | otherwise          -- The case pattern binds type variables, which are used
 563                                 -- in the types of the arguments of the pattern
 564            = (ex_tvs ++ co_tvs ++ dict_vs, field_vs)
 565
 566         (ex_tvs, co_tvs, arg_vs) = dataConOrigInstPat uniqs' data_con res_tys
 567         (dict_vs, field_vs) = splitAt (length dc_theta) arg_vs
 568
 569         (_, pre_dc_theta, dc_arg_tys) = dataConSig data_con
 570         dc_theta  = filter (not . isEqPred) pre_dc_theta
 571
 572         arg_base' = arg_base + length dc_theta
 573
 574         unpack_base = arg_base' + length dc_arg_tys
 575
 576         uniq_list = map mkBuiltinUnique [unpack_base..]
 577
 578         Succeeded refinement = gadtRefine emptyRefinement ex_tvs co_tvs
 579         (co_fn, _)      = refineType refinement (idType the_arg_id)
 580
 581         rhs = perform_co co_fn (Var the_arg_id)
 582
 583         perform_co (ExprCoFn co) expr = Cast expr co
 584         perform_co id_co expr = ASSERT(isIdCoercion id_co) expr
 585
 586           -- split the uniq_list into two
 587         uniqs  = takeHalf uniq_list
 588         uniqs' = takeHalf (drop 1 uniq_list)
 589
 590         takeHalf [] = []
 591         takeHalf (h:_:t) = h:(takeHalf t)
 592         takeHalf (h:t) = [h]
 593
 594         the_arg_id  = assoc "mkRecordSelId:mk_alt" (field_lbls `zip` arg_ids) field_label
 595         field_lbls  = dataConFieldLabels data_con
 596
 597     error_expr = mkRuntimeErrorApp rEC_SEL_ERROR_ID field_tau full_msg
 598     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 599
 600 -- unbox a product type...
 601 -- we will recurse into newtypes, casting along the way, and unbox at the
 602 -- first product data constructor we find. e.g.
 603 --
 604 --   data PairInt = PairInt Int Int
 605 --   newtype S = MkS PairInt
 606 --   newtype T = MkT S
 607 --
 608 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 609 -- ids, we get (modulo int passing)
 610 --
 611 --   case (e `cast` (sym CoT)) `cast` (sym CoS) of
 612 --     PairInt a b -> body [a,b]
 613 --
 614 -- The Ints passed around are just for creating fresh locals
 615 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> Type -> CoreExpr
 616 unboxProduct i arg arg_ty body res_ty
 617   = result
 618   where
 619     result = mkUnpackCase the_id arg arg_ty con_args boxing_con rhs
 620     (tycon, tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 621     ([the_id], i') = mkLocals i [arg_ty]
 622     (con_args, i'') = mkLocals i' tys
 623     rhs = body i'' con_args
 624
 625 mkUnpackCase ::  Id -> CoreExpr -> Type -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 626 -- (mkUnpackCase x e args Con body)
 627 --      returns
 628 -- case (e `cast` ...) of bndr { Con args -> body }
 629 --
 630 -- the type of the bndr passed in is irrelevent
 631 mkUnpackCase bndr arg arg_ty unpk_args boxing_con body
 632   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 633   where
 634   (cast_arg, bndr_ty) = go (idType bndr) arg
 635   go ty arg
 636     | res@(tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 637     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 638     = go (newTyConInstRhs tycon tycon_args)
 639          (unwrapNewTypeBody tycon tycon_args arg)
 640     | otherwise = (arg, ty)
 641
 642 -- ...and the dual
 643 reboxProduct :: [Unique]     -- uniques to create new local binders
 644              -> Type         -- type of product to box
 645              -> ([Unique],   -- remaining uniques
 646                  CoreExpr,   -- boxed product
 647                  [Id])       -- Ids being boxed into product
 648 reboxProduct us ty
 649   = let
 650         (tycon, tycon_args, pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 651
 652         us' = dropList con_arg_tys us
 653
 654         arg_ids  = zipWith (mkSysLocal FSLIT("rb")) us con_arg_tys
 655
 656         bind_rhs = mkProductBox arg_ids ty
 657
 658     in
 659       (us', bind_rhs, arg_ids)
 660
 661 mkProductBox :: [Id] -> Type -> CoreExpr
 662 mkProductBox arg_ids ty
 663   = result_expr
 664   where
 665     (tycon, tycon_args, pack_con, con_arg_tys) = splitProductType "mkProductBox" ty
 666
 667     result_expr
 668       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 669       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 670       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 671
 672     wrap expr = wrapNewTypeBody tycon tycon_args expr
 673
 674
 675 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 676 -- alternative  (con, xs, rhs)
 677 -- but it does the reboxing necessary to construct the *source*
 678 -- arguments, xs, from the representation arguments ys.
 679 -- For example:
 680 --      data T = MkT !(Int,Int) Bool
 681 --
 682 -- mkReboxingAlt MkT [x,b] r
 683 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 684 --
 685 -- mkDataAlt should really be in DataCon, but it can't because
 686 -- it manipulates CoreSyn.
 687
 688 mkReboxingAlt
 689   :: [Unique]           -- Uniques for the new Ids
 690   -> DataCon
 691   -> [Var]              -- Source-level args, including existential dicts
 692   -> CoreExpr           -- RHS
 693   -> CoreAlt
 694
 695 mkReboxingAlt us con args rhs
 696   | not (any isMarkedUnboxed stricts)
 697   = (DataAlt con, args, rhs)
 698
 699   | otherwise
 700   = let
 701         (binds, args') = go args stricts us
 702     in
 703     (DataAlt con, args', mkLets binds rhs)
 704
 705   where
 706     stricts = dataConExStricts con ++ dataConStrictMarks con
 707
 708     go [] stricts us = ([], [])
 709
 710         -- Type variable case
 711     go (arg:args) stricts us
 712       | isTyVar arg
 713       = let (binds, args') = go args stricts us
 714         in  (binds, arg:args')
 715
 716         -- Term variable case
 717     go (arg:args) (str:stricts) us
 718       | isMarkedUnboxed str
 719       =
 720         let (binds, unpacked_args')        = go args stricts us'
 721             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 722         in
 723             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 724       | otherwise
 725       = let (binds, args') = go args stricts us
 726         in  (binds, arg:args')
 727 \end{code}
 728
 729
 730 %************************************************************************
 731 %*                                                                      *
 732 \subsection{Dictionary selectors}
 733 %*                                                                      *
 734 %************************************************************************
 735
 736 Selecting a field for a dictionary.  If there is just one field, then
 737 there's nothing to do.
 738
 739 Dictionary selectors may get nested forall-types.  Thus:
 740
 741         class Foo a where
 742           op :: forall b. Ord b => a -> b -> b
 743
 744 Then the top-level type for op is
 745
 746         op :: forall a. Foo a =>
 747               forall b. Ord b =>
 748               a -> b -> b
 749
 750 This is unlike ordinary record selectors, which have all the for-alls
 751 at the outside.  When dealing with classes it's very convenient to
 752 recover the original type signature from the class op selector.
 753
 754 \begin{code}
 755 mkDictSelId :: Name -> Class -> Id
 756 mkDictSelId name clas
 757   = mkGlobalId (ClassOpId clas) name sel_ty info
 758   where
 759     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 760         -- We can't just say (exprType rhs), because that would give a type
 761         --      C a -> C a
 762         -- for a single-op class (after all, the selector is the identity)
 763         -- But it's type must expose the representation of the dictionary
 764         -- to gat (say)         C a -> (a -> a)
 765
 766     info = noCafIdInfo
 767                 `setArityInfo`          1
 768                 `setUnfoldingInfo`      mkTopUnfolding rhs
 769                 `setAllStrictnessInfo`  Just strict_sig
 770
 771         -- We no longer use 'must-inline' on record selectors.  They'll
 772         -- inline like crazy if they scrutinise a constructor
 773
 774         -- The strictness signature is of the form U(AAAVAAAA) -> T
 775         -- where the V depends on which item we are selecting
 776         -- It's worth giving one, so that absence info etc is generated
 777         -- even if the selector isn't inlined
 778     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 779     arg_dmd | isNewTyCon tycon = evalDmd
 780             | otherwise        = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 781                                             | id <- arg_ids ])
 782
 783     tycon      = classTyCon clas
 784     [data_con] = tyConDataCons tycon
 785     tyvars     = dataConUnivTyVars data_con
 786     arg_tys    = ASSERT( isVanillaDataCon data_con ) dataConRepArgTys data_con
 787     the_arg_id = assoc "MkId.mkDictSelId" (map idName (classSelIds clas) `zip` arg_ids) name
 788
 789     pred              = mkClassPred clas (mkTyVarTys tyvars)
 790     (dict_id:arg_ids) = mkTemplateLocals (mkPredTy pred : arg_tys)
 791
 792     rhs = mkLams tyvars (Lam dict_id rhs_body)
 793     rhs_body | isNewTyCon tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 794              | otherwise        = Case (Var dict_id) dict_id (idType the_arg_id)
 795                                        [(DataAlt data_con, arg_ids, Var the_arg_id)]
 796
 797 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 798 -- The wrapper for the data constructor for a newtype looks like this:
 799 --      newtype T a = MkT (a,Int)
 800 --      MkT :: forall a. (a,Int) -> T a
 801 --      MkT = /\a. \(x:(a,Int)). x `cast` CoT a
 802 -- where CoT is the coercion TyCon assoicated with the newtype
 803 --
 804 -- The call (wrapNewTypeBody T [a] e) returns the
 805 -- body of the wrapper, namely
 806 --      e `cast` CoT [a]
 807 --
 808 -- If a coercion constructor is prodivided in the newtype, then we use
 809 -- it, otherwise the wrap/unwrap are both no-ops
 810 --
 811 wrapNewTypeBody tycon args result_expr
 812   | Just co_con <- newTyConCo tycon
 813   = Cast result_expr (mkTyConApp co_con args)
 814   | otherwise
 815   = result_expr
 816
 817 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 818 unwrapNewTypeBody tycon args result_expr
 819   | Just co_con <- newTyConCo tycon
 820   = Cast result_expr (mkSymCoercion (mkTyConApp co_con args))
 821   | otherwise
 822   = result_expr
 823
 824
 825 \end{code}
 826
 827
 828 %************************************************************************
 829 %*                                                                      *
 830 \subsection{Primitive operations
 831 %*                                                                      *
 832 %************************************************************************
 833
 834 \begin{code}
 835 mkPrimOpId :: PrimOp -> Id
 836 mkPrimOpId prim_op
 837   = id
 838   where
 839     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 840     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 841     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 842                          (mkPrimOpIdUnique (primOpTag prim_op))
 843                          Nothing (AnId id) UserSyntax
 844     id   = mkGlobalId (PrimOpId prim_op) name ty info
 845
 846     info = noCafIdInfo
 847            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 848            `setArityInfo`         arity
 849            `setAllStrictnessInfo` Just strict_sig
 850
 851 -- For each ccall we manufacture a separate CCallOpId, giving it
 852 -- a fresh unique, a type that is correct for this particular ccall,
 853 -- and a CCall structure that gives the correct details about calling
 854 -- convention etc.
 855 --
 856 -- The *name* of this Id is a local name whose OccName gives the full
 857 -- details of the ccall, type and all.  This means that the interface
 858 -- file reader can reconstruct a suitable Id
 859
 860 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 861 mkFCallId uniq fcall ty
 862   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 863         -- A CCallOpId should have no free type variables;
 864         -- when doing substitutions won't substitute over it
 865     mkGlobalId (FCallId fcall) name ty info
 866   where
 867     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 868         -- The "occurrence name" of a ccall is the full info about the
 869         -- ccall; it is encoded, but may have embedded spaces etc!
 870
 871     name = mkFCallName uniq occ_str
 872
 873     info = noCafIdInfo
 874            `setArityInfo`               arity
 875            `setAllStrictnessInfo`       Just strict_sig
 876
 877     (_, tau)     = tcSplitForAllTys ty
 878     (arg_tys, _) = tcSplitFunTys tau
 879     arity        = length arg_tys
 880     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 881 \end{code}
 882
 883
 884 %************************************************************************
 885 %*                                                                      *
 886 \subsection{DictFuns and default methods}
 887 %*                                                                      *
 888 %************************************************************************
 889
 890 Important notes about dict funs and default methods
 891 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 892 Dict funs and default methods are *not* ImplicitIds.  Their definition
 893 involves user-written code, so we can't figure out their strictness etc
 894 based on fixed info, as we can for constructors and record selectors (say).
 895
 896 We build them as LocalIds, but with External Names.  This ensures that
 897 they are taken to account by free-variable finding and dependency
 898 analysis (e.g. CoreFVs.exprFreeVars).
 899
 900 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
 901 they are globals, the specialiser floats dict uses above their defns,
 902 which prevents good simplifications happening.  Also the strictness
 903 analyser treats a occurrence of a GlobalId as imported and assumes it
 904 contains strictness in its IdInfo, which isn't true if the thing is
 905 bound in the same module as the occurrence.
 906
 907 It's OK for dfuns to be LocalIds, because we form the instance-env to
 908 pass on to the next module (md_insts) in CoreTidy, afer tidying
 909 and globalising the top-level Ids.
 910
 911 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
 912 that they aren't discarded by the occurrence analyser.
 913
 914 \begin{code}
 915 mkDefaultMethodId dm_name ty = mkExportedLocalId dm_name ty
 916
 917 mkDictFunId :: Name             -- Name to use for the dict fun;
 918             -> [TyVar]
 919             -> ThetaType
 920             -> Class
 921             -> [Type]
 922             -> Id
 923
 924 mkDictFunId dfun_name inst_tyvars dfun_theta clas inst_tys
 925   = mkExportedLocalId dfun_name dfun_ty
 926   where
 927     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 928
 929 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 930     of compatibility with Hugs.
 931     See `types/InstEnv' for a discussion related to this.
 932
 933     (class_tyvars, sc_theta, _, _) = classBigSig clas
 934     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 935     sc_theta' = substClasses (zipTopTvSubst class_tyvars inst_tys) sc_theta
 936     dfun_theta = case inst_decl_theta of
 937                    []    -> []  -- If inst_decl_theta is empty, then we don't
 938                                 -- want to have any dict arguments, so that we can
 939                                 -- expose the constant methods.
 940
 941                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 942                                 -- Otherwise we pass the superclass dictionaries to
 943                                 -- the dictionary function; the Mark Jones optimisation.
 944                                 --
 945                                 -- NOTE the "nub".  I got caught by this one:
 946                                 --   class Monad m => MonadT t m where ...
 947                                 --   instance Monad m => MonadT (EnvT env) m where ...
 948                                 -- Here, the inst_decl_theta has (Monad m); but so
 949                                 -- does the sc_theta'!
 950                                 --
 951                                 -- NOTE the "not_const".  I got caught by this one too:
 952                                 --   class Foo a => Baz a b where ...
 953                                 --   instance Wob b => Baz T b where..
 954                                 -- Now sc_theta' has Foo T
 955 -}
 956 \end{code}
 957
 958
 959 %************************************************************************
 960 %*                                                                      *
 961 \subsection{Un-definable}
 962 %*                                                                      *
 963 %************************************************************************
 964
 965 These Ids can't be defined in Haskell.  They could be defined in
 966 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
 967 ensure that they were definitely, definitely inlined, because there is
 968 no curried identifier for them.  That's what mkCompulsoryUnfolding
 969 does.  If we had a way to get a compulsory unfolding from an interface
 970 file, we could do that, but we don't right now.
 971
 972 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 973 just gets expanded into a type coercion wherever it occurs.  Hence we
 974 add it as a built-in Id with an unfolding here.
 975
 976 The type variables we use here are "open" type variables: this means
 977 they can unify with both unlifted and lifted types.  Hence we provide
 978 another gun with which to shoot yourself in the foot.
 979
 980 \begin{code}
 981 mkWiredInIdName mod fs uniq id
 982  = mkWiredInName mod (mkOccNameFS varName fs) uniq Nothing (AnId id) UserSyntax
 983
 984 unsafeCoerceName = mkWiredInIdName gHC_PRIM FSLIT("unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
 985 nullAddrName     = mkWiredInIdName gHC_PRIM FSLIT("nullAddr#")     nullAddrIdKey      nullAddrId
 986 seqName          = mkWiredInIdName gHC_PRIM FSLIT("seq")           seqIdKey           seqId
 987 realWorldName    = mkWiredInIdName gHC_PRIM FSLIT("realWorld#")    realWorldPrimIdKey realWorldPrimId
 988 lazyIdName       = mkWiredInIdName gHC_BASE FSLIT("lazy")         lazyIdKey           lazyId
 989
 990 errorName                = mkWiredInIdName gHC_ERR FSLIT("error")            errorIdKey eRROR_ID
 991 recSelErrorName          = mkWiredInIdName gHC_ERR FSLIT("recSelError")     recSelErrorIdKey rEC_SEL_ERROR_ID
 992 runtimeErrorName         = mkWiredInIdName gHC_ERR FSLIT("runtimeError")    runtimeErrorIdKey rUNTIME_ERROR_ID
 993 irrefutPatErrorName      = mkWiredInIdName gHC_ERR FSLIT("irrefutPatError") irrefutPatErrorIdKey iRREFUT_PAT_ERROR_ID
 994 recConErrorName          = mkWiredInIdName gHC_ERR FSLIT("recConError")     recConErrorIdKey rEC_CON_ERROR_ID
 995 patErrorName             = mkWiredInIdName gHC_ERR FSLIT("patError")         patErrorIdKey pAT_ERROR_ID
 996 noMethodBindingErrorName = mkWiredInIdName gHC_ERR FSLIT("noMethodBindingError")
 997                                            noMethodBindingErrorIdKey nO_METHOD_BINDING_ERROR_ID
 998 nonExhaustiveGuardsErrorName
 999   = mkWiredInIdName gHC_ERR FSLIT("nonExhaustiveGuardsError")
1000                     nonExhaustiveGuardsErrorIdKey nON_EXHAUSTIVE_GUARDS_ERROR_ID
1001 \end{code}
1002
1003 \begin{code}
1004 -- unsafeCoerce# :: forall a b. a -> b
1005 unsafeCoerceId
1006   = pcMiscPrelId unsafeCoerceName ty info
1007   where
1008     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1009
1010
1011     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
1012                       (mkFunTy openAlphaTy openBetaTy)
1013     [x] = mkTemplateLocals [openAlphaTy]
1014     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
1015 --       Note (Coerce openBetaTy openAlphaTy) (Var x)
1016          Cast (Var x) (mkUnsafeCoercion openAlphaTy openBetaTy)
1017
1018 -- nullAddr# :: Addr#
1019 -- The reason is is here is because we don't provide
1020 -- a way to write this literal in Haskell.
1021 nullAddrId
1022   = pcMiscPrelId nullAddrName addrPrimTy info
1023   where
1024     info = noCafIdInfo `setUnfoldingInfo`
1025            mkCompulsoryUnfolding (Lit nullAddrLit)
1026
1027 seqId
1028   = pcMiscPrelId seqName ty info
1029   where
1030     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1031
1032
1033     ty  = mkForAllTys [alphaTyVar,openBetaTyVar]
1034                       (mkFunTy alphaTy (mkFunTy openBetaTy openBetaTy))
1035     [x,y] = mkTemplateLocals [alphaTy, openBetaTy]
1036     rhs = mkLams [alphaTyVar,openBetaTyVar,x,y] (Case (Var x) x openBetaTy [(DEFAULT, [], Var y)])
1037
1038 -- lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1039 -- Used to lazify pseq:         pseq a b = a `seq` lazy b
1040 --
1041 -- Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1042 -- not from GHC.Base.hi.   This is important, because the strictness
1043 -- analyser will spot it as strict!
1044 --
1045 -- Also no unfolding in lazyId: it gets "inlined" by a HACK in the worker/wrapper pass
1046 --      (see WorkWrap.wwExpr)
1047 -- We could use inline phases to do this, but that would be vulnerable to changes in
1048 -- phase numbering....we must inline precisely after strictness analysis.
1049 lazyId
1050   = pcMiscPrelId lazyIdName ty info
1051   where
1052     info = noCafIdInfo
1053     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
1054
1055 lazyIdUnfolding :: CoreExpr     -- Used to expand 'lazyId' after strictness anal
1056 lazyIdUnfolding = mkLams [openAlphaTyVar,x] (Var x)
1057                 where
1058                   [x] = mkTemplateLocals [openAlphaTy]
1059 \end{code}
1060
1061 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1062 nasty as-is, change it back to a literal (@Literal@).
1063
1064 voidArgId is a Local Id used simply as an argument in functions
1065 where we just want an arg to avoid having a thunk of unlifted type.
1066 E.g.
1067         x = \ void :: State# RealWorld -> (# p, q #)
1068
1069 This comes up in strictness analysis
1070
1071 \begin{code}
1072 realWorldPrimId -- :: State# RealWorld
1073   = pcMiscPrelId realWorldName realWorldStatePrimTy
1074                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1075         -- The evaldUnfolding makes it look that realWorld# is evaluated
1076         -- which in turn makes Simplify.interestingArg return True,
1077         -- which in turn makes INLINE things applied to realWorld# likely
1078         -- to be inlined
1079
1080 voidArgId       -- :: State# RealWorld
1081   = mkSysLocal FSLIT("void") voidArgIdKey realWorldStatePrimTy
1082 \end{code}
1083
1084
1085 %************************************************************************
1086 %*                                                                      *
1087 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
1088 %*                                                                      *
1089 %************************************************************************
1090
1091 GHC randomly injects these into the code.
1092
1093 @patError@ is just a version of @error@ for pattern-matching
1094 failures.  It knows various ``codes'' which expand to longer
1095 strings---this saves space!
1096
1097 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
1098 well shouldn't be yanked on, but if one is, then you will get a
1099 friendly message from @absentErr@ (rather than a totally random
1100 crash).
1101
1102 @parError@ is a special version of @error@ which the compiler does
1103 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
1104 templates, but we don't ever expect to generate code for it.
1105
1106 \begin{code}
1107 mkRuntimeErrorApp
1108         :: Id           -- Should be of type (forall a. Addr# -> a)
1109                         --      where Addr# points to a UTF8 encoded string
1110         -> Type         -- The type to instantiate 'a'
1111         -> String       -- The string to print
1112         -> CoreExpr
1113
1114 mkRuntimeErrorApp err_id res_ty err_msg
1115   = mkApps (Var err_id) [Type res_ty, err_string]
1116   where
1117     err_string = Lit (mkStringLit err_msg)
1118
1119 rEC_SEL_ERROR_ID                = mkRuntimeErrorId recSelErrorName
1120 rUNTIME_ERROR_ID                = mkRuntimeErrorId runtimeErrorName
1121 iRREFUT_PAT_ERROR_ID            = mkRuntimeErrorId irrefutPatErrorName
1122 rEC_CON_ERROR_ID                = mkRuntimeErrorId recConErrorName
1123 pAT_ERROR_ID                    = mkRuntimeErrorId patErrorName
1124 nO_METHOD_BINDING_ERROR_ID      = mkRuntimeErrorId noMethodBindingErrorName
1125 nON_EXHAUSTIVE_GUARDS_ERROR_ID  = mkRuntimeErrorId nonExhaustiveGuardsErrorName
1126
1127 -- The runtime error Ids take a UTF8-encoded string as argument
1128 mkRuntimeErrorId name = pc_bottoming_Id name runtimeErrorTy
1129 runtimeErrorTy        = mkSigmaTy [openAlphaTyVar] [] (mkFunTy addrPrimTy openAlphaTy)
1130 \end{code}
1131
1132 \begin{code}
1133 eRROR_ID = pc_bottoming_Id errorName errorTy
1134
1135 errorTy  :: Type
1136 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy] openAlphaTy)
1137     -- Notice the openAlphaTyVar.  It says that "error" can be applied
1138     -- to unboxed as well as boxed types.  This is OK because it never
1139     -- returns, so the return type is irrelevant.
1140 \end{code}
1141
1142
1143 %************************************************************************
1144 %*                                                                      *
1145 \subsection{Utilities}
1146 %*                                                                      *
1147 %************************************************************************
1148
1149 \begin{code}
1150 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1151 pcMiscPrelId name ty info
1152   = mkVanillaGlobal name ty info
1153     -- We lie and say the thing is imported; otherwise, we get into
1154     -- a mess with dependency analysis; e.g., core2stg may heave in
1155     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1156     -- being compiled, then it's just a matter of luck if the definition
1157     -- will be in "the right place" to be in scope.
1158
1159 pc_bottoming_Id name ty
1160  = pcMiscPrelId name ty bottoming_info
1161  where
1162     bottoming_info = vanillaIdInfo `setAllStrictnessInfo` Just strict_sig
1163         -- Do *not* mark them as NoCafRefs, because they can indeed have
1164         -- CAF refs.  For example, pAT_ERROR_ID calls GHC.Err.untangle,
1165         -- which has some CAFs
1166         -- In due course we may arrange that these error-y things are
1167         -- regarded by the GC as permanently live, in which case we
1168         -- can give them NoCaf info.  As it is, any function that calls
1169         -- any pc_bottoming_Id will itself have CafRefs, which bloats
1170         -- SRTs.
1171
1172     strict_sig     = mkStrictSig (mkTopDmdType [evalDmd] BotRes)
1173         -- These "bottom" out, no matter what their arguments
1174
1175 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
1176 openAlphaTy  = mkTyVarTy openAlphaTyVar
1177 openBetaTy   = mkTyVarTy openBetaTyVar
1178 \end{code}
1179