compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the \"namespace\" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName,
  29         tvName, srcDataName,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc, mkClassOpAuxOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPDataTyConOcc, mkPDataDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         extendOccEnv_Acc, filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 import Util
  96 import Unique
  97 import BasicTypes
  98 import UniqFM
  99 import UniqSet
 100 import FastString
 101 import Outputable
 102 import Binary
 103 import Data.Char
 104 \end{code}
 105
 106 \begin{code}
 107 -- Unicode TODO: put isSymbol in libcompat
 108 #if !defined(__GLASGOW_HASKELL__) || __GLASGOW_HASKELL__ > 604
 109 #else
 110 isSymbol :: a -> Bool
 111 isSymbol = const False
 112 #endif
 113
 114 \end{code}
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{Name space}
 119 %*                                                                      *
 120 %************************************************************************
 121
 122 \begin{code}
 123 data NameSpace = VarName        -- Variables, including "real" data constructors
 124                | DataName       -- "Source" data constructors
 125                | TvName         -- Type variables
 126                | TcClsName      -- Type constructors and classes; Haskell has them
 127                                 -- in the same name space for now.
 128                deriving( Eq, Ord )
 129    {-! derive: Binary !-}
 130
 131 -- Note [Data Constructors]
 132 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 133 --
 134 -- $real_vs_source_data_constructors
 135 -- There are two forms of data constructor:
 136 --
 137 --      [Source data constructors] The data constructors mentioned in Haskell source code
 138 --
 139 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 140 --
 141 -- For example:
 142 --
 143 -- > data T = T !(Int, Int)
 144 --
 145 -- The source datacon has type @(Int, Int) -> T@
 146 -- The real   datacon has type @Int -> Int -> T@
 147 --
 148 -- GHC chooses a representation based on the strictness etc.
 149
 150 tcName, clsName, tcClsName :: NameSpace
 151 dataName, srcDataName      :: NameSpace
 152 tvName, varName            :: NameSpace
 153
 154 -- Though type constructors and classes are in the same name space now,
 155 -- the NameSpace type is abstract, so we can easily separate them later
 156 tcName    = TcClsName           -- Type constructors
 157 clsName   = TcClsName           -- Classes
 158 tcClsName = TcClsName           -- Not sure which!
 159
 160 dataName    = DataName
 161 srcDataName = DataName  -- Haskell-source data constructors should be
 162                         -- in the Data name space
 163
 164 tvName      = TvName
 165 varName     = VarName
 166
 167 isDataConNameSpace :: NameSpace -> Bool
 168 isDataConNameSpace DataName = True
 169 isDataConNameSpace _        = False
 170
 171 isTcClsNameSpace :: NameSpace -> Bool
 172 isTcClsNameSpace TcClsName = True
 173 isTcClsNameSpace _         = False
 174
 175 isTvNameSpace :: NameSpace -> Bool
 176 isTvNameSpace TvName = True
 177 isTvNameSpace _      = False
 178
 179 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 180 isVarNameSpace TvName  = True
 181 isVarNameSpace VarName = True
 182 isVarNameSpace _       = False
 183
 184 isValNameSpace :: NameSpace -> Bool
 185 isValNameSpace DataName = True
 186 isValNameSpace VarName  = True
 187 isValNameSpace _        = False
 188
 189 pprNameSpace :: NameSpace -> SDoc
 190 pprNameSpace DataName  = ptext (sLit "data constructor")
 191 pprNameSpace VarName   = ptext (sLit "variable")
 192 pprNameSpace TvName    = ptext (sLit "type variable")
 193 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 194
 195 pprNonVarNameSpace :: NameSpace -> SDoc
 196 pprNonVarNameSpace VarName = empty
 197 pprNonVarNameSpace ns = pprNameSpace ns
 198
 199 pprNameSpaceBrief :: NameSpace -> SDoc
 200 pprNameSpaceBrief DataName  = char 'd'
 201 pprNameSpaceBrief VarName   = char 'v'
 202 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 203 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 204 \end{code}
 205
 206
 207 %************************************************************************
 208 %*                                                                      *
 209 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 210 %*                                                                      *
 211 %************************************************************************
 212
 213 \begin{code}
 214 data OccName = OccName
 215     { occNameSpace  :: !NameSpace
 216     , occNameFS     :: !FastString
 217     }
 218 \end{code}
 219
 220
 221 \begin{code}
 222 instance Eq OccName where
 223     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 224
 225 instance Ord OccName where
 226         -- Compares lexicographically, *not* by Unique of the string
 227     compare (OccName sp1 s1) (OccName sp2 s2)
 228         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 229 \end{code}
 230
 231
 232 %************************************************************************
 233 %*                                                                      *
 234 \subsection{Printing}
 235 %*                                                                      *
 236 %************************************************************************
 237
 238 \begin{code}
 239 instance Outputable OccName where
 240     ppr = pprOccName
 241
 242 pprOccName :: OccName -> SDoc
 243 pprOccName (OccName sp occ)
 244   = getPprStyle $ \ sty ->
 245     if codeStyle sty
 246         then ftext (zEncodeFS occ)
 247         else ftext occ <> if debugStyle sty
 248                             then braces (pprNameSpaceBrief sp)
 249                             else empty
 250 \end{code}
 251
 252
 253 %************************************************************************
 254 %*                                                                      *
 255 \subsection{Construction}
 256 %*                                                                      *
 257 %************************************************************************
 258
 259 \begin{code}
 260 mkOccName :: NameSpace -> String -> OccName
 261 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 262
 263 mkOccNameFS :: NameSpace -> FastString -> OccName
 264 mkOccNameFS occ_sp fs = OccName occ_sp fs
 265
 266 mkVarOcc :: String -> OccName
 267 mkVarOcc s = mkOccName varName s
 268
 269 mkVarOccFS :: FastString -> OccName
 270 mkVarOccFS fs = mkOccNameFS varName fs
 271
 272 mkDataOcc :: String -> OccName
 273 mkDataOcc = mkOccName dataName
 274
 275 mkDataOccFS :: FastString -> OccName
 276 mkDataOccFS = mkOccNameFS dataName
 277
 278 mkTyVarOcc :: String -> OccName
 279 mkTyVarOcc = mkOccName tvName
 280
 281 mkTyVarOccFS :: FastString -> OccName
 282 mkTyVarOccFS fs = mkOccNameFS tvName fs
 283
 284 mkTcOcc :: String -> OccName
 285 mkTcOcc = mkOccName tcName
 286
 287 mkTcOccFS :: FastString -> OccName
 288 mkTcOccFS = mkOccNameFS tcName
 289
 290 mkClsOcc :: String -> OccName
 291 mkClsOcc = mkOccName clsName
 292
 293 mkClsOccFS :: FastString -> OccName
 294 mkClsOccFS = mkOccNameFS clsName
 295 \end{code}
 296
 297
 298 %************************************************************************
 299 %*                                                                      *
 300                 Environments
 301 %*                                                                      *
 302 %************************************************************************
 303
 304 OccEnvs are used mainly for the envts in ModIfaces.
 305
 306 Note [The Unique of an OccName]
 307 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 308 They are efficient, because FastStrings have unique Int# keys.  We assume
 309 this key is less than 2^24, and indeed FastStrings are allocated keys
 310 sequentially starting at 0.
 311
 312 So we can make a Unique using
 313         mkUnique ns key  :: Unique
 314 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 315 easy to build an OccEnv.
 316
 317 \begin{code}
 318 instance Uniquable OccName where
 319       -- See Note [The Unique of an OccName]
 320   getUnique (OccName VarName   fs) = mkVarOccUnique  fs
 321   getUnique (OccName DataName  fs) = mkDataOccUnique fs
 322   getUnique (OccName TvName    fs) = mkTvOccUnique   fs
 323   getUnique (OccName TcClsName fs) = mkTcOccUnique   fs
 324
 325 newtype OccEnv a = A (UniqFM a)
 326
 327 emptyOccEnv :: OccEnv a
 328 unitOccEnv  :: OccName -> a -> OccEnv a
 329 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 330 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 331 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 332 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 333 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 334 elemOccEnv   :: OccName -> OccEnv a -> Bool
 335 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 336 occEnvElts   :: OccEnv a -> [a]
 337 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 338 extendOccEnv_Acc :: (a->b->b) -> (a->b) -> OccEnv b -> OccName -> a -> OccEnv b
 339 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 340 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 341 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 342 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 343 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 344 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 345
 346 emptyOccEnv      = A emptyUFM
 347 unitOccEnv x y = A $ unitUFM x y
 348 extendOccEnv (A x) y z = A $ addToUFM x y z
 349 extendOccEnvList (A x) l = A $ addListToUFM x l
 350 lookupOccEnv (A x) y = lookupUFM x y
 351 mkOccEnv     l    = A $ listToUFM l
 352 elemOccEnv x (A y)       = elemUFM x y
 353 foldOccEnv a b (A c)     = foldUFM a b c
 354 occEnvElts (A x)         = eltsUFM x
 355 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 356 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 357 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 358 extendOccEnv_Acc f g (A x) y z   = A $ addToUFM_Acc f g x y z
 359 mapOccEnv f (A x)        = A $ mapUFM f x
 360 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 361 delFromOccEnv (A x) y    = A $ delFromUFM x y
 362 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 363 filterOccEnv x (A y)       = A $ filterUFM x y
 364
 365 instance Outputable a => Outputable (OccEnv a) where
 366     ppr (A x) = ppr x
 367
 368 type OccSet = UniqSet OccName
 369
 370 emptyOccSet       :: OccSet
 371 unitOccSet        :: OccName -> OccSet
 372 mkOccSet          :: [OccName] -> OccSet
 373 extendOccSet      :: OccSet -> OccName -> OccSet
 374 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 375 unionOccSets      :: OccSet -> OccSet -> OccSet
 376 unionManyOccSets  :: [OccSet] -> OccSet
 377 minusOccSet       :: OccSet -> OccSet -> OccSet
 378 elemOccSet        :: OccName -> OccSet -> Bool
 379 occSetElts        :: OccSet -> [OccName]
 380 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 381 isEmptyOccSet     :: OccSet -> Bool
 382 intersectOccSet   :: OccSet -> OccSet -> OccSet
 383 intersectsOccSet  :: OccSet -> OccSet -> Bool
 384
 385 emptyOccSet       = emptyUniqSet
 386 unitOccSet        = unitUniqSet
 387 mkOccSet          = mkUniqSet
 388 extendOccSet      = addOneToUniqSet
 389 extendOccSetList  = addListToUniqSet
 390 unionOccSets      = unionUniqSets
 391 unionManyOccSets  = unionManyUniqSets
 392 minusOccSet       = minusUniqSet
 393 elemOccSet        = elementOfUniqSet
 394 occSetElts        = uniqSetToList
 395 foldOccSet        = foldUniqSet
 396 isEmptyOccSet     = isEmptyUniqSet
 397 intersectOccSet   = intersectUniqSets
 398 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 399 \end{code}
 400
 401
 402 %************************************************************************
 403 %*                                                                      *
 404 \subsection{Predicates and taking them apart}
 405 %*                                                                      *
 406 %************************************************************************
 407
 408 \begin{code}
 409 occNameString :: OccName -> String
 410 occNameString (OccName _ s) = unpackFS s
 411
 412 setOccNameSpace :: NameSpace -> OccName -> OccName
 413 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 414
 415 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 416
 417 isVarOcc (OccName VarName _) = True
 418 isVarOcc _                   = False
 419
 420 isTvOcc (OccName TvName _) = True
 421 isTvOcc _                  = False
 422
 423 isTcOcc (OccName TcClsName _) = True
 424 isTcOcc _                     = False
 425
 426 -- | /Value/ 'OccNames's are those that are either in
 427 -- the variable or data constructor namespaces
 428 isValOcc :: OccName -> Bool
 429 isValOcc (OccName VarName  _) = True
 430 isValOcc (OccName DataName _) = True
 431 isValOcc _                    = False
 432
 433 isDataOcc (OccName DataName _) = True
 434 isDataOcc (OccName VarName s)
 435   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 436                 -- Jan06: I don't think this should happen
 437 isDataOcc _                    = False
 438
 439 -- | Test if the 'OccName' is a data constructor that starts with
 440 -- a symbol (e.g. @:@, or @[]@)
 441 isDataSymOcc :: OccName -> Bool
 442 isDataSymOcc (OccName DataName s) = isLexConSym s
 443 isDataSymOcc (OccName VarName s)
 444   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 445                 -- Jan06: I don't think this should happen
 446 isDataSymOcc _                    = False
 447 -- Pretty inefficient!
 448
 449 -- | Test if the 'OccName' is that for any operator (whether
 450 -- it is a data constructor or variable or whatever)
 451 isSymOcc :: OccName -> Bool
 452 isSymOcc (OccName DataName s)  = isLexConSym s
 453 isSymOcc (OccName TcClsName s) = isLexConSym s
 454 isSymOcc (OccName VarName s)   = isLexSym s
 455 isSymOcc (OccName TvName s)    = isLexSym s
 456 -- Pretty inefficient!
 457
 458 parenSymOcc :: OccName -> SDoc -> SDoc
 459 -- ^ Wrap parens around an operator
 460 parenSymOcc occ doc | isSymOcc occ = parens doc
 461                     | otherwise    = doc
 462 \end{code}
 463
 464
 465 \begin{code}
 466 startsWithUnderscore :: OccName -> Bool
 467 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 468 -- names in a pattern if they start with @_@: this implements that test
 469 startsWithUnderscore occ = case occNameString occ of
 470                              ('_' : _) -> True
 471                              _other    -> False
 472 \end{code}
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477 \subsection{Making system names}
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 Here's our convention for splitting up the interface file name space:
 482
 483    d...         dictionary identifiers
 484                 (local variables, so no name-clash worries)
 485
 486 All of these other OccNames contain a mixture of alphabetic
 487 and symbolic characters, and hence cannot possibly clash with
 488 a user-written type or function name
 489
 490    $f...        Dict-fun identifiers (from inst decls)
 491    $dmop        Default method for 'op'
 492    $pnC         n'th superclass selector for class C
 493    $wf          Worker for functtoin 'f'
 494    $sf..        Specialised version of f
 495    T:C          Tycon for dictionary for class C
 496    D:C          Data constructor for dictionary for class C
 497    NTCo:T       Coercion connecting newtype T with its representation type
 498    TFCo:R       Coercion connecting a data family to its respresentation type R
 499
 500 In encoded form these appear as Zdfxxx etc
 501
 502         :...            keywords (export:, letrec: etc.)
 503 --- I THINK THIS IS WRONG!
 504
 505 This knowledge is encoded in the following functions.
 506
 507 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 508 NB: The string must already be encoded!
 509
 510 \begin{code}
 511 mk_deriv :: NameSpace
 512          -> String              -- Distinguishes one sort of derived name from another
 513          -> String
 514          -> OccName
 515
 516 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 517
 518 isDerivedOccName :: OccName -> Bool
 519 isDerivedOccName occ =
 520    case occNameString occ of
 521      '$':c:_ | isAlphaNum c -> True
 522      ':':c:_ | isAlphaNum c -> True
 523      _other                 -> False
 524 \end{code}
 525
 526 \begin{code}
 527 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 528         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 529         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 530         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 531         mkInstTyCoOcc, mkEqPredCoOcc, mkClassOpAuxOcc,
 532         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 533         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 534         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 535    :: OccName -> OccName
 536
 537 -- These derived variables have a prefix that no Haskell value could have
 538 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 539 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 540 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 541 mkClassOpAuxOcc     = mk_simple_deriv varName  "$c"
 542 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 543 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 544 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 545                                                         -- for datacons from classes
 546 mkDictOcc           = mk_simple_deriv varName  "$d"
 547 mkIPOcc             = mk_simple_deriv varName  "$i"
 548 mkSpecOcc           = mk_simple_deriv varName  "$s"
 549 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 550 mkNewTyCoOcc        = mk_simple_deriv tcName   "NTCo:"  -- Coercion for newtypes
 551 mkInstTyCoOcc       = mk_simple_deriv tcName   "TFCo:"   -- Coercion for type functions
 552 mkEqPredCoOcc       = mk_simple_deriv tcName   "$co"
 553
 554 -- used in derived instances
 555 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 556 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 557 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 558
 559 -- Generic derivable classes
 560 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 561 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 562
 563 -- data T = MkT ... deriving( Data ) needs defintions for
 564 --      $tT   :: Data.Generics.Basics.DataType
 565 --      $cMkT :: Data.Generics.Basics.Constr
 566 mkDataTOcc = mk_simple_deriv varName  "$t"
 567 mkDataCOcc = mk_simple_deriv varName  "$c"
 568
 569 -- Vectorisation
 570 mkVectOcc          = mk_simple_deriv varName  "$v_"
 571 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 572 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 573 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 574 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 575 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 576 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 577 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 578
 579 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 580 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 581
 582 -- Data constructor workers are made by setting the name space
 583 -- of the data constructor OccName (which should be a DataName)
 584 -- to VarName
 585 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 586 \end{code}
 587
 588 \begin{code}
 589 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 590                   -> OccName    -- ^ Class, e.g. @Ord@
 591                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 592 mkSuperDictSelOcc index cls_occ
 593   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 594
 595 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 596            -> OccName           -- ^ Local name, e.g. @sat@
 597            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 598 mkLocalOcc uniq occ
 599    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 600         -- The Unique might print with characters
 601         -- that need encoding (e.g. 'z'!)
 602 \end{code}
 603
 604 \begin{code}
 605 -- | Derive a name for the representation type constructor of a
 606 -- @data@\/@newtype@ instance.
 607 mkInstTyTcOcc :: String                 -- ^ Family name, e.g. @Map@
 608               -> OccSet                 -- ^ avoid these Occs
 609               -> OccName                -- ^ @R:Map@
 610 mkInstTyTcOcc str set =
 611   chooseUniqueOcc tcName ('R' : ':' : str) set
 612 \end{code}
 613
 614 \begin{code}
 615 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 616                                 -- Only used in debug mode, for extra clarity
 617           -> Bool               -- ^ Is this a hs-boot instance DFun?
 618           -> OccSet             -- ^ avoid these Occs
 619           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 620
 621 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 622 -- thing when we compile the mother module. Reason: we don't know exactly
 623 -- what the  mother module will call it.
 624
 625 mkDFunOcc info_str is_boot set
 626   = chooseUniqueOcc VarName (prefix ++ info_str) set
 627   where
 628     prefix | is_boot   = "$fx"
 629            | otherwise = "$f"
 630 \end{code}
 631
 632 Sometimes we need to pick an OccName that has not already been used,
 633 given a set of in-use OccNames.
 634
 635 \begin{code}
 636 chooseUniqueOcc :: NameSpace -> String -> OccSet -> OccName
 637 chooseUniqueOcc ns str set = loop (mkOccName ns str) (0::Int)
 638   where
 639   loop occ n
 640    | occ `elemOccSet` set = loop (mkOccName ns (str ++ show n)) (n+1)
 641    | otherwise            = occ
 642 \end{code}
 643
 644 We used to add a '$m' to indicate a method, but that gives rise to bad
 645 error messages from the type checker when we print the function name or pattern
 646 of an instance-decl binding.  Why? Because the binding is zapped
 647 to use the method name in place of the selector name.
 648 (See TcClassDcl.tcMethodBind)
 649
 650 The way it is now, -ddump-xx output may look confusing, but
 651 you can always say -dppr-debug to get the uniques.
 652
 653 However, we *do* have to zap the first character to be lower case,
 654 because overloaded constructors (blarg) generate methods too.
 655 And convert to VarName space
 656
 657 e.g. a call to constructor MkFoo where
 658         data (Ord a) => Foo a = MkFoo a
 659
 660 If this is necessary, we do it by prefixing '$m'.  These
 661 guys never show up in error messages.  What a hack.
 662
 663 \begin{code}
 664 mkMethodOcc :: OccName -> OccName
 665 mkMethodOcc occ@(OccName VarName _) = occ
 666 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 667 \end{code}
 668
 669
 670 %************************************************************************
 671 %*                                                                      *
 672 \subsection{Tidying them up}
 673 %*                                                                      *
 674 %************************************************************************
 675
 676 Before we print chunks of code we like to rename it so that
 677 we don't have to print lots of silly uniques in it.  But we mustn't
 678 accidentally introduce name clashes!  So the idea is that we leave the
 679 OccName alone unless it accidentally clashes with one that is already
 680 in scope; if so, we tack on '1' at the end and try again, then '2', and
 681 so on till we find a unique one.
 682
 683 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 684 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 685 tack on the '1', if necessary.
 686
 687 \begin{code}
 688 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 689         -- Range gives a plausible starting point for new guesses
 690
 691 emptyTidyOccEnv :: TidyOccEnv
 692 emptyTidyOccEnv = emptyOccEnv
 693
 694 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 695 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 696
 697 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 698
 699 tidyOccName in_scope occ@(OccName occ_sp fs)
 700   = case lookupOccEnv in_scope occ of
 701         Nothing ->      -- Not already used: make it used
 702                    (extendOccEnv in_scope occ 1, occ)
 703
 704         Just n  ->      -- Already used: make a new guess,
 705                         -- change the guess base, and try again
 706                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 707                                 (mkOccName occ_sp (unpackFS fs ++ show n))
 708 \end{code}
 709
 710 %************************************************************************
 711 %*                                                                      *
 712                 Stuff for dealing with tuples
 713 %*                                                                      *
 714 %************************************************************************
 715
 716 \begin{code}
 717 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 718 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 719   where
 720         -- no need to cache these, the caching is done in the caller
 721         -- (TysWiredIn.mk_tuple)
 722     str = case bx of
 723                 Boxed   -> '(' : commas ++ ")"
 724                 Unboxed -> '(' : '#' : commas ++ "#)"
 725
 726     commas = take (ar-1) (repeat ',')
 727
 728 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 729 -- Tuples are special, because there are so many of them!
 730 isTupleOcc_maybe (OccName ns fs)
 731   = case unpackFS fs of
 732         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 733         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 734         _other           -> Nothing
 735   where
 736     count_commas (',':rest) = 1 + count_commas rest
 737     count_commas _          = 0
 738 \end{code}
 739
 740 %************************************************************************
 741 %*                                                                      *
 742 \subsection{Lexical categories}
 743 %*                                                                      *
 744 %************************************************************************
 745
 746 These functions test strings to see if they fit the lexical categories
 747 defined in the Haskell report.
 748
 749 \begin{code}
 750 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 751 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 752
 753 isLexCon cs = isLexConId  cs || isLexConSym cs
 754 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 755
 756 isLexId  cs = isLexConId  cs || isLexVarId  cs
 757 isLexSym cs = isLexConSym cs || isLexVarSym cs
 758
 759 -------------
 760
 761 isLexConId cs                           -- Prefix type or data constructors
 762   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 763   | cs == (fsLit "[]") = True
 764   | otherwise          = startsConId (headFS cs)
 765
 766 isLexVarId cs                           -- Ordinary prefix identifiers
 767   | nullFS cs         = False           --      e.g. "x", "_x"
 768   | otherwise         = startsVarId (headFS cs)
 769
 770 isLexConSym cs                          -- Infix type or data constructors
 771   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 772   | cs == (fsLit "->") = True
 773   | otherwise          = startsConSym (headFS cs)
 774
 775 isLexVarSym cs                          -- Infix identifiers
 776   | nullFS cs         = False           --      e.g. "+"
 777   | otherwise         = startsVarSym (headFS cs)
 778
 779 -------------
 780 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 781 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 782 startsConSym c = c == ':'                               -- Infix data constructors
 783 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 784 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 785
 786 isSymbolASCII :: Char -> Bool
 787 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 788 \end{code}
 789
 790 %************************************************************************
 791 %*                                                                      *
 792                 Binary instance
 793     Here rather than BinIface because OccName is abstract
 794 %*                                                                      *
 795 %************************************************************************
 796
 797 \begin{code}
 798 instance Binary NameSpace where
 799     put_ bh VarName = do
 800             putByte bh 0
 801     put_ bh DataName = do
 802             putByte bh 1
 803     put_ bh TvName = do
 804             putByte bh 2
 805     put_ bh TcClsName = do
 806             putByte bh 3
 807     get bh = do
 808             h <- getByte bh
 809             case h of
 810               0 -> do return VarName
 811               1 -> do return DataName
 812               2 -> do return TvName
 813               _ -> do return TcClsName
 814
 815 instance Binary OccName where
 816     put_ bh (OccName aa ab) = do
 817             put_ bh aa
 818             put_ bh ab
 819     get bh = do
 820           aa <- get bh
 821           ab <- get bh
 822           return (OccName aa ab)
 823 \end{code}