compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1998
   4 %
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9 - data constructors
  10 - record selectors
  11 - method and superclass selectors
  12 - primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkDictFunId, mkDictFunTy, mkDefaultMethodId, mkDictSelId,
  17
  18         mkDataConIds,
  19         mkPrimOpId, mkFCallId, mkTickBoxOpId, mkBreakPointOpId,
  20
  21         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  22         wrapFamInstBody, unwrapFamInstScrut,
  23         mkUnpackCase, mkProductBox,
  24
  25         -- And some particular Ids; see below for why they are wired in
  26         wiredInIds, ghcPrimIds,
  27         unsafeCoerceName, unsafeCoerceId, realWorldPrimId,
  28         voidArgId, nullAddrId, seqId, lazyId, lazyIdKey
  29     ) where
  30
  31 #include "HsVersions.h"
  32
  33 import Rules
  34 import TysPrim
  35 import PrelRules
  36 import Type
  37 import Coercion
  38 import TcType
  39 import MkCore
  40 import CoreUtils        ( exprType, mkCoerce )
  41 import CoreUnfold
  42 import Literal
  43 import TyCon
  44 import Class
  45 import VarSet
  46 import Name
  47 import PrimOp
  48 import ForeignCall
  49 import DataCon
  50 import Id
  51 import Var              ( Var, TyVar, mkCoVar, mkExportedLocalVar )
  52 import IdInfo
  53 import Demand
  54 import CoreSyn
  55 import Unique
  56 import PrelNames
  57 import BasicTypes       hiding ( SuccessFlag(..) )
  58 import Util
  59 import Outputable
  60 import FastString
  61 import ListSetOps
  62 import Module
  63 \end{code}
  64
  65 %************************************************************************
  66 %*                                                                      *
  67 \subsection{Wired in Ids}
  68 %*                                                                      *
  69 %************************************************************************
  70
  71 Note [Wired-in Ids]
  72 ~~~~~~~~~~~~~~~~~~~
  73 There are several reasons why an Id might appear in the wiredInIds:
  74
  75 (1) The ghcPrimIds are wired in because they can't be defined in
  76     Haskell at all, although the can be defined in Core.  They have
  77     compulsory unfoldings, so they are always inlined and they  have
  78     no definition site.  Their home module is GHC.Prim, so they
  79     also have a description in primops.txt.pp, where they are called
  80     'pseudoops'.
  81
  82 (2) The 'error' function, eRROR_ID, is wired in because we don't yet have
  83     a way to express in an interface file that the result type variable
  84     is 'open'; that is can be unified with an unboxed type
  85
  86     [The interface file format now carry such information, but there's
  87     no way yet of expressing at the definition site for these
  88     error-reporting functions that they have an 'open'
  89     result type. -- sof 1/99]
  90
  91 (3) Other error functions (rUNTIME_ERROR_ID) are wired in (a) because
  92     the desugarer generates code that mentiones them directly, and
  93     (b) for the same reason as eRROR_ID
  94
  95 (4) lazyId is wired in because the wired-in version overrides the
  96     strictness of the version defined in GHC.Base
  97
  98 In cases (2-4), the function has a definition in a library module, and
  99 can be called; but the wired-in version means that the details are
 100 never read from that module's interface file; instead, the full definition
 101 is right here.
 102
 103 \begin{code}
 104 wiredInIds :: [Id]
 105 wiredInIds
 106   =  [lazyId]
 107   ++ errorIds           -- Defined in MkCore
 108   ++ ghcPrimIds
 109
 110 -- These Ids are exported from GHC.Prim
 111 ghcPrimIds :: [Id]
 112 ghcPrimIds
 113   = [   -- These can't be defined in Haskell, but they have
 114         -- perfectly reasonable unfoldings in Core
 115     realWorldPrimId,
 116     unsafeCoerceId,
 117     nullAddrId,
 118     seqId
 119     ]
 120 \end{code}
 121
 122 %************************************************************************
 123 %*                                                                      *
 124 \subsection{Data constructors}
 125 %*                                                                      *
 126 %************************************************************************
 127
 128 The wrapper for a constructor is an ordinary top-level binding that evaluates
 129 any strict args, unboxes any args that are going to be flattened, and calls
 130 the worker.
 131
 132 We're going to build a constructor that looks like:
 133
 134         data (Data a, C b) =>  T a b = T1 !a !Int b
 135
 136         T1 = /\ a b ->
 137              \d1::Data a, d2::C b ->
 138              \p q r -> case p of { p ->
 139                        case q of { q ->
 140                        Con T1 [a,b] [p,q,r]}}
 141
 142 Notice that
 143
 144 * d2 is thrown away --- a context in a data decl is used to make sure
 145   one *could* construct dictionaries at the site the constructor
 146   is used, but the dictionary isn't actually used.
 147
 148 * We have to check that we can construct Data dictionaries for
 149   the types a and Int.  Once we've done that we can throw d1 away too.
 150
 151 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 152   all that matters is that the arguments are evaluated.  "seq" is
 153   very careful to preserve evaluation order, which we don't need
 154   to be here.
 155
 156   You might think that we could simply give constructors some strictness
 157   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 158   But we don't do that because in the case of primops and functions strictness
 159   is a *property* not a *requirement*.  In the case of constructors we need to
 160   do something active to evaluate the argument.
 161
 162   Making an explicit case expression allows the simplifier to eliminate
 163   it in the (common) case where the constructor arg is already evaluated.
 164
 165 Note [Wrappers for data instance tycons]
 166 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 167 In the case of data instances, the wrapper also applies the coercion turning
 168 the representation type into the family instance type to cast the result of
 169 the wrapper.  For example, consider the declarations
 170
 171   data family Map k :: * -> *
 172   data instance Map (a, b) v = MapPair (Map a (Pair b v))
 173
 174 The tycon to which the datacon MapPair belongs gets a unique internal
 175 name of the form :R123Map, and we call it the representation tycon.
 176 In contrast, Map is the family tycon (accessible via
 177 tyConFamInst_maybe). A coercion allows you to move between
 178 representation and family type.  It is accessible from :R123Map via
 179 tyConFamilyCoercion_maybe and has kind
 180
 181   Co123Map a b v :: {Map (a, b) v ~ :R123Map a b v}
 182
 183 The wrapper and worker of MapPair get the types
 184
 185         -- Wrapper
 186   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
 187   $WMapPair a b v = MapPair a b v `cast` sym (Co123Map a b v)
 188
 189         -- Worker
 190   MapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
 191
 192 This coercion is conditionally applied by wrapFamInstBody.
 193
 194 It's a bit more complicated if the data instance is a GADT as well!
 195
 196    data instance T [a] where
 197         T1 :: forall b. b -> T [Maybe b]
 198
 199 Hence we translate to
 200
 201         -- Wrapper
 202   $WT1 :: forall b. b -> T [Maybe b]
 203   $WT1 b v = T1 (Maybe b) b (Maybe b) v
 204                         `cast` sym (Co7T (Maybe b))
 205
 206         -- Worker
 207   T1 :: forall c b. (c ~ Maybe b) => b -> :R7T c
 208
 209         -- Coercion from family type to representation type
 210   Co7T a :: T [a] ~ :R7T a
 211
 212 \begin{code}
 213 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 214 mkDataConIds wrap_name wkr_name data_con
 215   | isNewTyCon tycon                    -- Newtype, only has a worker
 216   = DCIds Nothing nt_work_id
 217
 218   | any isBanged all_strict_marks      -- Algebraic, needs wrapper
 219     || not (null eq_spec)              -- NB: LoadIface.ifaceDeclSubBndrs
 220     || isFamInstTyCon tycon            --     depends on this test
 221   = DCIds (Just alg_wrap_id) wrk_id
 222
 223   | otherwise                                -- Algebraic, no wrapper
 224   = DCIds Nothing wrk_id
 225   where
 226     (univ_tvs, ex_tvs, eq_spec,
 227      eq_theta, dict_theta, orig_arg_tys, res_ty) = dataConFullSig data_con
 228     tycon = dataConTyCon data_con       -- The representation TyCon (not family)
 229
 230         ----------- Worker (algebraic data types only) --------------
 231         -- The *worker* for the data constructor is the function that
 232         -- takes the representation arguments and builds the constructor.
 233     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 234                         (dataConRepType data_con) wkr_info
 235
 236     wkr_arity = dataConRepArity data_con
 237     wkr_info  = noCafIdInfo
 238                 `setArityInfo`          wkr_arity
 239                 `setStrictnessInfo`  Just wkr_sig
 240                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 241                                                         -- even if arity = 0
 242
 243     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 244         --      Note [Data-con worker strictness]
 245         -- Notice that we do *not* say the worker is strict
 246         -- even if the data constructor is declared strict
 247         --      e.g.    data T = MkT !(Int,Int)
 248         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 249         -- expresssions that do the evals) but the *worker* itself is not.
 250         -- If we pretend it is strict then when we see
 251         --      case x of y -> $wMkT y
 252         -- the simplifier thinks that y is "sure to be evaluated" (because
 253         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 254         --
 255         -- When the simplifer sees a pattern
 256         --      case e of MkT x -> ...
 257         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 258         -- but that's fine... dataConRepStrictness comes from the data con
 259         -- not from the worker Id.
 260
 261     cpr_info | isProductTyCon tycon &&
 262                isDataTyCon tycon    &&
 263                wkr_arity > 0        &&
 264                wkr_arity <= mAX_CPR_SIZE        = retCPR
 265              | otherwise                        = TopRes
 266         -- RetCPR is only true for products that are real data types;
 267         -- that is, not unboxed tuples or [non-recursive] newtypes
 268
 269         ----------- Workers for newtypes --------------
 270     nt_work_id   = mkGlobalId (DataConWrapId data_con) wkr_name wrap_ty nt_work_info
 271     nt_work_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 272                   `setArityInfo` 1      -- Arity 1
 273                   `setUnfoldingInfo`     newtype_unf
 274     id_arg1      = mkTemplateLocal 1 (head orig_arg_tys)
 275     newtype_unf  = ASSERT2( isVanillaDataCon data_con &&
 276                             isSingleton orig_arg_tys, ppr data_con  )
 277                               -- Note [Newtype datacons]
 278                    mkCompulsoryUnfolding $
 279                    mkLams wrap_tvs $ Lam id_arg1 $
 280                    wrapNewTypeBody tycon res_ty_args (Var id_arg1)
 281
 282
 283         ----------- Wrapper --------------
 284         -- We used to include the stupid theta in the wrapper's args
 285         -- but now we don't.  Instead the type checker just injects these
 286         -- extra constraints where necessary.
 287     wrap_tvs    = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 288     res_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
 289     eq_tys   = mkPredTys eq_theta
 290     dict_tys = mkPredTys dict_theta
 291     wrap_ty  = mkForAllTys wrap_tvs $ mkFunTys eq_tys $ mkFunTys dict_tys $
 292                mkFunTys orig_arg_tys $ res_ty
 293         -- NB: watch out here if you allow user-written equality
 294         --     constraints in data constructor signatures
 295
 296         ----------- Wrappers for algebraic data types --------------
 297     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 298     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 299                     `setArityInfo`         wrap_arity
 300                         -- It's important to specify the arity, so that partial
 301                         -- applications are treated as values
 302                     `setInlinePragInfo`    alwaysInlinePragma
 303                     `setUnfoldingInfo`     wrap_unf
 304                     `setStrictnessInfo` Just wrap_sig
 305
 306     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 307     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 308     arg_dmds = map mk_dmd all_strict_marks
 309     mk_dmd str | isBanged str = evalDmd
 310                | otherwise    = lazyDmd
 311         -- The Cpr info can be important inside INLINE rhss, where the
 312         -- wrapper constructor isn't inlined.
 313         -- And the argument strictness can be important too; we
 314         -- may not inline a contructor when it is partially applied.
 315         -- For example:
 316         --      data W = C !Int !Int !Int
 317         --      ...(let w = C x in ...(w p q)...)...
 318         -- we want to see that w is strict in its two arguments
 319
 320     wrap_unf = mkInlineUnfolding (Just (length dict_args + length id_args)) wrap_rhs
 321     wrap_rhs = mkLams wrap_tvs $
 322                mkLams eq_args $
 323                mkLams dict_args $ mkLams id_args $
 324                foldr mk_case con_app
 325                      (zip (dict_args ++ id_args) all_strict_marks)
 326                      i3 []
 327
 328     con_app _ rep_ids = wrapFamInstBody tycon res_ty_args $
 329                           Var wrk_id `mkTyApps`  res_ty_args
 330                                      `mkVarApps` ex_tvs
 331                                      -- Equality evidence:
 332                                      `mkTyApps`  map snd eq_spec
 333                                      `mkVarApps` eq_args
 334                                      `mkVarApps` reverse rep_ids
 335
 336     (dict_args,i2) = mkLocals 1  dict_tys
 337     (id_args,i3)   = mkLocals i2 orig_arg_tys
 338     wrap_arity     = i3-1
 339     (eq_args,_)    = mkCoVarLocals i3 eq_tys
 340
 341     mkCoVarLocals i []     = ([],i)
 342     mkCoVarLocals i (x:xs) = let (ys,j) = mkCoVarLocals (i+1) xs
 343                                  y      = mkCoVar (mkSysTvName (mkBuiltinUnique i)
 344                                                   (fsLit "dc_co")) x
 345                              in (y:ys,j)
 346
 347     mk_case
 348            :: (Id, HsBang)      -- Arg, strictness
 349            -> (Int -> [Id] -> CoreExpr) -- Body
 350            -> Int                       -- Next rep arg id
 351            -> [Id]                      -- Rep args so far, reversed
 352            -> CoreExpr
 353     mk_case (arg,strict) body i rep_args
 354           = case strict of
 355                 HsNoBang -> body i (arg:rep_args)
 356                 HsUnpack -> unboxProduct i (Var arg) (idType arg) the_body
 357                       where
 358                         the_body i con_args = body i (reverse con_args ++ rep_args)
 359                 _other  -- HsUnpackFailed and HsStrict
 360                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 361                    | otherwise -> Case (Var arg) arg res_ty
 362                                        [(DEFAULT,[], body i (arg:rep_args))]
 363
 364 mAX_CPR_SIZE :: Arity
 365 mAX_CPR_SIZE = 10
 366 -- We do not treat very big tuples as CPR-ish:
 367 --      a) for a start we get into trouble because there aren't
 368 --         "enough" unboxed tuple types (a tiresome restriction,
 369 --         but hard to fix),
 370 --      b) more importantly, big unboxed tuples get returned mainly
 371 --         on the stack, and are often then allocated in the heap
 372 --         by the caller.  So doing CPR for them may in fact make
 373 --         things worse.
 374
 375 mkLocals :: Int -> [Type] -> ([Id], Int)
 376 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 377                where
 378                  n = length tys
 379 \end{code}
 380
 381 Note [Newtype datacons]
 382 ~~~~~~~~~~~~~~~~~~~~~~~
 383 The "data constructor" for a newtype should always be vanilla.  At one
 384 point this wasn't true, because the newtype arising from
 385      class C a => D a
 386 looked like
 387        newtype T:D a = D:D (C a)
 388 so the data constructor for T:C had a single argument, namely the
 389 predicate (C a).  But now we treat that as an ordinary argument, not
 390 part of the theta-type, so all is well.
 391
 392
 393 %************************************************************************
 394 %*                                                                      *
 395 \subsection{Dictionary selectors}
 396 %*                                                                      *
 397 %************************************************************************
 398
 399 Selecting a field for a dictionary.  If there is just one field, then
 400 there's nothing to do.
 401
 402 Dictionary selectors may get nested forall-types.  Thus:
 403
 404         class Foo a where
 405           op :: forall b. Ord b => a -> b -> b
 406
 407 Then the top-level type for op is
 408
 409         op :: forall a. Foo a =>
 410               forall b. Ord b =>
 411               a -> b -> b
 412
 413 This is unlike ordinary record selectors, which have all the for-alls
 414 at the outside.  When dealing with classes it's very convenient to
 415 recover the original type signature from the class op selector.
 416
 417 \begin{code}
 418 mkDictSelId :: Bool          -- True <=> don't include the unfolding
 419                              -- Little point on imports without -O, because the
 420                              -- dictionary itself won't be visible
 421             -> Name          -- Name of one of the *value* selectors
 422                              -- (dictionary superclass or method)
 423             -> Class -> Id
 424 mkDictSelId no_unf name clas
 425   = mkGlobalId (ClassOpId clas) name sel_ty info
 426   where
 427     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 428         -- We can't just say (exprType rhs), because that would give a type
 429         --      C a -> C a
 430         -- for a single-op class (after all, the selector is the identity)
 431         -- But it's type must expose the representation of the dictionary
 432         -- to get (say)         C a -> (a -> a)
 433
 434     base_info = noCafIdInfo
 435                 `setArityInfo`      1
 436                 `setStrictnessInfo`  Just strict_sig
 437                 `setUnfoldingInfo`  (if no_unf then noUnfolding
 438                                      else mkImplicitUnfolding rhs)
 439                    -- In module where class op is defined, we must add
 440                    -- the unfolding, even though it'll never be inlined
 441                    -- becuase we use that to generate a top-level binding
 442                    -- for the ClassOp
 443
 444     info = base_info    `setSpecInfo`       mkSpecInfo [rule]
 445                         `setInlinePragInfo` neverInlinePragma
 446                 -- Add a magic BuiltinRule, and never inline it
 447                 -- so that the rule is always available to fire.
 448                 -- See Note [ClassOp/DFun selection] in TcInstDcls
 449
 450     n_ty_args = length tyvars
 451
 452     -- This is the built-in rule that goes
 453     --      op (dfT d1 d2) --->  opT d1 d2
 454     rule = BuiltinRule { ru_name = fsLit "Class op " `appendFS`
 455                                      occNameFS (getOccName name)
 456                        , ru_fn    = name
 457                        , ru_nargs = n_ty_args + 1
 458                        , ru_try   = dictSelRule val_index n_ty_args n_eq_args }
 459
 460         -- The strictness signature is of the form U(AAAVAAAA) -> T
 461         -- where the V depends on which item we are selecting
 462         -- It's worth giving one, so that absence info etc is generated
 463         -- even if the selector isn't inlined
 464     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 465     arg_dmd | new_tycon = evalDmd
 466             | otherwise = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 467                                      | id <- arg_ids ])
 468
 469     tycon          = classTyCon clas
 470     new_tycon      = isNewTyCon tycon
 471     [data_con]     = tyConDataCons tycon
 472     tyvars         = dataConUnivTyVars data_con
 473     arg_tys        = dataConRepArgTys data_con  -- Includes the dictionary superclasses
 474     eq_theta       = dataConEqTheta data_con
 475     n_eq_args      = length eq_theta
 476
 477     -- 'index' is a 0-index into the *value* arguments of the dictionary
 478     val_index      = assoc "MkId.mkDictSelId" sel_index_prs name
 479     sel_index_prs  = map idName (classAllSelIds clas) `zip` [0..]
 480
 481     the_arg_id     = arg_ids !! val_index
 482     pred           = mkClassPred clas (mkTyVarTys tyvars)
 483     dict_id        = mkTemplateLocal 1 $ mkPredTy pred
 484     arg_ids        = mkTemplateLocalsNum 2 arg_tys
 485     eq_ids         = map mkWildEvBinder eq_theta
 486
 487     rhs = mkLams tyvars  (Lam dict_id   rhs_body)
 488     rhs_body | new_tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 489              | otherwise = Case (Var dict_id) dict_id (idType the_arg_id)
 490                                 [(DataAlt data_con, eq_ids ++ arg_ids, Var the_arg_id)]
 491
 492 dictSelRule :: Int -> Arity -> Arity
 493             -> IdUnfoldingFun -> [CoreExpr] -> Maybe CoreExpr
 494 -- Tries to persuade the argument to look like a constructor
 495 -- application, using exprIsConApp_maybe, and then selects
 496 -- from it
 497 --       sel_i t1..tk (D t1..tk op1 ... opm) = opi
 498 --
 499 dictSelRule val_index n_ty_args n_eq_args id_unf args
 500   | (dict_arg : _) <- drop n_ty_args args
 501   , Just (_, _, con_args) <- exprIsConApp_maybe id_unf dict_arg
 502   , let val_args = drop n_eq_args con_args
 503   = Just (val_args !! val_index)
 504   | otherwise
 505   = Nothing
 506 \end{code}
 507
 508
 509 %************************************************************************
 510 %*                                                                      *
 511         Boxing and unboxing
 512 %*                                                                      *
 513 %************************************************************************
 514
 515 \begin{code}
 516 -- unbox a product type...
 517 -- we will recurse into newtypes, casting along the way, and unbox at the
 518 -- first product data constructor we find. e.g.
 519 --
 520 --   data PairInt = PairInt Int Int
 521 --   newtype S = MkS PairInt
 522 --   newtype T = MkT S
 523 --
 524 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 525 -- ids, we get (modulo int passing)
 526 --
 527 --   case (e `cast` CoT) `cast` CoS of
 528 --     PairInt a b -> body [a,b]
 529 --
 530 -- The Ints passed around are just for creating fresh locals
 531 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> CoreExpr
 532 unboxProduct i arg arg_ty body
 533   = result
 534   where
 535     result = mkUnpackCase the_id arg con_args boxing_con rhs
 536     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 537     ([the_id], i') = mkLocals i [arg_ty]
 538     (con_args, i'') = mkLocals i' tys
 539     rhs = body i'' con_args
 540
 541 mkUnpackCase ::  Id -> CoreExpr -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 542 -- (mkUnpackCase x e args Con body)
 543 --      returns
 544 -- case (e `cast` ...) of bndr { Con args -> body }
 545 --
 546 -- the type of the bndr passed in is irrelevent
 547 mkUnpackCase bndr arg unpk_args boxing_con body
 548   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 549   where
 550   (cast_arg, bndr_ty) = go (idType bndr) arg
 551   go ty arg
 552     | (tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 553     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 554     = go (newTyConInstRhs tycon tycon_args)
 555          (unwrapNewTypeBody tycon tycon_args arg)
 556     | otherwise = (arg, ty)
 557
 558 -- ...and the dual
 559 reboxProduct :: [Unique]     -- uniques to create new local binders
 560              -> Type         -- type of product to box
 561              -> ([Unique],   -- remaining uniques
 562                  CoreExpr,   -- boxed product
 563                  [Id])       -- Ids being boxed into product
 564 reboxProduct us ty
 565   = let
 566         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 567
 568         us' = dropList con_arg_tys us
 569
 570         arg_ids  = zipWith (mkSysLocal (fsLit "rb")) us con_arg_tys
 571
 572         bind_rhs = mkProductBox arg_ids ty
 573
 574     in
 575       (us', bind_rhs, arg_ids)
 576
 577 mkProductBox :: [Id] -> Type -> CoreExpr
 578 mkProductBox arg_ids ty
 579   = result_expr
 580   where
 581     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
 582
 583     result_expr
 584       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 585       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 586       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 587
 588     wrap expr = wrapNewTypeBody tycon tycon_args expr
 589
 590
 591 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 592 -- alternative (con, xs, rhs)
 593 -- but it does the reboxing necessary to construct the *source*
 594 -- arguments, xs, from the representation arguments ys.
 595 -- For example:
 596 --      data T = MkT !(Int,Int) Bool
 597 --
 598 -- mkReboxingAlt MkT [x,b] r
 599 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 600 --
 601 -- mkDataAlt should really be in DataCon, but it can't because
 602 -- it manipulates CoreSyn.
 603
 604 mkReboxingAlt
 605   :: [Unique] -- Uniques for the new Ids
 606   -> DataCon
 607   -> [Var]    -- Source-level args, including existential dicts
 608   -> CoreExpr -- RHS
 609   -> CoreAlt
 610
 611 mkReboxingAlt us con args rhs
 612   | not (any isMarkedUnboxed stricts)
 613   = (DataAlt con, args, rhs)
 614
 615   | otherwise
 616   = let
 617         (binds, args') = go args stricts us
 618     in
 619     (DataAlt con, args', mkLets binds rhs)
 620
 621   where
 622     stricts = dataConExStricts con ++ dataConStrictMarks con
 623
 624     go [] _stricts _us = ([], [])
 625
 626     -- Type variable case
 627     go (arg:args) stricts us
 628       | isTyCoVar arg
 629       = let (binds, args') = go args stricts us
 630         in  (binds, arg:args')
 631
 632         -- Term variable case
 633     go (arg:args) (str:stricts) us
 634       | isMarkedUnboxed str
 635       =
 636         let (binds, unpacked_args')        = go args stricts us'
 637             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 638         in
 639             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 640       | otherwise
 641       = let (binds, args') = go args stricts us
 642         in  (binds, arg:args')
 643     go (_ : _) [] _ = panic "mkReboxingAlt"
 644 \end{code}
 645
 646
 647 %************************************************************************
 648 %*                                                                      *
 649         Wrapping and unwrapping newtypes and type families
 650 %*                                                                      *
 651 %************************************************************************
 652
 653 \begin{code}
 654 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 655 -- The wrapper for the data constructor for a newtype looks like this:
 656 --      newtype T a = MkT (a,Int)
 657 --      MkT :: forall a. (a,Int) -> T a
 658 --      MkT = /\a. \(x:(a,Int)). x `cast` sym (CoT a)
 659 -- where CoT is the coercion TyCon assoicated with the newtype
 660 --
 661 -- The call (wrapNewTypeBody T [a] e) returns the
 662 -- body of the wrapper, namely
 663 --      e `cast` (CoT [a])
 664 --
 665 -- If a coercion constructor is provided in the newtype, then we use
 666 -- it, otherwise the wrap/unwrap are both no-ops
 667 --
 668 -- If the we are dealing with a newtype *instance*, we have a second coercion
 669 -- identifying the family instance with the constructor of the newtype
 670 -- instance.  This coercion is applied in any case (ie, composed with the
 671 -- coercion constructor of the newtype or applied by itself).
 672
 673 wrapNewTypeBody tycon args result_expr
 674   = wrapFamInstBody tycon args inner
 675   where
 676     inner
 677       | Just co_con <- newTyConCo_maybe tycon
 678       = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) result_expr
 679       | otherwise
 680       = result_expr
 681
 682 -- When unwrapping, we do *not* apply any family coercion, because this will
 683 -- be done via a CoPat by the type checker.  We have to do it this way as
 684 -- computing the right type arguments for the coercion requires more than just
 685 -- a spliting operation (cf, TcPat.tcConPat).
 686
 687 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 688 unwrapNewTypeBody tycon args result_expr
 689   | Just co_con <- newTyConCo_maybe tycon
 690   = mkCoerce (mkTyConApp co_con args) result_expr
 691   | otherwise
 692   = result_expr
 693
 694 -- If the type constructor is a representation type of a data instance, wrap
 695 -- the expression into a cast adjusting the expression type, which is an
 696 -- instance of the representation type, to the corresponding instance of the
 697 -- family instance type.
 698 -- See Note [Wrappers for data instance tycons]
 699 wrapFamInstBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 700 wrapFamInstBody tycon args body
 701   | Just co_con <- tyConFamilyCoercion_maybe tycon
 702   = mkCoerce (mkSymCoercion (mkTyConApp co_con args)) body
 703   | otherwise
 704   = body
 705
 706 unwrapFamInstScrut :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 707 unwrapFamInstScrut tycon args scrut
 708   | Just co_con <- tyConFamilyCoercion_maybe tycon
 709   = mkCoerce (mkTyConApp co_con args) scrut
 710   | otherwise
 711   = scrut
 712 \end{code}
 713
 714
 715 %************************************************************************
 716 %*                                                                      *
 717 \subsection{Primitive operations}
 718 %*                                                                      *
 719 %************************************************************************
 720
 721 \begin{code}
 722 mkPrimOpId :: PrimOp -> Id
 723 mkPrimOpId prim_op
 724   = id
 725   where
 726     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 727     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 728     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 729                          (mkPrimOpIdUnique (primOpTag prim_op))
 730                          (AnId id) UserSyntax
 731     id   = mkGlobalId (PrimOpId prim_op) name ty info
 732
 733     info = noCafIdInfo
 734            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 735            `setArityInfo`         arity
 736            `setStrictnessInfo` Just strict_sig
 737
 738 -- For each ccall we manufacture a separate CCallOpId, giving it
 739 -- a fresh unique, a type that is correct for this particular ccall,
 740 -- and a CCall structure that gives the correct details about calling
 741 -- convention etc.
 742 --
 743 -- The *name* of this Id is a local name whose OccName gives the full
 744 -- details of the ccall, type and all.  This means that the interface
 745 -- file reader can reconstruct a suitable Id
 746
 747 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 748 mkFCallId uniq fcall ty
 749   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 750     -- A CCallOpId should have no free type variables;
 751     -- when doing substitutions won't substitute over it
 752     mkGlobalId (FCallId fcall) name ty info
 753   where
 754     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 755     -- The "occurrence name" of a ccall is the full info about the
 756     -- ccall; it is encoded, but may have embedded spaces etc!
 757
 758     name = mkFCallName uniq occ_str
 759
 760     info = noCafIdInfo
 761            `setArityInfo`         arity
 762            `setStrictnessInfo` Just strict_sig
 763
 764     (_, tau)     = tcSplitForAllTys ty
 765     (arg_tys, _) = tcSplitFunTys tau
 766     arity        = length arg_tys
 767     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 768
 769 -- Tick boxes and breakpoints are both represented as TickBoxOpIds,
 770 -- except for the type:
 771 --
 772 --    a plain HPC tick box has type (State# RealWorld)
 773 --    a breakpoint Id has type forall a.a
 774 --
 775 -- The breakpoint Id will be applied to a list of arbitrary free variables,
 776 -- which is why it needs a polymorphic type.
 777
 778 mkTickBoxOpId :: Unique -> Module -> TickBoxId -> Id
 779 mkTickBoxOpId uniq mod ix = mkTickBox' uniq mod ix realWorldStatePrimTy
 780
 781 mkBreakPointOpId :: Unique -> Module -> TickBoxId -> Id
 782 mkBreakPointOpId uniq mod ix = mkTickBox' uniq mod ix ty
 783  where ty = mkSigmaTy [openAlphaTyVar] [] openAlphaTy
 784
 785 mkTickBox' :: Unique -> Module -> TickBoxId -> Type -> Id
 786 mkTickBox' uniq mod ix ty = mkGlobalId (TickBoxOpId tickbox) name ty info
 787   where
 788     tickbox = TickBox mod ix
 789     occ_str = showSDoc (braces (ppr tickbox))
 790     name    = mkTickBoxOpName uniq occ_str
 791     info    = noCafIdInfo
 792 \end{code}
 793
 794
 795 %************************************************************************
 796 %*                                                                      *
 797 \subsection{DictFuns and default methods}
 798 %*                                                                      *
 799 %************************************************************************
 800
 801 Important notes about dict funs and default methods
 802 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 803 Dict funs and default methods are *not* ImplicitIds.  Their definition
 804 involves user-written code, so we can't figure out their strictness etc
 805 based on fixed info, as we can for constructors and record selectors (say).
 806
 807 We build them as LocalIds, but with External Names.  This ensures that
 808 they are taken to account by free-variable finding and dependency
 809 analysis (e.g. CoreFVs.exprFreeVars).
 810
 811 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
 812 they are globals, the specialiser floats dict uses above their defns,
 813 which prevents good simplifications happening.  Also the strictness
 814 analyser treats a occurrence of a GlobalId as imported and assumes it
 815 contains strictness in its IdInfo, which isn't true if the thing is
 816 bound in the same module as the occurrence.
 817
 818 It's OK for dfuns to be LocalIds, because we form the instance-env to
 819 pass on to the next module (md_insts) in CoreTidy, afer tidying
 820 and globalising the top-level Ids.
 821
 822 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
 823 that they aren't discarded by the occurrence analyser.
 824
 825 \begin{code}
 826 mkDefaultMethodId :: Id         -- Selector Id
 827                   -> Name       -- Default method name
 828                   -> Id         -- Default method Id
 829 mkDefaultMethodId sel_id dm_name = mkExportedLocalId dm_name (idType sel_id)
 830
 831 mkDictFunId :: Name      -- Name to use for the dict fun;
 832             -> [TyVar]
 833             -> ThetaType
 834             -> Class
 835             -> [Type]
 836             -> Id
 837 -- Implements the DFun Superclass Invariant (see TcInstDcls)
 838
 839 mkDictFunId dfun_name tvs theta clas tys
 840   = mkExportedLocalVar (DFunId n_silent is_nt)
 841                        dfun_name
 842                        dfun_ty
 843                        vanillaIdInfo
 844   where
 845     is_nt = isNewTyCon (classTyCon clas)
 846     (n_silent, dfun_ty) = mkDictFunTy tvs theta clas tys
 847
 848 mkDictFunTy :: [TyVar] -> ThetaType -> Class -> [Type] -> (Int, Type)
 849 mkDictFunTy tvs theta clas tys
 850   = (length silent_theta, dfun_ty)
 851   where
 852     dfun_ty = mkSigmaTy tvs (silent_theta ++ theta) (mkDictTy clas tys)
 853     silent_theta = filterOut discard $
 854                    substTheta (zipTopTvSubst (classTyVars clas) tys)
 855                               (classSCTheta clas)
 856                    -- See Note [Silent Superclass Arguments]
 857     discard pred = isEmptyVarSet (tyVarsOfPred pred)
 858                  || any (`tcEqPred` pred) theta
 859                  -- See the DFun Superclass Invariant in TcInstDcls
 860 \end{code}
 861
 862
 863 %************************************************************************
 864 %*                                                                      *
 865 \subsection{Un-definable}
 866 %*                                                                      *
 867 %************************************************************************
 868
 869 These Ids can't be defined in Haskell.  They could be defined in
 870 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
 871 ensure that they were definitely, definitely inlined, because there is
 872 no curried identifier for them.  That's what mkCompulsoryUnfolding
 873 does.  If we had a way to get a compulsory unfolding from an interface
 874 file, we could do that, but we don't right now.
 875
 876 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 877 just gets expanded into a type coercion wherever it occurs.  Hence we
 878 add it as a built-in Id with an unfolding here.
 879
 880 The type variables we use here are "open" type variables: this means
 881 they can unify with both unlifted and lifted types.  Hence we provide
 882 another gun with which to shoot yourself in the foot.
 883
 884 \begin{code}
 885 lazyIdName, unsafeCoerceName, nullAddrName, seqName, realWorldName :: Name
 886 unsafeCoerceName = mkWiredInIdName gHC_PRIM (fsLit "unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
 887 nullAddrName     = mkWiredInIdName gHC_PRIM (fsLit "nullAddr#")     nullAddrIdKey      nullAddrId
 888 seqName          = mkWiredInIdName gHC_PRIM (fsLit "seq")           seqIdKey           seqId
 889 realWorldName    = mkWiredInIdName gHC_PRIM (fsLit "realWorld#")    realWorldPrimIdKey realWorldPrimId
 890 lazyIdName       = mkWiredInIdName gHC_BASE (fsLit "lazy")         lazyIdKey           lazyId
 891 \end{code}
 892
 893 \begin{code}
 894 ------------------------------------------------
 895 -- unsafeCoerce# :: forall a b. a -> b
 896 unsafeCoerceId :: Id
 897 unsafeCoerceId
 898   = pcMiscPrelId unsafeCoerceName ty info
 899   where
 900     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 901
 902
 903     ty  = mkForAllTys [argAlphaTyVar,openBetaTyVar]
 904                       (mkFunTy argAlphaTy openBetaTy)
 905     [x] = mkTemplateLocals [argAlphaTy]
 906     rhs = mkLams [argAlphaTyVar,openBetaTyVar,x] $
 907           Cast (Var x) (mkUnsafeCoercion argAlphaTy openBetaTy)
 908
 909 ------------------------------------------------
 910 nullAddrId :: Id
 911 -- nullAddr# :: Addr#
 912 -- The reason is is here is because we don't provide
 913 -- a way to write this literal in Haskell.
 914 nullAddrId = pcMiscPrelId nullAddrName addrPrimTy info
 915   where
 916     info = noCafIdInfo `setUnfoldingInfo`
 917            mkCompulsoryUnfolding (Lit nullAddrLit)
 918
 919 ------------------------------------------------
 920 seqId :: Id     -- See Note [seqId magic]
 921 seqId = pcMiscPrelId seqName ty info
 922   where
 923     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 924                        `setSpecInfo` mkSpecInfo [seq_cast_rule]
 925
 926
 927     ty  = mkForAllTys [alphaTyVar,argBetaTyVar]
 928                       (mkFunTy alphaTy (mkFunTy argBetaTy argBetaTy))
 929     [x,y] = mkTemplateLocals [alphaTy, argBetaTy]
 930     rhs = mkLams [alphaTyVar,argBetaTyVar,x,y] (Case (Var x) x argBetaTy [(DEFAULT, [], Var y)])
 931
 932     -- See Note [Built-in RULES for seq]
 933     seq_cast_rule = BuiltinRule { ru_name  = fsLit "seq of cast"
 934                                 , ru_fn    = seqName
 935                                 , ru_nargs = 4
 936                                 , ru_try   = match_seq_of_cast
 937                                 }
 938
 939 match_seq_of_cast :: IdUnfoldingFun -> [CoreExpr] -> Maybe CoreExpr
 940     -- See Note [Built-in RULES for seq]
 941 match_seq_of_cast _ [Type _, Type res_ty, Cast scrut co, expr]
 942   = Just (Var seqId `mkApps` [Type (fst (coercionKind co)), Type res_ty,
 943                               scrut, expr])
 944 match_seq_of_cast _ _ = Nothing
 945
 946 ------------------------------------------------
 947 lazyId :: Id    -- See Note [lazyId magic]
 948 lazyId = pcMiscPrelId lazyIdName ty info
 949   where
 950     info = noCafIdInfo
 951     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
 952 \end{code}
 953
 954 Note [seqId magic]
 955 ~~~~~~~~~~~~~~~~~~
 956 'GHC.Prim.seq' is special in several ways.
 957
 958 a) Its second arg can have an unboxed type
 959       x `seq` (v +# w)
 960
 961 b) Its fixity is set in LoadIface.ghcPrimIface
 962
 963 c) It has quite a bit of desugaring magic.
 964    See DsUtils.lhs Note [Desugaring seq (1)] and (2) and (3)
 965
 966 d) There is some special rule handing: Note [User-defined RULES for seq]
 967
 968 e) See Note [Typing rule for seq] in TcExpr.
 969
 970 Note [User-defined RULES for seq]
 971 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 972 Roman found situations where he had
 973       case (f n) of _ -> e
 974 where he knew that f (which was strict in n) would terminate if n did.
 975 Notice that the result of (f n) is discarded. So it makes sense to
 976 transform to
 977       case n of _ -> e
 978
 979 Rather than attempt some general analysis to support this, I've added
 980 enough support that you can do this using a rewrite rule:
 981
 982   RULE "f/seq" forall n.  seq (f n) e = seq n e
 983
 984 You write that rule.  When GHC sees a case expression that discards
 985 its result, it mentally transforms it to a call to 'seq' and looks for
 986 a RULE.  (This is done in Simplify.rebuildCase.)  As usual, the
 987 correctness of the rule is up to you.
 988
 989 To make this work, we need to be careful that the magical desugaring
 990 done in Note [seqId magic] item (c) is *not* done on the LHS of a rule.
 991 Or rather, we arrange to un-do it, in DsBinds.decomposeRuleLhs.
 992
 993 Note [Built-in RULES for seq]
 994 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 995 We also have the following built-in rule for seq
 996
 997   seq (x `cast` co) y = seq x y
 998
 999 This eliminates unnecessary casts and also allows other seq rules to
1000 match more often.  Notably,
1001
1002    seq (f x `cast` co) y  -->  seq (f x) y
1003
1004 and now a user-defined rule for seq (see Note [User-defined RULES for seq])
1005 may fire.
1006
1007
1008 Note [lazyId magic]
1009 ~~~~~~~~~~~~~~~~~~~
1010     lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1011
1012 Used to lazify pseq:   pseq a b = a `seq` lazy b
1013
1014 Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1015 not from GHC.Base.hi.   This is important, because the strictness
1016 analyser will spot it as strict!
1017
1018 Also no unfolding in lazyId: it gets "inlined" by a HACK in CorePrep.
1019 It's very important to do this inlining *after* unfoldings are exposed
1020 in the interface file.  Otherwise, the unfolding for (say) pseq in the
1021 interface file will not mention 'lazy', so if we inline 'pseq' we'll totally
1022 miss the very thing that 'lazy' was there for in the first place.
1023 See Trac #3259 for a real world example.
1024
1025 lazyId is defined in GHC.Base, so we don't *have* to inline it.  If it
1026 appears un-applied, we'll end up just calling it.
1027
1028 -------------------------------------------------------------
1029 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1030 nasty as-is, change it back to a literal (@Literal@).
1031
1032 voidArgId is a Local Id used simply as an argument in functions
1033 where we just want an arg to avoid having a thunk of unlifted type.
1034 E.g.
1035         x = \ void :: State# RealWorld -> (# p, q #)
1036
1037 This comes up in strictness analysis
1038
1039 \begin{code}
1040 realWorldPrimId :: Id
1041 realWorldPrimId -- :: State# RealWorld
1042   = pcMiscPrelId realWorldName realWorldStatePrimTy
1043                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1044         -- The evaldUnfolding makes it look that realWorld# is evaluated
1045         -- which in turn makes Simplify.interestingArg return True,
1046         -- which in turn makes INLINE things applied to realWorld# likely
1047         -- to be inlined
1048
1049 voidArgId :: Id
1050 voidArgId       -- :: State# RealWorld
1051   = mkSysLocal (fsLit "void") voidArgIdKey realWorldStatePrimTy
1052 \end{code}
1053
1054
1055 \begin{code}
1056 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1057 pcMiscPrelId name ty info
1058   = mkVanillaGlobalWithInfo name ty info
1059     -- We lie and say the thing is imported; otherwise, we get into
1060     -- a mess with dependency analysis; e.g., core2stg may heave in
1061     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1062     -- being compiled, then it's just a matter of luck if the definition
1063     -- will be in "the right place" to be in scope.
1064 \end{code}