compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsBottom,
  29         exprIsCheap, exprIsExpandable, exprIsCheap', CheapAppFun,
  30         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  31         rhsIsStatic, isCheapApp, isExpandableApp,
  32
  33         -- * Expression and bindings size
  34         coreBindsSize, exprSize,
  35
  36         -- * Hashing
  37         hashExpr,
  38
  39         -- * Equality
  40         cheapEqExpr, eqExpr, eqExprX,
  41
  42         -- * Eta reduction
  43         tryEtaReduce,
  44
  45         -- * Manipulating data constructors and types
  46         applyTypeToArgs, applyTypeToArg,
  47         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  48     ) where
  49
  50 #include "HsVersions.h"
  51
  52 import CoreSyn
  53 import PprCore
  54 import Var
  55 import SrcLoc
  56 import VarEnv
  57 import VarSet
  58 import Name
  59 import Literal
  60 import DataCon
  61 import PrimOp
  62 import Id
  63 import IdInfo
  64 import TcType   ( isPredTy )
  65 import Type
  66 import Coercion
  67 import TyCon
  68 import CostCentre
  69 import Unique
  70 import Outputable
  71 import TysPrim
  72 import PrelNames( absentErrorIdKey )
  73 import FastString
  74 import Maybes
  75 import Util
  76 import Data.Word
  77 import Data.Bits
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89 -- ^ Recover the type of a well-typed Core expression. Fails when
  90 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  91 -- really be said to have a type
  92 exprType (Var var)           = idType var
  93 exprType (Lit lit)           = literalType lit
  94 exprType (Let _ body)        = exprType body
  95 exprType (Case _ _ ty _)     = ty
  96 exprType (Cast _ co)         = snd (coercionKind co)
  97 exprType (Note _ e)          = exprType e
  98 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  99 exprType e@(App _ _)
 100   = case collectArgs e of
 101         (fun, args) -> applyTypeToArgs e (exprType fun) args
 102
 103 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 104
 105 coreAltType :: CoreAlt -> Type
 106 -- ^ Returns the type of the alternatives right hand side
 107 coreAltType (_,bs,rhs)
 108   | any bad_binder bs = expandTypeSynonyms ty
 109   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 110   where
 111     ty           = exprType rhs
 112     free_tvs     = tyVarsOfType ty
 113     bad_binder b = isTyCoVar b && b `elemVarSet` free_tvs
 114
 115 coreAltsType :: [CoreAlt] -> Type
 116 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 117 coreAltsType (alt:_) = coreAltType alt
 118 coreAltsType []      = panic "corAltsType"
 119 \end{code}
 120
 121 Note [Existential variables and silly type synonyms]
 122 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 123 Consider
 124         data T = forall a. T (Funny a)
 125         type Funny a = Bool
 126         f :: T -> Bool
 127         f (T x) = x
 128
 129 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 130 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 131 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 132 example.
 133
 134 Various possibilities suggest themselves:
 135
 136  - Ignore the problem, and make Lint not complain about such variables
 137
 138  - Expand all type synonyms (or at least all those that discard arguments)
 139       This is tricky, because at least for top-level things we want to
 140       retain the type the user originally specified.
 141
 142  - Expand synonyms on the fly, when the problem arises. That is what
 143    we are doing here.  It's not too expensive, I think.
 144
 145 \begin{code}
 146 mkPiType  :: EvVar -> Type -> Type
 147 -- ^ Makes a @(->)@ type or a forall type, depending
 148 -- on whether it is given a type variable or a term variable.
 149 mkPiTypes :: [EvVar] -> Type -> Type
 150 -- ^ 'mkPiType' for multiple type or value arguments
 151
 152 mkPiType v ty
 153    | isId v    = mkFunTy (idType v) ty
 154    | otherwise = mkForAllTy v ty
 155
 156 mkPiTypes vs ty = foldr mkPiType ty vs
 157 \end{code}
 158
 159 \begin{code}
 160 applyTypeToArg :: Type -> CoreExpr -> Type
 161 -- ^ Determines the type resulting from applying an expression to a function with the given type
 162 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 163 applyTypeToArg fun_ty _             = funResultTy fun_ty
 164
 165 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 166 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 167 -- The first argument is just for debugging, and gives some context
 168 applyTypeToArgs _ op_ty [] = op_ty
 169
 170 applyTypeToArgs e op_ty (Type ty : args)
 171   =     -- Accumulate type arguments so we can instantiate all at once
 172     go [ty] args
 173   where
 174     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 175     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 176                                 where
 177                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 178                                   msg = ptext (sLit "applyTypeToArgs") <+>
 179                                         panic_msg e op_ty
 180
 181 applyTypeToArgs e op_ty (_ : args)
 182   = case (splitFunTy_maybe op_ty) of
 183         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 184         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 185
 186 panic_msg :: CoreExpr -> Type -> SDoc
 187 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192 \subsection{Attaching notes}
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 198 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 199 mkCoerceI (IdCo _) e = e
 200 mkCoerceI (ACo co) e = mkCoerce co e
 201
 202 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 203 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 204 mkCoerce co (Cast expr co2)
 205   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 206                  (_from_ty2, to_ty2) = coercionKind co2} in
 207            from_ty `coreEqType` to_ty2 )
 208     mkCoerce (mkTransCoercion co2 co) expr
 209
 210 mkCoerce co expr
 211   = let (from_ty, _to_ty) = coercionKind co in
 212 --    if to_ty `coreEqType` from_ty
 213 --    then expr
 214 --    else
 215         WARN(not (from_ty `coreEqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 216          (Cast expr co)
 217 \end{code}
 218
 219 \begin{code}
 220 -- | Wraps the given expression in the cost centre unless
 221 -- in a way that maximises their utility to the user
 222 mkSCC :: CostCentre -> Expr b -> Expr b
 223         -- Note: Nested SCC's *are* preserved for the benefit of
 224         --       cost centre stack profiling
 225 mkSCC _  (Lit lit)          = Lit lit
 226 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 227 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 228 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 229 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 230 mkSCC cc expr               = Note (SCC cc) expr
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Other expression construction}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 \begin{code}
 241 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 242 -- ^ @bindNonRec x r b@ produces either:
 243 --
 244 -- > let x = r in b
 245 --
 246 -- or:
 247 --
 248 -- > case r of x { _DEFAULT_ -> b }
 249 --
 250 -- depending on whether we have to use a @case@ or @let@
 251 -- binding for the expression (see 'needsCaseBinding').
 252 -- It's used by the desugarer to avoid building bindings
 253 -- that give Core Lint a heart attack, although actually
 254 -- the simplifier deals with them perfectly well. See
 255 -- also 'MkCore.mkCoreLet'
 256 bindNonRec bndr rhs body
 257   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 258   | otherwise                          = Let (NonRec bndr rhs) body
 259
 260 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 261 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 262 needsCaseBinding :: Type -> CoreExpr -> Bool
 263 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 264         -- Make a case expression instead of a let
 265         -- These can arise either from the desugarer,
 266         -- or from beta reductions: (\x.e) (x +# y)
 267 \end{code}
 268
 269 \begin{code}
 270 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 271           -> [CoreBndr] -- ^ Things bound by the pattern match
 272           -> [Type]     -- ^ The type arguments to the case alternative
 273           -> CoreExpr
 274 -- ^ This guy constructs the value that the scrutinee must have
 275 -- given that you are in one particular branch of a case
 276 mkAltExpr (DataAlt con) args inst_tys
 277   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 278 mkAltExpr (LitAlt lit) [] []
 279   = Lit lit
 280 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 281 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 282 \end{code}
 283
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection{Taking expressions apart}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 The default alternative must be first, if it exists at all.
 292 This makes it easy to find, though it makes matching marginally harder.
 293
 294 \begin{code}
 295 -- | Extract the default case alternative
 296 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 297 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 298 findDefault alts                        =                     (alts, Nothing)
 299
 300 isDefaultAlt :: CoreAlt -> Bool
 301 isDefaultAlt (DEFAULT, _, _) = True
 302 isDefaultAlt _               = False
 303
 304
 305 -- | Find the case alternative corresponding to a particular
 306 -- constructor: panics if no such constructor exists
 307 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 308     -- A "Nothing" result *is* legitmiate
 309     -- See Note [Unreachable code]
 310 findAlt con alts
 311   = case alts of
 312         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 313         _                          -> go alts Nothing
 314   where
 315     go []                     deflt = deflt
 316     go (alt@(con1,_,_) : alts) deflt
 317       = case con `cmpAltCon` con1 of
 318           LT -> deflt   -- Missed it already; the alts are in increasing order
 319           EQ -> Just alt
 320           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 321
 322 ---------------------------------
 323 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 324 -- ^ Merge alternatives preserving order; alternatives in
 325 -- the first argument shadow ones in the second
 326 mergeAlts [] as2 = as2
 327 mergeAlts as1 [] = as1
 328 mergeAlts (a1:as1) (a2:as2)
 329   = case a1 `cmpAlt` a2 of
 330         LT -> a1 : mergeAlts as1      (a2:as2)
 331         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 332         GT -> a2 : mergeAlts (a1:as1) as2
 333
 334
 335 ---------------------------------
 336 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 337 -- ^ Given:
 338 --
 339 -- > case (C a b x y) of
 340 -- >        C b x y -> ...
 341 --
 342 -- We want to drop the leading type argument of the scrutinee
 343 -- leaving the arguments to match agains the pattern
 344
 345 trimConArgs DEFAULT      args = ASSERT( null args ) []
 346 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 347 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 348 \end{code}
 349
 350 Note [Unreachable code]
 351 ~~~~~~~~~~~~~~~~~~~~~~~
 352 It is possible (although unusual) for GHC to find a case expression
 353 that cannot match.  For example:
 354
 355      data Col = Red | Green | Blue
 356      x = Red
 357      f v = case x of
 358               Red -> ...
 359               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 360
 361 Suppose that for some silly reason, x isn't substituted in the case
 362 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 363 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 364 this
 365
 366      x = Red
 367      lvl = case x of { Green -> e1; Blue -> e2 })
 368      f v = case x of
 369              Red -> ...
 370              _ -> ...lvl...
 371
 372 Now if x gets inlined, we won't be able to find a matching alternative
 373 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 374 we generate (error "Inaccessible alternative").
 375
 376 Similar things can happen (augmented by GADTs) when the Simplifier
 377 filters down the matching alternatives in Simplify.rebuildCase.
 378
 379
 380 %************************************************************************
 381 %*                                                                      *
 382              exprIsTrivial
 383 %*                                                                      *
 384 %************************************************************************
 385
 386 Note [exprIsTrivial]
 387 ~~~~~~~~~~~~~~~~~~~~
 388 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 389                 duplicate; simple variables and constants, and type
 390                 applications.  Note that primop Ids aren't considered
 391                 trivial unless
 392
 393 Note [Variable are trivial]
 394 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 395 There used to be a gruesome test for (hasNoBinding v) in the
 396 Var case:
 397         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 398 The idea here is that a constructor worker, like \$wJust, is
 399 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 400 So it should be treated like a lambda.  Ditto unsaturated primops.
 401 But now constructor workers are not "have-no-binding" Ids.  And
 402 completely un-applied primops and foreign-call Ids are sufficiently
 403 rare that I plan to allow them to be duplicated and put up with
 404 saturating them.
 405
 406 Note [SCCs are trivial]
 407 ~~~~~~~~~~~~~~~~~~~~~~~
 408 We used not to treat (_scc_ "foo" x) as trivial, because it really
 409 generates code, (and a heap object when it's a function arg) to
 410 capture the cost centre.  However, the profiling system discounts the
 411 allocation costs for such "boxing thunks" whereas the extra costs of
 412 *not* inlining otherwise-trivial bindings can be high, and are hard to
 413 discount.
 414
 415 \begin{code}
 416 exprIsTrivial :: CoreExpr -> Bool
 417 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 418 exprIsTrivial (Type _)         = True
 419 exprIsTrivial (Lit lit)        = litIsTrivial lit
 420 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 421 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 422 exprIsTrivial (Cast e _)       = exprIsTrivial e
 423 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 424 exprIsTrivial _                = False
 425 \end{code}
 426
 427 exprIsBottom is a very cheap and cheerful function; it may return
 428 False for bottoming expressions, but it never costs much to ask.
 429 See also CoreArity.exprBotStrictness_maybe, but that's a bit more
 430 expensive.
 431
 432 \begin{code}
 433 exprIsBottom :: CoreExpr -> Bool
 434 exprIsBottom e
 435   = go 0 e
 436   where
 437     go n (Var v) = isBottomingId v &&  n >= idArity v
 438     go n (App e a) | isTypeArg a = go n e
 439                    | otherwise   = go (n+1) e
 440     go n (Note _ e)              = go n e
 441     go n (Cast e _)              = go n e
 442     go n (Let _ e)               = go n e
 443     go _ _                       = False
 444 \end{code}
 445
 446
 447 %************************************************************************
 448 %*                                                                      *
 449              exprIsDupable
 450 %*                                                                      *
 451 %************************************************************************
 452
 453 Note [exprIsDupable]
 454 ~~~~~~~~~~~~~~~~~~~~
 455 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 456                 cost in code size.  This will only happen in different case
 457                 branches, so there's no issue about duplicating work.
 458
 459                 That is, exprIsDupable returns True of (f x) even if
 460                 f is very very expensive to call.
 461
 462                 Its only purpose is to avoid fruitless let-binding
 463                 and then inlining of case join points
 464
 465
 466 \begin{code}
 467 exprIsDupable :: CoreExpr -> Bool
 468 exprIsDupable e
 469   = isJust (go dupAppSize e)
 470   where
 471     go :: Int -> CoreExpr -> Maybe Int
 472     go n (Type {}) = Just n
 473     go n (Var {})  = decrement n
 474     go n (Note _ e) = go n e
 475     go n (Cast e _) = go n e
 476     go n (App f a) | Just n' <- go n a = go n' f
 477     go n (Lit lit) | litIsDupable lit = decrement n
 478     go _ _ = Nothing
 479
 480     decrement :: Int -> Maybe Int
 481     decrement 0 = Nothing
 482     decrement n = Just (n-1)
 483
 484 dupAppSize :: Int
 485 dupAppSize = 6   -- Size of term we are prepared to duplicate
 486 \end{code}
 487
 488 %************************************************************************
 489 %*                                                                      *
 490              exprIsCheap, exprIsExpandable
 491 %*                                                                      *
 492 %************************************************************************
 493
 494 Note [exprIsCheap]   See also Note [Interaction of exprIsCheap and lone variables]
 495 ~~~~~~~~~~~~~~~~~~   in CoreUnfold.lhs
 496 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 497 it is obviously in weak head normal form, or is cheap to get to WHNF.
 498 [Note that that's not the same as exprIsDupable; an expression might be
 499 big, and hence not dupable, but still cheap.]
 500
 501 By ``cheap'' we mean a computation we're willing to:
 502         push inside a lambda, or
 503         inline at more than one place
 504 That might mean it gets evaluated more than once, instead of being
 505 shared.  The main examples of things which aren't WHNF but are
 506 ``cheap'' are:
 507
 508   *     case e of
 509           pi -> ei
 510         (where e, and all the ei are cheap)
 511
 512   *     let x = e in b
 513         (where e and b are cheap)
 514
 515   *     op x1 ... xn
 516         (where op is a cheap primitive operator)
 517
 518   *     error "foo"
 519         (because we are happy to substitute it inside a lambda)
 520
 521 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 522 because sharing will make sure it is only evaluated once.
 523
 524 Note [exprIsCheap and exprIsHNF]
 525 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 526 Note that exprIsHNF does not imply exprIsCheap.  Eg
 527         let x = fac 20 in Just x
 528 This responds True to exprIsHNF (you can discard a seq), but
 529 False to exprIsCheap.
 530
 531 \begin{code}
 532 exprIsCheap :: CoreExpr -> Bool
 533 exprIsCheap = exprIsCheap' isCheapApp
 534
 535 exprIsExpandable :: CoreExpr -> Bool
 536 exprIsExpandable = exprIsCheap' isExpandableApp -- See Note [CONLIKE pragma] in BasicTypes
 537
 538 type CheapAppFun = Id -> Int -> Bool
 539 exprIsCheap' :: CheapAppFun -> CoreExpr -> Bool
 540 exprIsCheap' _          (Lit _)   = True
 541 exprIsCheap' _          (Type _)  = True
 542 exprIsCheap' _          (Var _)   = True
 543 exprIsCheap' good_app (Note _ e)  = exprIsCheap' good_app e
 544 exprIsCheap' good_app (Cast e _)  = exprIsCheap' good_app e
 545 exprIsCheap' good_app (Lam x e)   = isRuntimeVar x
 546                                  || exprIsCheap' good_app e
 547
 548 exprIsCheap' good_app (Case e _ _ alts) = exprIsCheap' good_app e &&
 549                                           and [exprIsCheap' good_app rhs | (_,_,rhs) <- alts]
 550         -- Experimentally, treat (case x of ...) as cheap
 551         -- (and case __coerce x etc.)
 552         -- This improves arities of overloaded functions where
 553         -- there is only dictionary selection (no construction) involved
 554
 555 exprIsCheap' good_app (Let (NonRec x _) e)
 556   | isUnLiftedType (idType x) = exprIsCheap' good_app e
 557   | otherwise                 = False
 558         -- Strict lets always have cheap right hand sides,
 559         -- and do no allocation, so just look at the body
 560         -- Non-strict lets do allocation so we don't treat them as cheap
 561         -- See also
 562
 563 exprIsCheap' good_app other_expr        -- Applications and variables
 564   = go other_expr []
 565   where
 566         -- Accumulate value arguments, then decide
 567     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 568                           | otherwise      = go f val_args
 569
 570     go (Var _) [] = True        -- Just a type application of a variable
 571                                 -- (f t1 t2 t3) counts as WHNF
 572     go (Var f) args
 573         = case idDetails f of
 574                 RecSelId {}                  -> go_sel args
 575                 ClassOpId {}                 -> go_sel args
 576                 PrimOpId op                  -> go_primop op args
 577                 _ | good_app f (length args) -> go_pap args
 578                   | isBottomingId f          -> True
 579                   | otherwise                -> False
 580                         -- Application of a function which
 581                         -- always gives bottom; we treat this as cheap
 582                         -- because it certainly doesn't need to be shared!
 583
 584     go _ _ = False
 585
 586     --------------
 587     go_pap args = all exprIsTrivial args
 588         -- For constructor applications and primops, check that all
 589         -- the args are trivial.  We don't want to treat as cheap, say,
 590         --      (1:2:3:4:5:[])
 591         -- We'll put up with one constructor application, but not dozens
 592
 593     --------------
 594     go_primop op args = primOpIsCheap op && all (exprIsCheap' good_app) args
 595         -- In principle we should worry about primops
 596         -- that return a type variable, since the result
 597         -- might be applied to something, but I'm not going
 598         -- to bother to check the number of args
 599
 600     --------------
 601     go_sel [arg] = exprIsCheap' good_app arg    -- I'm experimenting with making record selection
 602     go_sel _     = False                -- look cheap, so we will substitute it inside a
 603                                         -- lambda.  Particularly for dictionary field selection.
 604                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 605                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 606
 607 isCheapApp :: CheapAppFun
 608 isCheapApp fn n_val_args
 609   = isDataConWorkId fn
 610   || n_val_args < idArity fn
 611
 612 isExpandableApp :: CheapAppFun
 613 isExpandableApp fn n_val_args
 614   =  isConLikeId fn
 615   || n_val_args < idArity fn
 616   || go n_val_args (idType fn)
 617   where
 618   -- See if all the arguments are PredTys (implicit params or classes)
 619   -- If so we'll regard it as expandable; see Note [Expandable overloadings]
 620      go 0 _ = True
 621      go n_val_args ty
 622        | Just (_, ty) <- splitForAllTy_maybe ty   = go n_val_args ty
 623        | Just (arg, ty) <- splitFunTy_maybe ty
 624        , isPredTy arg                             = go (n_val_args-1) ty
 625        | otherwise                                = False
 626 \end{code}
 627
 628 Note [Expandable overloadings]
 629 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 630 Suppose the user wrote this
 631    {-# RULE  forall x. foo (negate x) = h x #-}
 632    f x = ....(foo (negate x))....
 633 He'd expect the rule to fire. But since negate is overloaded, we might
 634 get this:
 635     f = \d -> let n = negate d in \x -> ...foo (n x)...
 636 So we treat the application of a function (negate in this case) to a
 637 *dictionary* as expandable.  In effect, every function is CONLIKE when
 638 it's applied only to dictionaries.
 639
 640
 641 %************************************************************************
 642 %*                                                                      *
 643              exprOkForSpeculation
 644 %*                                                                      *
 645 %************************************************************************
 646
 647 \begin{code}
 648 -- | 'exprOkForSpeculation' returns True of an expression that is:
 649 --
 650 --  * Safe to evaluate even if normal order eval might not
 651 --    evaluate the expression at all, or
 652 --
 653 --  * Safe /not/ to evaluate even if normal order would do so
 654 --
 655 -- It is usually called on arguments of unlifted type, but not always
 656 -- In particular, Simplify.rebuildCase calls it on lifted types
 657 -- when a 'case' is a plain 'seq'. See the example in
 658 -- Note [exprOkForSpeculation: case expressions] below
 659 --
 660 -- Precisely, it returns @True@ iff:
 661 --
 662 --  * The expression guarantees to terminate,
 663 --  * soon,
 664 --  * without raising an exception,
 665 --  * without causing a side effect (e.g. writing a mutable variable)
 666 --
 667 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 668 -- As an example of the considerations in this test, consider:
 669 --
 670 -- > let x = case y# +# 1# of { r# -> I# r# }
 671 -- > in E
 672 --
 673 -- being translated to:
 674 --
 675 -- > case y# +# 1# of { r# ->
 676 -- >    let x = I# r#
 677 -- >    in E
 678 -- > }
 679 --
 680 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 681 -- side effects, and can't diverge or raise an exception.
 682 exprOkForSpeculation :: CoreExpr -> Bool
 683 exprOkForSpeculation (Lit _)     = True
 684 exprOkForSpeculation (Type _)    = True
 685
 686 exprOkForSpeculation (Var v)
 687   | isTickBoxOp v = False     -- Tick boxes are *not* suitable for speculation
 688   | otherwise     =  isUnLiftedType (idType v)  -- c.f. the Var case of exprIsHNF
 689                   || isDataConWorkId v          -- Nullary constructors
 690                   || idArity v > 0              -- Functions
 691                   || isEvaldUnfolding (idUnfolding v)   -- Let-bound values
 692
 693 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 694 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 695
 696 exprOkForSpeculation (Case e _ _ alts)
 697   =  exprOkForSpeculation e  -- Note [exprOkForSpeculation: case expressions]
 698   && all (\(_,_,rhs) -> exprOkForSpeculation rhs) alts
 699
 700 exprOkForSpeculation other_expr
 701   = case collectArgs other_expr of
 702         (Var f, args) | f `hasKey` absentErrorIdKey     -- Note [Absent error Id]
 703                       -> all exprOkForSpeculation args  --    in WwLib
 704                       | otherwise
 705                       -> spec_ok (idDetails f) args
 706         _             -> False
 707
 708   where
 709     spec_ok (DataConWorkId _) _
 710       = True    -- The strictness of the constructor has already
 711                 -- been expressed by its "wrapper", so we don't need
 712                 -- to take the arguments into account
 713
 714     spec_ok (PrimOpId op) args
 715       | isDivOp op,             -- Special case for dividing operations that fail
 716         [arg1, Lit lit] <- args -- only if the divisor is zero
 717       = not (isZeroLit lit) && exprOkForSpeculation arg1
 718                 -- Often there is a literal divisor, and this
 719                 -- can get rid of a thunk in an inner looop
 720
 721       | DataToTagOp <- op      -- See Note [dataToTag speculation]
 722       = True
 723
 724       | otherwise
 725       = primOpOkForSpeculation op &&
 726         all exprOkForSpeculation args
 727                                 -- A bit conservative: we don't really need
 728                                 -- to care about lazy arguments, but this is easy
 729
 730     spec_ok (DFunId _ new_type) _ = not new_type
 731          -- DFuns terminate, unless the dict is implemented with a newtype
 732          -- in which case they may not
 733
 734     spec_ok _ _ = False
 735
 736 -- | True of dyadic operators that can fail only if the second arg is zero!
 737 isDivOp :: PrimOp -> Bool
 738 -- This function probably belongs in PrimOp, or even in
 739 -- an automagically generated file.. but it's such a
 740 -- special case I thought I'd leave it here for now.
 741 isDivOp IntQuotOp        = True
 742 isDivOp IntRemOp         = True
 743 isDivOp WordQuotOp       = True
 744 isDivOp WordRemOp        = True
 745 isDivOp FloatDivOp       = True
 746 isDivOp DoubleDivOp      = True
 747 isDivOp _                = False
 748 \end{code}
 749
 750 Note [exprOkForSpeculation: case expressions]
 751 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 752 It's always sound for exprOkForSpeculation to return False, and we
 753 don't want it to take too long, so it bales out on complicated-looking
 754 terms.  Notably lets, which can be stacked very deeply; and in any
 755 case the argument of exprOkForSpeculation is usually in a strict context,
 756 so any lets will have been floated away.
 757
 758 However, we keep going on case-expressions.  An example like this one
 759 showed up in DPH code (Trac #3717):
 760     foo :: Int -> Int
 761     foo 0 = 0
 762     foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
 763
 764 If exprOkForSpeculation doesn't look through case expressions, you get this:
 765     T.$wfoo =
 766       \ (ww :: GHC.Prim.Int#) ->
 767         case ww of ds {
 768           __DEFAULT -> case (case <# ds 5 of _ {
 769                           GHC.Types.False -> lvl1;
 770                           GHC.Types.True -> lvl})
 771                        of _ { __DEFAULT ->
 772                        T.$wfoo (GHC.Prim.-# ds_XkE 1) };
 773           0 -> 0
 774         }
 775
 776 The inner case is redundant, and should be nuked.
 777
 778 Note [dataToTag speculation]
 779 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 780 Is this OK?
 781    f x = let v::Int# = dataToTag# x
 782          in ...
 783 We say "yes", even though 'x' may not be evaluated.  Reasons
 784
 785   * dataToTag#'s strictness means that its argument often will be
 786     evaluated, but FloatOut makes that temporarily untrue
 787          case x of y -> let v = dataToTag# y in ...
 788     -->
 789          case x of y -> let v = dataToTag# x in ...
 790     Note that we look at 'x' instead of 'y' (this is to improve
 791     floating in FloatOut).  So Lint complains.
 792
 793     Moreover, it really *might* improve floating to let the
 794     v-binding float out
 795
 796   * CorePrep makes sure dataToTag#'s argument is evaluated, just
 797     before code gen.  Until then, it's not guaranteed
 798
 799
 800 %************************************************************************
 801 %*                                                                      *
 802              exprIsHNF, exprIsConLike
 803 %*                                                                      *
 804 %************************************************************************
 805
 806 \begin{code}
 807 -- Note [exprIsHNF]             See also Note [exprIsCheap and exprIsHNF]
 808 -- ~~~~~~~~~~~~~~~~
 809 -- | exprIsHNF returns true for expressions that are certainly /already/
 810 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 811 -- to change:
 812 --
 813 -- > case x of _ -> e
 814 --
 815 --    into:
 816 --
 817 -- > e
 818 --
 819 -- and to decide whether it's safe to discard a 'seq'.
 820 --
 821 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 822 -- However, it /does/ treat partial applications and constructor applications
 823 -- as values, even if their arguments are non-trivial, provided the argument
 824 -- type is lifted. For example, both of these are values:
 825 --
 826 -- > (:) (f x) (map f xs)
 827 -- > map (...redex...)
 828 --
 829 -- because 'seq' on such things completes immediately.
 830 --
 831 -- For unlifted argument types, we have to be careful:
 832 --
 833 -- > C (f x :: Int#)
 834 --
 835 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 836 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 837 -- unboxed type must be ok-for-speculation (or trivial).
 838 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 839 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 840 \end{code}
 841
 842 \begin{code}
 843 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 844 -- data constructors. Conlike arguments are considered interesting by the
 845 -- inliner.
 846 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 847 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 848
 849 -- | Returns true for values or value-like expressions. These are lambdas,
 850 -- constructors / CONLIKE functions (as determined by the function argument)
 851 -- or PAPs.
 852 --
 853 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 854 exprIsHNFlike is_con is_con_unf = is_hnf_like
 855   where
 856     is_hnf_like (Var v) -- NB: There are no value args at this point
 857       =  is_con v       -- Catches nullary constructors,
 858                         --      so that [] and () are values, for example
 859       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 860       || is_con_unf (idUnfolding v)
 861         -- Check the thing's unfolding; it might be bound to a value
 862         -- We don't look through loop breakers here, which is a bit conservative
 863         -- but otherwise I worry that if an Id's unfolding is just itself,
 864         -- we could get an infinite loop
 865
 866     is_hnf_like (Lit _)          = True
 867     is_hnf_like (Type _)         = True       -- Types are honorary Values;
 868                                               -- we don't mind copying them
 869     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 870     is_hnf_like (Note _ e)       = is_hnf_like e
 871     is_hnf_like (Cast e _)       = is_hnf_like e
 872     is_hnf_like (App e (Type _)) = is_hnf_like e
 873     is_hnf_like (App e a)        = app_is_value e [a]
 874     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 875     is_hnf_like _                = False
 876
 877     -- There is at least one value argument
 878     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 879     app_is_value (Var fun) args
 880       = idArity fun > valArgCount args    -- Under-applied function
 881         || is_con fun                     --  or constructor-like
 882     app_is_value (Note _ f) as = app_is_value f as
 883     app_is_value (Cast f _) as = app_is_value f as
 884     app_is_value (App f a)  as = app_is_value f (a:as)
 885     app_is_value _          _  = False
 886 \end{code}
 887
 888
 889 %************************************************************************
 890 %*                                                                      *
 891              Instantiating data constructors
 892 %*                                                                      *
 893 %************************************************************************
 894
 895 These InstPat functions go here to avoid circularity between DataCon and Id
 896
 897 \begin{code}
 898 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 899 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 900
 901 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 902 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 903 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 904   where
 905     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 906         -- Remember to include the existential dictionaries
 907
 908 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 909                   -> [FastString]          -- A long enough list of FSs to use for names
 910                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 911                   -> DataCon
 912                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 913                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 914 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 915 -- (ex_tvs, co_tvs, arg_ids),
 916 --
 917 --   ex_tvs are intended to be used as binders for existential type args
 918 --
 919 --   co_tvs are intended to be used as binders for coercion args and the kinds
 920 --     of these vars have been instantiated by the inst_tys and the ex_tys
 921 --     The co_tvs include both GADT equalities (dcEqSpec) and
 922 --     programmer-specified equalities (dcEqTheta)
 923 --
 924 --   arg_ids are indended to be used as binders for value arguments,
 925 --     and their types have been instantiated with inst_tys and ex_tys
 926 --     The arg_ids include both dicts (dcDictTheta) and
 927 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 928 --
 929 -- Example.
 930 --  The following constructor T1
 931 --
 932 --  data T a where
 933 --    T1 :: forall b. Int -> b -> T(a,b)
 934 --    ...
 935 --
 936 --  has representation type
 937 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 938 --     Int -> b -> T a
 939 --
 940 --  dataConInstPat fss us T1 (a1',b') will return
 941 --
 942 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 943 --
 944 --  where the double-primed variables are created with the FastStrings and
 945 --  Uniques given as fss and us
 946 dataConInstPat arg_fun fss uniqs con inst_tys
 947   = (ex_bndrs, co_bndrs, arg_ids)
 948   where
 949     univ_tvs = dataConUnivTyVars con
 950     ex_tvs   = dataConExTyVars con
 951     arg_tys  = arg_fun con
 952     eq_spec  = dataConEqSpec con
 953     eq_theta = dataConEqTheta con
 954     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 955
 956     n_ex = length ex_tvs
 957     n_co = length eq_preds
 958
 959       -- split the Uniques and FastStrings
 960     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 961     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 962
 963     (ex_fss, fss')     = splitAt n_ex fss
 964     (co_fss, id_fss)   = splitAt n_co fss'
 965
 966       -- Make existential type variables
 967     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 968     mk_ex_var uniq fs var = mkTyVar new_name kind
 969       where
 970         new_name = mkSysTvName uniq fs
 971         kind     = tyVarKind var
 972
 973       -- Make the instantiating substitution
 974     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 975
 976       -- Make new coercion vars, instantiating kind
 977     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 978     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 979        where
 980          new_name = mkSysTvName uniq fs
 981          co_kind  = substTy subst (mkPredTy eq_pred)
 982
 983       -- make value vars, instantiating types
 984     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 985     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 986
 987 \end{code}
 988
 989 %************************************************************************
 990 %*                                                                      *
 991          Equality
 992 %*                                                                      *
 993 %************************************************************************
 994
 995 \begin{code}
 996 -- | A cheap equality test which bales out fast!
 997 --      If it returns @True@ the arguments are definitely equal,
 998 --      otherwise, they may or may not be equal.
 999 --
1000 -- See also 'exprIsBig'
1001 cheapEqExpr :: Expr b -> Expr b -> Bool
1002
1003 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1004 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1005 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1006
1007 cheapEqExpr (App f1 a1) (App f2 a2)
1008   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1009
1010 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
1011   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
1012
1013 cheapEqExpr _ _ = False
1014 \end{code}
1015
1016 \begin{code}
1017 exprIsBig :: Expr b -> Bool
1018 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
1019 exprIsBig (Lit _)      = False
1020 exprIsBig (Var _)      = False
1021 exprIsBig (Type _)     = False
1022 exprIsBig (Lam _ e)    = exprIsBig e
1023 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1024 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1025 exprIsBig _            = True
1026 \end{code}
1027
1028 \begin{code}
1029 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
1030 -- Compares for equality, modulo alpha
1031 eqExpr in_scope e1 e2
1032   = eqExprX id_unf (mkRnEnv2 in_scope) e1 e2
1033   where
1034     id_unf _ = noUnfolding      -- Don't expand
1035 \end{code}
1036
1037 \begin{code}
1038 eqExprX :: IdUnfoldingFun -> RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1039 -- ^ Compares expressions for equality, modulo alpha.
1040 -- Does /not/ look through newtypes or predicate types
1041 -- Used in rule matching, and also CSE
1042
1043 eqExprX id_unfolding_fun env e1 e2
1044   = go env e1 e2
1045   where
1046     go env (Var v1) (Var v2)
1047       | rnOccL env v1 == rnOccR env v2
1048       = True
1049
1050     -- The next two rules expand non-local variables
1051     -- C.f. Note [Expanding variables] in Rules.lhs
1052     -- and  Note [Do not expand locally-bound variables] in Rules.lhs
1053     go env (Var v1) e2
1054       | not (locallyBoundL env v1)
1055       , Just e1' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v1))
1056       = go (nukeRnEnvL env) e1' e2
1057
1058     go env e1 (Var v2)
1059       | not (locallyBoundR env v2)
1060       , Just e2' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v2))
1061       = go (nukeRnEnvR env) e1 e2'
1062
1063     go _   (Lit lit1)    (Lit lit2)    = lit1 == lit2
1064     go env (Type t1)     (Type t2)     = tcEqTypeX env t1 t2
1065     go env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && go env e1 e2
1066     go env (App f1 a1)   (App f2 a2)   = go env f1 f2 && go env a1 a2
1067     go env (Note n1 e1)  (Note n2 e2)  = go_note n1 n2 && go env e1 e2
1068
1069     go env (Lam b1 e1)  (Lam b2 e2)
1070       =  tcEqTypeX env (varType b1) (varType b2)   -- False for Id/TyVar combination
1071       && go (rnBndr2 env b1 b2) e1 e2
1072
1073     go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1074       =  go env r1 r2  -- No need to check binder types, since RHSs match
1075       && go (rnBndr2 env v1 v2) e1 e2
1076
1077     go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1078       = all2 (go env') rs1 rs2 && go env' e1 e2
1079       where
1080         (bs1,rs1) = unzip ps1
1081         (bs2,rs2) = unzip ps2
1082         env' = rnBndrs2 env bs1 bs2
1083
1084     go env (Case e1 b1 _ a1) (Case e2 b2 _ a2)
1085       =  go env e1 e2
1086       && tcEqTypeX env (idType b1) (idType b2)
1087       && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1088
1089     go _ _ _ = False
1090
1091     -----------
1092     go_alt env (c1, bs1, e1) (c2, bs2, e2)
1093       = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1094
1095     -----------
1096     go_note (SCC cc1)     (SCC cc2)      = cc1 == cc2
1097     go_note (CoreNote s1) (CoreNote s2)  = s1 == s2
1098     go_note _             _              = False
1099 \end{code}
1100
1101 Auxiliary functions
1102
1103 \begin{code}
1104 locallyBoundL, locallyBoundR :: RnEnv2 -> Var -> Bool
1105 locallyBoundL rn_env v = inRnEnvL rn_env v
1106 locallyBoundR rn_env v = inRnEnvR rn_env v
1107 \end{code}
1108
1109
1110 %************************************************************************
1111 %*                                                                      *
1112 \subsection{The size of an expression}
1113 %*                                                                      *
1114 %************************************************************************
1115
1116 \begin{code}
1117 coreBindsSize :: [CoreBind] -> Int
1118 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1119
1120 exprSize :: CoreExpr -> Int
1121 -- ^ A measure of the size of the expressions, strictly greater than 0
1122 -- It also forces the expression pretty drastically as a side effect
1123 exprSize (Var v)         = v `seq` 1
1124 exprSize (Lit lit)       = lit `seq` 1
1125 exprSize (App f a)       = exprSize f + exprSize a
1126 exprSize (Lam b e)       = varSize b + exprSize e
1127 exprSize (Let b e)       = bindSize b + exprSize e
1128 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1129 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1130 exprSize (Note n e)      = noteSize n + exprSize e
1131 exprSize (Type t)        = seqType t `seq` 1
1132
1133 noteSize :: Note -> Int
1134 noteSize (SCC cc)       = cc `seq` 1
1135 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1136
1137 varSize :: Var -> Int
1138 varSize b  | isTyCoVar b = 1
1139            | otherwise = seqType (idType b)             `seq`
1140                          megaSeqIdInfo (idInfo b)       `seq`
1141                          1
1142
1143 varsSize :: [Var] -> Int
1144 varsSize = sum . map varSize
1145
1146 bindSize :: CoreBind -> Int
1147 bindSize (NonRec b e) = varSize b + exprSize e
1148 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1149
1150 pairSize :: (Var, CoreExpr) -> Int
1151 pairSize (b,e) = varSize b + exprSize e
1152
1153 altSize :: CoreAlt -> Int
1154 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1155 \end{code}
1156
1157
1158 %************************************************************************
1159 %*                                                                      *
1160 \subsection{Hashing}
1161 %*                                                                      *
1162 %************************************************************************
1163
1164 \begin{code}
1165 hashExpr :: CoreExpr -> Int
1166 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1167 -- Two expressions that hash to the different Ints are definitely unequal.
1168 --
1169 -- The emphasis is on a crude, fast hash, rather than on high precision.
1170 --
1171 -- But unequal here means \"not identical\"; two alpha-equivalent
1172 -- expressions may hash to the different Ints.
1173 --
1174 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1175 -- (at least if we want the above invariant to be true).
1176
1177 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1178              -- UniqFM doesn't like negative Ints
1179
1180 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1181
1182 hash_expr :: HashEnv -> CoreExpr -> Word32
1183 -- Word32, because we're expecting overflows here, and overflowing
1184 -- signed types just isn't cool.  In C it's even undefined.
1185 hash_expr env (Note _ e)              = hash_expr env e
1186 hash_expr env (Cast e _)              = hash_expr env e
1187 hash_expr env (Var v)                 = hashVar env v
1188 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1189 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1190 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1191 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1192 hash_expr env (Case e _ _ _)          = hash_expr env e
1193 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1194 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1195 -- Shouldn't happen.  Better to use WARN than trace, because trace
1196 -- prevents the CPR optimisation kicking in for hash_expr.
1197
1198 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1199 fast_hash_expr env (Var v)      = hashVar env v
1200 fast_hash_expr env (Type t)     = fast_hash_type env t
1201 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1202 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1203 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1204 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1205 fast_hash_expr _   _            = 1
1206
1207 fast_hash_type :: HashEnv -> Type -> Word32
1208 fast_hash_type env ty
1209   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1210   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1211                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1212   | otherwise                               = 1
1213
1214 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1215 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1216
1217 hashVar :: HashEnv -> Var -> Word32
1218 hashVar (_,env) v
1219  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1220 \end{code}
1221
1222
1223 %************************************************************************
1224 %*                                                                      *
1225                 Eta reduction
1226 %*                                                                      *
1227 %************************************************************************
1228
1229 Note [Eta reduction conditions]
1230 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1231 We try for eta reduction here, but *only* if we get all the way to an
1232 trivial expression.  We don't want to remove extra lambdas unless we
1233 are going to avoid allocating this thing altogether.
1234
1235 There are some particularly delicate points here:
1236
1237 * Eta reduction is not valid in general:
1238         \x. bot  /=  bot
1239   This matters, partly for old-fashioned correctness reasons but,
1240   worse, getting it wrong can yield a seg fault. Consider
1241         f = \x.f x
1242         h y = case (case y of { True -> f `seq` True; False -> False }) of
1243                 True -> ...; False -> ...
1244
1245   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
1246   says f=bottom, and replaces the (f `seq` True) with just
1247   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
1248   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
1249   the definition again, so that it does not termninate after all.
1250   Result: seg-fault because the boolean case actually gets a function value.
1251   See Trac #1947.
1252
1253   So it's important to to the right thing.
1254
1255 * Note [Arity care]: we need to be careful if we just look at f's
1256   arity. Currently (Dec07), f's arity is visible in its own RHS (see
1257   Note [Arity robustness] in SimplEnv) so we must *not* trust the
1258   arity when checking that 'f' is a value.  Otherwise we will
1259   eta-reduce
1260       f = \x. f x
1261   to
1262       f = f
1263   Which might change a terminiating program (think (f `seq` e)) to a
1264   non-terminating one.  So we check for being a loop breaker first.
1265
1266   However for GlobalIds we can look at the arity; and for primops we
1267   must, since they have no unfolding.
1268
1269 * Regardless of whether 'f' is a value, we always want to
1270   reduce (/\a -> f a) to f
1271   This came up in a RULE: foldr (build (/\a -> g a))
1272   did not match           foldr (build (/\b -> ...something complex...))
1273   The type checker can insert these eta-expanded versions,
1274   with both type and dictionary lambdas; hence the slightly
1275   ad-hoc isDictId
1276
1277 * Never *reduce* arity. For example
1278       f = \xy. g x y
1279   Then if h has arity 1 we don't want to eta-reduce because then
1280   f's arity would decrease, and that is bad
1281
1282 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1283 Alas.
1284
1285 Note [Eta reduction with casted arguments]
1286 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1287 Consider
1288     (\(x:t3). f (x |> g)) :: t3 -> t2
1289   where
1290     f :: t1 -> t2
1291     g :: t3 ~ t1
1292 This should be eta-reduced to
1293
1294     f |> (sym g -> t2)
1295
1296 So we need to accumulate a coercion, pushing it inward (past
1297 variable arguments only) thus:
1298    f (x |> co_arg) |> co  -->  (f |> (sym co_arg -> co)) x
1299    f (x:t)         |> co  -->  (f |> (t -> co)) x
1300    f @ a           |> co  -->  (f |> (forall a.co)) @ a
1301    f @ (g:t1~t2)   |> co  -->  (f |> (t1~t2 => co)) @ (g:t1~t2)
1302 These are the equations for ok_arg.
1303
1304 It's true that we could also hope to eta reduce these:
1305     (\xy. (f x |> g) y)
1306     (\xy. (f x y) |> g)
1307 But the simplifier pushes those casts outwards, so we don't
1308 need to address that here.
1309
1310 \begin{code}
1311 tryEtaReduce :: [Var] -> CoreExpr -> Maybe CoreExpr
1312 tryEtaReduce bndrs body
1313   = go (reverse bndrs) body (IdCo (exprType body))
1314   where
1315     incoming_arity = count isId bndrs
1316
1317     go :: [Var]            -- Binders, innermost first, types [a3,a2,a1]
1318        -> CoreExpr         -- Of type tr
1319        -> CoercionI        -- Of type tr ~ ts
1320        -> Maybe CoreExpr   -- Of type a1 -> a2 -> a3 -> ts
1321     -- See Note [Eta reduction with casted arguments]
1322     -- for why we have an accumulating coercion
1323     go [] fun co
1324       | ok_fun fun = Just (mkCoerceI co fun)
1325
1326     go (b : bs) (App fun arg) co
1327       | Just co' <- ok_arg b arg co
1328       = go bs fun co'
1329
1330     go _ _ _  = Nothing         -- Failure!
1331
1332     ---------------
1333     -- Note [Eta reduction conditions]
1334     ok_fun (App fun (Type ty))
1335         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1336         =  ok_fun fun
1337     ok_fun (Var fun_id)
1338         =  not (fun_id `elem` bndrs)
1339         && (ok_fun_id fun_id || all ok_lam bndrs)
1340     ok_fun _fun = False
1341
1342     ---------------
1343     ok_fun_id fun = fun_arity fun >= incoming_arity
1344
1345     ---------------
1346     fun_arity fun             -- See Note [Arity care]
1347        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1348        | otherwise = idArity fun
1349
1350     ---------------
1351     ok_lam v = isTyCoVar v || isDictId v
1352
1353     ---------------
1354     ok_arg :: Var               -- Of type bndr_t
1355            -> CoreExpr          -- Of type arg_t
1356            -> CoercionI         -- Of kind (t1~t2)
1357            -> Maybe CoercionI   -- Of type (arg_t -> t1 ~  bndr_t -> t2)
1358                                 --   (and similarly for tyvars, coercion args)
1359     -- See Note [Eta reduction with casted arguments]
1360     ok_arg bndr (Type ty) co
1361        | Just tv <- getTyVar_maybe ty
1362        , bndr == tv  = Just (mkForAllTyCoI tv co)
1363     ok_arg bndr (Var v) co
1364        | bndr == v   = Just (mkFunTyCoI (IdCo (idType bndr)) co)
1365     ok_arg bndr (Cast (Var v) co_arg) co
1366        | bndr == v  = Just (mkFunTyCoI (ACo (mkSymCoercion co_arg)) co)
1367        -- The simplifier combines multiple casts into one,
1368        -- so we can have a simple-minded pattern match here
1369     ok_arg _ _ _ = Nothing
1370 \end{code}
1371
1372
1373 %************************************************************************
1374 %*                                                                      *
1375 \subsection{Determining non-updatable right-hand-sides}
1376 %*                                                                      *
1377 %************************************************************************
1378
1379 Top-level constructor applications can usually be allocated
1380 statically, but they can't if the constructor, or any of the
1381 arguments, come from another DLL (because we can't refer to static
1382 labels in other DLLs).
1383
1384 If this happens we simply make the RHS into an updatable thunk,
1385 and 'execute' it rather than allocating it statically.
1386
1387 \begin{code}
1388 -- | This function is called only on *top-level* right-hand sides.
1389 -- Returns @True@ if the RHS can be allocated statically in the output,
1390 -- with no thunks involved at all.
1391 rhsIsStatic :: (Name -> Bool) -> CoreExpr -> Bool
1392 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1393 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1394 -- update flag on it and (iii) in DsExpr to decide how to expand
1395 -- list literals
1396 --
1397 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1398 --      (a) a value lambda
1399 --      (b) a saturated constructor application with static args
1400 --
1401 -- BUT watch out for
1402 --  (i) Any cross-DLL references kill static-ness completely
1403 --      because they must be 'executed' not statically allocated
1404 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1405 --      this is not necessary)
1406 --
1407 -- (ii) We treat partial applications as redexes, because in fact we
1408 --      make a thunk for them that runs and builds a PAP
1409 --      at run-time.  The only appliations that are treated as
1410 --      static are *saturated* applications of constructors.
1411
1412 -- We used to try to be clever with nested structures like this:
1413 --              ys = (:) w ((:) w [])
1414 -- on the grounds that CorePrep will flatten ANF-ise it later.
1415 -- But supporting this special case made the function much more
1416 -- complicated, because the special case only applies if there are no
1417 -- enclosing type lambdas:
1418 --              ys = /\ a -> Foo (Baz ([] a))
1419 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1420 --
1421 -- But in fact, even without -O, nested structures at top level are
1422 -- flattened by the simplifier, so we don't need to be super-clever here.
1423 --
1424 -- Examples
1425 --
1426 --      f = \x::Int. x+7        TRUE
1427 --      p = (True,False)        TRUE
1428 --
1429 --      d = (fst p, False)      FALSE because there's a redex inside
1430 --                              (this particular one doesn't happen but...)
1431 --
1432 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1433 --      n = /\a. Nil a                  TRUE
1434 --
1435 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1436 --
1437 --
1438 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1439 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1440 --
1441 --    b) (C x xs), where C is a contructor is updatable if the application is
1442 --         dynamic
1443 --
1444 --    c) don't look through unfolding of f in (f x).
1445
1446 rhsIsStatic _is_dynamic_name rhs = is_static False rhs
1447   where
1448   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1449           -> CoreExpr -> Bool
1450
1451   is_static False (Lam b e)   = isRuntimeVar b || is_static False e
1452   is_static in_arg (Note n e) = notSccNote n && is_static in_arg e
1453   is_static in_arg (Cast e _) = is_static in_arg e
1454
1455   is_static _      (Lit lit)
1456     = case lit of
1457         MachLabel _ _ _ -> False
1458         _             -> True
1459         -- A MachLabel (foreign import "&foo") in an argument
1460         -- prevents a constructor application from being static.  The
1461         -- reason is that it might give rise to unresolvable symbols
1462         -- in the object file: under Linux, references to "weak"
1463         -- symbols from the data segment give rise to "unresolvable
1464         -- relocation" errors at link time This might be due to a bug
1465         -- in the linker, but we'll work around it here anyway.
1466         -- SDM 24/2/2004
1467
1468   is_static in_arg other_expr = go other_expr 0
1469    where
1470     go (Var f) n_val_args
1471 #if mingw32_TARGET_OS
1472         | not (_is_dynamic_name (idName f))
1473 #endif
1474         =  saturated_data_con f n_val_args
1475         || (in_arg && n_val_args == 0)
1476                 -- A naked un-applied variable is *not* deemed a static RHS
1477                 -- E.g.         f = g
1478                 -- Reason: better to update so that the indirection gets shorted
1479                 --         out, and the true value will be seen
1480                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1481                 --     are always updatable.  If you do so, make sure that non-updatable
1482                 --     ones have enough space for their static link field!
1483
1484     go (App f a) n_val_args
1485         | isTypeArg a                    = go f n_val_args
1486         | not in_arg && is_static True a = go f (n_val_args + 1)
1487         -- The (not in_arg) checks that we aren't in a constructor argument;
1488         -- if we are, we don't allow (value) applications of any sort
1489         --
1490         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1491         --   x = D# (1.0## /## 2.0##)
1492         -- can't float because /## can fail.
1493
1494     go (Note n f) n_val_args = notSccNote n && go f n_val_args
1495     go (Cast e _) n_val_args = go e n_val_args
1496     go _          _          = False
1497
1498     saturated_data_con f n_val_args
1499         = case isDataConWorkId_maybe f of
1500             Just dc -> n_val_args == dataConRepArity dc
1501             Nothing -> False
1502 \end{code}