compiler/coreSyn/MkExternalCore.lhs

   1
   2 % (c) The University of Glasgow 2001-2006
   3 %
   4 \begin{code}
   5 module MkExternalCore (
   6         emitExternalCore
   7 ) where
   8
   9 #include "HsVersions.h"
  10
  11 import qualified ExternalCore as C
  12 import Module
  13 import CoreSyn
  14 import HscTypes
  15 import TyCon
  16 import TypeRep
  17 import Type
  18 import PprExternalCore () -- Instances
  19 import DataCon
  20 import Coercion
  21 import Var
  22 import IdInfo
  23 import Literal
  24 import Name
  25 import Outputable
  26 import Encoding
  27 import ForeignCall
  28 import DynFlags
  29 import FastString
  30 import Exception
  31
  32 import Data.Char
  33 import System.IO
  34
  35 emitExternalCore :: DynFlags -> CgGuts -> IO ()
  36 emitExternalCore dflags cg_guts
  37  | dopt Opt_EmitExternalCore dflags
  38  = (do handle <- openFile corename WriteMode
  39        hPutStrLn handle (show (mkExternalCore cg_guts))
  40        hClose handle)
  41    `catchIO` (\_ -> pprPanic "Failed to open or write external core output file"
  42                              (text corename))
  43    where corename = extCoreName dflags
  44 emitExternalCore _ _
  45  | otherwise
  46  = return ()
  47
  48 -- Reinventing the Reader monad; whee.
  49 newtype CoreM a = CoreM (CoreState -> (CoreState, a))
  50 type CoreState = Module
  51 instance Monad CoreM where
  52   (CoreM m) >>= f = CoreM (\ s -> case m s of
  53                                     (s',r) -> case f r of
  54                                                 CoreM f' -> f' s')
  55   return x = CoreM (\ s -> (s, x))
  56 runCoreM :: CoreM a -> CoreState -> a
  57 runCoreM (CoreM f) s = snd $ f s
  58 ask :: CoreM CoreState
  59 ask = CoreM (\ s -> (s,s))
  60
  61 mkExternalCore :: CgGuts -> C.Module
  62 -- The ModGuts has been tidied, but the implicit bindings have
  63 -- not been injected, so we have to add them manually here
  64 -- We don't include the strange data-con *workers* because they are
  65 -- implicit in the data type declaration itself
  66 mkExternalCore (CgGuts {cg_module=this_mod, cg_tycons = tycons,
  67                         cg_binds = binds})
  68 {- Note that modules can be mutually recursive, but even so, we
  69    print out dependency information within each module. -}
  70   = C.Module mname tdefs (runCoreM (mapM (make_vdef True) binds) this_mod)
  71   where
  72     mname  = make_mid this_mod
  73     tdefs  = foldr collect_tdefs [] tycons
  74
  75 collect_tdefs :: TyCon -> [C.Tdef] -> [C.Tdef]
  76 collect_tdefs tcon tdefs
  77   | isAlgTyCon tcon = tdef: tdefs
  78   where
  79     tdef | isNewTyCon tcon =
  80                 C.Newtype (qtc tcon)
  81                   (case newTyConCo_maybe tcon of
  82                      Just co -> qtc co
  83                      Nothing       -> pprPanic ("MkExternalCore: newtype tcon\
  84                                        should have a coercion: ") (ppr tcon))
  85                   (map make_tbind tyvars)
  86                   (make_ty (snd (newTyConRhs tcon)))
  87          | otherwise =
  88                 C.Data (qtc tcon) (map make_tbind tyvars)
  89                    (map make_cdef (tyConDataCons tcon))
  90     tyvars = tyConTyVars tcon
  91
  92 collect_tdefs _ tdefs = tdefs
  93
  94 qtc :: TyCon -> C.Qual C.Tcon
  95 qtc = make_con_qid . tyConName
  96
  97
  98 make_cdef :: DataCon -> C.Cdef
  99 make_cdef dcon =  C.Constr dcon_name existentials tys
 100   where
 101     dcon_name    = make_qid False False (dataConName dcon)
 102     existentials = map make_tbind ex_tyvars
 103     ex_tyvars    = dataConExTyVars dcon
 104     tys          = map make_ty (dataConRepArgTys dcon)
 105
 106 make_tbind :: TyVar -> C.Tbind
 107 make_tbind tv = (make_var_id (tyVarName tv), make_kind (tyVarKind tv))
 108
 109 make_vbind :: Var -> C.Vbind
 110 make_vbind v = (make_var_id  (Var.varName v), make_ty (varType v))
 111
 112 make_vdef :: Bool -> CoreBind -> CoreM C.Vdefg
 113 make_vdef topLevel b =
 114   case b of
 115     NonRec v e -> f (v,e)     >>= (return . C.Nonrec)
 116     Rec ves    -> mapM f ves  >>= (return . C.Rec)
 117   where
 118   f :: (CoreBndr,CoreExpr) -> CoreM C.Vdef
 119   f (v,e) = do
 120           localN <- isALocal vName
 121           let local = not topLevel || localN
 122           rhs <- make_exp e
 123           -- use local flag to determine where to add the module name
 124           return (local, make_qid local True vName, make_ty (varType v),rhs)
 125         where vName = Var.varName v
 126
 127 make_exp :: CoreExpr -> CoreM C.Exp
 128 make_exp (Var v) = do
 129   let vName = Var.varName v
 130   isLocal <- isALocal vName
 131   return $
 132      case idDetails v of
 133        FCallId (CCall (CCallSpec (StaticTarget nm _) callconv _))
 134            -> C.External (unpackFS nm) (showSDoc (ppr callconv)) (make_ty (varType v))
 135        FCallId (CCall (CCallSpec DynamicTarget     callconv _))
 136            -> C.DynExternal            (showSDoc (ppr callconv)) (make_ty (varType v))
 137        -- Constructors are always exported, so make sure to declare them
 138        -- with qualified names
 139        DataConWorkId _ -> C.Var (make_var_qid False vName)
 140        DataConWrapId _ -> C.Var (make_var_qid False vName)
 141        _ -> C.Var (make_var_qid isLocal vName)
 142 make_exp (Lit (MachLabel s _ _)) = return $ C.Label (unpackFS s)
 143 make_exp (Lit l) = return $ C.Lit (make_lit l)
 144 make_exp (App e (Type t)) = make_exp e >>= (\ b -> return $ C.Appt b (make_ty t))
 145 make_exp (App e1 e2) = do
 146    rator <- make_exp e1
 147    rand <- make_exp e2
 148    return $ C.App rator rand
 149 make_exp (Lam v e) | isTyCoVar v = make_exp e >>= (\ b ->
 150                                     return $ C.Lam (C.Tb (make_tbind v)) b)
 151 make_exp (Lam v e) | otherwise = make_exp e >>= (\ b ->
 152                                     return $ C.Lam (C.Vb (make_vbind v)) b)
 153 make_exp (Cast e co) = make_exp e >>= (\ b -> return $ C.Cast b (make_ty co))
 154 make_exp (Let b e) = do
 155   vd   <- make_vdef False b
 156   body <- make_exp e
 157   return $ C.Let vd body
 158 make_exp (Case e v ty alts) = do
 159   scrut <- make_exp e
 160   newAlts  <- mapM make_alt alts
 161   return $ C.Case scrut (make_vbind v) (make_ty ty) newAlts
 162 make_exp (Note (SCC _) e) = make_exp e >>= (return . C.Note "SCC") -- temporary
 163 make_exp (Note (CoreNote s) e) = make_exp e >>= (return . C.Note s)  -- hdaume: core annotations
 164 make_exp _ = error "MkExternalCore died: make_exp"
 165
 166 make_alt :: CoreAlt -> CoreM C.Alt
 167 make_alt (DataAlt dcon, vs, e) = do
 168     newE <- make_exp e
 169     return $ C.Acon (make_con_qid (dataConName dcon))
 170            (map make_tbind tbs)
 171            (map make_vbind vbs)
 172            newE
 173         where (tbs,vbs) = span isTyCoVar vs
 174 make_alt (LitAlt l,_,e)   = make_exp e >>= (return . (C.Alit (make_lit l)))
 175 make_alt (DEFAULT,[],e)   = make_exp e >>= (return . C.Adefault)
 176 -- This should never happen, as the DEFAULT alternative binds no variables,
 177 -- but we might as well check for it:
 178 make_alt a@(DEFAULT,_ ,_) = pprPanic ("MkExternalCore: make_alt: DEFAULT "
 179              ++ "alternative had a non-empty var list") (ppr a)
 180
 181
 182 make_lit :: Literal -> C.Lit
 183 make_lit l =
 184   case l of
 185     -- Note that we need to check whether the character is "big".
 186     -- External Core only allows character literals up to '\xff'.
 187     MachChar i | i <= chr 0xff -> C.Lchar i t
 188     -- For a character bigger than 0xff, we represent it in ext-core
 189     -- as an int lit with a char type.
 190     MachChar i             -> C.Lint (fromIntegral $ ord i) t
 191     MachStr s -> C.Lstring (unpackFS s) t
 192     MachNullAddr -> C.Lint 0 t
 193     MachInt i -> C.Lint i t
 194     MachInt64 i -> C.Lint i t
 195     MachWord i -> C.Lint i t
 196     MachWord64 i -> C.Lint i t
 197     MachFloat r -> C.Lrational r t
 198     MachDouble r -> C.Lrational r t
 199     _ -> error "MkExternalCore died: make_lit"
 200   where
 201     t = make_ty (literalType l)
 202
 203 -- Expand type synonyms, then convert.
 204 make_ty :: Type -> C.Ty                 -- Be sure to expand types recursively!
 205                                         -- example: FilePath ~> String ~> [Char]
 206 make_ty t | Just expanded <- tcView t = make_ty expanded
 207 make_ty t = make_ty' t
 208
 209 -- note calls to make_ty so as to expand types recursively
 210 make_ty' :: Type -> C.Ty
 211 make_ty' (TyVarTy tv)            = C.Tvar (make_var_id (tyVarName tv))
 212 make_ty' (AppTy t1 t2)           = C.Tapp (make_ty t1) (make_ty t2)
 213 make_ty' (FunTy t1 t2)           = make_ty (TyConApp funTyCon [t1,t2])
 214 make_ty' (ForAllTy tv t)         = C.Tforall (make_tbind tv) (make_ty t)
 215 make_ty' (TyConApp tc ts)        = make_tyConApp tc ts
 216
 217 -- Newtypes are treated just like any other type constructor; not expanded
 218 -- Reason: predTypeRep does substitution and, while substitution deals
 219 --         correctly with name capture, it's only correct if you see the uniques!
 220 --         If you just see occurrence names, name capture may occur.
 221 -- Example: newtype A a = A (forall b. b -> a)
 222 --          test :: forall q b. q -> A b
 223 --          test _ = undefined
 224 --      Here the 'a' gets substituted by 'b', which is captured.
 225 -- Another solution would be to expand newtypes before tidying; but that would
 226 -- expose the representation in interface files, which definitely isn't right.
 227 -- Maybe CoreTidy should know whether to expand newtypes or not?
 228
 229 make_ty' (PredTy p)     = make_ty (predTypeRep p)
 230
 231 make_tyConApp :: TyCon -> [Type] -> C.Ty
 232 make_tyConApp tc [t1, t2] | tc == transCoercionTyCon =
 233   C.TransCoercion (make_ty t1) (make_ty t2)
 234 make_tyConApp tc [t]      | tc == symCoercionTyCon =
 235   C.SymCoercion (make_ty t)
 236 make_tyConApp tc [t1, t2] | tc == unsafeCoercionTyCon =
 237   C.UnsafeCoercion (make_ty t1) (make_ty t2)
 238 make_tyConApp tc [t]      | tc == leftCoercionTyCon =
 239   C.LeftCoercion (make_ty t)
 240 make_tyConApp tc [t]      | tc == rightCoercionTyCon =
 241   C.RightCoercion (make_ty t)
 242 make_tyConApp tc [t1, t2] | tc == instCoercionTyCon =
 243   C.InstCoercion (make_ty t1) (make_ty t2)
 244 -- this fails silently if we have an application
 245 -- of a wired-in coercion tycon to the wrong number of args.
 246 -- Not great...
 247 make_tyConApp tc ts =
 248   foldl C.Tapp (C.Tcon (qtc tc))
 249             (map make_ty ts)
 250
 251
 252 make_kind :: Kind -> C.Kind
 253 make_kind (PredTy p) | isEqPred p = C.Keq (make_ty t1) (make_ty t2)
 254     where (t1, t2) = getEqPredTys p
 255 make_kind (FunTy k1 k2)  = C.Karrow (make_kind k1) (make_kind k2)
 256 make_kind k
 257   | isLiftedTypeKind k   = C.Klifted
 258   | isUnliftedTypeKind k = C.Kunlifted
 259   | isOpenTypeKind k     = C.Kopen
 260 make_kind _ = error "MkExternalCore died: make_kind"
 261
 262 {- Id generation. -}
 263
 264 make_id :: Bool -> Name -> C.Id
 265 -- include uniques for internal names in order to avoid name shadowing
 266 make_id _is_var nm = ((occNameString . nameOccName) nm)
 267   ++ (if isInternalName nm then (show . nameUnique) nm else "")
 268
 269 make_var_id :: Name -> C.Id
 270 make_var_id = make_id True
 271
 272 -- It's important to encode the module name here, because in External Core,
 273 -- base:GHC.Base => base:GHCziBase
 274 -- We don't do this in pprExternalCore because we
 275 -- *do* want to keep the package name (we don't want baseZCGHCziBase,
 276 -- because that would just be ugly.)
 277 -- SIGH.
 278 -- We encode the package name as well.
 279 make_mid :: Module -> C.Id
 280 -- Super ugly code, but I can't find anything else that does quite what I
 281 -- want (encodes the hierarchical module name without encoding the colon
 282 -- that separates the package name from it.)
 283 make_mid m = showSDoc $
 284               (text $ zEncodeString $ packageIdString $ modulePackageId m)
 285               <> text ":"
 286               <> (pprEncoded $ pprModuleName $ moduleName m)
 287      where pprEncoded = pprCode CStyle
 288
 289 make_qid :: Bool -> Bool -> Name -> C.Qual C.Id
 290 make_qid force_unqual is_var n = (mname,make_id is_var n)
 291     where mname =
 292            case nameModule_maybe n of
 293             Just m | not force_unqual -> make_mid m
 294             _ -> ""
 295
 296 make_var_qid :: Bool -> Name -> C.Qual C.Id
 297 make_var_qid force_unqual = make_qid force_unqual True
 298
 299 make_con_qid :: Name -> C.Qual C.Id
 300 make_con_qid = make_qid False False
 301
 302 -------
 303 isALocal :: Name -> CoreM Bool
 304 isALocal vName = do
 305   modName <- ask
 306   return $ case nameModule_maybe vName of
 307              -- Not sure whether isInternalName corresponds to "local"ness
 308              -- in the External Core sense; need to re-read the spec.
 309              Just m | m == modName -> isInternalName vName
 310              _                     -> False
 311 \end{code}
 312
 313
 314
 315