compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the "namespace" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName,
  29         tvName, srcDataName,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPDataTyConOcc, mkPDataDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 import Util
  96 import Unique
  97 import BasicTypes
  98 import StaticFlags
  99 import UniqFM
 100 import UniqSet
 101 import FastString
 102 import FastTypes
 103 import Outputable
 104 import Binary
 105 import Data.Char
 106 \end{code}
 107
 108 \begin{code}
 109 -- Unicode TODO: put isSymbol in libcompat
 110 #if !defined(__GLASGOW_HASKELL__) || __GLASGOW_HASKELL__ > 604
 111 #else
 112 isSymbol :: a -> Bool
 113 isSymbol = const False
 114 #endif
 115
 116 \end{code}
 117
 118 %************************************************************************
 119 %*                                                                      *
 120 \subsection{Name space}
 121 %*                                                                      *
 122 %************************************************************************
 123
 124 \begin{code}
 125 data NameSpace = VarName        -- Variables, including "real" data constructors
 126                | DataName       -- "Source" data constructors
 127                | TvName         -- Type variables
 128                | TcClsName      -- Type constructors and classes; Haskell has them
 129                                 -- in the same name space for now.
 130                deriving( Eq, Ord )
 131    {-! derive: Binary !-}
 132
 133 -- Note [Data Constructors]
 134 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 135 --
 136 -- $real_vs_source_data_constructors
 137 -- There are two forms of data constructor:
 138 --
 139 --      [Source data constructors] The data constructors mentioned in Haskell source code
 140 --
 141 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 142 --
 143 -- For example:
 144 --
 145 -- > data T = T !(Int, Int)
 146 --
 147 -- The source datacon has type @(Int, Int) -> T@
 148 -- The real   datacon has type @Int -> Int -> T@
 149 --
 150 -- GHC chooses a representation based on the strictness etc.
 151
 152 tcName, clsName, tcClsName :: NameSpace
 153 dataName, srcDataName      :: NameSpace
 154 tvName, varName            :: NameSpace
 155
 156 -- Though type constructors and classes are in the same name space now,
 157 -- the NameSpace type is abstract, so we can easily separate them later
 158 tcName    = TcClsName           -- Type constructors
 159 clsName   = TcClsName           -- Classes
 160 tcClsName = TcClsName           -- Not sure which!
 161
 162 dataName    = DataName
 163 srcDataName = DataName  -- Haskell-source data constructors should be
 164                         -- in the Data name space
 165
 166 tvName      = TvName
 167 varName     = VarName
 168
 169 isDataConNameSpace :: NameSpace -> Bool
 170 isDataConNameSpace DataName = True
 171 isDataConNameSpace _        = False
 172
 173 isTcClsNameSpace :: NameSpace -> Bool
 174 isTcClsNameSpace TcClsName = True
 175 isTcClsNameSpace _         = False
 176
 177 isTvNameSpace :: NameSpace -> Bool
 178 isTvNameSpace TvName = True
 179 isTvNameSpace _      = False
 180
 181 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 182 isVarNameSpace TvName  = True
 183 isVarNameSpace VarName = True
 184 isVarNameSpace _       = False
 185
 186 isValNameSpace :: NameSpace -> Bool
 187 isValNameSpace DataName = True
 188 isValNameSpace VarName  = True
 189 isValNameSpace _        = False
 190
 191 pprNameSpace :: NameSpace -> SDoc
 192 pprNameSpace DataName  = ptext (sLit "data constructor")
 193 pprNameSpace VarName   = ptext (sLit "variable")
 194 pprNameSpace TvName    = ptext (sLit "type variable")
 195 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 196
 197 pprNonVarNameSpace :: NameSpace -> SDoc
 198 pprNonVarNameSpace VarName = empty
 199 pprNonVarNameSpace ns = pprNameSpace ns
 200
 201 pprNameSpaceBrief :: NameSpace -> SDoc
 202 pprNameSpaceBrief DataName  = char 'd'
 203 pprNameSpaceBrief VarName   = char 'v'
 204 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 205 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 206 \end{code}
 207
 208
 209 %************************************************************************
 210 %*                                                                      *
 211 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 212 %*                                                                      *
 213 %************************************************************************
 214
 215 \begin{code}
 216 data OccName = OccName
 217     { occNameSpace  :: !NameSpace
 218     , occNameFS     :: !FastString
 219     }
 220 \end{code}
 221
 222
 223 \begin{code}
 224 instance Eq OccName where
 225     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 226
 227 instance Ord OccName where
 228         -- Compares lexicographically, *not* by Unique of the string
 229     compare (OccName sp1 s1) (OccName sp2 s2)
 230         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Printing}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 \begin{code}
 241 instance Outputable OccName where
 242     ppr = pprOccName
 243
 244 pprOccName :: OccName -> SDoc
 245 pprOccName (OccName sp occ)
 246   = getPprStyle $ \ sty ->
 247     if codeStyle sty
 248         then ftext (zEncodeFS occ)
 249         else ftext occ <> if debugStyle sty
 250                             then braces (pprNameSpaceBrief sp)
 251                             else empty
 252 \end{code}
 253
 254
 255 %************************************************************************
 256 %*                                                                      *
 257 \subsection{Construction}
 258 %*                                                                      *
 259 %************************************************************************
 260
 261 \begin{code}
 262 mkOccName :: NameSpace -> String -> OccName
 263 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 264
 265 mkOccNameFS :: NameSpace -> FastString -> OccName
 266 mkOccNameFS occ_sp fs = OccName occ_sp fs
 267
 268 mkVarOcc :: String -> OccName
 269 mkVarOcc s = mkOccName varName s
 270
 271 mkVarOccFS :: FastString -> OccName
 272 mkVarOccFS fs = mkOccNameFS varName fs
 273
 274 mkDataOcc :: String -> OccName
 275 mkDataOcc = mkOccName dataName
 276
 277 mkDataOccFS :: FastString -> OccName
 278 mkDataOccFS = mkOccNameFS dataName
 279
 280 mkTyVarOcc :: String -> OccName
 281 mkTyVarOcc = mkOccName tvName
 282
 283 mkTyVarOccFS :: FastString -> OccName
 284 mkTyVarOccFS fs = mkOccNameFS tvName fs
 285
 286 mkTcOcc :: String -> OccName
 287 mkTcOcc = mkOccName tcName
 288
 289 mkTcOccFS :: FastString -> OccName
 290 mkTcOccFS = mkOccNameFS tcName
 291
 292 mkClsOcc :: String -> OccName
 293 mkClsOcc = mkOccName clsName
 294
 295 mkClsOccFS :: FastString -> OccName
 296 mkClsOccFS = mkOccNameFS clsName
 297 \end{code}
 298
 299
 300 %************************************************************************
 301 %*                                                                      *
 302                 Environments
 303 %*                                                                      *
 304 %************************************************************************
 305
 306 OccEnvs are used mainly for the envts in ModIfaces.
 307
 308 They are efficient, because FastStrings have unique Int# keys.  We assume
 309 this key is less than 2^24, so we can make a Unique using
 310         mkUnique ns key  :: Unique
 311 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 312 easy to build an OccEnv.
 313
 314 \begin{code}
 315 instance Uniquable OccName where
 316   getUnique (OccName ns fs)
 317       = mkUnique char (iBox (uniqueOfFS fs))
 318       where     -- See notes above about this getUnique function
 319         char = case ns of
 320                 VarName   -> 'i'
 321                 DataName  -> 'd'
 322                 TvName    -> 'v'
 323                 TcClsName -> 't'
 324
 325 newtype OccEnv a = A (UniqFM a)
 326
 327 emptyOccEnv :: OccEnv a
 328 unitOccEnv  :: OccName -> a -> OccEnv a
 329 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 330 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 331 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 332 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 333 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 334 elemOccEnv   :: OccName -> OccEnv a -> Bool
 335 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 336 occEnvElts   :: OccEnv a -> [a]
 337 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 338 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 339 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 340 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 341 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 342 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 343 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 344
 345 emptyOccEnv      = A emptyUFM
 346 unitOccEnv x y = A $ unitUFM x y
 347 extendOccEnv (A x) y z = A $ addToUFM x y z
 348 extendOccEnvList (A x) l = A $ addListToUFM x l
 349 lookupOccEnv (A x) y = lookupUFM x y
 350 mkOccEnv     l    = A $ listToUFM l
 351 elemOccEnv x (A y)       = elemUFM x y
 352 foldOccEnv a b (A c)     = foldUFM a b c
 353 occEnvElts (A x)         = eltsUFM x
 354 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 355 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 356 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 357 mapOccEnv f (A x)        = A $ mapUFM f x
 358 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 359 delFromOccEnv (A x) y    = A $ delFromUFM x y
 360 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 361 filterOccEnv x (A y)       = A $ filterUFM x y
 362
 363 instance Outputable a => Outputable (OccEnv a) where
 364     ppr (A x) = ppr x
 365
 366 type OccSet = UniqSet OccName
 367
 368 emptyOccSet       :: OccSet
 369 unitOccSet        :: OccName -> OccSet
 370 mkOccSet          :: [OccName] -> OccSet
 371 extendOccSet      :: OccSet -> OccName -> OccSet
 372 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 373 unionOccSets      :: OccSet -> OccSet -> OccSet
 374 unionManyOccSets  :: [OccSet] -> OccSet
 375 minusOccSet       :: OccSet -> OccSet -> OccSet
 376 elemOccSet        :: OccName -> OccSet -> Bool
 377 occSetElts        :: OccSet -> [OccName]
 378 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 379 isEmptyOccSet     :: OccSet -> Bool
 380 intersectOccSet   :: OccSet -> OccSet -> OccSet
 381 intersectsOccSet  :: OccSet -> OccSet -> Bool
 382
 383 emptyOccSet       = emptyUniqSet
 384 unitOccSet        = unitUniqSet
 385 mkOccSet          = mkUniqSet
 386 extendOccSet      = addOneToUniqSet
 387 extendOccSetList  = addListToUniqSet
 388 unionOccSets      = unionUniqSets
 389 unionManyOccSets  = unionManyUniqSets
 390 minusOccSet       = minusUniqSet
 391 elemOccSet        = elementOfUniqSet
 392 occSetElts        = uniqSetToList
 393 foldOccSet        = foldUniqSet
 394 isEmptyOccSet     = isEmptyUniqSet
 395 intersectOccSet   = intersectUniqSets
 396 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 397 \end{code}
 398
 399
 400 %************************************************************************
 401 %*                                                                      *
 402 \subsection{Predicates and taking them apart}
 403 %*                                                                      *
 404 %************************************************************************
 405
 406 \begin{code}
 407 occNameString :: OccName -> String
 408 occNameString (OccName _ s) = unpackFS s
 409
 410 setOccNameSpace :: NameSpace -> OccName -> OccName
 411 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 412
 413 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 414
 415 isVarOcc (OccName VarName _) = True
 416 isVarOcc _                   = False
 417
 418 isTvOcc (OccName TvName _) = True
 419 isTvOcc _                  = False
 420
 421 isTcOcc (OccName TcClsName _) = True
 422 isTcOcc _                     = False
 423
 424 -- | /Value/ 'OccNames's are those that are either in
 425 -- the variable or data constructor namespaces
 426 isValOcc :: OccName -> Bool
 427 isValOcc (OccName VarName  _) = True
 428 isValOcc (OccName DataName _) = True
 429 isValOcc _                    = False
 430
 431 isDataOcc (OccName DataName _) = True
 432 isDataOcc (OccName VarName s)
 433   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 434                 -- Jan06: I don't think this should happen
 435 isDataOcc _                    = False
 436
 437 -- | Test if the 'OccName' is a data constructor that starts with
 438 -- a symbol (e.g. @:@, or @[]@)
 439 isDataSymOcc :: OccName -> Bool
 440 isDataSymOcc (OccName DataName s) = isLexConSym s
 441 isDataSymOcc (OccName VarName s)
 442   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 443                 -- Jan06: I don't think this should happen
 444 isDataSymOcc _                    = False
 445 -- Pretty inefficient!
 446
 447 -- | Test if the 'OccName' is that for any operator (whether
 448 -- it is a data constructor or variable or whatever)
 449 isSymOcc :: OccName -> Bool
 450 isSymOcc (OccName DataName s)  = isLexConSym s
 451 isSymOcc (OccName TcClsName s) = isLexConSym s
 452 isSymOcc (OccName VarName s)   = isLexSym s
 453 isSymOcc (OccName TvName s)    = isLexSym s
 454 -- Pretty inefficient!
 455
 456 parenSymOcc :: OccName -> SDoc -> SDoc
 457 -- ^ Wrap parens around an operator
 458 parenSymOcc occ doc | isSymOcc occ = parens doc
 459                     | otherwise    = doc
 460 \end{code}
 461
 462
 463 \begin{code}
 464 startsWithUnderscore :: OccName -> Bool
 465 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 466 -- names in a pattern if they start with @_@: this implements that test
 467 startsWithUnderscore occ = case occNameString occ of
 468                              ('_' : _) -> True
 469                              _other    -> False
 470 \end{code}
 471
 472
 473 %************************************************************************
 474 %*                                                                      *
 475 \subsection{Making system names}
 476 %*                                                                      *
 477 %************************************************************************
 478
 479 Here's our convention for splitting up the interface file name space:
 480
 481    d...         dictionary identifiers
 482                 (local variables, so no name-clash worries)
 483
 484 All of these other OccNames contain a mixture of alphabetic
 485 and symbolic characters, and hence cannot possibly clash with
 486 a user-written type or function name
 487
 488    $f...        Dict-fun identifiers (from inst decls)
 489    $dmop        Default method for 'op'
 490    $pnC         n'th superclass selector for class C
 491    $wf          Worker for functtoin 'f'
 492    $sf..        Specialised version of f
 493    T:C          Tycon for dictionary for class C
 494    D:C          Data constructor for dictionary for class C
 495    NTCo:T       Coercion connecting newtype T with its representation type
 496    TFCo:R       Coercion connecting a data family to its respresentation type R
 497
 498 In encoded form these appear as Zdfxxx etc
 499
 500         :...            keywords (export:, letrec: etc.)
 501 --- I THINK THIS IS WRONG!
 502
 503 This knowledge is encoded in the following functions.
 504
 505 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 506 NB: The string must already be encoded!
 507
 508 \begin{code}
 509 mk_deriv :: NameSpace
 510          -> String              -- Distinguishes one sort of derived name from another
 511          -> String
 512          -> OccName
 513
 514 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 515
 516 isDerivedOccName :: OccName -> Bool
 517 isDerivedOccName occ =
 518    case occNameString occ of
 519      '$':c:_ | isAlphaNum c -> True
 520      ':':c:_ | isAlphaNum c -> True
 521      _other                 -> False
 522 \end{code}
 523
 524 \begin{code}
 525 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 526         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 527         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 528         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 529         mkInstTyCoOcc, mkEqPredCoOcc,
 530         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 531         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 532         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 533    :: OccName -> OccName
 534
 535 -- These derived variables have a prefix that no Haskell value could have
 536 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 537 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 538 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 539 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 540 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 541 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 542                                                         -- for datacons from classes
 543 mkDictOcc           = mk_simple_deriv varName  "$d"
 544 mkIPOcc             = mk_simple_deriv varName  "$i"
 545 mkSpecOcc           = mk_simple_deriv varName  "$s"
 546 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 547 mkNewTyCoOcc        = mk_simple_deriv tcName  "NTCo:"   -- Coercion for newtypes
 548 mkInstTyCoOcc       = mk_simple_deriv tcName  "TFCo:"   -- Coercion for type functions
 549 mkEqPredCoOcc       = mk_simple_deriv tcName  "$co"
 550
 551 -- used in derived instances
 552 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 553 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 554 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 555
 556 -- Generic derivable classes
 557 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 558 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 559
 560 -- data T = MkT ... deriving( Data ) needs defintions for
 561 --      $tT   :: Data.Generics.Basics.DataType
 562 --      $cMkT :: Data.Generics.Basics.Constr
 563 mkDataTOcc = mk_simple_deriv varName  "$t"
 564 mkDataCOcc = mk_simple_deriv varName  "$c"
 565
 566 -- Vectorisation
 567 mkVectOcc          = mk_simple_deriv varName  "$v_"
 568 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 569 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 570 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 571 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 572 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 573 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 574 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 575
 576 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 577 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 578
 579 -- Data constructor workers are made by setting the name space
 580 -- of the data constructor OccName (which should be a DataName)
 581 -- to VarName
 582 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 583 \end{code}
 584
 585 \begin{code}
 586 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 587                   -> OccName    -- ^ Class, e.g. @Ord@
 588                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 589 mkSuperDictSelOcc index cls_occ
 590   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 591
 592 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 593            -> OccName           -- ^ Local name, e.g. @sat@
 594            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 595 mkLocalOcc uniq occ
 596    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 597         -- The Unique might print with characters
 598         -- that need encoding (e.g. 'z'!)
 599 \end{code}
 600
 601 \begin{code}
 602 -- | Derive a name for the representation type constructor of a
 603 -- @data@\/@newtype@ instance.
 604 mkInstTyTcOcc :: Int                    -- ^ DFun Index
 605               -> OccName                -- ^ Family name, e.g. @Map@
 606               -> OccName                -- ^ Nice unique version, e.g. @:R23Map@
 607 mkInstTyTcOcc index occ
 608    = mk_deriv tcName ("R" ++ show index ++ ":") (occNameString occ)
 609 \end{code}
 610
 611 \begin{code}
 612 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 613                                 -- Only used in debug mode, for extra clarity
 614           -> Bool               -- ^ Is this a hs-boot instance DFun?
 615           -> Int                -- ^ Unique index
 616           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 617
 618 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 619 -- thing when we compile the mother module. Reason: we don't know exactly
 620 -- what the  mother module will call it.
 621
 622 mkDFunOcc info_str is_boot index
 623   = mk_deriv VarName prefix string
 624   where
 625     prefix | is_boot   = "$fx"
 626            | otherwise = "$f"
 627     string | opt_PprStyle_Debug = show index ++ info_str
 628            | otherwise          = show index
 629 \end{code}
 630
 631 We used to add a '$m' to indicate a method, but that gives rise to bad
 632 error messages from the type checker when we print the function name or pattern
 633 of an instance-decl binding.  Why? Because the binding is zapped
 634 to use the method name in place of the selector name.
 635 (See TcClassDcl.tcMethodBind)
 636
 637 The way it is now, -ddump-xx output may look confusing, but
 638 you can always say -dppr-debug to get the uniques.
 639
 640 However, we *do* have to zap the first character to be lower case,
 641 because overloaded constructors (blarg) generate methods too.
 642 And convert to VarName space
 643
 644 e.g. a call to constructor MkFoo where
 645         data (Ord a) => Foo a = MkFoo a
 646
 647 If this is necessary, we do it by prefixing '$m'.  These
 648 guys never show up in error messages.  What a hack.
 649
 650 \begin{code}
 651 mkMethodOcc :: OccName -> OccName
 652 mkMethodOcc occ@(OccName VarName _) = occ
 653 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 654 \end{code}
 655
 656
 657 %************************************************************************
 658 %*                                                                      *
 659 \subsection{Tidying them up}
 660 %*                                                                      *
 661 %************************************************************************
 662
 663 Before we print chunks of code we like to rename it so that
 664 we don't have to print lots of silly uniques in it.  But we mustn't
 665 accidentally introduce name clashes!  So the idea is that we leave the
 666 OccName alone unless it accidentally clashes with one that is already
 667 in scope; if so, we tack on '1' at the end and try again, then '2', and
 668 so on till we find a unique one.
 669
 670 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 671 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 672 tack on the '1', if necessary.
 673
 674 \begin{code}
 675 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 676         -- Range gives a plausible starting point for new guesses
 677
 678 emptyTidyOccEnv :: TidyOccEnv
 679 emptyTidyOccEnv = emptyOccEnv
 680
 681 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 682 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 683
 684 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 685
 686 tidyOccName in_scope occ@(OccName occ_sp fs)
 687   = case lookupOccEnv in_scope occ of
 688         Nothing ->      -- Not already used: make it used
 689                    (extendOccEnv in_scope occ 1, occ)
 690
 691         Just n  ->      -- Already used: make a new guess,
 692                         -- change the guess base, and try again
 693                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 694                                 (mkOccName occ_sp (unpackFS fs ++ show n))
 695 \end{code}
 696
 697 %************************************************************************
 698 %*                                                                      *
 699                 Stuff for dealing with tuples
 700 %*                                                                      *
 701 %************************************************************************
 702
 703 \begin{code}
 704 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 705 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 706   where
 707         -- no need to cache these, the caching is done in the caller
 708         -- (TysWiredIn.mk_tuple)
 709     str = case bx of
 710                 Boxed   -> '(' : commas ++ ")"
 711                 Unboxed -> '(' : '#' : commas ++ "#)"
 712
 713     commas = take (ar-1) (repeat ',')
 714
 715 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 716 -- Tuples are special, because there are so many of them!
 717 isTupleOcc_maybe (OccName ns fs)
 718   = case unpackFS fs of
 719         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 720         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 721         _other           -> Nothing
 722   where
 723     count_commas (',':rest) = 1 + count_commas rest
 724     count_commas _          = 0
 725 \end{code}
 726
 727 %************************************************************************
 728 %*                                                                      *
 729 \subsection{Lexical categories}
 730 %*                                                                      *
 731 %************************************************************************
 732
 733 These functions test strings to see if they fit the lexical categories
 734 defined in the Haskell report.
 735
 736 \begin{code}
 737 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 738 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 739
 740 isLexCon cs = isLexConId  cs || isLexConSym cs
 741 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 742
 743 isLexId  cs = isLexConId  cs || isLexVarId  cs
 744 isLexSym cs = isLexConSym cs || isLexVarSym cs
 745
 746 -------------
 747
 748 isLexConId cs                           -- Prefix type or data constructors
 749   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 750   | cs == (fsLit "[]") = True
 751   | otherwise          = startsConId (headFS cs)
 752
 753 isLexVarId cs                           -- Ordinary prefix identifiers
 754   | nullFS cs         = False           --      e.g. "x", "_x"
 755   | otherwise         = startsVarId (headFS cs)
 756
 757 isLexConSym cs                          -- Infix type or data constructors
 758   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 759   | cs == (fsLit "->") = True
 760   | otherwise          = startsConSym (headFS cs)
 761
 762 isLexVarSym cs                          -- Infix identifiers
 763   | nullFS cs         = False           --      e.g. "+"
 764   | otherwise         = startsVarSym (headFS cs)
 765
 766 -------------
 767 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 768 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 769 startsConSym c = c == ':'                               -- Infix data constructors
 770 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 771 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 772
 773 isSymbolASCII :: Char -> Bool
 774 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 775 \end{code}
 776
 777 %************************************************************************
 778 %*                                                                      *
 779                 Binary instance
 780     Here rather than BinIface because OccName is abstract
 781 %*                                                                      *
 782 %************************************************************************
 783
 784 \begin{code}
 785 instance Binary NameSpace where
 786     put_ bh VarName = do
 787             putByte bh 0
 788     put_ bh DataName = do
 789             putByte bh 1
 790     put_ bh TvName = do
 791             putByte bh 2
 792     put_ bh TcClsName = do
 793             putByte bh 3
 794     get bh = do
 795             h <- getByte bh
 796             case h of
 797               0 -> do return VarName
 798               1 -> do return DataName
 799               2 -> do return TvName
 800               _ -> do return TcClsName
 801
 802 instance Binary OccName where
 803     put_ bh (OccName aa ab) = do
 804             put_ bh aa
 805             put_ bh ab
 806     get bh = do
 807           aa <- get bh
 808           ab <- get bh
 809           return (OccName aa ab)
 810 \end{code}