compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsBottom,
  29         exprIsCheap, exprIsExpandable, exprIsCheap', CheapAppFun,
  30         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  31         rhsIsStatic, isCheapApp, isExpandableApp,
  32
  33         -- * Expression and bindings size
  34         coreBindsSize, exprSize,
  35
  36         -- * Hashing
  37         hashExpr,
  38
  39         -- * Equality
  40         cheapEqExpr, eqExpr, eqExprX,
  41
  42         -- * Eta reduction
  43         tryEtaReduce,
  44
  45         -- * Manipulating data constructors and types
  46         applyTypeToArgs, applyTypeToArg,
  47         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  48     ) where
  49
  50 #include "HsVersions.h"
  51
  52 import CoreSyn
  53 import PprCore
  54 import Var
  55 import SrcLoc
  56 import VarEnv
  57 import VarSet
  58 import Name
  59 import Literal
  60 import DataCon
  61 import PrimOp
  62 import Id
  63 import IdInfo
  64 import TcType   ( isPredTy )
  65 import Type
  66 import Coercion
  67 import TyCon
  68 import CostCentre
  69 import Unique
  70 import Outputable
  71 import TysPrim
  72 import PrelNames( absentErrorIdKey )
  73 import FastString
  74 import Maybes
  75 import Util
  76 import Data.Word
  77 import Data.Bits
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89 -- ^ Recover the type of a well-typed Core expression. Fails when
  90 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  91 -- really be said to have a type
  92 exprType (Var var)           = idType var
  93 exprType (Lit lit)           = literalType lit
  94 exprType (Let _ body)        = exprType body
  95 exprType (Case _ _ ty _)     = ty
  96 exprType (Cast _ co)         = snd (coercionKind co)
  97 exprType (Note _ e)          = exprType e
  98 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  99 exprType e@(App _ _)
 100   = case collectArgs e of
 101         (fun, args) -> applyTypeToArgs e (exprType fun) args
 102
 103 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 104
 105 coreAltType :: CoreAlt -> Type
 106 -- ^ Returns the type of the alternatives right hand side
 107 coreAltType (_,bs,rhs)
 108   | any bad_binder bs = expandTypeSynonyms ty
 109   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 110   where
 111     ty           = exprType rhs
 112     free_tvs     = tyVarsOfType ty
 113     bad_binder b = isTyCoVar b && b `elemVarSet` free_tvs
 114
 115 coreAltsType :: [CoreAlt] -> Type
 116 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 117 coreAltsType (alt:_) = coreAltType alt
 118 coreAltsType []      = panic "corAltsType"
 119 \end{code}
 120
 121 Note [Existential variables and silly type synonyms]
 122 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 123 Consider
 124         data T = forall a. T (Funny a)
 125         type Funny a = Bool
 126         f :: T -> Bool
 127         f (T x) = x
 128
 129 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 130 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 131 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 132 example.
 133
 134 Various possibilities suggest themselves:
 135
 136  - Ignore the problem, and make Lint not complain about such variables
 137
 138  - Expand all type synonyms (or at least all those that discard arguments)
 139       This is tricky, because at least for top-level things we want to
 140       retain the type the user originally specified.
 141
 142  - Expand synonyms on the fly, when the problem arises. That is what
 143    we are doing here.  It's not too expensive, I think.
 144
 145 \begin{code}
 146 mkPiType  :: EvVar -> Type -> Type
 147 -- ^ Makes a @(->)@ type or a forall type, depending
 148 -- on whether it is given a type variable or a term variable.
 149 mkPiTypes :: [EvVar] -> Type -> Type
 150 -- ^ 'mkPiType' for multiple type or value arguments
 151
 152 mkPiType v ty
 153    | isId v    = mkFunTy (idType v) ty
 154    | otherwise = mkForAllTy v ty
 155
 156 mkPiTypes vs ty = foldr mkPiType ty vs
 157 \end{code}
 158
 159 \begin{code}
 160 applyTypeToArg :: Type -> CoreExpr -> Type
 161 -- ^ Determines the type resulting from applying an expression to a function with the given type
 162 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 163 applyTypeToArg fun_ty _             = funResultTy fun_ty
 164
 165 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 166 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 167 -- The first argument is just for debugging, and gives some context
 168 applyTypeToArgs _ op_ty [] = op_ty
 169
 170 applyTypeToArgs e op_ty (Type ty : args)
 171   =     -- Accumulate type arguments so we can instantiate all at once
 172     go [ty] args
 173   where
 174     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 175     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 176                                 where
 177                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 178                                   msg = ptext (sLit "applyTypeToArgs") <+>
 179                                         panic_msg e op_ty
 180
 181 applyTypeToArgs e op_ty (_ : args)
 182   = case (splitFunTy_maybe op_ty) of
 183         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 184         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 185
 186 panic_msg :: CoreExpr -> Type -> SDoc
 187 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192 \subsection{Attaching notes}
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 198 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 199 mkCoerceI (IdCo _) e = e
 200 mkCoerceI (ACo co) e = mkCoerce co e
 201
 202 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 203 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 204 mkCoerce co (Cast expr co2)
 205   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 206                  (_from_ty2, to_ty2) = coercionKind co2} in
 207            from_ty `coreEqType` to_ty2 )
 208     mkCoerce (mkTransCoercion co2 co) expr
 209
 210 mkCoerce co expr
 211   = let (from_ty, _to_ty) = coercionKind co in
 212 --    if to_ty `coreEqType` from_ty
 213 --    then expr
 214 --    else
 215         WARN(not (from_ty `coreEqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 216          (Cast expr co)
 217 \end{code}
 218
 219 \begin{code}
 220 -- | Wraps the given expression in the cost centre unless
 221 -- in a way that maximises their utility to the user
 222 mkSCC :: CostCentre -> Expr b -> Expr b
 223         -- Note: Nested SCC's *are* preserved for the benefit of
 224         --       cost centre stack profiling
 225 mkSCC _  (Lit lit)          = Lit lit
 226 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 227 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 228 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 229 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 230 mkSCC cc expr               = Note (SCC cc) expr
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Other expression construction}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 \begin{code}
 241 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 242 -- ^ @bindNonRec x r b@ produces either:
 243 --
 244 -- > let x = r in b
 245 --
 246 -- or:
 247 --
 248 -- > case r of x { _DEFAULT_ -> b }
 249 --
 250 -- depending on whether we have to use a @case@ or @let@
 251 -- binding for the expression (see 'needsCaseBinding').
 252 -- It's used by the desugarer to avoid building bindings
 253 -- that give Core Lint a heart attack, although actually
 254 -- the simplifier deals with them perfectly well. See
 255 -- also 'MkCore.mkCoreLet'
 256 bindNonRec bndr rhs body
 257   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 258   | otherwise                          = Let (NonRec bndr rhs) body
 259
 260 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 261 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 262 needsCaseBinding :: Type -> CoreExpr -> Bool
 263 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 264         -- Make a case expression instead of a let
 265         -- These can arise either from the desugarer,
 266         -- or from beta reductions: (\x.e) (x +# y)
 267 \end{code}
 268
 269 \begin{code}
 270 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 271           -> [CoreBndr] -- ^ Things bound by the pattern match
 272           -> [Type]     -- ^ The type arguments to the case alternative
 273           -> CoreExpr
 274 -- ^ This guy constructs the value that the scrutinee must have
 275 -- given that you are in one particular branch of a case
 276 mkAltExpr (DataAlt con) args inst_tys
 277   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 278 mkAltExpr (LitAlt lit) [] []
 279   = Lit lit
 280 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 281 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 282 \end{code}
 283
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection{Taking expressions apart}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 The default alternative must be first, if it exists at all.
 292 This makes it easy to find, though it makes matching marginally harder.
 293
 294 \begin{code}
 295 -- | Extract the default case alternative
 296 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 297 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 298 findDefault alts                        =                     (alts, Nothing)
 299
 300 isDefaultAlt :: CoreAlt -> Bool
 301 isDefaultAlt (DEFAULT, _, _) = True
 302 isDefaultAlt _               = False
 303
 304
 305 -- | Find the case alternative corresponding to a particular
 306 -- constructor: panics if no such constructor exists
 307 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 308     -- A "Nothing" result *is* legitmiate
 309     -- See Note [Unreachable code]
 310 findAlt con alts
 311   = case alts of
 312         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 313         _                          -> go alts Nothing
 314   where
 315     go []                     deflt = deflt
 316     go (alt@(con1,_,_) : alts) deflt
 317       = case con `cmpAltCon` con1 of
 318           LT -> deflt   -- Missed it already; the alts are in increasing order
 319           EQ -> Just alt
 320           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 321
 322 ---------------------------------
 323 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 324 -- ^ Merge alternatives preserving order; alternatives in
 325 -- the first argument shadow ones in the second
 326 mergeAlts [] as2 = as2
 327 mergeAlts as1 [] = as1
 328 mergeAlts (a1:as1) (a2:as2)
 329   = case a1 `cmpAlt` a2 of
 330         LT -> a1 : mergeAlts as1      (a2:as2)
 331         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 332         GT -> a2 : mergeAlts (a1:as1) as2
 333
 334
 335 ---------------------------------
 336 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 337 -- ^ Given:
 338 --
 339 -- > case (C a b x y) of
 340 -- >        C b x y -> ...
 341 --
 342 -- We want to drop the leading type argument of the scrutinee
 343 -- leaving the arguments to match agains the pattern
 344
 345 trimConArgs DEFAULT      args = ASSERT( null args ) []
 346 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 347 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 348 \end{code}
 349
 350 Note [Unreachable code]
 351 ~~~~~~~~~~~~~~~~~~~~~~~
 352 It is possible (although unusual) for GHC to find a case expression
 353 that cannot match.  For example:
 354
 355      data Col = Red | Green | Blue
 356      x = Red
 357      f v = case x of
 358               Red -> ...
 359               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 360
 361 Suppose that for some silly reason, x isn't substituted in the case
 362 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 363 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 364 this
 365
 366      x = Red
 367      lvl = case x of { Green -> e1; Blue -> e2 })
 368      f v = case x of
 369              Red -> ...
 370              _ -> ...lvl...
 371
 372 Now if x gets inlined, we won't be able to find a matching alternative
 373 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 374 we generate (error "Inaccessible alternative").
 375
 376 Similar things can happen (augmented by GADTs) when the Simplifier
 377 filters down the matching alternatives in Simplify.rebuildCase.
 378
 379
 380 %************************************************************************
 381 %*                                                                      *
 382              exprIsTrivial
 383 %*                                                                      *
 384 %************************************************************************
 385
 386 Note [exprIsTrivial]
 387 ~~~~~~~~~~~~~~~~~~~~
 388 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 389                 duplicate; simple variables and constants, and type
 390                 applications.  Note that primop Ids aren't considered
 391                 trivial unless
 392
 393 Note [Variable are trivial]
 394 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 395 There used to be a gruesome test for (hasNoBinding v) in the
 396 Var case:
 397         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 398 The idea here is that a constructor worker, like \$wJust, is
 399 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 400 So it should be treated like a lambda.  Ditto unsaturated primops.
 401 But now constructor workers are not "have-no-binding" Ids.  And
 402 completely un-applied primops and foreign-call Ids are sufficiently
 403 rare that I plan to allow them to be duplicated and put up with
 404 saturating them.
 405
 406 Note [SCCs are trivial]
 407 ~~~~~~~~~~~~~~~~~~~~~~~
 408 We used not to treat (_scc_ "foo" x) as trivial, because it really
 409 generates code, (and a heap object when it's a function arg) to
 410 capture the cost centre.  However, the profiling system discounts the
 411 allocation costs for such "boxing thunks" whereas the extra costs of
 412 *not* inlining otherwise-trivial bindings can be high, and are hard to
 413 discount.
 414
 415 \begin{code}
 416 exprIsTrivial :: CoreExpr -> Bool
 417 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 418 exprIsTrivial (Type _)         = True
 419 exprIsTrivial (Lit lit)        = litIsTrivial lit
 420 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 421 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 422 exprIsTrivial (Cast e _)       = exprIsTrivial e
 423 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 424 exprIsTrivial _                = False
 425 \end{code}
 426
 427 exprIsBottom is a very cheap and cheerful function; it may return
 428 False for bottoming expressions, but it never costs much to ask.
 429 See also CoreArity.exprBotStrictness_maybe, but that's a bit more
 430 expensive.
 431
 432 \begin{code}
 433 exprIsBottom :: CoreExpr -> Bool
 434 exprIsBottom e
 435   = go 0 e
 436   where
 437     go n (Var v) = isBottomingId v &&  n >= idArity v
 438     go n (App e a) | isTypeArg a = go n e
 439                    | otherwise   = go (n+1) e
 440     go n (Note _ e)              = go n e
 441     go n (Cast e _)              = go n e
 442     go n (Let _ e)               = go n e
 443     go _ _                       = False
 444 \end{code}
 445
 446
 447 %************************************************************************
 448 %*                                                                      *
 449              exprIsDupable
 450 %*                                                                      *
 451 %************************************************************************
 452
 453 Note [exprIsDupable]
 454 ~~~~~~~~~~~~~~~~~~~~
 455 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 456                 cost in code size.  This will only happen in different case
 457                 branches, so there's no issue about duplicating work.
 458
 459                 That is, exprIsDupable returns True of (f x) even if
 460                 f is very very expensive to call.
 461
 462                 Its only purpose is to avoid fruitless let-binding
 463                 and then inlining of case join points
 464
 465
 466 \begin{code}
 467 exprIsDupable :: CoreExpr -> Bool
 468 exprIsDupable (Type _)   = True
 469 exprIsDupable (Var _)    = True
 470 exprIsDupable (Lit lit)  = litIsDupable lit
 471 exprIsDupable (Note _ e) = exprIsDupable e
 472 exprIsDupable (Cast e _) = exprIsDupable e
 473 exprIsDupable expr
 474   = go expr 0
 475   where
 476     go (Var _)   _      = True
 477     go (App f a) n_args =  n_args < dupAppSize
 478                         && exprIsDupable a
 479                         && go f (n_args+1)
 480     go _         _      = False
 481
 482 dupAppSize :: Int
 483 dupAppSize = 4          -- Size of application we are prepared to duplicate
 484 \end{code}
 485
 486 %************************************************************************
 487 %*                                                                      *
 488              exprIsCheap, exprIsExpandable
 489 %*                                                                      *
 490 %************************************************************************
 491
 492 Note [exprIsCheap]   See also Note [Interaction of exprIsCheap and lone variables]
 493 ~~~~~~~~~~~~~~~~~~   in CoreUnfold.lhs
 494 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 495 it is obviously in weak head normal form, or is cheap to get to WHNF.
 496 [Note that that's not the same as exprIsDupable; an expression might be
 497 big, and hence not dupable, but still cheap.]
 498
 499 By ``cheap'' we mean a computation we're willing to:
 500         push inside a lambda, or
 501         inline at more than one place
 502 That might mean it gets evaluated more than once, instead of being
 503 shared.  The main examples of things which aren't WHNF but are
 504 ``cheap'' are:
 505
 506   *     case e of
 507           pi -> ei
 508         (where e, and all the ei are cheap)
 509
 510   *     let x = e in b
 511         (where e and b are cheap)
 512
 513   *     op x1 ... xn
 514         (where op is a cheap primitive operator)
 515
 516   *     error "foo"
 517         (because we are happy to substitute it inside a lambda)
 518
 519 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 520 because sharing will make sure it is only evaluated once.
 521
 522 Note [exprIsCheap and exprIsHNF]
 523 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 524 Note that exprIsHNF does not imply exprIsCheap.  Eg
 525         let x = fac 20 in Just x
 526 This responds True to exprIsHNF (you can discard a seq), but
 527 False to exprIsCheap.
 528
 529 \begin{code}
 530 exprIsCheap :: CoreExpr -> Bool
 531 exprIsCheap = exprIsCheap' isCheapApp
 532
 533 exprIsExpandable :: CoreExpr -> Bool
 534 exprIsExpandable = exprIsCheap' isExpandableApp -- See Note [CONLIKE pragma] in BasicTypes
 535
 536 type CheapAppFun = Id -> Int -> Bool
 537 exprIsCheap' :: CheapAppFun -> CoreExpr -> Bool
 538 exprIsCheap' _          (Lit _)   = True
 539 exprIsCheap' _          (Type _)  = True
 540 exprIsCheap' _          (Var _)   = True
 541 exprIsCheap' good_app (Note _ e)  = exprIsCheap' good_app e
 542 exprIsCheap' good_app (Cast e _)  = exprIsCheap' good_app e
 543 exprIsCheap' good_app (Lam x e)   = isRuntimeVar x
 544                                  || exprIsCheap' good_app e
 545
 546 exprIsCheap' good_app (Case e _ _ alts) = exprIsCheap' good_app e &&
 547                                           and [exprIsCheap' good_app rhs | (_,_,rhs) <- alts]
 548         -- Experimentally, treat (case x of ...) as cheap
 549         -- (and case __coerce x etc.)
 550         -- This improves arities of overloaded functions where
 551         -- there is only dictionary selection (no construction) involved
 552
 553 exprIsCheap' good_app (Let (NonRec x _) e)
 554   | isUnLiftedType (idType x) = exprIsCheap' good_app e
 555   | otherwise                 = False
 556         -- Strict lets always have cheap right hand sides,
 557         -- and do no allocation, so just look at the body
 558         -- Non-strict lets do allocation so we don't treat them as cheap
 559         -- See also
 560
 561 exprIsCheap' good_app other_expr        -- Applications and variables
 562   = go other_expr []
 563   where
 564         -- Accumulate value arguments, then decide
 565     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 566                           | otherwise      = go f val_args
 567
 568     go (Var _) [] = True        -- Just a type application of a variable
 569                                 -- (f t1 t2 t3) counts as WHNF
 570     go (Var f) args
 571         = case idDetails f of
 572                 RecSelId {}                  -> go_sel args
 573                 ClassOpId {}                 -> go_sel args
 574                 PrimOpId op                  -> go_primop op args
 575                 _ | good_app f (length args) -> go_pap args
 576                   | isBottomingId f          -> True
 577                   | otherwise                -> False
 578                         -- Application of a function which
 579                         -- always gives bottom; we treat this as cheap
 580                         -- because it certainly doesn't need to be shared!
 581
 582     go _ _ = False
 583
 584     --------------
 585     go_pap args = all exprIsTrivial args
 586         -- For constructor applications and primops, check that all
 587         -- the args are trivial.  We don't want to treat as cheap, say,
 588         --      (1:2:3:4:5:[])
 589         -- We'll put up with one constructor application, but not dozens
 590
 591     --------------
 592     go_primop op args = primOpIsCheap op && all (exprIsCheap' good_app) args
 593         -- In principle we should worry about primops
 594         -- that return a type variable, since the result
 595         -- might be applied to something, but I'm not going
 596         -- to bother to check the number of args
 597
 598     --------------
 599     go_sel [arg] = exprIsCheap' good_app arg    -- I'm experimenting with making record selection
 600     go_sel _     = False                -- look cheap, so we will substitute it inside a
 601                                         -- lambda.  Particularly for dictionary field selection.
 602                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 603                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 604
 605 isCheapApp :: CheapAppFun
 606 isCheapApp fn n_val_args
 607   = isDataConWorkId fn
 608   || n_val_args < idArity fn
 609
 610 isExpandableApp :: CheapAppFun
 611 isExpandableApp fn n_val_args
 612   =  isConLikeId fn
 613   || n_val_args < idArity fn
 614   || go n_val_args (idType fn)
 615   where
 616   -- See if all the arguments are PredTys (implicit params or classes)
 617   -- If so we'll regard it as expandable; see Note [Expandable overloadings]
 618      go 0 _ = True
 619      go n_val_args ty
 620        | Just (_, ty) <- splitForAllTy_maybe ty   = go n_val_args ty
 621        | Just (arg, ty) <- splitFunTy_maybe ty
 622        , isPredTy arg                             = go (n_val_args-1) ty
 623        | otherwise                                = False
 624 \end{code}
 625
 626 Note [Expandable overloadings]
 627 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 628 Suppose the user wrote this
 629    {-# RULE  forall x. foo (negate x) = h x #-}
 630    f x = ....(foo (negate x))....
 631 He'd expect the rule to fire. But since negate is overloaded, we might
 632 get this:
 633     f = \d -> let n = negate d in \x -> ...foo (n x)...
 634 So we treat the application of a function (negate in this case) to a
 635 *dictionary* as expandable.  In effect, every function is CONLIKE when
 636 it's applied only to dictionaries.
 637
 638
 639 %************************************************************************
 640 %*                                                                      *
 641              exprOkForSpeculation
 642 %*                                                                      *
 643 %************************************************************************
 644
 645 \begin{code}
 646 -- | 'exprOkForSpeculation' returns True of an expression that is:
 647 --
 648 --  * Safe to evaluate even if normal order eval might not
 649 --    evaluate the expression at all, or
 650 --
 651 --  * Safe /not/ to evaluate even if normal order would do so
 652 --
 653 -- It is usually called on arguments of unlifted type, but not always
 654 -- In particular, Simplify.rebuildCase calls it on lifted types
 655 -- when a 'case' is a plain 'seq'. See the example in
 656 -- Note [exprOkForSpeculation: case expressions] below
 657 --
 658 -- Precisely, it returns @True@ iff:
 659 --
 660 --  * The expression guarantees to terminate,
 661 --  * soon,
 662 --  * without raising an exception,
 663 --  * without causing a side effect (e.g. writing a mutable variable)
 664 --
 665 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 666 -- As an example of the considerations in this test, consider:
 667 --
 668 -- > let x = case y# +# 1# of { r# -> I# r# }
 669 -- > in E
 670 --
 671 -- being translated to:
 672 --
 673 -- > case y# +# 1# of { r# ->
 674 -- >    let x = I# r#
 675 -- >    in E
 676 -- > }
 677 --
 678 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 679 -- side effects, and can't diverge or raise an exception.
 680 exprOkForSpeculation :: CoreExpr -> Bool
 681 exprOkForSpeculation (Lit _)     = True
 682 exprOkForSpeculation (Type _)    = True
 683
 684 exprOkForSpeculation (Var v)
 685   | isTickBoxOp v = False     -- Tick boxes are *not* suitable for speculation
 686   | otherwise     =  isUnLiftedType (idType v)  -- c.f. the Var case of exprIsHNF
 687                   || isDataConWorkId v          -- Nullary constructors
 688                   || idArity v > 0              -- Functions
 689                   || isEvaldUnfolding (idUnfolding v)   -- Let-bound values
 690
 691 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 692 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 693
 694 exprOkForSpeculation (Case e _ _ alts)
 695   =  exprOkForSpeculation e  -- Note [exprOkForSpeculation: case expressions]
 696   && all (\(_,_,rhs) -> exprOkForSpeculation rhs) alts
 697
 698 exprOkForSpeculation other_expr
 699   = case collectArgs other_expr of
 700         (Var f, args) | f `hasKey` absentErrorIdKey     -- Note [Absent error Id]
 701                       -> all exprOkForSpeculation args  --    in WwLib
 702                       | otherwise
 703                       -> spec_ok (idDetails f) args
 704         _             -> False
 705
 706   where
 707     spec_ok (DataConWorkId _) _
 708       = True    -- The strictness of the constructor has already
 709                 -- been expressed by its "wrapper", so we don't need
 710                 -- to take the arguments into account
 711
 712     spec_ok (PrimOpId op) args
 713       | isDivOp op,             -- Special case for dividing operations that fail
 714         [arg1, Lit lit] <- args -- only if the divisor is zero
 715       = not (isZeroLit lit) && exprOkForSpeculation arg1
 716                 -- Often there is a literal divisor, and this
 717                 -- can get rid of a thunk in an inner looop
 718
 719       | DataToTagOp <- op      -- See Note [dataToTag speculation]
 720       = True
 721
 722       | otherwise
 723       = primOpOkForSpeculation op &&
 724         all exprOkForSpeculation args
 725                                 -- A bit conservative: we don't really need
 726                                 -- to care about lazy arguments, but this is easy
 727
 728     spec_ok (DFunId _ new_type) _ = not new_type
 729          -- DFuns terminate, unless the dict is implemented with a newtype
 730          -- in which case they may not
 731
 732     spec_ok _ _ = False
 733
 734 -- | True of dyadic operators that can fail only if the second arg is zero!
 735 isDivOp :: PrimOp -> Bool
 736 -- This function probably belongs in PrimOp, or even in
 737 -- an automagically generated file.. but it's such a
 738 -- special case I thought I'd leave it here for now.
 739 isDivOp IntQuotOp        = True
 740 isDivOp IntRemOp         = True
 741 isDivOp WordQuotOp       = True
 742 isDivOp WordRemOp        = True
 743 isDivOp FloatDivOp       = True
 744 isDivOp DoubleDivOp      = True
 745 isDivOp _                = False
 746 \end{code}
 747
 748 Note [exprOkForSpeculation: case expressions]
 749 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 750 It's always sound for exprOkForSpeculation to return False, and we
 751 don't want it to take too long, so it bales out on complicated-looking
 752 terms.  Notably lets, which can be stacked very deeply; and in any
 753 case the argument of exprOkForSpeculation is usually in a strict context,
 754 so any lets will have been floated away.
 755
 756 However, we keep going on case-expressions.  An example like this one
 757 showed up in DPH code (Trac #3717):
 758     foo :: Int -> Int
 759     foo 0 = 0
 760     foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
 761
 762 If exprOkForSpeculation doesn't look through case expressions, you get this:
 763     T.$wfoo =
 764       \ (ww :: GHC.Prim.Int#) ->
 765         case ww of ds {
 766           __DEFAULT -> case (case <# ds 5 of _ {
 767                           GHC.Types.False -> lvl1;
 768                           GHC.Types.True -> lvl})
 769                        of _ { __DEFAULT ->
 770                        T.$wfoo (GHC.Prim.-# ds_XkE 1) };
 771           0 -> 0
 772         }
 773
 774 The inner case is redundant, and should be nuked.
 775
 776 Note [dataToTag speculation]
 777 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 778 Is this OK?
 779    f x = let v::Int# = dataToTag# x
 780          in ...
 781 We say "yes", even though 'x' may not be evaluated.  Reasons
 782
 783   * dataToTag#'s strictness means that its argument often will be
 784     evaluated, but FloatOut makes that temporarily untrue
 785          case x of y -> let v = dataToTag# y in ...
 786     -->
 787          case x of y -> let v = dataToTag# x in ...
 788     Note that we look at 'x' instead of 'y' (this is to improve
 789     floating in FloatOut).  So Lint complains.
 790
 791     Moreover, it really *might* improve floating to let the
 792     v-binding float out
 793
 794   * CorePrep makes sure dataToTag#'s argument is evaluated, just
 795     before code gen.  Until then, it's not guaranteed
 796
 797
 798 %************************************************************************
 799 %*                                                                      *
 800              exprIsHNF, exprIsConLike
 801 %*                                                                      *
 802 %************************************************************************
 803
 804 \begin{code}
 805 -- Note [exprIsHNF]             See also Note [exprIsCheap and exprIsHNF]
 806 -- ~~~~~~~~~~~~~~~~
 807 -- | exprIsHNF returns true for expressions that are certainly /already/
 808 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 809 -- to change:
 810 --
 811 -- > case x of _ -> e
 812 --
 813 --    into:
 814 --
 815 -- > e
 816 --
 817 -- and to decide whether it's safe to discard a 'seq'.
 818 --
 819 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 820 -- However, it /does/ treat partial applications and constructor applications
 821 -- as values, even if their arguments are non-trivial, provided the argument
 822 -- type is lifted. For example, both of these are values:
 823 --
 824 -- > (:) (f x) (map f xs)
 825 -- > map (...redex...)
 826 --
 827 -- because 'seq' on such things completes immediately.
 828 --
 829 -- For unlifted argument types, we have to be careful:
 830 --
 831 -- > C (f x :: Int#)
 832 --
 833 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 834 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 835 -- unboxed type must be ok-for-speculation (or trivial).
 836 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 837 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 838 \end{code}
 839
 840 \begin{code}
 841 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 842 -- data constructors. Conlike arguments are considered interesting by the
 843 -- inliner.
 844 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 845 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 846
 847 -- | Returns true for values or value-like expressions. These are lambdas,
 848 -- constructors / CONLIKE functions (as determined by the function argument)
 849 -- or PAPs.
 850 --
 851 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 852 exprIsHNFlike is_con is_con_unf = is_hnf_like
 853   where
 854     is_hnf_like (Var v) -- NB: There are no value args at this point
 855       =  is_con v       -- Catches nullary constructors,
 856                         --      so that [] and () are values, for example
 857       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 858       || is_con_unf (idUnfolding v)
 859         -- Check the thing's unfolding; it might be bound to a value
 860         -- We don't look through loop breakers here, which is a bit conservative
 861         -- but otherwise I worry that if an Id's unfolding is just itself,
 862         -- we could get an infinite loop
 863
 864     is_hnf_like (Lit _)          = True
 865     is_hnf_like (Type _)         = True       -- Types are honorary Values;
 866                                               -- we don't mind copying them
 867     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 868     is_hnf_like (Note _ e)       = is_hnf_like e
 869     is_hnf_like (Cast e _)       = is_hnf_like e
 870     is_hnf_like (App e (Type _)) = is_hnf_like e
 871     is_hnf_like (App e a)        = app_is_value e [a]
 872     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 873     is_hnf_like _                = False
 874
 875     -- There is at least one value argument
 876     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 877     app_is_value (Var fun) args
 878       = idArity fun > valArgCount args    -- Under-applied function
 879         || is_con fun                     --  or constructor-like
 880     app_is_value (Note _ f) as = app_is_value f as
 881     app_is_value (Cast f _) as = app_is_value f as
 882     app_is_value (App f a)  as = app_is_value f (a:as)
 883     app_is_value _          _  = False
 884 \end{code}
 885
 886
 887 %************************************************************************
 888 %*                                                                      *
 889              Instantiating data constructors
 890 %*                                                                      *
 891 %************************************************************************
 892
 893 These InstPat functions go here to avoid circularity between DataCon and Id
 894
 895 \begin{code}
 896 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 897 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 898
 899 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 900 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 901 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 902   where
 903     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 904         -- Remember to include the existential dictionaries
 905
 906 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 907                   -> [FastString]          -- A long enough list of FSs to use for names
 908                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 909                   -> DataCon
 910                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 911                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 912 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 913 -- (ex_tvs, co_tvs, arg_ids),
 914 --
 915 --   ex_tvs are intended to be used as binders for existential type args
 916 --
 917 --   co_tvs are intended to be used as binders for coercion args and the kinds
 918 --     of these vars have been instantiated by the inst_tys and the ex_tys
 919 --     The co_tvs include both GADT equalities (dcEqSpec) and
 920 --     programmer-specified equalities (dcEqTheta)
 921 --
 922 --   arg_ids are indended to be used as binders for value arguments,
 923 --     and their types have been instantiated with inst_tys and ex_tys
 924 --     The arg_ids include both dicts (dcDictTheta) and
 925 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 926 --
 927 -- Example.
 928 --  The following constructor T1
 929 --
 930 --  data T a where
 931 --    T1 :: forall b. Int -> b -> T(a,b)
 932 --    ...
 933 --
 934 --  has representation type
 935 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 936 --     Int -> b -> T a
 937 --
 938 --  dataConInstPat fss us T1 (a1',b') will return
 939 --
 940 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 941 --
 942 --  where the double-primed variables are created with the FastStrings and
 943 --  Uniques given as fss and us
 944 dataConInstPat arg_fun fss uniqs con inst_tys
 945   = (ex_bndrs, co_bndrs, arg_ids)
 946   where
 947     univ_tvs = dataConUnivTyVars con
 948     ex_tvs   = dataConExTyVars con
 949     arg_tys  = arg_fun con
 950     eq_spec  = dataConEqSpec con
 951     eq_theta = dataConEqTheta con
 952     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 953
 954     n_ex = length ex_tvs
 955     n_co = length eq_preds
 956
 957       -- split the Uniques and FastStrings
 958     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 959     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 960
 961     (ex_fss, fss')     = splitAt n_ex fss
 962     (co_fss, id_fss)   = splitAt n_co fss'
 963
 964       -- Make existential type variables
 965     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 966     mk_ex_var uniq fs var = mkTyVar new_name kind
 967       where
 968         new_name = mkSysTvName uniq fs
 969         kind     = tyVarKind var
 970
 971       -- Make the instantiating substitution
 972     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 973
 974       -- Make new coercion vars, instantiating kind
 975     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 976     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 977        where
 978          new_name = mkSysTvName uniq fs
 979          co_kind  = substTy subst (mkPredTy eq_pred)
 980
 981       -- make value vars, instantiating types
 982     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 983     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 984
 985 \end{code}
 986
 987 %************************************************************************
 988 %*                                                                      *
 989          Equality
 990 %*                                                                      *
 991 %************************************************************************
 992
 993 \begin{code}
 994 -- | A cheap equality test which bales out fast!
 995 --      If it returns @True@ the arguments are definitely equal,
 996 --      otherwise, they may or may not be equal.
 997 --
 998 -- See also 'exprIsBig'
 999 cheapEqExpr :: Expr b -> Expr b -> Bool
1000
1001 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1002 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1003 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1004
1005 cheapEqExpr (App f1 a1) (App f2 a2)
1006   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1007
1008 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
1009   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
1010
1011 cheapEqExpr _ _ = False
1012 \end{code}
1013
1014 \begin{code}
1015 exprIsBig :: Expr b -> Bool
1016 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
1017 exprIsBig (Lit _)      = False
1018 exprIsBig (Var _)      = False
1019 exprIsBig (Type _)     = False
1020 exprIsBig (Lam _ e)    = exprIsBig e
1021 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1022 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1023 exprIsBig _            = True
1024 \end{code}
1025
1026 \begin{code}
1027 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
1028 -- Compares for equality, modulo alpha
1029 eqExpr in_scope e1 e2
1030   = eqExprX id_unf (mkRnEnv2 in_scope) e1 e2
1031   where
1032     id_unf _ = noUnfolding      -- Don't expand
1033 \end{code}
1034
1035 \begin{code}
1036 eqExprX :: IdUnfoldingFun -> RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1037 -- ^ Compares expressions for equality, modulo alpha.
1038 -- Does /not/ look through newtypes or predicate types
1039 -- Used in rule matching, and also CSE
1040
1041 eqExprX id_unfolding_fun env e1 e2
1042   = go env e1 e2
1043   where
1044     go env (Var v1) (Var v2)
1045       | rnOccL env v1 == rnOccR env v2
1046       = True
1047
1048     -- The next two rules expand non-local variables
1049     -- C.f. Note [Expanding variables] in Rules.lhs
1050     -- and  Note [Do not expand locally-bound variables] in Rules.lhs
1051     go env (Var v1) e2
1052       | not (locallyBoundL env v1)
1053       , Just e1' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v1))
1054       = go (nukeRnEnvL env) e1' e2
1055
1056     go env e1 (Var v2)
1057       | not (locallyBoundR env v2)
1058       , Just e2' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v2))
1059       = go (nukeRnEnvR env) e1 e2'
1060
1061     go _   (Lit lit1)    (Lit lit2)    = lit1 == lit2
1062     go env (Type t1)     (Type t2)     = tcEqTypeX env t1 t2
1063     go env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && go env e1 e2
1064     go env (App f1 a1)   (App f2 a2)   = go env f1 f2 && go env a1 a2
1065     go env (Note n1 e1)  (Note n2 e2)  = go_note n1 n2 && go env e1 e2
1066
1067     go env (Lam b1 e1)  (Lam b2 e2)
1068       =  tcEqTypeX env (varType b1) (varType b2)   -- False for Id/TyVar combination
1069       && go (rnBndr2 env b1 b2) e1 e2
1070
1071     go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1072       =  go env r1 r2  -- No need to check binder types, since RHSs match
1073       && go (rnBndr2 env v1 v2) e1 e2
1074
1075     go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1076       = all2 (go env') rs1 rs2 && go env' e1 e2
1077       where
1078         (bs1,rs1) = unzip ps1
1079         (bs2,rs2) = unzip ps2
1080         env' = rnBndrs2 env bs1 bs2
1081
1082     go env (Case e1 b1 _ a1) (Case e2 b2 _ a2)
1083       =  go env e1 e2
1084       && tcEqTypeX env (idType b1) (idType b2)
1085       && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1086
1087     go _ _ _ = False
1088
1089     -----------
1090     go_alt env (c1, bs1, e1) (c2, bs2, e2)
1091       = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1092
1093     -----------
1094     go_note (SCC cc1)     (SCC cc2)      = cc1 == cc2
1095     go_note (CoreNote s1) (CoreNote s2)  = s1 == s2
1096     go_note _             _              = False
1097 \end{code}
1098
1099 Auxiliary functions
1100
1101 \begin{code}
1102 locallyBoundL, locallyBoundR :: RnEnv2 -> Var -> Bool
1103 locallyBoundL rn_env v = inRnEnvL rn_env v
1104 locallyBoundR rn_env v = inRnEnvR rn_env v
1105 \end{code}
1106
1107
1108 %************************************************************************
1109 %*                                                                      *
1110 \subsection{The size of an expression}
1111 %*                                                                      *
1112 %************************************************************************
1113
1114 \begin{code}
1115 coreBindsSize :: [CoreBind] -> Int
1116 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1117
1118 exprSize :: CoreExpr -> Int
1119 -- ^ A measure of the size of the expressions, strictly greater than 0
1120 -- It also forces the expression pretty drastically as a side effect
1121 exprSize (Var v)         = v `seq` 1
1122 exprSize (Lit lit)       = lit `seq` 1
1123 exprSize (App f a)       = exprSize f + exprSize a
1124 exprSize (Lam b e)       = varSize b + exprSize e
1125 exprSize (Let b e)       = bindSize b + exprSize e
1126 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1127 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1128 exprSize (Note n e)      = noteSize n + exprSize e
1129 exprSize (Type t)        = seqType t `seq` 1
1130
1131 noteSize :: Note -> Int
1132 noteSize (SCC cc)       = cc `seq` 1
1133 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1134
1135 varSize :: Var -> Int
1136 varSize b  | isTyCoVar b = 1
1137            | otherwise = seqType (idType b)             `seq`
1138                          megaSeqIdInfo (idInfo b)       `seq`
1139                          1
1140
1141 varsSize :: [Var] -> Int
1142 varsSize = sum . map varSize
1143
1144 bindSize :: CoreBind -> Int
1145 bindSize (NonRec b e) = varSize b + exprSize e
1146 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1147
1148 pairSize :: (Var, CoreExpr) -> Int
1149 pairSize (b,e) = varSize b + exprSize e
1150
1151 altSize :: CoreAlt -> Int
1152 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1153 \end{code}
1154
1155
1156 %************************************************************************
1157 %*                                                                      *
1158 \subsection{Hashing}
1159 %*                                                                      *
1160 %************************************************************************
1161
1162 \begin{code}
1163 hashExpr :: CoreExpr -> Int
1164 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1165 -- Two expressions that hash to the different Ints are definitely unequal.
1166 --
1167 -- The emphasis is on a crude, fast hash, rather than on high precision.
1168 --
1169 -- But unequal here means \"not identical\"; two alpha-equivalent
1170 -- expressions may hash to the different Ints.
1171 --
1172 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1173 -- (at least if we want the above invariant to be true).
1174
1175 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1176              -- UniqFM doesn't like negative Ints
1177
1178 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1179
1180 hash_expr :: HashEnv -> CoreExpr -> Word32
1181 -- Word32, because we're expecting overflows here, and overflowing
1182 -- signed types just isn't cool.  In C it's even undefined.
1183 hash_expr env (Note _ e)              = hash_expr env e
1184 hash_expr env (Cast e _)              = hash_expr env e
1185 hash_expr env (Var v)                 = hashVar env v
1186 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1187 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1188 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1189 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1190 hash_expr env (Case e _ _ _)          = hash_expr env e
1191 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1192 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1193 -- Shouldn't happen.  Better to use WARN than trace, because trace
1194 -- prevents the CPR optimisation kicking in for hash_expr.
1195
1196 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1197 fast_hash_expr env (Var v)      = hashVar env v
1198 fast_hash_expr env (Type t)     = fast_hash_type env t
1199 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1200 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1201 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1202 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1203 fast_hash_expr _   _            = 1
1204
1205 fast_hash_type :: HashEnv -> Type -> Word32
1206 fast_hash_type env ty
1207   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1208   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1209                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1210   | otherwise                               = 1
1211
1212 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1213 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1214
1215 hashVar :: HashEnv -> Var -> Word32
1216 hashVar (_,env) v
1217  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1218 \end{code}
1219
1220
1221 %************************************************************************
1222 %*                                                                      *
1223                 Eta reduction
1224 %*                                                                      *
1225 %************************************************************************
1226
1227 Note [Eta reduction conditions]
1228 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1229 We try for eta reduction here, but *only* if we get all the way to an
1230 trivial expression.  We don't want to remove extra lambdas unless we
1231 are going to avoid allocating this thing altogether.
1232
1233 There are some particularly delicate points here:
1234
1235 * Eta reduction is not valid in general:
1236         \x. bot  /=  bot
1237   This matters, partly for old-fashioned correctness reasons but,
1238   worse, getting it wrong can yield a seg fault. Consider
1239         f = \x.f x
1240         h y = case (case y of { True -> f `seq` True; False -> False }) of
1241                 True -> ...; False -> ...
1242
1243   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
1244   says f=bottom, and replaces the (f `seq` True) with just
1245   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
1246   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
1247   the definition again, so that it does not termninate after all.
1248   Result: seg-fault because the boolean case actually gets a function value.
1249   See Trac #1947.
1250
1251   So it's important to to the right thing.
1252
1253 * Note [Arity care]: we need to be careful if we just look at f's
1254   arity. Currently (Dec07), f's arity is visible in its own RHS (see
1255   Note [Arity robustness] in SimplEnv) so we must *not* trust the
1256   arity when checking that 'f' is a value.  Otherwise we will
1257   eta-reduce
1258       f = \x. f x
1259   to
1260       f = f
1261   Which might change a terminiating program (think (f `seq` e)) to a
1262   non-terminating one.  So we check for being a loop breaker first.
1263
1264   However for GlobalIds we can look at the arity; and for primops we
1265   must, since they have no unfolding.
1266
1267 * Regardless of whether 'f' is a value, we always want to
1268   reduce (/\a -> f a) to f
1269   This came up in a RULE: foldr (build (/\a -> g a))
1270   did not match           foldr (build (/\b -> ...something complex...))
1271   The type checker can insert these eta-expanded versions,
1272   with both type and dictionary lambdas; hence the slightly
1273   ad-hoc isDictId
1274
1275 * Never *reduce* arity. For example
1276       f = \xy. g x y
1277   Then if h has arity 1 we don't want to eta-reduce because then
1278   f's arity would decrease, and that is bad
1279
1280 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1281 Alas.
1282
1283 Note [Eta reduction with casted arguments]
1284 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1285 Consider
1286     (\(x:t3). f (x |> g)) :: t3 -> t2
1287   where
1288     f :: t1 -> t2
1289     g :: t3 ~ t1
1290 This should be eta-reduced to
1291
1292     f |> (sym g -> t2)
1293
1294 So we need to accumulate a coercion, pushing it inward (past
1295 variable arguments only) thus:
1296    f (x |> co_arg) |> co  -->  (f |> (sym co_arg -> co)) x
1297    f (x:t)         |> co  -->  (f |> (t -> co)) x
1298    f @ a           |> co  -->  (f |> (forall a.co)) @ a
1299    f @ (g:t1~t2)   |> co  -->  (f |> (t1~t2 => co)) @ (g:t1~t2)
1300 These are the equations for ok_arg.
1301
1302 It's true that we could also hope to eta reduce these:
1303     (\xy. (f x |> g) y)
1304     (\xy. (f x y) |> g)
1305 But the simplifier pushes those casts outwards, so we don't
1306 need to address that here.
1307
1308 \begin{code}
1309 tryEtaReduce :: [Var] -> CoreExpr -> Maybe CoreExpr
1310 tryEtaReduce bndrs body
1311   = go (reverse bndrs) body (IdCo (exprType body))
1312   where
1313     incoming_arity = count isId bndrs
1314
1315     go :: [Var]            -- Binders, innermost first, types [a3,a2,a1]
1316        -> CoreExpr         -- Of type tr
1317        -> CoercionI        -- Of type tr ~ ts
1318        -> Maybe CoreExpr   -- Of type a1 -> a2 -> a3 -> ts
1319     -- See Note [Eta reduction with casted arguments]
1320     -- for why we have an accumulating coercion
1321     go [] fun co
1322       | ok_fun fun = Just (mkCoerceI co fun)
1323
1324     go (b : bs) (App fun arg) co
1325       | Just co' <- ok_arg b arg co
1326       = go bs fun co'
1327
1328     go _ _ _  = Nothing         -- Failure!
1329
1330     ---------------
1331     -- Note [Eta reduction conditions]
1332     ok_fun (App fun (Type ty))
1333         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1334         =  ok_fun fun
1335     ok_fun (Var fun_id)
1336         =  not (fun_id `elem` bndrs)
1337         && (ok_fun_id fun_id || all ok_lam bndrs)
1338     ok_fun _fun = False
1339
1340     ---------------
1341     ok_fun_id fun = fun_arity fun >= incoming_arity
1342
1343     ---------------
1344     fun_arity fun             -- See Note [Arity care]
1345        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1346        | otherwise = idArity fun
1347
1348     ---------------
1349     ok_lam v = isTyCoVar v || isDictId v
1350
1351     ---------------
1352     ok_arg :: Var               -- Of type bndr_t
1353            -> CoreExpr          -- Of type arg_t
1354            -> CoercionI         -- Of kind (t1~t2)
1355            -> Maybe CoercionI   -- Of type (arg_t -> t1 ~  bndr_t -> t2)
1356                                 --   (and similarly for tyvars, coercion args)
1357     -- See Note [Eta reduction with casted arguments]
1358     ok_arg bndr (Type ty) co
1359        | Just tv <- getTyVar_maybe ty
1360        , bndr == tv  = Just (mkForAllTyCoI tv co)
1361     ok_arg bndr (Var v) co
1362        | bndr == v   = Just (mkFunTyCoI (IdCo (idType bndr)) co)
1363     ok_arg bndr (Cast (Var v) co_arg) co
1364        | bndr == v  = Just (mkFunTyCoI (ACo (mkSymCoercion co_arg)) co)
1365        -- The simplifier combines multiple casts into one,
1366        -- so we can have a simple-minded pattern match here
1367     ok_arg _ _ _ = Nothing
1368 \end{code}
1369
1370
1371 %************************************************************************
1372 %*                                                                      *
1373 \subsection{Determining non-updatable right-hand-sides}
1374 %*                                                                      *
1375 %************************************************************************
1376
1377 Top-level constructor applications can usually be allocated
1378 statically, but they can't if the constructor, or any of the
1379 arguments, come from another DLL (because we can't refer to static
1380 labels in other DLLs).
1381
1382 If this happens we simply make the RHS into an updatable thunk,
1383 and 'execute' it rather than allocating it statically.
1384
1385 \begin{code}
1386 -- | This function is called only on *top-level* right-hand sides.
1387 -- Returns @True@ if the RHS can be allocated statically in the output,
1388 -- with no thunks involved at all.
1389 rhsIsStatic :: (Name -> Bool) -> CoreExpr -> Bool
1390 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1391 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1392 -- update flag on it and (iii) in DsExpr to decide how to expand
1393 -- list literals
1394 --
1395 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1396 --      (a) a value lambda
1397 --      (b) a saturated constructor application with static args
1398 --
1399 -- BUT watch out for
1400 --  (i) Any cross-DLL references kill static-ness completely
1401 --      because they must be 'executed' not statically allocated
1402 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1403 --      this is not necessary)
1404 --
1405 -- (ii) We treat partial applications as redexes, because in fact we
1406 --      make a thunk for them that runs and builds a PAP
1407 --      at run-time.  The only appliations that are treated as
1408 --      static are *saturated* applications of constructors.
1409
1410 -- We used to try to be clever with nested structures like this:
1411 --              ys = (:) w ((:) w [])
1412 -- on the grounds that CorePrep will flatten ANF-ise it later.
1413 -- But supporting this special case made the function much more
1414 -- complicated, because the special case only applies if there are no
1415 -- enclosing type lambdas:
1416 --              ys = /\ a -> Foo (Baz ([] a))
1417 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1418 --
1419 -- But in fact, even without -O, nested structures at top level are
1420 -- flattened by the simplifier, so we don't need to be super-clever here.
1421 --
1422 -- Examples
1423 --
1424 --      f = \x::Int. x+7        TRUE
1425 --      p = (True,False)        TRUE
1426 --
1427 --      d = (fst p, False)      FALSE because there's a redex inside
1428 --                              (this particular one doesn't happen but...)
1429 --
1430 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1431 --      n = /\a. Nil a                  TRUE
1432 --
1433 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1434 --
1435 --
1436 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1437 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1438 --
1439 --    b) (C x xs), where C is a contructor is updatable if the application is
1440 --         dynamic
1441 --
1442 --    c) don't look through unfolding of f in (f x).
1443
1444 rhsIsStatic _is_dynamic_name rhs = is_static False rhs
1445   where
1446   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1447           -> CoreExpr -> Bool
1448
1449   is_static False (Lam b e)   = isRuntimeVar b || is_static False e
1450   is_static in_arg (Note n e) = notSccNote n && is_static in_arg e
1451   is_static in_arg (Cast e _) = is_static in_arg e
1452
1453   is_static _      (Lit lit)
1454     = case lit of
1455         MachLabel _ _ _ -> False
1456         _             -> True
1457         -- A MachLabel (foreign import "&foo") in an argument
1458         -- prevents a constructor application from being static.  The
1459         -- reason is that it might give rise to unresolvable symbols
1460         -- in the object file: under Linux, references to "weak"
1461         -- symbols from the data segment give rise to "unresolvable
1462         -- relocation" errors at link time This might be due to a bug
1463         -- in the linker, but we'll work around it here anyway.
1464         -- SDM 24/2/2004
1465
1466   is_static in_arg other_expr = go other_expr 0
1467    where
1468     go (Var f) n_val_args
1469 #if mingw32_TARGET_OS
1470         | not (_is_dynamic_name (idName f))
1471 #endif
1472         =  saturated_data_con f n_val_args
1473         || (in_arg && n_val_args == 0)
1474                 -- A naked un-applied variable is *not* deemed a static RHS
1475                 -- E.g.         f = g
1476                 -- Reason: better to update so that the indirection gets shorted
1477                 --         out, and the true value will be seen
1478                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1479                 --     are always updatable.  If you do so, make sure that non-updatable
1480                 --     ones have enough space for their static link field!
1481
1482     go (App f a) n_val_args
1483         | isTypeArg a                    = go f n_val_args
1484         | not in_arg && is_static True a = go f (n_val_args + 1)
1485         -- The (not in_arg) checks that we aren't in a constructor argument;
1486         -- if we are, we don't allow (value) applications of any sort
1487         --
1488         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1489         --   x = D# (1.0## /## 2.0##)
1490         -- can't float because /## can fail.
1491
1492     go (Note n f) n_val_args = notSccNote n && go f n_val_args
1493     go (Cast e _) n_val_args = go e n_val_args
1494     go _          _          = False
1495
1496     saturated_data_con f n_val_args
1497         = case isDataConWorkId_maybe f of
1498             Just dc -> n_val_args == dataConRepArity dc
1499             Nothing -> False
1500 \end{code}