compiler/coreSyn/MkExternalCore.lhs

   1
   2 % (c) The University of Glasgow 2001-2006
   3 %
   4 \begin{code}
   5 module MkExternalCore (
   6         emitExternalCore
   7 ) where
   8
   9 #include "HsVersions.h"
  10
  11 import qualified ExternalCore as C
  12 import Module
  13 import CoreSyn
  14 import HscTypes
  15 import TyCon
  16 import TypeRep
  17 import Type
  18 import PprExternalCore () -- Instances
  19 import DataCon
  20 import Coercion
  21 import Var
  22 import IdInfo
  23 import Literal
  24 import Name
  25 import Outputable
  26 import Encoding
  27 import ForeignCall
  28 import DynFlags
  29 import StaticFlags
  30 import FastString
  31
  32 import IO
  33 import Data.Char
  34
  35 emitExternalCore :: DynFlags -> CgGuts -> IO ()
  36 emitExternalCore dflags cg_guts
  37  | opt_EmitExternalCore
  38  = (do handle <- openFile corename WriteMode
  39        hPutStrLn handle (show (mkExternalCore cg_guts))
  40        hClose handle)
  41    `catch` (\_ -> pprPanic "Failed to open or write external core output file"
  42                            (text corename))
  43    where corename = extCoreName dflags
  44 emitExternalCore _ _
  45  | otherwise
  46  = return ()
  47
  48 -- Reinventing the Reader monad; whee.
  49 newtype CoreM a = CoreM (CoreState -> (CoreState, a))
  50 type CoreState = Module
  51 instance Monad CoreM where
  52   (CoreM m) >>= f = CoreM (\ s -> case m s of
  53                                     (s',r) -> case f r of
  54                                                 CoreM f' -> f' s')
  55   return x = CoreM (\ s -> (s, x))
  56 runCoreM :: CoreM a -> CoreState -> a
  57 runCoreM (CoreM f) s = snd $ f s
  58 ask :: CoreM CoreState
  59 ask = CoreM (\ s -> (s,s))
  60
  61 mkExternalCore :: CgGuts -> C.Module
  62 -- The ModGuts has been tidied, but the implicit bindings have
  63 -- not been injected, so we have to add them manually here
  64 -- We don't include the strange data-con *workers* because they are
  65 -- implicit in the data type declaration itself
  66 mkExternalCore (CgGuts {cg_module=this_mod, cg_tycons = tycons,
  67                         cg_binds = binds})
  68  -- Note that we flatten binds at the top level:
  69  -- every module is just a single recursive bag of declarations.
  70  -- Rationale: since modules can be mutually recursive,
  71  -- there's not much reason to preserve dependency info within a module.
  72   = C.Module mname tdefs (case flattenBinds binds of
  73                           -- check for empty list so we don't create an
  74                           -- empty Rec group
  75                             [] -> []
  76                             bs  -> [(runCoreM (make_vdef True
  77                                       (Rec bs)) this_mod)])
  78   where
  79     mname  = make_mid this_mod
  80     tdefs  = foldr collect_tdefs [] tycons
  81
  82 collect_tdefs :: TyCon -> [C.Tdef] -> [C.Tdef]
  83 collect_tdefs tcon tdefs
  84   | isAlgTyCon tcon = tdef: tdefs
  85   where
  86     tdef | isNewTyCon tcon =
  87                 C.Newtype (qtc tcon)
  88                   (case newTyConCo_maybe tcon of
  89                      Just co -> qtc co
  90                      Nothing       -> pprPanic ("MkExternalCore: newtype tcon\
  91                                        should have a coercion: ") (ppr tcon))
  92                   (map make_tbind tyvars)
  93                   (make_ty (snd (newTyConRhs tcon)))
  94          | otherwise =
  95                 C.Data (qtc tcon) (map make_tbind tyvars)
  96                    (map make_cdef (tyConDataCons tcon))
  97     tyvars = tyConTyVars tcon
  98
  99 collect_tdefs _ tdefs = tdefs
 100
 101 qtc :: TyCon -> C.Qual C.Tcon
 102 qtc = make_con_qid . tyConName
 103
 104
 105 make_cdef :: DataCon -> C.Cdef
 106 make_cdef dcon =  C.Constr dcon_name existentials tys
 107   where
 108     dcon_name    = make_qid False False (dataConName dcon)
 109     existentials = map make_tbind ex_tyvars
 110     ex_tyvars    = dataConExTyVars dcon
 111     tys          = map make_ty (dataConRepArgTys dcon)
 112
 113 make_tbind :: TyVar -> C.Tbind
 114 make_tbind tv = (make_var_id (tyVarName tv), make_kind (tyVarKind tv))
 115
 116 make_vbind :: Var -> C.Vbind
 117 make_vbind v = (make_var_id  (Var.varName v), make_ty (varType v))
 118
 119 make_vdef :: Bool -> CoreBind -> CoreM C.Vdefg
 120 make_vdef topLevel b =
 121   case b of
 122     NonRec v e -> f (v,e)     >>= (return . C.Nonrec)
 123     Rec ves    -> mapM f ves  >>= (return . C.Rec)
 124   where
 125   f :: (CoreBndr,CoreExpr) -> CoreM C.Vdef
 126   f (v,e) = do
 127           localN <- isALocal vName
 128           let local = not topLevel || localN
 129           rhs <- make_exp e
 130           -- use local flag to determine where to add the module name
 131           return (local, make_qid local True vName, make_ty (varType v),rhs)
 132         where vName = Var.varName v
 133
 134 make_exp :: CoreExpr -> CoreM C.Exp
 135 make_exp (Var v) = do
 136   let vName = Var.varName v
 137   isLocal <- isALocal vName
 138   return $
 139      case globalIdVarDetails v of
 140        FCallId (CCall (CCallSpec (StaticTarget nm) callconv _))
 141            -> C.External (unpackFS nm) (showSDoc (ppr callconv)) (make_ty (varType v))
 142        FCallId (CCall (CCallSpec DynamicTarget     callconv _))
 143            -> C.DynExternal            (showSDoc (ppr callconv)) (make_ty (varType v))
 144        FCallId _
 145            -> pprPanic "MkExternalCore died: can't handle non-{static,dynamic}-C foreign call"
 146                     (ppr v)
 147        -- Constructors are always exported, so make sure to declare them
 148        -- with qualified names
 149        DataConWorkId _ -> C.Var (make_var_qid False vName)
 150        DataConWrapId _ -> C.Var (make_var_qid False vName)
 151        _ -> C.Var (make_var_qid isLocal vName)
 152 make_exp (Lit (MachLabel s _)) = return $ C.Label (unpackFS s)
 153 make_exp (Lit l) = return $ C.Lit (make_lit l)
 154 make_exp (App e (Type t)) = make_exp e >>= (\ b -> return $ C.Appt b (make_ty t))
 155 make_exp (App e1 e2) = do
 156    rator <- make_exp e1
 157    rand <- make_exp e2
 158    return $ C.App rator rand
 159 make_exp (Lam v e) | isTyVar v = make_exp e >>= (\ b ->
 160                                     return $ C.Lam (C.Tb (make_tbind v)) b)
 161 make_exp (Lam v e) | otherwise = make_exp e >>= (\ b ->
 162                                     return $ C.Lam (C.Vb (make_vbind v)) b)
 163 make_exp (Cast e co) = make_exp e >>= (\ b -> return $ C.Cast b (make_ty co))
 164 make_exp (Let b e) = do
 165   vd   <- make_vdef False b
 166   body <- make_exp e
 167   return $ C.Let vd body
 168 make_exp (Case e v ty alts) = do
 169   scrut <- make_exp e
 170   newAlts  <- mapM make_alt alts
 171   return $ C.Case scrut (make_vbind v) (make_ty ty) newAlts
 172 make_exp (Note (SCC _) e) = make_exp e >>= (return . C.Note "SCC") -- temporary
 173 make_exp (Note (CoreNote s) e) = make_exp e >>= (return . C.Note s)  -- hdaume: core annotations
 174 make_exp _ = error "MkExternalCore died: make_exp"
 175
 176 make_alt :: CoreAlt -> CoreM C.Alt
 177 make_alt (DataAlt dcon, vs, e) = do
 178     newE <- make_exp e
 179     return $ C.Acon (make_con_qid (dataConName dcon))
 180            (map make_tbind tbs)
 181            (map make_vbind vbs)
 182            newE
 183         where (tbs,vbs) = span isTyVar vs
 184 make_alt (LitAlt l,_,e)   = make_exp e >>= (return . (C.Alit (make_lit l)))
 185 make_alt (DEFAULT,[],e)   = make_exp e >>= (return . C.Adefault)
 186 -- This should never happen, as the DEFAULT alternative binds no variables,
 187 -- but we might as well check for it:
 188 make_alt a@(DEFAULT,_ ,_) = pprPanic ("MkExternalCore: make_alt: DEFAULT "
 189              ++ "alternative had a non-empty var list") (ppr a)
 190
 191
 192 make_lit :: Literal -> C.Lit
 193 make_lit l =
 194   case l of
 195     -- Note that we need to check whether the character is "big".
 196     -- External Core only allows character literals up to '\xff'.
 197     MachChar i | i <= chr 0xff -> C.Lchar i t
 198     -- For a character bigger than 0xff, we represent it in ext-core
 199     -- as an int lit with a char type.
 200     MachChar i             -> C.Lint (fromIntegral $ ord i) t
 201     MachStr s -> C.Lstring (unpackFS s) t
 202     MachNullAddr -> C.Lint 0 t
 203     MachInt i -> C.Lint i t
 204     MachInt64 i -> C.Lint i t
 205     MachWord i -> C.Lint i t
 206     MachWord64 i -> C.Lint i t
 207     MachFloat r -> C.Lrational r t
 208     MachDouble r -> C.Lrational r t
 209     _ -> error "MkExternalCore died: make_lit"
 210   where
 211     t = make_ty (literalType l)
 212
 213 -- Expand type synonyms, then convert.
 214 make_ty :: Type -> C.Ty                 -- Be sure to expand types recursively!
 215                                         -- example: FilePath ~> String ~> [Char]
 216 make_ty t | Just expanded <- tcView t = make_ty expanded
 217 make_ty t = make_ty' t
 218
 219 -- note calls to make_ty so as to expand types recursively
 220 make_ty' :: Type -> C.Ty
 221 make_ty' (TyVarTy tv)            = C.Tvar (make_var_id (tyVarName tv))
 222 make_ty' (AppTy t1 t2)           = C.Tapp (make_ty t1) (make_ty t2)
 223 make_ty' (FunTy t1 t2)           = make_ty (TyConApp funTyCon [t1,t2])
 224 make_ty' (ForAllTy tv t)         = C.Tforall (make_tbind tv) (make_ty t)
 225 make_ty' (TyConApp tc ts)        = make_tyConApp tc ts
 226
 227 -- Newtypes are treated just like any other type constructor; not expanded
 228 -- Reason: predTypeRep does substitution and, while substitution deals
 229 --         correctly with name capture, it's only correct if you see the uniques!
 230 --         If you just see occurrence names, name capture may occur.
 231 -- Example: newtype A a = A (forall b. b -> a)
 232 --          test :: forall q b. q -> A b
 233 --          test _ = undefined
 234 --      Here the 'a' gets substituted by 'b', which is captured.
 235 -- Another solution would be to expand newtypes before tidying; but that would
 236 -- expose the representation in interface files, which definitely isn't right.
 237 -- Maybe CoreTidy should know whether to expand newtypes or not?
 238
 239 make_ty' (PredTy p)     = make_ty (predTypeRep p)
 240
 241 make_tyConApp :: TyCon -> [Type] -> C.Ty
 242 make_tyConApp tc [t1, t2] | tc == transCoercionTyCon =
 243   C.TransCoercion (make_ty t1) (make_ty t2)
 244 make_tyConApp tc [t]      | tc == symCoercionTyCon =
 245   C.SymCoercion (make_ty t)
 246 make_tyConApp tc [t1, t2] | tc == unsafeCoercionTyCon =
 247   C.UnsafeCoercion (make_ty t1) (make_ty t2)
 248 make_tyConApp tc [t]      | tc == leftCoercionTyCon =
 249   C.LeftCoercion (make_ty t)
 250 make_tyConApp tc [t]      | tc == rightCoercionTyCon =
 251   C.RightCoercion (make_ty t)
 252 make_tyConApp tc [t1, t2] | tc == instCoercionTyCon =
 253   C.InstCoercion (make_ty t1) (make_ty t2)
 254 -- this fails silently if we have an application
 255 -- of a wired-in coercion tycon to the wrong number of args.
 256 -- Not great...
 257 make_tyConApp tc ts =
 258   foldl C.Tapp (C.Tcon (qtc tc))
 259             (map make_ty ts)
 260
 261
 262 make_kind :: Kind -> C.Kind
 263 make_kind (PredTy p) | isEqPred p = C.Keq (make_ty t1) (make_ty t2)
 264     where (t1, t2) = getEqPredTys p
 265 make_kind (FunTy k1 k2)  = C.Karrow (make_kind k1) (make_kind k2)
 266 make_kind k
 267   | isLiftedTypeKind k   = C.Klifted
 268   | isUnliftedTypeKind k = C.Kunlifted
 269   | isOpenTypeKind k     = C.Kopen
 270 make_kind _ = error "MkExternalCore died: make_kind"
 271
 272 {- Id generation. -}
 273
 274 make_id :: Bool -> Name -> C.Id
 275 -- include uniques for internal names in order to avoid name shadowing
 276 make_id _is_var nm = ((occNameString . nameOccName) nm)
 277   ++ (if isInternalName nm then (show . nameUnique) nm else "")
 278
 279 make_var_id :: Name -> C.Id
 280 make_var_id = make_id True
 281
 282 -- It's important to encode the module name here, because in External Core,
 283 -- base:GHC.Base => base:GHCziBase
 284 -- We don't do this in pprExternalCore because we
 285 -- *do* want to keep the package name (we don't want baseZCGHCziBase,
 286 -- because that would just be ugly.)
 287 -- SIGH.
 288 -- We encode the package name as well.
 289 make_mid :: Module -> C.Id
 290 -- Super ugly code, but I can't find anything else that does quite what I
 291 -- want (encodes the hierarchical module name without encoding the colon
 292 -- that separates the package name from it.)
 293 make_mid m = showSDoc $
 294               (text $ zEncodeString $ packageIdString $ modulePackageId m)
 295               <> text ":"
 296               <> (pprEncoded $ pprModuleName $ moduleName m)
 297      where pprEncoded = pprCode CStyle
 298
 299 make_qid :: Bool -> Bool -> Name -> C.Qual C.Id
 300 make_qid force_unqual is_var n = (mname,make_id is_var n)
 301     where mname =
 302            case nameModule_maybe n of
 303             Just m | not force_unqual -> make_mid m
 304             _ -> ""
 305
 306 make_var_qid :: Bool -> Name -> C.Qual C.Id
 307 make_var_qid force_unqual = make_qid force_unqual True
 308
 309 make_con_qid :: Name -> C.Qual C.Id
 310 make_con_qid = make_qid False False
 311
 312 -------
 313 isALocal :: Name -> CoreM Bool
 314 isALocal vName = do
 315   modName <- ask
 316   return $ case nameModule_maybe vName of
 317              -- Not sure whether isInternalName corresponds to "local"ness
 318              -- in the External Core sense; need to re-read the spec.
 319              Just m | m == modName -> isInternalName vName
 320              _                     -> False
 321 \end{code}
 322
 323
 324
 325