compiler/cmm/PprC.hs

   1 -----------------------------------------------------------------------------
   2 --
   3 -- Pretty-printing of Cmm as C, suitable for feeding gcc
   4 --
   5 -- (c) The University of Glasgow 2004-2006
   6 --
   7 -----------------------------------------------------------------------------
   8
   9 --
  10 -- Print Cmm as real C, for -fvia-C
  11 --
  12 -- This is simpler than the old PprAbsC, because Cmm is "macro-expanded"
  13 -- relative to the old AbstractC, and many oddities/decorations have
  14 -- disappeared from the data type.
  15 --
  16
  17 -- ToDo: save/restore volatile registers around calls.
  18
  19 module PprC (
  20         writeCs,
  21         pprStringInCStyle
  22   ) where
  23
  24 #include "HsVersions.h"
  25
  26 -- Cmm stuff
  27 import Cmm
  28 import CLabel
  29 import MachOp
  30 import ForeignCall
  31 import ClosureInfo
  32
  33 -- Utils
  34 import DynFlags
  35 import Unique
  36 import UniqSet
  37 import FiniteMap
  38 import UniqFM
  39 import FastString
  40 import Outputable
  41 import Constants
  42
  43 -- The rest
  44 import Data.List
  45 import Data.Bits
  46 import Data.Char
  47 import System.IO
  48 import Data.Word
  49
  50 #ifdef DEBUG
  51 import PprCmm           () -- instances only
  52 -- import Debug.Trace
  53 #endif
  54
  55 import Data.Array.ST
  56 import Control.Monad.ST
  57
  58 #if x86_64_TARGET_ARCH
  59 import StaticFlags      ( opt_Unregisterised )
  60 #endif
  61
  62 #if defined(alpha_TARGET_ARCH) || defined(mips_TARGET_ARCH) || defined(mipsel_TARGET_ARCH) || defined(arm_TARGET_ARCH)
  63 #define BEWARE_LOAD_STORE_ALIGNMENT
  64 #endif
  65
  66 -- --------------------------------------------------------------------------
  67 -- Top level
  68
  69 pprCs :: DynFlags -> [RawCmm] -> SDoc
  70 pprCs dflags cmms
  71  = pprCode CStyle (vcat $ map (\c -> split_marker $$ pprC c) cmms)
  72  where
  73    split_marker
  74      | dopt Opt_SplitObjs dflags = ptext SLIT("__STG_SPLIT_MARKER")
  75      | otherwise                 = empty
  76
  77 writeCs :: DynFlags -> Handle -> [RawCmm] -> IO ()
  78 writeCs dflags handle cmms
  79   = printForC handle (pprCs dflags cmms)
  80
  81 -- --------------------------------------------------------------------------
  82 -- Now do some real work
  83 --
  84 -- for fun, we could call cmmToCmm over the tops...
  85 --
  86
  87 pprC :: RawCmm -> SDoc
  88 pprC (Cmm tops) = vcat $ intersperse (text "") $ map pprTop tops
  89
  90 --
  91 -- top level procs
  92 --
  93 pprTop :: RawCmmTop -> SDoc
  94 pprTop (CmmProc info clbl _params blocks) =
  95     (if not (null info)
  96         then pprDataExterns info $$
  97              pprWordArray (entryLblToInfoLbl clbl) info
  98         else empty) $$
  99     (case blocks of
 100         [] -> empty
 101          -- the first block doesn't get a label:
 102         (BasicBlock _ stmts : rest) -> vcat [
 103            text "",
 104            extern_decls,
 105            (if (externallyVisibleCLabel clbl)
 106                     then mkFN_ else mkIF_) (pprCLabel clbl) <+> lbrace,
 107            nest 8 temp_decls,
 108            nest 8 mkFB_,
 109            nest 8 (vcat (map pprStmt stmts)) $$
 110               vcat (map pprBBlock rest),
 111            nest 8 mkFE_,
 112            rbrace ]
 113     )
 114   where
 115         (temp_decls, extern_decls) = pprTempAndExternDecls blocks
 116
 117
 118 -- Chunks of static data.
 119
 120 -- We only handle (a) arrays of word-sized things and (b) strings.
 121
 122 pprTop (CmmData _section _ds@[CmmDataLabel lbl, CmmString str]) =
 123   hcat [
 124     pprLocalness lbl, ptext SLIT("char "), pprCLabel lbl,
 125     ptext SLIT("[] = "), pprStringInCStyle str, semi
 126   ]
 127
 128 pprTop (CmmData _section _ds@[CmmDataLabel lbl, CmmUninitialised size]) =
 129   hcat [
 130     pprLocalness lbl, ptext SLIT("char "), pprCLabel lbl,
 131     brackets (int size), semi
 132   ]
 133
 134 pprTop top@(CmmData _section (CmmDataLabel lbl : lits)) =
 135   pprDataExterns lits $$
 136   pprWordArray lbl lits
 137
 138 -- these shouldn't appear?
 139 pprTop (CmmData _ _) = panic "PprC.pprTop: can't handle this data"
 140
 141
 142 -- --------------------------------------------------------------------------
 143 -- BasicBlocks are self-contained entities: they always end in a jump.
 144 --
 145 -- Like nativeGen/AsmCodeGen, we could probably reorder blocks to turn
 146 -- as many jumps as possible into fall throughs.
 147 --
 148
 149 pprBBlock :: CmmBasicBlock -> SDoc
 150 pprBBlock (BasicBlock lbl stmts) =
 151     if null stmts then
 152         pprTrace "pprC.pprBBlock: curious empty code block for"
 153                         (pprBlockId lbl) empty
 154     else
 155         nest 4 (pprBlockId lbl <> colon) $$
 156         nest 8 (vcat (map pprStmt stmts))
 157
 158 -- --------------------------------------------------------------------------
 159 -- Info tables. Just arrays of words.
 160 -- See codeGen/ClosureInfo, and nativeGen/PprMach
 161
 162 pprWordArray :: CLabel -> [CmmStatic] -> SDoc
 163 pprWordArray lbl ds
 164   = hcat [ pprLocalness lbl, ptext SLIT("StgWord")
 165          , space, pprCLabel lbl, ptext SLIT("[] = {") ]
 166     $$ nest 8 (commafy (pprStatics ds))
 167     $$ ptext SLIT("};")
 168
 169 --
 170 -- has to be static, if it isn't globally visible
 171 --
 172 pprLocalness :: CLabel -> SDoc
 173 pprLocalness lbl | not $ externallyVisibleCLabel lbl = ptext SLIT("static ")
 174                  | otherwise = empty
 175
 176 -- --------------------------------------------------------------------------
 177 -- Statements.
 178 --
 179
 180 pprStmt :: CmmStmt -> SDoc
 181
 182 pprStmt stmt = case stmt of
 183     CmmNop       -> empty
 184     CmmComment s -> (hang (ptext SLIT("/*")) 3 (ftext s)) $$ ptext SLIT("*/")
 185
 186     CmmAssign dest src -> pprAssign dest src
 187
 188     CmmStore  dest src
 189         | rep == I64 && wordRep /= I64
 190         -> ptext SLIT("ASSIGN_Word64") <>
 191                 parens (mkP_ <> pprExpr1 dest <> comma <> pprExpr src) <> semi
 192
 193         | rep == F64 && wordRep /= I64
 194         -> ptext SLIT("ASSIGN_DBL") <>
 195                 parens (mkP_ <> pprExpr1 dest <> comma <> pprExpr src) <> semi
 196
 197         | otherwise
 198         -> hsep [ pprExpr (CmmLoad dest rep), equals, pprExpr src <> semi ]
 199         where
 200           rep = cmmExprRep src
 201
 202     CmmCall (CmmForeignCall fn cconv) results args safety ->
 203         -- Controversial: leave this out for now.
 204         -- pprUndef fn $$
 205
 206         pprCall ppr_fn cconv results args safety
 207         where
 208         ppr_fn = case fn of
 209                    CmmLit (CmmLabel lbl) -> pprCLabel lbl
 210                    _ -> parens (cCast (pprCFunType cconv results args) fn)
 211                         -- for a dynamic call, cast the expression to
 212                         -- a function of the right type (we hope).
 213
 214         -- we #undef a function before calling it: the FFI is supposed to be
 215         -- an interface specifically to C, not to C+CPP.  For one thing, this
 216         -- makes the via-C route more compatible with the NCG.  If macros
 217         -- are being used for optimisation, then inline functions are probably
 218         -- better anyway.
 219         pprUndef (CmmLit (CmmLabel lbl)) =
 220            ptext SLIT("#undef") <+> pprCLabel lbl
 221         pprUndef _ = empty
 222
 223     CmmCall (CmmPrim op) results args safety ->
 224         pprCall ppr_fn CCallConv results args safety
 225         where
 226         ppr_fn = pprCallishMachOp_for_C op
 227
 228     CmmBranch ident          -> pprBranch ident
 229     CmmCondBranch expr ident -> pprCondBranch expr ident
 230     CmmJump lbl _params      -> mkJMP_(pprExpr lbl) <> semi
 231     CmmSwitch arg ids        -> pprSwitch arg ids
 232
 233 pprCFunType :: CCallConv -> CmmHintFormals -> CmmActuals -> SDoc
 234 pprCFunType cconv ress args
 235   = hcat [
 236         res_type ress,
 237         parens (text (ccallConvAttribute cconv) <>  char '*'),
 238         parens (commafy (map arg_type args))
 239    ]
 240   where
 241         res_type [] = ptext SLIT("void")
 242         res_type [(one,hint)] = machRepHintCType (localRegRep one) hint
 243
 244         arg_type (expr,hint) = machRepHintCType (cmmExprRep expr) hint
 245
 246 -- ---------------------------------------------------------------------
 247 -- unconditional branches
 248 pprBranch :: BlockId -> SDoc
 249 pprBranch ident = ptext SLIT("goto") <+> pprBlockId ident <> semi
 250
 251
 252 -- ---------------------------------------------------------------------
 253 -- conditional branches to local labels
 254 pprCondBranch :: CmmExpr -> BlockId -> SDoc
 255 pprCondBranch expr ident
 256         = hsep [ ptext SLIT("if") , parens(pprExpr expr) ,
 257                         ptext SLIT("goto") , (pprBlockId ident) <> semi ]
 258
 259
 260 -- ---------------------------------------------------------------------
 261 -- a local table branch
 262 --
 263 -- we find the fall-through cases
 264 --
 265 -- N.B. we remove Nothing's from the list of branches, as they are
 266 -- 'undefined'. However, they may be defined one day, so we better
 267 -- document this behaviour.
 268 --
 269 pprSwitch :: CmmExpr -> [ Maybe BlockId ] -> SDoc
 270 pprSwitch e maybe_ids
 271   = let pairs  = [ (ix, ident) | (ix,Just ident) <- zip [0..] maybe_ids ]
 272         pairs2 = [ (map fst as, snd (head as)) | as <- groupBy sndEq pairs ]
 273     in
 274         (hang (ptext SLIT("switch") <+> parens ( pprExpr e ) <+> lbrace)
 275                 4 (vcat ( map caseify pairs2 )))
 276         $$ rbrace
 277
 278   where
 279     sndEq (_,x) (_,y) = x == y
 280
 281     -- fall through case
 282     caseify (ix:ixs, ident) = vcat (map do_fallthrough ixs) $$ final_branch ix
 283         where
 284         do_fallthrough ix =
 285                  hsep [ ptext SLIT("case") , pprHexVal ix wordRep <> colon ,
 286                         ptext SLIT("/* fall through */") ]
 287
 288         final_branch ix =
 289                 hsep [ ptext SLIT("case") , pprHexVal ix wordRep <> colon ,
 290                        ptext SLIT("goto") , (pprBlockId ident) <> semi ]
 291
 292 -- ---------------------------------------------------------------------
 293 -- Expressions.
 294 --
 295
 296 -- C Types: the invariant is that the C expression generated by
 297 --
 298 --      pprExpr e
 299 --
 300 -- has a type in C which is also given by
 301 --
 302 --      machRepCType (cmmExprRep e)
 303 --
 304 -- (similar invariants apply to the rest of the pretty printer).
 305
 306 pprExpr :: CmmExpr -> SDoc
 307 pprExpr e = case e of
 308     CmmLit lit -> pprLit lit
 309
 310     CmmLoad e I64 | wordRep /= I64
 311         -> ptext SLIT("PK_Word64") <> parens (mkP_ <> pprExpr1 e)
 312
 313     CmmLoad e F64 | wordRep /= I64
 314         -> ptext SLIT("PK_DBL") <> parens (mkP_ <> pprExpr1 e)
 315
 316     CmmLoad (CmmReg r) rep
 317         | isPtrReg r && rep == wordRep
 318         -> char '*' <> pprAsPtrReg r
 319
 320     CmmLoad (CmmRegOff r 0) rep
 321         | isPtrReg r && rep == wordRep
 322         -> char '*' <> pprAsPtrReg r
 323
 324     CmmLoad (CmmRegOff r off) rep
 325         | isPtrReg r && rep == wordRep && (off `rem` wORD_SIZE == 0)
 326         -- ToDo: check that the offset is a word multiple?
 327         --       (For tagging to work, I had to avoid unaligned loads. --ARY)
 328         -> pprAsPtrReg r <> brackets (ppr (off `shiftR` wordShift))
 329
 330     CmmLoad expr rep ->
 331         -- the general case:
 332         cLoad expr rep
 333
 334     CmmReg reg      -> pprCastReg reg
 335     CmmRegOff reg 0 -> pprCastReg reg
 336
 337     CmmRegOff reg i
 338         | i >  0    -> pprRegOff (char '+') i
 339         | otherwise -> pprRegOff (char '-') (-i)
 340       where
 341         pprRegOff op i' = pprCastReg reg <> op <> int i'
 342
 343     CmmMachOp mop args -> pprMachOpApp mop args
 344
 345 pprExpr1 :: CmmExpr -> SDoc
 346 pprExpr1 (CmmLit lit)     = pprLit1 lit
 347 pprExpr1 e@(CmmReg _reg)  = pprExpr e
 348 pprExpr1 other            = parens (pprExpr other)
 349
 350 -- --------------------------------------------------------------------------
 351 -- MachOp applications
 352
 353 pprMachOpApp :: MachOp -> [CmmExpr] -> SDoc
 354
 355 pprMachOpApp op args
 356   | isMulMayOfloOp op
 357   = ptext SLIT("mulIntMayOflo") <> parens (commafy (map pprExpr args))
 358   where isMulMayOfloOp (MO_U_MulMayOflo _) = True
 359         isMulMayOfloOp (MO_S_MulMayOflo _) = True
 360         isMulMayOfloOp _ = False
 361
 362 pprMachOpApp mop args
 363   | Just ty <- machOpNeedsCast mop
 364   = ty <> parens (pprMachOpApp' mop args)
 365   | otherwise
 366   = pprMachOpApp' mop args
 367
 368 -- Comparisons in C have type 'int', but we want type W_ (this is what
 369 -- resultRepOfMachOp says).  The other C operations inherit their type
 370 -- from their operands, so no casting is required.
 371 machOpNeedsCast :: MachOp -> Maybe SDoc
 372 machOpNeedsCast mop
 373   | isComparisonMachOp mop = Just mkW_
 374   | otherwise              = Nothing
 375
 376 pprMachOpApp' mop args
 377  = case args of
 378     -- dyadic
 379     [x,y] -> pprArg x <+> pprMachOp_for_C mop <+> pprArg y
 380
 381     -- unary
 382     [x]   -> pprMachOp_for_C mop <> parens (pprArg x)
 383
 384     _     -> panic "PprC.pprMachOp : machop with wrong number of args"
 385
 386   where
 387     pprArg e | signedOp mop = cCast (machRepSignedCType (cmmExprRep e)) e
 388              | otherwise    = pprExpr1 e
 389
 390 -- --------------------------------------------------------------------------
 391 -- Literals
 392
 393 pprLit :: CmmLit -> SDoc
 394 pprLit lit = case lit of
 395     CmmInt i rep      -> pprHexVal i rep
 396     CmmFloat f rep     -> parens (machRepCType rep) <> (rational f)
 397     CmmLabel clbl      -> mkW_ <> pprCLabelAddr clbl
 398     CmmLabelOff clbl i -> mkW_ <> pprCLabelAddr clbl <> char '+' <> int i
 399     CmmLabelDiffOff clbl1 clbl2 i
 400         -- WARNING:
 401         --  * the lit must occur in the info table clbl2
 402         --  * clbl1 must be an SRT, a slow entry point or a large bitmap
 403         -- The Mangler is expected to convert any reference to an SRT,
 404         -- a slow entry point or a large bitmap
 405         -- from an info table to an offset.
 406         -> mkW_ <> pprCLabelAddr clbl1 <> char '+' <> int i
 407
 408 pprCLabelAddr lbl = char '&' <> pprCLabel lbl
 409
 410 pprLit1 :: CmmLit -> SDoc
 411 pprLit1 lit@(CmmLabelOff _ _) = parens (pprLit lit)
 412 pprLit1 lit@(CmmLabelDiffOff _ _ _) = parens (pprLit lit)
 413 pprLit1 lit@(CmmFloat _ _)    = parens (pprLit lit)
 414 pprLit1 other = pprLit other
 415
 416 -- ---------------------------------------------------------------------------
 417 -- Static data
 418
 419 pprStatics :: [CmmStatic] -> [SDoc]
 420 pprStatics [] = []
 421 pprStatics (CmmStaticLit (CmmFloat f F32) : rest)
 422   = pprLit1 (floatToWord f) : pprStatics rest
 423 pprStatics (CmmStaticLit (CmmFloat f F64) : rest)
 424   = map pprLit1 (doubleToWords f) ++ pprStatics rest
 425 pprStatics (CmmStaticLit (CmmInt i I64) : rest)
 426   | machRepByteWidth I32 == wORD_SIZE
 427 #ifdef WORDS_BIGENDIAN
 428   = pprStatics (CmmStaticLit (CmmInt q I32) :
 429                 CmmStaticLit (CmmInt r I32) : rest)
 430 #else
 431   = pprStatics (CmmStaticLit (CmmInt r I32) :
 432                 CmmStaticLit (CmmInt q I32) : rest)
 433 #endif
 434   where r = i .&. 0xffffffff
 435         q = i `shiftR` 32
 436 pprStatics (CmmStaticLit (CmmInt i rep) : rest)
 437   | machRepByteWidth rep /= wORD_SIZE
 438   = panic "pprStatics: cannot emit a non-word-sized static literal"
 439 pprStatics (CmmStaticLit lit : rest)
 440   = pprLit1 lit : pprStatics rest
 441 pprStatics (other : rest)
 442   = pprPanic "pprWord" (pprStatic other)
 443
 444 pprStatic :: CmmStatic -> SDoc
 445 pprStatic s = case s of
 446
 447     CmmStaticLit lit   -> nest 4 (pprLit lit)
 448     CmmAlign i         -> nest 4 (ptext SLIT("/* align */") <+> int i)
 449     CmmDataLabel clbl  -> pprCLabel clbl <> colon
 450     CmmUninitialised i -> nest 4 (mkC_ <> brackets (int i))
 451
 452     -- these should be inlined, like the old .hc
 453     CmmString s'       -> nest 4 (mkW_ <> parens(pprStringInCStyle s'))
 454
 455
 456 -- ---------------------------------------------------------------------------
 457 -- Block Ids
 458
 459 pprBlockId :: BlockId -> SDoc
 460 pprBlockId b = char '_' <> ppr (getUnique b)
 461
 462 -- --------------------------------------------------------------------------
 463 -- Print a MachOp in a way suitable for emitting via C.
 464 --
 465
 466 pprMachOp_for_C :: MachOp -> SDoc
 467
 468 pprMachOp_for_C mop = case mop of
 469
 470         -- Integer operations
 471         MO_Add          _ -> char '+'
 472         MO_Sub          _ -> char '-'
 473         MO_Eq           _ -> ptext SLIT("==")
 474         MO_Ne           _ -> ptext SLIT("!=")
 475         MO_Mul          _ -> char '*'
 476
 477         MO_S_Quot       _ -> char '/'
 478         MO_S_Rem        _ -> char '%'
 479         MO_S_Neg        _ -> char '-'
 480
 481         MO_U_Quot       _ -> char '/'
 482         MO_U_Rem        _ -> char '%'
 483
 484         -- Signed comparisons (floating-point comparisons also use these)
 485         -- & Unsigned comparisons
 486         MO_S_Ge         _ -> ptext SLIT(">=")
 487         MO_S_Le         _ -> ptext SLIT("<=")
 488         MO_S_Gt         _ -> char '>'
 489         MO_S_Lt         _ -> char '<'
 490
 491         MO_U_Ge         _ -> ptext SLIT(">=")
 492         MO_U_Le         _ -> ptext SLIT("<=")
 493         MO_U_Gt         _ -> char '>'
 494         MO_U_Lt         _ -> char '<'
 495
 496         -- Bitwise operations.  Not all of these may be supported at all
 497         -- sizes, and only integral MachReps are valid.
 498         MO_And          _ -> char '&'
 499         MO_Or           _ -> char '|'
 500         MO_Xor          _ -> char '^'
 501         MO_Not          _ -> char '~'
 502         MO_Shl          _ -> ptext SLIT("<<")
 503         MO_U_Shr        _ -> ptext SLIT(">>") -- unsigned shift right
 504         MO_S_Shr        _ -> ptext SLIT(">>") -- signed shift right
 505
 506 -- Conversions.  Some of these will be NOPs.
 507 -- Floating-point conversions use the signed variant.
 508 -- We won't know to generate (void*) casts here, but maybe from
 509 -- context elsewhere
 510
 511 -- noop casts
 512         MO_U_Conv I8 I8     -> empty
 513         MO_U_Conv I16 I16   -> empty
 514         MO_U_Conv I32 I32   -> empty
 515         MO_U_Conv I64 I64   -> empty
 516         MO_U_Conv I128 I128 -> empty
 517         MO_S_Conv I8 I8     -> empty
 518         MO_S_Conv I16 I16   -> empty
 519         MO_S_Conv I32 I32   -> empty
 520         MO_S_Conv I64 I64   -> empty
 521         MO_S_Conv I128 I128 -> empty
 522
 523         MO_U_Conv _from to  -> parens (machRepCType to)
 524         MO_S_Conv _from to  -> parens (machRepSignedCType to)
 525
 526         _ -> panic "PprC.pprMachOp_for_C: unknown machop"
 527
 528 signedOp :: MachOp -> Bool
 529 signedOp (MO_S_Quot _)   = True
 530 signedOp (MO_S_Rem  _)   = True
 531 signedOp (MO_S_Neg  _)   = True
 532 signedOp (MO_S_Ge   _)   = True
 533 signedOp (MO_S_Le   _)   = True
 534 signedOp (MO_S_Gt   _)   = True
 535 signedOp (MO_S_Lt   _)   = True
 536 signedOp (MO_S_Shr  _)   = True
 537 signedOp (MO_S_Conv _ _) = True
 538 signedOp _ = False
 539
 540 -- ---------------------------------------------------------------------
 541 -- tend to be implemented by foreign calls
 542
 543 pprCallishMachOp_for_C :: CallishMachOp -> SDoc
 544
 545 pprCallishMachOp_for_C mop
 546     = case mop of
 547         MO_F64_Pwr  -> ptext SLIT("pow")
 548         MO_F64_Sin  -> ptext SLIT("sin")
 549         MO_F64_Cos  -> ptext SLIT("cos")
 550         MO_F64_Tan  -> ptext SLIT("tan")
 551         MO_F64_Sinh -> ptext SLIT("sinh")
 552         MO_F64_Cosh -> ptext SLIT("cosh")
 553         MO_F64_Tanh -> ptext SLIT("tanh")
 554         MO_F64_Asin -> ptext SLIT("asin")
 555         MO_F64_Acos -> ptext SLIT("acos")
 556         MO_F64_Atan -> ptext SLIT("atan")
 557         MO_F64_Log  -> ptext SLIT("log")
 558         MO_F64_Exp  -> ptext SLIT("exp")
 559         MO_F64_Sqrt -> ptext SLIT("sqrt")
 560         MO_F32_Pwr  -> ptext SLIT("powf")
 561         MO_F32_Sin  -> ptext SLIT("sinf")
 562         MO_F32_Cos  -> ptext SLIT("cosf")
 563         MO_F32_Tan  -> ptext SLIT("tanf")
 564         MO_F32_Sinh -> ptext SLIT("sinhf")
 565         MO_F32_Cosh -> ptext SLIT("coshf")
 566         MO_F32_Tanh -> ptext SLIT("tanhf")
 567         MO_F32_Asin -> ptext SLIT("asinf")
 568         MO_F32_Acos -> ptext SLIT("acosf")
 569         MO_F32_Atan -> ptext SLIT("atanf")
 570         MO_F32_Log  -> ptext SLIT("logf")
 571         MO_F32_Exp  -> ptext SLIT("expf")
 572         MO_F32_Sqrt -> ptext SLIT("sqrtf")
 573         MO_WriteBarrier -> ptext SLIT("write_barrier")
 574
 575 -- ---------------------------------------------------------------------
 576 -- Useful #defines
 577 --
 578
 579 mkJMP_, mkFN_, mkIF_ :: SDoc -> SDoc
 580
 581 mkJMP_ i = ptext SLIT("JMP_") <> parens i
 582 mkFN_  i = ptext SLIT("FN_")  <> parens i -- externally visible function
 583 mkIF_  i = ptext SLIT("IF_")  <> parens i -- locally visible
 584
 585
 586 mkFB_, mkFE_ :: SDoc
 587 mkFB_ = ptext SLIT("FB_") -- function code begin
 588 mkFE_ = ptext SLIT("FE_") -- function code end
 589
 590 -- from includes/Stg.h
 591 --
 592 mkC_,mkW_,mkP_,mkPP_,mkI_,mkA_,mkD_,mkF_,mkB_,mkL_,mkLI_,mkLW_ :: SDoc
 593
 594 mkC_  = ptext SLIT("(C_)")        -- StgChar
 595 mkW_  = ptext SLIT("(W_)")        -- StgWord
 596 mkP_  = ptext SLIT("(P_)")        -- StgWord*
 597 mkPP_ = ptext SLIT("(PP_)")       -- P_*
 598 mkI_  = ptext SLIT("(I_)")        -- StgInt
 599 mkA_  = ptext SLIT("(A_)")        -- StgAddr
 600 mkD_  = ptext SLIT("(D_)")        -- const StgWord*
 601 mkF_  = ptext SLIT("(F_)")        -- StgFunPtr
 602 mkB_  = ptext SLIT("(B_)")        -- StgByteArray
 603 mkL_  = ptext SLIT("(L_)")        -- StgClosurePtr
 604
 605 mkLI_ = ptext SLIT("(LI_)")       -- StgInt64
 606 mkLW_ = ptext SLIT("(LW_)")       -- StgWord64
 607
 608
 609 -- ---------------------------------------------------------------------
 610 --
 611 -- Assignments
 612 --
 613 -- Generating assignments is what we're all about, here
 614 --
 615 pprAssign :: CmmReg -> CmmExpr -> SDoc
 616
 617 -- dest is a reg, rhs is a reg
 618 pprAssign r1 (CmmReg r2)
 619    | isPtrReg r1 && isPtrReg r2
 620    = hcat [ pprAsPtrReg r1, equals, pprAsPtrReg r2, semi ]
 621
 622 -- dest is a reg, rhs is a CmmRegOff
 623 pprAssign r1 (CmmRegOff r2 off)
 624    | isPtrReg r1 && isPtrReg r2 && (off `rem` wORD_SIZE == 0)
 625    = hcat [ pprAsPtrReg r1, equals, pprAsPtrReg r2, op, int off', semi ]
 626   where
 627         off1 = off `shiftR` wordShift
 628
 629         (op,off') | off >= 0  = (char '+', off1)
 630                   | otherwise = (char '-', -off1)
 631
 632 -- dest is a reg, rhs is anything.
 633 -- We can't cast the lvalue, so we have to cast the rhs if necessary.  Casting
 634 -- the lvalue elicits a warning from new GCC versions (3.4+).
 635 pprAssign r1 r2
 636   | isFixedPtrReg r1             = mkAssign (mkP_ <> pprExpr1 r2)
 637   | Just ty <- strangeRegType r1 = mkAssign (parens ty <> pprExpr1 r2)
 638   | otherwise                    = mkAssign (pprExpr r2)
 639     where mkAssign x = if r1 == CmmGlobal BaseReg
 640                        then ptext SLIT("ASSIGN_BaseReg") <> parens x <> semi
 641                        else pprReg r1 <> ptext SLIT(" = ") <> x <> semi
 642
 643 -- ---------------------------------------------------------------------
 644 -- Registers
 645
 646 pprCastReg reg
 647    | isStrangeTypeReg reg = mkW_ <> pprReg reg
 648    | otherwise            = pprReg reg
 649
 650 -- True if (pprReg reg) will give an expression with type StgPtr.  We
 651 -- need to take care with pointer arithmetic on registers with type
 652 -- StgPtr.
 653 isFixedPtrReg :: CmmReg -> Bool
 654 isFixedPtrReg (CmmLocal _) = False
 655 isFixedPtrReg (CmmGlobal r) = isFixedPtrGlobalReg r
 656
 657 -- True if (pprAsPtrReg reg) will give an expression with type StgPtr
 658 isPtrReg :: CmmReg -> Bool
 659 isPtrReg (CmmLocal _)               = False
 660 isPtrReg (CmmGlobal (VanillaReg n)) = True -- if we print via pprAsPtrReg
 661 isPtrReg (CmmGlobal reg)            = isFixedPtrGlobalReg reg
 662
 663 -- True if this global reg has type StgPtr
 664 isFixedPtrGlobalReg :: GlobalReg -> Bool
 665 isFixedPtrGlobalReg Sp          = True
 666 isFixedPtrGlobalReg Hp          = True
 667 isFixedPtrGlobalReg HpLim       = True
 668 isFixedPtrGlobalReg SpLim       = True
 669 isFixedPtrGlobalReg _           = False
 670
 671 -- True if in C this register doesn't have the type given by
 672 -- (machRepCType (cmmRegRep reg)), so it has to be cast.
 673 isStrangeTypeReg :: CmmReg -> Bool
 674 isStrangeTypeReg (CmmLocal _)   = False
 675 isStrangeTypeReg (CmmGlobal g)  = isStrangeTypeGlobal g
 676
 677 isStrangeTypeGlobal :: GlobalReg -> Bool
 678 isStrangeTypeGlobal CurrentTSO          = True
 679 isStrangeTypeGlobal CurrentNursery      = True
 680 isStrangeTypeGlobal BaseReg             = True
 681 isStrangeTypeGlobal r                   = isFixedPtrGlobalReg r
 682
 683 strangeRegType :: CmmReg -> Maybe SDoc
 684 strangeRegType (CmmGlobal CurrentTSO) = Just (ptext SLIT("struct StgTSO_ *"))
 685 strangeRegType (CmmGlobal CurrentNursery) = Just (ptext SLIT("struct bdescr_ *"))
 686 strangeRegType (CmmGlobal BaseReg) = Just (ptext SLIT("struct StgRegTable_ *"))
 687 strangeRegType _ = Nothing
 688
 689 -- pprReg just prints the register name.
 690 --
 691 pprReg :: CmmReg -> SDoc
 692 pprReg r = case r of
 693         CmmLocal  local  -> pprLocalReg local
 694         CmmGlobal global -> pprGlobalReg global
 695
 696 pprAsPtrReg :: CmmReg -> SDoc
 697 pprAsPtrReg (CmmGlobal (VanillaReg n)) = char 'R' <> int n <> ptext SLIT(".p")
 698 pprAsPtrReg other_reg = pprReg other_reg
 699
 700 pprGlobalReg :: GlobalReg -> SDoc
 701 pprGlobalReg gr = case gr of
 702     VanillaReg n   -> char 'R' <> int n  <> ptext SLIT(".w")
 703     FloatReg   n   -> char 'F' <> int n
 704     DoubleReg  n   -> char 'D' <> int n
 705     LongReg    n   -> char 'L' <> int n
 706     Sp             -> ptext SLIT("Sp")
 707     SpLim          -> ptext SLIT("SpLim")
 708     Hp             -> ptext SLIT("Hp")
 709     HpLim          -> ptext SLIT("HpLim")
 710     CurrentTSO     -> ptext SLIT("CurrentTSO")
 711     CurrentNursery -> ptext SLIT("CurrentNursery")
 712     HpAlloc        -> ptext SLIT("HpAlloc")
 713     BaseReg        -> ptext SLIT("BaseReg")
 714     GCEnter1       -> ptext SLIT("stg_gc_enter_1")
 715     GCFun          -> ptext SLIT("stg_gc_fun")
 716
 717 pprLocalReg :: LocalReg -> SDoc
 718 pprLocalReg (LocalReg uniq _ _) = char '_' <> ppr uniq
 719
 720 -- -----------------------------------------------------------------------------
 721 -- Foreign Calls
 722
 723 pprCall :: SDoc -> CCallConv -> CmmHintFormals -> CmmActuals -> CmmSafety
 724         -> SDoc
 725
 726 pprCall ppr_fn cconv results args _
 727   | not (is_cish cconv)
 728   = panic "pprCall: unknown calling convention"
 729
 730   | otherwise
 731   =
 732 #if x86_64_TARGET_ARCH
 733         -- HACK around gcc optimisations.
 734         -- x86_64 needs a __DISCARD__() here, to create a barrier between
 735         -- putting the arguments into temporaries and passing the arguments
 736         -- to the callee, because the argument expressions may refer to
 737         -- machine registers that are also used for passing arguments in the
 738         -- C calling convention.
 739     (if (not opt_Unregisterised)
 740         then ptext SLIT("__DISCARD__();")
 741         else empty) $$
 742 #endif
 743     ppr_assign results (ppr_fn <> parens (commafy (map pprArg args))) <> semi
 744   where
 745      ppr_assign []           rhs = rhs
 746      ppr_assign [(one,hint)] rhs
 747          = pprLocalReg one <> ptext SLIT(" = ")
 748                  <> pprUnHint hint (localRegRep one) <> rhs
 749      ppr_assign _other _rhs = panic "pprCall: multiple results"
 750
 751      pprArg (expr, PtrHint)
 752         = cCast (ptext SLIT("void *")) expr
 753         -- see comment by machRepHintCType below
 754      pprArg (expr, SignedHint)
 755         = cCast (machRepSignedCType (cmmExprRep expr)) expr
 756      pprArg (expr, _other)
 757         = pprExpr expr
 758
 759      pprUnHint PtrHint    rep = parens (machRepCType rep)
 760      pprUnHint SignedHint rep = parens (machRepCType rep)
 761      pprUnHint _          _   = empty
 762
 763 pprGlobalRegName :: GlobalReg -> SDoc
 764 pprGlobalRegName gr = case gr of
 765     VanillaReg n   -> char 'R' <> int n  -- without the .w suffix
 766     _              -> pprGlobalReg gr
 767
 768 -- Currently we only have these two calling conventions, but this might
 769 -- change in the future...
 770 is_cish CCallConv   = True
 771 is_cish StdCallConv = True
 772
 773 -- ---------------------------------------------------------------------
 774 -- Find and print local and external declarations for a list of
 775 -- Cmm statements.
 776 --
 777 pprTempAndExternDecls :: [CmmBasicBlock] -> (SDoc{-temps-}, SDoc{-externs-})
 778 pprTempAndExternDecls stmts
 779   = (vcat (map pprTempDecl (eltsUFM temps)),
 780      vcat (map (pprExternDecl False{-ToDo-}) (keysFM lbls)))
 781   where (temps, lbls) = runTE (mapM_ te_BB stmts)
 782
 783 pprDataExterns :: [CmmStatic] -> SDoc
 784 pprDataExterns statics
 785   = vcat (map (pprExternDecl False{-ToDo-}) (keysFM lbls))
 786   where (_, lbls) = runTE (mapM_ te_Static statics)
 787
 788 pprTempDecl :: LocalReg -> SDoc
 789 pprTempDecl l@(LocalReg _ rep _)
 790   = hcat [ machRepCType rep, space, pprLocalReg l, semi ]
 791
 792 pprExternDecl :: Bool -> CLabel -> SDoc
 793 pprExternDecl in_srt lbl
 794   -- do not print anything for "known external" things
 795   | not (needsCDecl lbl) = empty
 796   | otherwise               =
 797         hcat [ visibility, label_type (labelType lbl),
 798                lparen, pprCLabel lbl, text ");" ]
 799  where
 800   label_type CodeLabel = ptext SLIT("F_")
 801   label_type DataLabel = ptext SLIT("I_")
 802
 803   visibility
 804      | externallyVisibleCLabel lbl = char 'E'
 805      | otherwise                   = char 'I'
 806
 807
 808 type TEState = (UniqSet LocalReg, FiniteMap CLabel ())
 809 newtype TE a = TE { unTE :: TEState -> (a, TEState) }
 810
 811 instance Monad TE where
 812    TE m >>= k  = TE $ \s -> case m s of (a, s') -> unTE (k a) s'
 813    return a    = TE $ \s -> (a, s)
 814
 815 te_lbl :: CLabel -> TE ()
 816 te_lbl lbl = TE $ \(temps,lbls) -> ((), (temps, addToFM lbls lbl ()))
 817
 818 te_temp :: LocalReg -> TE ()
 819 te_temp r = TE $ \(temps,lbls) -> ((), (addOneToUniqSet temps r, lbls))
 820
 821 runTE :: TE () -> TEState
 822 runTE (TE m) = snd (m (emptyUniqSet, emptyFM))
 823
 824 te_Static :: CmmStatic -> TE ()
 825 te_Static (CmmStaticLit lit) = te_Lit lit
 826 te_Static _ = return ()
 827
 828 te_BB :: CmmBasicBlock -> TE ()
 829 te_BB (BasicBlock _ ss)         = mapM_ te_Stmt ss
 830
 831 te_Lit :: CmmLit -> TE ()
 832 te_Lit (CmmLabel l) = te_lbl l
 833 te_Lit (CmmLabelOff l _) = te_lbl l
 834 te_Lit (CmmLabelDiffOff l1 l2 _) = te_lbl l1
 835 te_Lit _ = return ()
 836
 837 te_Stmt :: CmmStmt -> TE ()
 838 te_Stmt (CmmAssign r e)         = te_Reg r >> te_Expr e
 839 te_Stmt (CmmStore l r)          = te_Expr l >> te_Expr r
 840 te_Stmt (CmmCall _ rs es _)     = mapM_ (te_temp.fst) rs >>
 841                                   mapM_ (te_Expr.fst) es
 842 te_Stmt (CmmCondBranch e _)     = te_Expr e
 843 te_Stmt (CmmSwitch e _)         = te_Expr e
 844 te_Stmt (CmmJump e _)           = te_Expr e
 845 te_Stmt _                       = return ()
 846
 847 te_Expr :: CmmExpr -> TE ()
 848 te_Expr (CmmLit lit)            = te_Lit lit
 849 te_Expr (CmmLoad e _)           = te_Expr e
 850 te_Expr (CmmReg r)              = te_Reg r
 851 te_Expr (CmmMachOp _ es)        = mapM_ te_Expr es
 852 te_Expr (CmmRegOff r _)         = te_Reg r
 853
 854 te_Reg :: CmmReg -> TE ()
 855 te_Reg (CmmLocal l) = te_temp l
 856 te_Reg _            = return ()
 857
 858
 859 -- ---------------------------------------------------------------------
 860 -- C types for MachReps
 861
 862 cCast :: SDoc -> CmmExpr -> SDoc
 863 cCast ty expr = parens ty <> pprExpr1 expr
 864
 865 cLoad :: CmmExpr -> MachRep -> SDoc
 866 #ifdef BEWARE_LOAD_STORE_ALIGNMENT
 867 cLoad expr rep =
 868     let decl = machRepCType rep <+> ptext SLIT("x") <> semi
 869         struct = ptext SLIT("struct") <+> braces (decl)
 870         packed_attr = ptext SLIT("__attribute__((packed))")
 871         cast = parens (struct <+> packed_attr <> char '*')
 872     in parens (cast <+> pprExpr1 expr) <> ptext SLIT("->x")
 873 #else
 874 cLoad expr rep = char '*' <> parens (cCast (machRepPtrCType rep) expr)
 875 #endif
 876
 877 -- This is for finding the types of foreign call arguments.  For a pointer
 878 -- argument, we always cast the argument to (void *), to avoid warnings from
 879 -- the C compiler.
 880 machRepHintCType :: MachRep -> MachHint -> SDoc
 881 machRepHintCType rep PtrHint    = ptext SLIT("void *")
 882 machRepHintCType rep SignedHint = machRepSignedCType rep
 883 machRepHintCType rep _other     = machRepCType rep
 884
 885 machRepPtrCType :: MachRep -> SDoc
 886 machRepPtrCType r | r == wordRep = ptext SLIT("P_")
 887                   | otherwise    = machRepCType r <> char '*'
 888
 889 machRepCType :: MachRep -> SDoc
 890 machRepCType r | r == wordRep = ptext SLIT("W_")
 891                | otherwise    = sized_type
 892   where sized_type = case r of
 893                         I8      -> ptext SLIT("StgWord8")
 894                         I16     -> ptext SLIT("StgWord16")
 895                         I32     -> ptext SLIT("StgWord32")
 896                         I64     -> ptext SLIT("StgWord64")
 897                         F32     -> ptext SLIT("StgFloat") -- ToDo: correct?
 898                         F64     -> ptext SLIT("StgDouble")
 899                         _  -> panic "machRepCType"
 900
 901 machRepSignedCType :: MachRep -> SDoc
 902 machRepSignedCType r | r == wordRep = ptext SLIT("I_")
 903                      | otherwise    = sized_type
 904   where sized_type = case r of
 905                         I8      -> ptext SLIT("StgInt8")
 906                         I16     -> ptext SLIT("StgInt16")
 907                         I32     -> ptext SLIT("StgInt32")
 908                         I64     -> ptext SLIT("StgInt64")
 909                         F32     -> ptext SLIT("StgFloat") -- ToDo: correct?
 910                         F64     -> ptext SLIT("StgDouble")
 911                         _ -> panic "machRepCType"
 912
 913 -- ---------------------------------------------------------------------
 914 -- print strings as valid C strings
 915
 916 pprStringInCStyle :: [Word8] -> SDoc
 917 pprStringInCStyle s = doubleQuotes (text (concatMap charToC s))
 918
 919 charToC :: Word8 -> String
 920 charToC w =
 921   case chr (fromIntegral w) of
 922         '\"' -> "\\\""
 923         '\'' -> "\\\'"
 924         '\\' -> "\\\\"
 925         c | c >= ' ' && c <= '~' -> [c]
 926           | otherwise -> ['\\',
 927                          chr (ord '0' + ord c `div` 64),
 928                          chr (ord '0' + ord c `div` 8 `mod` 8),
 929                          chr (ord '0' + ord c         `mod` 8)]
 930
 931 -- ---------------------------------------------------------------------------
 932 -- Initialising static objects with floating-point numbers.  We can't
 933 -- just emit the floating point number, because C will cast it to an int
 934 -- by rounding it.  We want the actual bit-representation of the float.
 935
 936 -- This is a hack to turn the floating point numbers into ints that we
 937 -- can safely initialise to static locations.
 938
 939 big_doubles
 940   | machRepByteWidth F64 == 2 * wORD_SIZE  = True
 941   | machRepByteWidth F64 == wORD_SIZE      = False
 942   | otherwise = panic "big_doubles"
 943
 944 castFloatToIntArray :: STUArray s Int Float -> ST s (STUArray s Int Int)
 945 castFloatToIntArray = castSTUArray
 946
 947 castDoubleToIntArray :: STUArray s Int Double -> ST s (STUArray s Int Int)
 948 castDoubleToIntArray = castSTUArray
 949
 950 -- floats are always 1 word
 951 floatToWord :: Rational -> CmmLit
 952 floatToWord r
 953   = runST (do
 954         arr <- newArray_ ((0::Int),0)
 955         writeArray arr 0 (fromRational r)
 956         arr' <- castFloatToIntArray arr
 957         i <- readArray arr' 0
 958         return (CmmInt (toInteger i) wordRep)
 959     )
 960
 961 doubleToWords :: Rational -> [CmmLit]
 962 doubleToWords r
 963   | big_doubles                         -- doubles are 2 words
 964   = runST (do
 965         arr <- newArray_ ((0::Int),1)
 966         writeArray arr 0 (fromRational r)
 967         arr' <- castDoubleToIntArray arr
 968         i1 <- readArray arr' 0
 969         i2 <- readArray arr' 1
 970         return [ CmmInt (toInteger i1) wordRep
 971                , CmmInt (toInteger i2) wordRep
 972                ]
 973     )
 974   | otherwise                           -- doubles are 1 word
 975   = runST (do
 976         arr <- newArray_ ((0::Int),0)
 977         writeArray arr 0 (fromRational r)
 978         arr' <- castDoubleToIntArray arr
 979         i <- readArray arr' 0
 980         return [ CmmInt (toInteger i) wordRep ]
 981     )
 982
 983 -- ---------------------------------------------------------------------------
 984 -- Utils
 985
 986 wordShift :: Int
 987 wordShift = machRepLogWidth wordRep
 988
 989 commafy :: [SDoc] -> SDoc
 990 commafy xs = hsep $ punctuate comma xs
 991
 992 -- Print in C hex format: 0x13fa
 993 pprHexVal :: Integer -> MachRep -> SDoc
 994 pprHexVal 0 _ = ptext SLIT("0x0")
 995 pprHexVal w rep
 996   | w < 0     = parens (char '-' <> ptext SLIT("0x") <> go (-w) <> repsuffix rep)
 997   | otherwise = ptext SLIT("0x") <> go w <> repsuffix rep
 998   where
 999         -- type suffix for literals:
1000         -- Integer literals are unsigned in Cmm/C.  We explicitly cast to
1001         -- signed values for doing signed operations, but at all other
1002         -- times values are unsigned.  This also helps eliminate occasional
1003         -- warnings about integer overflow from gcc.
1004
1005         -- on 32-bit platforms, add "ULL" to 64-bit literals
1006       repsuffix I64 | wORD_SIZE == 4 = ptext SLIT("ULL")
1007         -- on 64-bit platforms with 32-bit int, add "L" to 64-bit literals
1008       repsuffix I64 | cINT_SIZE == 4 = ptext SLIT("UL")
1009       repsuffix _ = char 'U'
1010
1011       go 0 = empty
1012       go w' = go q <> dig
1013            where
1014              (q,r) = w' `quotRem` 16
1015              dig | r < 10    = char (chr (fromInteger r + ord '0'))
1016                  | otherwise = char (chr (fromInteger r - 10 + ord 'a'))
1017