compiler/cmm/ZipCfg.hs

   1 {-# LANGUAGE ScopedTypeVariables #-}
   2 module ZipCfg
   3     (   -- These data types and names are carefully thought out
   4       BlockId(..)       -- ToDo: BlockId should be abstract, but it isn't yet
   5     , BlockEnv, emptyBlockEnv, lookupBlockEnv, extendBlockEnv, insertBlock, mkBlockEnv
   6     , BlockSet, emptyBlockSet, elemBlockSet, extendBlockSet, mkBlockSet
   7     , Graph(..), LGraph(..), FGraph(..)
   8     , Block(..), ZBlock(..), ZHead(..), ZTail(..), ZLast(..)
   9     , HavingSuccessors, succs, fold_succs
  10     , LastNode, mkBranchNode, isBranchNode, branchNodeTarget
  11
  12         -- Observers and transformers
  13         -- (open to renaming suggestions here)
  14     , blockId, zip, unzip, last, goto_end, zipht, tailOfLast
  15     , splice_tail, splice_head, splice_head_only', splice_head'
  16     , of_block_list, to_block_list
  17     , map_nodes
  18     , postorder_dfs, postorder_dfs_from, postorder_dfs_from_except
  19     , fold_layout
  20     , fold_blocks
  21     , translate
  22
  23     , pprLgraph, pprGraph
  24
  25     , entry -- exported for the convenience of ZipDataflow, at least for now
  26
  27     {-
  28     -- the following functions might one day be useful and can be found
  29     -- either below or in ZipCfgExtras:
  30     , entry, exit, focus, focusp, unfocus
  31     , ht_to_block, ht_to_last,
  32     , splice_focus_entry, splice_focus_exit
  33     , fold_fwd_block, foldM_fwd_block
  34     -}
  35
  36     )
  37 where
  38
  39 #include "HsVersions.h"
  40
  41 import Outputable hiding (empty)
  42 import Panic
  43 import Unique
  44 import UniqFM
  45 import UniqSet
  46
  47 import Maybe
  48 import Prelude hiding (zip, unzip, last)
  49
  50 -------------------------------------------------------------------------
  51 --               GENERIC ZIPPER-BASED CONTROL-FLOW GRAPH               --
  52 -------------------------------------------------------------------------
  53 {-
  54
  55 This module defines datatypes used to represent control-flow graphs,
  56 along with some functions for analyzing and splicing graphs.
  57 Functions for building graphs are found in a separate module 'MkZipCfg'.
  58
  59 Every graph has a distinguished entry point.  A graph has at least one
  60 exit; most exits are instructions (or statements) like 'jump' or
  61 'return', which transfer control to other procedures, but a graph may
  62 have up to one 'fall through' exit.  (A graph that represents an
  63 entire Haskell or C-- procedure does not have a 'fall through' exit.)
  64
  65 A graph is a collection of basic blocks.  A basic block begins with a
  66 label (unique id; see Note [Unique BlockId]) which is followed by a
  67 sequence of zero or more 'middle' nodes; the basic block ends with a
  68 'last' node.  Each 'middle' node is a single-entry, single-exit,
  69 uninterruptible computation.  A 'last' node is a single-entry,
  70 multiple-exit computation.  A last node may have zero or more successors,
  71 which are identified by their unique ids.
  72
  73 A special case of last node is the ``default exit,'' which represents
  74 'falling off the end' of the graph.  Such a node is always represented by
  75 the data constructor 'LastExit'.  A graph may contain at most one
  76 'LastExit' node, and a graph representing a full procedure should not
  77 contain any 'LastExit' nodes.  'LastExit' nodes are used only to splice
  78 graphs together, either during graph construction (see module 'MkZipCfg')
  79 or during optimization (see module 'ZipDataflow').
  80
  81 A graph is parameterized over the types of middle and last nodes.  Each of
  82 these types will typically be instantiated with a subset of C-- statements
  83 (see module 'ZipCfgCmmRep') or a subset of machine instructions (yet to be
  84 implemented as of August 2007).
  85
  86
  87 Note [Kinds of Graphs]
  88 ~~~~~~~~~~~~~~~~~~~~~~
  89 This module exposes three representations of graphs.  In order of
  90 increasing complexity, they are:
  91
  92   Graph  m l      The basic graph with its distinguished entry point
  93
  94   LGraph m l      A graph with a *labelled* entry point
  95
  96   FGraph m l      A labelled graph with the *focus* on a particular edge
  97
  98 There are three types because each type offers a slightly different
  99 invariant or cost model.
 100
 101   * The distinguished entry of a Graph has no label.  Because labels must be
 102     unique, acquiring one requires a supply of Unique labels (BlockId's).
 103     The primary advantage of the Graph representation is that we can build a
 104     small Graph purely functionally, without needing a fresh BlockId or
 105     Unique.  For example, during optimization we can easily rewrite a single
 106     middle node into a Graph containing a sequence of two middle nodes
 107     followed by LastExit.
 108
 109   * In an LGraph, every basic block is labelled.  The primary advantage of
 110     this representation is its simplicity: each basic block can be treated
 111     like any other.  This representation is used for mapping, folding, and
 112     translation, as well as layout.
 113
 114     Like any graph, an LGraph still has a distinguished entry point,
 115     which you can discover using 'lg_entry'.
 116
 117   * An FGraph is an LGraph with the *focus* on one particular edge.  The
 118     primary advantage of this representation is that it provides
 119     constant-time access to the nodes connected by that edge, and it also
 120     allows constant-time, functional *replacement* of those nodes---in the
 121     style of Huet's 'zipper'.
 122
 123 None of these representations is ideally suited to the incremental
 124 construction of large graphs.  A separate module, 'MkZipCfg', provides a
 125 fourth representation that is asymptotically optimal for such construction.
 126
 127 -}
 128
 129 --------------- Representation --------------------
 130
 131 -- | A basic block is a 'first' node, followed by zero or more 'middle'
 132 -- nodes, followed by a 'last' node.
 133
 134 -- eventually this module should probably replace the original Cmm, but for
 135 -- now we leave it to dynamic invariants what can be found where
 136
 137 data ZLast l
 138   = LastExit     -- fall through; used for the block that has no last node
 139                  -- LastExit is a device used only for graphs under
 140                  -- construction, or framgments of graph under optimisation,
 141                  -- so we don't want to pollute the 'l' type parameter with it
 142   | LastOther l
 143
 144 data ZHead m   = ZFirst BlockId  | ZHead (ZHead m) m
 145     -- ZHead is a (reversed) sequence of middle nodes labeled by a BlockId
 146 data ZTail m l = ZLast (ZLast l) | ZTail m (ZTail m l)
 147     -- ZTail is a sequence of middle nodes followed by a last node
 148
 149 -- | Blocks and flow graphs; see Note [Kinds of graphs]
 150 data Block m l = Block BlockId (ZTail m l)
 151
 152 data Graph m l = Graph { g_entry :: (ZTail m l), g_blocks :: (BlockEnv (Block m l)) }
 153
 154 data LGraph m l = LGraph  { lg_entry  :: BlockId
 155                           , lg_blocks :: BlockEnv (Block m l) }
 156         -- Invariant: lg_entry is in domain( lg_blocks )
 157
 158 -- | And now the zipper.  The focus is between the head and tail.
 159 -- We cannot ever focus on an inter-block edge.
 160 data ZBlock m l = ZBlock (ZHead m) (ZTail m l)
 161 data FGraph m l = FGraph { fg_entry  :: BlockId
 162                          , fg_focus  :: ZBlock m l
 163                          , fg_others :: BlockEnv (Block m l) }
 164                     -- Invariant: the block represented by 'fg_focus' is *not*
 165                     -- in the map 'fg_others'
 166
 167 ----  Utility functions ---
 168
 169 blockId   :: Block  m l -> BlockId
 170 zip       :: ZBlock m l -> Block  m l
 171 unzip     :: Block  m l -> ZBlock m l
 172
 173 last      :: ZBlock m l -> ZLast l
 174 goto_end  :: ZBlock m l -> (ZHead m, ZLast l)
 175
 176 tailOfLast :: l -> ZTail m l
 177
 178 -- | Take a head and tail and go to beginning or end.  The asymmetry
 179 -- in the types and names is a bit unfortunate, but 'Block m l' is
 180 -- effectively '(BlockId, ZTail m l)' and is accepted in many more places.
 181
 182 ht_to_block, zipht :: ZHead m -> ZTail m l -> Block m l
 183 ht_to_last         :: ZHead m -> ZTail m l -> (ZHead m, ZLast l)
 184
 185 -- | We can splice a single-entry, single-exit LGraph onto a head or a tail.
 186 -- For a head, we have a head 'h' followed by a LGraph 'g'.
 187 -- The entry node of 'g' gets joined to 'h', forming the entry into
 188 -- the new LGraph.  The exit of 'g' becomes the new head.
 189 -- For both arguments and results, the order of values is the order of
 190 -- control flow: before splicing, the head flows into the LGraph; after
 191 -- splicing, the LGraph flows into the head.
 192 -- Splicing a tail is the dual operation.
 193 -- (In order to maintain the order-means-control-flow convention, the
 194 -- orders are reversed.)
 195 --
 196 -- For example, assume
 197 --      head = [L: x:=0]
 198 --      grph = (M, [M: <stuff>,
 199 --                  <blocks>,
 200 --                  N: y:=x; LastExit])
 201 --      tail = [return (y,x)]
 202 --
 203 -- Then         splice_head head grph
 204 --              = ((L, [L: x:=0; goto M,
 205 --                      M: <stuff>,
 206 --                      <blocks>])
 207 --                 , N: y:=x)
 208 --
 209 -- Then         splice_tail grph tail
 210 --              = ( <stuff>
 211 --                , (???, [<blocks>,
 212 --                         N: y:=x; return (y,x)])
 213
 214 splice_head  :: ZHead m    -> LGraph m l -> (LGraph m l, ZHead  m)
 215 splice_head' :: ZHead m -> Graph m l -> (BlockEnv (Block m l), ZHead m)
 216 splice_tail  :: Graph m l -> ZTail  m l -> Graph m l
 217
 218 -- | We can also splice a single-entry, no-exit Graph into a head.
 219 splice_head_only :: ZHead m -> LGraph m l -> LGraph m l
 220 splice_head_only' :: ZHead m -> Graph m l -> LGraph m l
 221
 222
 223 -- | A safe operation
 224
 225 -- | Conversion to and from the environment form is convenient.  For
 226 -- layout or dataflow, however, one will want to use 'postorder_dfs'
 227 -- in order to get the blocks in an order that relates to the control
 228 -- flow in the procedure.
 229 of_block_list :: BlockId -> [Block m l] -> LGraph m l  -- N log N
 230 to_block_list :: LGraph m l -> [Block m l]  -- N log N
 231
 232 -- | Traversal: 'postorder_dfs' returns a list of blocks reachable
 233 -- from the entry node.  This list has the following property:
 234 --
 235 --      Say a "back reference" exists if one of a block's
 236 --      control-flow successors precedes it in the output list
 237 --
 238 --      Then there are as few back references as possible
 239 --
 240 -- The output is suitable for use in
 241 -- a forward dataflow problem.  For a backward problem, simply reverse
 242 -- the list.  ('postorder_dfs' is sufficiently tricky to implement that
 243 -- one doesn't want to try and maintain both forward and backward
 244 -- versions.)
 245
 246 postorder_dfs :: LastNode l => LGraph m l -> [Block m l]
 247
 248 -- | For layout, we fold over pairs of 'Block m l' and 'Maybe BlockId'
 249 -- in layout order.  The 'Maybe BlockId', if present, identifies the
 250 -- block that will be the layout successor of the current block.  This
 251 -- may be useful to help an emitter omit the final 'goto' of a block
 252 -- that flows directly to its layout successor.
 253 --
 254 -- For example: fold_layout f z [ L1:B1, L2:B2, L3:B3 ]
 255 --              = z <$> f (L1:B1) (Just L2)
 256 --                  <$> f (L2:B2) (Just L3)
 257 --                  <$> f (L3:B3) Nothing
 258 -- where a <$> f = f a
 259 fold_layout ::
 260     LastNode l => (Block m l -> Maybe BlockId -> a -> a) -> a -> LGraph m l-> a
 261
 262 -- | We can also fold over blocks in an unspecified order.  The
 263 -- 'ZipCfgExtras' module provides a monadic version, which we
 264 -- haven't needed (else it would be here).
 265 fold_blocks :: (Block m l -> a -> a) -> a -> LGraph m l -> a
 266
 267 map_nodes :: (BlockId -> BlockId) -> (m -> m') -> (l -> l') -> LGraph m l -> LGraph m' l'
 268    -- mapping includes the entry id!
 269
 270 -- | These translation functions are speculative.  I hope eventually
 271 -- they will be used in the native-code back ends ---NR
 272 translate :: (m          -> UniqSM (LGraph m' l')) ->
 273              (l          -> UniqSM (LGraph m' l')) ->
 274              (LGraph m l -> UniqSM (LGraph m' l'))
 275
 276 {-
 277 -- | It's possible that another form of translation would be more suitable:
 278 translateA :: (m -> Agraph m' l') -> (l -> AGraph m' l') -> LGraph m l -> LGraph m' l'
 279 -}
 280
 281 ------------------- Last nodes
 282
 283 -- | We can't make a graph out of just any old 'last node' type.  A last node
 284 -- has to be able to find its successors, and we need to be able to create and
 285 -- identify unconditional branches.  We put these capabilities in a type class.
 286 -- Moreover, the property of having successors is also shared by 'Block's and
 287 -- 'ZTails', so it is useful to have that property in a type class of its own.
 288
 289 class HavingSuccessors b where
 290     succs :: b -> [BlockId]
 291     fold_succs :: (BlockId -> a -> a) -> b -> a -> a
 292
 293     fold_succs add l z = foldr add z $ succs l
 294
 295 class HavingSuccessors l => LastNode l where
 296     mkBranchNode     :: BlockId -> l
 297     isBranchNode     :: l -> Bool
 298     branchNodeTarget :: l -> BlockId  -- panics if not branch node
 299       -- ^ N.B. This interface seems to make for more congenial clients than a
 300       -- single function of type 'l -> Maybe BlockId'
 301
 302 instance HavingSuccessors l => HavingSuccessors (ZLast l) where
 303     succs LastExit = []
 304     succs (LastOther l) = succs l
 305     fold_succs _ LastExit z = z
 306     fold_succs f (LastOther l) z = fold_succs f l z
 307
 308 instance LastNode l => LastNode (ZLast l) where
 309     mkBranchNode id = LastOther $ mkBranchNode id
 310     isBranchNode LastExit = False
 311     isBranchNode (LastOther l) = isBranchNode l
 312     branchNodeTarget LastExit = panic "branchNodeTarget LastExit"
 313     branchNodeTarget (LastOther l) = branchNodeTarget l
 314
 315 instance LastNode l => HavingSuccessors (ZBlock m l) where
 316     succs b = succs (last b)
 317
 318 instance LastNode l => HavingSuccessors (Block m l) where
 319     succs b = succs (unzip b)
 320
 321 instance LastNode l => HavingSuccessors (ZTail m l) where
 322     succs b = succs (lastTail b)
 323
 324
 325
 326 -- ================ IMPLEMENTATION ================--
 327
 328 ----- block manipulations
 329
 330 blockId (Block id _) = id
 331
 332 -- | Convert block between forms.
 333 -- These functions are tail-recursive, so we can go as deep as we like
 334 -- without fear of stack overflow.
 335
 336 ht_to_block head tail = case head of
 337   ZFirst id -> Block id tail
 338   ZHead h m -> ht_to_block h (ZTail m tail)
 339
 340 ht_to_last head (ZLast l)   = (head, l)
 341 ht_to_last head (ZTail m t) = ht_to_last (ZHead head m) t
 342
 343 zipht            h t  = ht_to_block h t
 344 zip      (ZBlock h t) = ht_to_block h t
 345 goto_end (ZBlock h t) = ht_to_last  h t
 346
 347 unzip (Block id t) = ZBlock (ZFirst id) t
 348
 349 head_id :: ZHead m -> BlockId
 350 head_id (ZFirst id) = id
 351 head_id (ZHead h _) = head_id h
 352
 353 last (ZBlock _ t) = lastTail t
 354
 355 lastTail :: ZTail m l -> ZLast l
 356 lastTail (ZLast l) = l
 357 lastTail (ZTail _ t) = lastTail t
 358
 359 tailOfLast l = ZLast (LastOther l) -- ^ tedious to write in every client
 360
 361
 362 ------------------ simple graph manipulations
 363
 364 focus :: BlockId -> LGraph m l -> FGraph m l -- focus on edge out of node with id
 365 focus id (LGraph entry blocks) =
 366     case lookupBlockEnv blocks id of
 367       Just b -> FGraph entry (unzip b) (delFromUFM blocks id)
 368       Nothing -> panic "asked for nonexistent block in flow graph"
 369
 370 entry   :: LGraph m l -> FGraph m l         -- focus on edge out of entry node
 371 entry g@(LGraph eid _) = focus eid g
 372
 373 -- | pull out a block satisfying the predicate, if any
 374 splitp_blocks :: (Block m l -> Bool) -> BlockEnv (Block m l) ->
 375                  Maybe (Block m l, BlockEnv (Block m l))
 376 splitp_blocks p blocks = lift $ foldUFM scan (Nothing, emptyBlockEnv) blocks
 377     where scan b (yes, no) =
 378               case yes of
 379                 Nothing | p b -> (Just b, no)
 380                         | otherwise -> (yes, insertBlock b no)
 381                 Just _ -> (yes, insertBlock b no)
 382           lift (Nothing, _) = Nothing
 383           lift (Just b, bs) = Just (b, bs)
 384
 385 -- | 'insertBlock' should not be used to *replace* an existing block
 386 -- but only to insert a new one
 387 insertBlock :: Block m l -> BlockEnv (Block m l) -> BlockEnv (Block m l)
 388 insertBlock b bs =
 389       ASSERT (isNothing $ lookupBlockEnv bs id)
 390       extendBlockEnv bs id b
 391     where id = blockId b
 392
 393 -- | Used in assertions; tells if a graph has exactly one exit
 394 single_exit :: LGraph l m -> Bool
 395 single_exit g = foldUFM check 0 (lg_blocks g) == 1
 396     where check block count = case last (unzip block) of
 397                                 LastExit -> count + (1 :: Int)
 398                                 _ -> count
 399
 400 -- | Used in assertions; tells if a graph has exactly one exit
 401 single_exitg :: Graph l m -> Bool
 402 single_exitg (Graph tail blocks) = foldUFM add (exit_count (lastTail tail)) blocks == 1
 403     where add block count = count + exit_count (last (unzip block))
 404           exit_count LastExit = 1 :: Int
 405           exit_count _        = 0
 406
 407 ------------------ graph traversals
 408
 409 -- | This is the most important traversal over this data structure.  It drops
 410 -- unreachable code and puts blocks in an order that is good for solving forward
 411 -- dataflow problems quickly.  The reverse order is good for solving backward
 412 -- dataflow problems quickly.  The forward order is also reasonably good for
 413 -- emitting instructions, except that it will not usually exploit Forrest
 414 -- Baskett's trick of eliminating the unconditional branch from a loop.  For
 415 -- that you would need a more serious analysis, probably based on dominators, to
 416 -- identify loop headers.
 417 --
 418 -- The ubiquity of 'postorder_dfs' is one reason for the ubiquity of the 'LGraph'
 419 -- representation, when for most purposes the plain 'Graph' representation is
 420 -- more mathematically elegant (but results in more complicated code).
 421 --
 422 -- Here's an easy way to go wrong!  Consider
 423 --      A -> [B,C]
 424 --      B -> D
 425 --      C -> D
 426 -- Then ordinary dfs would give [A,B,D,C] which has a back ref from C to D.
 427 -- Better to geot [A,B,C,D]
 428
 429
 430 postorder_dfs' :: LastNode l => LGraph m l -> [Block m l]
 431 postorder_dfs' g@(LGraph _ blocks) =
 432   let FGraph _ eblock _ = entry g
 433   in  vnode (zip eblock) (\acc _visited -> acc) [] emptyBlockSet
 434   where
 435     -- vnode ::
 436     --    Block m l -> ([Block m l] -> BlockSet -> a) -> [Block m l] -> BlockSet -> a
 437     vnode block@(Block id _) cont acc visited =
 438         if elemBlockSet id visited then
 439             cont acc visited
 440         else
 441             vchildren block (get_children block) cont acc (extendBlockSet visited id)
 442     vchildren block bs cont acc visited =
 443         let next children acc visited =
 444                 case children of []     -> cont (block : acc) visited
 445                                  (b:bs) -> vnode b (next bs) acc visited
 446         in next bs acc visited
 447     get_children block = foldl add_id [] (succs block)
 448     add_id rst id = case lookupBlockEnv blocks id of
 449                       Just b -> b : rst
 450                       Nothing -> rst
 451
 452 postorder_dfs g@(LGraph _ blockenv) =
 453     let FGraph id eblock _ = entry g
 454         dfs1 = zip eblock :
 455                postorder_dfs_from_except blockenv eblock (unitUniqSet id)
 456         dfs2 = postorder_dfs' g
 457 --    in  ASSERT (map blockId dfs1 == map blockId dfs2) dfs2
 458     in  if (map blockId dfs1 == map blockId dfs2) then dfs2 else panic "inconsistent DFS"
 459
 460 postorder_dfs_from
 461     :: (HavingSuccessors b, LastNode l) => BlockEnv (Block m l) -> b -> [Block m l]
 462 postorder_dfs_from blocks b = postorder_dfs_from_except blocks b emptyBlockSet
 463
 464 postorder_dfs_from_except :: forall b m l . (HavingSuccessors b, LastNode l) => BlockEnv (Block m l) -> b -> BlockSet -> [Block m l]
 465 postorder_dfs_from_except blocks b visited =
 466   vchildren (get_children b) (\acc _visited -> acc) [] visited
 467   where
 468     -- vnode ::
 469     --    Block m l -> ([Block m l] -> BlockSet -> a) -> [Block m l] -> BlockSet -> a
 470     vnode block@(Block id _) cont acc visited =
 471         if elemBlockSet id visited then
 472             cont acc visited
 473         else
 474             let cont' acc visited = cont (block:acc) visited in
 475             vchildren (get_children block) cont' acc (extendBlockSet visited id)
 476     vchildren bs cont acc visited =
 477         let next children acc visited =
 478                 case children of []     -> cont acc visited
 479                                  (b:bs) -> vnode b (next bs) acc visited
 480         in next bs acc visited
 481     get_children block = foldl add_id [] (succs block)
 482     add_id rst id = case lookupBlockEnv blocks id of
 483                       Just b -> b : rst
 484                       Nothing -> rst
 485
 486
 487 -- | Slightly more complicated than the usual fold because we want to tell block
 488 -- 'b1' what its inline successor is going to be, so that if 'b1' ends with
 489 -- 'goto b2', the goto can be omitted.
 490
 491 fold_layout f z g@(LGraph eid _) = fold (postorder_dfs g) z
 492   where fold blocks z =
 493             case blocks of [] -> z
 494                            [b] -> f b Nothing z
 495                            b1 : b2 : bs -> fold (b2 : bs) (f b1 (nextlabel b2) z)
 496         nextlabel (Block id _) =
 497             if id == eid then panic "entry as successor"
 498             else Just id
 499
 500 -- | The rest of the traversals are straightforward
 501
 502 map_nodes idm middle last (LGraph eid blocks) = LGraph (idm eid) (mapUFM block blocks)
 503     where block (Block id t) = Block (idm id) (tail t)
 504           tail (ZTail m t) = ZTail (middle m) (tail t)
 505           tail (ZLast LastExit) = ZLast LastExit
 506           tail (ZLast (LastOther l)) = ZLast (LastOther (last l))
 507
 508 fold_blocks f z (LGraph _ blocks) = foldUFM f z blocks
 509
 510 of_block_list e blocks = LGraph e $ foldr insertBlock emptyBlockEnv blocks
 511 to_block_list (LGraph _ blocks) = eltsUFM blocks
 512
 513
 514
 515
 516 -- We want to be able to scrutinize a single-entry, single-exit 'LGraph' for
 517 -- splicing purposes.  There are two useful cases: the 'LGraph' is a single block
 518 -- or it isn't.  We use continuation-passing style.
 519
 520 prepare_for_splicing ::
 521   LGraph m l -> (ZTail m l -> a) -> (ZTail m l -> ZHead m -> BlockEnv (Block m l) -> a)
 522   -> a
 523 prepare_for_splicing g single multi =
 524   let FGraph _ gentry gblocks = entry g
 525       ZBlock _ etail = gentry
 526   in if isNullUFM gblocks then
 527          case last gentry of
 528            LastExit -> single etail
 529            _ -> panic "bad single block"
 530      else
 531        case splitp_blocks is_exit gblocks of
 532          Nothing -> panic "Can't find an exit block"
 533          Just (gexit, gblocks) ->
 534               let (gh, gl) = goto_end $ unzip gexit in
 535               case gl of LastExit -> multi etail gh gblocks
 536                          _ -> panic "exit is not exit?!"
 537
 538 prepare_for_splicing' ::
 539   Graph m l -> (ZTail m l -> a) -> (ZTail m l -> ZHead m -> BlockEnv (Block m l) -> a)
 540   -> a
 541 prepare_for_splicing' (Graph etail gblocks) single multi =
 542    if isNullUFM gblocks then
 543        case lastTail etail of
 544          LastExit -> single etail
 545          _ -> panic "bad single block"
 546    else
 547      case splitp_blocks is_exit gblocks of
 548        Nothing -> panic "Can't find an exit block"
 549        Just (gexit, gblocks) ->
 550             let (gh, gl) = goto_end $ unzip gexit in
 551             case gl of LastExit -> multi etail gh gblocks
 552                        _ -> panic "exit is not exit?!"
 553
 554 is_exit :: Block m l -> Bool
 555 is_exit b = case last (unzip b) of { LastExit -> True; _ -> False }
 556
 557 splice_head head g =
 558   ASSERT (single_exit g) prepare_for_splicing g splice_one_block splice_many_blocks
 559    where eid = head_id head
 560          splice_one_block tail' =
 561              case ht_to_last head tail' of
 562                (head, LastExit) -> (LGraph eid emptyBlockEnv, head)
 563                _ -> panic "spliced LGraph without exit"
 564          splice_many_blocks entry exit others =
 565              (LGraph eid (insertBlock (zipht head entry) others), exit)
 566
 567 splice_head' head g =
 568   ASSERT (single_exitg g) prepare_for_splicing' g splice_one_block splice_many_blocks
 569    where splice_one_block tail' =
 570              case ht_to_last head tail' of
 571                (head, LastExit) -> (emptyBlockEnv, head)
 572                _ -> panic "spliced LGraph without exit"
 573          splice_many_blocks entry exit others =
 574              (insertBlock (zipht head entry) others, exit)
 575
 576 -- splice_tail :: Graph m l -> ZTail m l -> Graph m l
 577 splice_tail g tail =
 578   ASSERT (single_exitg g) prepare_for_splicing' g splice_one_block splice_many_blocks
 579     where splice_one_block tail' = Graph (tail' `append_tails` tail) emptyBlockEnv
 580           append_tails (ZLast LastExit) tail = tail
 581           append_tails (ZLast _) _ = panic "spliced single block without LastExit"
 582           append_tails (ZTail m t) tail = ZTail m (append_tails t tail)
 583           splice_many_blocks entry exit others =
 584               Graph entry (insertBlock (zipht exit tail) others)
 585
 586 {-
 587 splice_tail g tail =
 588   AS SERT (single_exit g) prepare_for_splicing g splice_one_block splice_many_blocks
 589     where splice_one_block tail' =  -- return tail' .. tail
 590             case ht_to_last (ZFirst (lg_entry g)) tail' of
 591               (head', LastExit) ->
 592                   case ht_to_block head' tail of
 593                      Block id t | id == lg_entry g -> (t, LGraph id emptyBlockEnv)
 594                      _ -> panic "entry in; garbage out"
 595               _ -> panic "spliced single block without Exit"
 596           splice_many_blocks entry exit others =
 597               (entry, LGraph (lg_entry g) (insertBlock (zipht exit tail) others))
 598 -}
 599
 600 splice_head_only head g =
 601   let FGraph eid gentry gblocks = entry g
 602   in case gentry of
 603        ZBlock (ZFirst _) tail -> LGraph eid (insertBlock (zipht head tail) gblocks)
 604        _ -> panic "entry not at start of block?!"
 605
 606 splice_head_only' head (Graph tail gblocks) =
 607   let eblock = zipht head tail in
 608   LGraph (blockId eblock) (insertBlock eblock gblocks)
 609
 610
 611 --- Translation
 612
 613 translate txm txl (LGraph eid blocks) =
 614     do blocks' <- foldUFM txblock (return emptyBlockEnv) blocks
 615        return $ LGraph eid blocks'
 616     where
 617       -- txblock ::
 618       -- Block m l -> UniqSM (BlockEnv (Block m' l')) -> UniqSM (BlockEnv (Block m' l'))
 619       txblock (Block id t) expanded =
 620         do blocks' <- expanded
 621            txtail (ZFirst id) t blocks'
 622       -- txtail :: ZHead m' -> ZTail m l -> BlockEnv (Block m' l') ->
 623       --           UniqSM (BlockEnv (Block m' l'))
 624       txtail h (ZTail m t) blocks' =
 625         do m' <- txm m
 626            let (g, h') = splice_head h m'
 627            txtail h' t (plusUFM (lg_blocks g) blocks')
 628       txtail h (ZLast (LastOther l)) blocks' =
 629         do l' <- txl l
 630            return $ plusUFM (lg_blocks (splice_head_only h l')) blocks'
 631       txtail h (ZLast LastExit) blocks' =
 632         return $ insertBlock (zipht h (ZLast LastExit)) blocks'
 633
 634 ----------------------------------------------------------------
 635 --- Block Ids, their environments, and their sets
 636
 637 {- Note [Unique BlockId]
 638 ~~~~~~~~~~~~~~~~~~~~~~~~
 639 Although a 'BlockId' is a local label, for reasons of implementation,
 640 'BlockId's must be unique within an entire compilation unit.  The reason
 641 is that each local label is mapped to an assembly-language label, and in
 642 most assembly languages allow, a label is visible throughout the enitre
 643 compilation unit in which it appears.
 644 -}
 645
 646 newtype BlockId = BlockId Unique
 647   deriving (Eq,Ord)
 648
 649 instance Uniquable BlockId where
 650   getUnique (BlockId u) = u
 651
 652 instance Show BlockId where
 653   show (BlockId u) = show u
 654
 655 instance Outputable BlockId where
 656   ppr = ppr . getUnique
 657
 658
 659 type BlockEnv a = UniqFM {- BlockId -} a
 660 emptyBlockEnv :: BlockEnv a
 661 emptyBlockEnv = emptyUFM
 662 lookupBlockEnv :: BlockEnv a -> BlockId -> Maybe a
 663 lookupBlockEnv = lookupUFM
 664 extendBlockEnv :: BlockEnv a -> BlockId -> a -> BlockEnv a
 665 extendBlockEnv = addToUFM
 666 mkBlockEnv :: [(BlockId,a)] -> BlockEnv a
 667 mkBlockEnv = listToUFM
 668
 669 type BlockSet = UniqSet BlockId
 670 emptyBlockSet :: BlockSet
 671 emptyBlockSet = emptyUniqSet
 672 elemBlockSet :: BlockId -> BlockSet -> Bool
 673 elemBlockSet = elementOfUniqSet
 674 extendBlockSet :: BlockSet -> BlockId -> BlockSet
 675 extendBlockSet = addOneToUniqSet
 676 mkBlockSet :: [BlockId] -> BlockSet
 677 mkBlockSet = mkUniqSet
 678
 679 ----------------------------------------------------------------
 680 ---- Prettyprinting
 681 ----------------------------------------------------------------
 682
 683 -- putting this code in PprCmmZ leads to circular imports :-(
 684
 685 instance (Outputable m, Outputable l) => Outputable (ZTail m l) where
 686     ppr = pprTail
 687
 688 pprTail :: (Outputable m, Outputable l) => ZTail m l -> SDoc
 689 pprTail (ZTail m t) = ppr m $$ ppr t
 690 pprTail (ZLast LastExit) = text "<exit>"
 691 pprTail (ZLast (LastOther l)) = ppr l
 692
 693 pprLgraph :: (Outputable m, Outputable l, LastNode l) => LGraph m l -> SDoc
 694 pprLgraph g = text "{" $$ nest 2 (vcat $ map pprBlock blocks) $$ text "}"
 695     where pprBlock (Block id tail) = ppr id <> colon $$ ppr tail
 696           blocks = postorder_dfs g
 697
 698 pprGraph :: (Outputable m, Outputable l, LastNode l) => Graph m l -> SDoc
 699 pprGraph (Graph tail blockenv) =
 700         text "{" $$ nest 2 (ppr tail $$ (vcat $ map pprBlock blocks)) $$ text "}"
 701     where pprBlock (Block id tail) = ppr id <> colon $$ ppr tail
 702           blocks = postorder_dfs_from blockenv tail
 703
 704 _unused :: FS.FastString
 705 _unused = undefined