compiler/basicTypes/MkId.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[StdIdInfo]{Standard unfoldings}
   5
   6 This module contains definitions for the IdInfo for things that
   7 have a standard form, namely:
   8
   9         * data constructors
  10         * record selectors
  11         * method and superclass selectors
  12         * primitive operations
  13
  14 \begin{code}
  15 module MkId (
  16         mkDictFunId, mkDefaultMethodId,
  17         mkDictSelId,
  18
  19         mkDataConIds,
  20         mkRecordSelId,
  21         mkPrimOpId, mkFCallId,
  22
  23         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
  24         mkUnpackCase, mkProductBox,
  25
  26         -- And some particular Ids; see below for why they are wired in
  27         wiredInIds, ghcPrimIds,
  28         unsafeCoerceId, realWorldPrimId, voidArgId, nullAddrId, seqId,
  29         lazyId, lazyIdUnfolding, lazyIdKey,
  30
  31         mkRuntimeErrorApp,
  32         rEC_CON_ERROR_ID, iRREFUT_PAT_ERROR_ID, rUNTIME_ERROR_ID,
  33         nON_EXHAUSTIVE_GUARDS_ERROR_ID, nO_METHOD_BINDING_ERROR_ID,
  34         pAT_ERROR_ID, eRROR_ID,
  35
  36         unsafeCoerceName
  37     ) where
  38
  39 #include "HsVersions.h"
  40
  41
  42 import BasicTypes       ( Arity, StrictnessMark(..), isMarkedUnboxed, isMarkedStrict )
  43 import Rules            ( mkSpecInfo )
  44 import TysPrim          ( openAlphaTyVars, alphaTyVar, alphaTy,
  45                           realWorldStatePrimTy, addrPrimTy
  46                         )
  47 import TysWiredIn       ( charTy, mkListTy )
  48 import PrelRules        ( primOpRules )
  49 import Type             ( TyThing(..), mkForAllTy, tyVarsOfTypes, newTyConInstRhs, coreEqType,
  50                           PredType(..),
  51                           mkTopTvSubst, substTyVar )
  52 import TcGadt           ( gadtRefine, refineType, emptyRefinement )
  53 import HsBinds          ( ExprCoFn(..), isIdCoercion )
  54 import Coercion         ( mkSymCoercion, mkUnsafeCoercion,
  55                           splitNewTypeRepCo_maybe, isEqPred )
  56 import TcType           ( Type, ThetaType, mkDictTy, mkPredTys, mkPredTy,
  57                           mkTyConApp, mkTyVarTys, mkClassPred, isPredTy,
  58                           mkFunTys, mkFunTy, mkSigmaTy, tcSplitSigmaTy, tcEqType,
  59                           isUnLiftedType, mkForAllTys, mkTyVarTy, tyVarsOfType,
  60                           tcSplitFunTys, tcSplitForAllTys, dataConsStupidTheta
  61                         )
  62 import CoreUtils        ( exprType, dataConOrigInstPat )
  63 import CoreUnfold       ( mkTopUnfolding, mkCompulsoryUnfolding )
  64 import Literal          ( nullAddrLit, mkStringLit )
  65 import TyCon            ( TyCon, isNewTyCon, tyConDataCons, FieldLabel,
  66                           tyConStupidTheta, isProductTyCon, isDataTyCon, isRecursiveTyCon,
  67                           newTyConCo, tyConArity )
  68 import Class            ( Class, classTyCon, classSelIds )
  69 import Var              ( Id, TyVar, Var, setIdType, mkCoVar, mkWildCoVar )
  70 import VarSet           ( isEmptyVarSet, subVarSet, varSetElems )
  71 import Name             ( mkFCallName, mkWiredInName, Name, BuiltInSyntax(..),
  72                           mkSysTvName )
  73 import OccName          ( mkOccNameFS, varName )
  74 import PrimOp           ( PrimOp, primOpSig, primOpOcc, primOpTag )
  75 import ForeignCall      ( ForeignCall )
  76 import DataCon          ( DataCon, DataConIds(..), dataConTyCon, dataConUnivTyVars,
  77                           dataConFieldLabels, dataConRepArity, dataConResTys,
  78                           dataConRepArgTys, dataConRepType, dataConFullSig,
  79                           dataConSig, dataConStrictMarks, dataConExStricts,
  80                           splitProductType, isVanillaDataCon, dataConFieldType,
  81                           dataConInstOrigArgTys, deepSplitProductType
  82                         )
  83 import Id               ( idType, mkGlobalId, mkVanillaGlobal, mkSysLocal,
  84                           mkTemplateLocals, mkTemplateLocalsNum, mkExportedLocalId,
  85                           mkTemplateLocal, idName, mkWildId
  86                         )
  87 import IdInfo           ( IdInfo, noCafIdInfo,  setUnfoldingInfo,
  88                           setArityInfo, setSpecInfo, setCafInfo,
  89                           setAllStrictnessInfo, vanillaIdInfo,
  90                           GlobalIdDetails(..), CafInfo(..)
  91                         )
  92 import NewDemand        ( mkStrictSig, DmdResult(..),
  93                           mkTopDmdType, topDmd, evalDmd, lazyDmd, retCPR,
  94                           Demand(..), Demands(..) )
  95 import DmdAnal          ( dmdAnalTopRhs )
  96 import CoreSyn
  97 import Unique           ( mkBuiltinUnique, mkPrimOpIdUnique )
  98 import Maybes
  99 import PrelNames
 100 import Util             ( dropList, isSingleton )
 101 import Outputable
 102 import FastString
 103 import ListSetOps       ( assoc, minusList )
 104 \end{code}
 105
 106 %************************************************************************
 107 %*                                                                      *
 108 \subsection{Wired in Ids}
 109 %*                                                                      *
 110 %************************************************************************
 111
 112 \begin{code}
 113 wiredInIds
 114   = [   -- These error-y things are wired in because we don't yet have
 115         -- a way to express in an interface file that the result type variable
 116         -- is 'open'; that is can be unified with an unboxed type
 117         --
 118         -- [The interface file format now carry such information, but there's
 119         -- no way yet of expressing at the definition site for these
 120         -- error-reporting functions that they have an 'open'
 121         -- result type. -- sof 1/99]
 122
 123     eRROR_ID,   -- This one isn't used anywhere else in the compiler
 124                 -- But we still need it in wiredInIds so that when GHC
 125                 -- compiles a program that mentions 'error' we don't
 126                 -- import its type from the interface file; we just get
 127                 -- the Id defined here.  Which has an 'open-tyvar' type.
 128
 129     rUNTIME_ERROR_ID,
 130     iRREFUT_PAT_ERROR_ID,
 131     nON_EXHAUSTIVE_GUARDS_ERROR_ID,
 132     nO_METHOD_BINDING_ERROR_ID,
 133     pAT_ERROR_ID,
 134     rEC_CON_ERROR_ID,
 135
 136     lazyId
 137     ] ++ ghcPrimIds
 138
 139 -- These Ids are exported from GHC.Prim
 140 ghcPrimIds
 141   = [   -- These can't be defined in Haskell, but they have
 142         -- perfectly reasonable unfoldings in Core
 143     realWorldPrimId,
 144     unsafeCoerceId,
 145     nullAddrId,
 146     seqId
 147     ]
 148 \end{code}
 149
 150 %************************************************************************
 151 %*                                                                      *
 152 \subsection{Data constructors}
 153 %*                                                                      *
 154 %************************************************************************
 155
 156 The wrapper for a constructor is an ordinary top-level binding that evaluates
 157 any strict args, unboxes any args that are going to be flattened, and calls
 158 the worker.
 159
 160 We're going to build a constructor that looks like:
 161
 162         data (Data a, C b) =>  T a b = T1 !a !Int b
 163
 164         T1 = /\ a b ->
 165              \d1::Data a, d2::C b ->
 166              \p q r -> case p of { p ->
 167                        case q of { q ->
 168                        Con T1 [a,b] [p,q,r]}}
 169
 170 Notice that
 171
 172 * d2 is thrown away --- a context in a data decl is used to make sure
 173   one *could* construct dictionaries at the site the constructor
 174   is used, but the dictionary isn't actually used.
 175
 176 * We have to check that we can construct Data dictionaries for
 177   the types a and Int.  Once we've done that we can throw d1 away too.
 178
 179 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
 180   all that matters is that the arguments are evaluated.  "seq" is
 181   very careful to preserve evaluation order, which we don't need
 182   to be here.
 183
 184   You might think that we could simply give constructors some strictness
 185   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
 186   But we don't do that because in the case of primops and functions strictness
 187   is a *property* not a *requirement*.  In the case of constructors we need to
 188   do something active to evaluate the argument.
 189
 190   Making an explicit case expression allows the simplifier to eliminate
 191   it in the (common) case where the constructor arg is already evaluated.
 192
 193
 194 \begin{code}
 195 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
 196 mkDataConIds wrap_name wkr_name data_con
 197   | isNewTyCon tycon
 198   = NewDC nt_wrap_id
 199
 200   | any isMarkedStrict all_strict_marks         -- Algebraic, needs wrapper
 201     || not (null eq_spec)
 202   = AlgDC (Just alg_wrap_id) wrk_id
 203
 204   | otherwise                                   -- Algebraic, no wrapper
 205   = AlgDC Nothing wrk_id
 206   where
 207     (univ_tvs, ex_tvs, eq_spec, theta, orig_arg_tys) = dataConFullSig data_con
 208     tycon = dataConTyCon data_con
 209
 210         ----------- Wrapper --------------
 211         -- We used to include the stupid theta in the wrapper's args
 212         -- but now we don't.  Instead the type checker just injects these
 213         -- extra constraints where necessary.
 214     wrap_tvs = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
 215     subst          = mkTopTvSubst eq_spec
 216     dict_tys       = mkPredTys theta
 217     result_ty_args = map (substTyVar subst) univ_tvs
 218     result_ty      = mkTyConApp tycon result_ty_args
 219     wrap_ty        = mkForAllTys wrap_tvs $ mkFunTys dict_tys $
 220                      mkFunTys orig_arg_tys $ result_ty
 221         -- NB: watch out here if you allow user-written equality
 222         --     constraints in data constructor signatures
 223
 224         ----------- Worker (algebraic data types only) --------------
 225         -- The *worker* for the data constructor is the function that
 226         -- takes the representation arguments and builds the constructor.
 227     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
 228                         (dataConRepType data_con) wkr_info
 229
 230     wkr_arity = dataConRepArity data_con
 231     wkr_info  = noCafIdInfo
 232                 `setArityInfo`          wkr_arity
 233                 `setAllStrictnessInfo`  Just wkr_sig
 234                 `setUnfoldingInfo`      evaldUnfolding  -- Record that it's evaluated,
 235                                                         -- even if arity = 0
 236
 237     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
 238         -- Notice that we do *not* say the worker is strict
 239         -- even if the data constructor is declared strict
 240         --      e.g.    data T = MkT !(Int,Int)
 241         -- Why?  Because the *wrapper* is strict (and its unfolding has case
 242         -- expresssions that do the evals) but the *worker* itself is not.
 243         -- If we pretend it is strict then when we see
 244         --      case x of y -> $wMkT y
 245         -- the simplifier thinks that y is "sure to be evaluated" (because
 246         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
 247         --
 248         -- When the simplifer sees a pattern
 249         --      case e of MkT x -> ...
 250         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
 251         -- but that's fine... dataConRepStrictness comes from the data con
 252         -- not from the worker Id.
 253
 254     cpr_info | isProductTyCon tycon &&
 255                isDataTyCon tycon    &&
 256                wkr_arity > 0        &&
 257                wkr_arity <= mAX_CPR_SIZE        = retCPR
 258              | otherwise                        = TopRes
 259         -- RetCPR is only true for products that are real data types;
 260         -- that is, not unboxed tuples or [non-recursive] newtypes
 261
 262         ----------- Wrappers for newtypes --------------
 263     nt_wrap_id   = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty nt_wrap_info
 264     nt_wrap_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
 265                   `setArityInfo` 1      -- Arity 1
 266                   `setUnfoldingInfo`     newtype_unf
 267     newtype_unf  = ASSERT( isVanillaDataCon data_con &&
 268                            isSingleton orig_arg_tys )
 269                    -- No existentials on a newtype, but it can have a context
 270                    -- e.g.      newtype Eq a => T a = MkT (...)
 271                    mkCompulsoryUnfolding $
 272                    mkLams wrap_tvs $ Lam id_arg1 $
 273                    wrapNewTypeBody tycon result_ty_args
 274                        (Var id_arg1)
 275
 276     id_arg1 = mkTemplateLocal 1 (head orig_arg_tys)
 277
 278         ----------- Wrappers for algebraic data types --------------
 279     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
 280     alg_wrap_info = noCafIdInfo         -- The NoCaf-ness is set by noCafIdInfo
 281                     `setArityInfo`         alg_arity
 282                         -- It's important to specify the arity, so that partial
 283                         -- applications are treated as values
 284                     `setUnfoldingInfo`     alg_unf
 285                     `setAllStrictnessInfo` Just wrap_sig
 286
 287     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
 288     wrap_sig = mkStrictSig (mkTopDmdType arg_dmds cpr_info)
 289     arg_dmds = map mk_dmd all_strict_marks
 290     mk_dmd str | isMarkedStrict str = evalDmd
 291                | otherwise          = lazyDmd
 292         -- The Cpr info can be important inside INLINE rhss, where the
 293         -- wrapper constructor isn't inlined.
 294         -- And the argument strictness can be important too; we
 295         -- may not inline a contructor when it is partially applied.
 296         -- For example:
 297         --      data W = C !Int !Int !Int
 298         --      ...(let w = C x in ...(w p q)...)...
 299         -- we want to see that w is strict in its two arguments
 300
 301     alg_unf = mkTopUnfolding $ Note InlineMe $
 302               mkLams wrap_tvs $
 303               mkLams dict_args $ mkLams id_args $
 304               foldr mk_case con_app
 305                     (zip (dict_args ++ id_args) all_strict_marks)
 306                     i3 []
 307
 308     con_app i rep_ids = Var wrk_id `mkTyApps`  result_ty_args
 309                                    `mkVarApps` ex_tvs
 310                                    `mkTyApps`  map snd eq_spec
 311                                    `mkVarApps` reverse rep_ids
 312
 313     (dict_args,i2) = mkLocals 1  dict_tys
 314     (id_args,i3)   = mkLocals i2 orig_arg_tys
 315     alg_arity      = i3-1
 316
 317     mk_case
 318            :: (Id, StrictnessMark)      -- Arg, strictness
 319            -> (Int -> [Id] -> CoreExpr) -- Body
 320            -> Int                       -- Next rep arg id
 321            -> [Id]                      -- Rep args so far, reversed
 322            -> CoreExpr
 323     mk_case (arg,strict) body i rep_args
 324           = case strict of
 325                 NotMarkedStrict -> body i (arg:rep_args)
 326                 MarkedStrict
 327                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
 328                    | otherwise ->
 329                         Case (Var arg) arg result_ty [(DEFAULT,[], body i (arg:rep_args))]
 330
 331                 MarkedUnboxed
 332                    -> unboxProduct i (Var arg) (idType arg) the_body result_ty
 333                       where
 334                         the_body i con_args = body i (reverse con_args ++ rep_args)
 335
 336 mAX_CPR_SIZE :: Arity
 337 mAX_CPR_SIZE = 10
 338 -- We do not treat very big tuples as CPR-ish:
 339 --      a) for a start we get into trouble because there aren't
 340 --         "enough" unboxed tuple types (a tiresome restriction,
 341 --         but hard to fix),
 342 --      b) more importantly, big unboxed tuples get returned mainly
 343 --         on the stack, and are often then allocated in the heap
 344 --         by the caller.  So doing CPR for them may in fact make
 345 --         things worse.
 346
 347 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
 348                where
 349                  n = length tys
 350 \end{code}
 351
 352
 353 %************************************************************************
 354 %*                                                                      *
 355 \subsection{Record selectors}
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 We're going to build a record selector unfolding that looks like this:
 360
 361         data T a b c = T1 { ..., op :: a, ...}
 362                      | T2 { ..., op :: a, ...}
 363                      | T3
 364
 365         sel = /\ a b c -> \ d -> case d of
 366                                     T1 ... x ... -> x
 367                                     T2 ... x ... -> x
 368                                     other        -> error "..."
 369
 370 Similarly for newtypes
 371
 372         newtype N a = MkN { unN :: a->a }
 373
 374         unN :: N a -> a -> a
 375         unN n = coerce (a->a) n
 376
 377 We need to take a little care if the field has a polymorphic type:
 378
 379         data R = R { f :: forall a. a->a }
 380
 381 Then we want
 382
 383         f :: forall a. R -> a -> a
 384         f = /\ a \ r = case r of
 385                           R f -> f a
 386
 387 (not f :: R -> forall a. a->a, which gives the type inference mechanism
 388 problems at call sites)
 389
 390 Similarly for (recursive) newtypes
 391
 392         newtype N = MkN { unN :: forall a. a->a }
 393
 394         unN :: forall b. N -> b -> b
 395         unN = /\b -> \n:N -> (coerce (forall a. a->a) n)
 396
 397
 398 Note [Naughty record selectors]
 399 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 400 A "naughty" field is one for which we can't define a record
 401 selector, because an existential type variable would escape.  For example:
 402         data T = forall a. MkT { x,y::a }
 403 We obviously can't define
 404         x (MkT v _) = v
 405 Nevertheless we *do* put a RecordSelId into the type environment
 406 so that if the user tries to use 'x' as a selector we can bleat
 407 helpfully, rather than saying unhelpfully that 'x' is not in scope.
 408 Hence the sel_naughty flag, to identify record selectors that don't really exist.
 409
 410 In general, a field is naughty if its type mentions a type variable that
 411 isn't in the result type of the constructor.
 412
 413 Note [GADT record selectors]
 414 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 415 For GADTs, we require that all constructors with a common field 'f' have the same
 416 result type (modulo alpha conversion).  [Checked in TcTyClsDecls.checkValidTyCon]
 417 E.g.
 418         data T where
 419           T1 { f :: a } :: T [a]
 420           T2 { f :: a, y :: b  } :: T [a]
 421 and now the selector takes that type as its argument:
 422         f :: forall a. T [a] -> a
 423         f t = case t of
 424                 T1 { f = v } -> v
 425                 T2 { f = v } -> v
 426 Note the forall'd tyvars of the selector are just the free tyvars
 427 of the result type; there may be other tyvars in the constructor's
 428 type (e.g. 'b' in T2).
 429
 430 \begin{code}
 431
 432 -- Steps for handling "naughty" vs "non-naughty" selectors:
 433 --  1. Determine naughtiness by comparing field type vs result type
 434 --  2. Install naughty ones with selector_ty of type _|_ and fill in mzero for info
 435 --  3. If it's not naughty, do the normal plan.
 436
 437 mkRecordSelId :: TyCon -> FieldLabel -> Id
 438 mkRecordSelId tycon field_label
 439         -- Assumes that all fields with the same field label have the same type
 440   | is_naughty = naughty_id
 441   | otherwise  = sel_id
 442   where
 443     is_naughty = not (tyVarsOfType field_ty `subVarSet` res_tv_set)
 444     sel_id_details = RecordSelId tycon field_label is_naughty
 445
 446     -- Escapist case here for naughty construcotrs
 447     -- We give it no IdInfo, and a type of forall a.a (never looked at)
 448     naughty_id = mkGlobalId sel_id_details field_label forall_a_a noCafIdInfo
 449     forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 450
 451     -- Normal case starts here
 452     sel_id = mkGlobalId sel_id_details field_label selector_ty info
 453     data_cons         = tyConDataCons tycon
 454     data_cons_w_field = filter has_field data_cons      -- Can't be empty!
 455     has_field con     = field_label `elem` dataConFieldLabels con
 456
 457     con1        = head data_cons_w_field
 458     res_tys     = dataConResTys con1
 459     res_tv_set  = tyVarsOfTypes res_tys
 460     res_tvs     = varSetElems res_tv_set
 461     data_ty     = mkTyConApp tycon res_tys
 462     field_ty    = dataConFieldType con1 field_label
 463
 464         -- *Very* tiresomely, the selectors are (unnecessarily!) overloaded over
 465         -- just the dictionaries in the types of the constructors that contain
 466         -- the relevant field.  [The Report says that pattern matching on a
 467         -- constructor gives the same constraints as applying it.]  Urgh.
 468         --
 469         -- However, not all data cons have all constraints (because of
 470         -- BuildTyCl.mkDataConStupidTheta).  So we need to find all the data cons
 471         -- involved in the pattern match and take the union of their constraints.
 472     stupid_dict_tys = mkPredTys (dataConsStupidTheta data_cons_w_field)
 473     n_stupid_dicts  = length stupid_dict_tys
 474
 475     (field_tyvars,pre_field_theta,field_tau) = tcSplitSigmaTy field_ty
 476
 477     field_theta  = filter (not . isEqPred) pre_field_theta
 478     field_dict_tys                       = mkPredTys field_theta
 479     n_field_dict_tys                     = length field_dict_tys
 480         -- If the field has a universally quantified type we have to
 481         -- be a bit careful.  Suppose we have
 482         --      data R = R { op :: forall a. Foo a => a -> a }
 483         -- Then we can't give op the type
 484         --      op :: R -> forall a. Foo a => a -> a
 485         -- because the typechecker doesn't understand foralls to the
 486         -- right of an arrow.  The "right" type to give it is
 487         --      op :: forall a. Foo a => R -> a -> a
 488         -- But then we must generate the right unfolding too:
 489         --      op = /\a -> \dfoo -> \ r ->
 490         --           case r of
 491         --              R op -> op a dfoo
 492         -- Note that this is exactly the type we'd infer from a user defn
 493         --      op (R op) = op
 494
 495     selector_ty :: Type
 496     selector_ty  = mkForAllTys res_tvs $ mkForAllTys field_tyvars $
 497                    mkFunTys stupid_dict_tys  $  mkFunTys field_dict_tys $
 498                    mkFunTy data_ty field_tau
 499
 500     arity = 1 + n_stupid_dicts + n_field_dict_tys
 501
 502     (strict_sig, rhs_w_str) = dmdAnalTopRhs sel_rhs
 503         -- Use the demand analyser to work out strictness.
 504         -- With all this unpackery it's not easy!
 505
 506     info = noCafIdInfo
 507            `setCafInfo`           caf_info
 508            `setArityInfo`         arity
 509            `setUnfoldingInfo`     mkTopUnfolding rhs_w_str
 510            `setAllStrictnessInfo` Just strict_sig
 511
 512         -- Allocate Ids.  We do it a funny way round because field_dict_tys is
 513         -- almost always empty.  Also note that we use max_dict_tys
 514         -- rather than n_dict_tys, because the latter gives an infinite loop:
 515         -- n_dict tys depends on the_alts, which depens on arg_ids, which depends
 516         -- on arity, which depends on n_dict tys.  Sigh!  Mega sigh!
 517     stupid_dict_ids  = mkTemplateLocalsNum 1 stupid_dict_tys
 518     max_stupid_dicts = length (tyConStupidTheta tycon)
 519     field_dict_base  = max_stupid_dicts + 1
 520     field_dict_ids   = mkTemplateLocalsNum field_dict_base field_dict_tys
 521     dict_id_base     = field_dict_base + n_field_dict_tys
 522     data_id          = mkTemplateLocal dict_id_base data_ty
 523     arg_base         = dict_id_base + 1
 524
 525     the_alts :: [CoreAlt]
 526     the_alts   = map mk_alt data_cons_w_field   -- Already sorted by data-con
 527     no_default = length data_cons == length data_cons_w_field   -- No default needed
 528
 529     default_alt | no_default = []
 530                 | otherwise  = [(DEFAULT, [], error_expr)]
 531
 532         -- The default branch may have CAF refs, because it calls recSelError etc.
 533     caf_info    | no_default = NoCafRefs
 534                 | otherwise  = MayHaveCafRefs
 535
 536     sel_rhs = mkLams res_tvs $ mkLams field_tyvars $
 537               mkLams stupid_dict_ids $ mkLams field_dict_ids $
 538               Lam data_id     $ mk_result sel_body
 539
 540         -- NB: A newtype always has a vanilla DataCon; no existentials etc
 541         --     res_tys will simply be the dataConUnivTyVars
 542     sel_body | isNewTyCon tycon = unwrapNewTypeBody tycon res_tys (Var data_id)
 543              | otherwise        = Case (Var data_id) data_id field_ty (default_alt ++ the_alts)
 544
 545     mk_result poly_result = mkVarApps (mkVarApps poly_result field_tyvars) field_dict_ids
 546         -- We pull the field lambdas to the top, so we need to
 547         -- apply them in the body.  For example:
 548         --      data T = MkT { foo :: forall a. a->a }
 549         --
 550         --      foo :: forall a. T -> a -> a
 551         --      foo = /\a. \t:T. case t of { MkT f -> f a }
 552
 553     mk_alt data_con
 554       =         -- In the non-vanilla case, the pattern must bind type variables and
 555                 -- the context stuff; hence the arg_prefix binding below
 556           ASSERT2( res_ty `tcEqType` field_tau, ppr data_con $$ ppr res_ty $$ ppr field_tau )
 557           mkReboxingAlt rebox_uniqs data_con (ex_tvs ++ co_tvs ++ arg_vs) rhs
 558       where
 559            -- get pattern binders with types appropriately instantiated
 560         arg_uniqs = map mkBuiltinUnique [arg_base..]
 561         (ex_tvs, co_tvs, arg_vs) = dataConOrigInstPat arg_uniqs data_con res_tys
 562
 563         rebox_base  = arg_base + length ex_tvs + length co_tvs + length arg_vs
 564         rebox_uniqs = map mkBuiltinUnique [rebox_base..]
 565
 566         -- data T :: *->* where T1 { fld :: Maybe b } -> T [b]
 567         --      Hence T1 :: forall a b. (a=[b]) => b -> T a
 568         -- fld :: forall b. T [b] -> Maybe b
 569         -- fld = /\b.\(t:T[b]). case t of
 570         --              T1 b' (c : [b]=[b']) (x:Maybe b')
 571         --                      -> x `cast` Maybe (sym (right c))
 572
 573         Succeeded refinement = gadtRefine emptyRefinement ex_tvs co_tvs
 574         (co_fn, res_ty) = refineType refinement (idType the_arg_id)
 575                 -- Generate the refinement for b'=b,
 576                 -- and apply to (Maybe b'), to get (Maybe b)
 577
 578         rhs = case co_fn of
 579                 ExprCoFn co -> Cast (Var the_arg_id) co
 580                 id_co       -> ASSERT(isIdCoercion id_co) Var the_arg_id
 581
 582         field_vs    = filter (not . isPredTy . idType) arg_vs
 583         the_arg_id  = assoc "mkRecordSelId:mk_alt" (field_lbls `zip` field_vs) field_label
 584         field_lbls  = dataConFieldLabels data_con
 585
 586     error_expr = mkRuntimeErrorApp rEC_SEL_ERROR_ID field_tau full_msg
 587     full_msg   = showSDoc (sep [text "No match in record selector", ppr sel_id])
 588
 589 -- unbox a product type...
 590 -- we will recurse into newtypes, casting along the way, and unbox at the
 591 -- first product data constructor we find. e.g.
 592 --
 593 --   data PairInt = PairInt Int Int
 594 --   newtype S = MkS PairInt
 595 --   newtype T = MkT S
 596 --
 597 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
 598 -- ids, we get (modulo int passing)
 599 --
 600 --   case (e `cast` (sym CoT)) `cast` (sym CoS) of
 601 --     PairInt a b -> body [a,b]
 602 --
 603 -- The Ints passed around are just for creating fresh locals
 604 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> Type -> CoreExpr
 605 unboxProduct i arg arg_ty body res_ty
 606   = result
 607   where
 608     result = mkUnpackCase the_id arg arg_ty con_args boxing_con rhs
 609     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
 610     ([the_id], i') = mkLocals i [arg_ty]
 611     (con_args, i'') = mkLocals i' tys
 612     rhs = body i'' con_args
 613
 614 mkUnpackCase ::  Id -> CoreExpr -> Type -> [Id] -> DataCon -> CoreExpr -> CoreExpr
 615 -- (mkUnpackCase x e args Con body)
 616 --      returns
 617 -- case (e `cast` ...) of bndr { Con args -> body }
 618 --
 619 -- the type of the bndr passed in is irrelevent
 620 mkUnpackCase bndr arg arg_ty unpk_args boxing_con body
 621   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
 622   where
 623   (cast_arg, bndr_ty) = go (idType bndr) arg
 624   go ty arg
 625     | res@(tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
 626     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
 627     = go (newTyConInstRhs tycon tycon_args)
 628          (unwrapNewTypeBody tycon tycon_args arg)
 629     | otherwise = (arg, ty)
 630
 631 -- ...and the dual
 632 reboxProduct :: [Unique]     -- uniques to create new local binders
 633              -> Type         -- type of product to box
 634              -> ([Unique],   -- remaining uniques
 635                  CoreExpr,   -- boxed product
 636                  [Id])       -- Ids being boxed into product
 637 reboxProduct us ty
 638   = let
 639         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
 640
 641         us' = dropList con_arg_tys us
 642
 643         arg_ids  = zipWith (mkSysLocal FSLIT("rb")) us con_arg_tys
 644
 645         bind_rhs = mkProductBox arg_ids ty
 646
 647     in
 648       (us', bind_rhs, arg_ids)
 649
 650 mkProductBox :: [Id] -> Type -> CoreExpr
 651 mkProductBox arg_ids ty
 652   = result_expr
 653   where
 654     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
 655
 656     result_expr
 657       | isNewTyCon tycon && not (isRecursiveTyCon tycon)
 658       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
 659       | otherwise = mkConApp pack_con (map Type tycon_args ++ map Var arg_ids)
 660
 661     wrap expr = wrapNewTypeBody tycon tycon_args expr
 662
 663
 664 -- (mkReboxingAlt us con xs rhs) basically constructs the case
 665 -- alternative  (con, xs, rhs)
 666 -- but it does the reboxing necessary to construct the *source*
 667 -- arguments, xs, from the representation arguments ys.
 668 -- For example:
 669 --      data T = MkT !(Int,Int) Bool
 670 --
 671 -- mkReboxingAlt MkT [x,b] r
 672 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
 673 --
 674 -- mkDataAlt should really be in DataCon, but it can't because
 675 -- it manipulates CoreSyn.
 676
 677 mkReboxingAlt
 678   :: [Unique]           -- Uniques for the new Ids
 679   -> DataCon
 680   -> [Var]              -- Source-level args, including existential dicts
 681   -> CoreExpr           -- RHS
 682   -> CoreAlt
 683
 684 mkReboxingAlt us con args rhs
 685   | not (any isMarkedUnboxed stricts)
 686   = (DataAlt con, args, rhs)
 687
 688   | otherwise
 689   = let
 690         (binds, args') = go args stricts us
 691     in
 692     (DataAlt con, args', mkLets binds rhs)
 693
 694   where
 695     stricts = dataConExStricts con ++ dataConStrictMarks con
 696
 697     go [] stricts us = ([], [])
 698
 699         -- Type variable case
 700     go (arg:args) stricts us
 701       | isTyVar arg
 702       = let (binds, args') = go args stricts us
 703         in  (binds, arg:args')
 704
 705         -- Term variable case
 706     go (arg:args) (str:stricts) us
 707       | isMarkedUnboxed str
 708       =
 709         let (binds, unpacked_args')        = go args stricts us'
 710             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
 711         in
 712             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
 713       | otherwise
 714       = let (binds, args') = go args stricts us
 715         in  (binds, arg:args')
 716 \end{code}
 717
 718
 719 %************************************************************************
 720 %*                                                                      *
 721 \subsection{Dictionary selectors}
 722 %*                                                                      *
 723 %************************************************************************
 724
 725 Selecting a field for a dictionary.  If there is just one field, then
 726 there's nothing to do.
 727
 728 Dictionary selectors may get nested forall-types.  Thus:
 729
 730         class Foo a where
 731           op :: forall b. Ord b => a -> b -> b
 732
 733 Then the top-level type for op is
 734
 735         op :: forall a. Foo a =>
 736               forall b. Ord b =>
 737               a -> b -> b
 738
 739 This is unlike ordinary record selectors, which have all the for-alls
 740 at the outside.  When dealing with classes it's very convenient to
 741 recover the original type signature from the class op selector.
 742
 743 \begin{code}
 744 mkDictSelId :: Name -> Class -> Id
 745 mkDictSelId name clas
 746   = mkGlobalId (ClassOpId clas) name sel_ty info
 747   where
 748     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
 749         -- We can't just say (exprType rhs), because that would give a type
 750         --      C a -> C a
 751         -- for a single-op class (after all, the selector is the identity)
 752         -- But it's type must expose the representation of the dictionary
 753         -- to gat (say)         C a -> (a -> a)
 754
 755     info = noCafIdInfo
 756                 `setArityInfo`          1
 757                 `setUnfoldingInfo`      mkTopUnfolding rhs
 758                 `setAllStrictnessInfo`  Just strict_sig
 759
 760         -- We no longer use 'must-inline' on record selectors.  They'll
 761         -- inline like crazy if they scrutinise a constructor
 762
 763         -- The strictness signature is of the form U(AAAVAAAA) -> T
 764         -- where the V depends on which item we are selecting
 765         -- It's worth giving one, so that absence info etc is generated
 766         -- even if the selector isn't inlined
 767     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
 768     arg_dmd | isNewTyCon tycon = evalDmd
 769             | otherwise        = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
 770                                             | id <- arg_ids ])
 771
 772     tycon      = classTyCon clas
 773     [data_con] = tyConDataCons tycon
 774     tyvars     = dataConUnivTyVars data_con
 775     arg_tys    = ASSERT( isVanillaDataCon data_con ) dataConRepArgTys data_con
 776     the_arg_id = assoc "MkId.mkDictSelId" (map idName (classSelIds clas) `zip` arg_ids) name
 777
 778     pred              = mkClassPred clas (mkTyVarTys tyvars)
 779     (dict_id:arg_ids) = mkTemplateLocals (mkPredTy pred : arg_tys)
 780
 781     rhs = mkLams tyvars (Lam dict_id rhs_body)
 782     rhs_body | isNewTyCon tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
 783              | otherwise        = Case (Var dict_id) dict_id (idType the_arg_id)
 784                                        [(DataAlt data_con, arg_ids, Var the_arg_id)]
 785
 786 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 787 -- The wrapper for the data constructor for a newtype looks like this:
 788 --      newtype T a = MkT (a,Int)
 789 --      MkT :: forall a. (a,Int) -> T a
 790 --      MkT = /\a. \(x:(a,Int)). x `cast` CoT a
 791 -- where CoT is the coercion TyCon assoicated with the newtype
 792 --
 793 -- The call (wrapNewTypeBody T [a] e) returns the
 794 -- body of the wrapper, namely
 795 --      e `cast` CoT [a]
 796 --
 797 -- If a coercion constructor is prodivided in the newtype, then we use
 798 -- it, otherwise the wrap/unwrap are both no-ops
 799 --
 800 wrapNewTypeBody tycon args result_expr
 801   | Just co_con <- newTyConCo tycon
 802   = Cast result_expr (mkTyConApp co_con args)
 803   | otherwise
 804   = result_expr
 805
 806 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
 807 unwrapNewTypeBody tycon args result_expr
 808   | Just co_con <- newTyConCo tycon
 809   = Cast result_expr (mkSymCoercion (mkTyConApp co_con args))
 810   | otherwise
 811   = result_expr
 812
 813
 814 \end{code}
 815
 816
 817 %************************************************************************
 818 %*                                                                      *
 819 \subsection{Primitive operations
 820 %*                                                                      *
 821 %************************************************************************
 822
 823 \begin{code}
 824 mkPrimOpId :: PrimOp -> Id
 825 mkPrimOpId prim_op
 826   = id
 827   where
 828     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
 829     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
 830     name = mkWiredInName gHC_PRIM (primOpOcc prim_op)
 831                          (mkPrimOpIdUnique (primOpTag prim_op))
 832                          Nothing (AnId id) UserSyntax
 833     id   = mkGlobalId (PrimOpId prim_op) name ty info
 834
 835     info = noCafIdInfo
 836            `setSpecInfo`          mkSpecInfo (primOpRules prim_op name)
 837            `setArityInfo`         arity
 838            `setAllStrictnessInfo` Just strict_sig
 839
 840 -- For each ccall we manufacture a separate CCallOpId, giving it
 841 -- a fresh unique, a type that is correct for this particular ccall,
 842 -- and a CCall structure that gives the correct details about calling
 843 -- convention etc.
 844 --
 845 -- The *name* of this Id is a local name whose OccName gives the full
 846 -- details of the ccall, type and all.  This means that the interface
 847 -- file reader can reconstruct a suitable Id
 848
 849 mkFCallId :: Unique -> ForeignCall -> Type -> Id
 850 mkFCallId uniq fcall ty
 851   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
 852         -- A CCallOpId should have no free type variables;
 853         -- when doing substitutions won't substitute over it
 854     mkGlobalId (FCallId fcall) name ty info
 855   where
 856     occ_str = showSDoc (braces (ppr fcall <+> ppr ty))
 857         -- The "occurrence name" of a ccall is the full info about the
 858         -- ccall; it is encoded, but may have embedded spaces etc!
 859
 860     name = mkFCallName uniq occ_str
 861
 862     info = noCafIdInfo
 863            `setArityInfo`               arity
 864            `setAllStrictnessInfo`       Just strict_sig
 865
 866     (_, tau)     = tcSplitForAllTys ty
 867     (arg_tys, _) = tcSplitFunTys tau
 868     arity        = length arg_tys
 869     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
 870 \end{code}
 871
 872
 873 %************************************************************************
 874 %*                                                                      *
 875 \subsection{DictFuns and default methods}
 876 %*                                                                      *
 877 %************************************************************************
 878
 879 Important notes about dict funs and default methods
 880 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 881 Dict funs and default methods are *not* ImplicitIds.  Their definition
 882 involves user-written code, so we can't figure out their strictness etc
 883 based on fixed info, as we can for constructors and record selectors (say).
 884
 885 We build them as LocalIds, but with External Names.  This ensures that
 886 they are taken to account by free-variable finding and dependency
 887 analysis (e.g. CoreFVs.exprFreeVars).
 888
 889 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
 890 they are globals, the specialiser floats dict uses above their defns,
 891 which prevents good simplifications happening.  Also the strictness
 892 analyser treats a occurrence of a GlobalId as imported and assumes it
 893 contains strictness in its IdInfo, which isn't true if the thing is
 894 bound in the same module as the occurrence.
 895
 896 It's OK for dfuns to be LocalIds, because we form the instance-env to
 897 pass on to the next module (md_insts) in CoreTidy, afer tidying
 898 and globalising the top-level Ids.
 899
 900 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so
 901 that they aren't discarded by the occurrence analyser.
 902
 903 \begin{code}
 904 mkDefaultMethodId dm_name ty = mkExportedLocalId dm_name ty
 905
 906 mkDictFunId :: Name             -- Name to use for the dict fun;
 907             -> [TyVar]
 908             -> ThetaType
 909             -> Class
 910             -> [Type]
 911             -> Id
 912
 913 mkDictFunId dfun_name inst_tyvars dfun_theta clas inst_tys
 914   = mkExportedLocalId dfun_name dfun_ty
 915   where
 916     dfun_ty = mkSigmaTy inst_tyvars dfun_theta (mkDictTy clas inst_tys)
 917
 918 {-  1 dec 99: disable the Mark Jones optimisation for the sake
 919     of compatibility with Hugs.
 920     See `types/InstEnv' for a discussion related to this.
 921
 922     (class_tyvars, sc_theta, _, _) = classBigSig clas
 923     not_const (clas, tys) = not (isEmptyVarSet (tyVarsOfTypes tys))
 924     sc_theta' = substClasses (zipTopTvSubst class_tyvars inst_tys) sc_theta
 925     dfun_theta = case inst_decl_theta of
 926                    []    -> []  -- If inst_decl_theta is empty, then we don't
 927                                 -- want to have any dict arguments, so that we can
 928                                 -- expose the constant methods.
 929
 930                    other -> nub (inst_decl_theta ++ filter not_const sc_theta')
 931                                 -- Otherwise we pass the superclass dictionaries to
 932                                 -- the dictionary function; the Mark Jones optimisation.
 933                                 --
 934                                 -- NOTE the "nub".  I got caught by this one:
 935                                 --   class Monad m => MonadT t m where ...
 936                                 --   instance Monad m => MonadT (EnvT env) m where ...
 937                                 -- Here, the inst_decl_theta has (Monad m); but so
 938                                 -- does the sc_theta'!
 939                                 --
 940                                 -- NOTE the "not_const".  I got caught by this one too:
 941                                 --   class Foo a => Baz a b where ...
 942                                 --   instance Wob b => Baz T b where..
 943                                 -- Now sc_theta' has Foo T
 944 -}
 945 \end{code}
 946
 947
 948 %************************************************************************
 949 %*                                                                      *
 950 \subsection{Un-definable}
 951 %*                                                                      *
 952 %************************************************************************
 953
 954 These Ids can't be defined in Haskell.  They could be defined in
 955 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
 956 ensure that they were definitely, definitely inlined, because there is
 957 no curried identifier for them.  That's what mkCompulsoryUnfolding
 958 does.  If we had a way to get a compulsory unfolding from an interface
 959 file, we could do that, but we don't right now.
 960
 961 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
 962 just gets expanded into a type coercion wherever it occurs.  Hence we
 963 add it as a built-in Id with an unfolding here.
 964
 965 The type variables we use here are "open" type variables: this means
 966 they can unify with both unlifted and lifted types.  Hence we provide
 967 another gun with which to shoot yourself in the foot.
 968
 969 \begin{code}
 970 mkWiredInIdName mod fs uniq id
 971  = mkWiredInName mod (mkOccNameFS varName fs) uniq Nothing (AnId id) UserSyntax
 972
 973 unsafeCoerceName = mkWiredInIdName gHC_PRIM FSLIT("unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
 974 nullAddrName     = mkWiredInIdName gHC_PRIM FSLIT("nullAddr#")     nullAddrIdKey      nullAddrId
 975 seqName          = mkWiredInIdName gHC_PRIM FSLIT("seq")           seqIdKey           seqId
 976 realWorldName    = mkWiredInIdName gHC_PRIM FSLIT("realWorld#")    realWorldPrimIdKey realWorldPrimId
 977 lazyIdName       = mkWiredInIdName gHC_BASE FSLIT("lazy")         lazyIdKey           lazyId
 978
 979 errorName                = mkWiredInIdName gHC_ERR FSLIT("error")            errorIdKey eRROR_ID
 980 recSelErrorName          = mkWiredInIdName gHC_ERR FSLIT("recSelError")     recSelErrorIdKey rEC_SEL_ERROR_ID
 981 runtimeErrorName         = mkWiredInIdName gHC_ERR FSLIT("runtimeError")    runtimeErrorIdKey rUNTIME_ERROR_ID
 982 irrefutPatErrorName      = mkWiredInIdName gHC_ERR FSLIT("irrefutPatError") irrefutPatErrorIdKey iRREFUT_PAT_ERROR_ID
 983 recConErrorName          = mkWiredInIdName gHC_ERR FSLIT("recConError")     recConErrorIdKey rEC_CON_ERROR_ID
 984 patErrorName             = mkWiredInIdName gHC_ERR FSLIT("patError")         patErrorIdKey pAT_ERROR_ID
 985 noMethodBindingErrorName = mkWiredInIdName gHC_ERR FSLIT("noMethodBindingError")
 986                                            noMethodBindingErrorIdKey nO_METHOD_BINDING_ERROR_ID
 987 nonExhaustiveGuardsErrorName
 988   = mkWiredInIdName gHC_ERR FSLIT("nonExhaustiveGuardsError")
 989                     nonExhaustiveGuardsErrorIdKey nON_EXHAUSTIVE_GUARDS_ERROR_ID
 990 \end{code}
 991
 992 \begin{code}
 993 -- unsafeCoerce# :: forall a b. a -> b
 994 unsafeCoerceId
 995   = pcMiscPrelId unsafeCoerceName ty info
 996   where
 997     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
 998
 999
1000     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
1001                       (mkFunTy openAlphaTy openBetaTy)
1002     [x] = mkTemplateLocals [openAlphaTy]
1003     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
1004 --       Note (Coerce openBetaTy openAlphaTy) (Var x)
1005          Cast (Var x) (mkUnsafeCoercion openAlphaTy openBetaTy)
1006
1007 -- nullAddr# :: Addr#
1008 -- The reason is is here is because we don't provide
1009 -- a way to write this literal in Haskell.
1010 nullAddrId
1011   = pcMiscPrelId nullAddrName addrPrimTy info
1012   where
1013     info = noCafIdInfo `setUnfoldingInfo`
1014            mkCompulsoryUnfolding (Lit nullAddrLit)
1015
1016 seqId
1017   = pcMiscPrelId seqName ty info
1018   where
1019     info = noCafIdInfo `setUnfoldingInfo` mkCompulsoryUnfolding rhs
1020
1021
1022     ty  = mkForAllTys [alphaTyVar,openBetaTyVar]
1023                       (mkFunTy alphaTy (mkFunTy openBetaTy openBetaTy))
1024     [x,y] = mkTemplateLocals [alphaTy, openBetaTy]
1025     rhs = mkLams [alphaTyVar,openBetaTyVar,x,y] (Case (Var x) x openBetaTy [(DEFAULT, [], Var y)])
1026
1027 -- lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1028 -- Used to lazify pseq:         pseq a b = a `seq` lazy b
1029 --
1030 -- Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1031 -- not from GHC.Base.hi.   This is important, because the strictness
1032 -- analyser will spot it as strict!
1033 --
1034 -- Also no unfolding in lazyId: it gets "inlined" by a HACK in the worker/wrapper pass
1035 --      (see WorkWrap.wwExpr)
1036 -- We could use inline phases to do this, but that would be vulnerable to changes in
1037 -- phase numbering....we must inline precisely after strictness analysis.
1038 lazyId
1039   = pcMiscPrelId lazyIdName ty info
1040   where
1041     info = noCafIdInfo
1042     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
1043
1044 lazyIdUnfolding :: CoreExpr     -- Used to expand 'lazyId' after strictness anal
1045 lazyIdUnfolding = mkLams [openAlphaTyVar,x] (Var x)
1046                 where
1047                   [x] = mkTemplateLocals [openAlphaTy]
1048 \end{code}
1049
1050 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1051 nasty as-is, change it back to a literal (@Literal@).
1052
1053 voidArgId is a Local Id used simply as an argument in functions
1054 where we just want an arg to avoid having a thunk of unlifted type.
1055 E.g.
1056         x = \ void :: State# RealWorld -> (# p, q #)
1057
1058 This comes up in strictness analysis
1059
1060 \begin{code}
1061 realWorldPrimId -- :: State# RealWorld
1062   = pcMiscPrelId realWorldName realWorldStatePrimTy
1063                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1064         -- The evaldUnfolding makes it look that realWorld# is evaluated
1065         -- which in turn makes Simplify.interestingArg return True,
1066         -- which in turn makes INLINE things applied to realWorld# likely
1067         -- to be inlined
1068
1069 voidArgId       -- :: State# RealWorld
1070   = mkSysLocal FSLIT("void") voidArgIdKey realWorldStatePrimTy
1071 \end{code}
1072
1073
1074 %************************************************************************
1075 %*                                                                      *
1076 \subsection[PrelVals-error-related]{@error@ and friends; @trace@}
1077 %*                                                                      *
1078 %************************************************************************
1079
1080 GHC randomly injects these into the code.
1081
1082 @patError@ is just a version of @error@ for pattern-matching
1083 failures.  It knows various ``codes'' which expand to longer
1084 strings---this saves space!
1085
1086 @absentErr@ is a thing we put in for ``absent'' arguments.  They jolly
1087 well shouldn't be yanked on, but if one is, then you will get a
1088 friendly message from @absentErr@ (rather than a totally random
1089 crash).
1090
1091 @parError@ is a special version of @error@ which the compiler does
1092 not know to be a bottoming Id.  It is used in the @_par_@ and @_seq_@
1093 templates, but we don't ever expect to generate code for it.
1094
1095 \begin{code}
1096 mkRuntimeErrorApp
1097         :: Id           -- Should be of type (forall a. Addr# -> a)
1098                         --      where Addr# points to a UTF8 encoded string
1099         -> Type         -- The type to instantiate 'a'
1100         -> String       -- The string to print
1101         -> CoreExpr
1102
1103 mkRuntimeErrorApp err_id res_ty err_msg
1104   = mkApps (Var err_id) [Type res_ty, err_string]
1105   where
1106     err_string = Lit (mkStringLit err_msg)
1107
1108 rEC_SEL_ERROR_ID                = mkRuntimeErrorId recSelErrorName
1109 rUNTIME_ERROR_ID                = mkRuntimeErrorId runtimeErrorName
1110 iRREFUT_PAT_ERROR_ID            = mkRuntimeErrorId irrefutPatErrorName
1111 rEC_CON_ERROR_ID                = mkRuntimeErrorId recConErrorName
1112 pAT_ERROR_ID                    = mkRuntimeErrorId patErrorName
1113 nO_METHOD_BINDING_ERROR_ID      = mkRuntimeErrorId noMethodBindingErrorName
1114 nON_EXHAUSTIVE_GUARDS_ERROR_ID  = mkRuntimeErrorId nonExhaustiveGuardsErrorName
1115
1116 -- The runtime error Ids take a UTF8-encoded string as argument
1117 mkRuntimeErrorId name = pc_bottoming_Id name runtimeErrorTy
1118 runtimeErrorTy        = mkSigmaTy [openAlphaTyVar] [] (mkFunTy addrPrimTy openAlphaTy)
1119 \end{code}
1120
1121 \begin{code}
1122 eRROR_ID = pc_bottoming_Id errorName errorTy
1123
1124 errorTy  :: Type
1125 errorTy  = mkSigmaTy [openAlphaTyVar] [] (mkFunTys [mkListTy charTy] openAlphaTy)
1126     -- Notice the openAlphaTyVar.  It says that "error" can be applied
1127     -- to unboxed as well as boxed types.  This is OK because it never
1128     -- returns, so the return type is irrelevant.
1129 \end{code}
1130
1131
1132 %************************************************************************
1133 %*                                                                      *
1134 \subsection{Utilities}
1135 %*                                                                      *
1136 %************************************************************************
1137
1138 \begin{code}
1139 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1140 pcMiscPrelId name ty info
1141   = mkVanillaGlobal name ty info
1142     -- We lie and say the thing is imported; otherwise, we get into
1143     -- a mess with dependency analysis; e.g., core2stg may heave in
1144     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1145     -- being compiled, then it's just a matter of luck if the definition
1146     -- will be in "the right place" to be in scope.
1147
1148 pc_bottoming_Id name ty
1149  = pcMiscPrelId name ty bottoming_info
1150  where
1151     bottoming_info = vanillaIdInfo `setAllStrictnessInfo` Just strict_sig
1152         -- Do *not* mark them as NoCafRefs, because they can indeed have
1153         -- CAF refs.  For example, pAT_ERROR_ID calls GHC.Err.untangle,
1154         -- which has some CAFs
1155         -- In due course we may arrange that these error-y things are
1156         -- regarded by the GC as permanently live, in which case we
1157         -- can give them NoCaf info.  As it is, any function that calls
1158         -- any pc_bottoming_Id will itself have CafRefs, which bloats
1159         -- SRTs.
1160
1161     strict_sig     = mkStrictSig (mkTopDmdType [evalDmd] BotRes)
1162         -- These "bottom" out, no matter what their arguments
1163
1164 (openAlphaTyVar:openBetaTyVar:_) = openAlphaTyVars
1165 openAlphaTy  = mkTyVarTy openAlphaTyVar
1166 openBetaTy   = mkTyVarTy openBetaTyVar
1167 \end{code}
1168