compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkInlineMe, mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkIfThenElse, mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsCheap,
  29         exprIsHNF,exprOkForSpeculation, exprIsBig,
  30         exprIsConApp_maybe, exprIsBottom,
  31         rhsIsStatic,
  32
  33         -- * Arity and eta expansion
  34         manifestArity, exprArity,
  35         exprEtaExpandArity, etaExpand,
  36
  37         -- * Expression and bindings size
  38         coreBindsSize, exprSize,
  39
  40         -- * Hashing
  41         hashExpr,
  42
  43         -- * Equality
  44         cheapEqExpr, tcEqExpr, tcEqExprX,
  45
  46         -- * Manipulating data constructors and types
  47         applyTypeToArgs, applyTypeToArg,
  48         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  49     ) where
  50
  51 #include "HsVersions.h"
  52
  53 import CoreSyn
  54 import CoreFVs
  55 import PprCore
  56 import Var
  57 import SrcLoc
  58 import VarSet
  59 import VarEnv
  60 import Name
  61 import Module
  62 #if mingw32_TARGET_OS
  63 import Packages
  64 #endif
  65 import Literal
  66 import DataCon
  67 import PrimOp
  68 import Id
  69 import IdInfo
  70 import NewDemand
  71 import Type
  72 import Coercion
  73 import TyCon
  74 import TysWiredIn
  75 import CostCentre
  76 import BasicTypes
  77 import Unique
  78 import Outputable
  79 import DynFlags
  80 import TysPrim
  81 import FastString
  82 import Maybes
  83 import Util
  84 import Data.Word
  85 import Data.Bits
  86
  87 import GHC.Exts         -- For `xori`
  88 \end{code}
  89
  90
  91 %************************************************************************
  92 %*                                                                      *
  93 \subsection{Find the type of a Core atom/expression}
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 \begin{code}
  98 exprType :: CoreExpr -> Type
  99 -- ^ Recover the type of a well-typed Core expression. Fails when
 100 -- applied to the actual 'CoreSyn.Type' expression as it cannot
 101 -- really be said to have a type
 102 exprType (Var var)           = idType var
 103 exprType (Lit lit)           = literalType lit
 104 exprType (Let _ body)        = exprType body
 105 exprType (Case _ _ ty _)     = ty
 106 exprType (Cast _ co)         = snd (coercionKind co)
 107 exprType (Note _ e)          = exprType e
 108 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
 109 exprType e@(App _ _)
 110   = case collectArgs e of
 111         (fun, args) -> applyTypeToArgs e (exprType fun) args
 112
 113 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 114
 115 coreAltType :: CoreAlt -> Type
 116 -- ^ Returns the type of the alternatives right hand side
 117 coreAltType (_,_,rhs) = exprType rhs
 118
 119 coreAltsType :: [CoreAlt] -> Type
 120 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 121 coreAltsType (alt:_) = coreAltType alt
 122 coreAltsType []      = panic "corAltsType"
 123 \end{code}
 124
 125 \begin{code}
 126 mkPiType  :: Var   -> Type -> Type
 127 -- ^ Makes a @(->)@ type or a forall type, depending
 128 -- on whether it is given a type variable or a term variable.
 129 mkPiTypes :: [Var] -> Type -> Type
 130 -- ^ 'mkPiType' for multiple type or value arguments
 131
 132 mkPiType v ty
 133    | isId v    = mkFunTy (idType v) ty
 134    | otherwise = mkForAllTy v ty
 135
 136 mkPiTypes vs ty = foldr mkPiType ty vs
 137 \end{code}
 138
 139 \begin{code}
 140 applyTypeToArg :: Type -> CoreExpr -> Type
 141 -- ^ Determines the type resulting from applying an expression to a function with the given type
 142 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 143 applyTypeToArg fun_ty _             = funResultTy fun_ty
 144
 145 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 146 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 147 -- The first argument is just for debugging, and gives some context
 148 applyTypeToArgs _ op_ty [] = op_ty
 149
 150 applyTypeToArgs e op_ty (Type ty : args)
 151   =     -- Accumulate type arguments so we can instantiate all at once
 152     go [ty] args
 153   where
 154     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 155     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 156                                 where
 157                                   op_ty' = applyTys op_ty (reverse rev_tys)
 158
 159 applyTypeToArgs e op_ty (_ : args)
 160   = case (splitFunTy_maybe op_ty) of
 161         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 162         Nothing -> pprPanic "applyTypeToArgs" (pprCoreExpr e $$ ppr op_ty)
 163 \end{code}
 164
 165 %************************************************************************
 166 %*                                                                      *
 167 \subsection{Attaching notes}
 168 %*                                                                      *
 169 %************************************************************************
 170
 171 mkNote removes redundant coercions, and SCCs where possible
 172
 173 \begin{code}
 174 #ifdef UNUSED
 175 mkNote :: Note -> CoreExpr -> CoreExpr
 176 mkNote (SCC cc) expr               = mkSCC cc expr
 177 mkNote InlineMe expr               = mkInlineMe expr
 178 mkNote note     expr               = Note note expr
 179 #endif
 180 \end{code}
 181
 182 Drop trivial InlineMe's.  This is somewhat important, because if we have an unfolding
 183 that looks like (Note InlineMe (Var v)), the InlineMe doesn't go away because it may
 184 not be *applied* to anything.
 185
 186 We don't use exprIsTrivial here, though, because we sometimes generate worker/wrapper
 187 bindings like
 188         fw = ...
 189         f  = inline_me (coerce t fw)
 190 As usual, the inline_me prevents the worker from getting inlined back into the wrapper.
 191 We want the split, so that the coerces can cancel at the call site.
 192
 193 However, we can get left with tiresome type applications.  Notably, consider
 194         f = /\ a -> let t = e in (t, w)
 195 Then lifting the let out of the big lambda gives
 196         t' = /\a -> e
 197         f = /\ a -> let t = inline_me (t' a) in (t, w)
 198 The inline_me is to stop the simplifier inlining t' right back
 199 into t's RHS.  In the next phase we'll substitute for t (since
 200 its rhs is trivial) and *then* we could get rid of the inline_me.
 201 But it hardly seems worth it, so I don't bother.
 202
 203 \begin{code}
 204 -- | Wraps the given expression in an inlining hint unless the expression
 205 -- is trivial in some sense, so that doing so would usually hurt us
 206 mkInlineMe :: CoreExpr -> CoreExpr
 207 mkInlineMe (Var v) = Var v
 208 mkInlineMe e       = Note InlineMe e
 209 \end{code}
 210
 211 \begin{code}
 212 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 213 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 214 mkCoerceI IdCo e = e
 215 mkCoerceI (ACo co) e = mkCoerce co e
 216
 217 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 218 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 219 mkCoerce co (Cast expr co2)
 220   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 221                  (_from_ty2, to_ty2) = coercionKind co2} in
 222            from_ty `coreEqType` to_ty2 )
 223     mkCoerce (mkTransCoercion co2 co) expr
 224
 225 mkCoerce co expr
 226   = let (from_ty, _to_ty) = coercionKind co in
 227 --    if to_ty `coreEqType` from_ty
 228 --    then expr
 229 --    else
 230         ASSERT2(from_ty `coreEqType` (exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ ppr (coercionKindPredTy co))
 231          (Cast expr co)
 232 \end{code}
 233
 234 \begin{code}
 235 -- | Wraps the given expression in the cost centre unless
 236 -- in a way that maximises their utility to the user
 237 mkSCC :: CostCentre -> Expr b -> Expr b
 238         -- Note: Nested SCC's *are* preserved for the benefit of
 239         --       cost centre stack profiling
 240 mkSCC _  (Lit lit)          = Lit lit
 241 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 242 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 243 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 244 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 245 mkSCC cc expr               = Note (SCC cc) expr
 246 \end{code}
 247
 248
 249 %************************************************************************
 250 %*                                                                      *
 251 \subsection{Other expression construction}
 252 %*                                                                      *
 253 %************************************************************************
 254
 255 \begin{code}
 256 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 257 -- ^ @bindNonRec x r b@ produces either:
 258 --
 259 -- > let x = r in b
 260 --
 261 -- or:
 262 --
 263 -- > case r of x { _DEFAULT_ -> b }
 264 --
 265 -- depending on whether we have to use a @case@ or @let@
 266 -- binding for the expression (see 'needsCaseBinding').
 267 -- It's used by the desugarer to avoid building bindings
 268 -- that give Core Lint a heart attack, although actually
 269 -- the simplifier deals with them perfectly well. See
 270 -- also 'MkCore.mkCoreLet'
 271 bindNonRec bndr rhs body
 272   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 273   | otherwise                          = Let (NonRec bndr rhs) body
 274
 275 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 276 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 277 needsCaseBinding :: Type -> CoreExpr -> Bool
 278 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 279         -- Make a case expression instead of a let
 280         -- These can arise either from the desugarer,
 281         -- or from beta reductions: (\x.e) (x +# y)
 282 \end{code}
 283
 284 \begin{code}
 285 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 286           -> [CoreBndr] -- ^ Things bound by the pattern match
 287           -> [Type]     -- ^ The type arguments to the case alternative
 288           -> CoreExpr
 289 -- ^ This guy constructs the value that the scrutinee must have
 290 -- given that you are in one particular branch of a case
 291 mkAltExpr (DataAlt con) args inst_tys
 292   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 293 mkAltExpr (LitAlt lit) [] []
 294   = Lit lit
 295 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 296 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 297
 298 mkIfThenElse :: CoreExpr -> CoreExpr -> CoreExpr -> CoreExpr
 299 mkIfThenElse guard then_expr else_expr
 300 -- Not going to be refining, so okay to take the type of the "then" clause
 301   = Case guard (mkWildId boolTy) (exprType then_expr)
 302          [ (DataAlt falseDataCon, [], else_expr),       -- Increasing order of tag!
 303            (DataAlt trueDataCon,  [], then_expr) ]
 304 \end{code}
 305
 306
 307 %************************************************************************
 308 %*                                                                      *
 309 \subsection{Taking expressions apart}
 310 %*                                                                      *
 311 %************************************************************************
 312
 313 The default alternative must be first, if it exists at all.
 314 This makes it easy to find, though it makes matching marginally harder.
 315
 316 \begin{code}
 317 -- | Extract the default case alternative
 318 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 319 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 320 findDefault alts                        =                     (alts, Nothing)
 321
 322 -- | Find the case alternative corresponding to a particular
 323 -- constructor: panics if no such constructor exists
 324 findAlt :: AltCon -> [CoreAlt] -> CoreAlt
 325 findAlt con alts
 326   = case alts of
 327         (deflt@(DEFAULT,_,_):alts) -> go alts deflt
 328         _                          -> go alts panic_deflt
 329   where
 330     panic_deflt = pprPanic "Missing alternative" (ppr con $$ vcat (map ppr alts))
 331
 332     go []                      deflt = deflt
 333     go (alt@(con1,_,_) : alts) deflt
 334       = case con `cmpAltCon` con1 of
 335           LT -> deflt   -- Missed it already; the alts are in increasing order
 336           EQ -> alt
 337           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 338
 339 isDefaultAlt :: CoreAlt -> Bool
 340 isDefaultAlt (DEFAULT, _, _) = True
 341 isDefaultAlt _               = False
 342
 343 ---------------------------------
 344 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 345 -- ^ Merge alternatives preserving order; alternatives in
 346 -- the first argument shadow ones in the second
 347 mergeAlts [] as2 = as2
 348 mergeAlts as1 [] = as1
 349 mergeAlts (a1:as1) (a2:as2)
 350   = case a1 `cmpAlt` a2 of
 351         LT -> a1 : mergeAlts as1      (a2:as2)
 352         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 353         GT -> a2 : mergeAlts (a1:as1) as2
 354
 355
 356 ---------------------------------
 357 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 358 -- ^ Given:
 359 --
 360 -- > case (C a b x y) of
 361 -- >        C b x y -> ...
 362 --
 363 -- We want to drop the leading type argument of the scrutinee
 364 -- leaving the arguments to match agains the pattern
 365
 366 trimConArgs DEFAULT      args = ASSERT( null args ) []
 367 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 368 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 369 \end{code}
 370
 371
 372 %************************************************************************
 373 %*                                                                      *
 374 \subsection{Figuring out things about expressions}
 375 %*                                                                      *
 376 %************************************************************************
 377
 378 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 379                 duplicate; simple variables and constants, and type
 380                 applications.  Note that primop Ids aren't considered
 381                 trivial unless
 382
 383 There used to be a gruesome test for (hasNoBinding v) in the
 384 Var case:
 385         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 386 The idea here is that a constructor worker, like \$wJust, is
 387 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 388 So it should be treated like a lambda.  Ditto unsaturated primops.
 389 But now constructor workers are not "have-no-binding" Ids.  And
 390 completely un-applied primops and foreign-call Ids are sufficiently
 391 rare that I plan to allow them to be duplicated and put up with
 392 saturating them.
 393
 394 SCC notes.  We do not treat (_scc_ "foo" x) as trivial, because
 395   a) it really generates code, (and a heap object when it's
 396      a function arg) to capture the cost centre
 397   b) see the note [SCC-and-exprIsTrivial] in Simplify.simplLazyBind
 398
 399 \begin{code}
 400 exprIsTrivial :: CoreExpr -> Bool
 401 exprIsTrivial (Var _)          = True        -- See notes above
 402 exprIsTrivial (Type _)         = True
 403 exprIsTrivial (Lit lit)        = litIsTrivial lit
 404 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 405 exprIsTrivial (Note (SCC _) _) = False       -- See notes above
 406 exprIsTrivial (Note _       e) = exprIsTrivial e
 407 exprIsTrivial (Cast e _)       = exprIsTrivial e
 408 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 409 exprIsTrivial _                = False
 410 \end{code}
 411
 412
 413 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 414                 cost in code size.  This will only happen in different case
 415                 branches, so there's no issue about duplicating work.
 416
 417                 That is, exprIsDupable returns True of (f x) even if
 418                 f is very very expensive to call.
 419
 420                 Its only purpose is to avoid fruitless let-binding
 421                 and then inlining of case join points
 422
 423
 424 \begin{code}
 425 exprIsDupable :: CoreExpr -> Bool
 426 exprIsDupable (Type _)          = True
 427 exprIsDupable (Var _)           = True
 428 exprIsDupable (Lit lit)         = litIsDupable lit
 429 exprIsDupable (Note InlineMe _) = True
 430 exprIsDupable (Note _ e)        = exprIsDupable e
 431 exprIsDupable (Cast e _)        = exprIsDupable e
 432 exprIsDupable expr
 433   = go expr 0
 434   where
 435     go (Var _)   _      = True
 436     go (App f a) n_args =  n_args < dupAppSize
 437                         && exprIsDupable a
 438                         && go f (n_args+1)
 439     go _         _      = False
 440
 441 dupAppSize :: Int
 442 dupAppSize = 4          -- Size of application we are prepared to duplicate
 443 \end{code}
 444
 445 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 446 it is obviously in weak head normal form, or is cheap to get to WHNF.
 447 [Note that that's not the same as exprIsDupable; an expression might be
 448 big, and hence not dupable, but still cheap.]
 449
 450 By ``cheap'' we mean a computation we're willing to:
 451         push inside a lambda, or
 452         inline at more than one place
 453 That might mean it gets evaluated more than once, instead of being
 454 shared.  The main examples of things which aren't WHNF but are
 455 ``cheap'' are:
 456
 457   *     case e of
 458           pi -> ei
 459         (where e, and all the ei are cheap)
 460
 461   *     let x = e in b
 462         (where e and b are cheap)
 463
 464   *     op x1 ... xn
 465         (where op is a cheap primitive operator)
 466
 467   *     error "foo"
 468         (because we are happy to substitute it inside a lambda)
 469
 470 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 471 because sharing will make sure it is only evaluated once.
 472
 473 \begin{code}
 474 exprIsCheap :: CoreExpr -> Bool
 475 exprIsCheap (Lit _)           = True
 476 exprIsCheap (Type _)          = True
 477 exprIsCheap (Var _)           = True
 478 exprIsCheap (Note InlineMe _) = True
 479 exprIsCheap (Note _ e)        = exprIsCheap e
 480 exprIsCheap (Cast e _)        = exprIsCheap e
 481 exprIsCheap (Lam x e)         = isRuntimeVar x || exprIsCheap e
 482 exprIsCheap (Case e _ _ alts) = exprIsCheap e &&
 483                                 and [exprIsCheap rhs | (_,_,rhs) <- alts]
 484         -- Experimentally, treat (case x of ...) as cheap
 485         -- (and case __coerce x etc.)
 486         -- This improves arities of overloaded functions where
 487         -- there is only dictionary selection (no construction) involved
 488 exprIsCheap (Let (NonRec x _) e)
 489       | isUnLiftedType (idType x) = exprIsCheap e
 490       | otherwise                 = False
 491         -- strict lets always have cheap right hand sides,
 492         -- and do no allocation.
 493
 494 exprIsCheap other_expr  -- Applications and variables
 495   = go other_expr []
 496   where
 497         -- Accumulate value arguments, then decide
 498     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 499                           | otherwise      = go f val_args
 500
 501     go (Var _) [] = True        -- Just a type application of a variable
 502                                 -- (f t1 t2 t3) counts as WHNF
 503     go (Var f) args
 504         = case globalIdDetails f of
 505                 RecordSelId {} -> go_sel args
 506                 ClassOpId _    -> go_sel args
 507                 PrimOpId op    -> go_primop op args
 508
 509                 DataConWorkId _ -> go_pap args
 510                 _ | length args < idArity f -> go_pap args
 511
 512                 _ -> isBottomingId f
 513                         -- Application of a function which
 514                         -- always gives bottom; we treat this as cheap
 515                         -- because it certainly doesn't need to be shared!
 516
 517     go _ _ = False
 518
 519     --------------
 520     go_pap args = all exprIsTrivial args
 521         -- For constructor applications and primops, check that all
 522         -- the args are trivial.  We don't want to treat as cheap, say,
 523         --      (1:2:3:4:5:[])
 524         -- We'll put up with one constructor application, but not dozens
 525
 526     --------------
 527     go_primop op args = primOpIsCheap op && all exprIsCheap args
 528         -- In principle we should worry about primops
 529         -- that return a type variable, since the result
 530         -- might be applied to something, but I'm not going
 531         -- to bother to check the number of args
 532
 533     --------------
 534     go_sel [arg] = exprIsCheap arg      -- I'm experimenting with making record selection
 535     go_sel _     = False                -- look cheap, so we will substitute it inside a
 536                                         -- lambda.  Particularly for dictionary field selection.
 537                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 538                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 539 \end{code}
 540
 541 \begin{code}
 542 -- | 'exprOkForSpeculation' returns True of an expression that is:
 543 --
 544 --  * Safe to evaluate even if normal order eval might not
 545 --    evaluate the expression at all, or
 546 --
 547 --  * Safe /not/ to evaluate even if normal order would do so
 548 --
 549 -- Precisely, it returns @True@ iff:
 550 --
 551 --  * The expression guarantees to terminate,
 552 --
 553 --  * soon,
 554 --
 555 --  * without raising an exception,
 556 --
 557 --  * without causing a side effect (e.g. writing a mutable variable)
 558 --
 559 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 560 -- As an example of the considerations in this test, consider:
 561 --
 562 -- > let x = case y# +# 1# of { r# -> I# r# }
 563 -- > in E
 564 --
 565 -- being translated to:
 566 --
 567 -- > case y# +# 1# of { r# ->
 568 -- >    let x = I# r#
 569 -- >    in E
 570 -- > }
 571 --
 572 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 573 -- side effects, and can't diverge or raise an exception.
 574 exprOkForSpeculation :: CoreExpr -> Bool
 575 exprOkForSpeculation (Lit _)     = True
 576 exprOkForSpeculation (Type _)    = True
 577     -- Tick boxes are *not* suitable for speculation
 578 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 579                                  && not (isTickBoxOp v)
 580 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 581 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 582 exprOkForSpeculation other_expr
 583   = case collectArgs other_expr of
 584         (Var f, args) -> spec_ok (globalIdDetails f) args
 585         _             -> False
 586
 587   where
 588     spec_ok (DataConWorkId _) _
 589       = True    -- The strictness of the constructor has already
 590                 -- been expressed by its "wrapper", so we don't need
 591                 -- to take the arguments into account
 592
 593     spec_ok (PrimOpId op) args
 594       | isDivOp op,             -- Special case for dividing operations that fail
 595         [arg1, Lit lit] <- args -- only if the divisor is zero
 596       = not (isZeroLit lit) && exprOkForSpeculation arg1
 597                 -- Often there is a literal divisor, and this
 598                 -- can get rid of a thunk in an inner looop
 599
 600       | otherwise
 601       = primOpOkForSpeculation op &&
 602         all exprOkForSpeculation args
 603                                 -- A bit conservative: we don't really need
 604                                 -- to care about lazy arguments, but this is easy
 605
 606     spec_ok _ _ = False
 607
 608 -- | True of dyadic operators that can fail only if the second arg is zero!
 609 isDivOp :: PrimOp -> Bool
 610 -- This function probably belongs in PrimOp, or even in
 611 -- an automagically generated file.. but it's such a
 612 -- special case I thought I'd leave it here for now.
 613 isDivOp IntQuotOp        = True
 614 isDivOp IntRemOp         = True
 615 isDivOp WordQuotOp       = True
 616 isDivOp WordRemOp        = True
 617 isDivOp IntegerQuotRemOp = True
 618 isDivOp IntegerDivModOp  = True
 619 isDivOp FloatDivOp       = True
 620 isDivOp DoubleDivOp      = True
 621 isDivOp _                = False
 622 \end{code}
 623
 624 \begin{code}
 625 -- | True of expressions that are guaranteed to diverge upon execution
 626 exprIsBottom :: CoreExpr -> Bool
 627 exprIsBottom e = go 0 e
 628                where
 629                 -- n is the number of args
 630                  go n (Note _ e)     = go n e
 631                  go n (Cast e _)     = go n e
 632                  go n (Let _ e)      = go n e
 633                  go _ (Case e _ _ _) = go 0 e   -- Just check the scrut
 634                  go n (App e _)      = go (n+1) e
 635                  go n (Var v)        = idAppIsBottom v n
 636                  go _ (Lit _)        = False
 637                  go _ (Lam _ _)      = False
 638                  go _ (Type _)       = False
 639
 640 idAppIsBottom :: Id -> Int -> Bool
 641 idAppIsBottom id n_val_args = appIsBottom (idNewStrictness id) n_val_args
 642 \end{code}
 643
 644 \begin{code}
 645
 646 -- | This returns true for expressions that are certainly /already/
 647 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 648 -- to change:
 649 --
 650 -- > case x of _ -> e
 651 --
 652 -- into:
 653 --
 654 -- > e
 655 --
 656 -- and to decide whether it's safe to discard a 'seq'.
 657 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 658 -- However, it /does/ treat partial applications and constructor applications
 659 -- as values, even if their arguments are non-trivial, provided the argument
 660 -- type is lifted. For example, both of these are values:
 661 --
 662 -- > (:) (f x) (map f xs)
 663 -- > map (...redex...)
 664 --
 665 -- Because 'seq' on such things completes immediately.
 666 --
 667 -- For unlifted argument types, we have to be careful:
 668 --
 669 -- > C (f x :: Int#)
 670 --
 671 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 672 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 673 -- unboxed type must be ok-for-speculation (or trivial).
 674 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 675 exprIsHNF (Var v)       -- NB: There are no value args at this point
 676   =  isDataConWorkId v  -- Catches nullary constructors,
 677                         --      so that [] and () are values, for example
 678   || idArity v > 0      -- Catches (e.g.) primops that don't have unfoldings
 679   || isEvaldUnfolding (idUnfolding v)
 680         -- Check the thing's unfolding; it might be bound to a value
 681         -- A worry: what if an Id's unfolding is just itself:
 682         -- then we could get an infinite loop...
 683
 684 exprIsHNF (Lit _)          = True
 685 exprIsHNF (Type _)         = True       -- Types are honorary Values;
 686                                         -- we don't mind copying them
 687 exprIsHNF (Lam b e)        = isRuntimeVar b || exprIsHNF e
 688 exprIsHNF (Note _ e)       = exprIsHNF e
 689 exprIsHNF (Cast e _)       = exprIsHNF e
 690 exprIsHNF (App e (Type _)) = exprIsHNF e
 691 exprIsHNF (App e a)        = app_is_value e [a]
 692 exprIsHNF _                = False
 693
 694 -- There is at least one value argument
 695 app_is_value :: CoreExpr -> [CoreArg] -> Bool
 696 app_is_value (Var fun) args
 697   = idArity fun > valArgCount args      -- Under-applied function
 698     ||  isDataConWorkId fun             --  or data constructor
 699 app_is_value (Note _ f) as = app_is_value f as
 700 app_is_value (Cast f _) as = app_is_value f as
 701 app_is_value (App f a)  as = app_is_value f (a:as)
 702 app_is_value _          _  = False
 703 \end{code}
 704
 705 These InstPat functions go here to avoid circularity between DataCon and Id
 706
 707 \begin{code}
 708 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 709 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 710
 711 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 712 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 713 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 714   where
 715     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 716         -- Remember to include the existential dictionaries
 717
 718 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 719                   -> [FastString]          -- A long enough list of FSs to use for names
 720                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 721                   -> DataCon
 722                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 723                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 724 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 725 -- (ex_tvs, co_tvs, arg_ids),
 726 --
 727 --   ex_tvs are intended to be used as binders for existential type args
 728 --
 729 --   co_tvs are intended to be used as binders for coercion args and the kinds
 730 --     of these vars have been instantiated by the inst_tys and the ex_tys
 731 --     The co_tvs include both GADT equalities (dcEqSpec) and
 732 --     programmer-specified equalities (dcEqTheta)
 733 --
 734 --   arg_ids are indended to be used as binders for value arguments,
 735 --     and their types have been instantiated with inst_tys and ex_tys
 736 --     The arg_ids include both dicts (dcDictTheta) and
 737 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 738 --
 739 -- Example.
 740 --  The following constructor T1
 741 --
 742 --  data T a where
 743 --    T1 :: forall b. Int -> b -> T(a,b)
 744 --    ...
 745 --
 746 --  has representation type
 747 --   forall a. forall a1. forall b. (a :=: (a1,b)) =>
 748 --     Int -> b -> T a
 749 --
 750 --  dataConInstPat fss us T1 (a1',b') will return
 751 --
 752 --  ([a1'', b''], [c :: (a1', b'):=:(a1'', b'')], [x :: Int, y :: b''])
 753 --
 754 --  where the double-primed variables are created with the FastStrings and
 755 --  Uniques given as fss and us
 756 dataConInstPat arg_fun fss uniqs con inst_tys
 757   = (ex_bndrs, co_bndrs, arg_ids)
 758   where
 759     univ_tvs = dataConUnivTyVars con
 760     ex_tvs   = dataConExTyVars con
 761     arg_tys  = arg_fun con
 762     eq_spec  = dataConEqSpec con
 763     eq_theta = dataConEqTheta con
 764     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 765
 766     n_ex = length ex_tvs
 767     n_co = length eq_preds
 768
 769       -- split the Uniques and FastStrings
 770     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 771     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 772
 773     (ex_fss, fss')     = splitAt n_ex fss
 774     (co_fss, id_fss)   = splitAt n_co fss'
 775
 776       -- Make existential type variables
 777     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 778     mk_ex_var uniq fs var = mkTyVar new_name kind
 779       where
 780         new_name = mkSysTvName uniq fs
 781         kind     = tyVarKind var
 782
 783       -- Make the instantiating substitution
 784     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 785
 786       -- Make new coercion vars, instantiating kind
 787     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 788     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 789        where
 790          new_name = mkSysTvName uniq fs
 791          co_kind  = substTy subst (mkPredTy eq_pred)
 792
 793       -- make value vars, instantiating types
 794     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 795     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 796
 797 -- | Returns @Just (dc, [x1..xn])@ if the argument expression is
 798 -- a constructor application of the form @dc x1 .. xn@
 799 exprIsConApp_maybe :: CoreExpr -> Maybe (DataCon, [CoreExpr])
 800 exprIsConApp_maybe (Cast expr co)
 801   =     -- Here we do the KPush reduction rule as described in the FC paper
 802     case exprIsConApp_maybe expr of {
 803         Nothing            -> Nothing ;
 804         Just (dc, dc_args) ->
 805
 806         -- The transformation applies iff we have
 807         --      (C e1 ... en) `cast` co
 808         -- where co :: (T t1 .. tn) :=: (T s1 ..sn)
 809         -- That is, with a T at the top of both sides
 810         -- The left-hand one must be a T, because exprIsConApp returned True
 811         -- but the right-hand one might not be.  (Though it usually will.)
 812
 813     let (from_ty, to_ty)           = coercionKind co
 814         (from_tc, from_tc_arg_tys) = splitTyConApp from_ty
 815                 -- The inner one must be a TyConApp
 816     in
 817     case splitTyConApp_maybe to_ty of {
 818         Nothing -> Nothing ;
 819         Just (to_tc, to_tc_arg_tys)
 820                 | from_tc /= to_tc -> Nothing
 821                 -- These two Nothing cases are possible; we might see
 822                 --      (C x y) `cast` (g :: T a ~ S [a]),
 823                 -- where S is a type function.  In fact, exprIsConApp
 824                 -- will probably not be called in such circumstances,
 825                 -- but there't nothing wrong with it
 826
 827                 | otherwise  ->
 828     let
 829         tc_arity = tyConArity from_tc
 830
 831         (univ_args, rest1)        = splitAt tc_arity dc_args
 832         (ex_args, rest2)          = splitAt n_ex_tvs rest1
 833         (co_args_spec, rest3)     = splitAt n_cos_spec rest2
 834         (co_args_theta, val_args) = splitAt n_cos_theta rest3
 835
 836         arg_tys             = dataConRepArgTys dc
 837         dc_univ_tyvars      = dataConUnivTyVars dc
 838         dc_ex_tyvars        = dataConExTyVars dc
 839         dc_eq_spec          = dataConEqSpec dc
 840         dc_eq_theta         = dataConEqTheta dc
 841         dc_tyvars           = dc_univ_tyvars ++ dc_ex_tyvars
 842         n_ex_tvs            = length dc_ex_tyvars
 843         n_cos_spec          = length dc_eq_spec
 844         n_cos_theta         = length dc_eq_theta
 845
 846         -- Make the "theta" from Fig 3 of the paper
 847         gammas              = decomposeCo tc_arity co
 848         new_tys             = gammas ++ map (\ (Type t) -> t) ex_args
 849         theta               = zipOpenTvSubst dc_tyvars new_tys
 850
 851           -- First we cast the existential coercion arguments
 852         cast_co_spec (tv, ty) co
 853           = cast_co_theta (mkEqPred (mkTyVarTy tv, ty)) co
 854         cast_co_theta eqPred (Type co)
 855           | (ty1, ty2) <- getEqPredTys eqPred
 856           = Type $ mkSymCoercion (substTy theta ty1)
 857                    `mkTransCoercion` co
 858                    `mkTransCoercion` (substTy theta ty2)
 859         new_co_args = zipWith cast_co_spec  dc_eq_spec  co_args_spec ++
 860                       zipWith cast_co_theta dc_eq_theta co_args_theta
 861
 862           -- ...and now value arguments
 863         new_val_args = zipWith cast_arg arg_tys val_args
 864         cast_arg arg_ty arg = mkCoerce (substTy theta arg_ty) arg
 865
 866     in
 867     ASSERT( length univ_args == tc_arity )
 868     ASSERT( from_tc == dataConTyCon dc )
 869     ASSERT( and (zipWith coreEqType [t | Type t <- univ_args] from_tc_arg_tys) )
 870     ASSERT( all isTypeArg (univ_args ++ ex_args) )
 871     ASSERT2( equalLength val_args arg_tys, ppr dc $$ ppr dc_tyvars $$ ppr dc_ex_tyvars $$ ppr arg_tys $$ ppr dc_args $$ ppr univ_args $$ ppr ex_args $$ ppr val_args $$ ppr arg_tys  )
 872
 873     Just (dc, map Type to_tc_arg_tys ++ ex_args ++ new_co_args ++ new_val_args)
 874     }}
 875
 876 {-
 877 -- We do not want to tell the world that we have a
 878 -- Cons, to *stop* Case of Known Cons, which removes
 879 -- the TickBox.
 880 exprIsConApp_maybe (Note (TickBox {}) expr)
 881   = Nothing
 882 exprIsConApp_maybe (Note (BinaryTickBox {}) expr)
 883   = Nothing
 884 -}
 885
 886 exprIsConApp_maybe (Note _ expr)
 887   = exprIsConApp_maybe expr
 888     -- We ignore InlineMe notes in case we have
 889     --  x = __inline_me__ (a,b)
 890     -- All part of making sure that INLINE pragmas never hurt
 891     -- Marcin tripped on this one when making dictionaries more inlinable
 892     --
 893     -- In fact, we ignore all notes.  For example,
 894     --          case _scc_ "foo" (C a b) of
 895     --                  C a b -> e
 896     -- should be optimised away, but it will be only if we look
 897     -- through the SCC note.
 898
 899 exprIsConApp_maybe expr = analyse (collectArgs expr)
 900   where
 901     analyse (Var fun, args)
 902         | Just con <- isDataConWorkId_maybe fun,
 903           args `lengthAtLeast` dataConRepArity con
 904                 -- Might be > because the arity excludes type args
 905         = Just (con,args)
 906
 907         -- Look through unfoldings, but only cheap ones, because
 908         -- we are effectively duplicating the unfolding
 909     analyse (Var fun, [])
 910         | let unf = idUnfolding fun,
 911           isCheapUnfolding unf
 912         = exprIsConApp_maybe (unfoldingTemplate unf)
 913
 914     analyse _ = Nothing
 915 \end{code}
 916
 917
 918
 919 %************************************************************************
 920 %*                                                                      *
 921 \subsection{Eta reduction and expansion}
 922 %*                                                                      *
 923 %************************************************************************
 924
 925 \begin{code}
 926 -- ^ The Arity returned is the number of value args the
 927 -- expression can be applied to without doing much work
 928 exprEtaExpandArity :: DynFlags -> CoreExpr -> Arity
 929 {-
 930 exprEtaExpandArity is used when eta expanding
 931         e  ==>  \xy -> e x y
 932
 933 It returns 1 (or more) to:
 934         case x of p -> \s -> ...
 935 because for I/O ish things we really want to get that \s to the top.
 936 We are prepared to evaluate x each time round the loop in order to get that
 937
 938 It's all a bit more subtle than it looks:
 939
 940 1.  One-shot lambdas
 941
 942 Consider one-shot lambdas
 943                 let x = expensive in \y z -> E
 944 We want this to have arity 2 if the \y-abstraction is a 1-shot lambda
 945 Hence the ArityType returned by arityType
 946
 947 2.  The state-transformer hack
 948
 949 The one-shot lambda special cause is particularly important/useful for
 950 IO state transformers, where we often get
 951         let x = E in \ s -> ...
 952
 953 and the \s is a real-world state token abstraction.  Such abstractions
 954 are almost invariably 1-shot, so we want to pull the \s out, past the
 955 let x=E, even if E is expensive.  So we treat state-token lambdas as
 956 one-shot even if they aren't really.  The hack is in Id.isOneShotBndr.
 957
 958 3.  Dealing with bottom
 959
 960 Consider also
 961         f = \x -> error "foo"
 962 Here, arity 1 is fine.  But if it is
 963         f = \x -> case x of
 964                         True  -> error "foo"
 965                         False -> \y -> x+y
 966 then we want to get arity 2.  Tecnically, this isn't quite right, because
 967         (f True) `seq` 1
 968 should diverge, but it'll converge if we eta-expand f.  Nevertheless, we
 969 do so; it improves some programs significantly, and increasing convergence
 970 isn't a bad thing.  Hence the ABot/ATop in ArityType.
 971
 972 Actually, the situation is worse.  Consider
 973         f = \x -> case x of
 974                         True  -> \y -> x+y
 975                         False -> \y -> x-y
 976 Can we eta-expand here?  At first the answer looks like "yes of course", but
 977 consider
 978         (f bot) `seq` 1
 979 This should diverge!  But if we eta-expand, it won't.   Again, we ignore this
 980 "problem", because being scrupulous would lose an important transformation for
 981 many programs.
 982
 983
 984 4. Newtypes
 985
 986 Non-recursive newtypes are transparent, and should not get in the way.
 987 We do (currently) eta-expand recursive newtypes too.  So if we have, say
 988
 989         newtype T = MkT ([T] -> Int)
 990
 991 Suppose we have
 992         e = coerce T f
 993 where f has arity 1.  Then: etaExpandArity e = 1;
 994 that is, etaExpandArity looks through the coerce.
 995
 996 When we eta-expand e to arity 1: eta_expand 1 e T
 997 we want to get:                  coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
 998
 999 HOWEVER, note that if you use coerce bogusly you can ge
1000         coerce Int negate
1001 And since negate has arity 2, you might try to eta expand.  But you can't
1002 decopose Int to a function type.   Hence the final case in eta_expand.
1003 -}
1004
1005
1006 exprEtaExpandArity dflags e = arityDepth (arityType dflags e)
1007
1008 -- A limited sort of function type
1009 data ArityType = AFun Bool ArityType    -- True <=> one-shot
1010                | ATop                   -- Know nothing
1011                | ABot                   -- Diverges
1012
1013 arityDepth :: ArityType -> Arity
1014 arityDepth (AFun _ ty) = 1 + arityDepth ty
1015 arityDepth _           = 0
1016
1017 andArityType :: ArityType -> ArityType -> ArityType
1018 andArityType ABot           at2           = at2
1019 andArityType ATop           _             = ATop
1020 andArityType (AFun t1 at1)  (AFun t2 at2) = AFun (t1 && t2) (andArityType at1 at2)
1021 andArityType at1            at2           = andArityType at2 at1
1022
1023 arityType :: DynFlags -> CoreExpr -> ArityType
1024         -- (go1 e) = [b1,..,bn]
1025         -- means expression can be rewritten \x_b1 -> ... \x_bn -> body
1026         -- where bi is True <=> the lambda is one-shot
1027
1028 arityType dflags (Note _ e) = arityType dflags e
1029 --      Not needed any more: etaExpand is cleverer
1030 -- removed: | ok_note n = arityType dflags e
1031 -- removed: | otherwise = ATop
1032
1033 arityType dflags (Cast e _) = arityType dflags e
1034
1035 arityType _ (Var v)
1036   = mk (idArity v) (arg_tys (idType v))
1037   where
1038     mk :: Arity -> [Type] -> ArityType
1039         -- The argument types are only to steer the "state hack"
1040         -- Consider case x of
1041         --              True  -> foo
1042         --              False -> \(s:RealWorld) -> e
1043         -- where foo has arity 1.  Then we want the state hack to
1044         -- apply to foo too, so we can eta expand the case.
1045     mk 0 tys | isBottomingId v                   = ABot
1046              | (ty:_) <- tys, isStateHackType ty = AFun True ATop
1047              | otherwise                         = ATop
1048     mk n (ty:tys) = AFun (isStateHackType ty) (mk (n-1) tys)
1049     mk n []       = AFun False                (mk (n-1) [])
1050
1051     arg_tys :: Type -> [Type]   -- Ignore for-alls
1052     arg_tys ty
1053         | Just (_, ty')  <- splitForAllTy_maybe ty = arg_tys ty'
1054         | Just (arg,res) <- splitFunTy_maybe ty    = arg : arg_tys res
1055         | otherwise                                = []
1056
1057         -- Lambdas; increase arity
1058 arityType dflags (Lam x e)
1059   | isId x    = AFun (isOneShotBndr x) (arityType dflags e)
1060   | otherwise = arityType dflags e
1061
1062         -- Applications; decrease arity
1063 arityType dflags (App f (Type _)) = arityType dflags f
1064 arityType dflags (App f a)
1065    = case arityType dflags f of
1066         ABot -> ABot    -- If function diverges, ignore argument
1067         ATop -> ATop    -- No no info about function
1068         AFun _ xs
1069                 | exprIsCheap a -> xs
1070                 | otherwise     -> ATop
1071
1072         -- Case/Let; keep arity if either the expression is cheap
1073         -- or it's a 1-shot lambda
1074         -- The former is not really right for Haskell
1075         --      f x = case x of { (a,b) -> \y. e }
1076         --  ===>
1077         --      f x y = case x of { (a,b) -> e }
1078         -- The difference is observable using 'seq'
1079 arityType dflags (Case scrut _ _ alts)
1080   = case foldr1 andArityType [arityType dflags rhs | (_,_,rhs) <- alts] of
1081         xs | exprIsCheap scrut     -> xs
1082         AFun one_shot _ | one_shot -> AFun True ATop
1083         _                          -> ATop
1084
1085 arityType dflags (Let b e)
1086   = case arityType dflags e of
1087         xs              | cheap_bind b -> xs
1088         AFun one_shot _ | one_shot     -> AFun True ATop
1089         _                              -> ATop
1090   where
1091     cheap_bind (NonRec b e) = is_cheap (b,e)
1092     cheap_bind (Rec prs)    = all is_cheap prs
1093     is_cheap (b,e) = (dopt Opt_DictsCheap dflags && isDictId b)
1094                    || exprIsCheap e
1095         -- If the experimental -fdicts-cheap flag is on, we eta-expand through
1096         -- dictionary bindings.  This improves arities. Thereby, it also
1097         -- means that full laziness is less prone to floating out the
1098         -- application of a function to its dictionary arguments, which
1099         -- can thereby lose opportunities for fusion.  Example:
1100         --      foo :: Ord a => a -> ...
1101         --      foo = /\a \(d:Ord a). let d' = ...d... in \(x:a). ....
1102         --              -- So foo has arity 1
1103         --
1104         --      f = \x. foo dInt $ bar x
1105         --
1106         -- The (foo DInt) is floated out, and makes ineffective a RULE
1107         --      foo (bar x) = ...
1108         --
1109         -- One could go further and make exprIsCheap reply True to any
1110         -- dictionary-typed expression, but that's more work.
1111
1112 arityType _ _ = ATop
1113
1114 {- NOT NEEDED ANY MORE: etaExpand is cleverer
1115 ok_note InlineMe = False
1116 ok_note other    = True
1117     -- Notice that we do not look through __inline_me__
1118     -- This may seem surprising, but consider
1119     --          f = _inline_me (\x -> e)
1120     -- We DO NOT want to eta expand this to
1121     --          f = \x -> (_inline_me (\x -> e)) x
1122     -- because the _inline_me gets dropped now it is applied,
1123     -- giving just
1124     --          f = \x -> e
1125     -- A Bad Idea
1126 -}
1127 \end{code}
1128
1129
1130 \begin{code}
1131 -- | @etaExpand n us e ty@ returns an expression with
1132 -- the same meaning as @e@, but with arity @n@.
1133 --
1134 -- Given:
1135 --
1136 -- > e' = etaExpand n us e ty
1137 --
1138 -- We should have that:
1139 --
1140 -- > ty = exprType e = exprType e'
1141 etaExpand :: Arity              -- ^ Result should have this number of value args
1142           -> [Unique]           -- ^ Uniques to assign to the new binders
1143           -> CoreExpr           -- ^ Expression to expand
1144           -> Type               -- ^ Type of expression to expand
1145           -> CoreExpr
1146 -- Note that SCCs are not treated specially.  If we have
1147 --      etaExpand 2 (\x -> scc "foo" e)
1148 --      = (\xy -> (scc "foo" e) y)
1149 -- So the costs of evaluating 'e' (not 'e y') are attributed to "foo"
1150
1151 etaExpand n us expr ty
1152   | manifestArity expr >= n = expr              -- The no-op case
1153   | otherwise
1154   = eta_expand n us expr ty
1155
1156 -- manifestArity sees how many leading value lambdas there are
1157 manifestArity :: CoreExpr -> Arity
1158 manifestArity (Lam v e) | isId v    = 1 + manifestArity e
1159                         | otherwise = manifestArity e
1160 manifestArity (Note _ e)            = manifestArity e
1161 manifestArity (Cast e _)            = manifestArity e
1162 manifestArity _                     = 0
1163
1164 -- etaExpand deals with for-alls. For example:
1165 --              etaExpand 1 E
1166 -- where  E :: forall a. a -> a
1167 -- would return
1168 --      (/\b. \y::a -> E b y)
1169 --
1170 -- It deals with coerces too, though they are now rare
1171 -- so perhaps the extra code isn't worth it
1172 eta_expand :: Int -> [Unique] -> CoreExpr -> Type -> CoreExpr
1173
1174 eta_expand n _ expr ty
1175   | n == 0 &&
1176     -- The ILX code generator requires eta expansion for type arguments
1177     -- too, but alas the 'n' doesn't tell us how many of them there
1178     -- may be.  So we eagerly eta expand any big lambdas, and just
1179     -- cross our fingers about possible loss of sharing in the ILX case.
1180     -- The Right Thing is probably to make 'arity' include
1181     -- type variables throughout the compiler.  (ToDo.)
1182     not (isForAllTy ty)
1183     -- Saturated, so nothing to do
1184   = expr
1185
1186         -- Short cut for the case where there already
1187         -- is a lambda; no point in gratuitously adding more
1188 eta_expand n us (Lam v body) ty
1189   | isTyVar v
1190   = Lam v (eta_expand n us body (applyTy ty (mkTyVarTy v)))
1191
1192   | otherwise
1193   = Lam v (eta_expand (n-1) us body (funResultTy ty))
1194
1195 -- We used to have a special case that stepped inside Coerces here,
1196 -- thus:  eta_expand n us (Note note@(Coerce _ ty) e) _
1197 --              = Note note (eta_expand n us e ty)
1198 -- BUT this led to an infinite loop
1199 -- Example:     newtype T = MkT (Int -> Int)
1200 --      eta_expand 1 (coerce (Int->Int) e)
1201 --      --> coerce (Int->Int) (eta_expand 1 T e)
1202 --              by the bogus eqn
1203 --      --> coerce (Int->Int) (coerce T
1204 --              (\x::Int -> eta_expand 1 (coerce (Int->Int) e)))
1205 --              by the splitNewType_maybe case below
1206 --      and round we go
1207
1208 eta_expand n us expr ty
1209   = ASSERT2 (exprType expr `coreEqType` ty, ppr (exprType expr) $$ ppr ty)
1210     case splitForAllTy_maybe ty of {
1211           Just (tv,ty') ->
1212
1213               Lam lam_tv (eta_expand n us2 (App expr (Type (mkTyVarTy lam_tv))) (substTyWith [tv] [mkTyVarTy lam_tv] ty'))
1214                   where
1215                     lam_tv = setVarName tv (mkSysTvName uniq (fsLit "etaT"))
1216                         -- Using tv as a base retains its tyvar/covar-ness
1217                     (uniq:us2) = us
1218         ; Nothing ->
1219
1220         case splitFunTy_maybe ty of {
1221           Just (arg_ty, res_ty) -> Lam arg1 (eta_expand (n-1) us2 (App expr (Var arg1)) res_ty)
1222                                 where
1223                                    arg1       = mkSysLocal (fsLit "eta") uniq arg_ty
1224                                    (uniq:us2) = us
1225
1226         ; Nothing ->
1227
1228                 -- Given this:
1229                 --      newtype T = MkT ([T] -> Int)
1230                 -- Consider eta-expanding this
1231                 --      eta_expand 1 e T
1232                 -- We want to get
1233                 --      coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
1234
1235         case splitNewTypeRepCo_maybe ty of {
1236           Just(ty1,co) -> mkCoerce (mkSymCoercion co)
1237                                    (eta_expand n us (mkCoerce co expr) ty1) ;
1238           Nothing  ->
1239
1240         -- We have an expression of arity > 0, but its type isn't a function
1241         -- This *can* legitmately happen: e.g.  coerce Int (\x. x)
1242         -- Essentially the programmer is playing fast and loose with types
1243         -- (Happy does this a lot).  So we simply decline to eta-expand.
1244         -- Otherwise we'd end up with an explicit lambda having a non-function type
1245         expr
1246         }}}
1247 \end{code}
1248
1249 exprArity is a cheap-and-cheerful version of exprEtaExpandArity.
1250 It tells how many things the expression can be applied to before doing
1251 any work.  It doesn't look inside cases, lets, etc.  The idea is that
1252 exprEtaExpandArity will do the hard work, leaving something that's easy
1253 for exprArity to grapple with.  In particular, Simplify uses exprArity to
1254 compute the ArityInfo for the Id.
1255
1256 Originally I thought that it was enough just to look for top-level lambdas, but
1257 it isn't.  I've seen this
1258
1259         foo = PrelBase.timesInt
1260
1261 We want foo to get arity 2 even though the eta-expander will leave it
1262 unchanged, in the expectation that it'll be inlined.  But occasionally it
1263 isn't, because foo is blacklisted (used in a rule).
1264
1265 Similarly, see the ok_note check in exprEtaExpandArity.  So
1266         f = __inline_me (\x -> e)
1267 won't be eta-expanded.
1268
1269 And in any case it seems more robust to have exprArity be a bit more intelligent.
1270 But note that   (\x y z -> f x y z)
1271 should have arity 3, regardless of f's arity.
1272
1273 Note [exprArity invariant]
1274 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1275 exprArity has the following invariant:
1276         (exprArity e) = n, then manifestArity (etaExpand e n) = n
1277
1278 That is, if exprArity says "the arity is n" then etaExpand really can get
1279 "n" manifest lambdas to the top.
1280
1281 Why is this important?  Because
1282   - In TidyPgm we use exprArity to fix the *final arity* of
1283     each top-level Id, and in
1284   - In CorePrep we use etaExpand on each rhs, so that the visible lambdas
1285     actually match that arity, which in turn means
1286     that the StgRhs has the right number of lambdas
1287
1288 An alternative would be to do the eta-expansion in TidyPgm, at least
1289 for top-level bindings, in which case we would not need the trim_arity
1290 in exprArity.  That is a less local change, so I'm going to leave it for today!
1291
1292
1293 \begin{code}
1294 -- | An approximate, fast, version of 'exprEtaExpandArity'
1295 exprArity :: CoreExpr -> Arity
1296 exprArity e = go e
1297   where
1298     go (Var v)                   = idArity v
1299     go (Lam x e) | isId x        = go e + 1
1300                  | otherwise     = go e
1301     go (Note _ e)                = go e
1302     go (Cast e co)               = trim_arity (go e) 0 (snd (coercionKind co))
1303     go (App e (Type _))          = go e
1304     go (App f a) | exprIsCheap a = (go f - 1) `max` 0
1305         -- NB: exprIsCheap a!
1306         --      f (fac x) does not have arity 2,
1307         --      even if f has arity 3!
1308         -- NB: `max 0`!  (\x y -> f x) has arity 2, even if f is
1309         --               unknown, hence arity 0
1310     go _                           = 0
1311
1312         -- Note [exprArity invariant]
1313     trim_arity n a ty
1314         | n==a                                        = a
1315         | Just (_, ty') <- splitForAllTy_maybe ty     = trim_arity n a     ty'
1316         | Just (_, ty') <- splitFunTy_maybe ty        = trim_arity n (a+1) ty'
1317         | Just (ty',_)  <- splitNewTypeRepCo_maybe ty = trim_arity n a     ty'
1318         | otherwise                                   = a
1319 \end{code}
1320
1321 %************************************************************************
1322 %*                                                                      *
1323 \subsection{Equality}
1324 %*                                                                      *
1325 %************************************************************************
1326
1327 \begin{code}
1328 -- | A cheap equality test which bales out fast!
1329 --      If it returns @True@ the arguments are definitely equal,
1330 --      otherwise, they may or may not be equal.
1331 --
1332 -- See also 'exprIsBig'
1333 cheapEqExpr :: Expr b -> Expr b -> Bool
1334
1335 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1336 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1337 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1338
1339 cheapEqExpr (App f1 a1) (App f2 a2)
1340   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1341
1342 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
1343   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
1344
1345 cheapEqExpr _ _ = False
1346
1347 exprIsBig :: Expr b -> Bool
1348 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
1349 exprIsBig (Lit _)      = False
1350 exprIsBig (Var _)      = False
1351 exprIsBig (Type _)     = False
1352 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1353 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1354 exprIsBig _            = True
1355 \end{code}
1356
1357
1358 \begin{code}
1359 tcEqExpr :: CoreExpr -> CoreExpr -> Bool
1360 -- ^ A kind of shallow equality used in rule matching, so does
1361 -- /not/ look through newtypes or predicate types
1362
1363 tcEqExpr e1 e2 = tcEqExprX rn_env e1 e2
1364   where
1365     rn_env = mkRnEnv2 (mkInScopeSet (exprFreeVars e1 `unionVarSet` exprFreeVars e2))
1366
1367 tcEqExprX :: RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1368 tcEqExprX env (Var v1)     (Var v2)     = rnOccL env v1 == rnOccR env v2
1369 tcEqExprX _   (Lit lit1)   (Lit lit2)   = lit1 == lit2
1370 tcEqExprX env (App f1 a1)  (App f2 a2)  = tcEqExprX env f1 f2 && tcEqExprX env a1 a2
1371 tcEqExprX env (Lam v1 e1)  (Lam v2 e2)  = tcEqExprX (rnBndr2 env v1 v2) e1 e2
1372 tcEqExprX env (Let (NonRec v1 r1) e1)
1373               (Let (NonRec v2 r2) e2)   = tcEqExprX env r1 r2
1374                                        && tcEqExprX (rnBndr2 env v1 v2) e1 e2
1375 tcEqExprX env (Let (Rec ps1) e1)
1376               (Let (Rec ps2) e2)        =  equalLength ps1 ps2
1377                                         && and (zipWith eq_rhs ps1 ps2)
1378                                         && tcEqExprX env' e1 e2
1379                                      where
1380                                        env' = foldl2 rn_bndr2 env ps2 ps2
1381                                        rn_bndr2 env (b1,_) (b2,_) = rnBndr2 env b1 b2
1382                                        eq_rhs       (_,r1) (_,r2) = tcEqExprX env' r1 r2
1383 tcEqExprX env (Case e1 v1 t1 a1)
1384               (Case e2 v2 t2 a2)     =  tcEqExprX env e1 e2
1385                                      && tcEqTypeX env t1 t2
1386                                      && equalLength a1 a2
1387                                      && and (zipWith (eq_alt env') a1 a2)
1388                                      where
1389                                        env' = rnBndr2 env v1 v2
1390
1391 tcEqExprX env (Note n1 e1)  (Note n2 e2)  = eq_note env n1 n2 && tcEqExprX env e1 e2
1392 tcEqExprX env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && tcEqExprX env e1 e2
1393 tcEqExprX env (Type t1)     (Type t2)     = tcEqTypeX env t1 t2
1394 tcEqExprX _   _             _             = False
1395
1396 eq_alt :: RnEnv2 -> CoreAlt -> CoreAlt -> Bool
1397 eq_alt env (c1,vs1,r1) (c2,vs2,r2) = c1==c2 && tcEqExprX (rnBndrs2 env vs1  vs2) r1 r2
1398
1399 eq_note :: RnEnv2 -> Note -> Note -> Bool
1400 eq_note _ (SCC cc1)     (SCC cc2)      = cc1 == cc2
1401 eq_note _ (CoreNote s1) (CoreNote s2)  = s1 == s2
1402 eq_note _ _             _              = False
1403 \end{code}
1404
1405
1406 %************************************************************************
1407 %*                                                                      *
1408 \subsection{The size of an expression}
1409 %*                                                                      *
1410 %************************************************************************
1411
1412 \begin{code}
1413 coreBindsSize :: [CoreBind] -> Int
1414 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1415
1416 exprSize :: CoreExpr -> Int
1417 -- ^ A measure of the size of the expressions, strictly greater than 0
1418 -- It also forces the expression pretty drastically as a side effect
1419 exprSize (Var v)         = v `seq` 1
1420 exprSize (Lit lit)       = lit `seq` 1
1421 exprSize (App f a)       = exprSize f + exprSize a
1422 exprSize (Lam b e)       = varSize b + exprSize e
1423 exprSize (Let b e)       = bindSize b + exprSize e
1424 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1425 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1426 exprSize (Note n e)      = noteSize n + exprSize e
1427 exprSize (Type t)        = seqType t `seq` 1
1428
1429 noteSize :: Note -> Int
1430 noteSize (SCC cc)       = cc `seq` 1
1431 noteSize InlineMe       = 1
1432 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1433
1434 varSize :: Var -> Int
1435 varSize b  | isTyVar b = 1
1436            | otherwise = seqType (idType b)             `seq`
1437                          megaSeqIdInfo (idInfo b)       `seq`
1438                          1
1439
1440 varsSize :: [Var] -> Int
1441 varsSize = sum . map varSize
1442
1443 bindSize :: CoreBind -> Int
1444 bindSize (NonRec b e) = varSize b + exprSize e
1445 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1446
1447 pairSize :: (Var, CoreExpr) -> Int
1448 pairSize (b,e) = varSize b + exprSize e
1449
1450 altSize :: CoreAlt -> Int
1451 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1452 \end{code}
1453
1454
1455 %************************************************************************
1456 %*                                                                      *
1457 \subsection{Hashing}
1458 %*                                                                      *
1459 %************************************************************************
1460
1461 \begin{code}
1462 hashExpr :: CoreExpr -> Int
1463 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1464 -- Two expressions that hash to the different Ints are definitely unequal.
1465 --
1466 -- The emphasis is on a crude, fast hash, rather than on high precision.
1467 --
1468 -- But unequal here means \"not identical\"; two alpha-equivalent
1469 -- expressions may hash to the different Ints.
1470 --
1471 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1472 -- (at least if we want the above invariant to be true).
1473
1474 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1475              -- UniqFM doesn't like negative Ints
1476
1477 type HashEnv = (Int, VarEnv Int)  -- ^ Hash code for bound variables
1478
1479 hash_expr :: HashEnv -> CoreExpr -> Word32
1480 -- Word32, because we're expecting overflows here, and overflowing
1481 -- signed types just isn't cool.  In C it's even undefined.
1482 hash_expr env (Note _ e)              = hash_expr env e
1483 hash_expr env (Cast e _)              = hash_expr env e
1484 hash_expr env (Var v)                 = hashVar env v
1485 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1486 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1487 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1488 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1489 hash_expr env (Case e _ _ _)          = hash_expr env e
1490 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1491 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1492 -- Shouldn't happen.  Better to use WARN than trace, because trace
1493 -- prevents the CPR optimisation kicking in for hash_expr.
1494
1495 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1496 fast_hash_expr env (Var v)      = hashVar env v
1497 fast_hash_expr env (Type t)     = fast_hash_type env t
1498 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1499 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1500 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1501 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1502 fast_hash_expr _   _            = 1
1503
1504 fast_hash_type :: HashEnv -> Type -> Word32
1505 fast_hash_type env ty
1506   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1507   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1508                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1509   | otherwise                               = 1
1510
1511 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1512 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1513
1514 hashVar :: HashEnv -> Var -> Word32
1515 hashVar (_,env) v
1516  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1517 \end{code}
1518
1519 %************************************************************************
1520 %*                                                                      *
1521 \subsection{Determining non-updatable right-hand-sides}
1522 %*                                                                      *
1523 %************************************************************************
1524
1525 Top-level constructor applications can usually be allocated
1526 statically, but they can't if the constructor, or any of the
1527 arguments, come from another DLL (because we can't refer to static
1528 labels in other DLLs).
1529
1530 If this happens we simply make the RHS into an updatable thunk,
1531 and 'execute' it rather than allocating it statically.
1532
1533 \begin{code}
1534 -- | This function is called only on *top-level* right-hand sides.
1535 -- Returns @True@ if the RHS can be allocated statically in the output,
1536 -- with no thunks involved at all.
1537 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1538 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1539 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1540 -- update flag on it and (iii) in DsExpr to decide how to expand
1541 -- list literals
1542 --
1543 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1544 --      (a) a value lambda
1545 --      (b) a saturated constructor application with static args
1546 --
1547 -- BUT watch out for
1548 --  (i) Any cross-DLL references kill static-ness completely
1549 --      because they must be 'executed' not statically allocated
1550 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1551 --      this is not necessary)
1552 --
1553 -- (ii) We treat partial applications as redexes, because in fact we
1554 --      make a thunk for them that runs and builds a PAP
1555 --      at run-time.  The only appliations that are treated as
1556 --      static are *saturated* applications of constructors.
1557
1558 -- We used to try to be clever with nested structures like this:
1559 --              ys = (:) w ((:) w [])
1560 -- on the grounds that CorePrep will flatten ANF-ise it later.
1561 -- But supporting this special case made the function much more
1562 -- complicated, because the special case only applies if there are no
1563 -- enclosing type lambdas:
1564 --              ys = /\ a -> Foo (Baz ([] a))
1565 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1566 --
1567 -- But in fact, even without -O, nested structures at top level are
1568 -- flattened by the simplifier, so we don't need to be super-clever here.
1569 --
1570 -- Examples
1571 --
1572 --      f = \x::Int. x+7        TRUE
1573 --      p = (True,False)        TRUE
1574 --
1575 --      d = (fst p, False)      FALSE because there's a redex inside
1576 --                              (this particular one doesn't happen but...)
1577 --
1578 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1579 --      n = /\a. Nil a                  TRUE
1580 --
1581 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1582 --
1583 --
1584 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1585 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1586 --
1587 --    b) (C x xs), where C is a contructors is updatable if the application is
1588 --         dynamic
1589 --
1590 --    c) don't look through unfolding of f in (f x).
1591
1592 rhsIsStatic _this_pkg rhs = is_static False rhs
1593   where
1594   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1595           -> CoreExpr -> Bool
1596
1597   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1598
1599   is_static _      (Note (SCC _) _) = False
1600   is_static in_arg (Note _ e)       = is_static in_arg e
1601   is_static in_arg (Cast e _)       = is_static in_arg e
1602
1603   is_static _      (Lit lit)
1604     = case lit of
1605         MachLabel _ _ -> False
1606         _             -> True
1607         -- A MachLabel (foreign import "&foo") in an argument
1608         -- prevents a constructor application from being static.  The
1609         -- reason is that it might give rise to unresolvable symbols
1610         -- in the object file: under Linux, references to "weak"
1611         -- symbols from the data segment give rise to "unresolvable
1612         -- relocation" errors at link time This might be due to a bug
1613         -- in the linker, but we'll work around it here anyway.
1614         -- SDM 24/2/2004
1615
1616   is_static in_arg other_expr = go other_expr 0
1617    where
1618     go (Var f) n_val_args
1619 #if mingw32_TARGET_OS
1620         | not (isDllName _this_pkg (idName f))
1621 #endif
1622         =  saturated_data_con f n_val_args
1623         || (in_arg && n_val_args == 0)
1624                 -- A naked un-applied variable is *not* deemed a static RHS
1625                 -- E.g.         f = g
1626                 -- Reason: better to update so that the indirection gets shorted
1627                 --         out, and the true value will be seen
1628                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1629                 --     are always updatable.  If you do so, make sure that non-updatable
1630                 --     ones have enough space for their static link field!
1631
1632     go (App f a) n_val_args
1633         | isTypeArg a                    = go f n_val_args
1634         | not in_arg && is_static True a = go f (n_val_args + 1)
1635         -- The (not in_arg) checks that we aren't in a constructor argument;
1636         -- if we are, we don't allow (value) applications of any sort
1637         --
1638         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1639         --   x = D# (1.0## /## 2.0##)
1640         -- can't float because /## can fail.
1641
1642     go (Note (SCC _) _) _          = False
1643     go (Note _ f)       n_val_args = go f n_val_args
1644     go (Cast e _)       n_val_args = go e n_val_args
1645
1646     go _                _          = False
1647
1648     saturated_data_con f n_val_args
1649         = case isDataConWorkId_maybe f of
1650             Just dc -> n_val_args == dataConRepArity dc
1651             Nothing -> False
1652 \end{code}