compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the "namespace" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName,
  29         tvName, srcDataName,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPArrayTyConOcc, mkPArrayDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 import Util
  96 import Unique
  97 import BasicTypes
  98 import StaticFlags
  99 import UniqFM
 100 import UniqSet
 101 import FastString
 102 import FastTypes
 103 import Outputable
 104 import Binary
 105
 106 import GHC.Exts
 107 import Data.Char
 108 \end{code}
 109
 110 \begin{code}
 111 -- Unicode TODO: put isSymbol in libcompat
 112 #if !defined(__GLASGOW_HASKELL__) || __GLASGOW_HASKELL__ > 604
 113 #else
 114 isSymbol :: a -> Bool
 115 isSymbol = const False
 116 #endif
 117
 118 \end{code}
 119
 120 %************************************************************************
 121 %*                                                                      *
 122 \subsection{Name space}
 123 %*                                                                      *
 124 %************************************************************************
 125
 126 \begin{code}
 127 data NameSpace = VarName        -- Variables, including "real" data constructors
 128                | DataName       -- "Source" data constructors
 129                | TvName         -- Type variables
 130                | TcClsName      -- Type constructors and classes; Haskell has them
 131                                 -- in the same name space for now.
 132                deriving( Eq, Ord )
 133    {-! derive: Binary !-}
 134
 135 -- Note [Data Constructors]
 136 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 137 --
 138 -- $real_vs_source_data_constructors
 139 -- There are two forms of data constructor:
 140 --
 141 --      [Source data constructors] The data constructors mentioned in Haskell source code
 142 --
 143 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 144 --
 145 -- For example:
 146 --
 147 -- > data T = T !(Int, Int)
 148 --
 149 -- The source datacon has type @(Int, Int) -> T@
 150 -- The real   datacon has type @Int -> Int -> T@
 151 --
 152 -- GHC chooses a representation based on the strictness etc.
 153
 154 tcName, clsName, tcClsName :: NameSpace
 155 dataName, srcDataName      :: NameSpace
 156 tvName, varName            :: NameSpace
 157
 158 -- Though type constructors and classes are in the same name space now,
 159 -- the NameSpace type is abstract, so we can easily separate them later
 160 tcName    = TcClsName           -- Type constructors
 161 clsName   = TcClsName           -- Classes
 162 tcClsName = TcClsName           -- Not sure which!
 163
 164 dataName    = DataName
 165 srcDataName = DataName  -- Haskell-source data constructors should be
 166                         -- in the Data name space
 167
 168 tvName      = TvName
 169 varName     = VarName
 170
 171 isDataConNameSpace :: NameSpace -> Bool
 172 isDataConNameSpace DataName = True
 173 isDataConNameSpace _        = False
 174
 175 isTcClsNameSpace :: NameSpace -> Bool
 176 isTcClsNameSpace TcClsName = True
 177 isTcClsNameSpace _         = False
 178
 179 isTvNameSpace :: NameSpace -> Bool
 180 isTvNameSpace TvName = True
 181 isTvNameSpace _      = False
 182
 183 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 184 isVarNameSpace TvName  = True
 185 isVarNameSpace VarName = True
 186 isVarNameSpace _       = False
 187
 188 isValNameSpace :: NameSpace -> Bool
 189 isValNameSpace DataName = True
 190 isValNameSpace VarName  = True
 191 isValNameSpace _        = False
 192
 193 pprNameSpace :: NameSpace -> SDoc
 194 pprNameSpace DataName  = ptext (sLit "data constructor")
 195 pprNameSpace VarName   = ptext (sLit "variable")
 196 pprNameSpace TvName    = ptext (sLit "type variable")
 197 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 198
 199 pprNonVarNameSpace :: NameSpace -> SDoc
 200 pprNonVarNameSpace VarName = empty
 201 pprNonVarNameSpace ns = pprNameSpace ns
 202
 203 pprNameSpaceBrief :: NameSpace -> SDoc
 204 pprNameSpaceBrief DataName  = char 'd'
 205 pprNameSpaceBrief VarName   = char 'v'
 206 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 207 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 208 \end{code}
 209
 210
 211 %************************************************************************
 212 %*                                                                      *
 213 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 214 %*                                                                      *
 215 %************************************************************************
 216
 217 \begin{code}
 218 data OccName = OccName
 219     { occNameSpace  :: !NameSpace
 220     , occNameFS     :: !FastString
 221     }
 222 \end{code}
 223
 224
 225 \begin{code}
 226 instance Eq OccName where
 227     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 228
 229 instance Ord OccName where
 230         -- Compares lexicographically, *not* by Unique of the string
 231     compare (OccName sp1 s1) (OccName sp2 s2)
 232         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 233 \end{code}
 234
 235
 236 %************************************************************************
 237 %*                                                                      *
 238 \subsection{Printing}
 239 %*                                                                      *
 240 %************************************************************************
 241
 242 \begin{code}
 243 instance Outputable OccName where
 244     ppr = pprOccName
 245
 246 pprOccName :: OccName -> SDoc
 247 pprOccName (OccName sp occ)
 248   = getPprStyle $ \ sty ->
 249     if codeStyle sty
 250         then ftext (zEncodeFS occ)
 251         else ftext occ <> if debugStyle sty
 252                             then braces (pprNameSpaceBrief sp)
 253                             else empty
 254 \end{code}
 255
 256
 257 %************************************************************************
 258 %*                                                                      *
 259 \subsection{Construction}
 260 %*                                                                      *
 261 %************************************************************************
 262
 263 \begin{code}
 264 mkOccName :: NameSpace -> String -> OccName
 265 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 266
 267 mkOccNameFS :: NameSpace -> FastString -> OccName
 268 mkOccNameFS occ_sp fs = OccName occ_sp fs
 269
 270 mkVarOcc :: String -> OccName
 271 mkVarOcc s = mkOccName varName s
 272
 273 mkVarOccFS :: FastString -> OccName
 274 mkVarOccFS fs = mkOccNameFS varName fs
 275
 276 mkDataOcc :: String -> OccName
 277 mkDataOcc = mkOccName dataName
 278
 279 mkDataOccFS :: FastString -> OccName
 280 mkDataOccFS = mkOccNameFS dataName
 281
 282 mkTyVarOcc :: String -> OccName
 283 mkTyVarOcc = mkOccName tvName
 284
 285 mkTyVarOccFS :: FastString -> OccName
 286 mkTyVarOccFS fs = mkOccNameFS tvName fs
 287
 288 mkTcOcc :: String -> OccName
 289 mkTcOcc = mkOccName tcName
 290
 291 mkTcOccFS :: FastString -> OccName
 292 mkTcOccFS = mkOccNameFS tcName
 293
 294 mkClsOcc :: String -> OccName
 295 mkClsOcc = mkOccName clsName
 296
 297 mkClsOccFS :: FastString -> OccName
 298 mkClsOccFS = mkOccNameFS clsName
 299 \end{code}
 300
 301
 302 %************************************************************************
 303 %*                                                                      *
 304                 Environments
 305 %*                                                                      *
 306 %************************************************************************
 307
 308 OccEnvs are used mainly for the envts in ModIfaces.
 309
 310 They are efficient, because FastStrings have unique Int# keys.  We assume
 311 this key is less than 2^24, so we can make a Unique using
 312         mkUnique ns key  :: Unique
 313 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 314 easy to build an OccEnv.
 315
 316 \begin{code}
 317 instance Uniquable OccName where
 318   getUnique (OccName ns fs)
 319       = mkUnique char (iBox (uniqueOfFS fs))
 320       where     -- See notes above about this getUnique function
 321         char = case ns of
 322                 VarName   -> 'i'
 323                 DataName  -> 'd'
 324                 TvName    -> 'v'
 325                 TcClsName -> 't'
 326
 327 newtype OccEnv a = A (UniqFM a)
 328
 329 emptyOccEnv :: OccEnv a
 330 unitOccEnv  :: OccName -> a -> OccEnv a
 331 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 332 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 333 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 334 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 335 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 336 elemOccEnv   :: OccName -> OccEnv a -> Bool
 337 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 338 occEnvElts   :: OccEnv a -> [a]
 339 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 340 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 341 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 342 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 343 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 344 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 345 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 346
 347 emptyOccEnv      = A emptyUFM
 348 unitOccEnv x y = A $ unitUFM x y
 349 extendOccEnv (A x) y z = A $ addToUFM x y z
 350 extendOccEnvList (A x) l = A $ addListToUFM x l
 351 lookupOccEnv (A x) y = lookupUFM x y
 352 mkOccEnv     l    = A $ listToUFM l
 353 elemOccEnv x (A y)       = elemUFM x y
 354 foldOccEnv a b (A c)     = foldUFM a b c
 355 occEnvElts (A x)         = eltsUFM x
 356 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 357 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 358 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 359 mapOccEnv f (A x)        = A $ mapUFM f x
 360 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 361 delFromOccEnv (A x) y    = A $ delFromUFM x y
 362 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 363 filterOccEnv x (A y)       = A $ filterUFM x y
 364
 365 instance Outputable a => Outputable (OccEnv a) where
 366     ppr (A x) = ppr x
 367
 368 type OccSet = UniqSet OccName
 369
 370 emptyOccSet       :: OccSet
 371 unitOccSet        :: OccName -> OccSet
 372 mkOccSet          :: [OccName] -> OccSet
 373 extendOccSet      :: OccSet -> OccName -> OccSet
 374 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 375 unionOccSets      :: OccSet -> OccSet -> OccSet
 376 unionManyOccSets  :: [OccSet] -> OccSet
 377 minusOccSet       :: OccSet -> OccSet -> OccSet
 378 elemOccSet        :: OccName -> OccSet -> Bool
 379 occSetElts        :: OccSet -> [OccName]
 380 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 381 isEmptyOccSet     :: OccSet -> Bool
 382 intersectOccSet   :: OccSet -> OccSet -> OccSet
 383 intersectsOccSet  :: OccSet -> OccSet -> Bool
 384
 385 emptyOccSet       = emptyUniqSet
 386 unitOccSet        = unitUniqSet
 387 mkOccSet          = mkUniqSet
 388 extendOccSet      = addOneToUniqSet
 389 extendOccSetList  = addListToUniqSet
 390 unionOccSets      = unionUniqSets
 391 unionManyOccSets  = unionManyUniqSets
 392 minusOccSet       = minusUniqSet
 393 elemOccSet        = elementOfUniqSet
 394 occSetElts        = uniqSetToList
 395 foldOccSet        = foldUniqSet
 396 isEmptyOccSet     = isEmptyUniqSet
 397 intersectOccSet   = intersectUniqSets
 398 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 399 \end{code}
 400
 401
 402 %************************************************************************
 403 %*                                                                      *
 404 \subsection{Predicates and taking them apart}
 405 %*                                                                      *
 406 %************************************************************************
 407
 408 \begin{code}
 409 occNameString :: OccName -> String
 410 occNameString (OccName _ s) = unpackFS s
 411
 412 setOccNameSpace :: NameSpace -> OccName -> OccName
 413 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 414
 415 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 416
 417 isVarOcc (OccName VarName _) = True
 418 isVarOcc _                   = False
 419
 420 isTvOcc (OccName TvName _) = True
 421 isTvOcc _                  = False
 422
 423 isTcOcc (OccName TcClsName _) = True
 424 isTcOcc _                     = False
 425
 426 -- | /Value/ 'OccNames's are those that are either in
 427 -- the variable or data constructor namespaces
 428 isValOcc :: OccName -> Bool
 429 isValOcc (OccName VarName  _) = True
 430 isValOcc (OccName DataName _) = True
 431 isValOcc _                    = False
 432
 433 isDataOcc (OccName DataName _) = True
 434 isDataOcc (OccName VarName s)
 435   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 436                 -- Jan06: I don't think this should happen
 437 isDataOcc _                    = False
 438
 439 -- | Test if the 'OccName' is a data constructor that starts with
 440 -- a symbol (e.g. @:@, or @[]@)
 441 isDataSymOcc :: OccName -> Bool
 442 isDataSymOcc (OccName DataName s) = isLexConSym s
 443 isDataSymOcc (OccName VarName s)
 444   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 445                 -- Jan06: I don't think this should happen
 446 isDataSymOcc _                    = False
 447 -- Pretty inefficient!
 448
 449 -- | Test if the 'OccName' is that for any operator (whether
 450 -- it is a data constructor or variable or whatever)
 451 isSymOcc :: OccName -> Bool
 452 isSymOcc (OccName DataName s)  = isLexConSym s
 453 isSymOcc (OccName TcClsName s) = isLexConSym s
 454 isSymOcc (OccName VarName s)   = isLexSym s
 455 isSymOcc (OccName TvName s)    = isLexSym s
 456 -- Pretty inefficient!
 457
 458 parenSymOcc :: OccName -> SDoc -> SDoc
 459 -- ^ Wrap parens around an operator
 460 parenSymOcc occ doc | isSymOcc occ = parens doc
 461                     | otherwise    = doc
 462 \end{code}
 463
 464
 465 \begin{code}
 466 startsWithUnderscore :: OccName -> Bool
 467 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 468 -- names in a pattern if they start with @_@: this implements that test
 469 startsWithUnderscore occ = case occNameString occ of
 470                              ('_' : _) -> True
 471                              _other    -> False
 472 \end{code}
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477 \subsection{Making system names}
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 Here's our convention for splitting up the interface file name space:
 482
 483    d...         dictionary identifiers
 484                 (local variables, so no name-clash worries)
 485
 486 All of these other OccNames contain a mixture of alphabetic
 487 and symbolic characters, and hence cannot possibly clash with
 488 a user-written type or function name
 489
 490    $f...        Dict-fun identifiers (from inst decls)
 491    $dmop        Default method for 'op'
 492    $pnC         n'th superclass selector for class C
 493    $wf          Worker for functtoin 'f'
 494    $sf..        Specialised version of f
 495    T:C          Tycon for dictionary for class C
 496    D:C          Data constructor for dictionary for class C
 497    NTCo:T       Coercion connecting newtype T with its representation type
 498    TFCo:R       Coercion connecting a data family to its respresentation type R
 499
 500 In encoded form these appear as Zdfxxx etc
 501
 502         :...            keywords (export:, letrec: etc.)
 503 --- I THINK THIS IS WRONG!
 504
 505 This knowledge is encoded in the following functions.
 506
 507 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 508 NB: The string must already be encoded!
 509
 510 \begin{code}
 511 mk_deriv :: NameSpace
 512          -> String              -- Distinguishes one sort of derived name from another
 513          -> String
 514          -> OccName
 515
 516 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 517
 518 isDerivedOccName :: OccName -> Bool
 519 isDerivedOccName occ =
 520    case occNameString occ of
 521      '$':c:_ | isAlphaNum c -> True
 522      ':':c:_ | isAlphaNum c -> True
 523      _other                 -> False
 524 \end{code}
 525
 526 \begin{code}
 527 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 528         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 529         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 530         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 531         mkInstTyCoOcc, mkEqPredCoOcc,
 532         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 533         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 534         mkPArrayTyConOcc, mkPArrayDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 535    :: OccName -> OccName
 536
 537 -- These derived variables have a prefix that no Haskell value could have
 538 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 539 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 540 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 541 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 542 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 543 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 544                                                         -- for datacons from classes
 545 mkDictOcc           = mk_simple_deriv varName  "$d"
 546 mkIPOcc             = mk_simple_deriv varName  "$i"
 547 mkSpecOcc           = mk_simple_deriv varName  "$s"
 548 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 549 mkNewTyCoOcc        = mk_simple_deriv tcName  "NTCo:"   -- Coercion for newtypes
 550 mkInstTyCoOcc       = mk_simple_deriv tcName  "TFCo:"   -- Coercion for type functions
 551 mkEqPredCoOcc       = mk_simple_deriv tcName  "$co"
 552
 553 -- used in derived instances
 554 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 555 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 556 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 557
 558 -- Generic derivable classes
 559 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 560 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 561
 562 -- data T = MkT ... deriving( Data ) needs defintions for
 563 --      $tT   :: Data.Generics.Basics.DataType
 564 --      $cMkT :: Data.Generics.Basics.Constr
 565 mkDataTOcc = mk_simple_deriv varName  "$t"
 566 mkDataCOcc = mk_simple_deriv varName  "$c"
 567
 568 -- Vectorisation
 569 mkVectOcc          = mk_simple_deriv varName  "$v_"
 570 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 571 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 572 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 573 mkPArrayTyConOcc   = mk_simple_deriv tcName   ":VP_"
 574 mkPArrayDataConOcc = mk_simple_deriv dataName ":VPD_"
 575 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 576 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 577
 578 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 579 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 580
 581 -- Data constructor workers are made by setting the name space
 582 -- of the data constructor OccName (which should be a DataName)
 583 -- to VarName
 584 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 585 \end{code}
 586
 587 \begin{code}
 588 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 589                   -> OccName    -- ^ Class, e.g. @Ord@
 590                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 591 mkSuperDictSelOcc index cls_occ
 592   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 593
 594 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 595            -> OccName           -- ^ Local name, e.g. @sat@
 596            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 597 mkLocalOcc uniq occ
 598    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 599         -- The Unique might print with characters
 600         -- that need encoding (e.g. 'z'!)
 601 \end{code}
 602
 603 \begin{code}
 604 -- | Derive a name for the representation type constructor of a
 605 -- @data@\/@newtype@ instance.
 606 mkInstTyTcOcc :: Int                    -- ^ DFun Index
 607               -> OccName                -- ^ Family name, e.g. @Map@
 608               -> OccName                -- ^ Nice unique version, e.g. @:R23Map@
 609 mkInstTyTcOcc index occ
 610    = mk_deriv tcName ("R" ++ show index ++ ":") (occNameString occ)
 611 \end{code}
 612
 613 \begin{code}
 614 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 615                                 -- Only used in debug mode, for extra clarity
 616           -> Bool               -- ^ Is this a hs-boot instance DFun?
 617           -> Int                -- ^ Unique index
 618           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 619
 620 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 621 -- thing when we compile the mother module. Reason: we don't know exactly
 622 -- what the  mother module will call it.
 623
 624 mkDFunOcc info_str is_boot index
 625   = mk_deriv VarName prefix string
 626   where
 627     prefix | is_boot   = "$fx"
 628            | otherwise = "$f"
 629     string | opt_PprStyle_Debug = show index ++ info_str
 630            | otherwise          = show index
 631 \end{code}
 632
 633 We used to add a '$m' to indicate a method, but that gives rise to bad
 634 error messages from the type checker when we print the function name or pattern
 635 of an instance-decl binding.  Why? Because the binding is zapped
 636 to use the method name in place of the selector name.
 637 (See TcClassDcl.tcMethodBind)
 638
 639 The way it is now, -ddump-xx output may look confusing, but
 640 you can always say -dppr-debug to get the uniques.
 641
 642 However, we *do* have to zap the first character to be lower case,
 643 because overloaded constructors (blarg) generate methods too.
 644 And convert to VarName space
 645
 646 e.g. a call to constructor MkFoo where
 647         data (Ord a) => Foo a = MkFoo a
 648
 649 If this is necessary, we do it by prefixing '$m'.  These
 650 guys never show up in error messages.  What a hack.
 651
 652 \begin{code}
 653 mkMethodOcc :: OccName -> OccName
 654 mkMethodOcc occ@(OccName VarName _) = occ
 655 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 656 \end{code}
 657
 658
 659 %************************************************************************
 660 %*                                                                      *
 661 \subsection{Tidying them up}
 662 %*                                                                      *
 663 %************************************************************************
 664
 665 Before we print chunks of code we like to rename it so that
 666 we don't have to print lots of silly uniques in it.  But we mustn't
 667 accidentally introduce name clashes!  So the idea is that we leave the
 668 OccName alone unless it accidentally clashes with one that is already
 669 in scope; if so, we tack on '1' at the end and try again, then '2', and
 670 so on till we find a unique one.
 671
 672 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 673 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 674 tack on the '1', if necessary.
 675
 676 \begin{code}
 677 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 678         -- Range gives a plausible starting point for new guesses
 679
 680 emptyTidyOccEnv :: TidyOccEnv
 681 emptyTidyOccEnv = emptyOccEnv
 682
 683 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 684 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 685
 686 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 687
 688 tidyOccName in_scope occ@(OccName occ_sp fs)
 689   = case lookupOccEnv in_scope occ of
 690         Nothing ->      -- Not already used: make it used
 691                    (extendOccEnv in_scope occ 1, occ)
 692
 693         Just n  ->      -- Already used: make a new guess,
 694                         -- change the guess base, and try again
 695                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 696                                 (mkOccName occ_sp (unpackFS fs ++ show n))
 697 \end{code}
 698
 699 %************************************************************************
 700 %*                                                                      *
 701                 Stuff for dealing with tuples
 702 %*                                                                      *
 703 %************************************************************************
 704
 705 \begin{code}
 706 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 707 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 708   where
 709         -- no need to cache these, the caching is done in the caller
 710         -- (TysWiredIn.mk_tuple)
 711     str = case bx of
 712                 Boxed   -> '(' : commas ++ ")"
 713                 Unboxed -> '(' : '#' : commas ++ "#)"
 714
 715     commas = take (ar-1) (repeat ',')
 716
 717 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 718 -- Tuples are special, because there are so many of them!
 719 isTupleOcc_maybe (OccName ns fs)
 720   = case unpackFS fs of
 721         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 722         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 723         _other           -> Nothing
 724   where
 725     count_commas (',':rest) = 1 + count_commas rest
 726     count_commas _          = 0
 727 \end{code}
 728
 729 %************************************************************************
 730 %*                                                                      *
 731 \subsection{Lexical categories}
 732 %*                                                                      *
 733 %************************************************************************
 734
 735 These functions test strings to see if they fit the lexical categories
 736 defined in the Haskell report.
 737
 738 \begin{code}
 739 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 740 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 741
 742 isLexCon cs = isLexConId  cs || isLexConSym cs
 743 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 744
 745 isLexId  cs = isLexConId  cs || isLexVarId  cs
 746 isLexSym cs = isLexConSym cs || isLexVarSym cs
 747
 748 -------------
 749
 750 isLexConId cs                           -- Prefix type or data constructors
 751   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 752   | cs == (fsLit "[]") = True
 753   | otherwise          = startsConId (headFS cs)
 754
 755 isLexVarId cs                           -- Ordinary prefix identifiers
 756   | nullFS cs         = False           --      e.g. "x", "_x"
 757   | otherwise         = startsVarId (headFS cs)
 758
 759 isLexConSym cs                          -- Infix type or data constructors
 760   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 761   | cs == (fsLit "->") = True
 762   | otherwise          = startsConSym (headFS cs)
 763
 764 isLexVarSym cs                          -- Infix identifiers
 765   | nullFS cs         = False           --      e.g. "+"
 766   | otherwise         = startsVarSym (headFS cs)
 767
 768 -------------
 769 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 770 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 771 startsConSym c = c == ':'                               -- Infix data constructors
 772 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 773 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 774
 775 isSymbolASCII :: Char -> Bool
 776 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 777 \end{code}
 778
 779 %************************************************************************
 780 %*                                                                      *
 781                 Binary instance
 782     Here rather than BinIface because OccName is abstract
 783 %*                                                                      *
 784 %************************************************************************
 785
 786 \begin{code}
 787 instance Binary NameSpace where
 788     put_ bh VarName = do
 789             putByte bh 0
 790     put_ bh DataName = do
 791             putByte bh 1
 792     put_ bh TvName = do
 793             putByte bh 2
 794     put_ bh TcClsName = do
 795             putByte bh 3
 796     get bh = do
 797             h <- getByte bh
 798             case h of
 799               0 -> do return VarName
 800               1 -> do return DataName
 801               2 -> do return TvName
 802               _ -> do return TcClsName
 803
 804 instance Binary OccName where
 805     put_ bh (OccName aa ab) = do
 806             put_ bh aa
 807             put_ bh ab
 808     get bh = do
 809           aa <- get bh
 810           ab <- get bh
 811           return (OccName aa ab)
 812 \end{code}