compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 module CoreUtils (
  10         -- Construction
  11         mkInlineMe, mkSCC, mkCoerce,
  12         bindNonRec, needsCaseBinding,
  13         mkIfThenElse, mkAltExpr, mkPiType, mkPiTypes,
  14
  15         -- Taking expressions apart
  16         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  17
  18         -- Properties of expressions
  19         exprType, coreAltType,
  20         exprIsDupable, exprIsTrivial, exprIsCheap,
  21         exprIsHNF,exprOkForSpeculation, exprIsBig,
  22         exprIsConApp_maybe, exprIsBottom,
  23         rhsIsStatic,
  24
  25         -- Arity and eta expansion
  26         manifestArity, exprArity,
  27         exprEtaExpandArity, etaExpand,
  28
  29         -- Size
  30         coreBindsSize,
  31
  32         -- Hashing
  33         hashExpr,
  34
  35         -- Equality
  36         cheapEqExpr, tcEqExpr, tcEqExprX, applyTypeToArgs, applyTypeToArg,
  37
  38         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  39     ) where
  40
  41 #include "HsVersions.h"
  42
  43 import CoreSyn
  44 import CoreFVs
  45 import PprCore
  46 import Var
  47 import SrcLoc
  48 import VarSet
  49 import VarEnv
  50 import Name
  51 #if mingw32_TARGET_OS
  52 import Packages
  53 #endif
  54 import Literal
  55 import DataCon
  56 import PrimOp
  57 import Id
  58 import IdInfo
  59 import NewDemand
  60 import Type
  61 import Coercion
  62 import TyCon
  63 import TysWiredIn
  64 import CostCentre
  65 import BasicTypes
  66 import PackageConfig
  67 import Unique
  68 import Outputable
  69 import DynFlags
  70 import TysPrim
  71 import FastString
  72 import Maybes
  73 import Util
  74 import Data.Word
  75 import Data.Bits
  76
  77 import GHC.Exts         -- For `xori`
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89
  90 exprType (Var var)              = idType var
  91 exprType (Lit lit)              = literalType lit
  92 exprType (Let _ body)           = exprType body
  93 exprType (Case _ _ ty alts)     = ty
  94 exprType (Cast e co)
  95   = let (_, ty) = coercionKind co in ty
  96 exprType (Note other_note e)    = exprType e
  97 exprType (Lam binder expr)      = mkPiType binder (exprType expr)
  98 exprType e@(App _ _)
  99   = case collectArgs e of
 100         (fun, args) -> applyTypeToArgs e (exprType fun) args
 101
 102 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 103
 104 coreAltType :: CoreAlt -> Type
 105 coreAltType (_,_,rhs) = exprType rhs
 106 \end{code}
 107
 108 @mkPiType@ makes a (->) type or a forall type, depending on whether
 109 it is given a type variable or a term variable.  We cleverly use the
 110 lbvarinfo field to figure out the right annotation for the arrove in
 111 case of a term variable.
 112
 113 \begin{code}
 114 mkPiType  :: Var   -> Type -> Type      -- The more polymorphic version
 115 mkPiTypes :: [Var] -> Type -> Type      --    doesn't work...
 116
 117 mkPiTypes vs ty = foldr mkPiType ty vs
 118
 119 mkPiType v ty
 120    | isId v    = mkFunTy (idType v) ty
 121    | otherwise = mkForAllTy v ty
 122 \end{code}
 123
 124 \begin{code}
 125 applyTypeToArg :: Type -> CoreExpr -> Type
 126 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 127 applyTypeToArg fun_ty other_arg     = funResultTy fun_ty
 128
 129 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 130 -- A more efficient version of applyTypeToArg
 131 -- when we have several args
 132 -- The first argument is just for debugging
 133 applyTypeToArgs e op_ty [] = op_ty
 134
 135 applyTypeToArgs e op_ty (Type ty : args)
 136   =     -- Accumulate type arguments so we can instantiate all at once
 137     go [ty] args
 138   where
 139     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 140     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 141                                 where
 142                                   op_ty' = applyTys op_ty (reverse rev_tys)
 143
 144 applyTypeToArgs e op_ty (other_arg : args)
 145   = case (splitFunTy_maybe op_ty) of
 146         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 147         Nothing -> pprPanic "applyTypeToArgs" (pprCoreExpr e $$ ppr op_ty)
 148 \end{code}
 149
 150
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Attaching notes}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 mkNote removes redundant coercions, and SCCs where possible
 159
 160 \begin{code}
 161 #ifdef UNUSED
 162 mkNote :: Note -> CoreExpr -> CoreExpr
 163 mkNote (SCC cc) expr               = mkSCC cc expr
 164 mkNote InlineMe expr               = mkInlineMe expr
 165 mkNote note     expr               = Note note expr
 166 #endif
 167 \end{code}
 168
 169 Drop trivial InlineMe's.  This is somewhat important, because if we have an unfolding
 170 that looks like (Note InlineMe (Var v)), the InlineMe doesn't go away because it may
 171 not be *applied* to anything.
 172
 173 We don't use exprIsTrivial here, though, because we sometimes generate worker/wrapper
 174 bindings like
 175         fw = ...
 176         f  = inline_me (coerce t fw)
 177 As usual, the inline_me prevents the worker from getting inlined back into the wrapper.
 178 We want the split, so that the coerces can cancel at the call site.
 179
 180 However, we can get left with tiresome type applications.  Notably, consider
 181         f = /\ a -> let t = e in (t, w)
 182 Then lifting the let out of the big lambda gives
 183         t' = /\a -> e
 184         f = /\ a -> let t = inline_me (t' a) in (t, w)
 185 The inline_me is to stop the simplifier inlining t' right back
 186 into t's RHS.  In the next phase we'll substitute for t (since
 187 its rhs is trivial) and *then* we could get rid of the inline_me.
 188 But it hardly seems worth it, so I don't bother.
 189
 190 \begin{code}
 191 mkInlineMe (Var v) = Var v
 192 mkInlineMe e       = Note InlineMe e
 193 \end{code}
 194
 195
 196
 197 \begin{code}
 198 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 199 mkCoerce co (Cast expr co2)
 200   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 201                  (_from_ty2, to_ty2) = coercionKind co2} in
 202            from_ty `coreEqType` to_ty2 )
 203     mkCoerce (mkTransCoercion co2 co) expr
 204
 205 mkCoerce co expr
 206   = let (from_ty, to_ty) = coercionKind co in
 207 --    if to_ty `coreEqType` from_ty
 208 --    then expr
 209 --    else
 210         ASSERT2(from_ty `coreEqType` (exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ ppr (coercionKindPredTy co))
 211          (Cast expr co)
 212 \end{code}
 213
 214 \begin{code}
 215 mkSCC :: CostCentre -> Expr b -> Expr b
 216         -- Note: Nested SCC's *are* preserved for the benefit of
 217         --       cost centre stack profiling
 218 mkSCC cc (Lit lit)          = Lit lit
 219 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 220 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 221 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 222 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 223 mkSCC cc expr               = Note (SCC cc) expr
 224 \end{code}
 225
 226
 227 %************************************************************************
 228 %*                                                                      *
 229 \subsection{Other expression construction}
 230 %*                                                                      *
 231 %************************************************************************
 232
 233 \begin{code}
 234 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 235 -- (bindNonRec x r b) produces either
 236 --      let x = r in b
 237 -- or
 238 --      case r of x { _DEFAULT_ -> b }
 239 --
 240 -- depending on whether x is unlifted or not
 241 -- It's used by the desugarer to avoid building bindings
 242 -- that give Core Lint a heart attack.  Actually the simplifier
 243 -- deals with them perfectly well.
 244
 245 bindNonRec bndr rhs body
 246   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 247   | otherwise                          = Let (NonRec bndr rhs) body
 248
 249 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 250         -- Make a case expression instead of a let
 251         -- These can arise either from the desugarer,
 252         -- or from beta reductions: (\x.e) (x +# y)
 253 \end{code}
 254
 255 \begin{code}
 256 mkAltExpr :: AltCon -> [CoreBndr] -> [Type] -> CoreExpr
 257         -- This guy constructs the value that the scrutinee must have
 258         -- when you are in one particular branch of a case
 259 mkAltExpr (DataAlt con) args inst_tys
 260   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 261 mkAltExpr (LitAlt lit) [] []
 262   = Lit lit
 263
 264 mkIfThenElse :: CoreExpr -> CoreExpr -> CoreExpr -> CoreExpr
 265 mkIfThenElse guard then_expr else_expr
 266 -- Not going to be refining, so okay to take the type of the "then" clause
 267   = Case guard (mkWildId boolTy) (exprType then_expr)
 268          [ (DataAlt falseDataCon, [], else_expr),       -- Increasing order of tag!
 269            (DataAlt trueDataCon,  [], then_expr) ]
 270 \end{code}
 271
 272
 273 %************************************************************************
 274 %*                                                                      *
 275 \subsection{Taking expressions apart}
 276 %*                                                                      *
 277 %************************************************************************
 278
 279 The default alternative must be first, if it exists at all.
 280 This makes it easy to find, though it makes matching marginally harder.
 281
 282 \begin{code}
 283 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 284 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 285 findDefault alts                        =                     (alts, Nothing)
 286
 287 findAlt :: AltCon -> [CoreAlt] -> CoreAlt
 288 findAlt con alts
 289   = case alts of
 290         (deflt@(DEFAULT,_,_):alts) -> go alts deflt
 291         other                      -> go alts panic_deflt
 292   where
 293     panic_deflt = pprPanic "Missing alternative" (ppr con $$ vcat (map ppr alts))
 294
 295     go []                      deflt = deflt
 296     go (alt@(con1,_,_) : alts) deflt
 297       = case con `cmpAltCon` con1 of
 298           LT -> deflt   -- Missed it already; the alts are in increasing order
 299           EQ -> alt
 300           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 301
 302 isDefaultAlt :: CoreAlt -> Bool
 303 isDefaultAlt (DEFAULT, _, _) = True
 304 isDefaultAlt other           = False
 305
 306 ---------------------------------
 307 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 308 -- Merge preserving order; alternatives in the first arg
 309 -- shadow ones in the second
 310 mergeAlts [] as2 = as2
 311 mergeAlts as1 [] = as1
 312 mergeAlts (a1:as1) (a2:as2)
 313   = case a1 `cmpAlt` a2 of
 314         LT -> a1 : mergeAlts as1      (a2:as2)
 315         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 316         GT -> a2 : mergeAlts (a1:as1) as2
 317
 318
 319 ---------------------------------
 320 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 321 -- Given        case (C a b x y) of
 322 --                 C b x y -> ...
 323 -- we want to drop the leading type argument of the scrutinee
 324 -- leaving the arguments to match agains the pattern
 325
 326 trimConArgs DEFAULT      args = ASSERT( null args ) []
 327 trimConArgs (LitAlt lit) args = ASSERT( null args ) []
 328 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 329 \end{code}
 330
 331
 332 %************************************************************************
 333 %*                                                                      *
 334 \subsection{Figuring out things about expressions}
 335 %*                                                                      *
 336 %************************************************************************
 337
 338 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 339                 duplicate; simple variables and constants, and type
 340                 applications.  Note that primop Ids aren't considered
 341                 trivial unless
 342
 343 @exprIsBottom@  is true of expressions that are guaranteed to diverge
 344
 345
 346 There used to be a gruesome test for (hasNoBinding v) in the
 347 Var case:
 348         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 349 The idea here is that a constructor worker, like $wJust, is
 350 really short for (\x -> $wJust x), becuase $wJust has no binding.
 351 So it should be treated like a lambda.  Ditto unsaturated primops.
 352 But now constructor workers are not "have-no-binding" Ids.  And
 353 completely un-applied primops and foreign-call Ids are sufficiently
 354 rare that I plan to allow them to be duplicated and put up with
 355 saturating them.
 356
 357 SCC notes.  We do not treat (_scc_ "foo" x) as trivial, because
 358   a) it really generates code, (and a heap object when it's
 359      a function arg) to capture the cost centre
 360   b) see the note [SCC-and-exprIsTrivial] in Simplify.simplLazyBind
 361
 362 \begin{code}
 363 exprIsTrivial (Var v)      = True       -- See notes above
 364 exprIsTrivial (Type _)     = True
 365 exprIsTrivial (Lit lit)    = litIsTrivial lit
 366 exprIsTrivial (App e arg)  = not (isRuntimeArg arg) && exprIsTrivial e
 367 exprIsTrivial (Note (SCC _) e) = False          -- See notes above
 368 exprIsTrivial (Note _       e) = exprIsTrivial e
 369 exprIsTrivial (Cast e co)  = exprIsTrivial e
 370 exprIsTrivial (Lam b body) = not (isRuntimeVar b) && exprIsTrivial body
 371 exprIsTrivial other        = False
 372 \end{code}
 373
 374
 375 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 376                 cost in code size.  This will only happen in different case
 377                 branches, so there's no issue about duplicating work.
 378
 379                 That is, exprIsDupable returns True of (f x) even if
 380                 f is very very expensive to call.
 381
 382                 Its only purpose is to avoid fruitless let-binding
 383                 and then inlining of case join points
 384
 385
 386 \begin{code}
 387 exprIsDupable (Type _)          = True
 388 exprIsDupable (Var v)           = True
 389 exprIsDupable (Lit lit)         = litIsDupable lit
 390 exprIsDupable (Note InlineMe e) = True
 391 exprIsDupable (Note _ e)        = exprIsDupable e
 392 exprIsDupable (Cast e co)       = exprIsDupable e
 393 exprIsDupable expr
 394   = go expr 0
 395   where
 396     go (Var v)   n_args = True
 397     go (App f a) n_args =  n_args < dupAppSize
 398                         && exprIsDupable a
 399                         && go f (n_args+1)
 400     go other n_args     = False
 401
 402 dupAppSize :: Int
 403 dupAppSize = 4          -- Size of application we are prepared to duplicate
 404 \end{code}
 405
 406 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 407 it is obviously in weak head normal form, or is cheap to get to WHNF.
 408 [Note that that's not the same as exprIsDupable; an expression might be
 409 big, and hence not dupable, but still cheap.]
 410
 411 By ``cheap'' we mean a computation we're willing to:
 412         push inside a lambda, or
 413         inline at more than one place
 414 That might mean it gets evaluated more than once, instead of being
 415 shared.  The main examples of things which aren't WHNF but are
 416 ``cheap'' are:
 417
 418   *     case e of
 419           pi -> ei
 420         (where e, and all the ei are cheap)
 421
 422   *     let x = e in b
 423         (where e and b are cheap)
 424
 425   *     op x1 ... xn
 426         (where op is a cheap primitive operator)
 427
 428   *     error "foo"
 429         (because we are happy to substitute it inside a lambda)
 430
 431 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 432 because sharing will make sure it is only evaluated once.
 433
 434 \begin{code}
 435 exprIsCheap :: CoreExpr -> Bool
 436 exprIsCheap (Lit lit)         = True
 437 exprIsCheap (Type _)          = True
 438 exprIsCheap (Var _)           = True
 439 exprIsCheap (Note InlineMe e) = True
 440 exprIsCheap (Note _ e)        = exprIsCheap e
 441 exprIsCheap (Cast e co)       = exprIsCheap e
 442 exprIsCheap (Lam x e)         = isRuntimeVar x || exprIsCheap e
 443 exprIsCheap (Case e _ _ alts) = exprIsCheap e &&
 444                                 and [exprIsCheap rhs | (_,_,rhs) <- alts]
 445         -- Experimentally, treat (case x of ...) as cheap
 446         -- (and case __coerce x etc.)
 447         -- This improves arities of overloaded functions where
 448         -- there is only dictionary selection (no construction) involved
 449 exprIsCheap (Let (NonRec x _) e)
 450       | isUnLiftedType (idType x) = exprIsCheap e
 451       | otherwise                 = False
 452         -- strict lets always have cheap right hand sides,
 453         -- and do no allocation.
 454
 455 exprIsCheap other_expr  -- Applications and variables
 456   = go other_expr []
 457   where
 458         -- Accumulate value arguments, then decide
 459     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 460                           | otherwise      = go f val_args
 461
 462     go (Var f) [] = True        -- Just a type application of a variable
 463                                 -- (f t1 t2 t3) counts as WHNF
 464     go (Var f) args
 465         = case globalIdDetails f of
 466                 RecordSelId {} -> go_sel args
 467                 ClassOpId _    -> go_sel args
 468                 PrimOpId op    -> go_primop op args
 469
 470                 DataConWorkId _ -> go_pap args
 471                 other | length args < idArity f -> go_pap args
 472
 473                 other -> isBottomingId f
 474                         -- Application of a function which
 475                         -- always gives bottom; we treat this as cheap
 476                         -- because it certainly doesn't need to be shared!
 477
 478     go other args = False
 479
 480     --------------
 481     go_pap args = all exprIsTrivial args
 482         -- For constructor applications and primops, check that all
 483         -- the args are trivial.  We don't want to treat as cheap, say,
 484         --      (1:2:3:4:5:[])
 485         -- We'll put up with one constructor application, but not dozens
 486
 487     --------------
 488     go_primop op args = primOpIsCheap op && all exprIsCheap args
 489         -- In principle we should worry about primops
 490         -- that return a type variable, since the result
 491         -- might be applied to something, but I'm not going
 492         -- to bother to check the number of args
 493
 494     --------------
 495     go_sel [arg] = exprIsCheap arg      -- I'm experimenting with making record selection
 496     go_sel other = False                -- look cheap, so we will substitute it inside a
 497                                         -- lambda.  Particularly for dictionary field selection.
 498                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 499                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 500 \end{code}
 501
 502 exprOkForSpeculation returns True of an expression that it is
 503
 504         * safe to evaluate even if normal order eval might not
 505           evaluate the expression at all, or
 506
 507         * safe *not* to evaluate even if normal order would do so
 508
 509 It returns True iff
 510
 511         the expression guarantees to terminate,
 512         soon,
 513         without raising an exception,
 514         without causing a side effect (e.g. writing a mutable variable)
 515
 516 NB: if exprIsHNF e, then exprOkForSpecuation e
 517
 518 E.G.
 519         let x = case y# +# 1# of { r# -> I# r# }
 520         in E
 521 ==>
 522         case y# +# 1# of { r# ->
 523         let x = I# r#
 524         in E
 525         }
 526
 527 We can only do this if the (y+1) is ok for speculation: it has no
 528 side effects, and can't diverge or raise an exception.
 529
 530 \begin{code}
 531 exprOkForSpeculation :: CoreExpr -> Bool
 532 exprOkForSpeculation (Lit _)     = True
 533 exprOkForSpeculation (Type _)    = True
 534     -- Tick boxes are *not* suitable for speculation
 535 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 536                                  && not (isTickBoxOp v)
 537 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 538 exprOkForSpeculation (Cast e co) = exprOkForSpeculation e
 539 exprOkForSpeculation other_expr
 540   = case collectArgs other_expr of
 541         (Var f, args) -> spec_ok (globalIdDetails f) args
 542         other         -> False
 543
 544   where
 545     spec_ok (DataConWorkId _) args
 546       = True    -- The strictness of the constructor has already
 547                 -- been expressed by its "wrapper", so we don't need
 548                 -- to take the arguments into account
 549
 550     spec_ok (PrimOpId op) args
 551       | isDivOp op,             -- Special case for dividing operations that fail
 552         [arg1, Lit lit] <- args -- only if the divisor is zero
 553       = not (isZeroLit lit) && exprOkForSpeculation arg1
 554                 -- Often there is a literal divisor, and this
 555                 -- can get rid of a thunk in an inner looop
 556
 557       | otherwise
 558       = primOpOkForSpeculation op &&
 559         all exprOkForSpeculation args
 560                                 -- A bit conservative: we don't really need
 561                                 -- to care about lazy arguments, but this is easy
 562
 563     spec_ok other args = False
 564
 565 isDivOp :: PrimOp -> Bool
 566 -- True of dyadic operators that can fail
 567 -- only if the second arg is zero
 568 -- This function probably belongs in PrimOp, or even in
 569 -- an automagically generated file.. but it's such a
 570 -- special case I thought I'd leave it here for now.
 571 isDivOp IntQuotOp        = True
 572 isDivOp IntRemOp         = True
 573 isDivOp WordQuotOp       = True
 574 isDivOp WordRemOp        = True
 575 isDivOp IntegerQuotRemOp = True
 576 isDivOp IntegerDivModOp  = True
 577 isDivOp FloatDivOp       = True
 578 isDivOp DoubleDivOp      = True
 579 isDivOp other            = False
 580 \end{code}
 581
 582
 583 \begin{code}
 584 exprIsBottom :: CoreExpr -> Bool        -- True => definitely bottom
 585 exprIsBottom e = go 0 e
 586                where
 587                 -- n is the number of args
 588                  go n (Note _ e)     = go n e
 589                  go n (Cast e co)    = go n e
 590                  go n (Let _ e)      = go n e
 591                  go n (Case e _ _ _) = go 0 e   -- Just check the scrut
 592                  go n (App e _)      = go (n+1) e
 593                  go n (Var v)        = idAppIsBottom v n
 594                  go n (Lit _)        = False
 595                  go n (Lam _ _)      = False
 596                  go n (Type _)       = False
 597
 598 idAppIsBottom :: Id -> Int -> Bool
 599 idAppIsBottom id n_val_args = appIsBottom (idNewStrictness id) n_val_args
 600 \end{code}
 601
 602 @exprIsHNF@ returns true for expressions that are certainly *already*
 603 evaluated to *head* normal form.  This is used to decide whether it's ok
 604 to change
 605
 606         case x of _ -> e   ===>   e
 607
 608 and to decide whether it's safe to discard a `seq`
 609
 610 So, it does *not* treat variables as evaluated, unless they say they are.
 611
 612 But it *does* treat partial applications and constructor applications
 613 as values, even if their arguments are non-trivial, provided the argument
 614 type is lifted;
 615         e.g.  (:) (f x) (map f xs)      is a value
 616               map (...redex...)         is a value
 617 Because `seq` on such things completes immediately
 618
 619 For unlifted argument types, we have to be careful:
 620                 C (f x :: Int#)
 621 Suppose (f x) diverges; then C (f x) is not a value.  However this can't
 622 happen: see CoreSyn Note [CoreSyn let/app invariant].  Args of unboxed
 623 type must be ok-for-speculation (or trivial).
 624
 625 \begin{code}
 626 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 627 exprIsHNF (Var v)       -- NB: There are no value args at this point
 628   =  isDataConWorkId v  -- Catches nullary constructors,
 629                         --      so that [] and () are values, for example
 630   || idArity v > 0      -- Catches (e.g.) primops that don't have unfoldings
 631   || isEvaldUnfolding (idUnfolding v)
 632         -- Check the thing's unfolding; it might be bound to a value
 633         -- A worry: what if an Id's unfolding is just itself:
 634         -- then we could get an infinite loop...
 635
 636 exprIsHNF (Lit l)          = True
 637 exprIsHNF (Type ty)        = True       -- Types are honorary Values;
 638                                         -- we don't mind copying them
 639 exprIsHNF (Lam b e)        = isRuntimeVar b || exprIsHNF e
 640 exprIsHNF (Note _ e)       = exprIsHNF e
 641 exprIsHNF (Cast e co)      = exprIsHNF e
 642 exprIsHNF (App e (Type _)) = exprIsHNF e
 643 exprIsHNF (App e a)        = app_is_value e [a]
 644 exprIsHNF other            = False
 645
 646 -- There is at least one value argument
 647 app_is_value (Var fun) args
 648   = idArity fun > valArgCount args      -- Under-applied function
 649     ||  isDataConWorkId fun             --  or data constructor
 650 app_is_value (Note n f) as = app_is_value f as
 651 app_is_value (Cast f _) as = app_is_value f as
 652 app_is_value (App f a)  as = app_is_value f (a:as)
 653 app_is_value other      as = False
 654 \end{code}
 655
 656 \begin{code}
 657 -- These InstPat functions go here to avoid circularity between DataCon and Id
 658 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat (FSLIT("ipv")))
 659 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 660 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat (FSLIT("ipv")))
 661   where
 662     dc_arg_tys dc = map mkPredTy (dataConTheta dc) ++ dataConOrigArgTys dc
 663         -- Remember to include the existential dictionaries
 664
 665 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 666                   -> [FastString]          -- A long enough list of FSs to use for names
 667                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 668                   -> DataCon
 669                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 670                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 671 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 672 -- (ex_tvs, co_tvs, arg_ids),
 673 --
 674 --   ex_tvs are intended to be used as binders for existential type args
 675 --
 676 --   co_tvs are intended to be used as binders for coercion args and the kinds
 677 --     of these vars have been instantiated by the inst_tys and the ex_tys
 678 --
 679 --   arg_ids are indended to be used as binders for value arguments, including
 680 --     dicts, and their types have been instantiated with inst_tys and ex_tys
 681 --
 682 -- Example.
 683 --  The following constructor T1
 684 --
 685 --  data T a where
 686 --    T1 :: forall b. Int -> b -> T(a,b)
 687 --    ...
 688 --
 689 --  has representation type
 690 --   forall a. forall a1. forall b. (a :=: (a1,b)) =>
 691 --     Int -> b -> T a
 692 --
 693 --  dataConInstPat fss us T1 (a1',b') will return
 694 --
 695 --  ([a1'', b''], [c :: (a1', b'):=:(a1'', b'')], [x :: Int, y :: b''])
 696 --
 697 --  where the double-primed variables are created with the FastStrings and
 698 --  Uniques given as fss and us
 699 dataConInstPat arg_fun fss uniqs con inst_tys
 700   = (ex_bndrs, co_bndrs, id_bndrs)
 701   where
 702     univ_tvs = dataConUnivTyVars con
 703     ex_tvs   = dataConExTyVars con
 704     arg_tys  = arg_fun con
 705     eq_spec  = dataConEqSpec con
 706     eq_preds = eqSpecPreds eq_spec
 707
 708     n_ex = length ex_tvs
 709     n_co = length eq_spec
 710
 711       -- split the Uniques and FastStrings
 712     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 713     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 714
 715     (ex_fss, fss')     = splitAt n_ex fss
 716     (co_fss, id_fss)   = splitAt n_co fss'
 717
 718       -- Make existential type variables
 719     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 720     mk_ex_var uniq fs var = mkTyVar new_name kind
 721       where
 722         new_name = mkSysTvName uniq fs
 723         kind     = tyVarKind var
 724
 725       -- Make the instantiating substitution
 726     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 727
 728       -- Make new coercion vars, instantiating kind
 729     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 730     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 731        where
 732          new_name = mkSysTvName uniq fs
 733          co_kind  = substTy subst (mkPredTy eq_pred)
 734
 735       -- make value vars, instantiating types
 736     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcLoc
 737     id_bndrs = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 738
 739 exprIsConApp_maybe :: CoreExpr -> Maybe (DataCon, [CoreExpr])
 740 -- Returns (Just (dc, [x1..xn])) if the argument expression is
 741 -- a constructor application of the form (dc x1 .. xn)
 742 exprIsConApp_maybe (Cast expr co)
 743   =     -- Here we do the PushC reduction rule as described in the FC paper
 744     case exprIsConApp_maybe expr of {
 745         Nothing            -> Nothing ;
 746         Just (dc, dc_args) ->
 747
 748         -- The transformation applies iff we have
 749         --      (C e1 ... en) `cast` co
 750         -- where co :: (T t1 .. tn) :=: (T s1 ..sn)
 751         -- That is, with a T at the top of both sides
 752         -- The left-hand one must be a T, because exprIsConApp returned True
 753         -- but the right-hand one might not be.  (Though it usually will.)
 754
 755     let (from_ty, to_ty)           = coercionKind co
 756         (from_tc, from_tc_arg_tys) = splitTyConApp from_ty
 757                 -- The inner one must be a TyConApp
 758     in
 759     case splitTyConApp_maybe to_ty of {
 760         Nothing -> Nothing ;
 761         Just (to_tc, to_tc_arg_tys)
 762                 | from_tc /= to_tc -> Nothing
 763                 -- These two Nothing cases are possible; we might see
 764                 --      (C x y) `cast` (g :: T a ~ S [a]),
 765                 -- where S is a type function.  In fact, exprIsConApp
 766                 -- will probably not be called in such circumstances,
 767                 -- but there't nothing wrong with it
 768
 769                 | otherwise  ->
 770     let
 771         tc_arity = tyConArity from_tc
 772
 773         (univ_args, rest1)  = splitAt tc_arity dc_args
 774         (ex_args, rest2)    = splitAt n_ex_tvs rest1
 775         (co_args, val_args) = splitAt n_cos rest2
 776
 777         arg_tys             = dataConRepArgTys dc
 778         dc_univ_tyvars      = dataConUnivTyVars dc
 779         dc_ex_tyvars        = dataConExTyVars dc
 780         dc_eq_spec          = dataConEqSpec dc
 781         dc_tyvars           = dc_univ_tyvars ++ dc_ex_tyvars
 782         n_ex_tvs            = length dc_ex_tyvars
 783         n_cos               = length dc_eq_spec
 784
 785         -- Make the "theta" from Fig 3 of the paper
 786         gammas              = decomposeCo tc_arity co
 787         new_tys             = gammas ++ map (\ (Type t) -> t) ex_args
 788         theta               = zipOpenTvSubst dc_tyvars new_tys
 789
 790           -- First we cast the existential coercion arguments
 791         cast_co (tv,ty) (Type co) = Type $ mkSymCoercion (substTyVar theta tv)
 792                                            `mkTransCoercion` co
 793                                            `mkTransCoercion` (substTy theta ty)
 794         new_co_args = zipWith cast_co dc_eq_spec co_args
 795
 796           -- ...and now value arguments
 797         new_val_args = zipWith cast_arg arg_tys val_args
 798         cast_arg arg_ty arg = mkCoerce (substTy theta arg_ty) arg
 799
 800     in
 801     ASSERT( length univ_args == tc_arity )
 802     ASSERT( from_tc == dataConTyCon dc )
 803     ASSERT( and (zipWith coreEqType [t | Type t <- univ_args] from_tc_arg_tys) )
 804     ASSERT( all isTypeArg (univ_args ++ ex_args) )
 805     ASSERT2( equalLength val_args arg_tys, ppr dc $$ ppr dc_tyvars $$ ppr dc_ex_tyvars $$ ppr arg_tys $$ ppr dc_args $$ ppr univ_args $$ ppr ex_args $$ ppr val_args $$ ppr arg_tys  )
 806
 807     Just (dc, map Type to_tc_arg_tys ++ ex_args ++ new_co_args ++ new_val_args)
 808     }}
 809
 810 {-
 811 -- We do not want to tell the world that we have a
 812 -- Cons, to *stop* Case of Known Cons, which removes
 813 -- the TickBox.
 814 exprIsConApp_maybe (Note (TickBox {}) expr)
 815   = Nothing
 816 exprIsConApp_maybe (Note (BinaryTickBox {}) expr)
 817   = Nothing
 818 -}
 819
 820 exprIsConApp_maybe (Note _ expr)
 821   = exprIsConApp_maybe expr
 822     -- We ignore InlineMe notes in case we have
 823     --  x = __inline_me__ (a,b)
 824     -- All part of making sure that INLINE pragmas never hurt
 825     -- Marcin tripped on this one when making dictionaries more inlinable
 826     --
 827     -- In fact, we ignore all notes.  For example,
 828     --          case _scc_ "foo" (C a b) of
 829     --                  C a b -> e
 830     -- should be optimised away, but it will be only if we look
 831     -- through the SCC note.
 832
 833 exprIsConApp_maybe expr = analyse (collectArgs expr)
 834   where
 835     analyse (Var fun, args)
 836         | Just con <- isDataConWorkId_maybe fun,
 837           args `lengthAtLeast` dataConRepArity con
 838                 -- Might be > because the arity excludes type args
 839         = Just (con,args)
 840
 841         -- Look through unfoldings, but only cheap ones, because
 842         -- we are effectively duplicating the unfolding
 843     analyse (Var fun, [])
 844         | let unf = idUnfolding fun,
 845           isCheapUnfolding unf
 846         = exprIsConApp_maybe (unfoldingTemplate unf)
 847
 848     analyse other = Nothing
 849 \end{code}
 850
 851
 852
 853 %************************************************************************
 854 %*                                                                      *
 855 \subsection{Eta reduction and expansion}
 856 %*                                                                      *
 857 %************************************************************************
 858
 859 \begin{code}
 860 exprEtaExpandArity :: DynFlags -> CoreExpr -> Arity
 861 {- The Arity returned is the number of value args the
 862    thing can be applied to without doing much work
 863
 864 exprEtaExpandArity is used when eta expanding
 865         e  ==>  \xy -> e x y
 866
 867 It returns 1 (or more) to:
 868         case x of p -> \s -> ...
 869 because for I/O ish things we really want to get that \s to the top.
 870 We are prepared to evaluate x each time round the loop in order to get that
 871
 872 It's all a bit more subtle than it looks:
 873
 874 1.  One-shot lambdas
 875
 876 Consider one-shot lambdas
 877                 let x = expensive in \y z -> E
 878 We want this to have arity 2 if the \y-abstraction is a 1-shot lambda
 879 Hence the ArityType returned by arityType
 880
 881 2.  The state-transformer hack
 882
 883 The one-shot lambda special cause is particularly important/useful for
 884 IO state transformers, where we often get
 885         let x = E in \ s -> ...
 886
 887 and the \s is a real-world state token abstraction.  Such abstractions
 888 are almost invariably 1-shot, so we want to pull the \s out, past the
 889 let x=E, even if E is expensive.  So we treat state-token lambdas as
 890 one-shot even if they aren't really.  The hack is in Id.isOneShotBndr.
 891
 892 3.  Dealing with bottom
 893
 894 Consider also
 895         f = \x -> error "foo"
 896 Here, arity 1 is fine.  But if it is
 897         f = \x -> case x of
 898                         True  -> error "foo"
 899                         False -> \y -> x+y
 900 then we want to get arity 2.  Tecnically, this isn't quite right, because
 901         (f True) `seq` 1
 902 should diverge, but it'll converge if we eta-expand f.  Nevertheless, we
 903 do so; it improves some programs significantly, and increasing convergence
 904 isn't a bad thing.  Hence the ABot/ATop in ArityType.
 905
 906 Actually, the situation is worse.  Consider
 907         f = \x -> case x of
 908                         True  -> \y -> x+y
 909                         False -> \y -> x-y
 910 Can we eta-expand here?  At first the answer looks like "yes of course", but
 911 consider
 912         (f bot) `seq` 1
 913 This should diverge!  But if we eta-expand, it won't.   Again, we ignore this
 914 "problem", because being scrupulous would lose an important transformation for
 915 many programs.
 916
 917
 918 4. Newtypes
 919
 920 Non-recursive newtypes are transparent, and should not get in the way.
 921 We do (currently) eta-expand recursive newtypes too.  So if we have, say
 922
 923         newtype T = MkT ([T] -> Int)
 924
 925 Suppose we have
 926         e = coerce T f
 927 where f has arity 1.  Then: etaExpandArity e = 1;
 928 that is, etaExpandArity looks through the coerce.
 929
 930 When we eta-expand e to arity 1: eta_expand 1 e T
 931 we want to get:                  coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
 932
 933 HOWEVER, note that if you use coerce bogusly you can ge
 934         coerce Int negate
 935 And since negate has arity 2, you might try to eta expand.  But you can't
 936 decopose Int to a function type.   Hence the final case in eta_expand.
 937 -}
 938
 939
 940 exprEtaExpandArity dflags e = arityDepth (arityType dflags e)
 941
 942 -- A limited sort of function type
 943 data ArityType = AFun Bool ArityType    -- True <=> one-shot
 944                | ATop                   -- Know nothing
 945                | ABot                   -- Diverges
 946
 947 arityDepth :: ArityType -> Arity
 948 arityDepth (AFun _ ty) = 1 + arityDepth ty
 949 arityDepth ty          = 0
 950
 951 andArityType ABot           at2           = at2
 952 andArityType ATop           at2           = ATop
 953 andArityType (AFun t1 at1)  (AFun t2 at2) = AFun (t1 && t2) (andArityType at1 at2)
 954 andArityType at1            at2           = andArityType at2 at1
 955
 956 arityType :: DynFlags -> CoreExpr -> ArityType
 957         -- (go1 e) = [b1,..,bn]
 958         -- means expression can be rewritten \x_b1 -> ... \x_bn -> body
 959         -- where bi is True <=> the lambda is one-shot
 960
 961 arityType dflags (Note n e) = arityType dflags e
 962 --      Not needed any more: etaExpand is cleverer
 963 --  | ok_note n = arityType dflags e
 964 --  | otherwise = ATop
 965
 966 arityType dflags (Cast e co) = arityType dflags e
 967
 968 arityType dflags (Var v)
 969   = mk (idArity v) (arg_tys (idType v))
 970   where
 971     mk :: Arity -> [Type] -> ArityType
 972         -- The argument types are only to steer the "state hack"
 973         -- Consider case x of
 974         --              True  -> foo
 975         --              False -> \(s:RealWorld) -> e
 976         -- where foo has arity 1.  Then we want the state hack to
 977         -- apply to foo too, so we can eta expand the case.
 978     mk 0 tys | isBottomingId v                     = ABot
 979              | (ty:tys) <- tys, isStateHackType ty = AFun True ATop
 980              | otherwise                           = ATop
 981     mk n (ty:tys) = AFun (isStateHackType ty) (mk (n-1) tys)
 982     mk n []       = AFun False                (mk (n-1) [])
 983
 984     arg_tys :: Type -> [Type]   -- Ignore for-alls
 985     arg_tys ty
 986         | Just (_, ty')  <- splitForAllTy_maybe ty = arg_tys ty'
 987         | Just (arg,res) <- splitFunTy_maybe ty    = arg : arg_tys res
 988         | otherwise                                = []
 989
 990         -- Lambdas; increase arity
 991 arityType dflags (Lam x e)
 992   | isId x    = AFun (isOneShotBndr x) (arityType dflags e)
 993   | otherwise = arityType dflags e
 994
 995         -- Applications; decrease arity
 996 arityType dflags (App f (Type _)) = arityType dflags f
 997 arityType dflags (App f a)        = case arityType dflags f of
 998                                         AFun one_shot xs | exprIsCheap a -> xs
 999                                         other                            -> ATop
1000
1001         -- Case/Let; keep arity if either the expression is cheap
1002         -- or it's a 1-shot lambda
1003         -- The former is not really right for Haskell
1004         --      f x = case x of { (a,b) -> \y. e }
1005         --  ===>
1006         --      f x y = case x of { (a,b) -> e }
1007         -- The difference is observable using 'seq'
1008 arityType dflags (Case scrut _ _ alts)
1009   = case foldr1 andArityType [arityType dflags rhs | (_,_,rhs) <- alts] of
1010         xs | exprIsCheap scrut          -> xs
1011         xs@(AFun one_shot _) | one_shot -> AFun True ATop
1012         other                           -> ATop
1013
1014 arityType dflags (Let b e)
1015   = case arityType dflags e of
1016         xs                   | cheap_bind b -> xs
1017         xs@(AFun one_shot _) | one_shot     -> AFun True ATop
1018         other                               -> ATop
1019   where
1020     cheap_bind (NonRec b e) = is_cheap (b,e)
1021     cheap_bind (Rec prs)    = all is_cheap prs
1022     is_cheap (b,e) = (dopt Opt_DictsCheap dflags && isDictId b)
1023                    || exprIsCheap e
1024         -- If the experimental -fdicts-cheap flag is on, we eta-expand through
1025         -- dictionary bindings.  This improves arities. Thereby, it also
1026         -- means that full laziness is less prone to floating out the
1027         -- application of a function to its dictionary arguments, which
1028         -- can thereby lose opportunities for fusion.  Example:
1029         --      foo :: Ord a => a -> ...
1030         --      foo = /\a \(d:Ord a). let d' = ...d... in \(x:a). ....
1031         --              -- So foo has arity 1
1032         --
1033         --      f = \x. foo dInt $ bar x
1034         --
1035         -- The (foo DInt) is floated out, and makes ineffective a RULE
1036         --      foo (bar x) = ...
1037         --
1038         -- One could go further and make exprIsCheap reply True to any
1039         -- dictionary-typed expression, but that's more work.
1040
1041 arityType dflags other = ATop
1042
1043 {- NOT NEEDED ANY MORE: etaExpand is cleverer
1044 ok_note InlineMe = False
1045 ok_note other    = True
1046     -- Notice that we do not look through __inline_me__
1047     -- This may seem surprising, but consider
1048     --          f = _inline_me (\x -> e)
1049     -- We DO NOT want to eta expand this to
1050     --          f = \x -> (_inline_me (\x -> e)) x
1051     -- because the _inline_me gets dropped now it is applied,
1052     -- giving just
1053     --          f = \x -> e
1054     -- A Bad Idea
1055 -}
1056 \end{code}
1057
1058
1059 \begin{code}
1060 etaExpand :: Arity              -- Result should have this number of value args
1061           -> [Unique]
1062           -> CoreExpr -> Type   -- Expression and its type
1063           -> CoreExpr
1064 -- (etaExpand n us e ty) returns an expression with
1065 -- the same meaning as 'e', but with arity 'n'.
1066 --
1067 -- Given e' = etaExpand n us e ty
1068 -- We should have
1069 --      ty = exprType e = exprType e'
1070 --
1071 -- Note that SCCs are not treated specially.  If we have
1072 --      etaExpand 2 (\x -> scc "foo" e)
1073 --      = (\xy -> (scc "foo" e) y)
1074 -- So the costs of evaluating 'e' (not 'e y') are attributed to "foo"
1075
1076 etaExpand n us expr ty
1077   | manifestArity expr >= n = expr              -- The no-op case
1078   | otherwise
1079   = eta_expand n us expr ty
1080   where
1081
1082 -- manifestArity sees how many leading value lambdas there are
1083 manifestArity :: CoreExpr -> Arity
1084 manifestArity (Lam v e) | isId v    = 1 + manifestArity e
1085                         | otherwise = manifestArity e
1086 manifestArity (Note _ e)            = manifestArity e
1087 manifestArity (Cast e _)            = manifestArity e
1088 manifestArity e                     = 0
1089
1090 -- etaExpand deals with for-alls. For example:
1091 --              etaExpand 1 E
1092 -- where  E :: forall a. a -> a
1093 -- would return
1094 --      (/\b. \y::a -> E b y)
1095 --
1096 -- It deals with coerces too, though they are now rare
1097 -- so perhaps the extra code isn't worth it
1098
1099 eta_expand n us expr ty
1100   | n == 0 &&
1101     -- The ILX code generator requires eta expansion for type arguments
1102     -- too, but alas the 'n' doesn't tell us how many of them there
1103     -- may be.  So we eagerly eta expand any big lambdas, and just
1104     -- cross our fingers about possible loss of sharing in the ILX case.
1105     -- The Right Thing is probably to make 'arity' include
1106     -- type variables throughout the compiler.  (ToDo.)
1107     not (isForAllTy ty)
1108     -- Saturated, so nothing to do
1109   = expr
1110
1111         -- Short cut for the case where there already
1112         -- is a lambda; no point in gratuitously adding more
1113 eta_expand n us (Lam v body) ty
1114   | isTyVar v
1115   = Lam v (eta_expand n us body (applyTy ty (mkTyVarTy v)))
1116
1117   | otherwise
1118   = Lam v (eta_expand (n-1) us body (funResultTy ty))
1119
1120 -- We used to have a special case that stepped inside Coerces here,
1121 -- thus:  eta_expand n us (Note note@(Coerce _ ty) e) _
1122 --              = Note note (eta_expand n us e ty)
1123 -- BUT this led to an infinite loop
1124 -- Example:     newtype T = MkT (Int -> Int)
1125 --      eta_expand 1 (coerce (Int->Int) e)
1126 --      --> coerce (Int->Int) (eta_expand 1 T e)
1127 --              by the bogus eqn
1128 --      --> coerce (Int->Int) (coerce T
1129 --              (\x::Int -> eta_expand 1 (coerce (Int->Int) e)))
1130 --              by the splitNewType_maybe case below
1131 --      and round we go
1132
1133 eta_expand n us expr ty
1134   = ASSERT2 (exprType expr `coreEqType` ty, ppr (exprType expr) $$ ppr ty)
1135     case splitForAllTy_maybe ty of {
1136           Just (tv,ty') ->
1137
1138               Lam lam_tv (eta_expand n us2 (App expr (Type (mkTyVarTy lam_tv))) (substTyWith [tv] [mkTyVarTy lam_tv] ty'))
1139                   where
1140                     lam_tv = setVarName tv (mkSysTvName uniq FSLIT("etaT"))
1141                         -- Using tv as a base retains its tyvar/covar-ness
1142                     (uniq:us2) = us
1143         ; Nothing ->
1144
1145         case splitFunTy_maybe ty of {
1146           Just (arg_ty, res_ty) -> Lam arg1 (eta_expand (n-1) us2 (App expr (Var arg1)) res_ty)
1147                                 where
1148                                    arg1       = mkSysLocal FSLIT("eta") uniq arg_ty
1149                                    (uniq:us2) = us
1150
1151         ; Nothing ->
1152
1153                 -- Given this:
1154                 --      newtype T = MkT ([T] -> Int)
1155                 -- Consider eta-expanding this
1156                 --      eta_expand 1 e T
1157                 -- We want to get
1158                 --      coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
1159
1160         case splitNewTypeRepCo_maybe ty of {
1161           Just(ty1,co) ->
1162               mkCoerce (mkSymCoercion co) (eta_expand n us (mkCoerce co expr) ty1) ;
1163           Nothing  ->
1164
1165         -- We have an expression of arity > 0, but its type isn't a function
1166         -- This *can* legitmately happen: e.g.  coerce Int (\x. x)
1167         -- Essentially the programmer is playing fast and loose with types
1168         -- (Happy does this a lot).  So we simply decline to eta-expand.
1169         expr
1170         }}}
1171 \end{code}
1172
1173 exprArity is a cheap-and-cheerful version of exprEtaExpandArity.
1174 It tells how many things the expression can be applied to before doing
1175 any work.  It doesn't look inside cases, lets, etc.  The idea is that
1176 exprEtaExpandArity will do the hard work, leaving something that's easy
1177 for exprArity to grapple with.  In particular, Simplify uses exprArity to
1178 compute the ArityInfo for the Id.
1179
1180 Originally I thought that it was enough just to look for top-level lambdas, but
1181 it isn't.  I've seen this
1182
1183         foo = PrelBase.timesInt
1184
1185 We want foo to get arity 2 even though the eta-expander will leave it
1186 unchanged, in the expectation that it'll be inlined.  But occasionally it
1187 isn't, because foo is blacklisted (used in a rule).
1188
1189 Similarly, see the ok_note check in exprEtaExpandArity.  So
1190         f = __inline_me (\x -> e)
1191 won't be eta-expanded.
1192
1193 And in any case it seems more robust to have exprArity be a bit more intelligent.
1194 But note that   (\x y z -> f x y z)
1195 should have arity 3, regardless of f's arity.
1196
1197 \begin{code}
1198 exprArity :: CoreExpr -> Arity
1199 exprArity e = go e
1200             where
1201               go (Var v)                   = idArity v
1202               go (Lam x e) | isId x        = go e + 1
1203                            | otherwise     = go e
1204               go (Note n e)                = go e
1205               go (Cast e _)                = go e
1206               go (App e (Type t))          = go e
1207               go (App f a) | exprIsCheap a = (go f - 1) `max` 0
1208                 -- NB: exprIsCheap a!
1209                 --      f (fac x) does not have arity 2,
1210                 --      even if f has arity 3!
1211                 -- NB: `max 0`!  (\x y -> f x) has arity 2, even if f is
1212                 --               unknown, hence arity 0
1213               go _                         = 0
1214 \end{code}
1215
1216 %************************************************************************
1217 %*                                                                      *
1218 \subsection{Equality}
1219 %*                                                                      *
1220 %************************************************************************
1221
1222 @cheapEqExpr@ is a cheap equality test which bales out fast!
1223         True  => definitely equal
1224         False => may or may not be equal
1225
1226 \begin{code}
1227 cheapEqExpr :: Expr b -> Expr b -> Bool
1228
1229 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1230 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1231 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1232
1233 cheapEqExpr (App f1 a1) (App f2 a2)
1234   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1235
1236 cheapEqExpr _ _ = False
1237
1238 exprIsBig :: Expr b -> Bool
1239 -- Returns True of expressions that are too big to be compared by cheapEqExpr
1240 exprIsBig (Lit _)      = False
1241 exprIsBig (Var v)      = False
1242 exprIsBig (Type t)     = False
1243 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1244 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1245 exprIsBig other        = True
1246 \end{code}
1247
1248
1249 \begin{code}
1250 tcEqExpr :: CoreExpr -> CoreExpr -> Bool
1251 -- Used in rule matching, so does *not* look through
1252 -- newtypes, predicate types; hence tcEqExpr
1253
1254 tcEqExpr e1 e2 = tcEqExprX rn_env e1 e2
1255   where
1256     rn_env = mkRnEnv2 (mkInScopeSet (exprFreeVars e1 `unionVarSet` exprFreeVars e2))
1257
1258 tcEqExprX :: RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1259 tcEqExprX env (Var v1)     (Var v2)     = rnOccL env v1 == rnOccR env v2
1260 tcEqExprX env (Lit lit1)   (Lit lit2)   = lit1 == lit2
1261 tcEqExprX env (App f1 a1)  (App f2 a2)  = tcEqExprX env f1 f2 && tcEqExprX env a1 a2
1262 tcEqExprX env (Lam v1 e1)  (Lam v2 e2)  = tcEqExprX (rnBndr2 env v1 v2) e1 e2
1263 tcEqExprX env (Let (NonRec v1 r1) e1)
1264               (Let (NonRec v2 r2) e2)   = tcEqExprX env r1 r2
1265                                        && tcEqExprX (rnBndr2 env v1 v2) e1 e2
1266 tcEqExprX env (Let (Rec ps1) e1)
1267               (Let (Rec ps2) e2)        =  equalLength ps1 ps2
1268                                         && and (zipWith eq_rhs ps1 ps2)
1269                                         && tcEqExprX env' e1 e2
1270                                      where
1271                                        env' = foldl2 rn_bndr2 env ps2 ps2
1272                                        rn_bndr2 env (b1,_) (b2,_) = rnBndr2 env b1 b2
1273                                        eq_rhs       (_,r1) (_,r2) = tcEqExprX env' r1 r2
1274 tcEqExprX env (Case e1 v1 t1 a1)
1275               (Case e2 v2 t2 a2)     =  tcEqExprX env e1 e2
1276                                      && tcEqTypeX env t1 t2
1277                                      && equalLength a1 a2
1278                                      && and (zipWith (eq_alt env') a1 a2)
1279                                      where
1280                                        env' = rnBndr2 env v1 v2
1281
1282 tcEqExprX env (Note n1 e1) (Note n2 e2) = eq_note env n1 n2 && tcEqExprX env e1 e2
1283 tcEqExprX env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && tcEqExprX env e1 e2
1284 tcEqExprX env (Type t1)    (Type t2)    = tcEqTypeX env t1 t2
1285 tcEqExprX env e1                e2      = False
1286
1287 eq_alt env (c1,vs1,r1) (c2,vs2,r2) = c1==c2 && tcEqExprX (rnBndrs2 env vs1  vs2) r1 r2
1288
1289 eq_note env (SCC cc1)      (SCC cc2)      = cc1 == cc2
1290 eq_note env (CoreNote s1)  (CoreNote s2)  = s1 == s2
1291 eq_note env other1             other2     = False
1292 \end{code}
1293
1294
1295 %************************************************************************
1296 %*                                                                      *
1297 \subsection{The size of an expression}
1298 %*                                                                      *
1299 %************************************************************************
1300
1301 \begin{code}
1302 coreBindsSize :: [CoreBind] -> Int
1303 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1304
1305 exprSize :: CoreExpr -> Int
1306         -- A measure of the size of the expressions
1307         -- It also forces the expression pretty drastically as a side effect
1308 exprSize (Var v)         = v `seq` 1
1309 exprSize (Lit lit)       = lit `seq` 1
1310 exprSize (App f a)       = exprSize f + exprSize a
1311 exprSize (Lam b e)       = varSize b + exprSize e
1312 exprSize (Let b e)       = bindSize b + exprSize e
1313 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1314 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1315 exprSize (Note n e)      = noteSize n + exprSize e
1316 exprSize (Type t)        = seqType t `seq` 1
1317
1318 noteSize (SCC cc)       = cc `seq` 1
1319 noteSize InlineMe       = 1
1320 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1321
1322 varSize :: Var -> Int
1323 varSize b  | isTyVar b = 1
1324            | otherwise = seqType (idType b)             `seq`
1325                          megaSeqIdInfo (idInfo b)       `seq`
1326                          1
1327
1328 varsSize = foldr ((+) . varSize) 0
1329
1330 bindSize (NonRec b e) = varSize b + exprSize e
1331 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1332
1333 pairSize (b,e) = varSize b + exprSize e
1334
1335 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1336 \end{code}
1337
1338
1339 %************************************************************************
1340 %*                                                                      *
1341 \subsection{Hashing}
1342 %*                                                                      *
1343 %************************************************************************
1344
1345 \begin{code}
1346 hashExpr :: CoreExpr -> Int
1347 -- Two expressions that hash to the same Int may be equal (but may not be)
1348 -- Two expressions that hash to the different Ints are definitely unequal
1349 --
1350 -- But "unequal" here means "not identical"; two alpha-equivalent
1351 -- expressions may hash to the different Ints
1352 --
1353 -- The emphasis is on a crude, fast hash, rather than on high precision
1354 --
1355 -- We must be careful that \x.x and \y.y map to the same hash code,
1356 -- (at least if we want the above invariant to be true)
1357
1358 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1359              -- UniqFM doesn't like negative Ints
1360
1361 type HashEnv = (Int, VarEnv Int)        -- Hash code for bound variables
1362
1363 hash_expr :: HashEnv -> CoreExpr -> Word32
1364 -- Word32, because we're expecting overflows here, and overflowing
1365 -- signed types just isn't cool.  In C it's even undefined.
1366 hash_expr env (Note _ e)              = hash_expr env e
1367 hash_expr env (Cast e co)             = hash_expr env e
1368 hash_expr env (Var v)                 = hashVar env v
1369 hash_expr env (Lit lit)               = fromIntegral (hashLiteral lit)
1370 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1371 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1372 hash_expr env (Let (Rec ((b,r):_)) e) = hash_expr (extend_env env b) e
1373 hash_expr env (Case e _ _ _)          = hash_expr env e
1374 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1375 hash_expr env (Type t)                = WARN(True, text "hash_expr: type") 1
1376 -- Shouldn't happen.  Better to use WARN than trace, because trace
1377 -- prevents the CPR optimisation kicking in for hash_expr.
1378
1379 fast_hash_expr env (Var v)      = hashVar env v
1380 fast_hash_expr env (Type t)     = fast_hash_type env t
1381 fast_hash_expr env (Lit lit)    = fromIntegral (hashLiteral lit)
1382 fast_hash_expr env (Cast e co)  = fast_hash_expr env e
1383 fast_hash_expr env (Note n e)   = fast_hash_expr env e
1384 fast_hash_expr env (App f a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1385 fast_hash_expr env other        = 1
1386
1387 fast_hash_type :: HashEnv -> Type -> Word32
1388 fast_hash_type env ty
1389   | Just tv <- getTyVar_maybe ty          = hashVar env tv
1390   | Just (tc,_) <- splitTyConApp_maybe ty
1391                               = fromIntegral (hashName (tyConName tc))
1392   | otherwise                             = 1
1393
1394 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1395 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1396
1397 hashVar :: HashEnv -> Var -> Word32
1398 hashVar (_,env) v
1399  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1400 \end{code}
1401
1402 %************************************************************************
1403 %*                                                                      *
1404 \subsection{Determining non-updatable right-hand-sides}
1405 %*                                                                      *
1406 %************************************************************************
1407
1408 Top-level constructor applications can usually be allocated
1409 statically, but they can't if the constructor, or any of the
1410 arguments, come from another DLL (because we can't refer to static
1411 labels in other DLLs).
1412
1413 If this happens we simply make the RHS into an updatable thunk,
1414 and 'exectute' it rather than allocating it statically.
1415
1416 \begin{code}
1417 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1418 -- This function is called only on *top-level* right-hand sides
1419 -- Returns True if the RHS can be allocated statically, with
1420 -- no thunks involved at all.
1421 --
1422 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1423 -- refers to, CAFs; and (ii) in CoreToStg to decide whether to put an
1424 -- update flag on it.
1425 --
1426 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1427 --      (a) a value lambda
1428 --      (b) a saturated constructor application with static args
1429 --
1430 -- BUT watch out for
1431 --  (i) Any cross-DLL references kill static-ness completely
1432 --      because they must be 'executed' not statically allocated
1433 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1434 --      this is not necessary)
1435 --
1436 -- (ii) We treat partial applications as redexes, because in fact we
1437 --      make a thunk for them that runs and builds a PAP
1438 --      at run-time.  The only appliations that are treated as
1439 --      static are *saturated* applications of constructors.
1440
1441 -- We used to try to be clever with nested structures like this:
1442 --              ys = (:) w ((:) w [])
1443 -- on the grounds that CorePrep will flatten ANF-ise it later.
1444 -- But supporting this special case made the function much more
1445 -- complicated, because the special case only applies if there are no
1446 -- enclosing type lambdas:
1447 --              ys = /\ a -> Foo (Baz ([] a))
1448 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1449 --
1450 -- But in fact, even without -O, nested structures at top level are
1451 -- flattened by the simplifier, so we don't need to be super-clever here.
1452 --
1453 -- Examples
1454 --
1455 --      f = \x::Int. x+7        TRUE
1456 --      p = (True,False)        TRUE
1457 --
1458 --      d = (fst p, False)      FALSE because there's a redex inside
1459 --                              (this particular one doesn't happen but...)
1460 --
1461 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1462 --      n = /\a. Nil a                  TRUE
1463 --
1464 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1465 --
1466 --
1467 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1468 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1469 --
1470 --    b) (C x xs), where C is a contructors is updatable if the application is
1471 --         dynamic
1472 --
1473 --    c) don't look through unfolding of f in (f x).
1474 --
1475 -- When opt_RuntimeTypes is on, we keep type lambdas and treat
1476 -- them as making the RHS re-entrant (non-updatable).
1477
1478 rhsIsStatic this_pkg rhs = is_static False rhs
1479   where
1480   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1481           -> CoreExpr -> Bool
1482
1483   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1484
1485   is_static in_arg (Note (SCC _) e) = False
1486   is_static in_arg (Note _ e)       = is_static in_arg e
1487   is_static in_arg (Cast e co)      = is_static in_arg e
1488
1489   is_static in_arg (Lit lit)
1490     = case lit of
1491         MachLabel _ _ -> False
1492         other         -> True
1493         -- A MachLabel (foreign import "&foo") in an argument
1494         -- prevents a constructor application from being static.  The
1495         -- reason is that it might give rise to unresolvable symbols
1496         -- in the object file: under Linux, references to "weak"
1497         -- symbols from the data segment give rise to "unresolvable
1498         -- relocation" errors at link time This might be due to a bug
1499         -- in the linker, but we'll work around it here anyway.
1500         -- SDM 24/2/2004
1501
1502   is_static in_arg other_expr = go other_expr 0
1503    where
1504     go (Var f) n_val_args
1505 #if mingw32_TARGET_OS
1506         | not (isDllName this_pkg (idName f))
1507 #endif
1508         =  saturated_data_con f n_val_args
1509         || (in_arg && n_val_args == 0)
1510                 -- A naked un-applied variable is *not* deemed a static RHS
1511                 -- E.g.         f = g
1512                 -- Reason: better to update so that the indirection gets shorted
1513                 --         out, and the true value will be seen
1514                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1515                 --     are always updatable.  If you do so, make sure that non-updatable
1516                 --     ones have enough space for their static link field!
1517
1518     go (App f a) n_val_args
1519         | isTypeArg a                    = go f n_val_args
1520         | not in_arg && is_static True a = go f (n_val_args + 1)
1521         -- The (not in_arg) checks that we aren't in a constructor argument;
1522         -- if we are, we don't allow (value) applications of any sort
1523         --
1524         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1525         --   x = D# (1.0## /## 2.0##)
1526         -- can't float because /## can fail.
1527
1528     go (Note (SCC _) f) n_val_args = False
1529     go (Note _ f) n_val_args       = go f n_val_args
1530     go (Cast e co) n_val_args      = go e n_val_args
1531
1532     go other n_val_args = False
1533
1534     saturated_data_con f n_val_args
1535         = case isDataConWorkId_maybe f of
1536             Just dc -> n_val_args == dataConRepArity dc
1537             Nothing -> False
1538 \end{code}