compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[CoreUtils]{Utility functions on @Core@ syntax}
   5
   6 \begin{code}
   7 module CoreUtils (
   8         -- Construction
   9         mkInlineMe, mkSCC, mkCoerce, mkCoerce2,
  10         bindNonRec, needsCaseBinding,
  11         mkIfThenElse, mkAltExpr, mkPiType, mkPiTypes,
  12
  13         -- Taking expressions apart
  14         findDefault, findAlt, isDefaultAlt, mergeAlts,
  15
  16         -- Properties of expressions
  17         exprType, coreAltType,
  18         exprIsDupable, exprIsTrivial, exprIsCheap,
  19         exprIsHNF,exprOkForSpeculation, exprIsBig,
  20         exprIsConApp_maybe, exprIsBottom,
  21         rhsIsStatic,
  22
  23         -- Arity and eta expansion
  24         manifestArity, exprArity,
  25         exprEtaExpandArity, etaExpand,
  26
  27         -- Size
  28         coreBindsSize,
  29
  30         -- Hashing
  31         hashExpr,
  32
  33         -- Equality
  34         cheapEqExpr, tcEqExpr, tcEqExprX, applyTypeToArgs, applyTypeToArg
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39
  40 import GLAEXTS          -- For `xori`
  41
  42 import CoreSyn
  43 import CoreFVs          ( exprFreeVars )
  44 import PprCore          ( pprCoreExpr )
  45 import Var              ( Var )
  46 import VarSet           ( unionVarSet )
  47 import VarEnv
  48 import Name             ( hashName )
  49 import Packages         ( HomeModules )
  50 #if mingw32_TARGET_OS
  51 import Packages         ( isDllName )
  52 #endif
  53 import Literal          ( hashLiteral, literalType, litIsDupable,
  54                           litIsTrivial, isZeroLit, Literal( MachLabel ) )
  55 import DataCon          ( DataCon, dataConRepArity, dataConInstArgTys,
  56                           isVanillaDataCon, dataConTyCon )
  57 import PrimOp           ( PrimOp(..), primOpOkForSpeculation, primOpIsCheap )
  58 import Id               ( Id, idType, globalIdDetails, idNewStrictness,
  59                           mkWildId, idArity, idName, idUnfolding, idInfo,
  60                           isOneShotBndr, isStateHackType, isDataConWorkId_maybe, mkSysLocal,
  61                           isDataConWorkId, isBottomingId
  62                         )
  63 import IdInfo           ( GlobalIdDetails(..), megaSeqIdInfo )
  64 import NewDemand        ( appIsBottom )
  65 import Type             ( Type, mkFunTy, mkForAllTy, splitFunTy_maybe,
  66                           splitFunTy, tcEqTypeX,
  67                           applyTys, isUnLiftedType, seqType, mkTyVarTy,
  68                           splitForAllTy_maybe, isForAllTy, splitRecNewType_maybe,
  69                           splitTyConApp_maybe, coreEqType, funResultTy, applyTy
  70                         )
  71 import TyCon            ( tyConArity )
  72 import TysWiredIn       ( boolTy, trueDataCon, falseDataCon )
  73 import CostCentre       ( CostCentre )
  74 import BasicTypes       ( Arity )
  75 import Unique           ( Unique )
  76 import Outputable
  77 import TysPrim          ( alphaTy )     -- Debugging only
  78 import Util             ( equalLength, lengthAtLeast, foldl2 )
  79 \end{code}
  80
  81
  82 %************************************************************************
  83 %*                                                                      *
  84 \subsection{Find the type of a Core atom/expression}
  85 %*                                                                      *
  86 %************************************************************************
  87
  88 \begin{code}
  89 exprType :: CoreExpr -> Type
  90
  91 exprType (Var var)              = idType var
  92 exprType (Lit lit)              = literalType lit
  93 exprType (Let _ body)           = exprType body
  94 exprType (Case _ _ ty alts)     = ty
  95 exprType (Note (Coerce ty _) e) = ty  --  **! should take usage from e
  96 exprType (Note other_note e)    = exprType e
  97 exprType (Lam binder expr)      = mkPiType binder (exprType expr)
  98 exprType e@(App _ _)
  99   = case collectArgs e of
 100         (fun, args) -> applyTypeToArgs e (exprType fun) args
 101
 102 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 103
 104 coreAltType :: CoreAlt -> Type
 105 coreAltType (_,_,rhs) = exprType rhs
 106 \end{code}
 107
 108 @mkPiType@ makes a (->) type or a forall type, depending on whether
 109 it is given a type variable or a term variable.  We cleverly use the
 110 lbvarinfo field to figure out the right annotation for the arrove in
 111 case of a term variable.
 112
 113 \begin{code}
 114 mkPiType  :: Var   -> Type -> Type      -- The more polymorphic version
 115 mkPiTypes :: [Var] -> Type -> Type      --    doesn't work...
 116
 117 mkPiTypes vs ty = foldr mkPiType ty vs
 118
 119 mkPiType v ty
 120    | isId v    = mkFunTy (idType v) ty
 121    | otherwise = mkForAllTy v ty
 122 \end{code}
 123
 124 \begin{code}
 125 applyTypeToArg :: Type -> CoreExpr -> Type
 126 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 127 applyTypeToArg fun_ty other_arg     = funResultTy fun_ty
 128
 129 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 130 -- A more efficient version of applyTypeToArg
 131 -- when we have several args
 132 -- The first argument is just for debugging
 133 applyTypeToArgs e op_ty [] = op_ty
 134
 135 applyTypeToArgs e op_ty (Type ty : args)
 136   =     -- Accumulate type arguments so we can instantiate all at once
 137     go [ty] args
 138   where
 139     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 140     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 141                                 where
 142                                   op_ty' = applyTys op_ty (reverse rev_tys)
 143
 144 applyTypeToArgs e op_ty (other_arg : args)
 145   = case (splitFunTy_maybe op_ty) of
 146         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 147         Nothing -> pprPanic "applyTypeToArgs" (pprCoreExpr e)
 148 \end{code}
 149
 150
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{Attaching notes}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 mkNote removes redundant coercions, and SCCs where possible
 159
 160 \begin{code}
 161 #ifdef UNUSED
 162 mkNote :: Note -> CoreExpr -> CoreExpr
 163 mkNote (Coerce to_ty from_ty) expr = mkCoerce2 to_ty from_ty expr
 164 mkNote (SCC cc) expr               = mkSCC cc expr
 165 mkNote InlineMe expr               = mkInlineMe expr
 166 mkNote note     expr               = Note note expr
 167 #endif
 168 \end{code}
 169
 170 Drop trivial InlineMe's.  This is somewhat important, because if we have an unfolding
 171 that looks like (Note InlineMe (Var v)), the InlineMe doesn't go away because it may
 172 not be *applied* to anything.
 173
 174 We don't use exprIsTrivial here, though, because we sometimes generate worker/wrapper
 175 bindings like
 176         fw = ...
 177         f  = inline_me (coerce t fw)
 178 As usual, the inline_me prevents the worker from getting inlined back into the wrapper.
 179 We want the split, so that the coerces can cancel at the call site.
 180
 181 However, we can get left with tiresome type applications.  Notably, consider
 182         f = /\ a -> let t = e in (t, w)
 183 Then lifting the let out of the big lambda gives
 184         t' = /\a -> e
 185         f = /\ a -> let t = inline_me (t' a) in (t, w)
 186 The inline_me is to stop the simplifier inlining t' right back
 187 into t's RHS.  In the next phase we'll substitute for t (since
 188 its rhs is trivial) and *then* we could get rid of the inline_me.
 189 But it hardly seems worth it, so I don't bother.
 190
 191 \begin{code}
 192 mkInlineMe (Var v) = Var v
 193 mkInlineMe e       = Note InlineMe e
 194 \end{code}
 195
 196
 197
 198 \begin{code}
 199 mkCoerce :: Type -> CoreExpr -> CoreExpr
 200 mkCoerce to_ty expr = mkCoerce2 to_ty (exprType expr) expr
 201
 202 mkCoerce2 :: Type -> Type -> CoreExpr -> CoreExpr
 203 mkCoerce2 to_ty from_ty (Note (Coerce to_ty2 from_ty2) expr)
 204   = ASSERT( from_ty `coreEqType` to_ty2 )
 205     mkCoerce2 to_ty from_ty2 expr
 206
 207 mkCoerce2 to_ty from_ty expr
 208   | to_ty `coreEqType` from_ty = expr
 209   | otherwise              = ASSERT( from_ty `coreEqType` exprType expr )
 210                              Note (Coerce to_ty from_ty) expr
 211 \end{code}
 212
 213 \begin{code}
 214 mkSCC :: CostCentre -> Expr b -> Expr b
 215         -- Note: Nested SCC's *are* preserved for the benefit of
 216         --       cost centre stack profiling
 217 mkSCC cc (Lit lit)          = Lit lit
 218 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 219 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 220 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 221 mkSCC cc expr               = Note (SCC cc) expr
 222 \end{code}
 223
 224
 225 %************************************************************************
 226 %*                                                                      *
 227 \subsection{Other expression construction}
 228 %*                                                                      *
 229 %************************************************************************
 230
 231 \begin{code}
 232 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 233 -- (bindNonRec x r b) produces either
 234 --      let x = r in b
 235 -- or
 236 --      case r of x { _DEFAULT_ -> b }
 237 --
 238 -- depending on whether x is unlifted or not
 239 -- It's used by the desugarer to avoid building bindings
 240 -- that give Core Lint a heart attack.  Actually the simplifier
 241 -- deals with them perfectly well.
 242
 243 bindNonRec bndr rhs body
 244   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 245   | otherwise                          = Let (NonRec bndr rhs) body
 246
 247 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 248         -- Make a case expression instead of a let
 249         -- These can arise either from the desugarer,
 250         -- or from beta reductions: (\x.e) (x +# y)
 251 \end{code}
 252
 253 \begin{code}
 254 mkAltExpr :: AltCon -> [CoreBndr] -> [Type] -> CoreExpr
 255         -- This guy constructs the value that the scrutinee must have
 256         -- when you are in one particular branch of a case
 257 mkAltExpr (DataAlt con) args inst_tys
 258   = mkConApp con (map Type inst_tys ++ map varToCoreExpr args)
 259 mkAltExpr (LitAlt lit) [] []
 260   = Lit lit
 261
 262 mkIfThenElse :: CoreExpr -> CoreExpr -> CoreExpr -> CoreExpr
 263 mkIfThenElse guard then_expr else_expr
 264 -- Not going to be refining, so okay to take the type of the "then" clause
 265   = Case guard (mkWildId boolTy) (exprType then_expr)
 266          [ (DataAlt falseDataCon, [], else_expr),       -- Increasing order of tag!
 267            (DataAlt trueDataCon,  [], then_expr) ]
 268 \end{code}
 269
 270
 271 %************************************************************************
 272 %*                                                                      *
 273 \subsection{Taking expressions apart}
 274 %*                                                                      *
 275 %************************************************************************
 276
 277 The default alternative must be first, if it exists at all.
 278 This makes it easy to find, though it makes matching marginally harder.
 279
 280 \begin{code}
 281 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 282 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 283 findDefault alts                        =                     (alts, Nothing)
 284
 285 findAlt :: AltCon -> [CoreAlt] -> CoreAlt
 286 findAlt con alts
 287   = case alts of
 288         (deflt@(DEFAULT,_,_):alts) -> go alts deflt
 289         other                      -> go alts panic_deflt
 290   where
 291     panic_deflt = pprPanic "Missing alternative" (ppr con $$ vcat (map ppr alts))
 292
 293     go []                      deflt = deflt
 294     go (alt@(con1,_,_) : alts) deflt
 295       = case con `cmpAltCon` con1 of
 296           LT -> deflt   -- Missed it already; the alts are in increasing order
 297           EQ -> alt
 298           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 299
 300 isDefaultAlt :: CoreAlt -> Bool
 301 isDefaultAlt (DEFAULT, _, _) = True
 302 isDefaultAlt other           = False
 303
 304 ---------------------------------
 305 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 306 -- Merge preserving order; alternatives in the first arg
 307 -- shadow ones in the second
 308 mergeAlts [] as2 = as2
 309 mergeAlts as1 [] = as1
 310 mergeAlts (a1:as1) (a2:as2)
 311   = case a1 `cmpAlt` a2 of
 312         LT -> a1 : mergeAlts as1      (a2:as2)
 313         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 314         GT -> a2 : mergeAlts (a1:as1) as2
 315 \end{code}
 316
 317
 318 %************************************************************************
 319 %*                                                                      *
 320 \subsection{Figuring out things about expressions}
 321 %*                                                                      *
 322 %************************************************************************
 323
 324 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 325                 duplicate; simple variables and constants, and type
 326                 applications.  Note that primop Ids aren't considered
 327                 trivial unless
 328
 329 @exprIsBottom@  is true of expressions that are guaranteed to diverge
 330
 331
 332 There used to be a gruesome test for (hasNoBinding v) in the
 333 Var case:
 334         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 335 The idea here is that a constructor worker, like $wJust, is
 336 really short for (\x -> $wJust x), becuase $wJust has no binding.
 337 So it should be treated like a lambda.  Ditto unsaturated primops.
 338 But now constructor workers are not "have-no-binding" Ids.  And
 339 completely un-applied primops and foreign-call Ids are sufficiently
 340 rare that I plan to allow them to be duplicated and put up with
 341 saturating them.
 342
 343 SCC notes.  We do not treat (_scc_ "foo" x) as trivial, because
 344   a) it really generates code, (and a heap object when it's
 345      a function arg) to capture the cost centre
 346   b) see the note [SCC-and-exprIsTrivial] in Simplify.simplLazyBind
 347
 348 \begin{code}
 349 exprIsTrivial (Var v)      = True       -- See notes above
 350 exprIsTrivial (Type _)     = True
 351 exprIsTrivial (Lit lit)    = litIsTrivial lit
 352 exprIsTrivial (App e arg)  = not (isRuntimeArg arg) && exprIsTrivial e
 353 exprIsTrivial (Note (SCC _) e) = False          -- See notes above
 354 exprIsTrivial (Note _       e) = exprIsTrivial e
 355 exprIsTrivial (Lam b body) = not (isRuntimeVar b) && exprIsTrivial body
 356 exprIsTrivial other        = False
 357 \end{code}
 358
 359
 360 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 361                 cost in code size.  This will only happen in different case
 362                 branches, so there's no issue about duplicating work.
 363
 364                 That is, exprIsDupable returns True of (f x) even if
 365                 f is very very expensive to call.
 366
 367                 Its only purpose is to avoid fruitless let-binding
 368                 and then inlining of case join points
 369
 370
 371 \begin{code}
 372 exprIsDupable (Type _)          = True
 373 exprIsDupable (Var v)           = True
 374 exprIsDupable (Lit lit)         = litIsDupable lit
 375 exprIsDupable (Note InlineMe e) = True
 376 exprIsDupable (Note _ e)        = exprIsDupable e
 377 exprIsDupable expr
 378   = go expr 0
 379   where
 380     go (Var v)   n_args = True
 381     go (App f a) n_args =  n_args < dupAppSize
 382                         && exprIsDupable a
 383                         && go f (n_args+1)
 384     go other n_args     = False
 385
 386 dupAppSize :: Int
 387 dupAppSize = 4          -- Size of application we are prepared to duplicate
 388 \end{code}
 389
 390 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 391 it is obviously in weak head normal form, or is cheap to get to WHNF.
 392 [Note that that's not the same as exprIsDupable; an expression might be
 393 big, and hence not dupable, but still cheap.]
 394
 395 By ``cheap'' we mean a computation we're willing to:
 396         push inside a lambda, or
 397         inline at more than one place
 398 That might mean it gets evaluated more than once, instead of being
 399 shared.  The main examples of things which aren't WHNF but are
 400 ``cheap'' are:
 401
 402   *     case e of
 403           pi -> ei
 404         (where e, and all the ei are cheap)
 405
 406   *     let x = e in b
 407         (where e and b are cheap)
 408
 409   *     op x1 ... xn
 410         (where op is a cheap primitive operator)
 411
 412   *     error "foo"
 413         (because we are happy to substitute it inside a lambda)
 414
 415 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 416 because sharing will make sure it is only evaluated once.
 417
 418 \begin{code}
 419 exprIsCheap :: CoreExpr -> Bool
 420 exprIsCheap (Lit lit)               = True
 421 exprIsCheap (Type _)                = True
 422 exprIsCheap (Var _)                 = True
 423 exprIsCheap (Note InlineMe e)       = True
 424 exprIsCheap (Note _ e)              = exprIsCheap e
 425 exprIsCheap (Lam x e)               = isRuntimeVar x || exprIsCheap e
 426 exprIsCheap (Case e _ _ alts)       = exprIsCheap e &&
 427                                     and [exprIsCheap rhs | (_,_,rhs) <- alts]
 428         -- Experimentally, treat (case x of ...) as cheap
 429         -- (and case __coerce x etc.)
 430         -- This improves arities of overloaded functions where
 431         -- there is only dictionary selection (no construction) involved
 432 exprIsCheap (Let (NonRec x _) e)
 433       | isUnLiftedType (idType x) = exprIsCheap e
 434       | otherwise                 = False
 435         -- strict lets always have cheap right hand sides, and
 436         -- do no allocation.
 437
 438 exprIsCheap other_expr
 439   = go other_expr 0 True
 440   where
 441     go (Var f) n_args args_cheap
 442         = (idAppIsCheap f n_args && args_cheap)
 443                         -- A constructor, cheap primop, or partial application
 444
 445           || idAppIsBottom f n_args
 446                         -- Application of a function which
 447                         -- always gives bottom; we treat this as cheap
 448                         -- because it certainly doesn't need to be shared!
 449
 450     go (App f a) n_args args_cheap
 451         | not (isRuntimeArg a) = go f n_args      args_cheap
 452         | otherwise            = go f (n_args + 1) (exprIsCheap a && args_cheap)
 453
 454     go other   n_args args_cheap = False
 455
 456 idAppIsCheap :: Id -> Int -> Bool
 457 idAppIsCheap id n_val_args
 458   | n_val_args == 0 = True      -- Just a type application of
 459                                 -- a variable (f t1 t2 t3)
 460                                 -- counts as WHNF
 461   | otherwise
 462   = case globalIdDetails id of
 463         DataConWorkId _ -> True
 464         RecordSelId {}  -> n_val_args == 1      -- I'm experimenting with making record selection
 465         ClassOpId _     -> n_val_args == 1      -- look cheap, so we will substitute it inside a
 466                                                 -- lambda.  Particularly for dictionary field selection.
 467                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 468                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 469
 470         PrimOpId op   -> primOpIsCheap op       -- In principle we should worry about primops
 471                                                 -- that return a type variable, since the result
 472                                                 -- might be applied to something, but I'm not going
 473                                                 -- to bother to check the number of args
 474         other         -> n_val_args < idArity id
 475 \end{code}
 476
 477 exprOkForSpeculation returns True of an expression that it is
 478
 479         * safe to evaluate even if normal order eval might not
 480           evaluate the expression at all, or
 481
 482         * safe *not* to evaluate even if normal order would do so
 483
 484 It returns True iff
 485
 486         the expression guarantees to terminate,
 487         soon,
 488         without raising an exception,
 489         without causing a side effect (e.g. writing a mutable variable)
 490
 491 E.G.
 492         let x = case y# +# 1# of { r# -> I# r# }
 493         in E
 494 ==>
 495         case y# +# 1# of { r# ->
 496         let x = I# r#
 497         in E
 498         }
 499
 500 We can only do this if the (y+1) is ok for speculation: it has no
 501 side effects, and can't diverge or raise an exception.
 502
 503 \begin{code}
 504 exprOkForSpeculation :: CoreExpr -> Bool
 505 exprOkForSpeculation (Lit _)    = True
 506 exprOkForSpeculation (Type _)   = True
 507 exprOkForSpeculation (Var v)    = isUnLiftedType (idType v)
 508 exprOkForSpeculation (Note _ e) = exprOkForSpeculation e
 509 exprOkForSpeculation other_expr
 510   = case collectArgs other_expr of
 511         (Var f, args) -> spec_ok (globalIdDetails f) args
 512         other         -> False
 513
 514   where
 515     spec_ok (DataConWorkId _) args
 516       = True    -- The strictness of the constructor has already
 517                 -- been expressed by its "wrapper", so we don't need
 518                 -- to take the arguments into account
 519
 520     spec_ok (PrimOpId op) args
 521       | isDivOp op,             -- Special case for dividing operations that fail
 522         [arg1, Lit lit] <- args -- only if the divisor is zero
 523       = not (isZeroLit lit) && exprOkForSpeculation arg1
 524                 -- Often there is a literal divisor, and this
 525                 -- can get rid of a thunk in an inner looop
 526
 527       | otherwise
 528       = primOpOkForSpeculation op &&
 529         all exprOkForSpeculation args
 530                                 -- A bit conservative: we don't really need
 531                                 -- to care about lazy arguments, but this is easy
 532
 533     spec_ok other args = False
 534
 535 isDivOp :: PrimOp -> Bool
 536 -- True of dyadic operators that can fail
 537 -- only if the second arg is zero
 538 -- This function probably belongs in PrimOp, or even in
 539 -- an automagically generated file.. but it's such a
 540 -- special case I thought I'd leave it here for now.
 541 isDivOp IntQuotOp        = True
 542 isDivOp IntRemOp         = True
 543 isDivOp WordQuotOp       = True
 544 isDivOp WordRemOp        = True
 545 isDivOp IntegerQuotRemOp = True
 546 isDivOp IntegerDivModOp  = True
 547 isDivOp FloatDivOp       = True
 548 isDivOp DoubleDivOp      = True
 549 isDivOp other            = False
 550 \end{code}
 551
 552
 553 \begin{code}
 554 exprIsBottom :: CoreExpr -> Bool        -- True => definitely bottom
 555 exprIsBottom e = go 0 e
 556                where
 557                 -- n is the number of args
 558                  go n (Note _ e)     = go n e
 559                  go n (Let _ e)      = go n e
 560                  go n (Case e _ _ _) = go 0 e   -- Just check the scrut
 561                  go n (App e _)      = go (n+1) e
 562                  go n (Var v)        = idAppIsBottom v n
 563                  go n (Lit _)        = False
 564                  go n (Lam _ _)      = False
 565                  go n (Type _)       = False
 566
 567 idAppIsBottom :: Id -> Int -> Bool
 568 idAppIsBottom id n_val_args = appIsBottom (idNewStrictness id) n_val_args
 569 \end{code}
 570
 571 @exprIsHNF@ returns true for expressions that are certainly *already*
 572 evaluated to *head* normal form.  This is used to decide whether it's ok
 573 to change
 574
 575         case x of _ -> e   ===>   e
 576
 577 and to decide whether it's safe to discard a `seq`
 578
 579 So, it does *not* treat variables as evaluated, unless they say they are.
 580
 581 But it *does* treat partial applications and constructor applications
 582 as values, even if their arguments are non-trivial, provided the argument
 583 type is lifted;
 584         e.g.  (:) (f x) (map f xs)      is a value
 585               map (...redex...)         is a value
 586 Because `seq` on such things completes immediately
 587
 588 For unlifted argument types, we have to be careful:
 589                 C (f x :: Int#)
 590 Suppose (f x) diverges; then C (f x) is not a value.  True, but
 591 this form is illegal (see the invariants in CoreSyn).  Args of unboxed
 592 type must be ok-for-speculation (or trivial).
 593
 594 \begin{code}
 595 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 596 exprIsHNF (Var v)       -- NB: There are no value args at this point
 597   =  isDataConWorkId v  -- Catches nullary constructors,
 598                         --      so that [] and () are values, for example
 599   || idArity v > 0      -- Catches (e.g.) primops that don't have unfoldings
 600   || isEvaldUnfolding (idUnfolding v)
 601         -- Check the thing's unfolding; it might be bound to a value
 602         -- A worry: what if an Id's unfolding is just itself:
 603         -- then we could get an infinite loop...
 604
 605 exprIsHNF (Lit l)            = True
 606 exprIsHNF (Type ty)          = True     -- Types are honorary Values;
 607                                         -- we don't mind copying them
 608 exprIsHNF (Lam b e)          = isRuntimeVar b || exprIsHNF e
 609 exprIsHNF (Note _ e)         = exprIsHNF e
 610 exprIsHNF (App e (Type _)) = exprIsHNF e
 611 exprIsHNF (App e a)        = app_is_value e [a]
 612 exprIsHNF other      = False
 613
 614 -- There is at least one value argument
 615 app_is_value (Var fun) args
 616   |  isDataConWorkId fun                        -- Constructor apps are values
 617   || idArity fun > valArgCount args     -- Under-applied function
 618   = check_args (idType fun) args
 619 app_is_value (App f a) as = app_is_value f (a:as)
 620 app_is_value other     as = False
 621
 622         -- 'check_args' checks that unlifted-type args
 623         -- are in fact guaranteed non-divergent
 624 check_args fun_ty []              = True
 625 check_args fun_ty (Type _ : args) = case splitForAllTy_maybe fun_ty of
 626                                       Just (_, ty) -> check_args ty args
 627 check_args fun_ty (arg : args)
 628   | isUnLiftedType arg_ty = exprOkForSpeculation arg
 629   | otherwise             = check_args res_ty args
 630   where
 631     (arg_ty, res_ty) = splitFunTy fun_ty
 632 \end{code}
 633
 634 \begin{code}
 635 exprIsConApp_maybe :: CoreExpr -> Maybe (DataCon, [CoreExpr])
 636 exprIsConApp_maybe (Note (Coerce to_ty from_ty) expr)
 637   =     -- Maybe this is over the top, but here we try to turn
 638         --      coerce (S,T) ( x, y )
 639         -- effectively into
 640         --      ( coerce S x, coerce T y )
 641         -- This happens in anger in PrelArrExts which has a coerce
 642         --      case coerce memcpy a b of
 643         --        (# r, s #) -> ...
 644         -- where the memcpy is in the IO monad, but the call is in
 645         -- the (ST s) monad
 646     case exprIsConApp_maybe expr of {
 647         Nothing           -> Nothing ;
 648         Just (dc, args)   ->
 649
 650     case splitTyConApp_maybe to_ty of {
 651         Nothing -> Nothing ;
 652         Just (tc, tc_arg_tys) | tc /= dataConTyCon dc     -> Nothing
 653                               | not (isVanillaDataCon dc) -> Nothing
 654                               | otherwise                 ->
 655                 -- Type constructor must match
 656                 -- We knock out existentials to keep matters simple(r)
 657     let
 658         arity            = tyConArity tc
 659         val_args         = drop arity args
 660         to_arg_tys       = dataConInstArgTys dc tc_arg_tys
 661         mk_coerce ty arg = mkCoerce ty arg
 662         new_val_args     = zipWith mk_coerce to_arg_tys val_args
 663     in
 664     ASSERT( all isTypeArg (take arity args) )
 665     ASSERT( equalLength val_args to_arg_tys )
 666     Just (dc, map Type tc_arg_tys ++ new_val_args)
 667     }}
 668
 669 exprIsConApp_maybe (Note _ expr)
 670   = exprIsConApp_maybe expr
 671     -- We ignore InlineMe notes in case we have
 672     --  x = __inline_me__ (a,b)
 673     -- All part of making sure that INLINE pragmas never hurt
 674     -- Marcin tripped on this one when making dictionaries more inlinable
 675     --
 676     -- In fact, we ignore all notes.  For example,
 677     --          case _scc_ "foo" (C a b) of
 678     --                  C a b -> e
 679     -- should be optimised away, but it will be only if we look
 680     -- through the SCC note.
 681
 682 exprIsConApp_maybe expr = analyse (collectArgs expr)
 683   where
 684     analyse (Var fun, args)
 685         | Just con <- isDataConWorkId_maybe fun,
 686           args `lengthAtLeast` dataConRepArity con
 687                 -- Might be > because the arity excludes type args
 688         = Just (con,args)
 689
 690         -- Look through unfoldings, but only cheap ones, because
 691         -- we are effectively duplicating the unfolding
 692     analyse (Var fun, [])
 693         | let unf = idUnfolding fun,
 694           isCheapUnfolding unf
 695         = exprIsConApp_maybe (unfoldingTemplate unf)
 696
 697     analyse other = Nothing
 698 \end{code}
 699
 700
 701
 702 %************************************************************************
 703 %*                                                                      *
 704 \subsection{Eta reduction and expansion}
 705 %*                                                                      *
 706 %************************************************************************
 707
 708 \begin{code}
 709 exprEtaExpandArity :: CoreExpr -> Arity
 710 {- The Arity returned is the number of value args the
 711    thing can be applied to without doing much work
 712
 713 exprEtaExpandArity is used when eta expanding
 714         e  ==>  \xy -> e x y
 715
 716 It returns 1 (or more) to:
 717         case x of p -> \s -> ...
 718 because for I/O ish things we really want to get that \s to the top.
 719 We are prepared to evaluate x each time round the loop in order to get that
 720
 721 It's all a bit more subtle than it looks:
 722
 723 1.  One-shot lambdas
 724
 725 Consider one-shot lambdas
 726                 let x = expensive in \y z -> E
 727 We want this to have arity 2 if the \y-abstraction is a 1-shot lambda
 728 Hence the ArityType returned by arityType
 729
 730 2.  The state-transformer hack
 731
 732 The one-shot lambda special cause is particularly important/useful for
 733 IO state transformers, where we often get
 734         let x = E in \ s -> ...
 735
 736 and the \s is a real-world state token abstraction.  Such abstractions
 737 are almost invariably 1-shot, so we want to pull the \s out, past the
 738 let x=E, even if E is expensive.  So we treat state-token lambdas as
 739 one-shot even if they aren't really.  The hack is in Id.isOneShotBndr.
 740
 741 3.  Dealing with bottom
 742
 743 Consider also
 744         f = \x -> error "foo"
 745 Here, arity 1 is fine.  But if it is
 746         f = \x -> case x of
 747                         True  -> error "foo"
 748                         False -> \y -> x+y
 749 then we want to get arity 2.  Tecnically, this isn't quite right, because
 750         (f True) `seq` 1
 751 should diverge, but it'll converge if we eta-expand f.  Nevertheless, we
 752 do so; it improves some programs significantly, and increasing convergence
 753 isn't a bad thing.  Hence the ABot/ATop in ArityType.
 754
 755 Actually, the situation is worse.  Consider
 756         f = \x -> case x of
 757                         True  -> \y -> x+y
 758                         False -> \y -> x-y
 759 Can we eta-expand here?  At first the answer looks like "yes of course", but
 760 consider
 761         (f bot) `seq` 1
 762 This should diverge!  But if we eta-expand, it won't.   Again, we ignore this
 763 "problem", because being scrupulous would lose an important transformation for
 764 many programs.
 765
 766
 767 4. Newtypes
 768
 769 Non-recursive newtypes are transparent, and should not get in the way.
 770 We do (currently) eta-expand recursive newtypes too.  So if we have, say
 771
 772         newtype T = MkT ([T] -> Int)
 773
 774 Suppose we have
 775         e = coerce T f
 776 where f has arity 1.  Then: etaExpandArity e = 1;
 777 that is, etaExpandArity looks through the coerce.
 778
 779 When we eta-expand e to arity 1: eta_expand 1 e T
 780 we want to get:                  coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
 781
 782 HOWEVER, note that if you use coerce bogusly you can ge
 783         coerce Int negate
 784 And since negate has arity 2, you might try to eta expand.  But you can't
 785 decopose Int to a function type.   Hence the final case in eta_expand.
 786 -}
 787
 788
 789 exprEtaExpandArity e = arityDepth (arityType e)
 790
 791 -- A limited sort of function type
 792 data ArityType = AFun Bool ArityType    -- True <=> one-shot
 793                | ATop                   -- Know nothing
 794                | ABot                   -- Diverges
 795
 796 arityDepth :: ArityType -> Arity
 797 arityDepth (AFun _ ty) = 1 + arityDepth ty
 798 arityDepth ty          = 0
 799
 800 andArityType ABot           at2           = at2
 801 andArityType ATop           at2           = ATop
 802 andArityType (AFun t1 at1)  (AFun t2 at2) = AFun (t1 && t2) (andArityType at1 at2)
 803 andArityType at1            at2           = andArityType at2 at1
 804
 805 arityType :: CoreExpr -> ArityType
 806         -- (go1 e) = [b1,..,bn]
 807         -- means expression can be rewritten \x_b1 -> ... \x_bn -> body
 808         -- where bi is True <=> the lambda is one-shot
 809
 810 arityType (Note n e) = arityType e
 811 --      Not needed any more: etaExpand is cleverer
 812 --  | ok_note n = arityType e
 813 --  | otherwise = ATop
 814
 815 arityType (Var v)
 816   = mk (idArity v) (arg_tys (idType v))
 817   where
 818     mk :: Arity -> [Type] -> ArityType
 819         -- The argument types are only to steer the "state hack"
 820         -- Consider case x of
 821         --              True  -> foo
 822         --              False -> \(s:RealWorld) -> e
 823         -- where foo has arity 1.  Then we want the state hack to
 824         -- apply to foo too, so we can eta expand the case.
 825     mk 0 tys | isBottomingId v  = ABot
 826              | otherwise        = ATop
 827     mk n (ty:tys) = AFun (isStateHackType ty) (mk (n-1) tys)
 828     mk n []       = AFun False                (mk (n-1) [])
 829
 830     arg_tys :: Type -> [Type]   -- Ignore for-alls
 831     arg_tys ty
 832         | Just (_, ty')  <- splitForAllTy_maybe ty = arg_tys ty'
 833         | Just (arg,res) <- splitFunTy_maybe ty    = arg : arg_tys res
 834         | otherwise                                = []
 835
 836         -- Lambdas; increase arity
 837 arityType (Lam x e) | isId x    = AFun (isOneShotBndr x) (arityType e)
 838                     | otherwise = arityType e
 839
 840         -- Applications; decrease arity
 841 arityType (App f (Type _)) = arityType f
 842 arityType (App f a)        = case arityType f of
 843                                 AFun one_shot xs | exprIsCheap a -> xs
 844                                 other                            -> ATop
 845
 846         -- Case/Let; keep arity if either the expression is cheap
 847         -- or it's a 1-shot lambda
 848         -- The former is not really right for Haskell
 849         --      f x = case x of { (a,b) -> \y. e }
 850         --  ===>
 851         --      f x y = case x of { (a,b) -> e }
 852         -- The difference is observable using 'seq'
 853 arityType (Case scrut _ _ alts) = case foldr1 andArityType [arityType rhs | (_,_,rhs) <- alts] of
 854                                   xs@(AFun one_shot _) | one_shot -> xs
 855                                   xs | exprIsCheap scrut          -> xs
 856                                      | otherwise                  -> ATop
 857
 858 arityType (Let b e) = case arityType e of
 859                         xs@(AFun one_shot _) | one_shot                       -> xs
 860                         xs                   | all exprIsCheap (rhssOfBind b) -> xs
 861                                              | otherwise                      -> ATop
 862
 863 arityType other = ATop
 864
 865 {- NOT NEEDED ANY MORE: etaExpand is cleverer
 866 ok_note InlineMe = False
 867 ok_note other    = True
 868     -- Notice that we do not look through __inline_me__
 869     -- This may seem surprising, but consider
 870     --          f = _inline_me (\x -> e)
 871     -- We DO NOT want to eta expand this to
 872     --          f = \x -> (_inline_me (\x -> e)) x
 873     -- because the _inline_me gets dropped now it is applied,
 874     -- giving just
 875     --          f = \x -> e
 876     -- A Bad Idea
 877 -}
 878 \end{code}
 879
 880
 881 \begin{code}
 882 etaExpand :: Arity              -- Result should have this number of value args
 883           -> [Unique]
 884           -> CoreExpr -> Type   -- Expression and its type
 885           -> CoreExpr
 886 -- (etaExpand n us e ty) returns an expression with
 887 -- the same meaning as 'e', but with arity 'n'.
 888 --
 889 -- Given e' = etaExpand n us e ty
 890 -- We should have
 891 --      ty = exprType e = exprType e'
 892 --
 893 -- Note that SCCs are not treated specially.  If we have
 894 --      etaExpand 2 (\x -> scc "foo" e)
 895 --      = (\xy -> (scc "foo" e) y)
 896 -- So the costs of evaluating 'e' (not 'e y') are attributed to "foo"
 897
 898 etaExpand n us expr ty
 899   | manifestArity expr >= n = expr              -- The no-op case
 900   | otherwise               = eta_expand n us expr ty
 901   where
 902
 903 -- manifestArity sees how many leading value lambdas there are
 904 manifestArity :: CoreExpr -> Arity
 905 manifestArity (Lam v e) | isId v    = 1 + manifestArity e
 906                         | otherwise = manifestArity e
 907 manifestArity (Note _ e)            = manifestArity e
 908 manifestArity e                     = 0
 909
 910 -- etaExpand deals with for-alls. For example:
 911 --              etaExpand 1 E
 912 -- where  E :: forall a. a -> a
 913 -- would return
 914 --      (/\b. \y::a -> E b y)
 915 --
 916 -- It deals with coerces too, though they are now rare
 917 -- so perhaps the extra code isn't worth it
 918
 919 eta_expand n us expr ty
 920   | n == 0 &&
 921     -- The ILX code generator requires eta expansion for type arguments
 922     -- too, but alas the 'n' doesn't tell us how many of them there
 923     -- may be.  So we eagerly eta expand any big lambdas, and just
 924     -- cross our fingers about possible loss of sharing in the ILX case.
 925     -- The Right Thing is probably to make 'arity' include
 926     -- type variables throughout the compiler.  (ToDo.)
 927     not (isForAllTy ty)
 928     -- Saturated, so nothing to do
 929   = expr
 930
 931         -- Short cut for the case where there already
 932         -- is a lambda; no point in gratuitously adding more
 933 eta_expand n us (Lam v body) ty
 934   | isTyVar v
 935   = Lam v (eta_expand n us body (applyTy ty (mkTyVarTy v)))
 936
 937   | otherwise
 938   = Lam v (eta_expand (n-1) us body (funResultTy ty))
 939
 940 -- We used to have a special case that stepped inside Coerces here,
 941 -- thus:  eta_expand n us (Note note@(Coerce _ ty) e) _
 942 --              = Note note (eta_expand n us e ty)
 943 -- BUT this led to an infinite loop
 944 -- Example:     newtype T = MkT (Int -> Int)
 945 --      eta_expand 1 (coerce (Int->Int) e)
 946 --      --> coerce (Int->Int) (eta_expand 1 T e)
 947 --              by the bogus eqn
 948 --      --> coerce (Int->Int) (coerce T
 949 --              (\x::Int -> eta_expand 1 (coerce (Int->Int) e)))
 950 --              by the splitNewType_maybe case below
 951 --      and round we go
 952
 953 eta_expand n us expr ty
 954   = case splitForAllTy_maybe ty of {
 955           Just (tv,ty') -> Lam tv (eta_expand n us (App expr (Type (mkTyVarTy tv))) ty')
 956
 957         ; Nothing ->
 958
 959         case splitFunTy_maybe ty of {
 960           Just (arg_ty, res_ty) -> Lam arg1 (eta_expand (n-1) us2 (App expr (Var arg1)) res_ty)
 961                                 where
 962                                    arg1       = mkSysLocal FSLIT("eta") uniq arg_ty
 963                                    (uniq:us2) = us
 964
 965         ; Nothing ->
 966
 967                 -- Given this:
 968                 --      newtype T = MkT ([T] -> Int)
 969                 -- Consider eta-expanding this
 970                 --      eta_expand 1 e T
 971                 -- We want to get
 972                 --      coerce T (\x::[T] -> (coerce ([T]->Int) e) x)
 973                 -- Only try this for recursive newtypes; the non-recursive kind
 974                 -- are transparent anyway
 975
 976         case splitRecNewType_maybe ty of {
 977           Just ty' -> mkCoerce2 ty ty' (eta_expand n us (mkCoerce2 ty' ty expr) ty') ;
 978           Nothing  ->
 979
 980         -- We have an expression of arity > 0, but its type isn't a function
 981         -- This *can* legitmately happen: e.g.  coerce Int (\x. x)
 982         -- Essentially the programmer is playing fast and loose with types
 983         -- (Happy does this a lot).  So we simply decline to eta-expand.
 984         expr
 985         }}}
 986 \end{code}
 987
 988 exprArity is a cheap-and-cheerful version of exprEtaExpandArity.
 989 It tells how many things the expression can be applied to before doing
 990 any work.  It doesn't look inside cases, lets, etc.  The idea is that
 991 exprEtaExpandArity will do the hard work, leaving something that's easy
 992 for exprArity to grapple with.  In particular, Simplify uses exprArity to
 993 compute the ArityInfo for the Id.
 994
 995 Originally I thought that it was enough just to look for top-level lambdas, but
 996 it isn't.  I've seen this
 997
 998         foo = PrelBase.timesInt
 999
1000 We want foo to get arity 2 even though the eta-expander will leave it
1001 unchanged, in the expectation that it'll be inlined.  But occasionally it
1002 isn't, because foo is blacklisted (used in a rule).
1003
1004 Similarly, see the ok_note check in exprEtaExpandArity.  So
1005         f = __inline_me (\x -> e)
1006 won't be eta-expanded.
1007
1008 And in any case it seems more robust to have exprArity be a bit more intelligent.
1009 But note that   (\x y z -> f x y z)
1010 should have arity 3, regardless of f's arity.
1011
1012 \begin{code}
1013 exprArity :: CoreExpr -> Arity
1014 exprArity e = go e
1015             where
1016               go (Var v)                   = idArity v
1017               go (Lam x e) | isId x        = go e + 1
1018                            | otherwise     = go e
1019               go (Note n e)                = go e
1020               go (App e (Type t))          = go e
1021               go (App f a) | exprIsCheap a = (go f - 1) `max` 0
1022                 -- NB: exprIsCheap a!
1023                 --      f (fac x) does not have arity 2,
1024                 --      even if f has arity 3!
1025                 -- NB: `max 0`!  (\x y -> f x) has arity 2, even if f is
1026                 --               unknown, hence arity 0
1027               go _                         = 0
1028 \end{code}
1029
1030 %************************************************************************
1031 %*                                                                      *
1032 \subsection{Equality}
1033 %*                                                                      *
1034 %************************************************************************
1035
1036 @cheapEqExpr@ is a cheap equality test which bales out fast!
1037         True  => definitely equal
1038         False => may or may not be equal
1039
1040 \begin{code}
1041 cheapEqExpr :: Expr b -> Expr b -> Bool
1042
1043 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1044 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1045 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1046
1047 cheapEqExpr (App f1 a1) (App f2 a2)
1048   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1049
1050 cheapEqExpr _ _ = False
1051
1052 exprIsBig :: Expr b -> Bool
1053 -- Returns True of expressions that are too big to be compared by cheapEqExpr
1054 exprIsBig (Lit _)      = False
1055 exprIsBig (Var v)      = False
1056 exprIsBig (Type t)     = False
1057 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1058 exprIsBig other        = True
1059 \end{code}
1060
1061
1062 \begin{code}
1063 tcEqExpr :: CoreExpr -> CoreExpr -> Bool
1064 -- Used in rule matching, so does *not* look through
1065 -- newtypes, predicate types; hence tcEqExpr
1066
1067 tcEqExpr e1 e2 = tcEqExprX rn_env e1 e2
1068   where
1069     rn_env = mkRnEnv2 (mkInScopeSet (exprFreeVars e1 `unionVarSet` exprFreeVars e2))
1070
1071 tcEqExprX :: RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1072 tcEqExprX env (Var v1)     (Var v2)     = rnOccL env v1 == rnOccR env v2
1073 tcEqExprX env (Lit lit1)   (Lit lit2)   = lit1 == lit2
1074 tcEqExprX env (App f1 a1)  (App f2 a2)  = tcEqExprX env f1 f2 && tcEqExprX env a1 a2
1075 tcEqExprX env (Lam v1 e1)  (Lam v2 e2)  = tcEqExprX (rnBndr2 env v1 v2) e1 e2
1076 tcEqExprX env (Let (NonRec v1 r1) e1)
1077               (Let (NonRec v2 r2) e2)   = tcEqExprX env r1 r2
1078                                        && tcEqExprX (rnBndr2 env v1 v2) e1 e2
1079 tcEqExprX env (Let (Rec ps1) e1)
1080               (Let (Rec ps2) e2)        =  equalLength ps1 ps2
1081                                         && and (zipWith eq_rhs ps1 ps2)
1082                                         && tcEqExprX env' e1 e2
1083                                      where
1084                                        env' = foldl2 rn_bndr2 env ps2 ps2
1085                                        rn_bndr2 env (b1,_) (b2,_) = rnBndr2 env b1 b2
1086                                        eq_rhs       (_,r1) (_,r2) = tcEqExprX env' r1 r2
1087 tcEqExprX env (Case e1 v1 t1 a1)
1088               (Case e2 v2 t2 a2)     =  tcEqExprX env e1 e2
1089                                      && tcEqTypeX env t1 t2
1090                                      && equalLength a1 a2
1091                                      && and (zipWith (eq_alt env') a1 a2)
1092                                      where
1093                                        env' = rnBndr2 env v1 v2
1094
1095 tcEqExprX env (Note n1 e1) (Note n2 e2) = eq_note env n1 n2 && tcEqExprX env e1 e2
1096 tcEqExprX env (Type t1)    (Type t2)    = tcEqTypeX env t1 t2
1097 tcEqExprX env e1                e2      = False
1098
1099 eq_alt env (c1,vs1,r1) (c2,vs2,r2) = c1==c2 && tcEqExprX (rnBndrs2 env vs1  vs2) r1 r2
1100
1101 eq_note env (SCC cc1)      (SCC cc2)      = cc1 == cc2
1102 eq_note env (Coerce t1 f1) (Coerce t2 f2) = tcEqTypeX env t1 t2 && tcEqTypeX env f1 f2
1103 eq_note env (CoreNote s1)  (CoreNote s2)  = s1 == s2
1104 eq_note env other1             other2     = False
1105 \end{code}
1106
1107
1108 %************************************************************************
1109 %*                                                                      *
1110 \subsection{The size of an expression}
1111 %*                                                                      *
1112 %************************************************************************
1113
1114 \begin{code}
1115 coreBindsSize :: [CoreBind] -> Int
1116 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1117
1118 exprSize :: CoreExpr -> Int
1119         -- A measure of the size of the expressions
1120         -- It also forces the expression pretty drastically as a side effect
1121 exprSize (Var v)         = v `seq` 1
1122 exprSize (Lit lit)       = lit `seq` 1
1123 exprSize (App f a)       = exprSize f + exprSize a
1124 exprSize (Lam b e)       = varSize b + exprSize e
1125 exprSize (Let b e)       = bindSize b + exprSize e
1126 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1127 exprSize (Note n e)      = noteSize n + exprSize e
1128 exprSize (Type t)        = seqType t `seq` 1
1129
1130 noteSize (SCC cc)       = cc `seq` 1
1131 noteSize (Coerce t1 t2) = seqType t1 `seq` seqType t2 `seq` 1
1132 noteSize InlineMe       = 1
1133 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1134
1135 varSize :: Var -> Int
1136 varSize b  | isTyVar b = 1
1137            | otherwise = seqType (idType b)             `seq`
1138                          megaSeqIdInfo (idInfo b)       `seq`
1139                          1
1140
1141 varsSize = foldr ((+) . varSize) 0
1142
1143 bindSize (NonRec b e) = varSize b + exprSize e
1144 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1145
1146 pairSize (b,e) = varSize b + exprSize e
1147
1148 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1149 \end{code}
1150
1151
1152 %************************************************************************
1153 %*                                                                      *
1154 \subsection{Hashing}
1155 %*                                                                      *
1156 %************************************************************************
1157
1158 \begin{code}
1159 hashExpr :: CoreExpr -> Int
1160 hashExpr e | hash < 0  = 77     -- Just in case we hit -maxInt
1161            | otherwise = hash
1162            where
1163              hash = abs (hash_expr e)   -- Negative numbers kill UniqFM
1164
1165 hash_expr (Note _ e)              = hash_expr e
1166 hash_expr (Let (NonRec b r) e)    = hashId b
1167 hash_expr (Let (Rec ((b,r):_)) e) = hashId b
1168 hash_expr (Case _ b _ _)          = hashId b
1169 hash_expr (App f e)               = hash_expr f * fast_hash_expr e
1170 hash_expr (Var v)                 = hashId v
1171 hash_expr (Lit lit)               = hashLiteral lit
1172 hash_expr (Lam b _)               = hashId b
1173 hash_expr (Type t)                = trace "hash_expr: type" 1           -- Shouldn't happen
1174
1175 fast_hash_expr (Var v)          = hashId v
1176 fast_hash_expr (Lit lit)        = hashLiteral lit
1177 fast_hash_expr (App f (Type _)) = fast_hash_expr f
1178 fast_hash_expr (App f a)        = fast_hash_expr a
1179 fast_hash_expr (Lam b _)        = hashId b
1180 fast_hash_expr other            = 1
1181
1182 hashId :: Id -> Int
1183 hashId id = hashName (idName id)
1184 \end{code}
1185
1186 %************************************************************************
1187 %*                                                                      *
1188 \subsection{Determining non-updatable right-hand-sides}
1189 %*                                                                      *
1190 %************************************************************************
1191
1192 Top-level constructor applications can usually be allocated
1193 statically, but they can't if the constructor, or any of the
1194 arguments, come from another DLL (because we can't refer to static
1195 labels in other DLLs).
1196
1197 If this happens we simply make the RHS into an updatable thunk,
1198 and 'exectute' it rather than allocating it statically.
1199
1200 \begin{code}
1201 rhsIsStatic :: HomeModules -> CoreExpr -> Bool
1202 -- This function is called only on *top-level* right-hand sides
1203 -- Returns True if the RHS can be allocated statically, with
1204 -- no thunks involved at all.
1205 --
1206 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1207 -- refers to, CAFs; and (ii) in CoreToStg to decide whether to put an
1208 -- update flag on it.
1209 --
1210 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1211 --      (a) a value lambda
1212 --      (b) a saturated constructor application with static args
1213 --
1214 -- BUT watch out for
1215 --  (i) Any cross-DLL references kill static-ness completely
1216 --      because they must be 'executed' not statically allocated
1217 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1218 --      this is not necessary)
1219 --
1220 -- (ii) We treat partial applications as redexes, because in fact we
1221 --      make a thunk for them that runs and builds a PAP
1222 --      at run-time.  The only appliations that are treated as
1223 --      static are *saturated* applications of constructors.
1224
1225 -- We used to try to be clever with nested structures like this:
1226 --              ys = (:) w ((:) w [])
1227 -- on the grounds that CorePrep will flatten ANF-ise it later.
1228 -- But supporting this special case made the function much more
1229 -- complicated, because the special case only applies if there are no
1230 -- enclosing type lambdas:
1231 --              ys = /\ a -> Foo (Baz ([] a))
1232 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1233 --
1234 -- But in fact, even without -O, nested structures at top level are
1235 -- flattened by the simplifier, so we don't need to be super-clever here.
1236 --
1237 -- Examples
1238 --
1239 --      f = \x::Int. x+7        TRUE
1240 --      p = (True,False)        TRUE
1241 --
1242 --      d = (fst p, False)      FALSE because there's a redex inside
1243 --                              (this particular one doesn't happen but...)
1244 --
1245 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1246 --      n = /\a. Nil a                  TRUE
1247 --
1248 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1249 --
1250 --
1251 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1252 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1253 --
1254 --    b) (C x xs), where C is a contructors is updatable if the application is
1255 --         dynamic
1256 --
1257 --    c) don't look through unfolding of f in (f x).
1258 --
1259 -- When opt_RuntimeTypes is on, we keep type lambdas and treat
1260 -- them as making the RHS re-entrant (non-updatable).
1261
1262 rhsIsStatic hmods rhs = is_static False rhs
1263   where
1264   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1265           -> CoreExpr -> Bool
1266
1267   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1268
1269   is_static in_arg (Note (SCC _) e) = False
1270   is_static in_arg (Note _ e)       = is_static in_arg e
1271
1272   is_static in_arg (Lit lit)
1273     = case lit of
1274         MachLabel _ _ -> False
1275         other         -> True
1276         -- A MachLabel (foreign import "&foo") in an argument
1277         -- prevents a constructor application from being static.  The
1278         -- reason is that it might give rise to unresolvable symbols
1279         -- in the object file: under Linux, references to "weak"
1280         -- symbols from the data segment give rise to "unresolvable
1281         -- relocation" errors at link time This might be due to a bug
1282         -- in the linker, but we'll work around it here anyway.
1283         -- SDM 24/2/2004
1284
1285   is_static in_arg other_expr = go other_expr 0
1286    where
1287     go (Var f) n_val_args
1288 #if mingw32_TARGET_OS
1289         | not (isDllName hmods (idName f))
1290 #endif
1291         =  saturated_data_con f n_val_args
1292         || (in_arg && n_val_args == 0)
1293                 -- A naked un-applied variable is *not* deemed a static RHS
1294                 -- E.g.         f = g
1295                 -- Reason: better to update so that the indirection gets shorted
1296                 --         out, and the true value will be seen
1297                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1298                 --     are always updatable.  If you do so, make sure that non-updatable
1299                 --     ones have enough space for their static link field!
1300
1301     go (App f a) n_val_args
1302         | isTypeArg a                    = go f n_val_args
1303         | not in_arg && is_static True a = go f (n_val_args + 1)
1304         -- The (not in_arg) checks that we aren't in a constructor argument;
1305         -- if we are, we don't allow (value) applications of any sort
1306         --
1307         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1308         --   x = D# (1.0## /## 2.0##)
1309         -- can't float because /## can fail.
1310
1311     go (Note (SCC _) f) n_val_args = False
1312     go (Note _ f) n_val_args       = go f n_val_args
1313
1314     go other n_val_args = False
1315
1316     saturated_data_con f n_val_args
1317         = case isDataConWorkId_maybe f of
1318             Just dc -> n_val_args == dataConRepArity dc
1319             Nothing -> False
1320 \end{code}