compiler/coreSyn/CoreSyn.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7
   8 -- | CoreSyn holds all the main data types for use by for the Glasgow Haskell Compiler midsection
   9 module CoreSyn (
  10         -- * Main data types
  11         Expr(..), Alt, Bind(..), AltCon(..), Arg, Note(..),
  12         CoreExpr, CoreAlt, CoreBind, CoreArg, CoreBndr,
  13         TaggedExpr, TaggedAlt, TaggedBind, TaggedArg, TaggedBndr(..),
  14
  15         -- ** 'Expr' construction
  16         mkLets, mkLams,
  17         mkApps, mkTyApps, mkVarApps,
  18
  19         mkIntLit, mkIntLitInt,
  20         mkWordLit, mkWordLitWord,
  21         mkCharLit, mkStringLit,
  22         mkFloatLit, mkFloatLitFloat,
  23         mkDoubleLit, mkDoubleLitDouble,
  24
  25         mkConApp, mkTyBind,
  26         varToCoreExpr, varsToCoreExprs,
  27
  28         isTyVar, isId, cmpAltCon, cmpAlt, ltAlt,
  29
  30         -- ** Simple 'Expr' access functions and predicates
  31         bindersOf, bindersOfBinds, rhssOfBind, rhssOfAlts,
  32         collectBinders, collectTyBinders, collectValBinders, collectTyAndValBinders,
  33         collectArgs, coreExprCc, flattenBinds,
  34
  35         isValArg, isTypeArg, valArgCount, valBndrCount, isRuntimeArg, isRuntimeVar,
  36
  37         -- * Unfolding data types
  38         Unfolding(..),  UnfoldingGuidance(..), UnfoldingSource(..),
  39                 -- Abstract everywhere but in CoreUnfold.lhs
  40
  41         -- ** Constructing 'Unfolding's
  42         noUnfolding, evaldUnfolding, mkOtherCon,
  43         unSaturatedOk, needSaturated, boringCxtOk, boringCxtNotOk,
  44
  45         -- ** Predicates and deconstruction on 'Unfolding'
  46         unfoldingTemplate, setUnfoldingTemplate,
  47         maybeUnfoldingTemplate, otherCons, unfoldingArity,
  48         isValueUnfolding, isEvaldUnfolding, isCheapUnfolding,
  49         isExpandableUnfolding, isConLikeUnfolding, isCompulsoryUnfolding,
  50         isInlineRule, isInlineRule_maybe, isClosedUnfolding, hasSomeUnfolding,
  51         isStableUnfolding, canUnfold, neverUnfoldGuidance, isInlineRuleSource,
  52
  53         -- * Strictness
  54         seqExpr, seqExprs, seqUnfolding,
  55
  56         -- * Annotated expression data types
  57         AnnExpr, AnnExpr'(..), AnnBind(..), AnnAlt,
  58
  59         -- ** Operations on annotations
  60         deAnnotate, deAnnotate', deAnnAlt, collectAnnBndrs,
  61
  62         -- * Core rule data types
  63         CoreRule(..),   -- CoreSubst, CoreTidy, CoreFVs, PprCore only
  64         RuleName, IdUnfoldingFun,
  65
  66         -- ** Operations on 'CoreRule's
  67         seqRules, ruleArity, ruleName, ruleIdName, ruleActivation_maybe,
  68         setRuleIdName,
  69         isBuiltinRule, isLocalRule
  70     ) where
  71
  72 #include "HsVersions.h"
  73
  74 import CostCentre
  75 import Var
  76 import Type
  77 import Coercion
  78 import Name
  79 import Literal
  80 import DataCon
  81 import BasicTypes
  82 import FastString
  83 import Outputable
  84 import Util
  85
  86 import Data.Word
  87
  88 infixl 4 `mkApps`, `mkTyApps`, `mkVarApps`
  89 -- Left associative, so that we can say (f `mkTyApps` xs `mkVarApps` ys)
  90 \end{code}
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{The main data types}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 These data types are the heart of the compiler
  99
 100 \begin{code}
 101 infixl 8 `App`  -- App brackets to the left
 102
 103 -- | This is the data type that represents GHCs core intermediate language. Currently
 104 -- GHC uses System FC <http://research.microsoft.com/~simonpj/papers/ext-f/> for this purpose,
 105 -- which is closely related to the simpler and better known System F <http://en.wikipedia.org/wiki/System_F>.
 106 --
 107 -- We get from Haskell source to this Core language in a number of stages:
 108 --
 109 -- 1. The source code is parsed into an abstract syntax tree, which is represented
 110 --    by the data type 'HsExpr.HsExpr' with the names being 'RdrName.RdrNames'
 111 --
 112 -- 2. This syntax tree is /renamed/, which attaches a 'Unique.Unique' to every 'RdrName.RdrName'
 113 --    (yielding a 'Name.Name') to disambiguate identifiers which are lexically identical.
 114 --    For example, this program:
 115 --
 116 -- @
 117 --      f x = let f x = x + 1
 118 --            in f (x - 2)
 119 -- @
 120 --
 121 --    Would be renamed by having 'Unique's attached so it looked something like this:
 122 --
 123 -- @
 124 --      f_1 x_2 = let f_3 x_4 = x_4 + 1
 125 --                in f_3 (x_2 - 2)
 126 -- @
 127 --
 128 -- 3. The resulting syntax tree undergoes type checking (which also deals with instantiating
 129 --    type class arguments) to yield a 'HsExpr.HsExpr' type that has 'Id.Id' as it's names.
 130 --
 131 -- 4. Finally the syntax tree is /desugared/ from the expressive 'HsExpr.HsExpr' type into
 132 --    this 'Expr' type, which has far fewer constructors and hence is easier to perform
 133 --    optimization, analysis and code generation on.
 134 --
 135 -- The type parameter @b@ is for the type of binders in the expression tree.
 136 data Expr b
 137   = Var   Id                            -- ^ Variables
 138   | Lit   Literal                       -- ^ Primitive literals
 139   | App   (Expr b) (Arg b)              -- ^ Applications: note that the argument may be a 'Type'.
 140                                         --
 141                                         -- See "CoreSyn#let_app_invariant" for another invariant
 142   | Lam   b (Expr b)                    -- ^ Lambda abstraction
 143   | Let   (Bind b) (Expr b)             -- ^ Recursive and non recursive @let@s. Operationally
 144                                         -- this corresponds to allocating a thunk for the things
 145                                         -- bound and then executing the sub-expression.
 146                                         --
 147                                         -- #top_level_invariant#
 148                                         -- #letrec_invariant#
 149                                         --
 150                                         -- The right hand sides of all top-level and recursive @let@s
 151                                         -- /must/ be of lifted type (see "Type#type_classification" for
 152                                         -- the meaning of /lifted/ vs. /unlifted/).
 153                                         --
 154                                         -- #let_app_invariant#
 155                                         -- The right hand side of of a non-recursive 'Let' _and_ the argument of an 'App',
 156                                         -- /may/ be of unlifted type, but only if the expression
 157                                         -- is ok-for-speculation.  This means that the let can be floated around
 158                                         -- without difficulty. For example, this is OK:
 159                                         --
 160                                         -- > y::Int# = x +# 1#
 161                                         --
 162                                         -- But this is not, as it may affect termination if the expression is floated out:
 163                                         --
 164                                         -- > y::Int# = fac 4#
 165                                         --
 166                                         -- In this situation you should use @case@ rather than a @let@. The function
 167                                         -- 'CoreUtils.needsCaseBinding' can help you determine which to generate, or
 168                                         -- alternatively use 'MkCore.mkCoreLet' rather than this constructor directly,
 169                                         -- which will generate a @case@ if necessary
 170                                         --
 171                                         -- #type_let#
 172                                         -- We allow a /non-recursive/ let to bind a type variable, thus:
 173                                         --
 174                                         -- > Let (NonRec tv (Type ty)) body
 175                                         --
 176                                         -- This can be very convenient for postponing type substitutions until
 177                                         -- the next run of the simplifier.
 178                                         --
 179                                         -- At the moment, the rest of the compiler only deals with type-let
 180                                         -- in a Let expression, rather than at top level.  We may want to revist
 181                                         -- this choice.
 182   | Case  (Expr b) b Type [Alt b]       -- ^ Case split. Operationally this corresponds to evaluating
 183                                         -- the scrutinee (expression examined) to weak head normal form
 184                                         -- and then examining at most one level of resulting constructor (i.e. you
 185                                         -- cannot do nested pattern matching directly with this).
 186                                         --
 187                                         -- The binder gets bound to the value of the scrutinee,
 188                                         -- and the 'Type' must be that of all the case alternatives
 189                                         --
 190                                         -- #case_invariants#
 191                                         -- This is one of the more complicated elements of the Core language, and comes
 192                                         -- with a number of restrictions:
 193                                         --
 194                                         -- The 'DEFAULT' case alternative must be first in the list, if it occurs at all.
 195                                         --
 196                                         -- The remaining cases are in order of increasing
 197                                         --      tag     (for 'DataAlts') or
 198                                         --      lit     (for 'LitAlts').
 199                                         -- This makes finding the relevant constructor easy, and makes comparison easier too.
 200                                         --
 201                                         -- The list of alternatives must be exhaustive. An /exhaustive/ case
 202                                         -- does not necessarily mention all constructors:
 203                                         --
 204                                         -- @
 205                                         --      data Foo = Red | Green | Blue
 206                                         -- ... case x of
 207                                         --      Red   -> True
 208                                         --      other -> f (case x of
 209                                         --                      Green -> ...
 210                                         --                      Blue  -> ... ) ...
 211                                         -- @
 212                                         --
 213                                         -- The inner case does not need a @Red@ alternative, because @x@ can't be @Red@ at
 214                                         -- that program point.
 215   | Cast  (Expr b) Coercion             -- ^ Cast an expression to a particular type. This is used to implement @newtype@s
 216                                         -- (a @newtype@ constructor or destructor just becomes a 'Cast' in Core) and GADTs.
 217   | Note  Note (Expr b)                 -- ^ Notes. These allow general information to be
 218                                         -- added to expressions in the syntax tree
 219   | Type  Type                          -- ^ A type: this should only show up at the top
 220                                         -- level of an Arg
 221
 222 -- | Type synonym for expressions that occur in function argument positions.
 223 -- Only 'Arg' should contain a 'Type' at top level, general 'Expr' should not
 224 type Arg b = Expr b
 225
 226 -- | A case split alternative. Consists of the constructor leading to the alternative,
 227 -- the variables bound from the constructor, and the expression to be executed given that binding.
 228 -- The default alternative is @(DEFAULT, [], rhs)@
 229 type Alt b = (AltCon, [b], Expr b)
 230
 231 -- | A case alternative constructor (i.e. pattern match)
 232 data AltCon = DataAlt DataCon   -- ^ A plain data constructor: @case e of { Foo x -> ... }@.
 233                                 -- Invariant: the 'DataCon' is always from a @data@ type, and never from a @newtype@
 234             | LitAlt  Literal   -- ^ A literal: @case e of { 1 -> ... }@
 235             | DEFAULT           -- ^ Trivial alternative: @case e of { _ -> ... }@
 236          deriving (Eq, Ord)
 237
 238 -- | Binding, used for top level bindings in a module and local bindings in a @let@.
 239 data Bind b = NonRec b (Expr b)
 240             | Rec [(b, (Expr b))]
 241 \end{code}
 242
 243 -------------------------- CoreSyn INVARIANTS ---------------------------
 244
 245 Note [CoreSyn top-level invariant]
 246 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 247 See #toplevel_invariant#
 248
 249 Note [CoreSyn letrec invariant]
 250 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 251 See #letrec_invariant#
 252
 253 Note [CoreSyn let/app invariant]
 254 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 255 See #let_app_invariant#
 256
 257 This is intially enforced by DsUtils.mkCoreLet and mkCoreApp
 258
 259 Note [CoreSyn case invariants]
 260 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 261 See #case_invariants#
 262
 263 Note [CoreSyn let goal]
 264 ~~~~~~~~~~~~~~~~~~~~~~~
 265 * The simplifier tries to ensure that if the RHS of a let is a constructor
 266   application, its arguments are trivial, so that the constructor can be
 267   inlined vigorously.
 268
 269
 270 Note [Type let]
 271 ~~~~~~~~~~~~~~~
 272 See #type_let#
 273
 274 \begin{code}
 275
 276 -- | Allows attaching extra information to points in expressions rather than e.g. identifiers.
 277 data Note
 278   = SCC CostCentre      -- ^ A cost centre annotation for profiling
 279   | CoreNote String     -- ^ A generic core annotation, propagated but not used by GHC
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285 \subsection{Transformation rules}
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 The CoreRule type and its friends are dealt with mainly in CoreRules,
 290 but CoreFVs, Subst, PprCore, CoreTidy also inspect the representation.
 291
 292 \begin{code}
 293 -- | A 'CoreRule' is:
 294 --
 295 -- * \"Local\" if the function it is a rule for is defined in the
 296 --   same module as the rule itself.
 297 --
 298 -- * \"Orphan\" if nothing on the LHS is defined in the same module
 299 --   as the rule itself
 300 data CoreRule
 301   = Rule {
 302         ru_name :: RuleName,            -- ^ Name of the rule, for communication with the user
 303         ru_act  :: Activation,          -- ^ When the rule is active
 304
 305         -- Rough-matching stuff
 306         -- see comments with InstEnv.Instance( is_cls, is_rough )
 307         ru_fn    :: Name,               -- ^ Name of the 'Id.Id' at the head of this rule
 308         ru_rough :: [Maybe Name],       -- ^ Name at the head of each argument to the left hand side
 309
 310         -- Proper-matching stuff
 311         -- see comments with InstEnv.Instance( is_tvs, is_tys )
 312         ru_bndrs :: [CoreBndr],         -- ^ Variables quantified over
 313         ru_args  :: [CoreExpr],         -- ^ Left hand side arguments
 314
 315         -- And the right-hand side
 316         ru_rhs   :: CoreExpr,           -- ^ Right hand side of the rule
 317                                         -- Occurrence info is guaranteed correct
 318                                         -- See Note [OccInfo in unfoldings and rules]
 319
 320         -- Locality
 321         ru_local :: Bool        -- ^ @True@ iff the fn at the head of the rule is
 322                                 -- defined in the same module as the rule
 323                                 -- and is not an implicit 'Id' (like a record selector,
 324                                 -- class operation, or data constructor)
 325
 326                 -- NB: ru_local is *not* used to decide orphan-hood
 327                 --      c.g. MkIface.coreRuleToIfaceRule
 328     }
 329
 330   -- | Built-in rules are used for constant folding
 331   -- and suchlike.  They have no free variables.
 332   | BuiltinRule {
 333         ru_name  :: RuleName,   -- ^ As above
 334         ru_fn    :: Name,       -- ^ As above
 335         ru_nargs :: Int,        -- ^ Number of arguments that 'ru_try' consumes,
 336                                 -- if it fires, including type arguments
 337         ru_try  :: IdUnfoldingFun -> [CoreExpr] -> Maybe CoreExpr
 338                 -- ^ This function does the rewrite.  It given too many
 339                 -- arguments, it simply discards them; the returned 'CoreExpr'
 340                 -- is just the rewrite of 'ru_fn' applied to the first 'ru_nargs' args
 341     }
 342                 -- See Note [Extra args in rule matching] in Rules.lhs
 343
 344 type IdUnfoldingFun = Id -> Unfolding
 345 -- A function that embodies how to unfold an Id if you need
 346 -- to do that in the Rule.  The reason we need to pass this info in
 347 -- is that whether an Id is unfoldable depends on the simplifier phase
 348
 349 isBuiltinRule :: CoreRule -> Bool
 350 isBuiltinRule (BuiltinRule {}) = True
 351 isBuiltinRule _                = False
 352
 353 -- | The number of arguments the 'ru_fn' must be applied
 354 -- to before the rule can match on it
 355 ruleArity :: CoreRule -> Int
 356 ruleArity (BuiltinRule {ru_nargs = n}) = n
 357 ruleArity (Rule {ru_args = args})      = length args
 358
 359 ruleName :: CoreRule -> RuleName
 360 ruleName = ru_name
 361
 362 ruleActivation_maybe :: CoreRule -> Maybe Activation
 363 ruleActivation_maybe (BuiltinRule { })       = Nothing
 364 ruleActivation_maybe (Rule { ru_act = act }) = Just act
 365
 366 -- | The 'Name' of the 'Id.Id' at the head of the rule left hand side
 367 ruleIdName :: CoreRule -> Name
 368 ruleIdName = ru_fn
 369
 370 isLocalRule :: CoreRule -> Bool
 371 isLocalRule = ru_local
 372
 373 -- | Set the 'Name' of the 'Id.Id' at the head of the rule left hand side
 374 setRuleIdName :: Name -> CoreRule -> CoreRule
 375 setRuleIdName nm ru = ru { ru_fn = nm }
 376 \end{code}
 377
 378
 379 %************************************************************************
 380 %*                                                                      *
 381                 Unfoldings
 382 %*                                                                      *
 383 %************************************************************************
 384
 385 The @Unfolding@ type is declared here to avoid numerous loops
 386
 387 \begin{code}
 388 -- | Records the /unfolding/ of an identifier, which is approximately the form the
 389 -- identifier would have if we substituted its definition in for the identifier.
 390 -- This type should be treated as abstract everywhere except in "CoreUnfold"
 391 data Unfolding
 392   = NoUnfolding        -- ^ We have no information about the unfolding
 393
 394   | OtherCon [AltCon]  -- ^ It ain't one of these constructors.
 395                        -- @OtherCon xs@ also indicates that something has been evaluated
 396                        -- and hence there's no point in re-evaluating it.
 397                        -- @OtherCon []@ is used even for non-data-type values
 398                        -- to indicated evaluated-ness.  Notably:
 399                        --
 400                        -- > data C = C !(Int -> Int)
 401                        -- > case x of { C f -> ... }
 402                        --
 403                        -- Here, @f@ gets an @OtherCon []@ unfolding.
 404
 405   | DFunUnfolding DataCon [CoreExpr]
 406                         -- The Unfolding of a DFunId
 407                         --     df = /\a1..am. \d1..dn. MkD (op1 a1..am d1..dn)
 408                         --                                 (op2 a1..am d1..dn)
 409                         -- where Arity = n, the number of dict args to the dfun
 410                         -- The [CoreExpr] are the superclasses and methods [op1,op2],
 411                         -- in positional order.
 412                         -- They are usually variables, but can be trivial expressions
 413                         -- instead (e.g. a type application).
 414
 415   | CoreUnfolding {             -- An unfolding for an Id with no pragma, or perhaps a NOINLINE pragma
 416                                 -- (For NOINLINE, the phase, if any, is in the InlinePragInfo for this Id.)
 417         uf_tmpl       :: CoreExpr,        -- Template; occurrence info is correct
 418         uf_src        :: UnfoldingSource, -- Where the unfolding came from
 419         uf_is_top     :: Bool,          -- True <=> top level binding
 420         uf_arity      :: Arity,         -- Number of value arguments expected
 421         uf_is_value   :: Bool,          -- exprIsHNF template (cached); it is ok to discard a `seq` on
 422                                         --      this variable
 423         uf_is_conlike :: Bool,          -- True <=> application of constructor or CONLIKE function
 424                                         --      Cached version of exprIsConLike
 425         uf_is_cheap   :: Bool,          -- True <=> doesn't waste (much) work to expand inside an inlining
 426                                         --      Cached version of exprIsCheap
 427         uf_expandable :: Bool,          -- True <=> can expand in RULE matching
 428                                         --      Cached version of exprIsExpandable
 429         uf_guidance   :: UnfoldingGuidance      -- Tells about the *size* of the template.
 430     }
 431   -- ^ An unfolding with redundant cached information. Parameters:
 432   --
 433   --  uf_tmpl: Template used to perform unfolding;
 434   --           NB: Occurrence info is guaranteed correct:
 435   --               see Note [OccInfo in unfoldings and rules]
 436   --
 437   --  uf_is_top: Is this a top level binding?
 438   --
 439   --  uf_is_value: 'exprIsHNF' template (cached); it is ok to discard a 'seq' on
 440   --     this variable
 441   --
 442   --  uf_is_cheap:  Does this waste only a little work if we expand it inside an inlining?
 443   --     Basically this is a cached version of 'exprIsCheap'
 444   --
 445   --  uf_guidance:  Tells us about the /size/ of the unfolding template
 446
 447 ------------------------------------------------
 448 data UnfoldingSource
 449   = InlineCompulsory   -- Something that *has* no binding, so you *must* inline it
 450                        -- Only a few primop-like things have this property
 451                        -- (see MkId.lhs, calls to mkCompulsoryUnfolding).
 452                        -- Inline absolutely always, however boring the context.
 453
 454   | InlineRule         -- From an {-# INLINE #-} pragma; See Note [InlineRules]
 455
 456   | InlineWrapper Id   -- This unfolding is a the wrapper in a
 457                        --     worker/wrapper split from the strictness analyser
 458                        -- The Id is the worker-id
 459                        -- Used to abbreviate the uf_tmpl in interface files
 460                        --       which don't need to contain the RHS;
 461                        --       it can be derived from the strictness info
 462
 463   | InlineRhs          -- The current rhs of the function
 464
 465    -- For InlineRhs, the uf_tmpl is replaced each time around
 466    -- For all the others we leave uf_tmpl alone
 467
 468
 469 -- | 'UnfoldingGuidance' says when unfolding should take place
 470 data UnfoldingGuidance
 471   = UnfWhen {   -- Inline without thinking about the *size* of the uf_tmpl
 472                 -- Used (a) for small *and* cheap unfoldings
 473                 --      (b) for INLINE functions
 474                 -- See Note [INLINE for small functions] in CoreUnfold
 475       ug_unsat_ok  :: Bool,     -- True <=> ok to inline even if unsaturated
 476       ug_boring_ok :: Bool      -- True <=> ok to inline even if the context is boring
 477     }
 478
 479   | UnfIfGoodArgs {     -- Arose from a normal Id; the info here is the
 480                         -- result of a simple analysis of the RHS
 481
 482       ug_args ::  [Int],  -- Discount if the argument is evaluated.
 483                           -- (i.e., a simplification will definitely
 484                           -- be possible).  One elt of the list per *value* arg.
 485
 486       ug_size :: Int,     -- The "size" of the unfolding.
 487
 488       ug_res :: Int       -- Scrutinee discount: the discount to substract if the thing is in
 489     }                     -- a context (case (thing args) of ...),
 490                           -- (where there are the right number of arguments.)
 491
 492   | UnfNever        -- The RHS is big, so don't inline it
 493
 494 -- Constants for the UnfWhen constructor
 495 needSaturated, unSaturatedOk :: Bool
 496 needSaturated = False
 497 unSaturatedOk = True
 498
 499 boringCxtNotOk, boringCxtOk :: Bool
 500 boringCxtOk    = True
 501 boringCxtNotOk = False
 502
 503 ------------------------------------------------
 504 noUnfolding :: Unfolding
 505 -- ^ There is no known 'Unfolding'
 506 evaldUnfolding :: Unfolding
 507 -- ^ This unfolding marks the associated thing as being evaluated
 508
 509 noUnfolding    = NoUnfolding
 510 evaldUnfolding = OtherCon []
 511
 512 mkOtherCon :: [AltCon] -> Unfolding
 513 mkOtherCon = OtherCon
 514
 515 seqUnfolding :: Unfolding -> ()
 516 seqUnfolding (CoreUnfolding { uf_tmpl = e, uf_is_top = top,
 517                 uf_is_value = b1, uf_is_cheap = b2,
 518                 uf_expandable = b3, uf_is_conlike = b4,
 519                 uf_arity = a, uf_guidance = g})
 520   = seqExpr e `seq` top `seq` b1 `seq` a `seq` b2 `seq` b3 `seq` b4 `seq` seqGuidance g
 521
 522 seqUnfolding _ = ()
 523
 524 seqGuidance :: UnfoldingGuidance -> ()
 525 seqGuidance (UnfIfGoodArgs ns n b) = n `seq` sum ns `seq` b `seq` ()
 526 seqGuidance _                      = ()
 527 \end{code}
 528
 529 \begin{code}
 530 isInlineRuleSource :: UnfoldingSource -> Bool
 531 isInlineRuleSource InlineCompulsory   = True
 532 isInlineRuleSource InlineRule         = True
 533 isInlineRuleSource (InlineWrapper {}) = True
 534 isInlineRuleSource InlineRhs          = False
 535
 536 -- | Retrieves the template of an unfolding: panics if none is known
 537 unfoldingTemplate :: Unfolding -> CoreExpr
 538 unfoldingTemplate = uf_tmpl
 539
 540 setUnfoldingTemplate :: Unfolding -> CoreExpr -> Unfolding
 541 setUnfoldingTemplate unf rhs = unf { uf_tmpl = rhs }
 542
 543 -- | Retrieves the template of an unfolding if possible
 544 maybeUnfoldingTemplate :: Unfolding -> Maybe CoreExpr
 545 maybeUnfoldingTemplate (CoreUnfolding { uf_tmpl = expr })       = Just expr
 546 maybeUnfoldingTemplate _                                        = Nothing
 547
 548 -- | The constructors that the unfolding could never be:
 549 -- returns @[]@ if no information is available
 550 otherCons :: Unfolding -> [AltCon]
 551 otherCons (OtherCon cons) = cons
 552 otherCons _               = []
 553
 554 -- | Determines if it is certainly the case that the unfolding will
 555 -- yield a value (something in HNF): returns @False@ if unsure
 556 isValueUnfolding :: Unfolding -> Bool
 557         -- Returns False for OtherCon
 558 isValueUnfolding (CoreUnfolding { uf_is_value = is_evald }) = is_evald
 559 isValueUnfolding _                                          = False
 560
 561 -- | Determines if it possibly the case that the unfolding will
 562 -- yield a value. Unlike 'isValueUnfolding' it returns @True@
 563 -- for 'OtherCon'
 564 isEvaldUnfolding :: Unfolding -> Bool
 565         -- Returns True for OtherCon
 566 isEvaldUnfolding (OtherCon _)                               = True
 567 isEvaldUnfolding (CoreUnfolding { uf_is_value = is_evald }) = is_evald
 568 isEvaldUnfolding _                                          = False
 569
 570 -- | @True@ if the unfolding is a constructor application, the application
 571 -- of a CONLIKE function or 'OtherCon'
 572 isConLikeUnfolding :: Unfolding -> Bool
 573 isConLikeUnfolding (OtherCon _)                             = True
 574 isConLikeUnfolding (CoreUnfolding { uf_is_conlike = con })  = con
 575 isConLikeUnfolding _                                        = False
 576
 577 -- | Is the thing we will unfold into certainly cheap?
 578 isCheapUnfolding :: Unfolding -> Bool
 579 isCheapUnfolding (CoreUnfolding { uf_is_cheap = is_cheap }) = is_cheap
 580 isCheapUnfolding _                                          = False
 581
 582 isExpandableUnfolding :: Unfolding -> Bool
 583 isExpandableUnfolding (CoreUnfolding { uf_expandable = is_expable }) = is_expable
 584 isExpandableUnfolding _                                              = False
 585
 586 isInlineRule :: Unfolding -> Bool
 587 isInlineRule (CoreUnfolding { uf_src = src }) = isInlineRuleSource src
 588 isInlineRule _                                = False
 589
 590 isInlineRule_maybe :: Unfolding -> Maybe (UnfoldingSource, Bool)
 591 isInlineRule_maybe (CoreUnfolding { uf_src = src, uf_guidance = guide })
 592    | isInlineRuleSource src
 593    = Just (src, unsat_ok)
 594    where
 595      unsat_ok = case guide of
 596                   UnfWhen unsat_ok _ -> unsat_ok
 597                   _                  -> needSaturated
 598 isInlineRule_maybe _ = Nothing
 599
 600 isCompulsoryUnfolding :: Unfolding -> Bool
 601 isCompulsoryUnfolding (CoreUnfolding { uf_src = InlineCompulsory }) = True
 602 isCompulsoryUnfolding _                                             = False
 603
 604 isStableUnfolding :: Unfolding -> Bool
 605 -- True of unfoldings that should not be overwritten
 606 -- by a CoreUnfolding for the RHS of a let-binding
 607 isStableUnfolding (CoreUnfolding { uf_src = src }) = isInlineRuleSource src
 608 isStableUnfolding (DFunUnfolding {})               = True
 609 isStableUnfolding _                                = False
 610
 611 unfoldingArity :: Unfolding -> Arity
 612 unfoldingArity (CoreUnfolding { uf_arity = arity }) = arity
 613 unfoldingArity _                                    = panic "unfoldingArity"
 614
 615 isClosedUnfolding :: Unfolding -> Bool          -- No free variables
 616 isClosedUnfolding (CoreUnfolding {}) = False
 617 isClosedUnfolding _                  = True
 618
 619 -- | Only returns False if there is no unfolding information available at all
 620 hasSomeUnfolding :: Unfolding -> Bool
 621 hasSomeUnfolding NoUnfolding = False
 622 hasSomeUnfolding _           = True
 623
 624 neverUnfoldGuidance :: UnfoldingGuidance -> Bool
 625 neverUnfoldGuidance UnfNever = True
 626 neverUnfoldGuidance _        = False
 627
 628 canUnfold :: Unfolding -> Bool
 629 canUnfold (CoreUnfolding { uf_guidance = g }) = not (neverUnfoldGuidance g)
 630 canUnfold _                                   = False
 631 \end{code}
 632
 633 Note [InlineRules]
 634 ~~~~~~~~~~~~~~~~~
 635 When you say
 636       {-# INLINE f #-}
 637       f x = <rhs>
 638 you intend that calls (f e) are replaced by <rhs>[e/x] So we
 639 should capture (\x.<rhs>) in the Unfolding of 'f', and never meddle
 640 with it.  Meanwhile, we can optimise <rhs> to our heart's content,
 641 leaving the original unfolding intact in Unfolding of 'f'.
 642
 643 So the representation of an Unfolding has changed quite a bit
 644 (see CoreSyn).  An INLINE pragma gives rise to an InlineRule
 645 unfolding.
 646
 647 Moreover, it's only used when 'f' is applied to the
 648 specified number of arguments; that is, the number of argument on
 649 the LHS of the '=' sign in the original source definition.
 650 For example, (.) is now defined in the libraries like this
 651    {-# INLINE (.) #-}
 652    (.) f g = \x -> f (g x)
 653 so that it'll inline when applied to two arguments. If 'x' appeared
 654 on the left, thus
 655    (.) f g x = f (g x)
 656 it'd only inline when applied to three arguments.  This slightly-experimental
 657 change was requested by Roman, but it seems to make sense.
 658
 659 See also Note [Inlining an InlineRule] in CoreUnfold.
 660
 661
 662 Note [OccInfo in unfoldings and rules]
 663 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 664 In unfoldings and rules, we guarantee that the template is occ-analysed,
 665 so that the occurence info on the binders is correct.  This is important,
 666 because the Simplifier does not re-analyse the template when using it. If
 667 the occurrence info is wrong
 668   - We may get more simpifier iterations than necessary, because
 669     once-occ info isn't there
 670   - More seriously, we may get an infinite loop if there's a Rec
 671     without a loop breaker marked
 672
 673
 674 %************************************************************************
 675 %*                                                                      *
 676 \subsection{The main data type}
 677 %*                                                                      *
 678 %************************************************************************
 679
 680 \begin{code}
 681 -- The Ord is needed for the FiniteMap used in the lookForConstructor
 682 -- in SimplEnv.  If you declared that lookForConstructor *ignores*
 683 -- constructor-applications with LitArg args, then you could get
 684 -- rid of this Ord.
 685
 686 instance Outputable AltCon where
 687   ppr (DataAlt dc) = ppr dc
 688   ppr (LitAlt lit) = ppr lit
 689   ppr DEFAULT      = ptext (sLit "__DEFAULT")
 690
 691 instance Show AltCon where
 692   showsPrec p con = showsPrecSDoc p (ppr con)
 693
 694 cmpAlt :: Alt b -> Alt b -> Ordering
 695 cmpAlt (con1, _, _) (con2, _, _) = con1 `cmpAltCon` con2
 696
 697 ltAlt :: Alt b -> Alt b -> Bool
 698 ltAlt a1 a2 = (a1 `cmpAlt` a2) == LT
 699
 700 cmpAltCon :: AltCon -> AltCon -> Ordering
 701 -- ^ Compares 'AltCon's within a single list of alternatives
 702 cmpAltCon DEFAULT      DEFAULT     = EQ
 703 cmpAltCon DEFAULT      _           = LT
 704
 705 cmpAltCon (DataAlt d1) (DataAlt d2) = dataConTag d1 `compare` dataConTag d2
 706 cmpAltCon (DataAlt _)  DEFAULT      = GT
 707 cmpAltCon (LitAlt  l1) (LitAlt  l2) = l1 `compare` l2
 708 cmpAltCon (LitAlt _)   DEFAULT      = GT
 709
 710 cmpAltCon con1 con2 = WARN( True, text "Comparing incomparable AltCons" <+>
 711                                   ppr con1 <+> ppr con2 )
 712                       LT
 713 \end{code}
 714
 715 %************************************************************************
 716 %*                                                                      *
 717 \subsection{Useful synonyms}
 718 %*                                                                      *
 719 %************************************************************************
 720
 721 \begin{code}
 722 -- | The common case for the type of binders and variables when
 723 -- we are manipulating the Core language within GHC
 724 type CoreBndr = Var
 725 -- | Expressions where binders are 'CoreBndr's
 726 type CoreExpr = Expr CoreBndr
 727 -- | Argument expressions where binders are 'CoreBndr's
 728 type CoreArg  = Arg  CoreBndr
 729 -- | Binding groups where binders are 'CoreBndr's
 730 type CoreBind = Bind CoreBndr
 731 -- | Case alternatives where binders are 'CoreBndr's
 732 type CoreAlt  = Alt  CoreBndr
 733 \end{code}
 734
 735 %************************************************************************
 736 %*                                                                      *
 737 \subsection{Tagging}
 738 %*                                                                      *
 739 %************************************************************************
 740
 741 \begin{code}
 742 -- | Binders are /tagged/ with a t
 743 data TaggedBndr t = TB CoreBndr t       -- TB for "tagged binder"
 744
 745 type TaggedBind t = Bind (TaggedBndr t)
 746 type TaggedExpr t = Expr (TaggedBndr t)
 747 type TaggedArg  t = Arg  (TaggedBndr t)
 748 type TaggedAlt  t = Alt  (TaggedBndr t)
 749
 750 instance Outputable b => Outputable (TaggedBndr b) where
 751   ppr (TB b l) = char '<' <> ppr b <> comma <> ppr l <> char '>'
 752
 753 instance Outputable b => OutputableBndr (TaggedBndr b) where
 754   pprBndr _ b = ppr b   -- Simple
 755 \end{code}
 756
 757
 758 %************************************************************************
 759 %*                                                                      *
 760 \subsection{Core-constructing functions with checking}
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 \begin{code}
 765 -- | Apply a list of argument expressions to a function expression in a nested fashion. Prefer to
 766 -- use 'CoreUtils.mkCoreApps' if possible
 767 mkApps    :: Expr b -> [Arg b]  -> Expr b
 768 -- | Apply a list of type argument expressions to a function expression in a nested fashion
 769 mkTyApps  :: Expr b -> [Type]   -> Expr b
 770 -- | Apply a list of type or value variables to a function expression in a nested fashion
 771 mkVarApps :: Expr b -> [Var] -> Expr b
 772 -- | Apply a list of argument expressions to a data constructor in a nested fashion. Prefer to
 773 -- use 'MkCore.mkCoreConApps' if possible
 774 mkConApp      :: DataCon -> [Arg b] -> Expr b
 775
 776 mkApps    f args = foldl App                       f args
 777 mkTyApps  f args = foldl (\ e a -> App e (Type a)) f args
 778 mkVarApps f vars = foldl (\ e a -> App e (varToCoreExpr a)) f vars
 779 mkConApp con args = mkApps (Var (dataConWorkId con)) args
 780
 781
 782 -- | Create a machine integer literal expression of type @Int#@ from an @Integer@.
 783 -- If you want an expression of type @Int@ use 'MkCore.mkIntExpr'
 784 mkIntLit      :: Integer -> Expr b
 785 -- | Create a machine integer literal expression of type @Int#@ from an @Int@.
 786 -- If you want an expression of type @Int@ use 'MkCore.mkIntExpr'
 787 mkIntLitInt   :: Int     -> Expr b
 788
 789 mkIntLit    n = Lit (mkMachInt n)
 790 mkIntLitInt n = Lit (mkMachInt (toInteger n))
 791
 792 -- | Create a machine word literal expression of type  @Word#@ from an @Integer@.
 793 -- If you want an expression of type @Word@ use 'MkCore.mkWordExpr'
 794 mkWordLit     :: Integer -> Expr b
 795 -- | Create a machine word literal expression of type  @Word#@ from a @Word@.
 796 -- If you want an expression of type @Word@ use 'MkCore.mkWordExpr'
 797 mkWordLitWord :: Word -> Expr b
 798
 799 mkWordLit     w = Lit (mkMachWord w)
 800 mkWordLitWord w = Lit (mkMachWord (toInteger w))
 801
 802 -- | Create a machine character literal expression of type @Char#@.
 803 -- If you want an expression of type @Char@ use 'MkCore.mkCharExpr'
 804 mkCharLit :: Char -> Expr b
 805 -- | Create a machine string literal expression of type @Addr#@.
 806 -- If you want an expression of type @String@ use 'MkCore.mkStringExpr'
 807 mkStringLit :: String -> Expr b
 808
 809 mkCharLit   c = Lit (mkMachChar c)
 810 mkStringLit s = Lit (mkMachString s)
 811
 812 -- | Create a machine single precision literal expression of type @Float#@ from a @Rational@.
 813 -- If you want an expression of type @Float@ use 'MkCore.mkFloatExpr'
 814 mkFloatLit :: Rational -> Expr b
 815 -- | Create a machine single precision literal expression of type @Float#@ from a @Float@.
 816 -- If you want an expression of type @Float@ use 'MkCore.mkFloatExpr'
 817 mkFloatLitFloat :: Float -> Expr b
 818
 819 mkFloatLit      f = Lit (mkMachFloat f)
 820 mkFloatLitFloat f = Lit (mkMachFloat (toRational f))
 821
 822 -- | Create a machine double precision literal expression of type @Double#@ from a @Rational@.
 823 -- If you want an expression of type @Double@ use 'MkCore.mkDoubleExpr'
 824 mkDoubleLit :: Rational -> Expr b
 825 -- | Create a machine double precision literal expression of type @Double#@ from a @Double@.
 826 -- If you want an expression of type @Double@ use 'MkCore.mkDoubleExpr'
 827 mkDoubleLitDouble :: Double -> Expr b
 828
 829 mkDoubleLit       d = Lit (mkMachDouble d)
 830 mkDoubleLitDouble d = Lit (mkMachDouble (toRational d))
 831
 832 -- | Bind all supplied binding groups over an expression in a nested let expression. Prefer to
 833 -- use 'CoreUtils.mkCoreLets' if possible
 834 mkLets        :: [Bind b] -> Expr b -> Expr b
 835 -- | Bind all supplied binders over an expression in a nested lambda expression. Prefer to
 836 -- use 'CoreUtils.mkCoreLams' if possible
 837 mkLams        :: [b] -> Expr b -> Expr b
 838
 839 mkLams binders body = foldr Lam body binders
 840 mkLets binds body   = foldr Let body binds
 841
 842
 843 -- | Create a binding group where a type variable is bound to a type. Per "CoreSyn#type_let",
 844 -- this can only be used to bind something in a non-recursive @let@ expression
 845 mkTyBind :: TyVar -> Type -> CoreBind
 846 mkTyBind tv ty      = NonRec tv (Type ty)
 847
 848 -- | Convert a binder into either a 'Var' or 'Type' 'Expr' appropriately
 849 varToCoreExpr :: CoreBndr -> Expr b
 850 varToCoreExpr v | isId v = Var v
 851                 | otherwise = Type (mkTyVarTy v)
 852
 853 varsToCoreExprs :: [CoreBndr] -> [Expr b]
 854 varsToCoreExprs vs = map varToCoreExpr vs
 855 \end{code}
 856
 857
 858 %************************************************************************
 859 %*                                                                      *
 860 \subsection{Simple access functions}
 861 %*                                                                      *
 862 %************************************************************************
 863
 864 \begin{code}
 865 -- | Extract every variable by this group
 866 bindersOf  :: Bind b -> [b]
 867 bindersOf (NonRec binder _) = [binder]
 868 bindersOf (Rec pairs)       = [binder | (binder, _) <- pairs]
 869
 870 -- | 'bindersOf' applied to a list of binding groups
 871 bindersOfBinds :: [Bind b] -> [b]
 872 bindersOfBinds binds = foldr ((++) . bindersOf) [] binds
 873
 874 rhssOfBind :: Bind b -> [Expr b]
 875 rhssOfBind (NonRec _ rhs) = [rhs]
 876 rhssOfBind (Rec pairs)    = [rhs | (_,rhs) <- pairs]
 877
 878 rhssOfAlts :: [Alt b] -> [Expr b]
 879 rhssOfAlts alts = [e | (_,_,e) <- alts]
 880
 881 -- | Collapse all the bindings in the supplied groups into a single
 882 -- list of lhs\/rhs pairs suitable for binding in a 'Rec' binding group
 883 flattenBinds :: [Bind b] -> [(b, Expr b)]
 884 flattenBinds (NonRec b r : binds) = (b,r) : flattenBinds binds
 885 flattenBinds (Rec prs1   : binds) = prs1 ++ flattenBinds binds
 886 flattenBinds []                   = []
 887 \end{code}
 888
 889 \begin{code}
 890 -- | We often want to strip off leading lambdas before getting down to
 891 -- business. This function is your friend.
 892 collectBinders               :: Expr b -> ([b],         Expr b)
 893 -- | Collect as many type bindings as possible from the front of a nested lambda
 894 collectTyBinders             :: CoreExpr -> ([TyVar],     CoreExpr)
 895 -- | Collect as many value bindings as possible from the front of a nested lambda
 896 collectValBinders            :: CoreExpr -> ([Id],        CoreExpr)
 897 -- | Collect type binders from the front of the lambda first,
 898 -- then follow up by collecting as many value bindings as possible
 899 -- from the resulting stripped expression
 900 collectTyAndValBinders       :: CoreExpr -> ([TyVar], [Id], CoreExpr)
 901
 902 collectBinders expr
 903   = go [] expr
 904   where
 905     go bs (Lam b e) = go (b:bs) e
 906     go bs e          = (reverse bs, e)
 907
 908 collectTyAndValBinders expr
 909   = (tvs, ids, body)
 910   where
 911     (tvs, body1) = collectTyBinders expr
 912     (ids, body)  = collectValBinders body1
 913
 914 collectTyBinders expr
 915   = go [] expr
 916   where
 917     go tvs (Lam b e) | isTyVar b = go (b:tvs) e
 918     go tvs e                     = (reverse tvs, e)
 919
 920 collectValBinders expr
 921   = go [] expr
 922   where
 923     go ids (Lam b e) | isId b = go (b:ids) e
 924     go ids body               = (reverse ids, body)
 925 \end{code}
 926
 927 \begin{code}
 928 -- | Takes a nested application expression and returns the the function
 929 -- being applied and the arguments to which it is applied
 930 collectArgs :: Expr b -> (Expr b, [Arg b])
 931 collectArgs expr
 932   = go expr []
 933   where
 934     go (App f a) as = go f (a:as)
 935     go e         as = (e, as)
 936 \end{code}
 937
 938 \begin{code}
 939 -- | Gets the cost centre enclosing an expression, if any.
 940 -- It looks inside lambdas because @(scc \"foo\" \\x.e) = \\x. scc \"foo\" e@
 941 coreExprCc :: Expr b -> CostCentre
 942 coreExprCc (Note (SCC cc) _)   = cc
 943 coreExprCc (Note _ e)          = coreExprCc e
 944 coreExprCc (Lam _ e)           = coreExprCc e
 945 coreExprCc _                   = noCostCentre
 946 \end{code}
 947
 948 %************************************************************************
 949 %*                                                                      *
 950 \subsection{Predicates}
 951 %*                                                                      *
 952 %************************************************************************
 953
 954 At one time we optionally carried type arguments through to runtime.
 955 @isRuntimeVar v@ returns if (Lam v _) really becomes a lambda at runtime,
 956 i.e. if type applications are actual lambdas because types are kept around
 957 at runtime.  Similarly isRuntimeArg.
 958
 959 \begin{code}
 960 -- | Will this variable exist at runtime?
 961 isRuntimeVar :: Var -> Bool
 962 isRuntimeVar = isId
 963
 964 -- | Will this argument expression exist at runtime?
 965 isRuntimeArg :: CoreExpr -> Bool
 966 isRuntimeArg = isValArg
 967
 968 -- | Returns @False@ iff the expression is a 'Type' expression at its top level
 969 isValArg :: Expr b -> Bool
 970 isValArg (Type _) = False
 971 isValArg _        = True
 972
 973 -- | Returns @True@ iff the expression is a 'Type' expression at its top level
 974 isTypeArg :: Expr b -> Bool
 975 isTypeArg (Type _) = True
 976 isTypeArg _        = False
 977
 978 -- | The number of binders that bind values rather than types
 979 valBndrCount :: [CoreBndr] -> Int
 980 valBndrCount = count isId
 981
 982 -- | The number of argument expressions that are values rather than types at their top level
 983 valArgCount :: [Arg b] -> Int
 984 valArgCount = count isValArg
 985 \end{code}
 986
 987
 988 %************************************************************************
 989 %*                                                                      *
 990 \subsection{Seq stuff}
 991 %*                                                                      *
 992 %************************************************************************
 993
 994 \begin{code}
 995 seqExpr :: CoreExpr -> ()
 996 seqExpr (Var v)         = v `seq` ()
 997 seqExpr (Lit lit)       = lit `seq` ()
 998 seqExpr (App f a)       = seqExpr f `seq` seqExpr a
 999 seqExpr (Lam b e)       = seqBndr b `seq` seqExpr e
1000 seqExpr (Let b e)       = seqBind b `seq` seqExpr e
1001 seqExpr (Case e b t as) = seqExpr e `seq` seqBndr b `seq` seqType t `seq` seqAlts as
1002 seqExpr (Cast e co)     = seqExpr e `seq` seqType co
1003 seqExpr (Note n e)      = seqNote n `seq` seqExpr e
1004 seqExpr (Type t)        = seqType t
1005
1006 seqExprs :: [CoreExpr] -> ()
1007 seqExprs [] = ()
1008 seqExprs (e:es) = seqExpr e `seq` seqExprs es
1009
1010 seqNote :: Note -> ()
1011 seqNote (CoreNote s)   = s `seq` ()
1012 seqNote _              = ()
1013
1014 seqBndr :: CoreBndr -> ()
1015 seqBndr b = b `seq` ()
1016
1017 seqBndrs :: [CoreBndr] -> ()
1018 seqBndrs [] = ()
1019 seqBndrs (b:bs) = seqBndr b `seq` seqBndrs bs
1020
1021 seqBind :: Bind CoreBndr -> ()
1022 seqBind (NonRec b e) = seqBndr b `seq` seqExpr e
1023 seqBind (Rec prs)    = seqPairs prs
1024
1025 seqPairs :: [(CoreBndr, CoreExpr)] -> ()
1026 seqPairs [] = ()
1027 seqPairs ((b,e):prs) = seqBndr b `seq` seqExpr e `seq` seqPairs prs
1028
1029 seqAlts :: [CoreAlt] -> ()
1030 seqAlts [] = ()
1031 seqAlts ((c,bs,e):alts) = c `seq` seqBndrs bs `seq` seqExpr e `seq` seqAlts alts
1032
1033 seqRules :: [CoreRule] -> ()
1034 seqRules [] = ()
1035 seqRules (Rule { ru_bndrs = bndrs, ru_args = args, ru_rhs = rhs } : rules)
1036   = seqBndrs bndrs `seq` seqExprs (rhs:args) `seq` seqRules rules
1037 seqRules (BuiltinRule {} : rules) = seqRules rules
1038 \end{code}
1039
1040 %************************************************************************
1041 %*                                                                      *
1042 \subsection{Annotated core}
1043 %*                                                                      *
1044 %************************************************************************
1045
1046 \begin{code}
1047 -- | Annotated core: allows annotation at every node in the tree
1048 type AnnExpr bndr annot = (annot, AnnExpr' bndr annot)
1049
1050 -- | A clone of the 'Expr' type but allowing annotation at every tree node
1051 data AnnExpr' bndr annot
1052   = AnnVar      Id
1053   | AnnLit      Literal
1054   | AnnLam      bndr (AnnExpr bndr annot)
1055   | AnnApp      (AnnExpr bndr annot) (AnnExpr bndr annot)
1056   | AnnCase     (AnnExpr bndr annot) bndr Type [AnnAlt bndr annot]
1057   | AnnLet      (AnnBind bndr annot) (AnnExpr bndr annot)
1058   | AnnCast     (AnnExpr bndr annot) Coercion
1059   | AnnNote     Note (AnnExpr bndr annot)
1060   | AnnType     Type
1061
1062 -- | A clone of the 'Alt' type but allowing annotation at every tree node
1063 type AnnAlt bndr annot = (AltCon, [bndr], AnnExpr bndr annot)
1064
1065 -- | A clone of the 'Bind' type but allowing annotation at every tree node
1066 data AnnBind bndr annot
1067   = AnnNonRec bndr (AnnExpr bndr annot)
1068   | AnnRec    [(bndr, AnnExpr bndr annot)]
1069 \end{code}
1070
1071 \begin{code}
1072 deAnnotate :: AnnExpr bndr annot -> Expr bndr
1073 deAnnotate (_, e) = deAnnotate' e
1074
1075 deAnnotate' :: AnnExpr' bndr annot -> Expr bndr
1076 deAnnotate' (AnnType t)           = Type t
1077 deAnnotate' (AnnVar  v)           = Var v
1078 deAnnotate' (AnnLit  lit)         = Lit lit
1079 deAnnotate' (AnnLam  binder body) = Lam binder (deAnnotate body)
1080 deAnnotate' (AnnApp  fun arg)     = App (deAnnotate fun) (deAnnotate arg)
1081 deAnnotate' (AnnCast e co)        = Cast (deAnnotate e) co
1082 deAnnotate' (AnnNote note body)   = Note note (deAnnotate body)
1083
1084 deAnnotate' (AnnLet bind body)
1085   = Let (deAnnBind bind) (deAnnotate body)
1086   where
1087     deAnnBind (AnnNonRec var rhs) = NonRec var (deAnnotate rhs)
1088     deAnnBind (AnnRec pairs) = Rec [(v,deAnnotate rhs) | (v,rhs) <- pairs]
1089
1090 deAnnotate' (AnnCase scrut v t alts)
1091   = Case (deAnnotate scrut) v t (map deAnnAlt alts)
1092
1093 deAnnAlt :: AnnAlt bndr annot -> Alt bndr
1094 deAnnAlt (con,args,rhs) = (con,args,deAnnotate rhs)
1095 \end{code}
1096
1097 \begin{code}
1098 -- | As 'collectBinders' but for 'AnnExpr' rather than 'Expr'
1099 collectAnnBndrs :: AnnExpr bndr annot -> ([bndr], AnnExpr bndr annot)
1100 collectAnnBndrs e
1101   = collect [] e
1102   where
1103     collect bs (_, AnnLam b body) = collect (b:bs) body
1104     collect bs body               = (reverse bs, body)
1105 \end{code}