compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 module CoreUtils (
  10         -- Construction
  11         mkInlineMe, mkSCC, mkCoerce,
  12         bindNonRec, needsCaseBinding,
  13         mkIfThenElse, mkAltExpr, mkPiType, mkPiTypes,
  14
  15         -- Taking expressions apart
  16         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  17
  18         -- Properties of expressions
  19         exprType, coreAltType,
  20         exprIsDupable, exprIsTrivial, exprIsCheap,
  21         exprIsHNF,exprOkForSpeculation, exprIsBig,
  22         exprIsConApp_maybe, exprIsBottom,
  23         rhsIsStatic,
  24
  25         -- Arity and eta expansion
  26         manifestArity, exprArity,
  27         exprEtaExpandArity, etaExpand,
  28
  29         -- Size
  30         coreBindsSize,
  31
  32         -- Hashing
  33         hashExpr,
  34
  35         -- Equality
  36         cheapEqExpr, tcEqExpr, tcEqExprX, applyTypeToArgs, applyTypeToArg,
  37
  38         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  39     ) where
  40
  41 #include "HsVersions.h"
  42
  43 import CoreSyn
  44 import CoreFVs
  45 import PprCore
  46 import Var
  47 import SrcLoc
  48 import VarSet
  49 import VarEnv
  50 import Name
  51 #if mingw32_TARGET_OS
  52 import Packages
  53 #endif
  54 import Literal
  55 import DataCon
  56 import PrimOp
  57 import Id
  58 import IdInfo
  59 import NewDemand
  60 import Type
  61 import Coercion
  62 import TyCon
  63 import TysWiredIn
  64 import CostCentre
  65 import BasicTypes
  66 import PackageConfig
  67 import Unique
  68 import Outputable
  69 import DynFlags
  70 import TysPrim
  71 import FastString
  72 import Maybes
  73 import Util
  74 import Data.Word
  75 import Data.Bits
  76
  77 import GHC.Exts         -- For `xori`
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89
  90 exprType (Var var)           = idType var
  91 exprType (Lit lit)           = literalType lit
  92 exprType (Let _ body)        = exprType body
  93 exprType (Case _ _ ty alts)  = ty
  94 exprType (Cast e co)         = snd (coercionKind co)
  95 exprType (Note other_note e) = exprType e
  96 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  97 exprType e@(App _ _)
  98   = case collectArgs e of
  99         (fun, args) -> applyTypeToArgs e (exprType fun) args
 100
 101 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 102
 103 coreAltType :: CoreAlt -> Type
 104 coreAltType (_,_,rhs) = exprType rhs
 105 \end{code}
 106
 107 @mkPiType@ makes a (->) type or a forall type, depending on whether
 108 it is given a type variable or a term variable.  We cleverly use the
 109 lbvarinfo field to figure out the right annotation for the arrove in
 110 case of a term variable.
 111
 112 \begin{code}
 113 mkPiType  :: Var   -> Type -> Type      -- The more polymorphic version
 114 mkPiTypes :: [Var] -> Type -> Type      --    doesn't work...
 115
 116 mkPiTypes vs ty = foldr mkPiType ty vs
 117
 118 mkPiType v ty
 119    | isId v    = mkFunTy (idType v) ty
 120    | otherwise = mkForAllTy v ty
 121 \end{code}
 122
 123 \begin{code}
 124 applyTypeToArg :: Type -> CoreExpr -> Type
 125 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 126 applyTypeToArg fun_ty other_arg     = funResultTy fun_ty
 127
 128 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 129 -- A more efficient version of applyTypeToArg
 130 -- when we have several args
 131 -- The first argument is just for debugging
 132 applyTypeToArgs e op_ty [] = op_ty
 133
 134 applyTypeToArgs e op_ty (Type ty : args)
 135   =     -- Accumulate type arguments so we can instantiate all at once
 136     go [ty] args
 137   where
 138     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 139     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 140                                 where
 141                                   op_ty' = applyTys op_ty (reverse rev_tys)
 142
 143 applyTypeToArgs e op_ty (other_arg : args)
 144   = case (splitFunTy_maybe op_ty) of
 145         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 146         Nothing -> pprPanic "applyTypeToArgs" (pprCoreExpr e $$ ppr op_ty)
 147 \end{code}
 148
 149
 150
 151 %************************************************************************
 152 %*                                                                      *
 153 \subsection{Attaching notes}
 154 %*                                                                      *
 155 %************************************************************************
 156
 157 mkNote removes redundant coercions, and SCCs where possible
 158
 159 \begin{code}
 160 #ifdef UNUSED
 161 mkNote :: Note -> CoreExpr -> CoreExpr
 162 mkNote (SCC cc) expr               = mkSCC cc expr
 163 mkNote InlineMe expr               = mkInlineMe expr
 164 mkNote note     expr               = Note note expr
 165 #endif
 166 \end{code}
 167
 168 Drop trivial InlineMe's.  This is somewhat important, because if we have an unfolding
 169 that looks like (Note InlineMe (Var v)), the InlineMe doesn't go away because it may
 170 not be *applied* to anything.
 171
 172 We don't use exprIsTrivial here, though, because we sometimes generate worker/wrapper
 173 bindings like
 174         fw = ...
 175         f  = inline_me (coerce t fw)
 176 As usual, the inline_me prevents the worker from getting inlined back into the wrapper.
 177 We want the split, so that the coerces can cancel at the call site.
 178
 179 However, we can get left with tiresome type applications.  Notably, consider
 180         f = /\ a -> let t = e in (t, w)
 181 Then lifting the let out of the big lambda gives
 182         t' = /\a -> e
 183         f = /\ a -> let t = inline_me (t' a) in (t, w)
 184 The inline_me is to stop the simplifier inlining t' right back
 185 into t's RHS.  In the next phase we'll substitute for t (since
 186 its rhs is trivial) and *then* we could get rid of the inline_me.
 187 But it hardly seems worth it, so I don't bother.
 188
 189 \begin{code}
 190 mkInlineMe (Var v) = Var v
 191 mkInlineMe e       = Note InlineMe e
 192 \end{code}
 193
 194
 195
 196 \begin{code}
 197 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 198 mkCoerce co (Cast expr co2)
 199   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 200                  (_from_ty2, to_ty2) = coercionKind co2} in
 201            from_ty `coreEqType` to_ty2 )
 202     mkCoerce (mkTransCoercion co2 co) expr
 203
 204 mkCoerce co expr
 205   = let (from_ty, to_ty) = coercionKind co in
 206 --    if to_ty `coreEqType` from_ty
 207 --    then expr
 208 --    else
 209         ASSERT2(from_ty `coreEqType` (exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ ppr (coercionKindPredTy co))
 210          (Cast expr co)
 211 \end{code}
 212
 213 \begin{code}
 214 mkSCC :: CostCentre -> Expr b -> Expr b
 215         -- Note: Nested SCC's *are* preserved for the benefit of
 216         --       cost centre stack profiling
 217 mkSCC cc (Lit lit)          = Lit lit
 218 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 219 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 220 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 221 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 222 mkSCC cc expr               = Note (SCC cc) expr
 223 \end{code}
 224
 225
 226 %************************************************************************
 227 %*                                                                      *
 228 \subsection{Other expression construction}
 229 %*                                                                      *
 230 %************************************************************************
 231
 232 \begin{code}
 233 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 234 -- (bindNonRec x r b) produces either
 235 --      let x = r in b
 236 -- or
 237 --      case r of x { _DEFAULT_ -> b }
 238 --
 239 -- depending on whether x is unlifted or not
 240 -- It's used by the desugarer to avoid building bindings
 241 -- that give Core Lint a heart attack.  Actually the simplifier
 242 -- deals with them perfectly well.
 243
 244 bindNonRec bndr rhs body
 245   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 246   | otherwise                          = Let (NonRec bndr rhs) body
 247
 248 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 249         -- Make a case expression instead of a let
 250         -- These can arise either from the desugarer,
 251         -- or from beta reductions: (\x.e) (x +# y)
 252 \end{code}
 253
 254 \begin{code}
 255 mkAltExpr :: AltCon -> [CoreBndr] -> [Type] -> CoreExpr
 256         -- This guy constructs the value that the scrutinee must have
 257         -- when you are in one particular branch of a case
 258 mkAltExpr (DataAlt con) args inst_tys
 259   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 260 mkAltExpr (LitAlt lit) [] []
 261   = Lit lit
 262
 263 mkIfThenElse :: CoreExpr -> CoreExpr -> CoreExpr -> CoreExpr
 264 mkIfThenElse guard then_expr else_expr
 265 -- Not going to be refining, so okay to take the type of the "then" clause
 266   = Case guard (mkWildId boolTy) (exprType then_expr)
 267          [ (DataAlt falseDataCon, [], else_expr),       -- Increasing order of tag!
 268            (DataAlt trueDataCon,  [], then_expr) ]
 269 \end{code}
 270
 271
 272 %************************************************************************
 273 %*                                                                      *
 274 \subsection{Taking expressions apart}
 275 %*                                                                      *
 276 %************************************************************************
 277
 278 The default alternative must be first, if it exists at all.
 279 This makes it easy to find, though it makes matching marginally harder.
 280
 281 \begin{code}
 282 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 283 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 284 findDefault alts                        =                     (alts, Nothing)
 285
 286 findAlt :: AltCon -> [CoreAlt] -> CoreAlt
 287 findAlt con alts
 288   = case alts of
 289         (deflt@(DEFAULT,_,_):alts) -> go alts deflt
 290         other                      -> go alts panic_deflt
 291   where
 292     panic_deflt = pprPanic "Missing alternative" (ppr con $$ vcat (map ppr alts))
 293
 294     go []                      deflt = deflt
 295     go (alt@(con1,_,_) : alts) deflt
 296       = case con `cmpAltCon` con1 of
 297           LT -> deflt   -- Missed it already; the alts are in increasing order
 298           EQ -> alt
 299           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 300
 301 isDefaultAlt :: CoreAlt -> Bool
 302 isDefaultAlt (DEFAULT, _, _) = True
 303 isDefaultAlt other           = False
 304
 305 ---------------------------------
 306 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 307 -- Merge preserving order; alternatives in the first arg
 308 -- shadow ones in the second
 309 mergeAlts [] as2 = as2
 310 mergeAlts as1 [] = as1
 311 mergeAlts (a1:as1) (a2:as2)
 312   = case a1 `cmpAlt` a2 of
 313         LT -> a1 : mergeAlts as1      (a2:as2)
 314         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 315         GT -> a2 : mergeAlts (a1:as1) as2
 316
 317
 318 ---------------------------------
 319 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 320 -- Given        case (C a b x y) of
 321 --                 C b x y -> ...
 322 -- we want to drop the leading type argument of the scrutinee
 323 -- leaving the arguments to match agains the pattern
 324
 325 trimConArgs DEFAULT      args = ASSERT( null args ) []
 326 trimConArgs (LitAlt lit) args = ASSERT( null args ) []
 327 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 328 \end{code}
 329
 330
 331 %************************************************************************
 332 %*                                                                      *
 333 \subsection{Figuring out things about expressions}
 334 %*                                                                      *
 335 %************************************************************************
 336
 337 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 338                 duplicate; simple variables and constants, and type
 339                 applications.  Note that primop Ids aren't considered
 340                 trivial unless
 341
 342 @exprIsBottom@  is true of expressions that are guaranteed to diverge
 343
 344
 345 There used to be a gruesome test for (hasNoBinding v) in the
 346 Var case:
 347         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 348 The idea here is that a constructor worker, like $wJust, is
 349 really short for (\x -> $wJust x), becuase $wJust has no binding.
 350 So it should be treated like a lambda.  Ditto unsaturated primops.
 351 But now constructor workers are not "have-no-binding" Ids.  And
 352 completely un-applied primops and foreign-call Ids are sufficiently
 353 rare that I plan to allow them to be duplicated and put up with
 354 saturating them.
 355
 356 SCC notes.  We do not treat (_scc_ "foo" x) as trivial, because
 357   a) it really generates code, (and a heap object when it's
 358      a function arg) to capture the cost centre
 359   b) see the note [SCC-and-exprIsTrivial] in Simplify.simplLazyBind
 360
 361 \begin{code}
 362 exprIsTrivial (Var v)      = True       -- See notes above
 363 exprIsTrivial (Type _)     = True
 364 exprIsTrivial (Lit lit)    = litIsTrivial lit
 365 exprIsTrivial (App e arg)  = not (isRuntimeArg arg) && exprIsTrivial e
 366 exprIsTrivial (Note (SCC _) e) = False          -- See notes above
 367 exprIsTrivial (Note _       e) = exprIsTrivial e
 368 exprIsTrivial (Cast e co)  = exprIsTrivial e
 369 exprIsTrivial (Lam b body) = not (isRuntimeVar b) && exprIsTrivial body
 370 exprIsTrivial other        = False
 371 \end{code}
 372
 373
 374 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 375                 cost in code size.  This will only happen in different case
 376                 branches, so there's no issue about duplicating work.
 377
 378                 That is, exprIsDupable returns True of (f x) even if
 379                 f is very very expensive to call.
 380
 381                 Its only purpose is to avoid fruitless let-binding
 382                 and then inlining of case join points
 383
 384
 385 \begin{code}
 386 exprIsDupable (Type _)          = True
 387 exprIsDupable (Var v)           = True
 388 exprIsDupable (Lit lit)         = litIsDupable lit
 389 exprIsDupable (Note InlineMe e) = True
 390 exprIsDupable (Note _ e)        = exprIsDupable e
 391 exprIsDupable (Cast e co)       = exprIsDupable e
 392 exprIsDupable expr
 393   = go expr 0
 394   where
 395     go (Var v)   n_args = True
 396     go (App f a) n_args =  n_args < dupAppSize
 397                         && exprIsDupable a
 398                         && go f (n_args+1)
 399     go other n_args     = False
 400
 401 dupAppSize :: Int
 402 dupAppSize = 4          -- Size of application we are prepared to duplicate
 403 \end{code}
 404
 405 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 406 it is obviously in weak head normal form, or is cheap to get to WHNF.
 407 [Note that that's not the same as exprIsDupable; an expression might be
 408 big, and hence not dupable, but still cheap.]
 409
 410 By ``cheap'' we mean a computation we're willing to:
 411         push inside a lambda, or
 412         inline at more than one place
 413 That might mean it gets evaluated more than once, instead of being
 414 shared.  The main examples of things which aren't WHNF but are
 415 ``cheap'' are:
 416
 417   *     case e of
 418           pi -> ei
 419         (where e, and all the ei are cheap)
 420
 421   *     let x = e in b
 422         (where e and b are cheap)
 423
 424   *     op x1 ... xn
 425         (where op is a cheap primitive operator)
 426
 427   *     error "foo"
 428         (because we are happy to substitute it inside a lambda)
 429
 430 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 431 because sharing will make sure it is only evaluated once.
 432
 433 \begin{code}
 434 exprIsCheap :: CoreExpr -> Bool
 435 exprIsCheap (Lit lit)         = True
 436 exprIsCheap (Type _)          = True
 437 exprIsCheap (Var _)           = True
 438 exprIsCheap (Note InlineMe e) = True
 439 exprIsCheap (Note _ e)        = exprIsCheap e
 440 exprIsCheap (Cast e co)       = exprIsCheap e
 441 exprIsCheap (Lam x e)         = isRuntimeVar x || exprIsCheap e
 442 exprIsCheap (Case e _ _ alts) = exprIsCheap e &&
 443                                 and [exprIsCheap rhs | (_,_,rhs) <- alts]
 444         -- Experimentally, treat (case x of ...) as cheap
 445         -- (and case __coerce x etc.)
 446         -- This improves arities of overloaded functions where
 447         -- there is only dictionary selection (no construction) involved
 448 exprIsCheap (Let (NonRec x _) e)
 449       | isUnLiftedType (idType x) = exprIsCheap e
 450       | otherwise                 = False
 451         -- strict lets always have cheap right hand sides,
 452         -- and do no allocation.
 453
 454 exprIsCheap other_expr  -- Applications and variables
 455   = go other_expr []
 456   where
 457         -- Accumulate value arguments, then decide
 458     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 459                           | otherwise      = go f val_args
 460
 461     go (Var f) [] = True        -- Just a type application of a variable
 462                                 -- (f t1 t2 t3) counts as WHNF
 463     go (Var f) args
 464         = case globalIdDetails f of
 465                 RecordSelId {} -> go_sel args
 466                 ClassOpId _    -> go_sel args
 467                 PrimOpId op    -> go_primop op args
 468
 469                 DataConWorkId _ -> go_pap args
 470                 other | length args < idArity f -> go_pap args
 471
 472                 other -> isBottomingId f
 473                         -- Application of a function which
 474                         -- always gives bottom; we treat this as cheap
 475                         -- because it certainly doesn't need to be shared!
 476
 477     go other args = False
 478
 479     --------------
 480     go_pap args = all exprIsTrivial args
 481         -- For constructor applications and primops, check that all
 482         -- the args are trivial.  We don't want to treat as cheap, say,
 483         --      (1:2:3:4:5:[])
 484         -- We'll put up with one constructor application, but not dozens
 485
 486     --------------
 487     go_primop op args = primOpIsCheap op && all exprIsCheap args
 488         -- In principle we should worry about primops
 489         -- that return a type variable, since the result
 490         -- might be applied to something, but I'm not going
 491         -- to bother to check the number of args
 492
 493     --------------
 494     go_sel [arg] = exprIsCheap arg      -- I'm experimenting with making record selection
 495     go_sel other = False                -- look cheap, so we will substitute it inside a
 496                                         -- lambda.  Particularly for dictionary field selection.
 497                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 498                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 499 \end{code}
 500
 501 exprOkForSpeculation returns True of an expression that it is
 502
 503         * safe to evaluate even if normal order eval might not
 504           evaluate the expression at all, or
 505
 506         * safe *not* to evaluate even if normal order would do so
 507
 508 It returns True iff
 509
 510         the expression guarantees to terminate,
 511         soon,
 512         without raising an exception,
 513         without causing a side effect (e.g. writing a mutable variable)
 514
 515 NB: if exprIsHNF e, then exprOkForSpecuation e
 516
 517 E.G.
 518         let x = case y# +# 1# of { r# -> I# r# }
 519         in E
 520 ==>
 521         case y# +# 1# of { r# ->
 522         let x = I# r#
 523         in E
 524         }
 525
 526 We can only do this if the (y+1) is ok for speculation: it has no
 527 side effects, and can't diverge or raise an exception.
 528
 529 \begin{code}
 530 exprOkForSpeculation :: CoreExpr -> Bool
 531 exprOkForSpeculation (Lit _)     = True
 532 exprOkForSpeculation (Type _)    = True
 533     -- Tick boxes are *not* suitable for speculation
 534 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 535                                  && not (isTickBoxOp v)
 536 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 537 exprOkForSpeculation (Cast e co) = exprOkForSpeculation e
 538 exprOkForSpeculation other_expr
 539   = case collectArgs other_expr of
 540         (Var f, args) -> spec_ok (globalIdDetails f) args
 541         other         -> False
 542
 543   where
 544     spec_ok (DataConWorkId _) args
 545       = True    -- The strictness of the constructor has already
 546                 -- been expressed by its "wrapper", so we don't need
 547                 -- to take the arguments into account
 548
 549     spec_ok (PrimOpId op) args
 550       | isDivOp op,             -- Special case for dividing operations that fail
 551         [arg1, Lit lit] <- args -- only if the divisor is zero
 552       = not (isZeroLit lit) && exprOkForSpeculation arg1
 553                 -- Often there is a literal divisor, and this
 554                 -- can get rid of a thunk in an inner looop
 555
 556       | otherwise
 557       = primOpOkForSpeculation op &&
 558         all exprOkForSpeculation args
 559                                 -- A bit conservative: we don't really need
 560                                 -- to care about lazy arguments, but this is easy
 561
 562     spec_ok other args = False
 563
 564 isDivOp :: PrimOp -> Bool
 565 -- True of dyadic operators that can fail
 566 -- only if the second arg is zero
 567 -- This function probably belongs in PrimOp, or even in
 568 -- an automagically generated file.. but it's such a
 569 -- special case I thought I'd leave it here for now.
 570 isDivOp IntQuotOp        = True
 571 isDivOp IntRemOp         = True
 572 isDivOp WordQuotOp       = True
 573 isDivOp WordRemOp        = True
 574 isDivOp IntegerQuotRemOp = True
 575 isDivOp IntegerDivModOp  = True
 576 isDivOp FloatDivOp       = True
 577 isDivOp DoubleDivOp      = True
 578 isDivOp other            = False
 579 \end{code}
 580
 581
 582 \begin{code}
 583 exprIsBottom :: CoreExpr -> Bool        -- True => definitely bottom
 584 exprIsBottom e = go 0 e
 585                where
 586                 -- n is the number of args
 587                  go n (Note _ e)     = go n e
 588                  go n (Cast e co)    = go n e
 589                  go n (Let _ e)      = go n e
 590                  go n (Case e _ _ _) = go 0 e   -- Just check the scrut
 591                  go n (App e _)      = go (n+1) e
 592                  go n (Var v)        = idAppIsBottom v n
 593                  go n (Lit _)        = False
 594                  go n (Lam _ _)      = False
 595                  go n (Type _)       = False
 596
 597 idAppIsBottom :: Id -> Int -> Bool
 598 idAppIsBottom id n_val_args = appIsBottom (idNewStrictness id) n_val_args
 599 \end{code}
 600
 601 @exprIsHNF@ returns true for expressions that are certainly *already*
 602 evaluated to *head* normal form.  This is used to decide whether it's ok
 603 to change
 604
 605         case x of _ -> e   ===>   e
 606
 607 and to decide whether it's safe to discard a `seq`
 608
 609 So, it does *not* treat variables as evaluated, unless they say they are.
 610
 611 But it *does* treat partial applications and constructor applications
 612 as values, even if their arguments are non-trivial, provided the argument
 613 type is lifted;
 614         e.g.  (:) (f x) (map f xs)      is a value
 615               map (...redex...)         is a value
 616 Because `seq` on such things completes immediately
 617
 618 For unlifted argument types, we have to be careful:
 619                 C (f x :: Int#)
 620 Suppose (f x) diverges; then C (f x) is not a value.  However this can't
 621 happen: see CoreSyn Note [CoreSyn let/app invariant].  Args of unboxed
 622 type must be ok-for-speculation (or trivial).
 623
 624 \begin{code}
 625 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 626 exprIsHNF (Var v)       -- NB: There are no value args at this point
 627   =  isDataConWorkId v  -- Catches nullary constructors,
 628                         --      so that [] and () are values, for example
 629   || idArity v > 0      -- Catches (e.g.) primops that don't have unfoldings
 630   || isEvaldUnfolding (idUnfolding v)
 631         -- Check the thing's unfolding; it might be bound to a value
 632         -- A worry: what if an Id's unfolding is just itself:
 633         -- then we could get an infinite loop...
 634
 635 exprIsHNF (Lit l)          = True
 636 exprIsHNF (Type ty)        = True       -- Types are honorary Values;
 637                                         -- we don't mind copying them
 638 exprIsHNF (Lam b e)        = isRuntimeVar b || exprIsHNF e
 639 exprIsHNF (Note _ e)       = exprIsHNF e
 640 exprIsHNF (Cast e co)      = exprIsHNF e
 641 exprIsHNF (App e (Type _)) = exprIsHNF e
 642 exprIsHNF (App e a)        = app_is_value e [a]
 643 exprIsHNF other            = False
 644
 645 -- There is at least one value argument
 646 app_is_value (Var fun) args
 647   = idArity fun > valArgCount args      -- Under-applied function
 648     ||  isDataConWorkId fun             --  or data constructor
 649 app_is_value (Note n f) as = app_is_value f as
 650 app_is_value (Cast f _) as = app_is_value f as
 651 app_is_value (App f a)  as = app_is_value f (a:as)
 652 app_is_value other      as = False
 653 \end{code}
 654
 655 \begin{code}
 656 -- These InstPat functions go here to avoid circularity between DataCon and Id
 657 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat (FSLIT("ipv")))
 658 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 659 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat (FSLIT("ipv")))
 660   where
 661     dc_arg_tys dc = map mkPredTy (dataConTheta dc) ++ dataConOrigArgTys dc
 662         -- Remember to include the existential dictionaries
 663
 664 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 665                   -> [FastString]          -- A long enough list of FSs to use for names
 666                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 667                   -> DataCon
 668                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 669                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 670 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 671 -- (ex_tvs, co_tvs, arg_ids),
 672 --
 673 --   ex_tvs are intended to be used as binders for existential type args
 674 --
 675 --   co_tvs are intended to be used as binders for coercion args and the kinds
 676 --     of these vars have been instantiated by the inst_tys and the ex_tys
 677 --
 678 --   arg_ids are indended to be used as binders for value arguments, including
 679 --     dicts, and their types have been instantiated with inst_tys and ex_tys
 680 --
 681 -- Example.
 682 --  The following constructor T1
 683 --
 684 --  data T a where
 685 --    T1 :: forall b. Int -> b -> T(a,b)
 686 --    ...
 687 --
 688 --  has representation type
 689 --   forall a. forall a1. forall b. (a :=: (a1,b)) =>
 690 --     Int -> b -> T a
 691 --
 692 --  dataConInstPat fss us T1 (a1',b') will return
 693 --
 694 --  ([a1'', b''], [c :: (a1', b'):=:(a1'', b'')], [x :: Int, y :: b''])
 695 --
 696 --  where the double-primed variables are created with the FastStrings and
 697 --  Uniques given as fss and us
 698 dataConInstPat arg_fun fss uniqs con inst_tys
 699   = (ex_bndrs, co_bndrs, id_bndrs)
 700   where
 701     univ_tvs = dataConUnivTyVars con
 702     ex_tvs   = dataConExTyVars con
 703     arg_tys  = arg_fun con
 704     eq_spec  = dataConEqSpec con
 705     eq_preds = eqSpecPreds eq_spec
 706
 707     n_ex = length ex_tvs
 708     n_co = length eq_spec
 709
 710       -- split the Uniques and FastStrings
 711     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 712     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 713
 714     (ex_fss, fss')     = splitAt n_ex fss
 715     (co_fss, id_fss)   = splitAt n_co fss'
 716
 717       -- Make existential type variables
 718     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 719     mk_ex_var uniq fs var = mkTyVar new_name kind
 720       where
 721         new_name = mkSysTvName uniq fs
 722         kind     = tyVarKind var
 723
 724       -- Make the instantiating substitution
 725     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 726
 727       -- Make new coercion vars, instantiating kind
 728     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 729     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 730        where
 731          new_name = mkSysTvName uniq fs
 732          co_kind  = substTy subst (mkPredTy eq_pred)
 733
 734       -- make value vars, instantiating types
 735     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcLoc
 736     id_bndrs = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 737
 738 exprIsConApp_maybe :: CoreExpr -> Maybe (DataCon, [CoreExpr])
 739 -- Returns (Just (dc, [x1..xn])) if the argument expression is
 740 -- a constructor application of the form (dc x1 .. xn)
 741 exprIsConApp_maybe (Cast expr co)
 742   =     -- Here we do the PushC reduction rule as described in the FC paper
 743     case exprIsConApp_maybe expr of {
 744         Nothing            -> Nothing ;
 745         Just (dc, dc_args) ->
 746
 747         -- The transformation applies iff we have
 748         --      (C e1 ... en) `cast` co
 749         -- where co :: (T t1 .. tn) :=: (T s1 ..sn)
 750         -- That is, with a T at the top of both sides
 751         -- The left-hand one must be a T, because exprIsConApp returned True
 752         -- but the right-hand one might not be.  (Though it usually will.)
 753
 754     let (from_ty, to_ty)           = coercionKind co
 755         (from_tc, from_tc_arg_tys) = splitTyConApp from_ty
 756                 -- The inner one must be a TyConApp
 757     in
 758     case splitTyConApp_maybe to_ty of {
 759         Nothing -> Nothing ;
 760         Just (to_tc, to_tc_arg_tys)
 761                 | from_tc /= to_tc -> Nothing
 762                 -- These two Nothing cases are possible; we might see
 763                 --      (C x y) `cast` (g :: T a ~ S [a]),
 764                 -- where S is a type function.  In fact, exprIsConApp
 765                 -- will probably not be called in such circumstances,
 766                 -- but there't nothing wrong with it
 767
 768                 | otherwise  ->
 769     let
 770         tc_arity = tyConArity from_tc
 771
 772         (univ_args, rest1)  = splitAt tc_arity dc_args
 773         (ex_args, rest2)    = splitAt n_ex_tvs rest1
 774         (co_args, val_args) = splitAt n_cos rest2
 775
 776         arg_tys             = dataConRepArgTys dc
 777         dc_univ_tyvars      = dataConUnivTyVars dc
 778         dc_ex_tyvars        = dataConExTyVars dc
 779         dc_eq_spec          = dataConEqSpec dc
 780         dc_tyvars           = dc_univ_tyvars ++ dc_ex_tyvars
 781         n_ex_tvs            = length dc_ex_tyvars
 782         n_cos               = length dc_eq_spec
 783
 784         -- Make the "theta" from Fig 3 of the paper
 785         gammas              = decomposeCo tc_arity co
 786         new_tys             = gammas ++ map (\ (Type t) -> t) ex_args
 787         theta               = zipOpenTvSubst dc_tyvars new_tys
 788
 789           -- First we cast the existential coercion arguments
 790         cast_co (tv,ty) (Type co) = Type $ mkSymCoercion (substTyVar theta tv)
 791                                            `mkTransCoercion` co
 792                                            `mkTransCoercion` (substTy theta ty)
 793         new_co_args = zipWith cast_co dc_eq_spec co_args
 794
 795           -- ...and now value arguments
 796         new_val_args = zipWith cast_arg arg_tys val_args
 797         cast_arg arg_ty arg = mkCoerce (substTy theta arg_ty) arg
 798
 799     in
 800     ASSERT( length univ_args == tc_arity )
 801     ASSERT( from_tc == dataConTyCon dc )
 802     ASSERT( and (zipWith coreEqType [t | Type t <- univ_args] from_tc_arg_tys) )
 803     ASSERT( all isTypeArg (univ_args ++ ex_args) )
 804     ASSERT2( equalLength val_args arg_tys, ppr dc $$ ppr dc_tyvars $$ ppr dc_ex_tyvars $$ ppr arg_tys $$ ppr dc_args $$ ppr univ_args $$ ppr ex_args $$ ppr val_args $$ ppr arg_tys  )
 805
 806     Just (dc, map Type to_tc_arg_tys ++ ex_args ++ new_co_args ++ new_val_args)
 807     }}
 808
 809 {-
 810 -- We do not want to tell the world that we have a
 811 -- Cons, to *stop* Case of Known Cons, which removes
 812 -- the TickBox.
 813 exprIsConApp_maybe (Note (TickBox {}) expr)
 814   = Nothing
 815 exprIsConApp_maybe (Note (BinaryTickBox {}) expr)
 816   = Nothing
 817 -}
 818
 819 exprIsConApp_maybe (Note _ expr)
 820   = exprIsConApp_maybe expr
 821     -- We ignore InlineMe notes in case we have
 822     --  x = __inline_me__ (a,b)
 823     -- All part of making sure that INLINE pragmas never hurt
 824     -- Marcin tripped on this one when making dictionaries more inlinable
 825     --
 826     -- In fact, we ignore all notes.  For example,
 827     --          case _scc_ "foo" (C a b) of
 828     --                  C a b -> e
 829     -- should be optimised away, but it will be only if we look
 830     -- through the SCC note.
 831
 832 exprIsConApp_maybe expr = analyse (collectArgs expr)
 833   where
 834     analyse (Var fun, args)
 835         | Just con <- isDataConWorkId_maybe fun,
 836           args `lengthAtLeast` dataConRepArity con
 837                 -- Might be > because the arity excludes type args
 838         = Just (con,args)
 839
 840         -- Look through unfoldings, but only cheap ones, because
 841         -- we are effectively duplicating the unfolding
 842     analyse (Var fun, [])
 843         | let unf = idUnfolding fun,
 844           isCheapUnfolding unf
 845         = exprIsConApp_maybe (unfoldingTemplate unf)
 846
 847     analyse other = Nothing
 848 \end{code}
 849
 850
 851
 852 %************************************************************************
 853 %*                                                                      *
 854 \subsection{Eta reduction and expansion}
 855 %*                                                                      *
 856 %************************************************************************
 857
 858 \begin{code}
 859 exprEtaExpandArity :: DynFlags -> CoreExpr -> Arity
 860 {- The Arity returned is the number of value args the
 861    thing can be applied to without doing much work
 862
 863 exprEtaExpandArity is used when eta expanding
 864         e  ==>  \xy -> e x y
 865
 866 It returns 1 (or more) to:
 867         case x of p -> \s -> ...
 868 because for I/O ish things we really want to get that \s to the top.
 869 We are prepared to evaluate x each time round the loop in order to get that
 870
 871 It's all a bit more subtle than it looks:
 872
 873 1.  One-shot lambdas
 874
 875 Consider one-shot lambdas
 876                 let x = expensive in \y z -> E
 877 We want this to have arity 2 if the \y-abstraction is a 1-shot lambda
 878 Hence the ArityType returned by arityType
 879
 880 2.  The state-transformer hack
 881
 882 The one-shot lambda special cause is particularly important/useful for
 883 IO state transformers, where we often get
 884         let x = E in \ s -> ...
 885
 886 and the \s is a real-world state token abstraction.  Such abstractions
 887 are almost invariably 1-shot, so we want to pull the \s out, past the
 888 let x=E, even if E is expensive.  So we treat state-token lambdas as
 889 one-shot even if they aren't really.  The hack is in Id.isOneShotBndr.
 890
 891 3.  Dealing with bottom
 892
 893 Consider also
 894         f = \x -> error "foo"
 895 Here, arity 1 is fine.  But if it is
 896         f = \x -> case x of
 897                         True  -> error "foo"
 898                         False -> \y -> x+y
 899 then we want to get arity 2.  Tecnically, this isn't quite right, because
 900         (f True) `seq` 1
 901 should diverge, but it'll converge if we eta-expand f.  Nevertheless, we
 902 do so; it improves some programs significantly, and increasing convergence
 903 isn't a bad thing.  Hence the ABot/ATop in ArityType.
 904
 905 Actually, the situation is worse.  Consider
 906         f = \x -> case x of
 907                         True  -> \y -> x+y
 908                         False -> \y -> x-y
 909 Can we eta-expand here?  At first the answer looks like "yes of course", but
 910 consider
 911         (f bot) `seq` 1
 912 This should diverge!  But if we eta-expand, it won't.   Again, we ignore this
 913 "problem", because being scrupulous would lose an important transformation for
 914 many programs.
 915
 916
 917 4. Newtypes
 918
 919 Non-recursive newtypes are transparent, and should not get in the way.
 920 We do (currently) eta-expand recursive newtypes too.  So if we have, say
 921
 922         newtype T = MkT ([T] -> Int)
 923
 924 Suppose we have
 925         e = coerce T f
 926 where f has arity 1.  Then: etaExpandArity e = 1;
 927 that is, etaExpandArity looks through the coerce.
 928
 929 When we eta-expand e to arity 1: eta_expand 1 e T
 930 we want to get:                  coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
 931
 932 HOWEVER, note that if you use coerce bogusly you can ge
 933         coerce Int negate
 934 And since negate has arity 2, you might try to eta expand.  But you can't
 935 decopose Int to a function type.   Hence the final case in eta_expand.
 936 -}
 937
 938
 939 exprEtaExpandArity dflags e = arityDepth (arityType dflags e)
 940
 941 -- A limited sort of function type
 942 data ArityType = AFun Bool ArityType    -- True <=> one-shot
 943                | ATop                   -- Know nothing
 944                | ABot                   -- Diverges
 945
 946 arityDepth :: ArityType -> Arity
 947 arityDepth (AFun _ ty) = 1 + arityDepth ty
 948 arityDepth ty          = 0
 949
 950 andArityType ABot           at2           = at2
 951 andArityType ATop           at2           = ATop
 952 andArityType (AFun t1 at1)  (AFun t2 at2) = AFun (t1 && t2) (andArityType at1 at2)
 953 andArityType at1            at2           = andArityType at2 at1
 954
 955 arityType :: DynFlags -> CoreExpr -> ArityType
 956         -- (go1 e) = [b1,..,bn]
 957         -- means expression can be rewritten \x_b1 -> ... \x_bn -> body
 958         -- where bi is True <=> the lambda is one-shot
 959
 960 arityType dflags (Note n e) = arityType dflags e
 961 --      Not needed any more: etaExpand is cleverer
 962 --  | ok_note n = arityType dflags e
 963 --  | otherwise = ATop
 964
 965 arityType dflags (Cast e co) = arityType dflags e
 966
 967 arityType dflags (Var v)
 968   = mk (idArity v) (arg_tys (idType v))
 969   where
 970     mk :: Arity -> [Type] -> ArityType
 971         -- The argument types are only to steer the "state hack"
 972         -- Consider case x of
 973         --              True  -> foo
 974         --              False -> \(s:RealWorld) -> e
 975         -- where foo has arity 1.  Then we want the state hack to
 976         -- apply to foo too, so we can eta expand the case.
 977     mk 0 tys | isBottomingId v                     = ABot
 978              | (ty:tys) <- tys, isStateHackType ty = AFun True ATop
 979              | otherwise                           = ATop
 980     mk n (ty:tys) = AFun (isStateHackType ty) (mk (n-1) tys)
 981     mk n []       = AFun False                (mk (n-1) [])
 982
 983     arg_tys :: Type -> [Type]   -- Ignore for-alls
 984     arg_tys ty
 985         | Just (_, ty')  <- splitForAllTy_maybe ty = arg_tys ty'
 986         | Just (arg,res) <- splitFunTy_maybe ty    = arg : arg_tys res
 987         | otherwise                                = []
 988
 989         -- Lambdas; increase arity
 990 arityType dflags (Lam x e)
 991   | isId x    = AFun (isOneShotBndr x) (arityType dflags e)
 992   | otherwise = arityType dflags e
 993
 994         -- Applications; decrease arity
 995 arityType dflags (App f (Type _)) = arityType dflags f
 996 arityType dflags (App f a)        = case arityType dflags f of
 997                                         AFun one_shot xs | exprIsCheap a -> xs
 998                                         other                            -> ATop
 999
1000         -- Case/Let; keep arity if either the expression is cheap
1001         -- or it's a 1-shot lambda
1002         -- The former is not really right for Haskell
1003         --      f x = case x of { (a,b) -> \y. e }
1004         --  ===>
1005         --      f x y = case x of { (a,b) -> e }
1006         -- The difference is observable using 'seq'
1007 arityType dflags (Case scrut _ _ alts)
1008   = case foldr1 andArityType [arityType dflags rhs | (_,_,rhs) <- alts] of
1009         xs | exprIsCheap scrut          -> xs
1010         xs@(AFun one_shot _) | one_shot -> AFun True ATop
1011         other                           -> ATop
1012
1013 arityType dflags (Let b e)
1014   = case arityType dflags e of
1015         xs                   | cheap_bind b -> xs
1016         xs@(AFun one_shot _) | one_shot     -> AFun True ATop
1017         other                               -> ATop
1018   where
1019     cheap_bind (NonRec b e) = is_cheap (b,e)
1020     cheap_bind (Rec prs)    = all is_cheap prs
1021     is_cheap (b,e) = (dopt Opt_DictsCheap dflags && isDictId b)
1022                    || exprIsCheap e
1023         -- If the experimental -fdicts-cheap flag is on, we eta-expand through
1024         -- dictionary bindings.  This improves arities. Thereby, it also
1025         -- means that full laziness is less prone to floating out the
1026         -- application of a function to its dictionary arguments, which
1027         -- can thereby lose opportunities for fusion.  Example:
1028         --      foo :: Ord a => a -> ...
1029         --      foo = /\a \(d:Ord a). let d' = ...d... in \(x:a). ....
1030         --              -- So foo has arity 1
1031         --
1032         --      f = \x. foo dInt $ bar x
1033         --
1034         -- The (foo DInt) is floated out, and makes ineffective a RULE
1035         --      foo (bar x) = ...
1036         --
1037         -- One could go further and make exprIsCheap reply True to any
1038         -- dictionary-typed expression, but that's more work.
1039
1040 arityType dflags other = ATop
1041
1042 {- NOT NEEDED ANY MORE: etaExpand is cleverer
1043 ok_note InlineMe = False
1044 ok_note other    = True
1045     -- Notice that we do not look through __inline_me__
1046     -- This may seem surprising, but consider
1047     --          f = _inline_me (\x -> e)
1048     -- We DO NOT want to eta expand this to
1049     --          f = \x -> (_inline_me (\x -> e)) x
1050     -- because the _inline_me gets dropped now it is applied,
1051     -- giving just
1052     --          f = \x -> e
1053     -- A Bad Idea
1054 -}
1055 \end{code}
1056
1057
1058 \begin{code}
1059 etaExpand :: Arity              -- Result should have this number of value args
1060           -> [Unique]
1061           -> CoreExpr -> Type   -- Expression and its type
1062           -> CoreExpr
1063 -- (etaExpand n us e ty) returns an expression with
1064 -- the same meaning as 'e', but with arity 'n'.
1065 --
1066 -- Given e' = etaExpand n us e ty
1067 -- We should have
1068 --      ty = exprType e = exprType e'
1069 --
1070 -- Note that SCCs are not treated specially.  If we have
1071 --      etaExpand 2 (\x -> scc "foo" e)
1072 --      = (\xy -> (scc "foo" e) y)
1073 -- So the costs of evaluating 'e' (not 'e y') are attributed to "foo"
1074
1075 etaExpand n us expr ty
1076   | manifestArity expr >= n = expr              -- The no-op case
1077   | otherwise
1078   = eta_expand n us expr ty
1079   where
1080
1081 -- manifestArity sees how many leading value lambdas there are
1082 manifestArity :: CoreExpr -> Arity
1083 manifestArity (Lam v e) | isId v    = 1 + manifestArity e
1084                         | otherwise = manifestArity e
1085 manifestArity (Note _ e)            = manifestArity e
1086 manifestArity (Cast e _)            = manifestArity e
1087 manifestArity e                     = 0
1088
1089 -- etaExpand deals with for-alls. For example:
1090 --              etaExpand 1 E
1091 -- where  E :: forall a. a -> a
1092 -- would return
1093 --      (/\b. \y::a -> E b y)
1094 --
1095 -- It deals with coerces too, though they are now rare
1096 -- so perhaps the extra code isn't worth it
1097
1098 eta_expand n us expr ty
1099   | n == 0 &&
1100     -- The ILX code generator requires eta expansion for type arguments
1101     -- too, but alas the 'n' doesn't tell us how many of them there
1102     -- may be.  So we eagerly eta expand any big lambdas, and just
1103     -- cross our fingers about possible loss of sharing in the ILX case.
1104     -- The Right Thing is probably to make 'arity' include
1105     -- type variables throughout the compiler.  (ToDo.)
1106     not (isForAllTy ty)
1107     -- Saturated, so nothing to do
1108   = expr
1109
1110         -- Short cut for the case where there already
1111         -- is a lambda; no point in gratuitously adding more
1112 eta_expand n us (Lam v body) ty
1113   | isTyVar v
1114   = Lam v (eta_expand n us body (applyTy ty (mkTyVarTy v)))
1115
1116   | otherwise
1117   = Lam v (eta_expand (n-1) us body (funResultTy ty))
1118
1119 -- We used to have a special case that stepped inside Coerces here,
1120 -- thus:  eta_expand n us (Note note@(Coerce _ ty) e) _
1121 --              = Note note (eta_expand n us e ty)
1122 -- BUT this led to an infinite loop
1123 -- Example:     newtype T = MkT (Int -> Int)
1124 --      eta_expand 1 (coerce (Int->Int) e)
1125 --      --> coerce (Int->Int) (eta_expand 1 T e)
1126 --              by the bogus eqn
1127 --      --> coerce (Int->Int) (coerce T
1128 --              (\x::Int -> eta_expand 1 (coerce (Int->Int) e)))
1129 --              by the splitNewType_maybe case below
1130 --      and round we go
1131
1132 eta_expand n us expr ty
1133   = ASSERT2 (exprType expr `coreEqType` ty, ppr (exprType expr) $$ ppr ty)
1134     case splitForAllTy_maybe ty of {
1135           Just (tv,ty') ->
1136
1137               Lam lam_tv (eta_expand n us2 (App expr (Type (mkTyVarTy lam_tv))) (substTyWith [tv] [mkTyVarTy lam_tv] ty'))
1138                   where
1139                     lam_tv = setVarName tv (mkSysTvName uniq FSLIT("etaT"))
1140                         -- Using tv as a base retains its tyvar/covar-ness
1141                     (uniq:us2) = us
1142         ; Nothing ->
1143
1144         case splitFunTy_maybe ty of {
1145           Just (arg_ty, res_ty) -> Lam arg1 (eta_expand (n-1) us2 (App expr (Var arg1)) res_ty)
1146                                 where
1147                                    arg1       = mkSysLocal FSLIT("eta") uniq arg_ty
1148                                    (uniq:us2) = us
1149
1150         ; Nothing ->
1151
1152                 -- Given this:
1153                 --      newtype T = MkT ([T] -> Int)
1154                 -- Consider eta-expanding this
1155                 --      eta_expand 1 e T
1156                 -- We want to get
1157                 --      coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
1158
1159         case splitNewTypeRepCo_maybe ty of {
1160           Just(ty1,co) ->
1161               mkCoerce (mkSymCoercion co) (eta_expand n us (mkCoerce co expr) ty1) ;
1162           Nothing  ->
1163
1164         -- We have an expression of arity > 0, but its type isn't a function
1165         -- This *can* legitmately happen: e.g.  coerce Int (\x. x)
1166         -- Essentially the programmer is playing fast and loose with types
1167         -- (Happy does this a lot).  So we simply decline to eta-expand.
1168         expr
1169         }}}
1170 \end{code}
1171
1172 exprArity is a cheap-and-cheerful version of exprEtaExpandArity.
1173 It tells how many things the expression can be applied to before doing
1174 any work.  It doesn't look inside cases, lets, etc.  The idea is that
1175 exprEtaExpandArity will do the hard work, leaving something that's easy
1176 for exprArity to grapple with.  In particular, Simplify uses exprArity to
1177 compute the ArityInfo for the Id.
1178
1179 Originally I thought that it was enough just to look for top-level lambdas, but
1180 it isn't.  I've seen this
1181
1182         foo = PrelBase.timesInt
1183
1184 We want foo to get arity 2 even though the eta-expander will leave it
1185 unchanged, in the expectation that it'll be inlined.  But occasionally it
1186 isn't, because foo is blacklisted (used in a rule).
1187
1188 Similarly, see the ok_note check in exprEtaExpandArity.  So
1189         f = __inline_me (\x -> e)
1190 won't be eta-expanded.
1191
1192 And in any case it seems more robust to have exprArity be a bit more intelligent.
1193 But note that   (\x y z -> f x y z)
1194 should have arity 3, regardless of f's arity.
1195
1196 \begin{code}
1197 exprArity :: CoreExpr -> Arity
1198 exprArity e = go e
1199             where
1200               go (Var v)                   = idArity v
1201               go (Lam x e) | isId x        = go e + 1
1202                            | otherwise     = go e
1203               go (Note n e)                = go e
1204               go (Cast e _)                = go e
1205               go (App e (Type t))          = go e
1206               go (App f a) | exprIsCheap a = (go f - 1) `max` 0
1207                 -- NB: exprIsCheap a!
1208                 --      f (fac x) does not have arity 2,
1209                 --      even if f has arity 3!
1210                 -- NB: `max 0`!  (\x y -> f x) has arity 2, even if f is
1211                 --               unknown, hence arity 0
1212               go _                         = 0
1213 \end{code}
1214
1215 %************************************************************************
1216 %*                                                                      *
1217 \subsection{Equality}
1218 %*                                                                      *
1219 %************************************************************************
1220
1221 @cheapEqExpr@ is a cheap equality test which bales out fast!
1222         True  => definitely equal
1223         False => may or may not be equal
1224
1225 \begin{code}
1226 cheapEqExpr :: Expr b -> Expr b -> Bool
1227
1228 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1229 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1230 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1231
1232 cheapEqExpr (App f1 a1) (App f2 a2)
1233   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1234
1235 cheapEqExpr _ _ = False
1236
1237 exprIsBig :: Expr b -> Bool
1238 -- Returns True of expressions that are too big to be compared by cheapEqExpr
1239 exprIsBig (Lit _)      = False
1240 exprIsBig (Var v)      = False
1241 exprIsBig (Type t)     = False
1242 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1243 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1244 exprIsBig other        = True
1245 \end{code}
1246
1247
1248 \begin{code}
1249 tcEqExpr :: CoreExpr -> CoreExpr -> Bool
1250 -- Used in rule matching, so does *not* look through
1251 -- newtypes, predicate types; hence tcEqExpr
1252
1253 tcEqExpr e1 e2 = tcEqExprX rn_env e1 e2
1254   where
1255     rn_env = mkRnEnv2 (mkInScopeSet (exprFreeVars e1 `unionVarSet` exprFreeVars e2))
1256
1257 tcEqExprX :: RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1258 tcEqExprX env (Var v1)     (Var v2)     = rnOccL env v1 == rnOccR env v2
1259 tcEqExprX env (Lit lit1)   (Lit lit2)   = lit1 == lit2
1260 tcEqExprX env (App f1 a1)  (App f2 a2)  = tcEqExprX env f1 f2 && tcEqExprX env a1 a2
1261 tcEqExprX env (Lam v1 e1)  (Lam v2 e2)  = tcEqExprX (rnBndr2 env v1 v2) e1 e2
1262 tcEqExprX env (Let (NonRec v1 r1) e1)
1263               (Let (NonRec v2 r2) e2)   = tcEqExprX env r1 r2
1264                                        && tcEqExprX (rnBndr2 env v1 v2) e1 e2
1265 tcEqExprX env (Let (Rec ps1) e1)
1266               (Let (Rec ps2) e2)        =  equalLength ps1 ps2
1267                                         && and (zipWith eq_rhs ps1 ps2)
1268                                         && tcEqExprX env' e1 e2
1269                                      where
1270                                        env' = foldl2 rn_bndr2 env ps2 ps2
1271                                        rn_bndr2 env (b1,_) (b2,_) = rnBndr2 env b1 b2
1272                                        eq_rhs       (_,r1) (_,r2) = tcEqExprX env' r1 r2
1273 tcEqExprX env (Case e1 v1 t1 a1)
1274               (Case e2 v2 t2 a2)     =  tcEqExprX env e1 e2
1275                                      && tcEqTypeX env t1 t2
1276                                      && equalLength a1 a2
1277                                      && and (zipWith (eq_alt env') a1 a2)
1278                                      where
1279                                        env' = rnBndr2 env v1 v2
1280
1281 tcEqExprX env (Note n1 e1) (Note n2 e2) = eq_note env n1 n2 && tcEqExprX env e1 e2
1282 tcEqExprX env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && tcEqExprX env e1 e2
1283 tcEqExprX env (Type t1)    (Type t2)    = tcEqTypeX env t1 t2
1284 tcEqExprX env e1                e2      = False
1285
1286 eq_alt env (c1,vs1,r1) (c2,vs2,r2) = c1==c2 && tcEqExprX (rnBndrs2 env vs1  vs2) r1 r2
1287
1288 eq_note env (SCC cc1)      (SCC cc2)      = cc1 == cc2
1289 eq_note env (CoreNote s1)  (CoreNote s2)  = s1 == s2
1290 eq_note env other1             other2     = False
1291 \end{code}
1292
1293
1294 %************************************************************************
1295 %*                                                                      *
1296 \subsection{The size of an expression}
1297 %*                                                                      *
1298 %************************************************************************
1299
1300 \begin{code}
1301 coreBindsSize :: [CoreBind] -> Int
1302 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1303
1304 exprSize :: CoreExpr -> Int
1305         -- A measure of the size of the expressions
1306         -- It also forces the expression pretty drastically as a side effect
1307 exprSize (Var v)         = v `seq` 1
1308 exprSize (Lit lit)       = lit `seq` 1
1309 exprSize (App f a)       = exprSize f + exprSize a
1310 exprSize (Lam b e)       = varSize b + exprSize e
1311 exprSize (Let b e)       = bindSize b + exprSize e
1312 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1313 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1314 exprSize (Note n e)      = noteSize n + exprSize e
1315 exprSize (Type t)        = seqType t `seq` 1
1316
1317 noteSize (SCC cc)       = cc `seq` 1
1318 noteSize InlineMe       = 1
1319 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1320
1321 varSize :: Var -> Int
1322 varSize b  | isTyVar b = 1
1323            | otherwise = seqType (idType b)             `seq`
1324                          megaSeqIdInfo (idInfo b)       `seq`
1325                          1
1326
1327 varsSize = foldr ((+) . varSize) 0
1328
1329 bindSize (NonRec b e) = varSize b + exprSize e
1330 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1331
1332 pairSize (b,e) = varSize b + exprSize e
1333
1334 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1335 \end{code}
1336
1337
1338 %************************************************************************
1339 %*                                                                      *
1340 \subsection{Hashing}
1341 %*                                                                      *
1342 %************************************************************************
1343
1344 \begin{code}
1345 hashExpr :: CoreExpr -> Int
1346 -- Two expressions that hash to the same Int may be equal (but may not be)
1347 -- Two expressions that hash to the different Ints are definitely unequal
1348 --
1349 -- But "unequal" here means "not identical"; two alpha-equivalent
1350 -- expressions may hash to the different Ints
1351 --
1352 -- The emphasis is on a crude, fast hash, rather than on high precision
1353 --
1354 -- We must be careful that \x.x and \y.y map to the same hash code,
1355 -- (at least if we want the above invariant to be true)
1356
1357 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1358              -- UniqFM doesn't like negative Ints
1359
1360 type HashEnv = (Int, VarEnv Int)        -- Hash code for bound variables
1361
1362 hash_expr :: HashEnv -> CoreExpr -> Word32
1363 -- Word32, because we're expecting overflows here, and overflowing
1364 -- signed types just isn't cool.  In C it's even undefined.
1365 hash_expr env (Note _ e)              = hash_expr env e
1366 hash_expr env (Cast e co)             = hash_expr env e
1367 hash_expr env (Var v)                 = hashVar env v
1368 hash_expr env (Lit lit)               = fromIntegral (hashLiteral lit)
1369 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1370 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1371 hash_expr env (Let (Rec ((b,r):_)) e) = hash_expr (extend_env env b) e
1372 hash_expr env (Case e _ _ _)          = hash_expr env e
1373 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1374 hash_expr env (Type t)                = WARN(True, text "hash_expr: type") 1
1375 -- Shouldn't happen.  Better to use WARN than trace, because trace
1376 -- prevents the CPR optimisation kicking in for hash_expr.
1377
1378 fast_hash_expr env (Var v)      = hashVar env v
1379 fast_hash_expr env (Type t)     = fast_hash_type env t
1380 fast_hash_expr env (Lit lit)    = fromIntegral (hashLiteral lit)
1381 fast_hash_expr env (Cast e co)  = fast_hash_expr env e
1382 fast_hash_expr env (Note n e)   = fast_hash_expr env e
1383 fast_hash_expr env (App f a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1384 fast_hash_expr env other        = 1
1385
1386 fast_hash_type :: HashEnv -> Type -> Word32
1387 fast_hash_type env ty
1388   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1389   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1390                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1391   | otherwise                               = 1
1392
1393 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1394 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1395
1396 hashVar :: HashEnv -> Var -> Word32
1397 hashVar (_,env) v
1398  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1399 \end{code}
1400
1401 %************************************************************************
1402 %*                                                                      *
1403 \subsection{Determining non-updatable right-hand-sides}
1404 %*                                                                      *
1405 %************************************************************************
1406
1407 Top-level constructor applications can usually be allocated
1408 statically, but they can't if the constructor, or any of the
1409 arguments, come from another DLL (because we can't refer to static
1410 labels in other DLLs).
1411
1412 If this happens we simply make the RHS into an updatable thunk,
1413 and 'exectute' it rather than allocating it statically.
1414
1415 \begin{code}
1416 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1417 -- This function is called only on *top-level* right-hand sides
1418 -- Returns True if the RHS can be allocated statically, with
1419 -- no thunks involved at all.
1420 --
1421 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1422 -- refers to, CAFs; and (ii) in CoreToStg to decide whether to put an
1423 -- update flag on it.
1424 --
1425 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1426 --      (a) a value lambda
1427 --      (b) a saturated constructor application with static args
1428 --
1429 -- BUT watch out for
1430 --  (i) Any cross-DLL references kill static-ness completely
1431 --      because they must be 'executed' not statically allocated
1432 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1433 --      this is not necessary)
1434 --
1435 -- (ii) We treat partial applications as redexes, because in fact we
1436 --      make a thunk for them that runs and builds a PAP
1437 --      at run-time.  The only appliations that are treated as
1438 --      static are *saturated* applications of constructors.
1439
1440 -- We used to try to be clever with nested structures like this:
1441 --              ys = (:) w ((:) w [])
1442 -- on the grounds that CorePrep will flatten ANF-ise it later.
1443 -- But supporting this special case made the function much more
1444 -- complicated, because the special case only applies if there are no
1445 -- enclosing type lambdas:
1446 --              ys = /\ a -> Foo (Baz ([] a))
1447 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1448 --
1449 -- But in fact, even without -O, nested structures at top level are
1450 -- flattened by the simplifier, so we don't need to be super-clever here.
1451 --
1452 -- Examples
1453 --
1454 --      f = \x::Int. x+7        TRUE
1455 --      p = (True,False)        TRUE
1456 --
1457 --      d = (fst p, False)      FALSE because there's a redex inside
1458 --                              (this particular one doesn't happen but...)
1459 --
1460 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1461 --      n = /\a. Nil a                  TRUE
1462 --
1463 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1464 --
1465 --
1466 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1467 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1468 --
1469 --    b) (C x xs), where C is a contructors is updatable if the application is
1470 --         dynamic
1471 --
1472 --    c) don't look through unfolding of f in (f x).
1473 --
1474 -- When opt_RuntimeTypes is on, we keep type lambdas and treat
1475 -- them as making the RHS re-entrant (non-updatable).
1476
1477 rhsIsStatic this_pkg rhs = is_static False rhs
1478   where
1479   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1480           -> CoreExpr -> Bool
1481
1482   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1483
1484   is_static in_arg (Note (SCC _) e) = False
1485   is_static in_arg (Note _ e)       = is_static in_arg e
1486   is_static in_arg (Cast e co)      = is_static in_arg e
1487
1488   is_static in_arg (Lit lit)
1489     = case lit of
1490         MachLabel _ _ -> False
1491         other         -> True
1492         -- A MachLabel (foreign import "&foo") in an argument
1493         -- prevents a constructor application from being static.  The
1494         -- reason is that it might give rise to unresolvable symbols
1495         -- in the object file: under Linux, references to "weak"
1496         -- symbols from the data segment give rise to "unresolvable
1497         -- relocation" errors at link time This might be due to a bug
1498         -- in the linker, but we'll work around it here anyway.
1499         -- SDM 24/2/2004
1500
1501   is_static in_arg other_expr = go other_expr 0
1502    where
1503     go (Var f) n_val_args
1504 #if mingw32_TARGET_OS
1505         | not (isDllName this_pkg (idName f))
1506 #endif
1507         =  saturated_data_con f n_val_args
1508         || (in_arg && n_val_args == 0)
1509                 -- A naked un-applied variable is *not* deemed a static RHS
1510                 -- E.g.         f = g
1511                 -- Reason: better to update so that the indirection gets shorted
1512                 --         out, and the true value will be seen
1513                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1514                 --     are always updatable.  If you do so, make sure that non-updatable
1515                 --     ones have enough space for their static link field!
1516
1517     go (App f a) n_val_args
1518         | isTypeArg a                    = go f n_val_args
1519         | not in_arg && is_static True a = go f (n_val_args + 1)
1520         -- The (not in_arg) checks that we aren't in a constructor argument;
1521         -- if we are, we don't allow (value) applications of any sort
1522         --
1523         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1524         --   x = D# (1.0## /## 2.0##)
1525         -- can't float because /## can fail.
1526
1527     go (Note (SCC _) f) n_val_args = False
1528     go (Note _ f) n_val_args       = go f n_val_args
1529     go (Cast e co) n_val_args      = go e n_val_args
1530
1531     go other n_val_args = False
1532
1533     saturated_data_con f n_val_args
1534         = case isDataConWorkId_maybe f of
1535             Just dc -> n_val_args == dataConRepArity dc
1536             Nothing -> False
1537 \end{code}