compiler/basicTypes/RdrName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7
   8 -- |
   9 -- #name_types#
  10 -- GHC uses several kinds of name internally:
  11 --
  12 -- * 'OccName.OccName': see "OccName#name_types"
  13 --
  14 -- * 'RdrName.RdrName' is the type of names that come directly from the parser. They
  15 --   have not yet had their scoping and binding resolved by the renamer and can be
  16 --   thought of to a first approximation as an 'OccName.OccName' with an optional module
  17 --   qualifier
  18 --
  19 -- * 'Name.Name': see "Name#name_types"
  20 --
  21 -- * 'Id.Id': see "Id#name_types"
  22 --
  23 -- * 'Var.Var': see "Var#name_types"
  24 module RdrName (
  25         -- * The main type
  26         RdrName(..),    -- Constructors exported only to BinIface
  27
  28         -- ** Construction
  29         mkRdrUnqual, mkRdrQual,
  30         mkUnqual, mkVarUnqual, mkQual, mkOrig,
  31         nameRdrName, getRdrName,
  32         mkDerivedRdrName,
  33
  34         -- ** Destruction
  35         rdrNameOcc, rdrNameSpace, setRdrNameSpace,
  36         isRdrDataCon, isRdrTyVar, isRdrTc, isQual, isQual_maybe, isUnqual,
  37         isOrig, isOrig_maybe, isExact, isExact_maybe, isSrcRdrName,
  38
  39         -- ** Printing
  40         showRdrName,
  41
  42         -- * Local mapping of 'RdrName' to 'Name.Name'
  43         LocalRdrEnv, emptyLocalRdrEnv, extendLocalRdrEnv,
  44         lookupLocalRdrEnv, lookupLocalRdrOcc, elemLocalRdrEnv,
  45
  46         -- * Global mapping of 'RdrName' to 'GlobalRdrElt's
  47         GlobalRdrEnv, emptyGlobalRdrEnv, mkGlobalRdrEnv, plusGlobalRdrEnv,
  48         lookupGlobalRdrEnv, extendGlobalRdrEnv,
  49         pprGlobalRdrEnv, globalRdrEnvElts,
  50         lookupGRE_RdrName, lookupGRE_Name, getGRE_NameQualifier_maybes,
  51         hideSomeUnquals, findLocalDupsRdrEnv,
  52
  53         -- ** Global 'RdrName' mapping elements: 'GlobalRdrElt', 'Provenance', 'ImportSpec'
  54         GlobalRdrElt(..), isLocalGRE, unQualOK, qualSpecOK, unQualSpecOK,
  55         Provenance(..), pprNameProvenance,
  56         Parent(..),
  57         ImportSpec(..), ImpDeclSpec(..), ImpItemSpec(..),
  58         importSpecLoc, importSpecModule, isExplicitItem
  59   ) where
  60
  61 #include "HsVersions.h"
  62
  63 import Module
  64 import Name
  65 import Maybes
  66 import SrcLoc
  67 import FastString
  68 import Outputable
  69 import Util
  70 \end{code}
  71
  72 %************************************************************************
  73 %*                                                                      *
  74 \subsection{The main data type}
  75 %*                                                                      *
  76 %************************************************************************
  77
  78 \begin{code}
  79 -- | Do not use the data constructors of RdrName directly: prefer the family
  80 -- of functions that creates them, such as 'mkRdrUnqual'
  81 data RdrName
  82   = Unqual OccName
  83         -- ^ Used for ordinary, unqualified occurrences, e.g. @x@, @y@ or @Foo@.
  84         -- Create such a 'RdrName' with 'mkRdrUnqual'
  85
  86   | Qual ModuleName OccName
  87         -- ^ A qualified name written by the user in
  88         -- /source/ code.  The module isn't necessarily
  89         -- the module where the thing is defined;
  90         -- just the one from which it is imported.
  91         -- Examples are @Bar.x@, @Bar.y@ or @Bar.Foo@.
  92         -- Create such a 'RdrName' with 'mkRdrQual'
  93
  94   | Orig Module OccName
  95         -- ^ An original name; the module is the /defining/ module.
  96         -- This is used when GHC generates code that will be fed
  97         -- into the renamer (e.g. from deriving clauses), but where
  98         -- we want to say \"Use Prelude.map dammit\". One of these
  99         -- can be created with 'mkOrig'
 100
 101   | Exact Name
 102         -- ^ We know exactly the 'Name'. This is used:
 103         --
 104         --  (1) When the parser parses built-in syntax like @[]@
 105         --      and @(,)@, but wants a 'RdrName' from it
 106         --
 107         --  (2) By Template Haskell, when TH has generated a unique name
 108         --
 109         -- Such a 'RdrName' can be created by using 'getRdrName' on a 'Name'
 110 \end{code}
 111
 112
 113 %************************************************************************
 114 %*                                                                      *
 115 \subsection{Simple functions}
 116 %*                                                                      *
 117 %************************************************************************
 118
 119 \begin{code}
 120 rdrNameOcc :: RdrName -> OccName
 121 rdrNameOcc (Qual _ occ) = occ
 122 rdrNameOcc (Unqual occ) = occ
 123 rdrNameOcc (Orig _ occ) = occ
 124 rdrNameOcc (Exact name) = nameOccName name
 125
 126 rdrNameSpace :: RdrName -> NameSpace
 127 rdrNameSpace = occNameSpace . rdrNameOcc
 128
 129 setRdrNameSpace :: RdrName -> NameSpace -> RdrName
 130 -- ^ This rather gruesome function is used mainly by the parser.
 131 -- When parsing:
 132 --
 133 -- > data T a = T | T1 Int
 134 --
 135 -- we parse the data constructors as /types/ because of parser ambiguities,
 136 -- so then we need to change the /type constr/ to a /data constr/
 137 --
 138 -- The exact-name case /can/ occur when parsing:
 139 --
 140 -- > data [] a = [] | a : [a]
 141 --
 142 -- For the exact-name case we return an original name.
 143 setRdrNameSpace (Unqual occ) ns = Unqual (setOccNameSpace ns occ)
 144 setRdrNameSpace (Qual m occ) ns = Qual m (setOccNameSpace ns occ)
 145 setRdrNameSpace (Orig m occ) ns = Orig m (setOccNameSpace ns occ)
 146 setRdrNameSpace (Exact n)    ns = ASSERT( isExternalName n )
 147                                   Orig (nameModule n)
 148                                        (setOccNameSpace ns (nameOccName n))
 149 \end{code}
 150
 151 \begin{code}
 152         -- These two are the basic constructors
 153 mkRdrUnqual :: OccName -> RdrName
 154 mkRdrUnqual occ = Unqual occ
 155
 156 mkRdrQual :: ModuleName -> OccName -> RdrName
 157 mkRdrQual mod occ = Qual mod occ
 158
 159 mkOrig :: Module -> OccName -> RdrName
 160 mkOrig mod occ = Orig mod occ
 161
 162 ---------------
 163 -- | Produce an original 'RdrName' whose module that of a parent 'Name' but its 'OccName'
 164 -- is derived from that of it's parent using the supplied function
 165 mkDerivedRdrName :: Name -> (OccName -> OccName) -> RdrName
 166 mkDerivedRdrName parent mk_occ
 167   = ASSERT2( isExternalName parent, ppr parent )
 168     mkOrig (nameModule parent) (mk_occ (nameOccName parent))
 169
 170 ---------------
 171         -- These two are used when parsing source files
 172         -- They do encode the module and occurrence names
 173 mkUnqual :: NameSpace -> FastString -> RdrName
 174 mkUnqual sp n = Unqual (mkOccNameFS sp n)
 175
 176 mkVarUnqual :: FastString -> RdrName
 177 mkVarUnqual n = Unqual (mkVarOccFS n)
 178
 179 -- | Make a qualified 'RdrName' in the given namespace and where the 'ModuleName' and
 180 -- the 'OccName' are taken from the first and second elements of the tuple respectively
 181 mkQual :: NameSpace -> (FastString, FastString) -> RdrName
 182 mkQual sp (m, n) = Qual (mkModuleNameFS m) (mkOccNameFS sp n)
 183
 184 getRdrName :: NamedThing thing => thing -> RdrName
 185 getRdrName name = nameRdrName (getName name)
 186
 187 nameRdrName :: Name -> RdrName
 188 nameRdrName name = Exact name
 189 -- Keep the Name even for Internal names, so that the
 190 -- unique is still there for debug printing, particularly
 191 -- of Types (which are converted to IfaceTypes before printing)
 192
 193 nukeExact :: Name -> RdrName
 194 nukeExact n
 195   | isExternalName n = Orig (nameModule n) (nameOccName n)
 196   | otherwise        = Unqual (nameOccName n)
 197 \end{code}
 198
 199 \begin{code}
 200 isRdrDataCon :: RdrName -> Bool
 201 isRdrTyVar   :: RdrName -> Bool
 202 isRdrTc      :: RdrName -> Bool
 203
 204 isRdrDataCon rn = isDataOcc (rdrNameOcc rn)
 205 isRdrTyVar   rn = isTvOcc   (rdrNameOcc rn)
 206 isRdrTc      rn = isTcOcc   (rdrNameOcc rn)
 207
 208 isSrcRdrName :: RdrName -> Bool
 209 isSrcRdrName (Unqual _) = True
 210 isSrcRdrName (Qual _ _) = True
 211 isSrcRdrName _          = False
 212
 213 isUnqual :: RdrName -> Bool
 214 isUnqual (Unqual _) = True
 215 isUnqual _          = False
 216
 217 isQual :: RdrName -> Bool
 218 isQual (Qual _ _) = True
 219 isQual _          = False
 220
 221 isQual_maybe :: RdrName -> Maybe (ModuleName, OccName)
 222 isQual_maybe (Qual m n) = Just (m,n)
 223 isQual_maybe _          = Nothing
 224
 225 isOrig :: RdrName -> Bool
 226 isOrig (Orig _ _) = True
 227 isOrig _          = False
 228
 229 isOrig_maybe :: RdrName -> Maybe (Module, OccName)
 230 isOrig_maybe (Orig m n) = Just (m,n)
 231 isOrig_maybe _          = Nothing
 232
 233 isExact :: RdrName -> Bool
 234 isExact (Exact _) = True
 235 isExact _         = False
 236
 237 isExact_maybe :: RdrName -> Maybe Name
 238 isExact_maybe (Exact n) = Just n
 239 isExact_maybe _         = Nothing
 240 \end{code}
 241
 242
 243 %************************************************************************
 244 %*                                                                      *
 245 \subsection{Instances}
 246 %*                                                                      *
 247 %************************************************************************
 248
 249 \begin{code}
 250 instance Outputable RdrName where
 251     ppr (Exact name)   = ppr name
 252     ppr (Unqual occ)   = ppr occ
 253     ppr (Qual mod occ) = ppr mod <> dot <> ppr occ
 254     ppr (Orig mod occ) = ppr mod <> dot <> ppr occ
 255
 256 instance OutputableBndr RdrName where
 257     pprBndr _ n
 258         | isTvOcc (rdrNameOcc n) = char '@' <+> ppr n
 259         | otherwise              = ppr n
 260
 261 showRdrName :: RdrName -> String
 262 showRdrName r = showSDoc (ppr r)
 263
 264 instance Eq RdrName where
 265     (Exact n1)    == (Exact n2)    = n1==n2
 266         -- Convert exact to orig
 267     (Exact n1)    == r2@(Orig _ _) = nukeExact n1 == r2
 268     r1@(Orig _ _) == (Exact n2)    = r1 == nukeExact n2
 269
 270     (Orig m1 o1)  == (Orig m2 o2)  = m1==m2 && o1==o2
 271     (Qual m1 o1)  == (Qual m2 o2)  = m1==m2 && o1==o2
 272     (Unqual o1)   == (Unqual o2)   = o1==o2
 273     _             == _             = False
 274
 275 instance Ord RdrName where
 276     a <= b = case (a `compare` b) of { LT -> True;  EQ -> True;  GT -> False }
 277     a <  b = case (a `compare` b) of { LT -> True;  EQ -> False; GT -> False }
 278     a >= b = case (a `compare` b) of { LT -> False; EQ -> True;  GT -> True  }
 279     a >  b = case (a `compare` b) of { LT -> False; EQ -> False; GT -> True  }
 280
 281         -- Exact < Unqual < Qual < Orig
 282         -- [Note: Apr 2004] We used to use nukeExact to convert Exact to Orig
 283         --      before comparing so that Prelude.map == the exact Prelude.map, but
 284         --      that meant that we reported duplicates when renaming bindings
 285         --      generated by Template Haskell; e.g
 286         --      do { n1 <- newName "foo"; n2 <- newName "foo";
 287         --           <decl involving n1,n2> }
 288         --      I think we can do without this conversion
 289     compare (Exact n1) (Exact n2) = n1 `compare` n2
 290     compare (Exact _)  _          = LT
 291
 292     compare (Unqual _)   (Exact _)    = GT
 293     compare (Unqual o1)  (Unqual  o2) = o1 `compare` o2
 294     compare (Unqual _)   _            = LT
 295
 296     compare (Qual _ _)   (Exact _)    = GT
 297     compare (Qual _ _)   (Unqual _)   = GT
 298     compare (Qual m1 o1) (Qual m2 o2) = (o1 `compare` o2) `thenCmp` (m1 `compare` m2)
 299     compare (Qual _ _)   (Orig _ _)   = LT
 300
 301     compare (Orig m1 o1) (Orig m2 o2) = (o1 `compare` o2) `thenCmp` (m1 `compare` m2)
 302     compare (Orig _ _)   _            = GT
 303 \end{code}
 304
 305 %************************************************************************
 306 %*                                                                      *
 307                         LocalRdrEnv
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 \begin{code}
 312 -- | This environment is used to store local bindings (@let@, @where@, lambda, @case@).
 313 -- It is keyed by OccName, because we never use it for qualified names
 314 type LocalRdrEnv = OccEnv Name
 315
 316 emptyLocalRdrEnv :: LocalRdrEnv
 317 emptyLocalRdrEnv = emptyOccEnv
 318
 319 extendLocalRdrEnv :: LocalRdrEnv -> [Name] -> LocalRdrEnv
 320 extendLocalRdrEnv env names
 321   = extendOccEnvList env [(nameOccName n, n) | n <- names]
 322
 323 lookupLocalRdrEnv :: LocalRdrEnv -> RdrName -> Maybe Name
 324 lookupLocalRdrEnv _   (Exact name) = Just name
 325 lookupLocalRdrEnv env (Unqual occ) = lookupOccEnv env occ
 326 lookupLocalRdrEnv _   _            = Nothing
 327
 328 lookupLocalRdrOcc :: LocalRdrEnv -> OccName -> Maybe Name
 329 lookupLocalRdrOcc env occ = lookupOccEnv env occ
 330
 331 elemLocalRdrEnv :: RdrName -> LocalRdrEnv -> Bool
 332 elemLocalRdrEnv rdr_name env
 333   | isUnqual rdr_name = rdrNameOcc rdr_name `elemOccEnv` env
 334   | otherwise         = False
 335 \end{code}
 336
 337 %************************************************************************
 338 %*                                                                      *
 339                         GlobalRdrEnv
 340 %*                                                                      *
 341 %************************************************************************
 342
 343 \begin{code}
 344 type GlobalRdrEnv = OccEnv [GlobalRdrElt]
 345 -- ^ Keyed by 'OccName'; when looking up a qualified name
 346 -- we look up the 'OccName' part, and then check the 'Provenance'
 347 -- to see if the appropriate qualification is valid.  This
 348 -- saves routinely doubling the size of the env by adding both
 349 -- qualified and unqualified names to the domain.
 350 --
 351 -- The list in the codomain is required because there may be name clashes
 352 -- These only get reported on lookup, not on construction
 353 --
 354 -- INVARIANT: All the members of the list have distinct
 355 --            'gre_name' fields; that is, no duplicate Names
 356 --
 357 -- INVARIANT: Imported provenance => Name is an ExternalName
 358 --            However LocalDefs can have an InternalName.  This
 359 --            happens only when type-checking a [d| ... |] Template
 360 --            Haskell quotation; see this note in RnNames
 361 --            Note [Top-level Names in Template Haskell decl quotes]
 362
 363 -- | An element of the 'GlobalRdrEnv'
 364 data GlobalRdrElt
 365   = GRE { gre_name :: Name,
 366           gre_par  :: Parent,
 367           gre_prov :: Provenance        -- ^ Why it's in scope
 368     }
 369
 370 data Parent = NoParent | ParentIs Name
 371               deriving (Eq)
 372
 373 instance Outputable Parent where
 374    ppr NoParent     = empty
 375    ppr (ParentIs n) = ptext (sLit "parent:") <> ppr n
 376
 377
 378 plusParent :: Parent -> Parent -> Parent
 379 plusParent p1 p2 = ASSERT2( p1 == p2, parens (ppr p1) <+> parens (ppr p2) )
 380                    p1
 381
 382 {- Why so complicated? -=chak
 383 plusParent :: Parent -> Parent -> Parent
 384 plusParent NoParent     rel =
 385   ASSERT2( case rel of { NoParent -> True; other -> False },
 386            ptext (sLit "plusParent[NoParent]: ") <+> ppr rel )
 387   NoParent
 388 plusParent (ParentIs n) rel =
 389   ASSERT2( case rel of { ParentIs m -> n==m;  other -> False },
 390            ptext (sLit "plusParent[ParentIs]:") <+> ppr n <> comma <+> ppr rel )
 391   ParentIs n
 392  -}
 393
 394 emptyGlobalRdrEnv :: GlobalRdrEnv
 395 emptyGlobalRdrEnv = emptyOccEnv
 396
 397 globalRdrEnvElts :: GlobalRdrEnv -> [GlobalRdrElt]
 398 globalRdrEnvElts env = foldOccEnv (++) [] env
 399
 400 instance Outputable GlobalRdrElt where
 401   ppr gre = ppr name <+> parens (ppr (gre_par gre) <+> pprNameProvenance gre)
 402           where
 403             name = gre_name gre
 404
 405 pprGlobalRdrEnv :: GlobalRdrEnv -> SDoc
 406 pprGlobalRdrEnv env
 407   = vcat (map pp (occEnvElts env))
 408   where
 409     pp gres = ppr (nameOccName (gre_name (head gres))) <> colon <+>
 410               vcat [ ppr (gre_name gre) <+> pprNameProvenance gre
 411                    | gre <- gres]
 412 \end{code}
 413
 414 \begin{code}
 415 lookupGlobalRdrEnv :: GlobalRdrEnv -> OccName -> [GlobalRdrElt]
 416 lookupGlobalRdrEnv env occ_name = case lookupOccEnv env occ_name of
 417                                         Nothing   -> []
 418                                         Just gres -> gres
 419
 420 extendGlobalRdrEnv :: GlobalRdrEnv -> GlobalRdrElt -> GlobalRdrEnv
 421 extendGlobalRdrEnv env gre = extendOccEnv_C add env occ [gre]
 422   where
 423     occ = nameOccName (gre_name gre)
 424     add gres _ = gre:gres
 425
 426 lookupGRE_RdrName :: RdrName -> GlobalRdrEnv -> [GlobalRdrElt]
 427 lookupGRE_RdrName rdr_name env
 428   = case lookupOccEnv env (rdrNameOcc rdr_name) of
 429         Nothing   -> []
 430         Just gres -> pickGREs rdr_name gres
 431
 432 lookupGRE_Name :: GlobalRdrEnv -> Name -> [GlobalRdrElt]
 433 lookupGRE_Name env name
 434   = [ gre | gre <- lookupGlobalRdrEnv env (nameOccName name),
 435             gre_name gre == name ]
 436
 437 getGRE_NameQualifier_maybes :: GlobalRdrEnv -> Name -> [Maybe [ModuleName]]
 438 getGRE_NameQualifier_maybes env
 439   = map qualifier_maybe . map gre_prov . lookupGRE_Name env
 440   where qualifier_maybe LocalDef       = Nothing
 441         qualifier_maybe (Imported iss) = Just $ map (is_as . is_decl) iss
 442
 443 pickGREs :: RdrName -> [GlobalRdrElt] -> [GlobalRdrElt]
 444 -- ^ Take a list of GREs which have the right OccName
 445 -- Pick those GREs that are suitable for this RdrName
 446 -- And for those, keep only only the Provenances that are suitable
 447 --
 448 -- Consider:
 449 --
 450 -- @
 451 --       module A ( f ) where
 452 --       import qualified Foo( f )
 453 --       import Baz( f )
 454 --       f = undefined
 455 -- @
 456 --
 457 -- Let's suppose that @Foo.f@ and @Baz.f@ are the same entity really.
 458 -- The export of @f@ is ambiguous because it's in scope from the local def
 459 -- and the import.  The lookup of @Unqual f@ should return a GRE for
 460 -- the locally-defined @f@, and a GRE for the imported @f@, with a /single/
 461 -- provenance, namely the one for @Baz(f)@.
 462 pickGREs rdr_name gres
 463   = mapCatMaybes pick gres
 464   where
 465     rdr_is_unqual = isUnqual rdr_name
 466     rdr_is_qual   = isQual_maybe rdr_name
 467
 468     pick :: GlobalRdrElt -> Maybe GlobalRdrElt
 469     pick gre@(GRE {gre_prov = LocalDef, gre_name = n})  -- Local def
 470         | rdr_is_unqual                    = Just gre
 471         | Just (mod,_) <- rdr_is_qual           -- Qualified name
 472         , Just n_mod <- nameModule_maybe n   -- Binder is External
 473         , mod == moduleName n_mod          = Just gre
 474         | otherwise                        = Nothing
 475     pick gre@(GRE {gre_prov = Imported [is]})   -- Single import (efficiency)
 476         | rdr_is_unqual,
 477           not (is_qual (is_decl is))    = Just gre
 478         | Just (mod,_) <- rdr_is_qual,
 479           mod == is_as (is_decl is)     = Just gre
 480         | otherwise                     = Nothing
 481     pick gre@(GRE {gre_prov = Imported is})     -- Multiple import
 482         | null filtered_is = Nothing
 483         | otherwise        = Just (gre {gre_prov = Imported filtered_is})
 484         where
 485           filtered_is | rdr_is_unqual
 486                       = filter (not . is_qual    . is_decl) is
 487                       | Just (mod,_) <- rdr_is_qual
 488                       = filter ((== mod) . is_as . is_decl) is
 489                       | otherwise
 490                       = []
 491
 492 isLocalGRE :: GlobalRdrElt -> Bool
 493 isLocalGRE (GRE {gre_prov = LocalDef}) = True
 494 isLocalGRE _                           = False
 495
 496 unQualOK :: GlobalRdrElt -> Bool
 497 -- ^ Test if an unqualifed version of this thing would be in scope
 498 unQualOK (GRE {gre_prov = LocalDef})    = True
 499 unQualOK (GRE {gre_prov = Imported is}) = any unQualSpecOK is
 500
 501 plusGlobalRdrEnv :: GlobalRdrEnv -> GlobalRdrEnv -> GlobalRdrEnv
 502 plusGlobalRdrEnv env1 env2 = plusOccEnv_C (foldr insertGRE) env1 env2
 503
 504 mkGlobalRdrEnv :: [GlobalRdrElt] -> GlobalRdrEnv
 505 mkGlobalRdrEnv gres
 506   = foldr add emptyGlobalRdrEnv gres
 507   where
 508     add gre env = extendOccEnv_C (foldr insertGRE) env
 509                                  (nameOccName (gre_name gre))
 510                                  [gre]
 511
 512 findLocalDupsRdrEnv :: GlobalRdrEnv -> [OccName] -> (GlobalRdrEnv, [[Name]])
 513 -- ^ For each 'OccName', see if there are multiple local definitions
 514 -- for it.  If so, remove all but one (to suppress subsequent error messages)
 515 -- and return a list of the duplicate bindings
 516 findLocalDupsRdrEnv rdr_env occs
 517   = go rdr_env [] occs
 518   where
 519     go rdr_env dups [] = (rdr_env, dups)
 520     go rdr_env dups (occ:occs)
 521       = case filter isLocalGRE gres of
 522           []       -> WARN( True, ppr occ <+> ppr rdr_env )
 523                       go rdr_env dups occs      -- Weird!  No binding for occ
 524           [_]      -> go rdr_env dups occs      -- The common case
 525           dup_gres -> go (extendOccEnv rdr_env occ (head dup_gres : nonlocal_gres))
 526                          (map gre_name dup_gres : dups)
 527                          occs
 528       where
 529         gres = lookupOccEnv rdr_env occ `orElse` []
 530         nonlocal_gres = filterOut isLocalGRE gres
 531
 532
 533 insertGRE :: GlobalRdrElt -> [GlobalRdrElt] -> [GlobalRdrElt]
 534 insertGRE new_g [] = [new_g]
 535 insertGRE new_g (old_g : old_gs)
 536         | gre_name new_g == gre_name old_g
 537         = new_g `plusGRE` old_g : old_gs
 538         | otherwise
 539         = old_g : insertGRE new_g old_gs
 540
 541 plusGRE :: GlobalRdrElt -> GlobalRdrElt -> GlobalRdrElt
 542 -- Used when the gre_name fields match
 543 plusGRE g1 g2
 544   = GRE { gre_name = gre_name g1,
 545           gre_prov = gre_prov g1 `plusProv`   gre_prov g2,
 546           gre_par  = gre_par  g1 `plusParent` gre_par  g2 }
 547
 548 hideSomeUnquals :: GlobalRdrEnv -> [OccName] -> GlobalRdrEnv
 549 -- ^ Hide any unqualified bindings for the specified OccNames
 550 -- This is used in TH, when renaming a declaration bracket
 551 --
 552 -- > [d| foo = ... |]
 553 --
 554 -- We want unqualified @foo@ in "..." to mean this @foo@, not
 555 -- the one from the enclosing module.  But the /qualified/ name
 556 -- from the enclosing module must certainly still be available
 557
 558 --      Seems like 5 times as much work as it deserves!
 559 hideSomeUnquals rdr_env occs
 560   = foldr hide rdr_env occs
 561   where
 562     hide occ env
 563         | Just gres <- lookupOccEnv env occ = extendOccEnv env occ (map qual_gre gres)
 564         | otherwise                         = env
 565     qual_gre gre@(GRE { gre_name = name, gre_prov = LocalDef })
 566         = gre { gre_prov = Imported [imp_spec] }
 567         where   -- Local defs get transfomed to (fake) imported things
 568           mod = ASSERT2( isExternalName name, ppr name) moduleName (nameModule name)
 569           imp_spec = ImpSpec { is_item = ImpAll, is_decl = decl_spec }
 570           decl_spec = ImpDeclSpec { is_mod = mod, is_as = mod,
 571                                     is_qual = True,
 572                                     is_dloc = srcLocSpan (nameSrcLoc name) }
 573
 574     qual_gre gre@(GRE { gre_prov = Imported specs })
 575         = gre { gre_prov = Imported (map qual_spec specs) }
 576
 577     qual_spec spec@(ImpSpec { is_decl = decl_spec })
 578         = spec { is_decl = decl_spec { is_qual = True } }
 579 \end{code}
 580
 581 %************************************************************************
 582 %*                                                                      *
 583                         Provenance
 584 %*                                                                      *
 585 %************************************************************************
 586
 587 \begin{code}
 588 -- | The 'Provenance' of something says how it came to be in scope.
 589 -- It's quite elaborate so that we can give accurate unused-name warnings.
 590 data Provenance
 591   = LocalDef            -- ^ The thing was defined locally
 592   | Imported
 593         [ImportSpec]    -- ^ The thing was imported.
 594                         --
 595                         -- INVARIANT: the list of 'ImportSpec' is non-empty
 596
 597 data ImportSpec = ImpSpec { is_decl :: ImpDeclSpec,
 598                             is_item ::  ImpItemSpec }
 599                 deriving( Eq, Ord )
 600
 601 -- | Describes a particular import declaration and is
 602 -- shared among all the 'Provenance's for that decl
 603 data ImpDeclSpec
 604   = ImpDeclSpec {
 605         is_mod      :: ModuleName, -- ^ Module imported, e.g. @import Muggle@
 606                                    -- Note the @Muggle@ may well not be
 607                                    -- the defining module for this thing!
 608
 609                                    -- TODO: either should be Module, or there
 610                                    -- should be a Maybe PackageId here too.
 611         is_as       :: ModuleName, -- ^ Import alias, e.g. from @as M@ (or @Muggle@ if there is no @as@ clause)
 612         is_qual     :: Bool,       -- ^ Was this import qualified?
 613         is_dloc     :: SrcSpan     -- ^ The location of the import declaration
 614     }
 615
 616 -- | Describes import info a particular Name
 617 data ImpItemSpec
 618   = ImpAll              -- ^ The import had no import list,
 619                         -- or had a hiding list
 620
 621   | ImpSome {
 622         is_explicit :: Bool,
 623         is_iloc     :: SrcSpan  -- Location of the import item
 624     }   -- ^ The import had an import list.
 625         -- The 'is_explicit' field is @True@ iff the thing was named
 626         -- /explicitly/ in the import specs rather
 627         -- than being imported as part of a "..." group. Consider:
 628         --
 629         -- > import C( T(..) )
 630         --
 631         -- Here the constructors of @T@ are not named explicitly;
 632         -- only @T@ is named explicitly.
 633
 634 unQualSpecOK :: ImportSpec -> Bool
 635 -- ^ Is in scope unqualified?
 636 unQualSpecOK is = not (is_qual (is_decl is))
 637
 638 qualSpecOK :: ModuleName -> ImportSpec -> Bool
 639 -- ^ Is in scope qualified with the given module?
 640 qualSpecOK mod is = mod == is_as (is_decl is)
 641
 642 importSpecLoc :: ImportSpec -> SrcSpan
 643 importSpecLoc (ImpSpec decl ImpAll) = is_dloc decl
 644 importSpecLoc (ImpSpec _    item)   = is_iloc item
 645
 646 importSpecModule :: ImportSpec -> ModuleName
 647 importSpecModule is = is_mod (is_decl is)
 648
 649 isExplicitItem :: ImpItemSpec -> Bool
 650 isExplicitItem ImpAll                        = False
 651 isExplicitItem (ImpSome {is_explicit = exp}) = exp
 652
 653 -- Note [Comparing provenance]
 654 -- Comparison of provenance is just used for grouping
 655 -- error messages (in RnEnv.warnUnusedBinds)
 656 instance Eq Provenance where
 657   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 658
 659 instance Eq ImpDeclSpec where
 660   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 661
 662 instance Eq ImpItemSpec where
 663   p1 == p2 = case p1 `compare` p2 of EQ -> True; _ -> False
 664
 665 instance Ord Provenance where
 666    compare LocalDef      LocalDef        = EQ
 667    compare LocalDef      (Imported _)    = LT
 668    compare (Imported _ ) LocalDef        = GT
 669    compare (Imported is1) (Imported is2) = compare (head is1)
 670         {- See Note [Comparing provenance] -}      (head is2)
 671
 672 instance Ord ImpDeclSpec where
 673    compare is1 is2 = (is_mod is1 `compare` is_mod is2) `thenCmp`
 674                      (is_dloc is1 `compare` is_dloc is2)
 675
 676 instance Ord ImpItemSpec where
 677    compare is1 is2 = is_iloc is1 `compare` is_iloc is2
 678 \end{code}
 679
 680 \begin{code}
 681 plusProv :: Provenance -> Provenance -> Provenance
 682 -- Choose LocalDef over Imported
 683 -- There is an obscure bug lurking here; in the presence
 684 -- of recursive modules, something can be imported *and* locally
 685 -- defined, and one might refer to it with a qualified name from
 686 -- the import -- but I'm going to ignore that because it makes
 687 -- the isLocalGRE predicate so much nicer this way
 688 plusProv LocalDef        LocalDef        = panic "plusProv"
 689 plusProv LocalDef        _               = LocalDef
 690 plusProv _               LocalDef        = LocalDef
 691 plusProv (Imported is1)  (Imported is2)  = Imported (is1++is2)
 692
 693 pprNameProvenance :: GlobalRdrElt -> SDoc
 694 -- ^ Print out the place where the name was imported
 695 pprNameProvenance (GRE {gre_name = name, gre_prov = LocalDef})
 696   = ptext (sLit "defined at") <+> ppr (nameSrcLoc name)
 697 pprNameProvenance (GRE {gre_name = name, gre_prov = Imported whys})
 698   = case whys of
 699         (why:_) -> sep [ppr why, nest 2 (ppr_defn (nameSrcLoc name))]
 700         [] -> panic "pprNameProvenance"
 701
 702 -- If we know the exact definition point (which we may do with GHCi)
 703 -- then show that too.  But not if it's just "imported from X".
 704 ppr_defn :: SrcLoc -> SDoc
 705 ppr_defn loc | isGoodSrcLoc loc = parens (ptext (sLit "defined at") <+> ppr loc)
 706              | otherwise        = empty
 707
 708 instance Outputable ImportSpec where
 709    ppr imp_spec
 710      = ptext (sLit "imported from") <+> ppr (importSpecModule imp_spec)
 711         <+> if isGoodSrcSpan loc then ptext (sLit "at") <+> ppr loc
 712                                  else empty
 713      where
 714        loc = importSpecLoc imp_spec
 715 \end{code}