compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1998
   4 %
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9 - data constructors
  10 - record selectors
  11 - method and superclass selectors
  12 - primitive operations
  13
  14 \begin{code}
  15 {-# OPTIONS -fno-warn-missing-signatures #-}
  16 -- The above warning supression flag is a temporary kludge.
  17 -- While working on this module you are encouraged to remove it and fix
  18 -- any warnings in the module. See
  19 --  <http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings>
  20 -- for details
  21
  22 module MkId (
  23         mkDictFunId, mkDefaultMethodId,
  24         mkDictSelId,
  25
  26         mkDataConIds,
  27         mkPrimOpId, mkFCallId, mkTickBoxOpId, mkBreakPointOpId,
  28
  29         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  30         wrapFamInstBody, unwrapFamInstScrut,
  31         mkUnpackCase, mkProductBox,
  32
  33         -- And some particular Ids; see below for why they are wired in
  34         wiredInIds, ghcPrimIds,
  35         unsafeCoerceId, realWorldPrimId, voidArgId, nullAddrId, seqId,
  36         lazyId, lazyIdKey,
  37
  38         mkRuntimeErrorApp, mkImpossibleExpr,
  39         rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID, rUNTIME_ERROR_ID,
  40         nON_EXHAUSTIVE_GUARDS_ERROR_ID, nO_METHOD_BINDING_ERROR_ID,
  41         pAT_ERROR_ID, eRROR_ID, rEC_SEL_ERROR_ID,
  42
  43         unsafeCoerceName
  44     ) where
  45
  46 #include "HsVersions.h"
  47
  48 import Rules
  49 import TysPrim
  50 import TysWiredIn
  51 import PrelRules
  52 import Type
  53 import Coercion
  54 import TcType
  55 import CoreUtils        ( exprType, mkCoerce )
  56 import CoreUnfold
  57 import Literal
  58 import TyCon
  59 import Class
  60 import VarSet
  61 import Name
  62 import PrimOp
  63 import ForeignCall
  64 import DataCon
  65 import Id
  66 import Var              ( Var, TyVar, mkCoVar, mkExportedLocalVar )
  67 import IdInfo
  68 import NewDemand
  69 import CoreSyn
  70 import Unique
  71 import PrelNames
  72 import BasicTypes       hiding ( SuccessFlag(..) )
  73 import Util
  74 import Outputable
  75 import FastString
  76 import ListSetOps
  77 import Module
  78 \end{code}
  79
  80 %************************************************************************
  81 %*                                                                      *
  82 \subsection{Wired in Ids}
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 Note [Wired-in Ids]
  87 ~~~~~~~~~~~~~~~~~~~
  88 There are several reasons why an Id might appear in the wiredInIds:
  89
  90 (1) The ghcPrimIds are wired in because they can't be defined in
  91     Haskell at all, although the can be defined in Core.  They have
  92     compulsory unfoldings, so they are always inlined and they  have
  93     no definition site.  Their home module is GHC.Prim, so they
  94     also have a description in primops.txt.pp, where they are called
  95     'pseudoops'.
  96
  97 (2) The 'error' function, eRROR_ID, is wired in because we don't yet have
  98     a way to express in an interface file that the result type variable
  99     is 'open'; that is can be unified with an unboxed type
 100
 101     [The interface file format now carry such information, but there's
 102     no way yet of expressing at the definition site for these
 103     error-reporting functions that they have an 'open'
 104     result type. -- sof 1/99]
 105
 106 (3) Other error functions (rUNTIME_ERROR_ID) are wired in (a) because
 107     the desugarer generates code that mentiones them directly, and
 108     (b) for the same reason as eRROR_ID
 109
 110 (4) lazyId is wired in because the wired-in version overrides the
 111     strictness of the version defined in GHC.Base
 112
 113 In cases (2-4), the function has a definition in a library module, and
 114 can be called; but the wired-in version means that the details are
 115 never read from that module's interface file; instead, the full definition
 116 is right here.
 117
 118 \begin{code}
 119 wiredInIds :: [Id]
 120 wiredInIds
 121   = [
 122
 123     eRROR_ID,   -- This one isn't used anywhere else in the compiler
 124                 -- But we still need it in wiredInIds so that when GHC
 125                 -- compiles a program that mentions 'error' we don't
 126                 -- import its type from the interface file; we just get
 127                 -- the Id defined here.  Which has an 'open-tyvar' type.
 128
 129     rUNTIME_ERROR_ID,
 130     iRREFUT_PAT_ERROR_ID,
 131     nON_EXHAUSTIVE_GUARDS_ERROR_ID,
 132     nO_METHOD_BINDING_ERROR_ID,
 133     pAT_ERROR_ID,
 134     rEC_CON_ERROR_ID,
 135     rEC_SEL_ERROR_ID,
 136
 137     lazyId
 138     ] ++ ghcPrimIds
 139
 140 -- These Ids are exported from GHC.Prim
 141 ghcPrimIds :: [Id]
 142 ghcPrimIds
 143   = [   -- These can't be defined in Haskell, but they have
 144         -- perfectly reasonable unfoldings in Core
 145     realWorldPrimId,
 146     unsafeCoerceId,
 147     nullAddrId,
 148     seqId
 149     ]
 150 \end{code}
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Data constructors}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 The wrapper for a constructor is an ordinary top-level binding that evaluates
 159 any strict args, unboxes any args that are going to be flattened, and calls
 160 the worker.
 161
 162 We're going to build a constructor that looks like:
 163
 164         data (Data a, C b) =>  T a b = T1 !a !Int b
 165
 166         T1 = /\ a b ->
 167              \d1::Data a, d2::C b ->
 168              \p q r -> case p of { p ->
 169                        case q of { q ->
 170                        Con T1 [a,b] [p,q,r]}}
 171
 172 Notice that
 173
 174 * d2 is thrown away --- a context in a data decl is used to make sure
 175   one *could* construct dictionaries at the site the constructor
 176   is used, but the dictionary isn't actually used.
 177
 178 * We have to check that we can construct Data dictionaries for
 179   the types a and Int.  Once we've done that we can throw d1 away too.
 180
 181 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 182   all that matters is that the arguments are evaluated.  "seq" is
 183   very careful to preserve evaluation order, which we don't need
 184   to be here.
 185
 186   You might think that we could simply give constructors some strictness
 187   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 188   But we don't do that because in the case of primops and functions strictness
 189   is a *property* not a *requirement*.  In the case of constructors we need to
 190   do something active to evaluate the argument.
 191
 192   Making an explicit case expression allows the simplifier to eliminate
 193   it in the (common) case where the constructor arg is already evaluated.
 194
 195 Note [Wrappers for data instance tycons]
 196 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 197 In the case of data instances, the wrapper also applies the coercion turning
 198 the representation type into the family instance type to cast the result of
 199 the wrapper.  For example, consider the declarations
 200
 201   data family Map k :: * -> *
 202   data instance Map (a, b) v = MapPair (Map a (Pair b v))
 203
 204 The tycon to which the datacon MapPair belongs gets a unique internal
 205 name of the form :R123Map, and we call it the representation tycon.
 206 In contrast, Map is the family tycon (accessible via
 207 tyConFamInst_maybe). A coercion allows you to move between
 208 representation and family type.  It is accessible from :R123Map via
 209 tyConFamilyCoercion_maybe and has kind
 210
 211   Co123Map a b v :: {Map (a, b) v ~ :R123Map a b v}
 212
 213 The wrapper and worker of MapPair get the types
 214
 215         -- Wrapper
 216   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
 217   $WMapPair a b v = MapPair a b v `cast` sym (Co123Map a b v)
 218
 219         -- Worker
 220   MapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
 221
 222 This coercion is conditionally applied by wrapFamInstBody.
 223
 224 It's a bit more complicated if the data instance is a GADT as well!
 225
 226    data instance T [a] where
 227         T1 :: forall b. b -> T [Maybe b]
 228 Hence
 229    Co7T a :: T [a] ~ :R7T a
 230
 231 Now we want
 232
 233         -- Wrapper
 234   $WT1 :: forall b. b -> T [Maybe b]
 235   $WT1 b v = T1 (Maybe b) b (Maybe b) v
 236                         `cast` sym (Co7T (Maybe b))
 237
 238         -- Worker
 239   T1 :: forall c b. (c ~ Maybe b) => b -> :R7T c
 240
 241 \begin{code}
 242 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 243 mkDataConIds wrap_name wkr_name data_con
 244   | isNewTyCon tycon                    -- Newtype, only has a worker
 245   = DCIds Nothing nt_work_id
 246
 247   | any isMarkedStrict all_strict_marks      -- Algebraic, needs wrapper
 248     || not (null eq_spec)                    -- NB: LoadIface.ifaceDeclSubBndrs
 249     || isFamInstTyCon tycon                  --     depends on this test
 250   = DCIds (Just alg_wrap_id) wrk_id
 251
 252   | otherwise                                -- Algebraic, no wrapper
 253   = DCIds Nothing wrk_id
 254   where
 255     (univ_tvs, ex_tvs, eq_spec,
 256      eq_theta, dict_theta, orig_arg_tys, res_ty) = dataConFullSig data_con
 257     tycon = dataConTyCon data_con       -- The representation TyCon (not family)
 258
 259         ----------- Worker (algebraic data types only) --------------
 260         -- The *worker* for the data constructor is the function that
 261         -- takes the representation arguments and builds the constructor.
 262     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 263                         (dataConRepType data_con) wkr_info
 264
 265     wkr_arity = dataConRepArity data_con
 266     wkr_info  = noCafIdInfo
 267                 `setArityInfo`          wkr_arity
 268                 `setAllStrictnessInfo`  Just wkr_sig
 269                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 270                                                         -- even if arity = 0
 271
 272     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 273         --      Note [Data-con worker strictness]
 274         -- Notice that we do *not* say the worker is strict
 275         -- even if the data constructor is declared strict
 276         --      e.g.    data T = MkT !(Int,Int)
 277         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 278         -- expresssions that do the evals) but the *worker* itself is not.
 279         -- If we pretend it is strict then when we see
 280         --      case x of y -> $wMkT y
 281         -- the simplifier thinks that y is "sure to be evaluated" (because
 282         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 283         --
 284         -- When the simplifer sees a pattern
 285         --      case e of MkT x -> ...
 286         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 287         -- but that's fine... dataConRepStrictness comes from the data con
 288         -- not from the worker Id.
 289
 290     cpr_info | isProductTyCon tycon &&
 291                isDataTyCon tycon    &&
 292                wkr_arity > 0        &&
 293                wkr_arity <= mAX_CPR_SIZE        = retCPR
 294              | otherwise                        = TopRes
 295         -- RetCPR is only true for products that are real data types;
 296         -- that is, not unboxed tuples or [non-recursive] newtypes
 297
 298         ----------- Workers for newtypes --------------
 299     nt_work_id   = mkGlobalId (DataConWrapId data_con) wkr_name wrap_ty nt_work_info
 300     nt_work_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 301                   `setArityInfo` 1      -- Arity 1
 302                   `setUnfoldingInfo`     newtype_unf
 303     id_arg1      = mkTemplateLocal 1 (head orig_arg_tys)
 304     newtype_unf  = ASSERT2( isVanillaDataCon data_con &&
 305                             isSingleton orig_arg_tys, ppr data_con  )
 306                               -- Note [Newtype datacons]
 307                    mkCompulsoryUnfolding $
 308                    mkLams wrap_tvs $ Lam id_arg1 $
 309                    wrapNewTypeBody tycon res_ty_args (Var id_arg1)
 310
 311
 312         ----------- Wrapper --------------
 313         -- We used to include the stupid theta in the wrapper's args
 314         -- but now we don't.  Instead the type checker just injects these
 315         -- extra constraints where necessary.
 316     wrap_tvs    = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 317     res_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
 318     eq_tys   = mkPredTys eq_theta
 319     dict_tys = mkPredTys dict_theta
 320     wrap_ty  = mkForAllTys wrap_tvs $ mkFunTys eq_tys $ mkFunTys dict_tys $
 321                mkFunTys orig_arg_tys $ res_ty
 322         -- NB: watch out here if you allow user-written equality
 323         --     constraints in data constructor signatures
 324
 325         ----------- Wrappers for algebraic data types --------------
 326     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 327     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 328                     `setArityInfo`         wrap_arity
 329                         -- It's important to specify the arity, so that partial
 330                         -- applications are treated as values
 331                     `setUnfoldingInfo`     wrap_unf
 332                     `setAllStrictnessInfo` Just wrap_sig
 333
 334     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 335     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 336     arg_dmds = map mk_dmd all_strict_marks
 337     mk_dmd str | isMarkedStrict str = evalDmd
 338                | otherwise          = lazyDmd
 339         -- The Cpr info can be important inside INLINE rhss, where the
 340         -- wrapper constructor isn't inlined.
 341         -- And the argument strictness can be important too; we
 342         -- may not inline a contructor when it is partially applied.
 343         -- For example:
 344         --      data W = C !Int !Int !Int
 345         --      ...(let w = C x in ...(w p q)...)...
 346         -- we want to see that w is strict in its two arguments
 347
 348     wrap_unf = mkImplicitUnfolding $ Note InlineMe $
 349                mkLams wrap_tvs $
 350                mkLams eq_args $
 351                mkLams dict_args $ mkLams id_args $
 352                foldr mk_case con_app
 353                      (zip (dict_args ++ id_args) all_strict_marks)
 354                      i3 []
 355
 356     con_app _ rep_ids = wrapFamInstBody tycon res_ty_args $
 357                           Var wrk_id `mkTyApps`  res_ty_args
 358                                      `mkVarApps` ex_tvs
 359                                      -- Equality evidence:
 360                                      `mkTyApps`  map snd eq_spec
 361                                      `mkVarApps` eq_args
 362                                      `mkVarApps` reverse rep_ids
 363
 364     (dict_args,i2) = mkLocals 1  dict_tys
 365     (id_args,i3)   = mkLocals i2 orig_arg_tys
 366     wrap_arity     = i3-1
 367     (eq_args,_)    = mkCoVarLocals i3 eq_tys
 368
 369     mkCoVarLocals i []     = ([],i)
 370     mkCoVarLocals i (x:xs) = let (ys,j) = mkCoVarLocals (i+1) xs
 371                                  y      = mkCoVar (mkSysTvName (mkBuiltinUnique i) (fsLit "dc_co")) x
 372                              in (y:ys,j)
 373
 374     mk_case
 375            :: (Id, StrictnessMark)      -- Arg, strictness
 376            -> (Int -> [Id] -> CoreExpr) -- Body
 377            -> Int                       -- Next rep arg id
 378            -> [Id]                      -- Rep args so far, reversed
 379            -> CoreExpr
 380     mk_case (arg,strict) body i rep_args
 381           = case strict of
 382                 NotMarkedStrict -> body i (arg:rep_args)
 383                 MarkedStrict
 384                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 385                    | otherwise ->
 386                         Case (Var arg) arg res_ty [(DEFAULT,[], body i (arg:rep_args))]
 387
 388                 MarkedUnboxed
 389                    -> unboxProduct i (Var arg) (idType arg) the_body
 390                       where
 391                         the_body i con_args = body i (reverse con_args ++ rep_args)
 392
 393 mAX_CPR_SIZE :: Arity
 394 mAX_CPR_SIZE = 10
 395 -- We do not treat very big tuples as CPR-ish:
 396 --      a) for a start we get into trouble because there aren't
 397 --         "enough" unboxed tuple types (a tiresome restriction,
 398 --         but hard to fix),
 399 --      b) more importantly, big unboxed tuples get returned mainly
 400 --         on the stack, and are often then allocated in the heap
 401 --         by the caller.  So doing CPR for them may in fact make
 402 --         things worse.
 403
 404 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 405                where
 406                  n = length tys
 407 \end{code}
 408
 409 Note [Newtype datacons]
 410 ~~~~~~~~~~~~~~~~~~~~~~~
 411 The "data constructor" for a newtype should always be vanilla.  At one
 412 point this wasn't true, because the newtype arising from
 413      class C a => D a
 414 looked like
 415        newtype T:D a = D:D (C a)
 416 so the data constructor for T:C had a single argument, namely the
 417 predicate (C a).  But now we treat that as an ordinary argument, not
 418 part of the theta-type, so all is well.
 419
 420
 421 %************************************************************************
 422 %*                                                                      *
 423 \subsection{Dictionary selectors}
 424 %*                                                                      *
 425 %************************************************************************
 426
 427 Selecting a field for a dictionary.  If there is just one field, then
 428 there's nothing to do.
 429
 430 Dictionary selectors may get nested forall-types.  Thus:
 431
 432         class Foo a where
 433           op :: forall b. Ord b => a -> b -> b
 434
 435 Then the top-level type for op is
 436
 437         op :: forall a. Foo a =>
 438               forall b. Ord b =>
 439               a -> b -> b
 440
 441 This is unlike ordinary record selectors, which have all the for-alls
 442 at the outside.  When dealing with classes it's very convenient to
 443 recover the original type signature from the class op selector.
 444
 445 \begin{code}
 446 mkDictSelId :: Bool     -- True <=> don't include the unfolding
 447                         -- Little point on imports without -O, because the
 448                         -- dictionary itself won't be visible
 449             -> Name -> Class -> Id
 450 mkDictSelId no_unf name clas
 451   = mkGlobalId (ClassOpId clas) name sel_ty info
 452   where
 453     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 454         -- We can't just say (exprType rhs), because that would give a type
 455         --      C a -> C a
 456         -- for a single-op class (after all, the selector is the identity)
 457         -- But it's type must expose the representation of the dictionary
 458         -- to get (say)         C a -> (a -> a)
 459
 460     info = noCafIdInfo
 461                 `setArityInfo`          1
 462                 `setAllStrictnessInfo`  Just strict_sig
 463                 `setUnfoldingInfo`      (if no_unf then noUnfolding
 464                                                    else mkImplicitUnfolding rhs)
 465
 466         -- We no longer use 'must-inline' on record selectors.  They'll
 467         -- inline like crazy if they scrutinise a constructor
 468
 469         -- The strictness signature is of the form U(AAAVAAAA) -> T
 470         -- where the V depends on which item we are selecting
 471         -- It's worth giving one, so that absence info etc is generated
 472         -- even if the selector isn't inlined
 473     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 474     arg_dmd | isNewTyCon tycon = evalDmd
 475             | otherwise        = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 476                                             | id <- arg_ids ])
 477
 478     tycon      = classTyCon clas
 479     [data_con] = tyConDataCons tycon
 480     tyvars     = dataConUnivTyVars data_con
 481     arg_tys    = {- ASSERT( isVanillaDataCon data_con ) -} dataConRepArgTys data_con
 482     eq_theta   = dataConEqTheta data_con
 483     the_arg_id = assoc "MkId.mkDictSelId" (map idName (classSelIds clas) `zip` arg_ids) name
 484
 485     pred       = mkClassPred clas (mkTyVarTys tyvars)
 486     dict_id    = mkTemplateLocal     1 $ mkPredTy pred
 487     (eq_ids,n) = mkCoVarLocals 2 $ mkPredTys eq_theta
 488     arg_ids    = mkTemplateLocalsNum n arg_tys
 489
 490     mkCoVarLocals i []     = ([],i)
 491     mkCoVarLocals i (x:xs) = let (ys,j) = mkCoVarLocals (i+1) xs
 492                                  y      = mkCoVar (mkSysTvName (mkBuiltinUnique i) (fsLit "dc_co")) x
 493                              in (y:ys,j)
 494
 495     rhs = mkLams tyvars  (Lam dict_id   rhs_body)
 496     rhs_body | isNewTyCon tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 497              | otherwise        = Case (Var dict_id) dict_id (idType the_arg_id)
 498                                        [(DataAlt data_con, eq_ids ++ arg_ids, Var the_arg_id)]
 499 \end{code}
 500
 501
 502 %************************************************************************
 503 %*                                                                      *
 504         Boxing and unboxing
 505 %*                                                                      *
 506 %************************************************************************
 507
 508 \begin{code}
 509 -- unbox a product type...
 510 -- we will recurse into newtypes, casting along the way, and unbox at the
 511 -- first product data constructor we find. e.g.
 512 --
 513 --   data PairInt = PairInt Int Int
 514 --   newtype S = MkS PairInt
 515 --   newtype T = MkT S
 516 --
 517 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 518 -- ids, we get (modulo int passing)
 519 --
 520 --   case (e `cast` CoT) `cast` CoS of
 521 --     PairInt a b -> body [a,b]
 522 --
 523 -- The Ints passed around are just for creating fresh locals
 524 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> CoreExpr
 525 unboxProduct i arg arg_ty body
 526   = result
 527   where
 528     result = mkUnpackCase the_id arg con_args boxing_con rhs
 529     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 530     ([the_id], i') = mkLocals i [arg_ty]
 531     (con_args, i'') = mkLocals i' tys
 532     rhs = body i'' con_args
 533
 534 mkUnpackCase ::  Id -> CoreExpr -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 535 -- (mkUnpackCase x e args Con body)
 536 --      returns
 537 -- case (e `cast` ...) of bndr { Con args -> body }
 538 --
 539 -- the type of the bndr passed in is irrelevent
 540 mkUnpackCase bndr arg unpk_args boxing_con body
 541   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 542   where
 543   (cast_arg, bndr_ty) = go (idType bndr) arg
 544   go ty arg
 545     | (tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 546     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 547     = go (newTyConInstRhs tycon tycon_args)
 548          (unwrapNewTypeBody tycon tycon_args arg)
 549     | otherwise = (arg, ty)
 550
 551 -- ...and the dual
 552 reboxProduct :: [Unique]     -- uniques to create new local binders
 553              -> Type         -- type of product to box
 554              -> ([Unique],   -- remaining uniques
 555                  CoreExpr,   -- boxed product
 556                  [Id])       -- Ids being boxed into product
 557 reboxProduct us ty
 558   = let
 559         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 560
 561         us' = dropList con_arg_tys us
 562
 563         arg_ids  = zipWith (mkSysLocal (fsLit "rb")) us con_arg_tys
 564
 565         bind_rhs = mkProductBox arg_ids ty
 566
 567     in
 568       (us', bind_rhs, arg_ids)
 569
 570 mkProductBox :: [Id] -> Type -> CoreExpr
 571 mkProductBox arg_ids ty
 572   = result_expr
 573   where
 574     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
 575
 576     result_expr
 577       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 578       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 579       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 580
 581     wrap expr = wrapNewTypeBody tycon tycon_args expr
 582
 583
 584 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 585 -- alternative (con, xs, rhs)
 586 -- but it does the reboxing necessary to construct the *source*
 587 -- arguments, xs, from the representation arguments ys.
 588 -- For example:
 589 --      data T = MkT !(Int,Int) Bool
 590 --
 591 -- mkReboxingAlt MkT [x,b] r
 592 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 593 --
 594 -- mkDataAlt should really be in DataCon, but it can't because
 595 -- it manipulates CoreSyn.
 596
 597 mkReboxingAlt
 598   :: [Unique] -- Uniques for the new Ids
 599   -> DataCon
 600   -> [Var]    -- Source-level args, including existential dicts
 601   -> CoreExpr -- RHS
 602   -> CoreAlt
 603
 604 mkReboxingAlt us con args rhs
 605   | not (any isMarkedUnboxed stricts)
 606   = (DataAlt con, args, rhs)
 607
 608   | otherwise
 609   = let
 610         (binds, args') = go args stricts us
 611     in
 612     (DataAlt con, args', mkLets binds rhs)
 613
 614   where
 615     stricts = dataConExStricts con ++ dataConStrictMarks con
 616
 617     go [] _stricts _us = ([], [])
 618
 619     -- Type variable case
 620     go (arg:args) stricts us
 621       | isTyVar arg
 622       = let (binds, args') = go args stricts us
 623         in  (binds, arg:args')
 624
 625         -- Term variable case
 626     go (arg:args) (str:stricts) us
 627       | isMarkedUnboxed str
 628       =
 629         let (binds, unpacked_args')        = go args stricts us'
 630             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 631         in
 632             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 633       | otherwise
 634       = let (binds, args') = go args stricts us
 635         in  (binds, arg:args')
 636     go (_ : _) [] _ = panic "mkReboxingAlt"
 637 \end{code}
 638
 639
 640 %************************************************************************
 641 %*                                                                      *
 642         Wrapping and unwrapping newtypes and type families
 643 %*                                                                      *
 644 %************************************************************************
 645
 646 \begin{code}
 647 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 648 -- The wrapper for the data constructor for a newtype looks like this:
 649 --      newtype T a = MkT (a,Int)
 650 --      MkT :: forall a. (a,Int) -> T a
 651 --      MkT = /\a. \(x:(a,Int)). x `cast` sym (CoT a)
 652 -- where CoT is the coercion TyCon assoicated with the newtype
 653 --
 654 -- The call (wrapNewTypeBody T [a] e) returns the
 655 -- body of the wrapper, namely
 656 --      e `cast` (CoT [a])
 657 --
 658 -- If a coercion constructor is provided in the newtype, then we use
 659 -- it, otherwise the wrap/unwrap are both no-ops
 660 --
 661 -- If the we are dealing with a newtype *instance*, we have a second coercion
 662 -- identifying the family instance with the constructor of the newtype
 663 -- instance.  This coercion is applied in any case (ie, composed with the
 664 -- coercion constructor of the newtype or applied by itself).
 665
 666 wrapNewTypeBody tycon args result_expr
 667   = wrapFamInstBody tycon args inner
 668   where
 669     inner
 670       | Just co_con <- newTyConCo_maybe tycon
 671       = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) result_expr
 672       | otherwise
 673       = result_expr
 674
 675 -- When unwrapping, we do *not* apply any family coercion, because this will
 676 -- be done via a CoPat by the type checker.  We have to do it this way as
 677 -- computing the right type arguments for the coercion requires more than just
 678 -- a spliting operation (cf, TcPat.tcConPat).
 679
 680 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 681 unwrapNewTypeBody tycon args result_expr
 682   | Just co_con <- newTyConCo_maybe tycon
 683   = mkCoerce (mkTyConApp co_con args) result_expr
 684   | otherwise
 685   = result_expr
 686
 687 -- If the type constructor is a representation type of a data instance, wrap
 688 -- the expression into a cast adjusting the expression type, which is an
 689 -- instance of the representation type, to the corresponding instance of the
 690 -- family instance type.
 691 -- See Note [Wrappers for data instance tycons]
 692 wrapFamInstBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 693 wrapFamInstBody tycon args body
 694   | Just co_con <- tyConFamilyCoercion_maybe tycon
 695   = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) body
 696   | otherwise
 697   = body
 698
 699 unwrapFamInstScrut :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 700 unwrapFamInstScrut tycon args scrut
 701   | Just co_con <- tyConFamilyCoercion_maybe tycon
 702   = mkCoerce (mkTyConApp co_con args) scrut
 703   | otherwise
 704   = scrut
 705 \end{code}
 706
 707
 708 %************************************************************************
 709 %*                                                                      *
 710 \subsection{Primitive operations}
 711 %*                                                                      *
 712 %************************************************************************
 713
 714 \begin{code}
 715 mkPrimOpId :: PrimOp -> Id
 716 mkPrimOpId prim_op
 717   = id
 718   where
 719     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 720     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 721     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 722                          (mkPrimOpIdUnique (primOpTag prim_op))
 723                          (AnId id) UserSyntax
 724     id   = mkGlobalId (PrimOpId prim_op) name ty info
 725
 726     info = noCafIdInfo
 727            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 728            `setArityInfo`         arity
 729            `setAllStrictnessInfo` Just strict_sig
 730
 731 -- For each ccall we manufacture a separate CCallOpId, giving it
 732 -- a fresh unique, a type that is correct for this particular ccall,
 733 -- and a CCall structure that gives the correct details about calling
 734 -- convention etc.
 735 --
 736 -- The *name* of this Id is a local name whose OccName gives the full
 737 -- details of the ccall, type and all.  This means that the interface
 738 -- file reader can reconstruct a suitable Id
 739
 740 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 741 mkFCallId uniq fcall ty
 742   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 743     -- A CCallOpId should have no free type variables;
 744     -- when doing substitutions won't substitute over it
 745     mkGlobalId (FCallId fcall) name ty info
 746   where
 747     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 748     -- The "occurrence name" of a ccall is the full info about the
 749     -- ccall; it is encoded, but may have embedded spaces etc!
 750
 751     name = mkFCallName uniq occ_str
 752
 753     info = noCafIdInfo
 754            `setArityInfo`         arity
 755            `setAllStrictnessInfo` Just strict_sig
 756
 757     (_, tau)     = tcSplitForAllTys ty
 758     (arg_tys, _) = tcSplitFunTys tau
 759     arity        = length arg_tys
 760     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 761
 762 -- Tick boxes and breakpoints are both represented as TickBoxOpIds,
 763 -- except for the type:
 764 --
 765 --    a plain HPC tick box has type (State# RealWorld)
 766 --    a breakpoint Id has type forall a.a
 767 --
 768 -- The breakpoint Id will be applied to a list of arbitrary free variables,
 769 -- which is why it needs a polymorphic type.
 770
 771 mkTickBoxOpId :: Unique -> Module -> TickBoxId -> Id
 772 mkTickBoxOpId uniq mod ix = mkTickBox' uniq mod ix realWorldStatePrimTy
 773
 774 mkBreakPointOpId :: Unique -> Module -> TickBoxId -> Id
 775 mkBreakPointOpId uniq mod ix = mkTickBox' uniq mod ix ty
 776  where ty = mkSigmaTy [openAlphaTyVar] [] openAlphaTy
 777
 778 mkTickBox' uniq mod ix ty = mkGlobalId (TickBoxOpId tickbox) name ty info
 779   where
 780     tickbox = TickBox mod ix
 781     occ_str = showSDoc (braces (ppr tickbox))
 782     name    = mkTickBoxOpName uniq occ_str
 783     info    = noCafIdInfo
 784 \end{code}
 785
 786
 787 %************************************************************************
 788 %*                                                                      *
 789 \subsection{DictFuns and default methods}
 790 %*                                                                      *
 791 %************************************************************************
 792
 793 Important notes about dict funs and default methods
 794 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 795 Dict funs and default methods are *not* ImplicitIds.  Their definition
 796 involves user-written code, so we can't figure out their strictness etc
 797 based on fixed info, as we can for constructors and record selectors (say).
 798
 799 We build them as LocalIds, but with External Names.  This ensures that
 800 they are taken to account by free-variable finding and dependency
 801 analysis (e.g. CoreFVs.exprFreeVars).
 802
 803 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
 804 they are globals, the specialiser floats dict uses above their defns,
 805 which prevents good simplifications happening.  Also the strictness
 806 analyser treats a occurrence of a GlobalId as imported and assumes it
 807 contains strictness in its IdInfo, which isn't true if the thing is
 808 bound in the same module as the occurrence.
 809
 810 It's OK for dfuns to be LocalIds, because we form the instance-env to
 811 pass on to the next module (md_insts) in CoreTidy, afer tidying
 812 and globalising the top-level Ids.
 813
 814 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
 815 that they aren't discarded by the occurrence analyser.
 816
 817 \begin{code}
 818 mkDefaultMethodId dm_name ty = mkExportedLocalId dm_name ty
 819
 820 mkDictFunId :: Name      -- Name to use for the dict fun;
 821             -> [TyVar]
 822             -> ThetaType
 823             -> Class
 824             -> [Type]
 825             -> Id
 826
 827 mkDictFunId dfun_name inst_tyvars dfun_theta clas inst_tys
 828   = mkExportedLocalVar DFunId dfun_name dfun_ty vanillaIdInfo
 829   where
 830     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 831 \end{code}
 832
 833
 834 %************************************************************************
 835 %*                                                                      *
 836 \subsection{Un-definable}
 837 %*                                                                      *
 838 %************************************************************************
 839
 840 These Ids can't be defined in Haskell.  They could be defined in
 841 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
 842 ensure that they were definitely, definitely inlined, because there is
 843 no curried identifier for them.  That's what mkCompulsoryUnfolding
 844 does.  If we had a way to get a compulsory unfolding from an interface
 845 file, we could do that, but we don't right now.
 846
 847 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 848 just gets expanded into a type coercion wherever it occurs.  Hence we
 849 add it as a built-in Id with an unfolding here.
 850
 851 The type variables we use here are "open" type variables: this means
 852 they can unify with both unlifted and lifted types.  Hence we provide
 853 another gun with which to shoot yourself in the foot.
 854
 855 \begin{code}
 856 mkWiredInIdName mod fs uniq id
 857  = mkWiredInName mod (mkOccNameFS varName fs) uniq (AnId id) UserSyntax
 858
 859 unsafeCoerceName = mkWiredInIdName gHC_PRIM (fsLit "unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
 860 nullAddrName     = mkWiredInIdName gHC_PRIM (fsLit "nullAddr#")     nullAddrIdKey      nullAddrId
 861 seqName          = mkWiredInIdName gHC_PRIM (fsLit "seq")           seqIdKey           seqId
 862 realWorldName    = mkWiredInIdName gHC_PRIM (fsLit "realWorld#")    realWorldPrimIdKey realWorldPrimId
 863 lazyIdName       = mkWiredInIdName gHC_BASE (fsLit "lazy")         lazyIdKey           lazyId
 864
 865 errorName                = mkWiredInIdName gHC_ERR (fsLit "error")            errorIdKey eRROR_ID
 866 recSelErrorName          = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "recSelError")     recSelErrorIdKey rEC_SEL_ERROR_ID
 867 runtimeErrorName         = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "runtimeError")    runtimeErrorIdKey rUNTIME_ERROR_ID
 868 irrefutPatErrorName      = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "irrefutPatError") irrefutPatErrorIdKey iRREFUT_PAT_ERROR_ID
 869 recConErrorName          = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "recConError")     recConErrorIdKey rEC_CON_ERROR_ID
 870 patErrorName             = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "patError")         patErrorIdKey pAT_ERROR_ID
 871 noMethodBindingErrorName = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "noMethodBindingError")
 872                                            noMethodBindingErrorIdKey nO_METHOD_BINDING_ERROR_ID
 873 nonExhaustiveGuardsErrorName
 874   = mkWiredInIdName cONTROL_EXCEPTION_BASE (fsLit "nonExhaustiveGuardsError")
 875                     nonExhaustiveGuardsErrorIdKey nON_EXHAUSTIVE_GUARDS_ERROR_ID
 876 \end{code}
 877
 878 \begin{code}
 879 ------------------------------------------------
 880 -- unsafeCoerce# :: forall a b. a -> b
 881 unsafeCoerceId
 882   = pcMiscPrelId unsafeCoerceName ty info
 883   where
 884     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 885
 886
 887     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
 888                       (mkFunTy openAlphaTy openBetaTy)
 889     [x] = mkTemplateLocals [openAlphaTy]
 890     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
 891           Cast (Var x) (mkUnsafeCoercion openAlphaTy openBetaTy)
 892
 893 ------------------------------------------------
 894 nullAddrId :: Id
 895 -- nullAddr# :: Addr#
 896 -- The reason is is here is because we don't provide
 897 -- a way to write this literal in Haskell.
 898 nullAddrId = pcMiscPrelId nullAddrName addrPrimTy info
 899   where
 900     info = noCafIdInfo `setUnfoldingInfo`
 901            mkCompulsoryUnfolding (Lit nullAddrLit)
 902
 903 ------------------------------------------------
 904 seqId :: Id     -- See Note [seqId magic]
 905 seqId = pcMiscPrelId seqName ty info
 906   where
 907     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 908
 909
 910     ty  = mkForAllTys [alphaTyVar,openBetaTyVar]
 911                       (mkFunTy alphaTy (mkFunTy openBetaTy openBetaTy))
 912     [x,y] = mkTemplateLocals [alphaTy, openBetaTy]
 913     rhs = mkLams [alphaTyVar,openBetaTyVar,x,y] (Case (Var x) x openBetaTy [(DEFAULT, [], Var y)])
 914
 915 ------------------------------------------------
 916 lazyId :: Id    -- See Note [lazyId magic]
 917 lazyId = pcMiscPrelId lazyIdName ty info
 918   where
 919     info = noCafIdInfo
 920     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
 921 \end{code}
 922
 923 Note [seqId magic]
 924 ~~~~~~~~~~~~~~~~~~
 925 'seq' is special in several ways.
 926
 927 a) Its second arg can have an unboxed type
 928       x `seq` (v +# w)
 929
 930 b) Its fixity is set in LoadIface.ghcPrimIface
 931
 932 c) It has quite a bit of desugaring magic.
 933    See DsUtils.lhs Note [Desugaring seq (1)] and (2) and (3)
 934
 935 d) There is some special rule handing: Note [RULES for seq]
 936
 937 Note [Rules for seq]
 938 ~~~~~~~~~~~~~~~~~~~~
 939 Roman found situations where he had
 940       case (f n) of _ -> e
 941 where he knew that f (which was strict in n) would terminate if n did.
 942 Notice that the result of (f n) is discarded. So it makes sense to
 943 transform to
 944       case n of _ -> e
 945
 946 Rather than attempt some general analysis to support this, I've added
 947 enough support that you can do this using a rewrite rule:
 948
 949   RULE "f/seq" forall n.  seq (f n) e = seq n e
 950
 951 You write that rule.  When GHC sees a case expression that discards
 952 its result, it mentally transforms it to a call to 'seq' and looks for
 953 a RULE.  (This is done in Simplify.rebuildCase.)  As usual, the
 954 correctness of the rule is up to you.
 955
 956 To make this work, we need to be careful that the magical desugaring
 957 done in Note [seqId magic] item (c) is *not* done on the LHS of a rule.
 958 Or rather, we arrange to un-do it, in DsBinds.decomposeRuleLhs.
 959
 960
 961 Note [lazyId magic]
 962 ~~~~~~~~~~~~~~~~~~~
 963     lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
 964
 965 Used to lazify pseq:   pseq a b = a `seq` lazy b
 966
 967 Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
 968 not from GHC.Base.hi.   This is important, because the strictness
 969 analyser will spot it as strict!
 970
 971 Also no unfolding in lazyId: it gets "inlined" by a HACK in CorePrep.
 972 It's very important to do this inlining *after* unfoldings are exposed
 973 in the interface file.  Otherwise, the unfolding for (say) pseq in the
 974 interface file will not mention 'lazy', so if we inline 'pseq' we'll totally
 975 miss the very thing that 'lazy' was there for in the first place.
 976 See Trac #3259 for a real world example.
 977
 978 lazyId is defined in GHC.Base, so we don't *have* to inline it.  If it
 979 appears un-applied, we'll end up just calling it.
 980
 981 -------------------------------------------------------------
 982 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
 983 nasty as-is, change it back to a literal (@Literal@).
 984
 985 voidArgId is a Local Id used simply as an argument in functions
 986 where we just want an arg to avoid having a thunk of unlifted type.
 987 E.g.
 988         x = \ void :: State# RealWorld -> (# p, q #)
 989
 990 This comes up in strictness analysis
 991
 992 \begin{code}
 993 realWorldPrimId -- :: State# RealWorld
 994   = pcMiscPrelId realWorldName realWorldStatePrimTy
 995                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
 996         -- The evaldUnfolding makes it look that realWorld# is evaluated
 997         -- which in turn makes Simplify.interestingArg return True,
 998         -- which in turn makes INLINE things applied to realWorld# likely
 999         -- to be inlined
1000
1001 voidArgId :: Id
1002 voidArgId       -- :: State# RealWorld
1003   = mkSysLocal (fsLit "void") voidArgIdKey realWorldStatePrimTy
1004 \end{code}
1005
1006
1007 %************************************************************************
1008 %*                                                                      *
1009 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
1010 %*                                                                      *
1011 %************************************************************************
1012
1013 GHC randomly injects these into the code.
1014
1015 @patError@ is just a version of @error@ for pattern-matching
1016 failures.  It knows various ``codes'' which expand to longer
1017 strings---this saves space!
1018
1019 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
1020 well shouldn't be yanked on, but if one is, then you will get a
1021 friendly message from @absentErr@ (rather than a totally random
1022 crash).
1023
1024 @parError@ is a special version of @error@ which the compiler does
1025 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
1026 templates, but we don't ever expect to generate code for it.
1027
1028 \begin{code}
1029 mkRuntimeErrorApp
1030         :: Id           -- Should be of type (forall a. Addr# -> a)
1031                         --      where Addr# points to a UTF8 encoded string
1032         -> Type         -- The type to instantiate 'a'
1033         -> String       -- The string to print
1034         -> CoreExpr
1035
1036 mkRuntimeErrorApp err_id res_ty err_msg
1037   = mkApps (Var err_id) [Type res_ty, err_string]
1038   where
1039     err_string = Lit (mkMachString err_msg)
1040
1041 mkImpossibleExpr :: Type -> CoreExpr
1042 mkImpossibleExpr res_ty
1043   = mkRuntimeErrorApp rUNTIME_ERROR_ID res_ty "Impossible case alternative"
1044
1045 rEC_SEL_ERROR_ID                = mkRuntimeErrorId recSelErrorName
1046 rUNTIME_ERROR_ID                = mkRuntimeErrorId runtimeErrorName
1047 iRREFUT_PAT_ERROR_ID            = mkRuntimeErrorId irrefutPatErrorName
1048 rEC_CON_ERROR_ID                = mkRuntimeErrorId recConErrorName
1049 pAT_ERROR_ID                    = mkRuntimeErrorId patErrorName
1050 nO_METHOD_BINDING_ERROR_ID      = mkRuntimeErrorId noMethodBindingErrorName
1051 nON_EXHAUSTIVE_GUARDS_ERROR_ID  = mkRuntimeErrorId nonExhaustiveGuardsErrorName
1052
1053 -- The runtime error Ids take a UTF8-encoded string as argument
1054
1055 mkRuntimeErrorId :: Name -> Id
1056 mkRuntimeErrorId name = pc_bottoming_Id name runtimeErrorTy
1057
1058 runtimeErrorTy :: Type
1059 runtimeErrorTy = mkSigmaTy [openAlphaTyVar] [] (mkFunTy addrPrimTy openAlphaTy)
1060 \end{code}
1061
1062 \begin{code}
1063 eRROR_ID = pc_bottoming_Id errorName errorTy
1064
1065 errorTy  :: Type
1066 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy] openAlphaTy)
1067     -- Notice the openAlphaTyVar.  It says that "error" can be applied
1068     -- to unboxed as well as boxed types.  This is OK because it never
1069     -- returns, so the return type is irrelevant.
1070 \end{code}
1071
1072
1073 %************************************************************************
1074 %*                                                                      *
1075 \subsection{Utilities}
1076 %*                                                                      *
1077 %************************************************************************
1078
1079 \begin{code}
1080 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1081 pcMiscPrelId name ty info
1082   = mkVanillaGlobalWithInfo name ty info
1083     -- We lie and say the thing is imported; otherwise, we get into
1084     -- a mess with dependency analysis; e.g., core2stg may heave in
1085     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1086     -- being compiled, then it's just a matter of luck if the definition
1087     -- will be in "the right place" to be in scope.
1088
1089 pc_bottoming_Id :: Name -> Type -> Id
1090 -- Function of arity 1, which diverges after being given one argument
1091 pc_bottoming_Id name ty
1092  = pcMiscPrelId name ty bottoming_info
1093  where
1094     bottoming_info = vanillaIdInfo `setAllStrictnessInfo` Just strict_sig
1095                                    `setArityInfo`         1
1096                         -- Make arity and strictness agree
1097
1098         -- Do *not* mark them as NoCafRefs, because they can indeed have
1099         -- CAF refs.  For example, pAT_ERROR_ID calls GHC.Err.untangle,
1100         -- which has some CAFs
1101         -- In due course we may arrange that these error-y things are
1102         -- regarded by the GC as permanently live, in which case we
1103         -- can give them NoCaf info.  As it is, any function that calls
1104         -- any pc_bottoming_Id will itself have CafRefs, which bloats
1105         -- SRTs.
1106
1107     strict_sig = mkStrictSig (mkTopDmdType [evalDmd] BotRes)
1108         -- These "bottom" out, no matter what their arguments
1109 \end{code}
1110