compiler/codeGen/CgCase.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 module CgCase ( cgCase, saveVolatileVarsAndRegs,
   8                 restoreCurrentCostCentre
   9         ) where
  10
  11 #include "HsVersions.h"
  12
  13 import {-# SOURCE #-} CgExpr  ( cgExpr )
  14
  15 import CgMonad
  16 import CgBindery
  17 import CgCon
  18 import CgHeapery
  19 import CgCallConv
  20 import CgStackery
  21 import CgTailCall
  22 import CgPrimOp
  23 import CgForeignCall
  24 import CgUtils
  25 import CgProf
  26 import CgInfoTbls
  27
  28 import ClosureInfo
  29 import SMRep
  30 import CmmUtils
  31 import Cmm
  32 import MachOp
  33
  34 import StgSyn
  35 import StaticFlags
  36 import Id
  37 import ForeignCall
  38 import VarSet
  39 import CoreSyn
  40 import PrimOp
  41 import TyCon
  42 import Util
  43 import Outputable
  44 \end{code}
  45
  46 \begin{code}
  47 data GCFlag
  48   = GCMayHappen -- The scrutinee may involve GC, so everything must be
  49                 -- tidy before the code for the scrutinee.
  50
  51   | NoGC        -- The scrutinee is a primitive value, or a call to a
  52                 -- primitive op which does no GC.  Hence the case can
  53                 -- be done inline, without tidying up first.
  54 \end{code}
  55
  56 It is quite interesting to decide whether to put a heap-check
  57 at the start of each alternative.  Of course we certainly have
  58 to do so if the case forces an evaluation, or if there is a primitive
  59 op which can trigger GC.
  60
  61 A more interesting situation is this:
  62
  63  \begin{verbatim}
  64         !A!;
  65         ...A...
  66         case x# of
  67           0#      -> !B!; ...B...
  68           default -> !C!; ...C...
  69  \end{verbatim}
  70
  71 where \tr{!x!} indicates a possible heap-check point. The heap checks
  72 in the alternatives {\em can} be omitted, in which case the topmost
  73 heapcheck will take their worst case into account.
  74
  75 In favour of omitting \tr{!B!}, \tr{!C!}:
  76
  77  - {\em May} save a heap overflow test,
  78         if ...A... allocates anything.  The other advantage
  79         of this is that we can use relative addressing
  80         from a single Hp to get at all the closures so allocated.
  81
  82  - No need to save volatile vars etc across the case
  83
  84 Against:
  85
  86   - May do more allocation than reqd.  This sometimes bites us
  87         badly.  For example, nfib (ha!)  allocates about 30\% more space if the
  88         worst-casing is done, because many many calls to nfib are leaf calls
  89         which don't need to allocate anything.
  90
  91         This never hurts us if there is only one alternative.
  92
  93 \begin{code}
  94 cgCase  :: StgExpr
  95         -> StgLiveVars
  96         -> StgLiveVars
  97         -> Id
  98         -> SRT
  99         -> AltType
 100         -> [StgAlt]
 101         -> Code
 102 \end{code}
 103
 104 Special case #1: case of literal.
 105
 106 \begin{code}
 107 cgCase (StgLit lit) live_in_whole_case live_in_alts bndr srt
 108        alt_type@(PrimAlt tycon) alts
 109   = do  { tmp_reg <- bindNewToTemp bndr
 110         ; cm_lit <- cgLit lit
 111         ; stmtC (CmmAssign (CmmLocal tmp_reg) (CmmLit cm_lit))
 112         ; cgPrimAlts NoGC alt_type (CmmLocal tmp_reg) alts }
 113 \end{code}
 114
 115 Special case #2: scrutinising a primitive-typed variable.       No
 116 evaluation required.  We don't save volatile variables, nor do we do a
 117 heap-check in the alternatives.  Instead, the heap usage of the
 118 alternatives is worst-cased and passed upstream.  This can result in
 119 allocating more heap than strictly necessary, but it will sometimes
 120 eliminate a heap check altogether.
 121
 122 \begin{code}
 123 cgCase (StgApp v []) live_in_whole_case live_in_alts bndr srt
 124        alt_type@(PrimAlt tycon) alts
 125   = do  { -- Careful! we can't just bind the default binder to the same thing
 126           -- as the scrutinee, since it might be a stack location, and having
 127           -- two bindings pointing at the same stack locn doesn't work (it
 128           -- confuses nukeDeadBindings).  Hence, use a new temp.
 129           v_info <- getCgIdInfo v
 130         ; amode <- idInfoToAmode v_info
 131         ; tmp_reg <- bindNewToTemp bndr
 132         ; stmtC (CmmAssign (CmmLocal tmp_reg) amode)
 133         ; cgPrimAlts NoGC alt_type (CmmLocal tmp_reg) alts }
 134 \end{code}
 135
 136 Special case #3: inline PrimOps and foreign calls.
 137
 138 \begin{code}
 139 cgCase (StgOpApp op@(StgPrimOp primop) args _)
 140        live_in_whole_case live_in_alts bndr srt alt_type alts
 141   | not (primOpOutOfLine primop)
 142   = cgInlinePrimOp primop args bndr alt_type live_in_alts alts
 143 \end{code}
 144
 145 TODO: Case-of-case of primop can probably be done inline too (but
 146 maybe better to translate it out beforehand).  See
 147 ghc/lib/misc/PackedString.lhs for examples where this crops up (with
 148 4.02).
 149
 150 Special case #4: inline foreign calls: an unsafe foreign call can be done
 151 right here, just like an inline primop.
 152
 153 \begin{code}
 154 cgCase (StgOpApp op@(StgFCallOp fcall _) args _)
 155        live_in_whole_case live_in_alts bndr srt alt_type alts
 156   | unsafe_foreign_call
 157   = ASSERT( isSingleton alts )
 158     do  --  *must* be an unboxed tuple alt.
 159         -- exactly like the cgInlinePrimOp case for unboxed tuple alts..
 160         { res_tmps <- mapFCs bindNewToTemp non_void_res_ids
 161         ; let res_hints = map (typeHint.idType) non_void_res_ids
 162         ; cgForeignCall (zip res_tmps res_hints) fcall args live_in_alts
 163         ; cgExpr rhs }
 164   where
 165    (_, res_ids, _, rhs) = head alts
 166    non_void_res_ids = filter (nonVoidArg . idCgRep) res_ids
 167
 168    unsafe_foreign_call
 169          = case fcall of
 170                 CCall (CCallSpec _ _ s) -> not (playSafe s)
 171                 _other                  -> False
 172 \end{code}
 173
 174 Special case: scrutinising a non-primitive variable.
 175 This can be done a little better than the general case, because
 176 we can reuse/trim the stack slot holding the variable (if it is in one).
 177
 178 \begin{code}
 179 cgCase (StgApp fun args)
 180         live_in_whole_case live_in_alts bndr srt alt_type alts
 181   = do  { fun_info <- getCgIdInfo fun
 182         ; arg_amodes <- getArgAmodes args
 183
 184         -- Nuking dead bindings *before* calculating the saves is the
 185         -- value-add here.  We might end up freeing up some slots currently
 186         -- occupied by variables only required for the call.
 187         -- NOTE: we need to look up the variables used in the call before
 188         -- doing this, because some of them may not be in the environment
 189         -- afterward.
 190         ; nukeDeadBindings live_in_alts
 191         ; (save_assts, alts_eob_info, maybe_cc_slot)
 192                 <- saveVolatileVarsAndRegs live_in_alts
 193
 194         ; scrut_eob_info
 195             <- forkEval alts_eob_info
 196                         (allocStackTop retAddrSizeW >> nopC)
 197                         (do { deAllocStackTop retAddrSizeW
 198                             ; cgEvalAlts maybe_cc_slot bndr srt alt_type alts })
 199
 200         ; setEndOfBlockInfo scrut_eob_info
 201                             (performTailCall fun_info arg_amodes save_assts) }
 202 \end{code}
 203
 204 Note about return addresses: we *always* push a return address, even
 205 if because of an optimisation we end up jumping direct to the return
 206 code (not through the address itself).  The alternatives always assume
 207 that the return address is on the stack.  The return address is
 208 required in case the alternative performs a heap check, since it
 209 encodes the liveness of the slots in the activation record.
 210
 211 On entry to the case alternative, we can re-use the slot containing
 212 the return address immediately after the heap check.  That's what the
 213 deAllocStackTop call is doing above.
 214
 215 Finally, here is the general case.
 216
 217 \begin{code}
 218 cgCase expr live_in_whole_case live_in_alts bndr srt alt_type alts
 219   = do  {       -- Figure out what volatile variables to save
 220           nukeDeadBindings live_in_whole_case
 221
 222         ; (save_assts, alts_eob_info, maybe_cc_slot)
 223                 <- saveVolatileVarsAndRegs live_in_alts
 224
 225              -- Save those variables right now!
 226         ; emitStmts save_assts
 227
 228             -- generate code for the alts
 229         ; scrut_eob_info
 230                <- forkEval alts_eob_info
 231                            (do  { nukeDeadBindings live_in_alts
 232                                 ; allocStackTop retAddrSizeW   -- space for retn address
 233                                 ; nopC })
 234                            (do  { deAllocStackTop retAddrSizeW
 235                                 ; cgEvalAlts maybe_cc_slot bndr srt alt_type alts })
 236
 237         ; setEndOfBlockInfo scrut_eob_info (cgExpr expr)
 238     }
 239 \end{code}
 240
 241 There's a lot of machinery going on behind the scenes to manage the
 242 stack pointer here.  forkEval takes the virtual Sp and free list from
 243 the first argument, and turns that into the *real* Sp for the second
 244 argument.  It also uses this virtual Sp as the args-Sp in the EOB info
 245 returned, so that the scrutinee will trim the real Sp back to the
 246 right place before doing whatever it does.
 247   --SDM (who just spent an hour figuring this out, and didn't want to
 248          forget it).
 249
 250 Why don't we push the return address just before evaluating the
 251 scrutinee?  Because the slot reserved for the return address might
 252 contain something useful, so we wait until performing a tail call or
 253 return before pushing the return address (see
 254 CgTailCall.pushReturnAddress).
 255
 256 This also means that the environment doesn't need to know about the
 257 free stack slot for the return address (for generating bitmaps),
 258 because we don't reserve it until just before the eval.
 259
 260 TODO!!  Problem: however, we have to save the current cost centre
 261 stack somewhere, because at the eval point the current CCS might be
 262 different.  So we pick a free stack slot and save CCCS in it.  One
 263 consequence of this is that activation records on the stack don't
 264 follow the layout of closures when we're profiling.  The CCS could be
 265 anywhere within the record).
 266
 267 %************************************************************************
 268 %*                                                                      *
 269                 Inline primops
 270 %*                                                                      *
 271 %************************************************************************
 272
 273 \begin{code}
 274 cgInlinePrimOp primop args bndr (PrimAlt tycon) live_in_alts alts
 275   | isVoidArg (idCgRep bndr)
 276   = ASSERT( con == DEFAULT && isSingleton alts && null bs )
 277     do  {       -- VOID RESULT; just sequencing,
 278                 -- so get in there and do it
 279           cgPrimOp [] primop args live_in_alts
 280         ; cgExpr rhs }
 281   where
 282     (con,bs,_,rhs) = head alts
 283
 284 cgInlinePrimOp primop args bndr (PrimAlt tycon) live_in_alts alts
 285   = do  {       -- PRIMITIVE ALTS, with non-void result
 286           tmp_reg <- bindNewToTemp bndr
 287         ; cgPrimOp [tmp_reg] primop args live_in_alts
 288         ; cgPrimAlts NoGC (PrimAlt tycon) (CmmLocal tmp_reg) alts }
 289
 290 cgInlinePrimOp primop args bndr (UbxTupAlt tycon) live_in_alts alts
 291   = ASSERT( isSingleton alts )
 292     do  {       -- UNBOXED TUPLE ALTS
 293                 -- No heap check, no yield, just get in there and do it.
 294                 -- NB: the case binder isn't bound to anything;
 295                 --     it has a unboxed tuple type
 296
 297           res_tmps <- mapFCs bindNewToTemp non_void_res_ids
 298         ; cgPrimOp res_tmps primop args live_in_alts
 299         ; cgExpr rhs }
 300   where
 301    (_, res_ids, _, rhs) = head alts
 302    non_void_res_ids = filter (nonVoidArg . idCgRep) res_ids
 303
 304 cgInlinePrimOp primop args bndr (AlgAlt tycon) live_in_alts alts
 305   = do  {       -- ENUMERATION TYPE RETURN
 306                 -- Typical: case a ># b of { True -> ..; False -> .. }
 307                 -- The primop itself returns an index into the table of
 308                 -- closures for the enumeration type.
 309            tag_amode <- ASSERT( isEnumerationTyCon tycon )
 310                         do_enum_primop primop
 311
 312                 -- Bind the default binder if necessary
 313                 -- (avoiding it avoids the assignment)
 314                 -- The deadness info is set by StgVarInfo
 315         ; this_pkg <- getThisPackage
 316         ; whenC (not (isDeadBinder bndr))
 317                 (do { tmp_reg <- bindNewToTemp bndr
 318                     ; stmtC (CmmAssign
 319                              (CmmLocal tmp_reg)
 320                              (tagToClosure this_pkg tycon tag_amode)) })
 321
 322                 -- Compile the alts
 323         ; (branches, mb_deflt) <- cgAlgAlts NoGC Nothing{-cc_slot-}
 324                                             (AlgAlt tycon) alts
 325
 326                 -- Do the switch
 327         ; emitSwitch tag_amode branches mb_deflt 0 (tyConFamilySize tycon - 1)
 328         }
 329   where
 330
 331     do_enum_primop :: PrimOp -> FCode CmmExpr   -- Returns amode for result
 332     do_enum_primop TagToEnumOp  -- No code!
 333        | [arg] <- args = do
 334          (_,e) <- getArgAmode arg
 335          return e
 336     do_enum_primop primop
 337       = do tmp <- newNonPtrTemp wordRep
 338            cgPrimOp [tmp] primop args live_in_alts
 339            returnFC (CmmReg (CmmLocal tmp))
 340
 341 cgInlinePrimOp primop arg_amodes bndr PolyAlt live_in_alts alts
 342   = pprPanic "cgCase: case of primop has polymorphic type" (ppr bndr)
 343 \end{code}
 344
 345 %************************************************************************
 346 %*                                                                      *
 347 \subsection[CgCase-alts]{Alternatives}
 348 %*                                                                      *
 349 %************************************************************************
 350
 351 @cgEvalAlts@ returns an addressing mode for a continuation for the
 352 alternatives of a @case@, used in a context when there
 353 is some evaluation to be done.
 354
 355 \begin{code}
 356 cgEvalAlts :: Maybe VirtualSpOffset     -- Offset of cost-centre to be restored, if any
 357            -> Id
 358            -> SRT                       -- SRT for the continuation
 359            -> AltType
 360            -> [StgAlt]
 361            -> FCode Sequel      -- Any addr modes inside are guaranteed
 362                                 -- to be a label so that we can duplicate it
 363                                 -- without risk of duplicating code
 364
 365 cgEvalAlts cc_slot bndr srt alt_type@(PrimAlt tycon) alts
 366   = do  { let   rep = tyConCgRep tycon
 367                 reg = dataReturnConvPrim rep    -- Bottom for voidRep
 368
 369         ; abs_c <- forkProc $ do
 370                 {       -- Bind the case binder, except if it's void
 371                         -- (reg is bottom in that case)
 372                   whenC (nonVoidArg rep) $
 373                   bindNewToReg bndr reg (mkLFArgument bndr)
 374                 ; restoreCurrentCostCentre cc_slot True
 375                 ; cgPrimAlts GCMayHappen alt_type reg alts }
 376
 377         ; lbl <- emitReturnTarget (idName bndr) abs_c srt
 378         ; returnFC (CaseAlts lbl Nothing bndr) }
 379
 380 cgEvalAlts cc_slot bndr srt (UbxTupAlt _) [(con,args,_,rhs)]
 381   =     -- Unboxed tuple case
 382         -- By now, the simplifier should have have turned it
 383         -- into         case e of (# a,b #) -> e
 384         -- There shouldn't be a
 385         --              case e of DEFAULT -> e
 386     ASSERT2( case con of { DataAlt _ -> True; other -> False },
 387              text "cgEvalAlts: dodgy case of unboxed tuple type" )
 388     do  {       -- forkAbsC for the RHS, so that the envt is
 389                 -- not changed for the emitReturn call
 390           abs_c <- forkProc $ do
 391                 { (live_regs, ptrs, nptrs, _) <- bindUnboxedTupleComponents args
 392                         -- Restore the CC *after* binding the tuple components,
 393                         -- so that we get the stack offset of the saved CC right.
 394                 ; restoreCurrentCostCentre cc_slot True
 395                         -- Generate a heap check if necessary
 396                         -- and finally the code for the alternative
 397                 ; unbxTupleHeapCheck live_regs ptrs nptrs noStmts
 398                                      (cgExpr rhs) }
 399         ; lbl <- emitReturnTarget (idName bndr) abs_c srt
 400         ; returnFC (CaseAlts lbl Nothing bndr) }
 401
 402 cgEvalAlts cc_slot bndr srt alt_type alts
 403   =     -- Algebraic and polymorphic case
 404     do  {       -- Bind the default binder
 405           bindNewToReg bndr nodeReg (mkLFArgument bndr)
 406
 407         -- Generate sequel info for use downstream
 408         -- At the moment, we only do it if the type is vector-returnable.
 409         -- Reason: if not, then it costs extra to label the
 410         -- alternatives, because we'd get return code like:
 411         --
 412         --      switch TagReg { 0 : JMP(alt_1); 1 : JMP(alt_2) ..etc }
 413         --
 414         -- which is worse than having the alt code in the switch statement
 415
 416         ; (alts, mb_deflt) <- cgAlgAlts GCMayHappen cc_slot alt_type alts
 417
 418         ; (lbl, branches) <- emitAlgReturnTarget (idName bndr)
 419                                 alts mb_deflt srt fam_sz
 420
 421         ; returnFC (CaseAlts lbl branches bndr) }
 422   where
 423     fam_sz = case alt_type of
 424                 AlgAlt tc -> tyConFamilySize tc
 425                 PolyAlt   -> 0
 426 \end{code}
 427
 428
 429 HWL comment on {\em GrAnSim\/}  (adding GRAN_YIELDs for context switch): If
 430 we  do  an inlining of the  case  no separate  functions  for returning are
 431 created, so we don't have to generate a GRAN_YIELD in that case.  This info
 432 must be  propagated  to cgAlgAltRhs (where the  GRAN_YIELD  macro might  be
 433 emitted). Hence, the new Bool arg to cgAlgAltRhs.
 434
 435 %************************************************************************
 436 %*                                                                      *
 437 \subsection[CgCase-alg-alts]{Algebraic alternatives}
 438 %*                                                                      *
 439 %************************************************************************
 440
 441 In @cgAlgAlts@, none of the binders in the alternatives are
 442 assumed to be yet bound.
 443
 444 HWL comment on {\em GrAnSim\/} (adding GRAN_YIELDs for context switch): The
 445 last   arg of  cgAlgAlts  indicates  if we  want  a context   switch at the
 446 beginning of  each alternative. Normally we  want that. The  only exception
 447 are inlined alternatives.
 448
 449 \begin{code}
 450 cgAlgAlts :: GCFlag
 451        -> Maybe VirtualSpOffset
 452        -> AltType                               --  ** AlgAlt or PolyAlt only **
 453        -> [StgAlt]                              -- The alternatives
 454        -> FCode ( [(ConTagZ, CgStmts)], -- The branches
 455                   Maybe CgStmts )       -- The default case
 456
 457 cgAlgAlts gc_flag cc_slot alt_type alts
 458   = do alts <- forkAlts [ cgAlgAlt gc_flag cc_slot alt_type alt | alt <- alts]
 459        let
 460             mb_deflt = case alts of -- DEFAULT is always first, if present
 461                          ((DEFAULT,blks) : _) -> Just blks
 462                          other                -> Nothing
 463
 464             branches = [(dataConTagZ con, blks)
 465                        | (DataAlt con, blks) <- alts]
 466        -- in
 467        return (branches, mb_deflt)
 468
 469
 470 cgAlgAlt :: GCFlag
 471          -> Maybe VirtualSpOffset       -- Turgid state
 472          -> AltType                     --  ** AlgAlt or PolyAlt only **
 473          -> StgAlt
 474          -> FCode (AltCon, CgStmts)
 475
 476 cgAlgAlt gc_flag cc_slot alt_type (con, args, use_mask, rhs)
 477   = do  { abs_c <- getCgStmts $ do
 478                 { bind_con_args con args
 479                 ; restoreCurrentCostCentre cc_slot True
 480                 ; maybeAltHeapCheck gc_flag alt_type (cgExpr rhs) }
 481         ; return (con, abs_c) }
 482   where
 483     bind_con_args DEFAULT      args = nopC
 484     bind_con_args (DataAlt dc) args = bindConArgs dc args
 485 \end{code}
 486
 487
 488 %************************************************************************
 489 %*                                                                      *
 490 \subsection[CgCase-prim-alts]{Primitive alternatives}
 491 %*                                                                      *
 492 %************************************************************************
 493
 494 @cgPrimAlts@ generates suitable a @CSwitch@
 495 for dealing with the alternatives of a primitive @case@, given an
 496 addressing mode for the thing to scrutinise.  It also keeps track of
 497 the maximum stack depth encountered down any branch.
 498
 499 As usual, no binders in the alternatives are yet bound.
 500
 501 \begin{code}
 502 cgPrimAlts :: GCFlag
 503            -> AltType   -- Always PrimAlt, but passed to maybeAltHeapCheck
 504            -> CmmReg    -- Scrutinee
 505            -> [StgAlt]  -- Alternatives
 506            -> Code
 507 -- NB: cgPrimAlts emits code that does the case analysis.
 508 -- It's often used in inline situations, rather than to genearte
 509 -- a labelled return point.  That's why its interface is a little
 510 -- different to cgAlgAlts
 511 --
 512 -- INVARIANT: the default binder is already bound
 513 cgPrimAlts gc_flag alt_type scrutinee alts
 514   = do  { tagged_absCs <- forkAlts (map (cgPrimAlt gc_flag alt_type) alts)
 515         ; let ((DEFAULT, deflt_absC) : others) = tagged_absCs   -- There is always a default
 516               alt_absCs = [(lit,rhs) | (LitAlt lit, rhs) <- others]
 517         ; emitLitSwitch (CmmReg scrutinee) alt_absCs deflt_absC }
 518
 519 cgPrimAlt :: GCFlag
 520           -> AltType
 521           -> StgAlt                             -- The alternative
 522           -> FCode (AltCon, CgStmts)    -- Its compiled form
 523
 524 cgPrimAlt gc_flag alt_type (con, [], [], rhs)
 525   = ASSERT( case con of { DEFAULT -> True; LitAlt _ -> True; other -> False } )
 526     do  { abs_c <- getCgStmts (maybeAltHeapCheck gc_flag alt_type (cgExpr rhs))
 527         ; returnFC (con, abs_c) }
 528 \end{code}
 529
 530
 531 %************************************************************************
 532 %*                                                                      *
 533 \subsection[CgCase-tidy]{Code for tidying up prior to an eval}
 534 %*                                                                      *
 535 %************************************************************************
 536
 537 \begin{code}
 538 maybeAltHeapCheck
 539         :: GCFlag
 540         -> AltType      -- PolyAlt, PrimAlt, AlgAlt, but *not* UbxTupAlt
 541         -> Code         -- Continuation
 542         -> Code
 543 maybeAltHeapCheck NoGC        _        code = code
 544 maybeAltHeapCheck GCMayHappen alt_type code = altHeapCheck alt_type code
 545
 546 saveVolatileVarsAndRegs
 547     :: StgLiveVars                    -- Vars which should be made safe
 548     -> FCode (CmmStmts,               -- Assignments to do the saves
 549               EndOfBlockInfo,         -- sequel for the alts
 550               Maybe VirtualSpOffset)  -- Slot for current cost centre
 551
 552 saveVolatileVarsAndRegs vars
 553   = do  { var_saves <- saveVolatileVars vars
 554         ; (maybe_cc_slot, cc_save) <- saveCurrentCostCentre
 555         ; eob_info <- getEndOfBlockInfo
 556         ; returnFC (var_saves `plusStmts` cc_save,
 557                     eob_info,
 558                     maybe_cc_slot) }
 559
 560
 561 saveVolatileVars :: StgLiveVars         -- Vars which should be made safe
 562                  -> FCode CmmStmts      -- Assignments to to the saves
 563
 564 saveVolatileVars vars
 565   = do  { stmts_s <- mapFCs save_it (varSetElems vars)
 566         ; return (foldr plusStmts noStmts stmts_s) }
 567   where
 568     save_it var
 569       = do { v <- getCAddrModeIfVolatile var
 570            ; case v of
 571                 Nothing         -> return noStmts          -- Non-volatile
 572                 Just vol_amode  -> save_var var vol_amode  -- Aha! It's volatile
 573         }
 574
 575     save_var var vol_amode
 576       = do { slot <- allocPrimStack (idCgRep var)
 577            ; rebindToStack var slot
 578            ; sp_rel <- getSpRelOffset slot
 579            ; returnFC (oneStmt (CmmStore sp_rel vol_amode)) }
 580 \end{code}
 581
 582 ---------------------------------------------------------------------------
 583
 584 When we save the current cost centre (which is done for lexical
 585 scoping), we allocate a free stack location, and return (a)~the
 586 virtual offset of the location, to pass on to the alternatives, and
 587 (b)~the assignment to do the save (just as for @saveVolatileVars@).
 588
 589 \begin{code}
 590 saveCurrentCostCentre ::
 591         FCode (Maybe VirtualSpOffset,   -- Where we decide to store it
 592                CmmStmts)                -- Assignment to save it
 593
 594 saveCurrentCostCentre
 595   | not opt_SccProfilingOn
 596   = returnFC (Nothing, noStmts)
 597   | otherwise
 598   = do  { slot <- allocPrimStack PtrArg
 599         ; sp_rel <- getSpRelOffset slot
 600         ; returnFC (Just slot,
 601                     oneStmt (CmmStore sp_rel curCCS)) }
 602
 603 -- Sometimes we don't free the slot containing the cost centre after restoring it
 604 -- (see CgLetNoEscape.cgLetNoEscapeBody).
 605 restoreCurrentCostCentre :: Maybe VirtualSpOffset -> Bool -> Code
 606 restoreCurrentCostCentre Nothing     _freeit = nopC
 607 restoreCurrentCostCentre (Just slot) freeit
 608  = do   { sp_rel <- getSpRelOffset slot
 609         ; whenC freeit (freeStackSlots [slot])
 610         ; stmtC (CmmStore curCCSAddr (CmmLoad sp_rel wordRep)) }
 611 \end{code}
 612