compiler/coreSyn/CoreUnfold.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1994-1998
   4 %
   5
   6 Core-syntax unfoldings
   7
   8 Unfoldings (which can travel across module boundaries) are in Core
   9 syntax (namely @CoreExpr@s).
  10
  11 The type @Unfolding@ sits ``above'' simply-Core-expressions
  12 unfoldings, capturing ``higher-level'' things we know about a binding,
  13 usually things that the simplifier found out (e.g., ``it's a
  14 literal'').  In the corner of a @CoreUnfolding@ unfolding, you will
  15 find, unsurprisingly, a Core expression.
  16
  17 \begin{code}
  18 module CoreUnfold (
  19         Unfolding, UnfoldingGuidance,   -- Abstract types
  20
  21         noUnfolding, mkImplicitUnfolding,
  22         mkTopUnfolding, mkUnfolding,
  23         mkInlineRule, mkWwInlineRule,
  24         mkCompulsoryUnfolding,
  25
  26         couldBeSmallEnoughToInline,
  27         certainlyWillInline, smallEnoughToInline,
  28
  29         callSiteInline, CallCtxt(..)
  30
  31     ) where
  32
  33 import StaticFlags
  34 import DynFlags
  35 import CoreSyn
  36 import PprCore          ()      -- Instances
  37 import OccurAnal
  38 import CoreSubst        ( emptySubst, substTy, extendIdSubst, extendTvSubst
  39                         , lookupIdSubst, substBndr, substBndrs, substRecBndrs )
  40 import CoreUtils
  41 import Id
  42 import DataCon
  43 import Literal
  44 import PrimOp
  45 import IdInfo
  46 import BasicTypes       ( Arity )
  47 import Type hiding( substTy, extendTvSubst )
  48 import Maybes
  49 import PrelNames
  50 import Bag
  51 import FastTypes
  52 import FastString
  53 import Outputable
  54
  55 \end{code}
  56
  57
  58 %************************************************************************
  59 %*                                                                      *
  60 \subsection{Making unfoldings}
  61 %*                                                                      *
  62 %************************************************************************
  63
  64 \begin{code}
  65 mkTopUnfolding :: CoreExpr -> Unfolding
  66 mkTopUnfolding expr = mkUnfolding True {- Top level -} expr
  67
  68 mkImplicitUnfolding :: CoreExpr -> Unfolding
  69 -- For implicit Ids, do a tiny bit of optimising first
  70 mkImplicitUnfolding expr
  71   = CoreUnfolding (simpleOptExpr expr)
  72                   True
  73                   (exprIsHNF expr)
  74                   (exprIsCheap expr)
  75                   (calcUnfoldingGuidance opt_UF_CreationThreshold expr)
  76
  77 mkInlineRule :: CoreExpr -> Arity -> Unfolding
  78 mkInlineRule expr arity
  79   = InlineRule { uf_tmpl = simpleOptExpr expr,
  80                  uf_is_top = True,       -- Conservative; this gets set more
  81                                          -- accuately by the simplifier (slight hack)
  82                                          -- in SimplEnv.substUnfolding
  83                  uf_arity = arity,
  84                  uf_is_value = exprIsHNF expr,
  85                  uf_worker = Nothing }
  86
  87 mkWwInlineRule :: CoreExpr -> Arity -> Id -> Unfolding
  88 mkWwInlineRule expr arity wkr
  89   = InlineRule { uf_tmpl = simpleOptExpr expr,
  90                  uf_is_top = True,       -- Conservative; see mkInlineRule
  91                  uf_arity = arity,
  92                  uf_is_value = exprIsHNF expr,
  93                  uf_worker = Just wkr }
  94
  95 mkUnfolding :: Bool -> CoreExpr -> Unfolding
  96 mkUnfolding top_lvl expr
  97   = CoreUnfolding { uf_tmpl = occurAnalyseExpr expr,
  98                     uf_is_top = top_lvl,
  99                     uf_is_value = exprIsHNF expr,
 100                     uf_is_cheap = exprIsCheap expr,
 101                     uf_guidance = calcUnfoldingGuidance opt_UF_CreationThreshold expr }
 102         -- Sometimes during simplification, there's a large let-bound thing
 103         -- which has been substituted, and so is now dead; so 'expr' contains
 104         -- two copies of the thing while the occurrence-analysed expression doesn't
 105         -- Nevertheless, we don't occ-analyse before computing the size because the
 106         -- size computation bales out after a while, whereas occurrence analysis does not.
 107         --
 108         -- This can occasionally mean that the guidance is very pessimistic;
 109         -- it gets fixed up next round
 110
 111 mkCompulsoryUnfolding :: CoreExpr -> Unfolding
 112 mkCompulsoryUnfolding expr      -- Used for things that absolutely must be unfolded
 113   = CompulsoryUnfolding (occurAnalyseExpr expr)
 114 \end{code}
 115
 116
 117 %************************************************************************
 118 %*                                                                      *
 119 \subsection{The UnfoldingGuidance type}
 120 %*                                                                      *
 121 %************************************************************************
 122
 123 \begin{code}
 124 calcUnfoldingGuidance
 125         :: Int                  -- bomb out if size gets bigger than this
 126         -> CoreExpr             -- expression to look at
 127         -> UnfoldingGuidance
 128 calcUnfoldingGuidance bOMB_OUT_SIZE expr
 129   = case collectBinders expr of { (binders, body) ->
 130     let
 131         val_binders = filter isId binders
 132         n_val_binders = length val_binders
 133     in
 134     case (sizeExpr (iUnbox bOMB_OUT_SIZE) val_binders body) of
 135       TooBig -> UnfoldNever
 136       SizeIs size cased_args scrut_discount
 137         -> UnfoldIfGoodArgs { ug_arity = n_val_binders
 138                             , ug_args  = map discount_for val_binders
 139                             , ug_size  = iBox size
 140                             , ug_res   = iBox scrut_discount }
 141         where
 142             discount_for b = foldlBag (\acc (b',n) -> if b==b' then acc+n else acc)
 143                                       0 cased_args
 144         }
 145 \end{code}
 146
 147 \begin{code}
 148 sizeExpr :: FastInt         -- Bomb out if it gets bigger than this
 149          -> [Id]            -- Arguments; we're interested in which of these
 150                             -- get case'd
 151          -> CoreExpr
 152          -> ExprSize
 153
 154 sizeExpr bOMB_OUT_SIZE top_args expr
 155   = size_up expr
 156   where
 157     size_up (Type _)           = sizeZero      -- Types cost nothing
 158     size_up (Var _)            = sizeOne
 159     size_up (Note _ body)      = size_up body  -- Notes cost nothing
 160     size_up (Cast e _)         = size_up e
 161     size_up (App fun (Type _)) = size_up fun
 162     size_up (App fun arg)      = size_up_app fun [arg]
 163
 164     size_up (Lit lit)          = sizeN (litSize lit)
 165
 166     size_up (Lam b e) | isId b    = lamScrutDiscount (size_up e `addSizeN` 1)
 167                       | otherwise = size_up e
 168
 169     size_up (Let (NonRec binder rhs) body)
 170       = nukeScrutDiscount (size_up rhs)         `addSize`
 171         size_up body                            `addSizeN`
 172         (if isUnLiftedType (idType binder) then 0 else 1)
 173                 -- For the allocation
 174                 -- If the binder has an unlifted type there is no allocation
 175
 176     size_up (Let (Rec pairs) body)
 177       = nukeScrutDiscount rhs_size              `addSize`
 178         size_up body                            `addSizeN`
 179         length pairs            -- For the allocation
 180       where
 181         rhs_size = foldr (addSize . size_up . snd) sizeZero pairs
 182
 183     size_up (Case (Var v) _ _ alts)
 184         | v `elem` top_args             -- We are scrutinising an argument variable
 185         =
 186 {-      I'm nuking this special case; BUT see the comment with case alternatives.
 187
 188         (a) It's too eager.  We don't want to inline a wrapper into a
 189             context with no benefit.
 190             E.g.  \ x. f (x+x)          no point in inlining (+) here!
 191
 192         (b) It's ineffective. Once g's wrapper is inlined, its case-expressions
 193             aren't scrutinising arguments any more
 194
 195             case alts of
 196
 197                 [alt] -> size_up_alt alt `addSize` SizeIs (_ILIT(0)) (unitBag (v, 1)) (_ILIT(0))
 198                 -- We want to make wrapper-style evaluation look cheap, so that
 199                 -- when we inline a wrapper it doesn't make call site (much) bigger
 200                 -- Otherwise we get nasty phase ordering stuff:
 201                 --      f x = g x x
 202                 --      h y = ...(f e)...
 203                 -- If we inline g's wrapper, f looks big, and doesn't get inlined
 204                 -- into h; if we inline f first, while it looks small, then g's
 205                 -- wrapper will get inlined later anyway.  To avoid this nasty
 206                 -- ordering difference, we make (case a of (x,y) -> ...),
 207                 --  *where a is one of the arguments* look free.
 208
 209                 other ->
 210 -}
 211                          alts_size (foldr addSize sizeOne alt_sizes)    -- The 1 is for the scrutinee
 212                                    (foldr1 maxSize alt_sizes)
 213
 214                 -- Good to inline if an arg is scrutinised, because
 215                 -- that may eliminate allocation in the caller
 216                 -- And it eliminates the case itself
 217
 218         where
 219           alt_sizes = map size_up_alt alts
 220
 221                 -- alts_size tries to compute a good discount for
 222                 -- the case when we are scrutinising an argument variable
 223           alts_size (SizeIs tot _tot_disc _tot_scrut)           -- Size of all alternatives
 224                     (SizeIs max  max_disc  max_scrut)           -- Size of biggest alternative
 225                 = SizeIs tot (unitBag (v, iBox (_ILIT(1) +# tot -# max)) `unionBags` max_disc) max_scrut
 226                         -- If the variable is known, we produce a discount that
 227                         -- will take us back to 'max', the size of rh largest alternative
 228                         -- The 1+ is a little discount for reduced allocation in the caller
 229           alts_size tot_size _ = tot_size
 230
 231     size_up (Case e _ _ alts) = nukeScrutDiscount (size_up e) `addSize`
 232                                  foldr (addSize . size_up_alt) sizeZero alts
 233                 -- We don't charge for the case itself
 234                 -- It's a strict thing, and the price of the call
 235                 -- is paid by scrut.  Also consider
 236                 --      case f x of DEFAULT -> e
 237                 -- This is just ';'!  Don't charge for it.
 238
 239     ------------
 240     size_up_app (App fun arg) args
 241         | isTypeArg arg              = size_up_app fun args
 242         | otherwise                  = size_up_app fun (arg:args)
 243     size_up_app fun           args   = foldr (addSize . nukeScrutDiscount . size_up)
 244                                              (size_up_fun fun args)
 245                                              args
 246
 247         -- A function application with at least one value argument
 248         -- so if the function is an argument give it an arg-discount
 249         --
 250         -- Also behave specially if the function is a build
 251         --
 252         -- Also if the function is a constant Id (constr or primop)
 253         -- compute discounts specially
 254     size_up_fun (Var fun) args
 255       | fun `hasKey` buildIdKey   = buildSize
 256       | fun `hasKey` augmentIdKey = augmentSize
 257       | otherwise
 258       = case globalIdDetails fun of
 259           DataConWorkId dc -> conSizeN dc (valArgCount args)
 260
 261           FCallId _    -> sizeN opt_UF_DearOp
 262           PrimOpId op  -> primOpSize op (valArgCount args)
 263                           -- foldr addSize (primOpSize op) (map arg_discount args)
 264                           -- At one time I tried giving an arg-discount if a primop
 265                           -- is applied to one of the function's arguments, but it's
 266                           -- not good.  At the moment, any unlifted-type arg gets a
 267                           -- 'True' for 'yes I'm evald', so we collect the discount even
 268                           -- if we know nothing about it.  And just having it in a primop
 269                           -- doesn't help at all if we don't know something more.
 270
 271           _            -> fun_discount fun `addSizeN`
 272                           (1 + length (filter (not . exprIsTrivial) args))
 273                                 -- The 1+ is for the function itself
 274                                 -- Add 1 for each non-trivial arg;
 275                                 -- the allocation cost, as in let(rec)
 276                                 -- Slight hack here: for constructors the args are almost always
 277                                 --      trivial; and for primops they are almost always prim typed
 278                                 --      We should really only count for non-prim-typed args in the
 279                                 --      general case, but that seems too much like hard work
 280
 281     size_up_fun other _ = size_up other
 282
 283     ------------
 284     size_up_alt (_con, _bndrs, rhs) = size_up rhs
 285         -- Don't charge for args, so that wrappers look cheap
 286         -- (See comments about wrappers with Case)
 287
 288     ------------
 289         -- We want to record if we're case'ing, or applying, an argument
 290     fun_discount v | v `elem` top_args = SizeIs (_ILIT(0)) (unitBag (v, opt_UF_FunAppDiscount)) (_ILIT(0))
 291     fun_discount _                     = sizeZero
 292
 293     ------------
 294         -- These addSize things have to be here because
 295         -- I don't want to give them bOMB_OUT_SIZE as an argument
 296
 297     addSizeN TooBig          _  = TooBig
 298     addSizeN (SizeIs n xs d) m  = mkSizeIs bOMB_OUT_SIZE (n +# iUnbox m) xs d
 299
 300     addSize TooBig            _                 = TooBig
 301     addSize _                 TooBig            = TooBig
 302     addSize (SizeIs n1 xs d1) (SizeIs n2 ys d2)
 303         = mkSizeIs bOMB_OUT_SIZE (n1 +# n2) (xs `unionBags` ys) (d1 +# d2)
 304 \end{code}
 305
 306 Code for manipulating sizes
 307
 308 \begin{code}
 309 data ExprSize = TooBig
 310               | SizeIs FastInt          -- Size found
 311                        (Bag (Id,Int))   -- Arguments cased herein, and discount for each such
 312                        FastInt          -- Size to subtract if result is scrutinised
 313                                         -- by a case expression
 314
 315 -- subtract the discount before deciding whether to bale out. eg. we
 316 -- want to inline a large constructor application into a selector:
 317 --      tup = (a_1, ..., a_99)
 318 --      x = case tup of ...
 319 --
 320 mkSizeIs :: FastInt -> FastInt -> Bag (Id, Int) -> FastInt -> ExprSize
 321 mkSizeIs max n xs d | (n -# d) ># max = TooBig
 322                     | otherwise       = SizeIs n xs d
 323
 324 maxSize :: ExprSize -> ExprSize -> ExprSize
 325 maxSize TooBig         _                                  = TooBig
 326 maxSize _              TooBig                             = TooBig
 327 maxSize s1@(SizeIs n1 _ _) s2@(SizeIs n2 _ _) | n1 ># n2  = s1
 328                                               | otherwise = s2
 329
 330 sizeZero, sizeOne :: ExprSize
 331 sizeN :: Int -> ExprSize
 332 conSizeN :: DataCon ->Int -> ExprSize
 333
 334 sizeZero        = SizeIs (_ILIT(0))  emptyBag (_ILIT(0))
 335 sizeOne         = SizeIs (_ILIT(1))  emptyBag (_ILIT(0))
 336 sizeN n         = SizeIs (iUnbox n) emptyBag (_ILIT(0))
 337 conSizeN dc n
 338   | isUnboxedTupleCon dc = SizeIs (_ILIT(0)) emptyBag (iUnbox n +# _ILIT(1))
 339   | otherwise            = SizeIs (_ILIT(1)) emptyBag (iUnbox n +# _ILIT(1))
 340         -- Treat constructors as size 1; we are keen to expose them
 341         -- (and we charge separately for their args).  We can't treat
 342         -- them as size zero, else we find that (iBox x) has size 1,
 343         -- which is the same as a lone variable; and hence 'v' will
 344         -- always be replaced by (iBox x), where v is bound to iBox x.
 345         --
 346         -- However, unboxed tuples count as size zero
 347         -- I found occasions where we had
 348         --      f x y z = case op# x y z of { s -> (# s, () #) }
 349         -- and f wasn't getting inlined
 350
 351 primOpSize :: PrimOp -> Int -> ExprSize
 352 primOpSize op n_args
 353  | not (primOpIsDupable op) = sizeN opt_UF_DearOp
 354  | not (primOpOutOfLine op) = sizeN (2 - n_args)
 355         -- Be very keen to inline simple primops.
 356         -- We give a discount of 1 for each arg so that (op# x y z) costs 2.
 357         -- We can't make it cost 1, else we'll inline let v = (op# x y z)
 358         -- at every use of v, which is excessive.
 359         --
 360         -- A good example is:
 361         --      let x = +# p q in C {x}
 362         -- Even though x get's an occurrence of 'many', its RHS looks cheap,
 363         -- and there's a good chance it'll get inlined back into C's RHS. Urgh!
 364  | otherwise                = sizeOne
 365
 366 buildSize :: ExprSize
 367 buildSize = SizeIs (_ILIT(-2)) emptyBag (_ILIT(4))
 368         -- We really want to inline applications of build
 369         -- build t (\cn -> e) should cost only the cost of e (because build will be inlined later)
 370         -- Indeed, we should add a result_discount becuause build is
 371         -- very like a constructor.  We don't bother to check that the
 372         -- build is saturated (it usually is).  The "-2" discounts for the \c n,
 373         -- The "4" is rather arbitrary.
 374
 375 augmentSize :: ExprSize
 376 augmentSize = SizeIs (_ILIT(-2)) emptyBag (_ILIT(4))
 377         -- Ditto (augment t (\cn -> e) ys) should cost only the cost of
 378         -- e plus ys. The -2 accounts for the \cn
 379
 380 nukeScrutDiscount :: ExprSize -> ExprSize
 381 nukeScrutDiscount (SizeIs n vs _) = SizeIs n vs (_ILIT(0))
 382 nukeScrutDiscount TooBig          = TooBig
 383
 384 -- When we return a lambda, give a discount if it's used (applied)
 385 lamScrutDiscount :: ExprSize -> ExprSize
 386 lamScrutDiscount (SizeIs n vs _) = case opt_UF_FunAppDiscount of { d -> SizeIs n vs (iUnbox d) }
 387 lamScrutDiscount TooBig          = TooBig
 388 \end{code}
 389
 390
 391 %************************************************************************
 392 %*                                                                      *
 393 \subsection[considerUnfolding]{Given all the info, do (not) do the unfolding}
 394 %*                                                                      *
 395 %************************************************************************
 396
 397 We have very limited information about an unfolding expression: (1)~so
 398 many type arguments and so many value arguments expected---for our
 399 purposes here, we assume we've got those.  (2)~A ``size'' or ``cost,''
 400 a single integer.  (3)~An ``argument info'' vector.  For this, what we
 401 have at the moment is a Boolean per argument position that says, ``I
 402 will look with great favour on an explicit constructor in this
 403 position.'' (4)~The ``discount'' to subtract if the expression
 404 is being scrutinised.
 405
 406 Assuming we have enough type- and value arguments (if not, we give up
 407 immediately), then we see if the ``discounted size'' is below some
 408 (semi-arbitrary) threshold.  It works like this: for every argument
 409 position where we're looking for a constructor AND WE HAVE ONE in our
 410 hands, we get a (again, semi-arbitrary) discount [proportion to the
 411 number of constructors in the type being scrutinized].
 412
 413 If we're in the context of a scrutinee ( \tr{(case <expr > of A .. -> ...;.. )})
 414 and the expression in question will evaluate to a constructor, we use
 415 the computed discount size *for the result only* rather than
 416 computing the argument discounts. Since we know the result of
 417 the expression is going to be taken apart, discounting its size
 418 is more accurate (see @sizeExpr@ above for how this discount size
 419 is computed).
 420
 421 We use this one to avoid exporting inlinings that we ``couldn't possibly
 422 use'' on the other side.  Can be overridden w/ flaggery.
 423 Just the same as smallEnoughToInline, except that it has no actual arguments.
 424
 425 \begin{code}
 426 couldBeSmallEnoughToInline :: Int -> CoreExpr -> Bool
 427 couldBeSmallEnoughToInline threshold rhs = case calcUnfoldingGuidance threshold rhs of
 428                                                 UnfoldNever -> False
 429                                                 _           -> True
 430
 431 certainlyWillInline :: Unfolding -> Bool
 432   -- Sees if the unfolding is pretty certain to inline
 433 certainlyWillInline (CompulsoryUnfolding {}) = True
 434 certainlyWillInline (InlineRule {})          = True
 435 certainlyWillInline (CoreUnfolding
 436     { uf_is_cheap = is_cheap
 437     , uf_guidance = UnfoldIfGoodArgs {ug_arity = n_vals, ug_size = size}})
 438   = is_cheap && size - (n_vals +1) <= opt_UF_UseThreshold
 439 certainlyWillInline _
 440   = False
 441
 442 smallEnoughToInline :: Unfolding -> Bool
 443 smallEnoughToInline (CoreUnfolding {uf_guidance = UnfoldIfGoodArgs {ug_size = size}})
 444   = size <= opt_UF_UseThreshold
 445 smallEnoughToInline _
 446   = False
 447 \end{code}
 448
 449 %************************************************************************
 450 %*                                                                      *
 451 \subsection{callSiteInline}
 452 %*                                                                      *
 453 %************************************************************************
 454
 455 This is the key function.  It decides whether to inline a variable at a call site
 456
 457 callSiteInline is used at call sites, so it is a bit more generous.
 458 It's a very important function that embodies lots of heuristics.
 459 A non-WHNF can be inlined if it doesn't occur inside a lambda,
 460 and occurs exactly once or
 461     occurs once in each branch of a case and is small
 462
 463 If the thing is in WHNF, there's no danger of duplicating work,
 464 so we can inline if it occurs once, or is small
 465
 466 NOTE: we don't want to inline top-level functions that always diverge.
 467 It just makes the code bigger.  Tt turns out that the convenient way to prevent
 468 them inlining is to give them a NOINLINE pragma, which we do in
 469 StrictAnal.addStrictnessInfoToTopId
 470
 471 \begin{code}
 472 callSiteInline :: DynFlags
 473                -> Bool                  -- True <=> the Id can be inlined
 474                -> Id                    -- The Id
 475                -> Bool                  -- True if there are are no arguments at all (incl type args)
 476                -> [Bool]                -- One for each value arg; True if it is interesting
 477                -> CallCtxt              -- True <=> continuation is interesting
 478                -> Maybe CoreExpr        -- Unfolding, if any
 479
 480
 481 data CallCtxt = BoringCtxt
 482
 483               | ArgCtxt Bool    -- We're somewhere in the RHS of function with rules
 484                                 --      => be keener to inline
 485                         Int     -- We *are* the argument of a function with this arg discount
 486                                 --      => be keener to inline
 487                 -- INVARIANT: ArgCtxt False 0 ==> BoringCtxt
 488
 489               | ValAppCtxt      -- We're applied to at least one value arg
 490                                 -- This arises when we have ((f x |> co) y)
 491                                 -- Then the (f x) has argument 'x' but in a ValAppCtxt
 492
 493               | CaseCtxt        -- We're the scrutinee of a case
 494                                 -- that decomposes its scrutinee
 495
 496 instance Outputable CallCtxt where
 497   ppr BoringCtxt    = ptext (sLit "BoringCtxt")
 498   ppr (ArgCtxt _ _) = ptext (sLit "ArgCtxt")
 499   ppr CaseCtxt      = ptext (sLit "CaseCtxt")
 500   ppr ValAppCtxt    = ptext (sLit "ValAppCtxt")
 501
 502 callSiteInline dflags active_inline id lone_variable arg_infos cont_info
 503   = let
 504         n_val_args  = length arg_infos
 505     in
 506     case idUnfolding id of {
 507         NoUnfolding -> Nothing ;
 508         OtherCon _  -> Nothing ;
 509
 510         CompulsoryUnfolding unf_template -> Just unf_template ;
 511                 -- CompulsoryUnfolding => there is no top-level binding
 512                 -- for these things, so we must inline it.
 513                 -- Only a couple of primop-like things have
 514                 -- compulsory unfoldings (see MkId.lhs).
 515                 -- We don't allow them to be inactive
 516
 517         InlineRule { uf_tmpl = unf_template, uf_arity = arity, uf_is_top = is_top
 518                    , uf_is_value = is_value, uf_worker = mb_worker }
 519             -> let yes_or_no | not active_inline   = False
 520                              | n_val_args <  arity = yes_unsat  -- Not enough value args
 521                              | n_val_args == arity = yes_exact  -- Exactly saturated
 522                              | otherwise           = True       -- Over-saturated
 523                    result | yes_or_no = Just unf_template
 524                           | otherwise = Nothing
 525
 526                    -- See Note [Inlining an InlineRule]
 527                    is_wrapper = isJust mb_worker
 528                    yes_unsat | is_wrapper  = or arg_infos
 529                              | otherwise   = False
 530
 531                    yes_exact = or arg_infos || interesting_saturated_call
 532                    interesting_saturated_call
 533                         = case cont_info of
 534                             BoringCtxt -> not is_top                            -- Note [Nested functions]
 535                             CaseCtxt   -> not lone_variable || not is_value     -- Note [Lone variables]
 536                             ArgCtxt {} -> arity > 0                             -- Note [Inlining in ArgCtxt]
 537                             ValAppCtxt -> True                                  -- Note [Cast then apply]
 538                in
 539                if dopt Opt_D_dump_inlinings dflags then
 540                 pprTrace ("Considering InlineRule for: " ++ showSDoc (ppr id))
 541                          (vcat [text "active:" <+> ppr active_inline,
 542                                 text "arg infos" <+> ppr arg_infos,
 543                                 text "interesting call" <+> ppr interesting_saturated_call,
 544                                 text "is value:" <+> ppr is_value,
 545                                 text "ANSWER =" <+> if yes_or_no then text "YES" else text "NO"])
 546                           result
 547                 else result ;
 548
 549         CoreUnfolding { uf_tmpl = unf_template, uf_is_top = is_top, uf_is_value = is_value,
 550                         uf_is_cheap = is_cheap, uf_guidance = guidance } ->
 551
 552     let
 553         result | yes_or_no = Just unf_template
 554                | otherwise = Nothing
 555
 556         yes_or_no = active_inline && is_cheap && consider_safe
 557                 -- We consider even the once-in-one-branch
 558                 -- occurrences, because they won't all have been
 559                 -- caught by preInlineUnconditionally.  In particular,
 560                 -- if the occurrence is once inside a lambda, and the
 561                 -- rhs is cheap but not a manifest lambda, then
 562                 -- pre-inline will not have inlined it for fear of
 563                 -- invalidating the occurrence info in the rhs.
 564
 565         consider_safe
 566                 -- consider_safe decides whether it's a good idea to
 567                 -- inline something, given that there's no
 568                 -- work-duplication issue (the caller checks that).
 569           = case guidance of
 570               UnfoldNever  -> False
 571               UnfoldIfGoodArgs { ug_arity = n_vals_wanted, ug_args = arg_discounts
 572                                , ug_res = res_discount, ug_size = size }
 573                   | enough_args && size <= (n_vals_wanted + 1)
 574                         -- Inline unconditionally if there no size increase
 575                         -- Size of call is n_vals_wanted (+1 for the function)
 576                   -> True
 577
 578                   | otherwise
 579                   -> some_benefit && small_enough && inline_enough_args
 580
 581                   where
 582                     enough_args = n_val_args >= n_vals_wanted
 583                     inline_enough_args =
 584                       not (dopt Opt_InlineIfEnoughArgs dflags) || enough_args
 585
 586
 587                     some_benefit = or arg_infos || really_interesting_cont
 588                                 -- There must be something interesting
 589                                 -- about some argument, or the result
 590                                 -- context, to make it worth inlining
 591
 592                     really_interesting_cont
 593                         | n_val_args <  n_vals_wanted = False   -- Too few args
 594                         | n_val_args == n_vals_wanted = interesting_saturated_call
 595                         | otherwise                   = True    -- Extra args
 596                         -- really_interesting_cont tells if the result of the
 597                         -- call is in an interesting context.
 598
 599                     interesting_saturated_call
 600                         = case cont_info of
 601                             BoringCtxt -> not is_top && n_vals_wanted > 0       -- Note [Nested functions]
 602                             CaseCtxt   -> not lone_variable || not is_value     -- Note [Lone variables]
 603                             ArgCtxt {} -> n_vals_wanted > 0                     -- Note [Inlining in ArgCtxt]
 604                             ValAppCtxt -> True                                  -- Note [Cast then apply]
 605
 606                     small_enough = (size - discount) <= opt_UF_UseThreshold
 607                     discount = computeDiscount n_vals_wanted arg_discounts
 608                                                res_discount' arg_infos
 609                     res_discount' = case cont_info of
 610                                         BoringCtxt  -> 0
 611                                         CaseCtxt    -> res_discount
 612                                         _other      -> 4 `min` res_discount
 613                         -- res_discount can be very large when a function returns
 614                         -- construtors; but we only want to invoke that large discount
 615                         -- when there's a case continuation.
 616                         -- Otherwise we, rather arbitrarily, threshold it.  Yuk.
 617                         -- But we want to aovid inlining large functions that return
 618                         -- constructors into contexts that are simply "interesting"
 619
 620     in
 621     if dopt Opt_D_dump_inlinings dflags then
 622         pprTrace ("Considering inlining: " ++ showSDoc (ppr id))
 623                  (vcat [text "active:" <+> ppr active_inline,
 624                         text "arg infos" <+> ppr arg_infos,
 625                         text "interesting continuation" <+> ppr cont_info,
 626                         text "is value:" <+> ppr is_value,
 627                         text "is cheap:" <+> ppr is_cheap,
 628                         text "guidance" <+> ppr guidance,
 629                         text "ANSWER =" <+> if yes_or_no then text "YES" else text "NO"])
 630                   result
 631     else
 632     result
 633     }
 634 \end{code}
 635
 636 Note [Inlining an InlineRule]
 637 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 638 An InlineRules is used for
 639   (a) pogrammer INLINE pragmas
 640   (b) inlinings from worker/wrapper
 641
 642 For (a) the RHS may be large, and our contract is that we *only* inline
 643 when the function is applied to all the arguments on the LHS of the
 644 source-code defn.  (The uf_arity in the rule.)
 645
 646 However for worker/wrapper it may be worth inlining even if the
 647 arity is not satisfied (as we do in the CoreUnfolding case) so we don't
 648 require saturation.
 649
 650
 651 Note [Nested functions]
 652 ~~~~~~~~~~~~~~~~~~~~~~~
 653 If a function has a nested defn we also record some-benefit, on the
 654 grounds that we are often able to eliminate the binding, and hence the
 655 allocation, for the function altogether; this is good for join points.
 656 But this only makes sense for *functions*; inlining a constructor
 657 doesn't help allocation unless the result is scrutinised.  UNLESS the
 658 constructor occurs just once, albeit possibly in multiple case
 659 branches.  Then inlining it doesn't increase allocation, but it does
 660 increase the chance that the constructor won't be allocated at all in
 661 the branches that don't use it.
 662
 663 Note [Cast then apply]
 664 ~~~~~~~~~~~~~~~~~~~~~~
 665 Consider
 666    myIndex = __inline_me ( (/\a. <blah>) |> co )
 667    co :: (forall a. a -> a) ~ (forall a. T a)
 668      ... /\a.\x. case ((myIndex a) |> sym co) x of { ... } ...
 669
 670 We need to inline myIndex to unravel this; but the actual call (myIndex a) has
 671 no value arguments.  The ValAppCtxt gives it enough incentive to inline.
 672
 673 Note [Inlining in ArgCtxt]
 674 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 675 The condition (n_vals_wanted > 0) here is very important, because otherwise
 676 we end up inlining top-level stuff into useless places; eg
 677    x = I# 3#
 678    f = \y.  g x
 679 This can make a very big difference: it adds 16% to nofib 'integer' allocs,
 680 and 20% to 'power'.
 681
 682 At one stage I replaced this condition by 'True' (leading to the above
 683 slow-down).  The motivation was test eyeball/inline1.hs; but that seems
 684 to work ok now.
 685
 686 Note [Lone variables]
 687 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 688 The "lone-variable" case is important.  I spent ages messing about
 689 with unsatisfactory varaints, but this is nice.  The idea is that if a
 690 variable appears all alone
 691         as an arg of lazy fn, or rhs    Stop
 692         as scrutinee of a case          Select
 693         as arg of a strict fn           ArgOf
 694 AND
 695         it is bound to a value
 696 then we should not inline it (unless there is some other reason,
 697 e.g. is is the sole occurrence).  That is what is happening at
 698 the use of 'lone_variable' in 'interesting_saturated_call'.
 699
 700 Why?  At least in the case-scrutinee situation, turning
 701         let x = (a,b) in case x of y -> ...
 702 into
 703         let x = (a,b) in case (a,b) of y -> ...
 704 and thence to
 705         let x = (a,b) in let y = (a,b) in ...
 706 is bad if the binding for x will remain.
 707
 708 Another example: I discovered that strings
 709 were getting inlined straight back into applications of 'error'
 710 because the latter is strict.
 711         s = "foo"
 712         f = \x -> ...(error s)...
 713
 714 Fundamentally such contexts should not encourage inlining because the
 715 context can ``see'' the unfolding of the variable (e.g. case or a
 716 RULE) so there's no gain.  If the thing is bound to a value.
 717
 718 However, watch out:
 719
 720  * Consider this:
 721         foo = _inline_ (\n. [n])
 722         bar = _inline_ (foo 20)
 723         baz = \n. case bar of { (m:_) -> m + n }
 724    Here we really want to inline 'bar' so that we can inline 'foo'
 725    and the whole thing unravels as it should obviously do.  This is
 726    important: in the NDP project, 'bar' generates a closure data
 727    structure rather than a list.
 728
 729  * Even a type application or coercion isn't a lone variable.
 730    Consider
 731         case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 732    We had better inline that sucker!  The case won't see through it.
 733
 734    For now, I'm treating treating a variable applied to types
 735    in a *lazy* context "lone". The motivating example was
 736         f = /\a. \x. BIG
 737         g = /\a. \y.  h (f a)
 738    There's no advantage in inlining f here, and perhaps
 739    a significant disadvantage.  Hence some_val_args in the Stop case
 740
 741 \begin{code}
 742 computeDiscount :: Int -> [Int] -> Int -> [Bool] -> Int
 743 computeDiscount n_vals_wanted arg_discounts result_discount arg_infos
 744         -- We multiple the raw discounts (args_discount and result_discount)
 745         -- ty opt_UnfoldingKeenessFactor because the former have to do with
 746         --  *size* whereas the discounts imply that there's some extra
 747         --  *efficiency* to be gained (e.g. beta reductions, case reductions)
 748         -- by inlining.
 749
 750         -- we also discount 1 for each argument passed, because these will
 751         -- reduce with the lambdas in the function (we count 1 for a lambda
 752         -- in size_up).
 753   = 1 +                 -- Discount of 1 because the result replaces the call
 754                         -- so we count 1 for the function itself
 755     length (take n_vals_wanted arg_infos) +
 756                         -- Discount of 1 for each arg supplied, because the
 757                         -- result replaces the call
 758     round (opt_UF_KeenessFactor *
 759            fromIntegral (arg_discount + result_discount))
 760   where
 761     arg_discount = sum (zipWith mk_arg_discount arg_discounts arg_infos)
 762
 763     mk_arg_discount discount is_evald | is_evald  = discount
 764                                       | otherwise = 0
 765 \end{code}
 766
 767 %************************************************************************
 768 %*                                                                      *
 769         The Very Simple Optimiser
 770 %*                                                                      *
 771 %************************************************************************
 772
 773
 774 \begin{code}
 775 simpleOptExpr :: CoreExpr -> CoreExpr
 776 -- Return an occur-analysed and slightly optimised expression
 777 -- The optimisation is very straightforward: just
 778 -- inline non-recursive bindings that are used only once,
 779 -- or wheere the RHS is trivial
 780
 781 simpleOptExpr expr
 782   = go emptySubst (occurAnalyseExpr expr)
 783   where
 784     go subst (Var v)          = lookupIdSubst subst v
 785     go subst (App e1 e2)      = App (go subst e1) (go subst e2)
 786     go subst (Type ty)        = Type (substTy subst ty)
 787     go _     (Lit lit)        = Lit lit
 788     go subst (Note note e)    = Note note (go subst e)
 789     go subst (Cast e co)      = Cast (go subst e) (substTy subst co)
 790     go subst (Let bind body)  = go_bind subst bind body
 791     go subst (Lam bndr body)  = Lam bndr' (go subst' body)
 792                               where
 793                                 (subst', bndr') = substBndr subst bndr
 794
 795     go subst (Case e b ty as) = Case (go subst e) b'
 796                                      (substTy subst ty)
 797                                      (map (go_alt subst') as)
 798                               where
 799                                  (subst', b') = substBndr subst b
 800
 801
 802     ----------------------
 803     go_alt subst (con, bndrs, rhs) = (con, bndrs', go subst' rhs)
 804                                  where
 805                                    (subst', bndrs') = substBndrs subst bndrs
 806
 807     ----------------------
 808     go_bind subst (Rec prs) body = Let (Rec (bndrs' `zip` rhss'))
 809                                        (go subst' body)
 810                             where
 811                               (bndrs, rhss)    = unzip prs
 812                               (subst', bndrs') = substRecBndrs subst bndrs
 813                               rhss'            = map (go subst') rhss
 814
 815     go_bind subst (NonRec b r) body = go_nonrec subst b (go subst r) body
 816
 817     ----------------------
 818     go_nonrec subst b (Type ty') body
 819       | isTyVar b = go (extendTvSubst subst b ty') body
 820         -- let a::* = TYPE ty in <body>
 821     go_nonrec subst b r' body
 822       | isId b  -- let x = e in <body>
 823       , exprIsTrivial r' || safe_to_inline (idOccInfo b)
 824       = go (extendIdSubst subst b r') body
 825     go_nonrec subst b r' body
 826       = Let (NonRec b' r') (go subst' body)
 827       where
 828         (subst', b') = substBndr subst b
 829
 830     ----------------------
 831         -- Unconditionally safe to inline
 832     safe_to_inline :: OccInfo -> Bool
 833     safe_to_inline IAmDead                  = True
 834     safe_to_inline (OneOcc in_lam one_br _) = not in_lam && one_br
 835     safe_to_inline (IAmALoopBreaker {})     = False
 836     safe_to_inline NoOccInfo                = False
 837 \end{code}