compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 module CoreUtils (
  10         -- Construction
  11         mkInlineMe, mkSCC, mkCoerce, mkCoerceI,
  12         bindNonRec, needsCaseBinding,
  13         mkIfThenElse, mkAltExpr, mkPiType, mkPiTypes,
  14
  15         -- Taking expressions apart
  16         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  17
  18         -- Properties of expressions
  19         exprType, coreAltType,
  20         exprIsDupable, exprIsTrivial, exprIsCheap,
  21         exprIsHNF,exprOkForSpeculation, exprIsBig,
  22         exprIsConApp_maybe, exprIsBottom,
  23         rhsIsStatic,
  24
  25         -- Arity and eta expansion
  26         manifestArity, exprArity,
  27         exprEtaExpandArity, etaExpand,
  28
  29         -- Size
  30         coreBindsSize,
  31
  32         -- Hashing
  33         hashExpr,
  34
  35         -- Equality
  36         cheapEqExpr, tcEqExpr, tcEqExprX, applyTypeToArgs, applyTypeToArg,
  37
  38         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  39     ) where
  40
  41 #include "HsVersions.h"
  42
  43 import CoreSyn
  44 import CoreFVs
  45 import PprCore
  46 import Var
  47 import SrcLoc
  48 import VarSet
  49 import VarEnv
  50 import Name
  51 #if mingw32_TARGET_OS
  52 import Packages
  53 #endif
  54 import Literal
  55 import DataCon
  56 import PrimOp
  57 import Id
  58 import IdInfo
  59 import NewDemand
  60 import Type
  61 import Coercion
  62 import TyCon
  63 import TysWiredIn
  64 import CostCentre
  65 import BasicTypes
  66 import PackageConfig
  67 import Unique
  68 import Outputable
  69 import DynFlags
  70 import TysPrim
  71 import FastString
  72 import Maybes
  73 import Util
  74 import Data.Word
  75 import Data.Bits
  76
  77 import GHC.Exts         -- For `xori`
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89
  90 exprType (Var var)           = idType var
  91 exprType (Lit lit)           = literalType lit
  92 exprType (Let _ body)        = exprType body
  93 exprType (Case _ _ ty alts)  = ty
  94 exprType (Cast e co)         = snd (coercionKind co)
  95 exprType (Note other_note e) = exprType e
  96 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  97 exprType e@(App _ _)
  98   = case collectArgs e of
  99         (fun, args) -> applyTypeToArgs e (exprType fun) args
 100
 101 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 102
 103 coreAltType :: CoreAlt -> Type
 104 coreAltType (_,_,rhs) = exprType rhs
 105 \end{code}
 106
 107 @mkPiType@ makes a (->) type or a forall type, depending on whether
 108 it is given a type variable or a term variable.  We cleverly use the
 109 lbvarinfo field to figure out the right annotation for the arrove in
 110 case of a term variable.
 111
 112 \begin{code}
 113 mkPiType  :: Var   -> Type -> Type      -- The more polymorphic version
 114 mkPiTypes :: [Var] -> Type -> Type      --    doesn't work...
 115
 116 mkPiTypes vs ty = foldr mkPiType ty vs
 117
 118 mkPiType v ty
 119    | isId v    = mkFunTy (idType v) ty
 120    | otherwise = mkForAllTy v ty
 121 \end{code}
 122
 123 \begin{code}
 124 applyTypeToArg :: Type -> CoreExpr -> Type
 125 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 126 applyTypeToArg fun_ty other_arg     = funResultTy fun_ty
 127
 128 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 129 -- A more efficient version of applyTypeToArg
 130 -- when we have several args
 131 -- The first argument is just for debugging
 132 applyTypeToArgs e op_ty [] = op_ty
 133
 134 applyTypeToArgs e op_ty (Type ty : args)
 135   =     -- Accumulate type arguments so we can instantiate all at once
 136     go [ty] args
 137   where
 138     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 139     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 140                                 where
 141                                   op_ty' = applyTys op_ty (reverse rev_tys)
 142
 143 applyTypeToArgs e op_ty (other_arg : args)
 144   = case (splitFunTy_maybe op_ty) of
 145         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 146         Nothing -> pprPanic "applyTypeToArgs" (pprCoreExpr e $$ ppr op_ty)
 147 \end{code}
 148
 149
 150
 151 %************************************************************************
 152 %*                                                                      *
 153 \subsection{Attaching notes}
 154 %*                                                                      *
 155 %************************************************************************
 156
 157 mkNote removes redundant coercions, and SCCs where possible
 158
 159 \begin{code}
 160 #ifdef UNUSED
 161 mkNote :: Note -> CoreExpr -> CoreExpr
 162 mkNote (SCC cc) expr               = mkSCC cc expr
 163 mkNote InlineMe expr               = mkInlineMe expr
 164 mkNote note     expr               = Note note expr
 165 #endif
 166 \end{code}
 167
 168 Drop trivial InlineMe's.  This is somewhat important, because if we have an unfolding
 169 that looks like (Note InlineMe (Var v)), the InlineMe doesn't go away because it may
 170 not be *applied* to anything.
 171
 172 We don't use exprIsTrivial here, though, because we sometimes generate worker/wrapper
 173 bindings like
 174         fw = ...
 175         f  = inline_me (coerce t fw)
 176 As usual, the inline_me prevents the worker from getting inlined back into the wrapper.
 177 We want the split, so that the coerces can cancel at the call site.
 178
 179 However, we can get left with tiresome type applications.  Notably, consider
 180         f = /\ a -> let t = e in (t, w)
 181 Then lifting the let out of the big lambda gives
 182         t' = /\a -> e
 183         f = /\ a -> let t = inline_me (t' a) in (t, w)
 184 The inline_me is to stop the simplifier inlining t' right back
 185 into t's RHS.  In the next phase we'll substitute for t (since
 186 its rhs is trivial) and *then* we could get rid of the inline_me.
 187 But it hardly seems worth it, so I don't bother.
 188
 189 \begin{code}
 190 mkInlineMe (Var v) = Var v
 191 mkInlineMe e       = Note InlineMe e
 192 \end{code}
 193
 194
 195
 196 \begin{code}
 197 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 198 mkCoerceI IdCo e = e
 199 mkCoerceI (ACo co) e = mkCoerce co e
 200
 201 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 202 mkCoerce co (Cast expr co2)
 203   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 204                  (_from_ty2, to_ty2) = coercionKind co2} in
 205            from_ty `coreEqType` to_ty2 )
 206     mkCoerce (mkTransCoercion co2 co) expr
 207
 208 mkCoerce co expr
 209   = let (from_ty, to_ty) = coercionKind co in
 210 --    if to_ty `coreEqType` from_ty
 211 --    then expr
 212 --    else
 213         ASSERT2(from_ty `coreEqType` (exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ ppr (coercionKindPredTy co))
 214          (Cast expr co)
 215 \end{code}
 216
 217 \begin{code}
 218 mkSCC :: CostCentre -> Expr b -> Expr b
 219         -- Note: Nested SCC's *are* preserved for the benefit of
 220         --       cost centre stack profiling
 221 mkSCC cc (Lit lit)          = Lit lit
 222 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 223 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 224 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 225 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 226 mkSCC cc expr               = Note (SCC cc) expr
 227 \end{code}
 228
 229
 230 %************************************************************************
 231 %*                                                                      *
 232 \subsection{Other expression construction}
 233 %*                                                                      *
 234 %************************************************************************
 235
 236 \begin{code}
 237 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 238 -- (bindNonRec x r b) produces either
 239 --      let x = r in b
 240 -- or
 241 --      case r of x { _DEFAULT_ -> b }
 242 --
 243 -- depending on whether x is unlifted or not
 244 -- It's used by the desugarer to avoid building bindings
 245 -- that give Core Lint a heart attack.  Actually the simplifier
 246 -- deals with them perfectly well.
 247
 248 bindNonRec bndr rhs body
 249   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 250   | otherwise                          = Let (NonRec bndr rhs) body
 251
 252 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 253         -- Make a case expression instead of a let
 254         -- These can arise either from the desugarer,
 255         -- or from beta reductions: (\x.e) (x +# y)
 256 \end{code}
 257
 258 \begin{code}
 259 mkAltExpr :: AltCon -> [CoreBndr] -> [Type] -> CoreExpr
 260         -- This guy constructs the value that the scrutinee must have
 261         -- when you are in one particular branch of a case
 262 mkAltExpr (DataAlt con) args inst_tys
 263   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 264 mkAltExpr (LitAlt lit) [] []
 265   = Lit lit
 266 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 267 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 268
 269 mkIfThenElse :: CoreExpr -> CoreExpr -> CoreExpr -> CoreExpr
 270 mkIfThenElse guard then_expr else_expr
 271 -- Not going to be refining, so okay to take the type of the "then" clause
 272   = Case guard (mkWildId boolTy) (exprType then_expr)
 273          [ (DataAlt falseDataCon, [], else_expr),       -- Increasing order of tag!
 274            (DataAlt trueDataCon,  [], then_expr) ]
 275 \end{code}
 276
 277
 278 %************************************************************************
 279 %*                                                                      *
 280 \subsection{Taking expressions apart}
 281 %*                                                                      *
 282 %************************************************************************
 283
 284 The default alternative must be first, if it exists at all.
 285 This makes it easy to find, though it makes matching marginally harder.
 286
 287 \begin{code}
 288 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 289 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 290 findDefault alts                        =                     (alts, Nothing)
 291
 292 findAlt :: AltCon -> [CoreAlt] -> CoreAlt
 293 findAlt con alts
 294   = case alts of
 295         (deflt@(DEFAULT,_,_):alts) -> go alts deflt
 296         other                      -> go alts panic_deflt
 297   where
 298     panic_deflt = pprPanic "Missing alternative" (ppr con $$ vcat (map ppr alts))
 299
 300     go []                      deflt = deflt
 301     go (alt@(con1,_,_) : alts) deflt
 302       = case con `cmpAltCon` con1 of
 303           LT -> deflt   -- Missed it already; the alts are in increasing order
 304           EQ -> alt
 305           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 306
 307 isDefaultAlt :: CoreAlt -> Bool
 308 isDefaultAlt (DEFAULT, _, _) = True
 309 isDefaultAlt other           = False
 310
 311 ---------------------------------
 312 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 313 -- Merge preserving order; alternatives in the first arg
 314 -- shadow ones in the second
 315 mergeAlts [] as2 = as2
 316 mergeAlts as1 [] = as1
 317 mergeAlts (a1:as1) (a2:as2)
 318   = case a1 `cmpAlt` a2 of
 319         LT -> a1 : mergeAlts as1      (a2:as2)
 320         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 321         GT -> a2 : mergeAlts (a1:as1) as2
 322
 323
 324 ---------------------------------
 325 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 326 -- Given        case (C a b x y) of
 327 --                 C b x y -> ...
 328 -- we want to drop the leading type argument of the scrutinee
 329 -- leaving the arguments to match agains the pattern
 330
 331 trimConArgs DEFAULT      args = ASSERT( null args ) []
 332 trimConArgs (LitAlt lit) args = ASSERT( null args ) []
 333 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 334 \end{code}
 335
 336
 337 %************************************************************************
 338 %*                                                                      *
 339 \subsection{Figuring out things about expressions}
 340 %*                                                                      *
 341 %************************************************************************
 342
 343 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 344                 duplicate; simple variables and constants, and type
 345                 applications.  Note that primop Ids aren't considered
 346                 trivial unless
 347
 348 @exprIsBottom@  is true of expressions that are guaranteed to diverge
 349
 350
 351 There used to be a gruesome test for (hasNoBinding v) in the
 352 Var case:
 353         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 354 The idea here is that a constructor worker, like $wJust, is
 355 really short for (\x -> $wJust x), becuase $wJust has no binding.
 356 So it should be treated like a lambda.  Ditto unsaturated primops.
 357 But now constructor workers are not "have-no-binding" Ids.  And
 358 completely un-applied primops and foreign-call Ids are sufficiently
 359 rare that I plan to allow them to be duplicated and put up with
 360 saturating them.
 361
 362 SCC notes.  We do not treat (_scc_ "foo" x) as trivial, because
 363   a) it really generates code, (and a heap object when it's
 364      a function arg) to capture the cost centre
 365   b) see the note [SCC-and-exprIsTrivial] in Simplify.simplLazyBind
 366
 367 \begin{code}
 368 exprIsTrivial (Var v)      = True       -- See notes above
 369 exprIsTrivial (Type _)     = True
 370 exprIsTrivial (Lit lit)    = litIsTrivial lit
 371 exprIsTrivial (App e arg)  = not (isRuntimeArg arg) && exprIsTrivial e
 372 exprIsTrivial (Note (SCC _) e) = False          -- See notes above
 373 exprIsTrivial (Note _       e) = exprIsTrivial e
 374 exprIsTrivial (Cast e co)  = exprIsTrivial e
 375 exprIsTrivial (Lam b body) = not (isRuntimeVar b) && exprIsTrivial body
 376 exprIsTrivial other        = False
 377 \end{code}
 378
 379
 380 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 381                 cost in code size.  This will only happen in different case
 382                 branches, so there's no issue about duplicating work.
 383
 384                 That is, exprIsDupable returns True of (f x) even if
 385                 f is very very expensive to call.
 386
 387                 Its only purpose is to avoid fruitless let-binding
 388                 and then inlining of case join points
 389
 390
 391 \begin{code}
 392 exprIsDupable (Type _)          = True
 393 exprIsDupable (Var v)           = True
 394 exprIsDupable (Lit lit)         = litIsDupable lit
 395 exprIsDupable (Note InlineMe e) = True
 396 exprIsDupable (Note _ e)        = exprIsDupable e
 397 exprIsDupable (Cast e co)       = exprIsDupable e
 398 exprIsDupable expr
 399   = go expr 0
 400   where
 401     go (Var v)   n_args = True
 402     go (App f a) n_args =  n_args < dupAppSize
 403                         && exprIsDupable a
 404                         && go f (n_args+1)
 405     go other n_args     = False
 406
 407 dupAppSize :: Int
 408 dupAppSize = 4          -- Size of application we are prepared to duplicate
 409 \end{code}
 410
 411 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 412 it is obviously in weak head normal form, or is cheap to get to WHNF.
 413 [Note that that's not the same as exprIsDupable; an expression might be
 414 big, and hence not dupable, but still cheap.]
 415
 416 By ``cheap'' we mean a computation we're willing to:
 417         push inside a lambda, or
 418         inline at more than one place
 419 That might mean it gets evaluated more than once, instead of being
 420 shared.  The main examples of things which aren't WHNF but are
 421 ``cheap'' are:
 422
 423   *     case e of
 424           pi -> ei
 425         (where e, and all the ei are cheap)
 426
 427   *     let x = e in b
 428         (where e and b are cheap)
 429
 430   *     op x1 ... xn
 431         (where op is a cheap primitive operator)
 432
 433   *     error "foo"
 434         (because we are happy to substitute it inside a lambda)
 435
 436 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 437 because sharing will make sure it is only evaluated once.
 438
 439 \begin{code}
 440 exprIsCheap :: CoreExpr -> Bool
 441 exprIsCheap (Lit lit)         = True
 442 exprIsCheap (Type _)          = True
 443 exprIsCheap (Var _)           = True
 444 exprIsCheap (Note InlineMe e) = True
 445 exprIsCheap (Note _ e)        = exprIsCheap e
 446 exprIsCheap (Cast e co)       = exprIsCheap e
 447 exprIsCheap (Lam x e)         = isRuntimeVar x || exprIsCheap e
 448 exprIsCheap (Case e _ _ alts) = exprIsCheap e &&
 449                                 and [exprIsCheap rhs | (_,_,rhs) <- alts]
 450         -- Experimentally, treat (case x of ...) as cheap
 451         -- (and case __coerce x etc.)
 452         -- This improves arities of overloaded functions where
 453         -- there is only dictionary selection (no construction) involved
 454 exprIsCheap (Let (NonRec x _) e)
 455       | isUnLiftedType (idType x) = exprIsCheap e
 456       | otherwise                 = False
 457         -- strict lets always have cheap right hand sides,
 458         -- and do no allocation.
 459
 460 exprIsCheap other_expr  -- Applications and variables
 461   = go other_expr []
 462   where
 463         -- Accumulate value arguments, then decide
 464     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 465                           | otherwise      = go f val_args
 466
 467     go (Var f) [] = True        -- Just a type application of a variable
 468                                 -- (f t1 t2 t3) counts as WHNF
 469     go (Var f) args
 470         = case globalIdDetails f of
 471                 RecordSelId {} -> go_sel args
 472                 ClassOpId _    -> go_sel args
 473                 PrimOpId op    -> go_primop op args
 474
 475                 DataConWorkId _ -> go_pap args
 476                 other | length args < idArity f -> go_pap args
 477
 478                 other -> isBottomingId f
 479                         -- Application of a function which
 480                         -- always gives bottom; we treat this as cheap
 481                         -- because it certainly doesn't need to be shared!
 482
 483     go other args = False
 484
 485     --------------
 486     go_pap args = all exprIsTrivial args
 487         -- For constructor applications and primops, check that all
 488         -- the args are trivial.  We don't want to treat as cheap, say,
 489         --      (1:2:3:4:5:[])
 490         -- We'll put up with one constructor application, but not dozens
 491
 492     --------------
 493     go_primop op args = primOpIsCheap op && all exprIsCheap args
 494         -- In principle we should worry about primops
 495         -- that return a type variable, since the result
 496         -- might be applied to something, but I'm not going
 497         -- to bother to check the number of args
 498
 499     --------------
 500     go_sel [arg] = exprIsCheap arg      -- I'm experimenting with making record selection
 501     go_sel other = False                -- look cheap, so we will substitute it inside a
 502                                         -- lambda.  Particularly for dictionary field selection.
 503                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 504                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 505 \end{code}
 506
 507 exprOkForSpeculation returns True of an expression that it is
 508
 509         * safe to evaluate even if normal order eval might not
 510           evaluate the expression at all, or
 511
 512         * safe *not* to evaluate even if normal order would do so
 513
 514 It returns True iff
 515
 516         the expression guarantees to terminate,
 517         soon,
 518         without raising an exception,
 519         without causing a side effect (e.g. writing a mutable variable)
 520
 521 NB: if exprIsHNF e, then exprOkForSpecuation e
 522
 523 E.G.
 524         let x = case y# +# 1# of { r# -> I# r# }
 525         in E
 526 ==>
 527         case y# +# 1# of { r# ->
 528         let x = I# r#
 529         in E
 530         }
 531
 532 We can only do this if the (y+1) is ok for speculation: it has no
 533 side effects, and can't diverge or raise an exception.
 534
 535 \begin{code}
 536 exprOkForSpeculation :: CoreExpr -> Bool
 537 exprOkForSpeculation (Lit _)     = True
 538 exprOkForSpeculation (Type _)    = True
 539     -- Tick boxes are *not* suitable for speculation
 540 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 541                                  && not (isTickBoxOp v)
 542 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 543 exprOkForSpeculation (Cast e co) = exprOkForSpeculation e
 544 exprOkForSpeculation other_expr
 545   = case collectArgs other_expr of
 546         (Var f, args) -> spec_ok (globalIdDetails f) args
 547         other         -> False
 548
 549   where
 550     spec_ok (DataConWorkId _) args
 551       = True    -- The strictness of the constructor has already
 552                 -- been expressed by its "wrapper", so we don't need
 553                 -- to take the arguments into account
 554
 555     spec_ok (PrimOpId op) args
 556       | isDivOp op,             -- Special case for dividing operations that fail
 557         [arg1, Lit lit] <- args -- only if the divisor is zero
 558       = not (isZeroLit lit) && exprOkForSpeculation arg1
 559                 -- Often there is a literal divisor, and this
 560                 -- can get rid of a thunk in an inner looop
 561
 562       | otherwise
 563       = primOpOkForSpeculation op &&
 564         all exprOkForSpeculation args
 565                                 -- A bit conservative: we don't really need
 566                                 -- to care about lazy arguments, but this is easy
 567
 568     spec_ok other args = False
 569
 570 isDivOp :: PrimOp -> Bool
 571 -- True of dyadic operators that can fail
 572 -- only if the second arg is zero
 573 -- This function probably belongs in PrimOp, or even in
 574 -- an automagically generated file.. but it's such a
 575 -- special case I thought I'd leave it here for now.
 576 isDivOp IntQuotOp        = True
 577 isDivOp IntRemOp         = True
 578 isDivOp WordQuotOp       = True
 579 isDivOp WordRemOp        = True
 580 isDivOp IntegerQuotRemOp = True
 581 isDivOp IntegerDivModOp  = True
 582 isDivOp FloatDivOp       = True
 583 isDivOp DoubleDivOp      = True
 584 isDivOp other            = False
 585 \end{code}
 586
 587
 588 \begin{code}
 589 exprIsBottom :: CoreExpr -> Bool        -- True => definitely bottom
 590 exprIsBottom e = go 0 e
 591                where
 592                 -- n is the number of args
 593                  go n (Note _ e)     = go n e
 594                  go n (Cast e co)    = go n e
 595                  go n (Let _ e)      = go n e
 596                  go n (Case e _ _ _) = go 0 e   -- Just check the scrut
 597                  go n (App e _)      = go (n+1) e
 598                  go n (Var v)        = idAppIsBottom v n
 599                  go n (Lit _)        = False
 600                  go n (Lam _ _)      = False
 601                  go n (Type _)       = False
 602
 603 idAppIsBottom :: Id -> Int -> Bool
 604 idAppIsBottom id n_val_args = appIsBottom (idNewStrictness id) n_val_args
 605 \end{code}
 606
 607 @exprIsHNF@ returns true for expressions that are certainly *already*
 608 evaluated to *head* normal form.  This is used to decide whether it's ok
 609 to change
 610
 611         case x of _ -> e   ===>   e
 612
 613 and to decide whether it's safe to discard a `seq`
 614
 615 So, it does *not* treat variables as evaluated, unless they say they are.
 616
 617 But it *does* treat partial applications and constructor applications
 618 as values, even if their arguments are non-trivial, provided the argument
 619 type is lifted;
 620         e.g.  (:) (f x) (map f xs)      is a value
 621               map (...redex...)         is a value
 622 Because `seq` on such things completes immediately
 623
 624 For unlifted argument types, we have to be careful:
 625                 C (f x :: Int#)
 626 Suppose (f x) diverges; then C (f x) is not a value.  However this can't
 627 happen: see CoreSyn Note [CoreSyn let/app invariant].  Args of unboxed
 628 type must be ok-for-speculation (or trivial).
 629
 630 \begin{code}
 631 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 632 exprIsHNF (Var v)       -- NB: There are no value args at this point
 633   =  isDataConWorkId v  -- Catches nullary constructors,
 634                         --      so that [] and () are values, for example
 635   || idArity v > 0      -- Catches (e.g.) primops that don't have unfoldings
 636   || isEvaldUnfolding (idUnfolding v)
 637         -- Check the thing's unfolding; it might be bound to a value
 638         -- A worry: what if an Id's unfolding is just itself:
 639         -- then we could get an infinite loop...
 640
 641 exprIsHNF (Lit l)          = True
 642 exprIsHNF (Type ty)        = True       -- Types are honorary Values;
 643                                         -- we don't mind copying them
 644 exprIsHNF (Lam b e)        = isRuntimeVar b || exprIsHNF e
 645 exprIsHNF (Note _ e)       = exprIsHNF e
 646 exprIsHNF (Cast e co)      = exprIsHNF e
 647 exprIsHNF (App e (Type _)) = exprIsHNF e
 648 exprIsHNF (App e a)        = app_is_value e [a]
 649 exprIsHNF other            = False
 650
 651 -- There is at least one value argument
 652 app_is_value (Var fun) args
 653   = idArity fun > valArgCount args      -- Under-applied function
 654     ||  isDataConWorkId fun             --  or data constructor
 655 app_is_value (Note n f) as = app_is_value f as
 656 app_is_value (Cast f _) as = app_is_value f as
 657 app_is_value (App f a)  as = app_is_value f (a:as)
 658 app_is_value other      as = False
 659 \end{code}
 660
 661 \begin{code}
 662 -- These InstPat functions go here to avoid circularity between DataCon and Id
 663 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat (FSLIT("ipv")))
 664 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 665 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat (FSLIT("ipv")))
 666   where
 667     dc_arg_tys dc = map mkPredTy (dataConTheta dc) ++ dataConOrigArgTys dc
 668         -- Remember to include the existential dictionaries
 669
 670 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 671                   -> [FastString]          -- A long enough list of FSs to use for names
 672                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 673                   -> DataCon
 674                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 675                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 676 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 677 -- (ex_tvs, co_tvs, arg_ids),
 678 --
 679 --   ex_tvs are intended to be used as binders for existential type args
 680 --
 681 --   co_tvs are intended to be used as binders for coercion args and the kinds
 682 --     of these vars have been instantiated by the inst_tys and the ex_tys
 683 --
 684 --   arg_ids are indended to be used as binders for value arguments, including
 685 --     dicts, and their types have been instantiated with inst_tys and ex_tys
 686 --
 687 -- Example.
 688 --  The following constructor T1
 689 --
 690 --  data T a where
 691 --    T1 :: forall b. Int -> b -> T(a,b)
 692 --    ...
 693 --
 694 --  has representation type
 695 --   forall a. forall a1. forall b. (a :=: (a1,b)) =>
 696 --     Int -> b -> T a
 697 --
 698 --  dataConInstPat fss us T1 (a1',b') will return
 699 --
 700 --  ([a1'', b''], [c :: (a1', b'):=:(a1'', b'')], [x :: Int, y :: b''])
 701 --
 702 --  where the double-primed variables are created with the FastStrings and
 703 --  Uniques given as fss and us
 704 dataConInstPat arg_fun fss uniqs con inst_tys
 705   = (ex_bndrs, co_bndrs, id_bndrs)
 706   where
 707     univ_tvs = dataConUnivTyVars con
 708     ex_tvs   = dataConExTyVars con
 709     arg_tys  = arg_fun con
 710     eq_spec  = dataConEqSpec con
 711     eq_preds = eqSpecPreds eq_spec
 712
 713     n_ex = length ex_tvs
 714     n_co = length eq_spec
 715
 716       -- split the Uniques and FastStrings
 717     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 718     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 719
 720     (ex_fss, fss')     = splitAt n_ex fss
 721     (co_fss, id_fss)   = splitAt n_co fss'
 722
 723       -- Make existential type variables
 724     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 725     mk_ex_var uniq fs var = mkTyVar new_name kind
 726       where
 727         new_name = mkSysTvName uniq fs
 728         kind     = tyVarKind var
 729
 730       -- Make the instantiating substitution
 731     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 732
 733       -- Make new coercion vars, instantiating kind
 734     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 735     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 736        where
 737          new_name = mkSysTvName uniq fs
 738          co_kind  = substTy subst (mkPredTy eq_pred)
 739
 740       -- make value vars, instantiating types
 741     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 742     id_bndrs = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 743
 744 exprIsConApp_maybe :: CoreExpr -> Maybe (DataCon, [CoreExpr])
 745 -- Returns (Just (dc, [x1..xn])) if the argument expression is
 746 -- a constructor application of the form (dc x1 .. xn)
 747 exprIsConApp_maybe (Cast expr co)
 748   =     -- Here we do the PushC reduction rule as described in the FC paper
 749     case exprIsConApp_maybe expr of {
 750         Nothing            -> Nothing ;
 751         Just (dc, dc_args) ->
 752
 753         -- The transformation applies iff we have
 754         --      (C e1 ... en) `cast` co
 755         -- where co :: (T t1 .. tn) :=: (T s1 ..sn)
 756         -- That is, with a T at the top of both sides
 757         -- The left-hand one must be a T, because exprIsConApp returned True
 758         -- but the right-hand one might not be.  (Though it usually will.)
 759
 760     let (from_ty, to_ty)           = coercionKind co
 761         (from_tc, from_tc_arg_tys) = splitTyConApp from_ty
 762                 -- The inner one must be a TyConApp
 763     in
 764     case splitTyConApp_maybe to_ty of {
 765         Nothing -> Nothing ;
 766         Just (to_tc, to_tc_arg_tys)
 767                 | from_tc /= to_tc -> Nothing
 768                 -- These two Nothing cases are possible; we might see
 769                 --      (C x y) `cast` (g :: T a ~ S [a]),
 770                 -- where S is a type function.  In fact, exprIsConApp
 771                 -- will probably not be called in such circumstances,
 772                 -- but there't nothing wrong with it
 773
 774                 | otherwise  ->
 775     let
 776         tc_arity = tyConArity from_tc
 777
 778         (univ_args, rest1)  = splitAt tc_arity dc_args
 779         (ex_args, rest2)    = splitAt n_ex_tvs rest1
 780         (co_args, val_args) = splitAt n_cos rest2
 781
 782         arg_tys             = dataConRepArgTys dc
 783         dc_univ_tyvars      = dataConUnivTyVars dc
 784         dc_ex_tyvars        = dataConExTyVars dc
 785         dc_eq_spec          = dataConEqSpec dc
 786         dc_tyvars           = dc_univ_tyvars ++ dc_ex_tyvars
 787         n_ex_tvs            = length dc_ex_tyvars
 788         n_cos               = length dc_eq_spec
 789
 790         -- Make the "theta" from Fig 3 of the paper
 791         gammas              = decomposeCo tc_arity co
 792         new_tys             = gammas ++ map (\ (Type t) -> t) ex_args
 793         theta               = zipOpenTvSubst dc_tyvars new_tys
 794
 795           -- First we cast the existential coercion arguments
 796         cast_co (tv,ty) (Type co) = Type $ mkSymCoercion (substTyVar theta tv)
 797                                            `mkTransCoercion` co
 798                                            `mkTransCoercion` (substTy theta ty)
 799         new_co_args = zipWith cast_co dc_eq_spec co_args
 800
 801           -- ...and now value arguments
 802         new_val_args = zipWith cast_arg arg_tys val_args
 803         cast_arg arg_ty arg = mkCoerce (substTy theta arg_ty) arg
 804
 805     in
 806     ASSERT( length univ_args == tc_arity )
 807     ASSERT( from_tc == dataConTyCon dc )
 808     ASSERT( and (zipWith coreEqType [t | Type t <- univ_args] from_tc_arg_tys) )
 809     ASSERT( all isTypeArg (univ_args ++ ex_args) )
 810     ASSERT2( equalLength val_args arg_tys, ppr dc $$ ppr dc_tyvars $$ ppr dc_ex_tyvars $$ ppr arg_tys $$ ppr dc_args $$ ppr univ_args $$ ppr ex_args $$ ppr val_args $$ ppr arg_tys  )
 811
 812     Just (dc, map Type to_tc_arg_tys ++ ex_args ++ new_co_args ++ new_val_args)
 813     }}
 814
 815 {-
 816 -- We do not want to tell the world that we have a
 817 -- Cons, to *stop* Case of Known Cons, which removes
 818 -- the TickBox.
 819 exprIsConApp_maybe (Note (TickBox {}) expr)
 820   = Nothing
 821 exprIsConApp_maybe (Note (BinaryTickBox {}) expr)
 822   = Nothing
 823 -}
 824
 825 exprIsConApp_maybe (Note _ expr)
 826   = exprIsConApp_maybe expr
 827     -- We ignore InlineMe notes in case we have
 828     --  x = __inline_me__ (a,b)
 829     -- All part of making sure that INLINE pragmas never hurt
 830     -- Marcin tripped on this one when making dictionaries more inlinable
 831     --
 832     -- In fact, we ignore all notes.  For example,
 833     --          case _scc_ "foo" (C a b) of
 834     --                  C a b -> e
 835     -- should be optimised away, but it will be only if we look
 836     -- through the SCC note.
 837
 838 exprIsConApp_maybe expr = analyse (collectArgs expr)
 839   where
 840     analyse (Var fun, args)
 841         | Just con <- isDataConWorkId_maybe fun,
 842           args `lengthAtLeast` dataConRepArity con
 843                 -- Might be > because the arity excludes type args
 844         = Just (con,args)
 845
 846         -- Look through unfoldings, but only cheap ones, because
 847         -- we are effectively duplicating the unfolding
 848     analyse (Var fun, [])
 849         | let unf = idUnfolding fun,
 850           isCheapUnfolding unf
 851         = exprIsConApp_maybe (unfoldingTemplate unf)
 852
 853     analyse other = Nothing
 854 \end{code}
 855
 856
 857
 858 %************************************************************************
 859 %*                                                                      *
 860 \subsection{Eta reduction and expansion}
 861 %*                                                                      *
 862 %************************************************************************
 863
 864 \begin{code}
 865 exprEtaExpandArity :: DynFlags -> CoreExpr -> Arity
 866 {- The Arity returned is the number of value args the
 867    thing can be applied to without doing much work
 868
 869 exprEtaExpandArity is used when eta expanding
 870         e  ==>  \xy -> e x y
 871
 872 It returns 1 (or more) to:
 873         case x of p -> \s -> ...
 874 because for I/O ish things we really want to get that \s to the top.
 875 We are prepared to evaluate x each time round the loop in order to get that
 876
 877 It's all a bit more subtle than it looks:
 878
 879 1.  One-shot lambdas
 880
 881 Consider one-shot lambdas
 882                 let x = expensive in \y z -> E
 883 We want this to have arity 2 if the \y-abstraction is a 1-shot lambda
 884 Hence the ArityType returned by arityType
 885
 886 2.  The state-transformer hack
 887
 888 The one-shot lambda special cause is particularly important/useful for
 889 IO state transformers, where we often get
 890         let x = E in \ s -> ...
 891
 892 and the \s is a real-world state token abstraction.  Such abstractions
 893 are almost invariably 1-shot, so we want to pull the \s out, past the
 894 let x=E, even if E is expensive.  So we treat state-token lambdas as
 895 one-shot even if they aren't really.  The hack is in Id.isOneShotBndr.
 896
 897 3.  Dealing with bottom
 898
 899 Consider also
 900         f = \x -> error "foo"
 901 Here, arity 1 is fine.  But if it is
 902         f = \x -> case x of
 903                         True  -> error "foo"
 904                         False -> \y -> x+y
 905 then we want to get arity 2.  Tecnically, this isn't quite right, because
 906         (f True) `seq` 1
 907 should diverge, but it'll converge if we eta-expand f.  Nevertheless, we
 908 do so; it improves some programs significantly, and increasing convergence
 909 isn't a bad thing.  Hence the ABot/ATop in ArityType.
 910
 911 Actually, the situation is worse.  Consider
 912         f = \x -> case x of
 913                         True  -> \y -> x+y
 914                         False -> \y -> x-y
 915 Can we eta-expand here?  At first the answer looks like "yes of course", but
 916 consider
 917         (f bot) `seq` 1
 918 This should diverge!  But if we eta-expand, it won't.   Again, we ignore this
 919 "problem", because being scrupulous would lose an important transformation for
 920 many programs.
 921
 922
 923 4. Newtypes
 924
 925 Non-recursive newtypes are transparent, and should not get in the way.
 926 We do (currently) eta-expand recursive newtypes too.  So if we have, say
 927
 928         newtype T = MkT ([T] -> Int)
 929
 930 Suppose we have
 931         e = coerce T f
 932 where f has arity 1.  Then: etaExpandArity e = 1;
 933 that is, etaExpandArity looks through the coerce.
 934
 935 When we eta-expand e to arity 1: eta_expand 1 e T
 936 we want to get:                  coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
 937
 938 HOWEVER, note that if you use coerce bogusly you can ge
 939         coerce Int negate
 940 And since negate has arity 2, you might try to eta expand.  But you can't
 941 decopose Int to a function type.   Hence the final case in eta_expand.
 942 -}
 943
 944
 945 exprEtaExpandArity dflags e = arityDepth (arityType dflags e)
 946
 947 -- A limited sort of function type
 948 data ArityType = AFun Bool ArityType    -- True <=> one-shot
 949                | ATop                   -- Know nothing
 950                | ABot                   -- Diverges
 951
 952 arityDepth :: ArityType -> Arity
 953 arityDepth (AFun _ ty) = 1 + arityDepth ty
 954 arityDepth ty          = 0
 955
 956 andArityType ABot           at2           = at2
 957 andArityType ATop           at2           = ATop
 958 andArityType (AFun t1 at1)  (AFun t2 at2) = AFun (t1 && t2) (andArityType at1 at2)
 959 andArityType at1            at2           = andArityType at2 at1
 960
 961 arityType :: DynFlags -> CoreExpr -> ArityType
 962         -- (go1 e) = [b1,..,bn]
 963         -- means expression can be rewritten \x_b1 -> ... \x_bn -> body
 964         -- where bi is True <=> the lambda is one-shot
 965
 966 arityType dflags (Note n e) = arityType dflags e
 967 --      Not needed any more: etaExpand is cleverer
 968 --  | ok_note n = arityType dflags e
 969 --  | otherwise = ATop
 970
 971 arityType dflags (Cast e co) = arityType dflags e
 972
 973 arityType dflags (Var v)
 974   = mk (idArity v) (arg_tys (idType v))
 975   where
 976     mk :: Arity -> [Type] -> ArityType
 977         -- The argument types are only to steer the "state hack"
 978         -- Consider case x of
 979         --              True  -> foo
 980         --              False -> \(s:RealWorld) -> e
 981         -- where foo has arity 1.  Then we want the state hack to
 982         -- apply to foo too, so we can eta expand the case.
 983     mk 0 tys | isBottomingId v                     = ABot
 984              | (ty:tys) <- tys, isStateHackType ty = AFun True ATop
 985              | otherwise                           = ATop
 986     mk n (ty:tys) = AFun (isStateHackType ty) (mk (n-1) tys)
 987     mk n []       = AFun False                (mk (n-1) [])
 988
 989     arg_tys :: Type -> [Type]   -- Ignore for-alls
 990     arg_tys ty
 991         | Just (_, ty')  <- splitForAllTy_maybe ty = arg_tys ty'
 992         | Just (arg,res) <- splitFunTy_maybe ty    = arg : arg_tys res
 993         | otherwise                                = []
 994
 995         -- Lambdas; increase arity
 996 arityType dflags (Lam x e)
 997   | isId x    = AFun (isOneShotBndr x) (arityType dflags e)
 998   | otherwise = arityType dflags e
 999
1000         -- Applications; decrease arity
1001 arityType dflags (App f (Type _)) = arityType dflags f
1002 arityType dflags (App f a)        = case arityType dflags f of
1003                                         AFun one_shot xs | exprIsCheap a -> xs
1004                                         other                            -> ATop
1005
1006         -- Case/Let; keep arity if either the expression is cheap
1007         -- or it's a 1-shot lambda
1008         -- The former is not really right for Haskell
1009         --      f x = case x of { (a,b) -> \y. e }
1010         --  ===>
1011         --      f x y = case x of { (a,b) -> e }
1012         -- The difference is observable using 'seq'
1013 arityType dflags (Case scrut _ _ alts)
1014   = case foldr1 andArityType [arityType dflags rhs | (_,_,rhs) <- alts] of
1015         xs | exprIsCheap scrut          -> xs
1016         xs@(AFun one_shot _) | one_shot -> AFun True ATop
1017         other                           -> ATop
1018
1019 arityType dflags (Let b e)
1020   = case arityType dflags e of
1021         xs                   | cheap_bind b -> xs
1022         xs@(AFun one_shot _) | one_shot     -> AFun True ATop
1023         other                               -> ATop
1024   where
1025     cheap_bind (NonRec b e) = is_cheap (b,e)
1026     cheap_bind (Rec prs)    = all is_cheap prs
1027     is_cheap (b,e) = (dopt Opt_DictsCheap dflags && isDictId b)
1028                    || exprIsCheap e
1029         -- If the experimental -fdicts-cheap flag is on, we eta-expand through
1030         -- dictionary bindings.  This improves arities. Thereby, it also
1031         -- means that full laziness is less prone to floating out the
1032         -- application of a function to its dictionary arguments, which
1033         -- can thereby lose opportunities for fusion.  Example:
1034         --      foo :: Ord a => a -> ...
1035         --      foo = /\a \(d:Ord a). let d' = ...d... in \(x:a). ....
1036         --              -- So foo has arity 1
1037         --
1038         --      f = \x. foo dInt $ bar x
1039         --
1040         -- The (foo DInt) is floated out, and makes ineffective a RULE
1041         --      foo (bar x) = ...
1042         --
1043         -- One could go further and make exprIsCheap reply True to any
1044         -- dictionary-typed expression, but that's more work.
1045
1046 arityType dflags other = ATop
1047
1048 {- NOT NEEDED ANY MORE: etaExpand is cleverer
1049 ok_note InlineMe = False
1050 ok_note other    = True
1051     -- Notice that we do not look through __inline_me__
1052     -- This may seem surprising, but consider
1053     --          f = _inline_me (\x -> e)
1054     -- We DO NOT want to eta expand this to
1055     --          f = \x -> (_inline_me (\x -> e)) x
1056     -- because the _inline_me gets dropped now it is applied,
1057     -- giving just
1058     --          f = \x -> e
1059     -- A Bad Idea
1060 -}
1061 \end{code}
1062
1063
1064 \begin{code}
1065 etaExpand :: Arity              -- Result should have this number of value args
1066           -> [Unique]
1067           -> CoreExpr -> Type   -- Expression and its type
1068           -> CoreExpr
1069 -- (etaExpand n us e ty) returns an expression with
1070 -- the same meaning as 'e', but with arity 'n'.
1071 --
1072 -- Given e' = etaExpand n us e ty
1073 -- We should have
1074 --      ty = exprType e = exprType e'
1075 --
1076 -- Note that SCCs are not treated specially.  If we have
1077 --      etaExpand 2 (\x -> scc "foo" e)
1078 --      = (\xy -> (scc "foo" e) y)
1079 -- So the costs of evaluating 'e' (not 'e y') are attributed to "foo"
1080
1081 etaExpand n us expr ty
1082   | manifestArity expr >= n = expr              -- The no-op case
1083   | otherwise
1084   = eta_expand n us expr ty
1085   where
1086
1087 -- manifestArity sees how many leading value lambdas there are
1088 manifestArity :: CoreExpr -> Arity
1089 manifestArity (Lam v e) | isId v    = 1 + manifestArity e
1090                         | otherwise = manifestArity e
1091 manifestArity (Note _ e)            = manifestArity e
1092 manifestArity (Cast e _)            = manifestArity e
1093 manifestArity e                     = 0
1094
1095 -- etaExpand deals with for-alls. For example:
1096 --              etaExpand 1 E
1097 -- where  E :: forall a. a -> a
1098 -- would return
1099 --      (/\b. \y::a -> E b y)
1100 --
1101 -- It deals with coerces too, though they are now rare
1102 -- so perhaps the extra code isn't worth it
1103
1104 eta_expand n us expr ty
1105   | n == 0 &&
1106     -- The ILX code generator requires eta expansion for type arguments
1107     -- too, but alas the 'n' doesn't tell us how many of them there
1108     -- may be.  So we eagerly eta expand any big lambdas, and just
1109     -- cross our fingers about possible loss of sharing in the ILX case.
1110     -- The Right Thing is probably to make 'arity' include
1111     -- type variables throughout the compiler.  (ToDo.)
1112     not (isForAllTy ty)
1113     -- Saturated, so nothing to do
1114   = expr
1115
1116         -- Short cut for the case where there already
1117         -- is a lambda; no point in gratuitously adding more
1118 eta_expand n us (Lam v body) ty
1119   | isTyVar v
1120   = Lam v (eta_expand n us body (applyTy ty (mkTyVarTy v)))
1121
1122   | otherwise
1123   = Lam v (eta_expand (n-1) us body (funResultTy ty))
1124
1125 -- We used to have a special case that stepped inside Coerces here,
1126 -- thus:  eta_expand n us (Note note@(Coerce _ ty) e) _
1127 --              = Note note (eta_expand n us e ty)
1128 -- BUT this led to an infinite loop
1129 -- Example:     newtype T = MkT (Int -> Int)
1130 --      eta_expand 1 (coerce (Int->Int) e)
1131 --      --> coerce (Int->Int) (eta_expand 1 T e)
1132 --              by the bogus eqn
1133 --      --> coerce (Int->Int) (coerce T
1134 --              (\x::Int -> eta_expand 1 (coerce (Int->Int) e)))
1135 --              by the splitNewType_maybe case below
1136 --      and round we go
1137
1138 eta_expand n us expr ty
1139   = ASSERT2 (exprType expr `coreEqType` ty, ppr (exprType expr) $$ ppr ty)
1140     case splitForAllTy_maybe ty of {
1141           Just (tv,ty') ->
1142
1143               Lam lam_tv (eta_expand n us2 (App expr (Type (mkTyVarTy lam_tv))) (substTyWith [tv] [mkTyVarTy lam_tv] ty'))
1144                   where
1145                     lam_tv = setVarName tv (mkSysTvName uniq FSLIT("etaT"))
1146                         -- Using tv as a base retains its tyvar/covar-ness
1147                     (uniq:us2) = us
1148         ; Nothing ->
1149
1150         case splitFunTy_maybe ty of {
1151           Just (arg_ty, res_ty) -> Lam arg1 (eta_expand (n-1) us2 (App expr (Var arg1)) res_ty)
1152                                 where
1153                                    arg1       = mkSysLocal FSLIT("eta") uniq arg_ty
1154                                    (uniq:us2) = us
1155
1156         ; Nothing ->
1157
1158                 -- Given this:
1159                 --      newtype T = MkT ([T] -> Int)
1160                 -- Consider eta-expanding this
1161                 --      eta_expand 1 e T
1162                 -- We want to get
1163                 --      coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
1164
1165         case splitNewTypeRepCo_maybe ty of {
1166           Just(ty1,co) -> mkCoerce (mkSymCoercion co)
1167                                    (eta_expand n us (mkCoerce co expr) ty1) ;
1168           Nothing  ->
1169
1170         -- We have an expression of arity > 0, but its type isn't a function
1171         -- This *can* legitmately happen: e.g.  coerce Int (\x. x)
1172         -- Essentially the programmer is playing fast and loose with types
1173         -- (Happy does this a lot).  So we simply decline to eta-expand.
1174         expr
1175         }}}
1176 \end{code}
1177
1178 exprArity is a cheap-and-cheerful version of exprEtaExpandArity.
1179 It tells how many things the expression can be applied to before doing
1180 any work.  It doesn't look inside cases, lets, etc.  The idea is that
1181 exprEtaExpandArity will do the hard work, leaving something that's easy
1182 for exprArity to grapple with.  In particular, Simplify uses exprArity to
1183 compute the ArityInfo for the Id.
1184
1185 Originally I thought that it was enough just to look for top-level lambdas, but
1186 it isn't.  I've seen this
1187
1188         foo = PrelBase.timesInt
1189
1190 We want foo to get arity 2 even though the eta-expander will leave it
1191 unchanged, in the expectation that it'll be inlined.  But occasionally it
1192 isn't, because foo is blacklisted (used in a rule).
1193
1194 Similarly, see the ok_note check in exprEtaExpandArity.  So
1195         f = __inline_me (\x -> e)
1196 won't be eta-expanded.
1197
1198 And in any case it seems more robust to have exprArity be a bit more intelligent.
1199 But note that   (\x y z -> f x y z)
1200 should have arity 3, regardless of f's arity.
1201
1202 \begin{code}
1203 exprArity :: CoreExpr -> Arity
1204 exprArity e = go e
1205             where
1206               go (Var v)                   = idArity v
1207               go (Lam x e) | isId x        = go e + 1
1208                            | otherwise     = go e
1209               go (Note n e)                = go e
1210               go (Cast e _)                = go e
1211               go (App e (Type t))          = go e
1212               go (App f a) | exprIsCheap a = (go f - 1) `max` 0
1213                 -- NB: exprIsCheap a!
1214                 --      f (fac x) does not have arity 2,
1215                 --      even if f has arity 3!
1216                 -- NB: `max 0`!  (\x y -> f x) has arity 2, even if f is
1217                 --               unknown, hence arity 0
1218               go _                         = 0
1219 \end{code}
1220
1221 %************************************************************************
1222 %*                                                                      *
1223 \subsection{Equality}
1224 %*                                                                      *
1225 %************************************************************************
1226
1227 @cheapEqExpr@ is a cheap equality test which bales out fast!
1228         True  => definitely equal
1229         False => may or may not be equal
1230
1231 \begin{code}
1232 cheapEqExpr :: Expr b -> Expr b -> Bool
1233
1234 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1235 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1236 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1237
1238 cheapEqExpr (App f1 a1) (App f2 a2)
1239   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1240
1241 cheapEqExpr _ _ = False
1242
1243 exprIsBig :: Expr b -> Bool
1244 -- Returns True of expressions that are too big to be compared by cheapEqExpr
1245 exprIsBig (Lit _)      = False
1246 exprIsBig (Var v)      = False
1247 exprIsBig (Type t)     = False
1248 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1249 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1250 exprIsBig other        = True
1251 \end{code}
1252
1253
1254 \begin{code}
1255 tcEqExpr :: CoreExpr -> CoreExpr -> Bool
1256 -- Used in rule matching, so does *not* look through
1257 -- newtypes, predicate types; hence tcEqExpr
1258
1259 tcEqExpr e1 e2 = tcEqExprX rn_env e1 e2
1260   where
1261     rn_env = mkRnEnv2 (mkInScopeSet (exprFreeVars e1 `unionVarSet` exprFreeVars e2))
1262
1263 tcEqExprX :: RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1264 tcEqExprX env (Var v1)     (Var v2)     = rnOccL env v1 == rnOccR env v2
1265 tcEqExprX env (Lit lit1)   (Lit lit2)   = lit1 == lit2
1266 tcEqExprX env (App f1 a1)  (App f2 a2)  = tcEqExprX env f1 f2 && tcEqExprX env a1 a2
1267 tcEqExprX env (Lam v1 e1)  (Lam v2 e2)  = tcEqExprX (rnBndr2 env v1 v2) e1 e2
1268 tcEqExprX env (Let (NonRec v1 r1) e1)
1269               (Let (NonRec v2 r2) e2)   = tcEqExprX env r1 r2
1270                                        && tcEqExprX (rnBndr2 env v1 v2) e1 e2
1271 tcEqExprX env (Let (Rec ps1) e1)
1272               (Let (Rec ps2) e2)        =  equalLength ps1 ps2
1273                                         && and (zipWith eq_rhs ps1 ps2)
1274                                         && tcEqExprX env' e1 e2
1275                                      where
1276                                        env' = foldl2 rn_bndr2 env ps2 ps2
1277                                        rn_bndr2 env (b1,_) (b2,_) = rnBndr2 env b1 b2
1278                                        eq_rhs       (_,r1) (_,r2) = tcEqExprX env' r1 r2
1279 tcEqExprX env (Case e1 v1 t1 a1)
1280               (Case e2 v2 t2 a2)     =  tcEqExprX env e1 e2
1281                                      && tcEqTypeX env t1 t2
1282                                      && equalLength a1 a2
1283                                      && and (zipWith (eq_alt env') a1 a2)
1284                                      where
1285                                        env' = rnBndr2 env v1 v2
1286
1287 tcEqExprX env (Note n1 e1) (Note n2 e2) = eq_note env n1 n2 && tcEqExprX env e1 e2
1288 tcEqExprX env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && tcEqExprX env e1 e2
1289 tcEqExprX env (Type t1)    (Type t2)    = tcEqTypeX env t1 t2
1290 tcEqExprX env e1                e2      = False
1291
1292 eq_alt env (c1,vs1,r1) (c2,vs2,r2) = c1==c2 && tcEqExprX (rnBndrs2 env vs1  vs2) r1 r2
1293
1294 eq_note env (SCC cc1)      (SCC cc2)      = cc1 == cc2
1295 eq_note env (CoreNote s1)  (CoreNote s2)  = s1 == s2
1296 eq_note env other1             other2     = False
1297 \end{code}
1298
1299
1300 %************************************************************************
1301 %*                                                                      *
1302 \subsection{The size of an expression}
1303 %*                                                                      *
1304 %************************************************************************
1305
1306 \begin{code}
1307 coreBindsSize :: [CoreBind] -> Int
1308 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1309
1310 exprSize :: CoreExpr -> Int
1311         -- A measure of the size of the expressions
1312         -- It also forces the expression pretty drastically as a side effect
1313 exprSize (Var v)         = v `seq` 1
1314 exprSize (Lit lit)       = lit `seq` 1
1315 exprSize (App f a)       = exprSize f + exprSize a
1316 exprSize (Lam b e)       = varSize b + exprSize e
1317 exprSize (Let b e)       = bindSize b + exprSize e
1318 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1319 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1320 exprSize (Note n e)      = noteSize n + exprSize e
1321 exprSize (Type t)        = seqType t `seq` 1
1322
1323 noteSize (SCC cc)       = cc `seq` 1
1324 noteSize InlineMe       = 1
1325 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1326
1327 varSize :: Var -> Int
1328 varSize b  | isTyVar b = 1
1329            | otherwise = seqType (idType b)             `seq`
1330                          megaSeqIdInfo (idInfo b)       `seq`
1331                          1
1332
1333 varsSize = foldr ((+) . varSize) 0
1334
1335 bindSize (NonRec b e) = varSize b + exprSize e
1336 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1337
1338 pairSize (b,e) = varSize b + exprSize e
1339
1340 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1341 \end{code}
1342
1343
1344 %************************************************************************
1345 %*                                                                      *
1346 \subsection{Hashing}
1347 %*                                                                      *
1348 %************************************************************************
1349
1350 \begin{code}
1351 hashExpr :: CoreExpr -> Int
1352 -- Two expressions that hash to the same Int may be equal (but may not be)
1353 -- Two expressions that hash to the different Ints are definitely unequal
1354 --
1355 -- But "unequal" here means "not identical"; two alpha-equivalent
1356 -- expressions may hash to the different Ints
1357 --
1358 -- The emphasis is on a crude, fast hash, rather than on high precision
1359 --
1360 -- We must be careful that \x.x and \y.y map to the same hash code,
1361 -- (at least if we want the above invariant to be true)
1362
1363 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1364              -- UniqFM doesn't like negative Ints
1365
1366 type HashEnv = (Int, VarEnv Int)        -- Hash code for bound variables
1367
1368 hash_expr :: HashEnv -> CoreExpr -> Word32
1369 -- Word32, because we're expecting overflows here, and overflowing
1370 -- signed types just isn't cool.  In C it's even undefined.
1371 hash_expr env (Note _ e)              = hash_expr env e
1372 hash_expr env (Cast e co)             = hash_expr env e
1373 hash_expr env (Var v)                 = hashVar env v
1374 hash_expr env (Lit lit)               = fromIntegral (hashLiteral lit)
1375 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1376 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1377 hash_expr env (Let (Rec ((b,r):_)) e) = hash_expr (extend_env env b) e
1378 hash_expr env (Case e _ _ _)          = hash_expr env e
1379 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1380 hash_expr env (Type t)                = WARN(True, text "hash_expr: type") 1
1381 -- Shouldn't happen.  Better to use WARN than trace, because trace
1382 -- prevents the CPR optimisation kicking in for hash_expr.
1383
1384 fast_hash_expr env (Var v)      = hashVar env v
1385 fast_hash_expr env (Type t)     = fast_hash_type env t
1386 fast_hash_expr env (Lit lit)    = fromIntegral (hashLiteral lit)
1387 fast_hash_expr env (Cast e co)  = fast_hash_expr env e
1388 fast_hash_expr env (Note n e)   = fast_hash_expr env e
1389 fast_hash_expr env (App f a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1390 fast_hash_expr env other        = 1
1391
1392 fast_hash_type :: HashEnv -> Type -> Word32
1393 fast_hash_type env ty
1394   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1395   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1396                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1397   | otherwise                               = 1
1398
1399 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1400 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1401
1402 hashVar :: HashEnv -> Var -> Word32
1403 hashVar (_,env) v
1404  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1405 \end{code}
1406
1407 %************************************************************************
1408 %*                                                                      *
1409 \subsection{Determining non-updatable right-hand-sides}
1410 %*                                                                      *
1411 %************************************************************************
1412
1413 Top-level constructor applications can usually be allocated
1414 statically, but they can't if the constructor, or any of the
1415 arguments, come from another DLL (because we can't refer to static
1416 labels in other DLLs).
1417
1418 If this happens we simply make the RHS into an updatable thunk,
1419 and 'exectute' it rather than allocating it statically.
1420
1421 \begin{code}
1422 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1423 -- This function is called only on *top-level* right-hand sides
1424 -- Returns True if the RHS can be allocated statically, with
1425 -- no thunks involved at all.
1426 --
1427 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1428 -- refers to, CAFs; and (ii) in CoreToStg to decide whether to put an
1429 -- update flag on it.
1430 --
1431 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1432 --      (a) a value lambda
1433 --      (b) a saturated constructor application with static args
1434 --
1435 -- BUT watch out for
1436 --  (i) Any cross-DLL references kill static-ness completely
1437 --      because they must be 'executed' not statically allocated
1438 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1439 --      this is not necessary)
1440 --
1441 -- (ii) We treat partial applications as redexes, because in fact we
1442 --      make a thunk for them that runs and builds a PAP
1443 --      at run-time.  The only appliations that are treated as
1444 --      static are *saturated* applications of constructors.
1445
1446 -- We used to try to be clever with nested structures like this:
1447 --              ys = (:) w ((:) w [])
1448 -- on the grounds that CorePrep will flatten ANF-ise it later.
1449 -- But supporting this special case made the function much more
1450 -- complicated, because the special case only applies if there are no
1451 -- enclosing type lambdas:
1452 --              ys = /\ a -> Foo (Baz ([] a))
1453 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1454 --
1455 -- But in fact, even without -O, nested structures at top level are
1456 -- flattened by the simplifier, so we don't need to be super-clever here.
1457 --
1458 -- Examples
1459 --
1460 --      f = \x::Int. x+7        TRUE
1461 --      p = (True,False)        TRUE
1462 --
1463 --      d = (fst p, False)      FALSE because there's a redex inside
1464 --                              (this particular one doesn't happen but...)
1465 --
1466 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1467 --      n = /\a. Nil a                  TRUE
1468 --
1469 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1470 --
1471 --
1472 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1473 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1474 --
1475 --    b) (C x xs), where C is a contructors is updatable if the application is
1476 --         dynamic
1477 --
1478 --    c) don't look through unfolding of f in (f x).
1479 --
1480 -- When opt_RuntimeTypes is on, we keep type lambdas and treat
1481 -- them as making the RHS re-entrant (non-updatable).
1482
1483 rhsIsStatic this_pkg rhs = is_static False rhs
1484   where
1485   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1486           -> CoreExpr -> Bool
1487
1488   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1489
1490   is_static in_arg (Note (SCC _) e) = False
1491   is_static in_arg (Note _ e)       = is_static in_arg e
1492   is_static in_arg (Cast e co)      = is_static in_arg e
1493
1494   is_static in_arg (Lit lit)
1495     = case lit of
1496         MachLabel _ _ -> False
1497         other         -> True
1498         -- A MachLabel (foreign import "&foo") in an argument
1499         -- prevents a constructor application from being static.  The
1500         -- reason is that it might give rise to unresolvable symbols
1501         -- in the object file: under Linux, references to "weak"
1502         -- symbols from the data segment give rise to "unresolvable
1503         -- relocation" errors at link time This might be due to a bug
1504         -- in the linker, but we'll work around it here anyway.
1505         -- SDM 24/2/2004
1506
1507   is_static in_arg other_expr = go other_expr 0
1508    where
1509     go (Var f) n_val_args
1510 #if mingw32_TARGET_OS
1511         | not (isDllName this_pkg (idName f))
1512 #endif
1513         =  saturated_data_con f n_val_args
1514         || (in_arg && n_val_args == 0)
1515                 -- A naked un-applied variable is *not* deemed a static RHS
1516                 -- E.g.         f = g
1517                 -- Reason: better to update so that the indirection gets shorted
1518                 --         out, and the true value will be seen
1519                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1520                 --     are always updatable.  If you do so, make sure that non-updatable
1521                 --     ones have enough space for their static link field!
1522
1523     go (App f a) n_val_args
1524         | isTypeArg a                    = go f n_val_args
1525         | not in_arg && is_static True a = go f (n_val_args + 1)
1526         -- The (not in_arg) checks that we aren't in a constructor argument;
1527         -- if we are, we don't allow (value) applications of any sort
1528         --
1529         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1530         --   x = D# (1.0## /## 2.0##)
1531         -- can't float because /## can fail.
1532
1533     go (Note (SCC _) f) n_val_args = False
1534     go (Note _ f) n_val_args       = go f n_val_args
1535     go (Cast e co) n_val_args      = go e n_val_args
1536
1537     go other n_val_args = False
1538
1539     saturated_data_con f n_val_args
1540         = case isDataConWorkId_maybe f of
1541             Just dc -> n_val_args == dataConRepArity dc
1542             Nothing -> False
1543 \end{code}