compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial,
  29         exprIsCheap, exprIsExpandable, exprIsCheap', CheapAppFun,
  30         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  31         rhsIsStatic, isCheapApp, isExpandableApp,
  32
  33         -- * Expression and bindings size
  34         coreBindsSize, exprSize,
  35
  36         -- * Hashing
  37         hashExpr,
  38
  39         -- * Equality
  40         cheapEqExpr, eqExpr, eqExprX,
  41
  42         -- * Eta reduction
  43         tryEtaReduce,
  44
  45         -- * Manipulating data constructors and types
  46         applyTypeToArgs, applyTypeToArg,
  47         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  48     ) where
  49
  50 #include "HsVersions.h"
  51
  52 import CoreSyn
  53 import PprCore
  54 import Var
  55 import SrcLoc
  56 import VarEnv
  57 import VarSet
  58 import Name
  59 import Literal
  60 import DataCon
  61 import PrimOp
  62 import Id
  63 import IdInfo
  64 import TcType   ( isPredTy )
  65 import Type
  66 import Coercion
  67 import TyCon
  68 import CostCentre
  69 import Unique
  70 import Outputable
  71 import TysPrim
  72 import PrelNames( absentErrorIdKey )
  73 import FastString
  74 import Maybes
  75 import Util
  76 import Data.Word
  77 import Data.Bits
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89 -- ^ Recover the type of a well-typed Core expression. Fails when
  90 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  91 -- really be said to have a type
  92 exprType (Var var)           = idType var
  93 exprType (Lit lit)           = literalType lit
  94 exprType (Let _ body)        = exprType body
  95 exprType (Case _ _ ty _)     = ty
  96 exprType (Cast _ co)         = snd (coercionKind co)
  97 exprType (Note _ e)          = exprType e
  98 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  99 exprType e@(App _ _)
 100   = case collectArgs e of
 101         (fun, args) -> applyTypeToArgs e (exprType fun) args
 102
 103 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 104
 105 coreAltType :: CoreAlt -> Type
 106 -- ^ Returns the type of the alternatives right hand side
 107 coreAltType (_,bs,rhs)
 108   | any bad_binder bs = expandTypeSynonyms ty
 109   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 110   where
 111     ty           = exprType rhs
 112     free_tvs     = tyVarsOfType ty
 113     bad_binder b = isTyCoVar b && b `elemVarSet` free_tvs
 114
 115 coreAltsType :: [CoreAlt] -> Type
 116 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 117 coreAltsType (alt:_) = coreAltType alt
 118 coreAltsType []      = panic "corAltsType"
 119 \end{code}
 120
 121 Note [Existential variables and silly type synonyms]
 122 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 123 Consider
 124         data T = forall a. T (Funny a)
 125         type Funny a = Bool
 126         f :: T -> Bool
 127         f (T x) = x
 128
 129 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 130 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 131 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 132 example.
 133
 134 Various possibilities suggest themselves:
 135
 136  - Ignore the problem, and make Lint not complain about such variables
 137
 138  - Expand all type synonyms (or at least all those that discard arguments)
 139       This is tricky, because at least for top-level things we want to
 140       retain the type the user originally specified.
 141
 142  - Expand synonyms on the fly, when the problem arises. That is what
 143    we are doing here.  It's not too expensive, I think.
 144
 145 \begin{code}
 146 mkPiType  :: EvVar -> Type -> Type
 147 -- ^ Makes a @(->)@ type or a forall type, depending
 148 -- on whether it is given a type variable or a term variable.
 149 mkPiTypes :: [EvVar] -> Type -> Type
 150 -- ^ 'mkPiType' for multiple type or value arguments
 151
 152 mkPiType v ty
 153    | isId v    = mkFunTy (idType v) ty
 154    | otherwise = mkForAllTy v ty
 155
 156 mkPiTypes vs ty = foldr mkPiType ty vs
 157 \end{code}
 158
 159 \begin{code}
 160 applyTypeToArg :: Type -> CoreExpr -> Type
 161 -- ^ Determines the type resulting from applying an expression to a function with the given type
 162 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 163 applyTypeToArg fun_ty _             = funResultTy fun_ty
 164
 165 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 166 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 167 -- The first argument is just for debugging, and gives some context
 168 applyTypeToArgs _ op_ty [] = op_ty
 169
 170 applyTypeToArgs e op_ty (Type ty : args)
 171   =     -- Accumulate type arguments so we can instantiate all at once
 172     go [ty] args
 173   where
 174     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 175     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 176                                 where
 177                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 178                                   msg = ptext (sLit "applyTypeToArgs") <+>
 179                                         panic_msg e op_ty
 180
 181 applyTypeToArgs e op_ty (_ : args)
 182   = case (splitFunTy_maybe op_ty) of
 183         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 184         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 185
 186 panic_msg :: CoreExpr -> Type -> SDoc
 187 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192 \subsection{Attaching notes}
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 198 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 199 mkCoerceI (IdCo _) e = e
 200 mkCoerceI (ACo co) e = mkCoerce co e
 201
 202 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 203 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 204 mkCoerce co (Cast expr co2)
 205   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 206                  (_from_ty2, to_ty2) = coercionKind co2} in
 207            from_ty `coreEqType` to_ty2 )
 208     mkCoerce (mkTransCoercion co2 co) expr
 209
 210 mkCoerce co expr
 211   = let (from_ty, _to_ty) = coercionKind co in
 212 --    if to_ty `coreEqType` from_ty
 213 --    then expr
 214 --    else
 215         WARN(not (from_ty `coreEqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 216          (Cast expr co)
 217 \end{code}
 218
 219 \begin{code}
 220 -- | Wraps the given expression in the cost centre unless
 221 -- in a way that maximises their utility to the user
 222 mkSCC :: CostCentre -> Expr b -> Expr b
 223         -- Note: Nested SCC's *are* preserved for the benefit of
 224         --       cost centre stack profiling
 225 mkSCC _  (Lit lit)          = Lit lit
 226 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 227 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 228 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 229 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 230 mkSCC cc expr               = Note (SCC cc) expr
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Other expression construction}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 \begin{code}
 241 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 242 -- ^ @bindNonRec x r b@ produces either:
 243 --
 244 -- > let x = r in b
 245 --
 246 -- or:
 247 --
 248 -- > case r of x { _DEFAULT_ -> b }
 249 --
 250 -- depending on whether we have to use a @case@ or @let@
 251 -- binding for the expression (see 'needsCaseBinding').
 252 -- It's used by the desugarer to avoid building bindings
 253 -- that give Core Lint a heart attack, although actually
 254 -- the simplifier deals with them perfectly well. See
 255 -- also 'MkCore.mkCoreLet'
 256 bindNonRec bndr rhs body
 257   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 258   | otherwise                          = Let (NonRec bndr rhs) body
 259
 260 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 261 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 262 needsCaseBinding :: Type -> CoreExpr -> Bool
 263 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 264         -- Make a case expression instead of a let
 265         -- These can arise either from the desugarer,
 266         -- or from beta reductions: (\x.e) (x +# y)
 267 \end{code}
 268
 269 \begin{code}
 270 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 271           -> [CoreBndr] -- ^ Things bound by the pattern match
 272           -> [Type]     -- ^ The type arguments to the case alternative
 273           -> CoreExpr
 274 -- ^ This guy constructs the value that the scrutinee must have
 275 -- given that you are in one particular branch of a case
 276 mkAltExpr (DataAlt con) args inst_tys
 277   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 278 mkAltExpr (LitAlt lit) [] []
 279   = Lit lit
 280 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 281 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 282 \end{code}
 283
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection{Taking expressions apart}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 The default alternative must be first, if it exists at all.
 292 This makes it easy to find, though it makes matching marginally harder.
 293
 294 \begin{code}
 295 -- | Extract the default case alternative
 296 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 297 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 298 findDefault alts                        =                     (alts, Nothing)
 299
 300 isDefaultAlt :: CoreAlt -> Bool
 301 isDefaultAlt (DEFAULT, _, _) = True
 302 isDefaultAlt _               = False
 303
 304
 305 -- | Find the case alternative corresponding to a particular
 306 -- constructor: panics if no such constructor exists
 307 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 308     -- A "Nothing" result *is* legitmiate
 309     -- See Note [Unreachable code]
 310 findAlt con alts
 311   = case alts of
 312         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 313         _                          -> go alts Nothing
 314   where
 315     go []                     deflt = deflt
 316     go (alt@(con1,_,_) : alts) deflt
 317       = case con `cmpAltCon` con1 of
 318           LT -> deflt   -- Missed it already; the alts are in increasing order
 319           EQ -> Just alt
 320           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 321
 322 ---------------------------------
 323 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 324 -- ^ Merge alternatives preserving order; alternatives in
 325 -- the first argument shadow ones in the second
 326 mergeAlts [] as2 = as2
 327 mergeAlts as1 [] = as1
 328 mergeAlts (a1:as1) (a2:as2)
 329   = case a1 `cmpAlt` a2 of
 330         LT -> a1 : mergeAlts as1      (a2:as2)
 331         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 332         GT -> a2 : mergeAlts (a1:as1) as2
 333
 334
 335 ---------------------------------
 336 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 337 -- ^ Given:
 338 --
 339 -- > case (C a b x y) of
 340 -- >        C b x y -> ...
 341 --
 342 -- We want to drop the leading type argument of the scrutinee
 343 -- leaving the arguments to match agains the pattern
 344
 345 trimConArgs DEFAULT      args = ASSERT( null args ) []
 346 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 347 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 348 \end{code}
 349
 350 Note [Unreachable code]
 351 ~~~~~~~~~~~~~~~~~~~~~~~
 352 It is possible (although unusual) for GHC to find a case expression
 353 that cannot match.  For example:
 354
 355      data Col = Red | Green | Blue
 356      x = Red
 357      f v = case x of
 358               Red -> ...
 359               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 360
 361 Suppose that for some silly reason, x isn't substituted in the case
 362 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 363 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 364 this
 365
 366      x = Red
 367      lvl = case x of { Green -> e1; Blue -> e2 })
 368      f v = case x of
 369              Red -> ...
 370              _ -> ...lvl...
 371
 372 Now if x gets inlined, we won't be able to find a matching alternative
 373 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 374 we generate (error "Inaccessible alternative").
 375
 376 Similar things can happen (augmented by GADTs) when the Simplifier
 377 filters down the matching alternatives in Simplify.rebuildCase.
 378
 379
 380 %************************************************************************
 381 %*                                                                      *
 382              exprIsTrivial
 383 %*                                                                      *
 384 %************************************************************************
 385
 386 Note [exprIsTrivial]
 387 ~~~~~~~~~~~~~~~~~~~~
 388 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 389                 duplicate; simple variables and constants, and type
 390                 applications.  Note that primop Ids aren't considered
 391                 trivial unless
 392
 393 Note [Variable are trivial]
 394 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 395 There used to be a gruesome test for (hasNoBinding v) in the
 396 Var case:
 397         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 398 The idea here is that a constructor worker, like \$wJust, is
 399 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 400 So it should be treated like a lambda.  Ditto unsaturated primops.
 401 But now constructor workers are not "have-no-binding" Ids.  And
 402 completely un-applied primops and foreign-call Ids are sufficiently
 403 rare that I plan to allow them to be duplicated and put up with
 404 saturating them.
 405
 406 Note [SCCs are trivial]
 407 ~~~~~~~~~~~~~~~~~~~~~~~
 408 We used not to treat (_scc_ "foo" x) as trivial, because it really
 409 generates code, (and a heap object when it's a function arg) to
 410 capture the cost centre.  However, the profiling system discounts the
 411 allocation costs for such "boxing thunks" whereas the extra costs of
 412 *not* inlining otherwise-trivial bindings can be high, and are hard to
 413 discount.
 414
 415 \begin{code}
 416 exprIsTrivial :: CoreExpr -> Bool
 417 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 418 exprIsTrivial (Type _)         = True
 419 exprIsTrivial (Lit lit)        = litIsTrivial lit
 420 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 421 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 422 exprIsTrivial (Cast e _)       = exprIsTrivial e
 423 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 424 exprIsTrivial _                = False
 425 \end{code}
 426
 427
 428 %************************************************************************
 429 %*                                                                      *
 430              exprIsDupable
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 Note [exprIsDupable]
 435 ~~~~~~~~~~~~~~~~~~~~
 436 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 437                 cost in code size.  This will only happen in different case
 438                 branches, so there's no issue about duplicating work.
 439
 440                 That is, exprIsDupable returns True of (f x) even if
 441                 f is very very expensive to call.
 442
 443                 Its only purpose is to avoid fruitless let-binding
 444                 and then inlining of case join points
 445
 446
 447 \begin{code}
 448 exprIsDupable :: CoreExpr -> Bool
 449 exprIsDupable (Type _)   = True
 450 exprIsDupable (Var _)    = True
 451 exprIsDupable (Lit lit)  = litIsDupable lit
 452 exprIsDupable (Note _ e) = exprIsDupable e
 453 exprIsDupable (Cast e _) = exprIsDupable e
 454 exprIsDupable expr
 455   = go expr 0
 456   where
 457     go (Var _)   _      = True
 458     go (App f a) n_args =  n_args < dupAppSize
 459                         && exprIsDupable a
 460                         && go f (n_args+1)
 461     go _         _      = False
 462
 463 dupAppSize :: Int
 464 dupAppSize = 4          -- Size of application we are prepared to duplicate
 465 \end{code}
 466
 467 %************************************************************************
 468 %*                                                                      *
 469              exprIsCheap, exprIsExpandable
 470 %*                                                                      *
 471 %************************************************************************
 472
 473 Note [exprIsCheap]   See also Note [Interaction of exprIsCheap and lone variables]
 474 ~~~~~~~~~~~~~~~~~~   in CoreUnfold.lhs
 475 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 476 it is obviously in weak head normal form, or is cheap to get to WHNF.
 477 [Note that that's not the same as exprIsDupable; an expression might be
 478 big, and hence not dupable, but still cheap.]
 479
 480 By ``cheap'' we mean a computation we're willing to:
 481         push inside a lambda, or
 482         inline at more than one place
 483 That might mean it gets evaluated more than once, instead of being
 484 shared.  The main examples of things which aren't WHNF but are
 485 ``cheap'' are:
 486
 487   *     case e of
 488           pi -> ei
 489         (where e, and all the ei are cheap)
 490
 491   *     let x = e in b
 492         (where e and b are cheap)
 493
 494   *     op x1 ... xn
 495         (where op is a cheap primitive operator)
 496
 497   *     error "foo"
 498         (because we are happy to substitute it inside a lambda)
 499
 500 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 501 because sharing will make sure it is only evaluated once.
 502
 503 Note [exprIsCheap and exprIsHNF]
 504 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 505 Note that exprIsHNF does not imply exprIsCheap.  Eg
 506         let x = fac 20 in Just x
 507 This responds True to exprIsHNF (you can discard a seq), but
 508 False to exprIsCheap.
 509
 510 \begin{code}
 511 exprIsCheap :: CoreExpr -> Bool
 512 exprIsCheap = exprIsCheap' isCheapApp
 513
 514 exprIsExpandable :: CoreExpr -> Bool
 515 exprIsExpandable = exprIsCheap' isExpandableApp -- See Note [CONLIKE pragma] in BasicTypes
 516
 517 type CheapAppFun = Id -> Int -> Bool
 518 exprIsCheap' :: CheapAppFun -> CoreExpr -> Bool
 519 exprIsCheap' _          (Lit _)   = True
 520 exprIsCheap' _          (Type _)  = True
 521 exprIsCheap' _          (Var _)   = True
 522 exprIsCheap' good_app (Note _ e)  = exprIsCheap' good_app e
 523 exprIsCheap' good_app (Cast e _)  = exprIsCheap' good_app e
 524 exprIsCheap' good_app (Lam x e)   = isRuntimeVar x
 525                                  || exprIsCheap' good_app e
 526
 527 exprIsCheap' good_app (Case e _ _ alts) = exprIsCheap' good_app e &&
 528                                           and [exprIsCheap' good_app rhs | (_,_,rhs) <- alts]
 529         -- Experimentally, treat (case x of ...) as cheap
 530         -- (and case __coerce x etc.)
 531         -- This improves arities of overloaded functions where
 532         -- there is only dictionary selection (no construction) involved
 533
 534 exprIsCheap' good_app (Let (NonRec x _) e)
 535   | isUnLiftedType (idType x) = exprIsCheap' good_app e
 536   | otherwise                 = False
 537         -- Strict lets always have cheap right hand sides,
 538         -- and do no allocation, so just look at the body
 539         -- Non-strict lets do allocation so we don't treat them as cheap
 540         -- See also
 541
 542 exprIsCheap' good_app other_expr        -- Applications and variables
 543   = go other_expr []
 544   where
 545         -- Accumulate value arguments, then decide
 546     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 547                           | otherwise      = go f val_args
 548
 549     go (Var _) [] = True        -- Just a type application of a variable
 550                                 -- (f t1 t2 t3) counts as WHNF
 551     go (Var f) args
 552         = case idDetails f of
 553                 RecSelId {}                  -> go_sel args
 554                 ClassOpId {}                 -> go_sel args
 555                 PrimOpId op                  -> go_primop op args
 556                 _ | good_app f (length args) -> go_pap args
 557                   | isBottomingId f          -> True
 558                   | otherwise                -> False
 559                         -- Application of a function which
 560                         -- always gives bottom; we treat this as cheap
 561                         -- because it certainly doesn't need to be shared!
 562
 563     go _ _ = False
 564
 565     --------------
 566     go_pap args = all exprIsTrivial args
 567         -- For constructor applications and primops, check that all
 568         -- the args are trivial.  We don't want to treat as cheap, say,
 569         --      (1:2:3:4:5:[])
 570         -- We'll put up with one constructor application, but not dozens
 571
 572     --------------
 573     go_primop op args = primOpIsCheap op && all (exprIsCheap' good_app) args
 574         -- In principle we should worry about primops
 575         -- that return a type variable, since the result
 576         -- might be applied to something, but I'm not going
 577         -- to bother to check the number of args
 578
 579     --------------
 580     go_sel [arg] = exprIsCheap' good_app arg    -- I'm experimenting with making record selection
 581     go_sel _     = False                -- look cheap, so we will substitute it inside a
 582                                         -- lambda.  Particularly for dictionary field selection.
 583                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 584                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 585
 586 isCheapApp :: CheapAppFun
 587 isCheapApp fn n_val_args
 588   = isDataConWorkId fn
 589   || n_val_args < idArity fn
 590
 591 isExpandableApp :: CheapAppFun
 592 isExpandableApp fn n_val_args
 593   =  isConLikeId fn
 594   || n_val_args < idArity fn
 595   || go n_val_args (idType fn)
 596   where
 597   -- See if all the arguments are PredTys (implicit params or classes)
 598   -- If so we'll regard it as expandable; see Note [Expandable overloadings]
 599      go 0 _ = True
 600      go n_val_args ty
 601        | Just (_, ty) <- splitForAllTy_maybe ty   = go n_val_args ty
 602        | Just (arg, ty) <- splitFunTy_maybe ty
 603        , isPredTy arg                             = go (n_val_args-1) ty
 604        | otherwise                                = False
 605 \end{code}
 606
 607 Note [Expandable overloadings]
 608 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 609 Suppose the user wrote this
 610    {-# RULE  forall x. foo (negate x) = h x #-}
 611    f x = ....(foo (negate x))....
 612 He'd expect the rule to fire. But since negate is overloaded, we might
 613 get this:
 614     f = \d -> let n = negate d in \x -> ...foo (n x)...
 615 So we treat the application of a function (negate in this case) to a
 616 *dictionary* as expandable.  In effect, every function is CONLIKE when
 617 it's applied only to dictionaries.
 618
 619
 620 %************************************************************************
 621 %*                                                                      *
 622              exprOkForSpeculation
 623 %*                                                                      *
 624 %************************************************************************
 625
 626 \begin{code}
 627 -- | 'exprOkForSpeculation' returns True of an expression that is:
 628 --
 629 --  * Safe to evaluate even if normal order eval might not
 630 --    evaluate the expression at all, or
 631 --
 632 --  * Safe /not/ to evaluate even if normal order would do so
 633 --
 634 -- Precisely, it returns @True@ iff:
 635 --
 636 --  * The expression guarantees to terminate,
 637 --  * soon,
 638 --  * without raising an exception,
 639 --  * without causing a side effect (e.g. writing a mutable variable)
 640 --
 641 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 642 -- As an example of the considerations in this test, consider:
 643 --
 644 -- > let x = case y# +# 1# of { r# -> I# r# }
 645 -- > in E
 646 --
 647 -- being translated to:
 648 --
 649 -- > case y# +# 1# of { r# ->
 650 -- >    let x = I# r#
 651 -- >    in E
 652 -- > }
 653 --
 654 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 655 -- side effects, and can't diverge or raise an exception.
 656 exprOkForSpeculation :: CoreExpr -> Bool
 657 exprOkForSpeculation (Lit _)     = True
 658 exprOkForSpeculation (Type _)    = True
 659     -- Tick boxes are *not* suitable for speculation
 660 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 661                                  && not (isTickBoxOp v)
 662 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 663 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 664
 665 exprOkForSpeculation (Case e _ _ alts)
 666   =  exprOkForSpeculation e  -- Note [exprOkForSpeculation: case expressions]
 667   && all (\(_,_,rhs) -> exprOkForSpeculation rhs) alts
 668
 669 exprOkForSpeculation other_expr
 670   = case collectArgs other_expr of
 671         (Var f, args) | f `hasKey` absentErrorIdKey     -- Note [Absent error Id]
 672                       -> all exprOkForSpeculation args  --    in WwLib
 673                       | otherwise
 674                       -> spec_ok (idDetails f) args
 675         _             -> False
 676
 677   where
 678     spec_ok (DataConWorkId _) _
 679       = True    -- The strictness of the constructor has already
 680                 -- been expressed by its "wrapper", so we don't need
 681                 -- to take the arguments into account
 682
 683     spec_ok (PrimOpId op) args
 684       | isDivOp op,             -- Special case for dividing operations that fail
 685         [arg1, Lit lit] <- args -- only if the divisor is zero
 686       = not (isZeroLit lit) && exprOkForSpeculation arg1
 687                 -- Often there is a literal divisor, and this
 688                 -- can get rid of a thunk in an inner looop
 689
 690       | otherwise
 691       = primOpOkForSpeculation op &&
 692         all exprOkForSpeculation args
 693                                 -- A bit conservative: we don't really need
 694                                 -- to care about lazy arguments, but this is easy
 695
 696     spec_ok (DFunId _ new_type) _ = not new_type
 697          -- DFuns terminate, unless the dict is implemented with a newtype
 698          -- in which case they may not
 699
 700     spec_ok _ _ = False
 701
 702 -- | True of dyadic operators that can fail only if the second arg is zero!
 703 isDivOp :: PrimOp -> Bool
 704 -- This function probably belongs in PrimOp, or even in
 705 -- an automagically generated file.. but it's such a
 706 -- special case I thought I'd leave it here for now.
 707 isDivOp IntQuotOp        = True
 708 isDivOp IntRemOp         = True
 709 isDivOp WordQuotOp       = True
 710 isDivOp WordRemOp        = True
 711 isDivOp FloatDivOp       = True
 712 isDivOp DoubleDivOp      = True
 713 isDivOp _                = False
 714 \end{code}
 715
 716 Note [exprOkForSpeculation: case expressions]
 717 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 718
 719 It's always sound for exprOkForSpeculation to return False, and we
 720 don't want it to take too long, so it bales out on complicated-looking
 721 terms.  Notably lets, which can be stacked very deeply; and in any
 722 case the argument of exprOkForSpeculation is usually in a strict context,
 723 so any lets will have been floated away.
 724
 725 However, we keep going on case-expressions.  An example like this one
 726 showed up in DPH code:
 727     foo :: Int -> Int
 728     foo 0 = 0
 729     foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
 730
 731 If exprOkForSpeculation doesn't look through case expressions, you get this:
 732     T.$wfoo =
 733       \ (ww :: GHC.Prim.Int#) ->
 734         case ww of ds {
 735           __DEFAULT -> case (case <# ds 5 of _ {
 736                           GHC.Types.False -> lvl1;
 737                           GHC.Types.True -> lvl})
 738                        of _ { __DEFAULT ->
 739                        T.$wfoo (GHC.Prim.-# ds_XkE 1) };
 740           0 -> 0
 741         }
 742
 743 The inner case is redundant, and should be nuked.
 744
 745
 746 %************************************************************************
 747 %*                                                                      *
 748              exprIsHNF, exprIsConLike
 749 %*                                                                      *
 750 %************************************************************************
 751
 752 \begin{code}
 753 -- Note [exprIsHNF]             See also Note [exprIsCheap and exprIsHNF]
 754 -- ~~~~~~~~~~~~~~~~
 755 -- | exprIsHNF returns true for expressions that are certainly /already/
 756 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 757 -- to change:
 758 --
 759 -- > case x of _ -> e
 760 --
 761 --    into:
 762 --
 763 -- > e
 764 --
 765 -- and to decide whether it's safe to discard a 'seq'.
 766 --
 767 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 768 -- However, it /does/ treat partial applications and constructor applications
 769 -- as values, even if their arguments are non-trivial, provided the argument
 770 -- type is lifted. For example, both of these are values:
 771 --
 772 -- > (:) (f x) (map f xs)
 773 -- > map (...redex...)
 774 --
 775 -- because 'seq' on such things completes immediately.
 776 --
 777 -- For unlifted argument types, we have to be careful:
 778 --
 779 -- > C (f x :: Int#)
 780 --
 781 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 782 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 783 -- unboxed type must be ok-for-speculation (or trivial).
 784 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 785 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 786 \end{code}
 787
 788 \begin{code}
 789 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 790 -- data constructors. Conlike arguments are considered interesting by the
 791 -- inliner.
 792 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 793 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 794
 795 -- | Returns true for values or value-like expressions. These are lambdas,
 796 -- constructors / CONLIKE functions (as determined by the function argument)
 797 -- or PAPs.
 798 --
 799 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 800 exprIsHNFlike is_con is_con_unf = is_hnf_like
 801   where
 802     is_hnf_like (Var v) -- NB: There are no value args at this point
 803       =  is_con v       -- Catches nullary constructors,
 804                         --      so that [] and () are values, for example
 805       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 806       || is_con_unf (idUnfolding v)
 807         -- Check the thing's unfolding; it might be bound to a value
 808         -- We don't look through loop breakers here, which is a bit conservative
 809         -- but otherwise I worry that if an Id's unfolding is just itself,
 810         -- we could get an infinite loop
 811
 812     is_hnf_like (Lit _)          = True
 813     is_hnf_like (Type _)         = True       -- Types are honorary Values;
 814                                               -- we don't mind copying them
 815     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 816     is_hnf_like (Note _ e)       = is_hnf_like e
 817     is_hnf_like (Cast e _)       = is_hnf_like e
 818     is_hnf_like (App e (Type _)) = is_hnf_like e
 819     is_hnf_like (App e a)        = app_is_value e [a]
 820     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 821     is_hnf_like _                = False
 822
 823     -- There is at least one value argument
 824     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 825     app_is_value (Var fun) args
 826       = idArity fun > valArgCount args    -- Under-applied function
 827         || is_con fun                     --  or constructor-like
 828     app_is_value (Note _ f) as = app_is_value f as
 829     app_is_value (Cast f _) as = app_is_value f as
 830     app_is_value (App f a)  as = app_is_value f (a:as)
 831     app_is_value _          _  = False
 832 \end{code}
 833
 834
 835 %************************************************************************
 836 %*                                                                      *
 837              Instantiating data constructors
 838 %*                                                                      *
 839 %************************************************************************
 840
 841 These InstPat functions go here to avoid circularity between DataCon and Id
 842
 843 \begin{code}
 844 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 845 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 846
 847 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 848 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 849 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 850   where
 851     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 852         -- Remember to include the existential dictionaries
 853
 854 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 855                   -> [FastString]          -- A long enough list of FSs to use for names
 856                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 857                   -> DataCon
 858                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 859                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 860 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 861 -- (ex_tvs, co_tvs, arg_ids),
 862 --
 863 --   ex_tvs are intended to be used as binders for existential type args
 864 --
 865 --   co_tvs are intended to be used as binders for coercion args and the kinds
 866 --     of these vars have been instantiated by the inst_tys and the ex_tys
 867 --     The co_tvs include both GADT equalities (dcEqSpec) and
 868 --     programmer-specified equalities (dcEqTheta)
 869 --
 870 --   arg_ids are indended to be used as binders for value arguments,
 871 --     and their types have been instantiated with inst_tys and ex_tys
 872 --     The arg_ids include both dicts (dcDictTheta) and
 873 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 874 --
 875 -- Example.
 876 --  The following constructor T1
 877 --
 878 --  data T a where
 879 --    T1 :: forall b. Int -> b -> T(a,b)
 880 --    ...
 881 --
 882 --  has representation type
 883 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 884 --     Int -> b -> T a
 885 --
 886 --  dataConInstPat fss us T1 (a1',b') will return
 887 --
 888 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 889 --
 890 --  where the double-primed variables are created with the FastStrings and
 891 --  Uniques given as fss and us
 892 dataConInstPat arg_fun fss uniqs con inst_tys
 893   = (ex_bndrs, co_bndrs, arg_ids)
 894   where
 895     univ_tvs = dataConUnivTyVars con
 896     ex_tvs   = dataConExTyVars con
 897     arg_tys  = arg_fun con
 898     eq_spec  = dataConEqSpec con
 899     eq_theta = dataConEqTheta con
 900     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 901
 902     n_ex = length ex_tvs
 903     n_co = length eq_preds
 904
 905       -- split the Uniques and FastStrings
 906     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 907     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 908
 909     (ex_fss, fss')     = splitAt n_ex fss
 910     (co_fss, id_fss)   = splitAt n_co fss'
 911
 912       -- Make existential type variables
 913     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 914     mk_ex_var uniq fs var = mkTyVar new_name kind
 915       where
 916         new_name = mkSysTvName uniq fs
 917         kind     = tyVarKind var
 918
 919       -- Make the instantiating substitution
 920     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 921
 922       -- Make new coercion vars, instantiating kind
 923     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 924     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 925        where
 926          new_name = mkSysTvName uniq fs
 927          co_kind  = substTy subst (mkPredTy eq_pred)
 928
 929       -- make value vars, instantiating types
 930     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 931     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 932
 933 \end{code}
 934
 935 %************************************************************************
 936 %*                                                                      *
 937          Equality
 938 %*                                                                      *
 939 %************************************************************************
 940
 941 \begin{code}
 942 -- | A cheap equality test which bales out fast!
 943 --      If it returns @True@ the arguments are definitely equal,
 944 --      otherwise, they may or may not be equal.
 945 --
 946 -- See also 'exprIsBig'
 947 cheapEqExpr :: Expr b -> Expr b -> Bool
 948
 949 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
 950 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
 951 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
 952
 953 cheapEqExpr (App f1 a1) (App f2 a2)
 954   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
 955
 956 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
 957   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
 958
 959 cheapEqExpr _ _ = False
 960 \end{code}
 961
 962 \begin{code}
 963 exprIsBig :: Expr b -> Bool
 964 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
 965 exprIsBig (Lit _)      = False
 966 exprIsBig (Var _)      = False
 967 exprIsBig (Type _)     = False
 968 exprIsBig (Lam _ e)    = exprIsBig e
 969 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
 970 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
 971 exprIsBig _            = True
 972 \end{code}
 973
 974 \begin{code}
 975 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
 976 -- Compares for equality, modulo alpha
 977 eqExpr in_scope e1 e2
 978   = eqExprX id_unf (mkRnEnv2 in_scope) e1 e2
 979   where
 980     id_unf _ = noUnfolding      -- Don't expand
 981 \end{code}
 982
 983 \begin{code}
 984 eqExprX :: IdUnfoldingFun -> RnEnv2 -> CoreExpr -> CoreExpr -> Bool
 985 -- ^ Compares expressions for equality, modulo alpha.
 986 -- Does /not/ look through newtypes or predicate types
 987 -- Used in rule matching, and also CSE
 988
 989 eqExprX id_unfolding_fun env e1 e2
 990   = go env e1 e2
 991   where
 992     go env (Var v1) (Var v2)
 993       | rnOccL env v1 == rnOccR env v2
 994       = True
 995
 996     -- The next two rules expand non-local variables
 997     -- C.f. Note [Expanding variables] in Rules.lhs
 998     -- and  Note [Do not expand locally-bound variables] in Rules.lhs
 999     go env (Var v1) e2
1000       | not (locallyBoundL env v1)
1001       , Just e1' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v1))
1002       = go (nukeRnEnvL env) e1' e2
1003
1004     go env e1 (Var v2)
1005       | not (locallyBoundR env v2)
1006       , Just e2' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v2))
1007       = go (nukeRnEnvR env) e1 e2'
1008
1009     go _   (Lit lit1)    (Lit lit2)    = lit1 == lit2
1010     go env (Type t1)     (Type t2)     = tcEqTypeX env t1 t2
1011     go env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && go env e1 e2
1012     go env (App f1 a1)   (App f2 a2)   = go env f1 f2 && go env a1 a2
1013     go env (Note n1 e1)  (Note n2 e2)  = go_note n1 n2 && go env e1 e2
1014
1015     go env (Lam b1 e1)  (Lam b2 e2)
1016       =  tcEqTypeX env (varType b1) (varType b2)   -- False for Id/TyVar combination
1017       && go (rnBndr2 env b1 b2) e1 e2
1018
1019     go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1020       =  go env r1 r2  -- No need to check binder types, since RHSs match
1021       && go (rnBndr2 env v1 v2) e1 e2
1022
1023     go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1024       = all2 (go env') rs1 rs2 && go env' e1 e2
1025       where
1026         (bs1,rs1) = unzip ps1
1027         (bs2,rs2) = unzip ps2
1028         env' = rnBndrs2 env bs1 bs2
1029
1030     go env (Case e1 b1 _ a1) (Case e2 b2 _ a2)
1031       =  go env e1 e2
1032       && tcEqTypeX env (idType b1) (idType b2)
1033       && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1034
1035     go _ _ _ = False
1036
1037     -----------
1038     go_alt env (c1, bs1, e1) (c2, bs2, e2)
1039       = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1040
1041     -----------
1042     go_note (SCC cc1)     (SCC cc2)      = cc1 == cc2
1043     go_note (CoreNote s1) (CoreNote s2)  = s1 == s2
1044     go_note _             _              = False
1045 \end{code}
1046
1047 Auxiliary functions
1048
1049 \begin{code}
1050 locallyBoundL, locallyBoundR :: RnEnv2 -> Var -> Bool
1051 locallyBoundL rn_env v = inRnEnvL rn_env v
1052 locallyBoundR rn_env v = inRnEnvR rn_env v
1053 \end{code}
1054
1055
1056 %************************************************************************
1057 %*                                                                      *
1058 \subsection{The size of an expression}
1059 %*                                                                      *
1060 %************************************************************************
1061
1062 \begin{code}
1063 coreBindsSize :: [CoreBind] -> Int
1064 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1065
1066 exprSize :: CoreExpr -> Int
1067 -- ^ A measure of the size of the expressions, strictly greater than 0
1068 -- It also forces the expression pretty drastically as a side effect
1069 exprSize (Var v)         = v `seq` 1
1070 exprSize (Lit lit)       = lit `seq` 1
1071 exprSize (App f a)       = exprSize f + exprSize a
1072 exprSize (Lam b e)       = varSize b + exprSize e
1073 exprSize (Let b e)       = bindSize b + exprSize e
1074 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1075 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1076 exprSize (Note n e)      = noteSize n + exprSize e
1077 exprSize (Type t)        = seqType t `seq` 1
1078
1079 noteSize :: Note -> Int
1080 noteSize (SCC cc)       = cc `seq` 1
1081 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1082
1083 varSize :: Var -> Int
1084 varSize b  | isTyCoVar b = 1
1085            | otherwise = seqType (idType b)             `seq`
1086                          megaSeqIdInfo (idInfo b)       `seq`
1087                          1
1088
1089 varsSize :: [Var] -> Int
1090 varsSize = sum . map varSize
1091
1092 bindSize :: CoreBind -> Int
1093 bindSize (NonRec b e) = varSize b + exprSize e
1094 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1095
1096 pairSize :: (Var, CoreExpr) -> Int
1097 pairSize (b,e) = varSize b + exprSize e
1098
1099 altSize :: CoreAlt -> Int
1100 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1101 \end{code}
1102
1103
1104 %************************************************************************
1105 %*                                                                      *
1106 \subsection{Hashing}
1107 %*                                                                      *
1108 %************************************************************************
1109
1110 \begin{code}
1111 hashExpr :: CoreExpr -> Int
1112 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1113 -- Two expressions that hash to the different Ints are definitely unequal.
1114 --
1115 -- The emphasis is on a crude, fast hash, rather than on high precision.
1116 --
1117 -- But unequal here means \"not identical\"; two alpha-equivalent
1118 -- expressions may hash to the different Ints.
1119 --
1120 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1121 -- (at least if we want the above invariant to be true).
1122
1123 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1124              -- UniqFM doesn't like negative Ints
1125
1126 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1127
1128 hash_expr :: HashEnv -> CoreExpr -> Word32
1129 -- Word32, because we're expecting overflows here, and overflowing
1130 -- signed types just isn't cool.  In C it's even undefined.
1131 hash_expr env (Note _ e)              = hash_expr env e
1132 hash_expr env (Cast e _)              = hash_expr env e
1133 hash_expr env (Var v)                 = hashVar env v
1134 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1135 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1136 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1137 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1138 hash_expr env (Case e _ _ _)          = hash_expr env e
1139 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1140 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1141 -- Shouldn't happen.  Better to use WARN than trace, because trace
1142 -- prevents the CPR optimisation kicking in for hash_expr.
1143
1144 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1145 fast_hash_expr env (Var v)      = hashVar env v
1146 fast_hash_expr env (Type t)     = fast_hash_type env t
1147 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1148 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1149 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1150 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1151 fast_hash_expr _   _            = 1
1152
1153 fast_hash_type :: HashEnv -> Type -> Word32
1154 fast_hash_type env ty
1155   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1156   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1157                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1158   | otherwise                               = 1
1159
1160 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1161 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1162
1163 hashVar :: HashEnv -> Var -> Word32
1164 hashVar (_,env) v
1165  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1166 \end{code}
1167
1168
1169 %************************************************************************
1170 %*                                                                      *
1171                 Eta reduction
1172 %*                                                                      *
1173 %************************************************************************
1174
1175 Note [Eta reduction conditions]
1176 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1177 We try for eta reduction here, but *only* if we get all the way to an
1178 trivial expression.  We don't want to remove extra lambdas unless we
1179 are going to avoid allocating this thing altogether.
1180
1181 There are some particularly delicate points here:
1182
1183 * Eta reduction is not valid in general:
1184         \x. bot  /=  bot
1185   This matters, partly for old-fashioned correctness reasons but,
1186   worse, getting it wrong can yield a seg fault. Consider
1187         f = \x.f x
1188         h y = case (case y of { True -> f `seq` True; False -> False }) of
1189                 True -> ...; False -> ...
1190
1191   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
1192   says f=bottom, and replaces the (f `seq` True) with just
1193   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
1194   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
1195   the definition again, so that it does not termninate after all.
1196   Result: seg-fault because the boolean case actually gets a function value.
1197   See Trac #1947.
1198
1199   So it's important to to the right thing.
1200
1201 * Note [Arity care]: we need to be careful if we just look at f's
1202   arity. Currently (Dec07), f's arity is visible in its own RHS (see
1203   Note [Arity robustness] in SimplEnv) so we must *not* trust the
1204   arity when checking that 'f' is a value.  Otherwise we will
1205   eta-reduce
1206       f = \x. f x
1207   to
1208       f = f
1209   Which might change a terminiating program (think (f `seq` e)) to a
1210   non-terminating one.  So we check for being a loop breaker first.
1211
1212   However for GlobalIds we can look at the arity; and for primops we
1213   must, since they have no unfolding.
1214
1215 * Regardless of whether 'f' is a value, we always want to
1216   reduce (/\a -> f a) to f
1217   This came up in a RULE: foldr (build (/\a -> g a))
1218   did not match           foldr (build (/\b -> ...something complex...))
1219   The type checker can insert these eta-expanded versions,
1220   with both type and dictionary lambdas; hence the slightly
1221   ad-hoc isDictId
1222
1223 * Never *reduce* arity. For example
1224       f = \xy. g x y
1225   Then if h has arity 1 we don't want to eta-reduce because then
1226   f's arity would decrease, and that is bad
1227
1228 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1229 Alas.
1230
1231 Note [Eta reduction with casted arguments]
1232 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1233 Consider
1234     (\(x:t3). f (x |> g)) :: t3 -> t2
1235   where
1236     f :: t1 -> t2
1237     g :: t3 ~ t1
1238 This should be eta-reduced to
1239
1240     f |> (sym g -> t2)
1241
1242 So we need to accumulate a coercion, pushing it inward (past
1243 variable arguments only) thus:
1244    f (x |> co_arg) |> co  -->  (f |> (sym co_arg -> co)) x
1245    f (x:t)         |> co  -->  (f |> (t -> co)) x
1246    f @ a           |> co  -->  (f |> (forall a.co)) @ a
1247    f @ (g:t1~t2)   |> co  -->  (f |> (t1~t2 => co)) @ (g:t1~t2)
1248 These are the equations for ok_arg.
1249
1250 It's true that we could also hope to eta reduce these:
1251     (\xy. (f x |> g) y)
1252     (\xy. (f x y) |> g)
1253 But the simplifier pushes those casts outwards, so we don't
1254 need to address that here.
1255
1256 \begin{code}
1257 tryEtaReduce :: [Var] -> CoreExpr -> Maybe CoreExpr
1258 tryEtaReduce bndrs body
1259   = go (reverse bndrs) body (IdCo (exprType body))
1260   where
1261     incoming_arity = count isId bndrs
1262
1263     go :: [Var]            -- Binders, innermost first, types [a3,a2,a1]
1264        -> CoreExpr         -- Of type tr
1265        -> CoercionI        -- Of type tr ~ ts
1266        -> Maybe CoreExpr   -- Of type a1 -> a2 -> a3 -> ts
1267     -- See Note [Eta reduction with casted arguments]
1268     -- for why we have an accumulating coercion
1269     go [] fun co
1270       | ok_fun fun = Just (mkCoerceI co fun)
1271
1272     go (b : bs) (App fun arg) co
1273       | Just co' <- ok_arg b arg co
1274       = go bs fun co'
1275
1276     go _ _ _  = Nothing         -- Failure!
1277
1278     ---------------
1279     -- Note [Eta reduction conditions]
1280     ok_fun (App fun (Type ty))
1281         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1282         =  ok_fun fun
1283     ok_fun (Var fun_id)
1284         =  not (fun_id `elem` bndrs)
1285         && (ok_fun_id fun_id || all ok_lam bndrs)
1286     ok_fun _fun = False
1287
1288     ---------------
1289     ok_fun_id fun = fun_arity fun >= incoming_arity
1290
1291     ---------------
1292     fun_arity fun             -- See Note [Arity care]
1293        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1294        | otherwise = idArity fun
1295
1296     ---------------
1297     ok_lam v = isTyCoVar v || isDictId v
1298
1299     ---------------
1300     ok_arg :: Var               -- Of type bndr_t
1301            -> CoreExpr          -- Of type arg_t
1302            -> CoercionI         -- Of kind (t1~t2)
1303            -> Maybe CoercionI   -- Of type (arg_t -> t1 ~  bndr_t -> t2)
1304                                 --   (and similarly for tyvars, coercion args)
1305     -- See Note [Eta reduction with casted arguments]
1306     ok_arg bndr (Type ty) co
1307        | Just tv <- getTyVar_maybe ty
1308        , bndr == tv  = Just (mkForAllTyCoI tv co)
1309     ok_arg bndr (Var v) co
1310        | bndr == v   = Just (mkFunTyCoI (IdCo (idType bndr)) co)
1311     ok_arg bndr (Cast (Var v) co_arg) co
1312        | bndr == v  = Just (mkFunTyCoI (ACo (mkSymCoercion co_arg)) co)
1313        -- The simplifier combines multiple casts into one,
1314        -- so we can have a simple-minded pattern match here
1315     ok_arg _ _ _ = Nothing
1316 \end{code}
1317
1318
1319 %************************************************************************
1320 %*                                                                      *
1321 \subsection{Determining non-updatable right-hand-sides}
1322 %*                                                                      *
1323 %************************************************************************
1324
1325 Top-level constructor applications can usually be allocated
1326 statically, but they can't if the constructor, or any of the
1327 arguments, come from another DLL (because we can't refer to static
1328 labels in other DLLs).
1329
1330 If this happens we simply make the RHS into an updatable thunk,
1331 and 'execute' it rather than allocating it statically.
1332
1333 \begin{code}
1334 -- | This function is called only on *top-level* right-hand sides.
1335 -- Returns @True@ if the RHS can be allocated statically in the output,
1336 -- with no thunks involved at all.
1337 rhsIsStatic :: (Name -> Bool) -> CoreExpr -> Bool
1338 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1339 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1340 -- update flag on it and (iii) in DsExpr to decide how to expand
1341 -- list literals
1342 --
1343 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1344 --      (a) a value lambda
1345 --      (b) a saturated constructor application with static args
1346 --
1347 -- BUT watch out for
1348 --  (i) Any cross-DLL references kill static-ness completely
1349 --      because they must be 'executed' not statically allocated
1350 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1351 --      this is not necessary)
1352 --
1353 -- (ii) We treat partial applications as redexes, because in fact we
1354 --      make a thunk for them that runs and builds a PAP
1355 --      at run-time.  The only appliations that are treated as
1356 --      static are *saturated* applications of constructors.
1357
1358 -- We used to try to be clever with nested structures like this:
1359 --              ys = (:) w ((:) w [])
1360 -- on the grounds that CorePrep will flatten ANF-ise it later.
1361 -- But supporting this special case made the function much more
1362 -- complicated, because the special case only applies if there are no
1363 -- enclosing type lambdas:
1364 --              ys = /\ a -> Foo (Baz ([] a))
1365 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1366 --
1367 -- But in fact, even without -O, nested structures at top level are
1368 -- flattened by the simplifier, so we don't need to be super-clever here.
1369 --
1370 -- Examples
1371 --
1372 --      f = \x::Int. x+7        TRUE
1373 --      p = (True,False)        TRUE
1374 --
1375 --      d = (fst p, False)      FALSE because there's a redex inside
1376 --                              (this particular one doesn't happen but...)
1377 --
1378 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1379 --      n = /\a. Nil a                  TRUE
1380 --
1381 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1382 --
1383 --
1384 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1385 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1386 --
1387 --    b) (C x xs), where C is a contructor is updatable if the application is
1388 --         dynamic
1389 --
1390 --    c) don't look through unfolding of f in (f x).
1391
1392 rhsIsStatic _is_dynamic_name rhs = is_static False rhs
1393   where
1394   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1395           -> CoreExpr -> Bool
1396
1397   is_static False (Lam b e)   = isRuntimeVar b || is_static False e
1398   is_static in_arg (Note n e) = notSccNote n && is_static in_arg e
1399   is_static in_arg (Cast e _) = is_static in_arg e
1400
1401   is_static _      (Lit lit)
1402     = case lit of
1403         MachLabel _ _ _ -> False
1404         _             -> True
1405         -- A MachLabel (foreign import "&foo") in an argument
1406         -- prevents a constructor application from being static.  The
1407         -- reason is that it might give rise to unresolvable symbols
1408         -- in the object file: under Linux, references to "weak"
1409         -- symbols from the data segment give rise to "unresolvable
1410         -- relocation" errors at link time This might be due to a bug
1411         -- in the linker, but we'll work around it here anyway.
1412         -- SDM 24/2/2004
1413
1414   is_static in_arg other_expr = go other_expr 0
1415    where
1416     go (Var f) n_val_args
1417 #if mingw32_TARGET_OS
1418         | not (_is_dynamic_name (idName f))
1419 #endif
1420         =  saturated_data_con f n_val_args
1421         || (in_arg && n_val_args == 0)
1422                 -- A naked un-applied variable is *not* deemed a static RHS
1423                 -- E.g.         f = g
1424                 -- Reason: better to update so that the indirection gets shorted
1425                 --         out, and the true value will be seen
1426                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1427                 --     are always updatable.  If you do so, make sure that non-updatable
1428                 --     ones have enough space for their static link field!
1429
1430     go (App f a) n_val_args
1431         | isTypeArg a                    = go f n_val_args
1432         | not in_arg && is_static True a = go f (n_val_args + 1)
1433         -- The (not in_arg) checks that we aren't in a constructor argument;
1434         -- if we are, we don't allow (value) applications of any sort
1435         --
1436         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1437         --   x = D# (1.0## /## 2.0##)
1438         -- can't float because /## can fail.
1439
1440     go (Note n f) n_val_args = notSccNote n && go f n_val_args
1441     go (Cast e _) n_val_args = go e n_val_args
1442     go _          _          = False
1443
1444     saturated_data_con f n_val_args
1445         = case isDataConWorkId_maybe f of
1446             Just dc -> n_val_args == dataConRepArity dc
1447             Nothing -> False
1448 \end{code}