compiler/deSugar/Check.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1997-1998
   4 %
   5 % Author: Juan J. Quintela    <quintela@krilin.dc.fi.udc.es>
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module Check ( check , ExhaustivePat ) where
  16
  17 #include "HsVersions.h"
  18
  19 import HsSyn
  20 import TcHsSyn
  21 import DsUtils
  22 import MatchLit
  23 import Id
  24 import DataCon
  25 import Name
  26 import TysWiredIn
  27 import PrelNames
  28 import TyCon
  29 import BasicTypes
  30 import SrcLoc
  31 import UniqSet
  32 import Util
  33 import Outputable
  34 import FastString
  35 \end{code}
  36
  37 This module performs checks about if one list of equations are:
  38 \begin{itemize}
  39 \item Overlapped
  40 \item Non exhaustive
  41 \end{itemize}
  42 To discover that we go through the list of equations in a tree-like fashion.
  43
  44 If you like theory, a similar algorithm is described in:
  45 \begin{quotation}
  46         {\em Two Techniques for Compiling Lazy Pattern Matching},
  47         Luc Maranguet,
  48         INRIA Rocquencourt (RR-2385, 1994)
  49 \end{quotation}
  50 The algorithm is based on the first technique, but there are some differences:
  51 \begin{itemize}
  52 \item We don't generate code
  53 \item We have constructors and literals (not only literals as in the
  54           article)
  55 \item We don't use directions, we must select the columns from
  56           left-to-right
  57 \end{itemize}
  58 (By the way the second technique is really similar to the one used in
  59  @Match.lhs@ to generate code)
  60
  61 This function takes the equations of a pattern and returns:
  62 \begin{itemize}
  63 \item The patterns that are not recognized
  64 \item The equations that are not overlapped
  65 \end{itemize}
  66 It simplify the patterns and then call @check'@ (the same semantics), and it
  67 needs to reconstruct the patterns again ....
  68
  69 The problem appear with things like:
  70 \begin{verbatim}
  71   f [x,y]   = ....
  72   f (x:xs)  = .....
  73 \end{verbatim}
  74 We want to put the two patterns with the same syntax, (prefix form) and
  75 then all the constructors are equal:
  76 \begin{verbatim}
  77   f (: x (: y []))   = ....
  78   f (: x xs)         = .....
  79 \end{verbatim}
  80 (more about that in @simplify_eqns@)
  81
  82 We would prefer to have a @WarningPat@ of type @String@, but Strings and the
  83 Pretty Printer are not friends.
  84
  85 We use @InPat@ in @WarningPat@ instead of @OutPat@
  86 because we need to print the
  87 warning messages in the same way they are introduced, i.e. if the user
  88 wrote:
  89 \begin{verbatim}
  90         f [x,y] = ..
  91 \end{verbatim}
  92 He don't want a warning message written:
  93 \begin{verbatim}
  94         f (: x (: y [])) ........
  95 \end{verbatim}
  96 Then we need to use InPats.
  97 \begin{quotation}
  98      Juan Quintela 5 JUL 1998\\
  99           User-friendliness and compiler writers are no friends.
 100 \end{quotation}
 101
 102 \begin{code}
 103 type WarningPat = InPat Name
 104 type ExhaustivePat = ([WarningPat], [(Name, [HsLit])])
 105 type EqnNo  = Int
 106 type EqnSet = UniqSet EqnNo
 107
 108
 109 check :: [EquationInfo] -> ([ExhaustivePat], [EquationInfo])
 110         -- Second result is the shadowed equations
 111 check qs = (untidy_warns, shadowed_eqns)
 112       where
 113         (warns, used_nos) = check' ([1..] `zip` map simplify_eqn qs)
 114         untidy_warns = map untidy_exhaustive warns
 115         shadowed_eqns = [eqn | (eqn,i) <- qs `zip` [1..],
 116                                 not (i `elementOfUniqSet` used_nos)]
 117
 118 untidy_exhaustive :: ExhaustivePat -> ExhaustivePat
 119 untidy_exhaustive ([pat], messages) =
 120                   ([untidy_no_pars pat], map untidy_message messages)
 121 untidy_exhaustive (pats, messages) =
 122                   (map untidy_pars pats, map untidy_message messages)
 123
 124 untidy_message :: (Name, [HsLit]) -> (Name, [HsLit])
 125 untidy_message (string, lits) = (string, map untidy_lit lits)
 126 \end{code}
 127
 128 The function @untidy@ does the reverse work of the @simplify_pat@ funcion.
 129
 130 \begin{code}
 131
 132 type NeedPars = Bool
 133
 134 untidy_no_pars :: WarningPat -> WarningPat
 135 untidy_no_pars p = untidy False p
 136
 137 untidy_pars :: WarningPat -> WarningPat
 138 untidy_pars p = untidy True p
 139
 140 untidy :: NeedPars -> WarningPat -> WarningPat
 141 untidy b (L loc p) = L loc (untidy' b p)
 142   where
 143     untidy' _ p@(WildPat _)   = p
 144     untidy' _ p@(VarPat name) = p
 145     untidy' _ (LitPat lit)    = LitPat (untidy_lit lit)
 146     untidy' _ p@(ConPatIn name (PrefixCon [])) = p
 147     untidy' b (ConPatIn name ps)     = pars b (L loc (ConPatIn name (untidy_con ps)))
 148     untidy' _ (ListPat pats ty)      = ListPat (map untidy_no_pars pats) ty
 149     untidy' _ (TuplePat pats box ty) = TuplePat (map untidy_no_pars pats) box ty
 150     untidy' _ (PArrPat _ _)          = panic "Check.untidy: Shouldn't get a parallel array here!"
 151     untidy' _ (SigPatIn _ _)         = panic "Check.untidy: SigPat"
 152
 153 untidy_con (PrefixCon pats) = PrefixCon (map untidy_pars pats)
 154 untidy_con (InfixCon p1 p2) = InfixCon  (untidy_pars p1) (untidy_pars p2)
 155 untidy_con (RecCon (HsRecFields flds dd))
 156   = RecCon (HsRecFields [ fld { hsRecFieldArg = untidy_pars (hsRecFieldArg fld) }
 157                         | fld <- flds ] dd)
 158
 159 pars :: NeedPars -> WarningPat -> Pat Name
 160 pars True p = ParPat p
 161 pars _    p = unLoc p
 162
 163 untidy_lit :: HsLit -> HsLit
 164 untidy_lit (HsCharPrim c) = HsChar c
 165 untidy_lit lit            = lit
 166 \end{code}
 167
 168 This equation is the same that check, the only difference is that the
 169 boring work is done, that work needs to be done only once, this is
 170 the reason top have two functions, check is the external interface,
 171 @check'@ is called recursively.
 172
 173 There are several cases:
 174
 175 \begin{itemize}
 176 \item There are no equations: Everything is OK.
 177 \item There are only one equation, that can fail, and all the patterns are
 178       variables. Then that equation is used and the same equation is
 179       non-exhaustive.
 180 \item All the patterns are variables, and the match can fail, there are
 181       more equations then the results is the result of the rest of equations
 182       and this equation is used also.
 183
 184 \item The general case, if all the patterns are variables (here the match
 185       can't fail) then the result is that this equation is used and this
 186       equation doesn't generate non-exhaustive cases.
 187
 188 \item In the general case, there can exist literals ,constructors or only
 189       vars in the first column, we actuate in consequence.
 190
 191 \end{itemize}
 192
 193
 194 \begin{code}
 195
 196 check' :: [(EqnNo, EquationInfo)]
 197         -> ([ExhaustivePat],    -- Pattern scheme that might not be matched at all
 198             EqnSet)             -- Eqns that are used (others are overlapped)
 199
 200 check' [] = ([([],[])],emptyUniqSet)
 201
 202 check' ((n, EqnInfo { eqn_pats = ps, eqn_rhs = MatchResult can_fail _ }) : rs)
 203    | first_eqn_all_vars && case can_fail of { CantFail -> True; CanFail -> False }
 204    = ([], unitUniqSet n)        -- One eqn, which can't fail
 205
 206    | first_eqn_all_vars && null rs      -- One eqn, but it can fail
 207    = ([(takeList ps (repeat nlWildPat),[])], unitUniqSet n)
 208
 209    | first_eqn_all_vars         -- Several eqns, first can fail
 210    = (pats, addOneToUniqSet indexs n)
 211   where
 212     first_eqn_all_vars = all_vars ps
 213     (pats,indexs) = check' rs
 214
 215 check' qs
 216    | literals     = split_by_literals qs
 217    | constructors = split_by_constructor qs
 218    | only_vars    = first_column_only_vars qs
 219 -- FIXME: hack to get view patterns through for now
 220    | otherwise    = ([([],[])],emptyUniqSet)
 221 -- pprPanic "Check.check': Not implemented :-(" (ppr first_pats)
 222   where
 223      -- Note: RecPats will have been simplified to ConPats
 224      --       at this stage.
 225     first_pats   = ASSERT2( okGroup qs, pprGroup qs ) map firstPatN qs
 226     constructors = any is_con first_pats
 227     literals     = any is_lit first_pats
 228     only_vars    = all is_var first_pats
 229 \end{code}
 230
 231 Here begins the code to deal with literals, we need to split the matrix
 232 in different matrix beginning by each literal and a last matrix with the
 233 rest of values.
 234
 235 \begin{code}
 236 split_by_literals :: [(EqnNo, EquationInfo)] -> ([ExhaustivePat], EqnSet)
 237 split_by_literals qs = process_literals used_lits qs
 238            where
 239              used_lits = get_used_lits qs
 240 \end{code}
 241
 242 @process_explicit_literals@ is a function that process each literal that appears
 243 in the column of the matrix.
 244
 245 \begin{code}
 246 process_explicit_literals :: [HsLit] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 247 process_explicit_literals lits qs = (concat pats, unionManyUniqSets indexs)
 248     where
 249       pats_indexs   = map (\x -> construct_literal_matrix x qs) lits
 250       (pats,indexs) = unzip pats_indexs
 251 \end{code}
 252
 253
 254 @process_literals@ calls @process_explicit_literals@ to deal with the literals
 255 that appears in the matrix and deal also with the rest of the cases. It
 256 must be one Variable to be complete.
 257
 258 \begin{code}
 259
 260 process_literals :: [HsLit] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 261 process_literals used_lits qs
 262   | null default_eqns  = ASSERT( not (null qs) ) ([make_row_vars used_lits (head qs)] ++ pats,indexs)
 263   | otherwise          = (pats_default,indexs_default)
 264      where
 265        (pats,indexs)   = process_explicit_literals used_lits qs
 266        default_eqns    = ASSERT2( okGroup qs, pprGroup qs )
 267                          [remove_var q | q <- qs, is_var (firstPatN q)]
 268        (pats',indexs') = check' default_eqns
 269        pats_default    = [(nlWildPat:ps,constraints) | (ps,constraints) <- (pats')] ++ pats
 270        indexs_default  = unionUniqSets indexs' indexs
 271 \end{code}
 272
 273 Here we have selected the literal and we will select all the equations that
 274 begins for that literal and create a new matrix.
 275
 276 \begin{code}
 277 construct_literal_matrix :: HsLit -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 278 construct_literal_matrix lit qs =
 279     (map (\ (xs,ys) -> (new_lit:xs,ys)) pats,indexs)
 280   where
 281     (pats,indexs) = (check' (remove_first_column_lit lit qs))
 282     new_lit = nlLitPat lit
 283
 284 remove_first_column_lit :: HsLit
 285                         -> [(EqnNo, EquationInfo)]
 286                         -> [(EqnNo, EquationInfo)]
 287 remove_first_column_lit lit qs
 288   = ASSERT2( okGroup qs, pprGroup qs )
 289     [(n, shift_pat eqn) | q@(n,eqn) <- qs, is_var_lit lit (firstPatN q)]
 290   where
 291      shift_pat eqn@(EqnInfo { eqn_pats = _:ps}) = eqn { eqn_pats = ps }
 292      shift_pat eqn@(EqnInfo { eqn_pats = []})   = panic "Check.shift_var: no patterns"
 293 \end{code}
 294
 295 This function splits the equations @qs@ in groups that deal with the
 296 same constructor.
 297
 298 \begin{code}
 299 split_by_constructor :: [(EqnNo, EquationInfo)] -> ([ExhaustivePat], EqnSet)
 300 split_by_constructor qs
 301   | notNull unused_cons = need_default_case used_cons unused_cons qs
 302   | otherwise           = no_need_default_case used_cons qs
 303                        where
 304                           used_cons   = get_used_cons qs
 305                           unused_cons = get_unused_cons used_cons
 306 \end{code}
 307
 308 The first column of the patterns matrix only have vars, then there is
 309 nothing to do.
 310
 311 \begin{code}
 312 first_column_only_vars :: [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 313 first_column_only_vars qs = (map (\ (xs,ys) -> (nlWildPat:xs,ys)) pats,indexs)
 314                           where
 315                             (pats, indexs) = check' (map remove_var qs)
 316 \end{code}
 317
 318 This equation takes a matrix of patterns and split the equations by
 319 constructor, using all the constructors that appears in the first column
 320 of the pattern matching.
 321
 322 We can need a default clause or not ...., it depends if we used all the
 323 constructors or not explicitly. The reasoning is similar to @process_literals@,
 324 the difference is that here the default case is not always needed.
 325
 326 \begin{code}
 327 no_need_default_case :: [Pat Id] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 328 no_need_default_case cons qs = (concat pats, unionManyUniqSets indexs)
 329     where
 330       pats_indexs   = map (\x -> construct_matrix x qs) cons
 331       (pats,indexs) = unzip pats_indexs
 332
 333 need_default_case :: [Pat Id] -> [DataCon] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 334 need_default_case used_cons unused_cons qs
 335   | null default_eqns  = (pats_default_no_eqns,indexs)
 336   | otherwise          = (pats_default,indexs_default)
 337      where
 338        (pats,indexs)   = no_need_default_case used_cons qs
 339        default_eqns    = ASSERT2( okGroup qs, pprGroup qs )
 340                          [remove_var q | q <- qs, is_var (firstPatN q)]
 341        (pats',indexs') = check' default_eqns
 342        pats_default    = [(make_whole_con c:ps,constraints) |
 343                           c <- unused_cons, (ps,constraints) <- pats'] ++ pats
 344        new_wilds       = ASSERT( not (null qs) ) make_row_vars_for_constructor (head qs)
 345        pats_default_no_eqns =  [(make_whole_con c:new_wilds,[]) | c <- unused_cons] ++ pats
 346        indexs_default  = unionUniqSets indexs' indexs
 347
 348 construct_matrix :: Pat Id -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 349 construct_matrix con qs =
 350     (map (make_con con) pats,indexs)
 351   where
 352     (pats,indexs) = (check' (remove_first_column con qs))
 353 \end{code}
 354
 355 Here remove first column is more difficult that with literals due to the fact
 356 that constructors can have arguments.
 357
 358 For instance, the matrix
 359 \begin{verbatim}
 360  (: x xs) y
 361  z        y
 362 \end{verbatim}
 363 is transformed in:
 364 \begin{verbatim}
 365  x xs y
 366  _ _  y
 367 \end{verbatim}
 368
 369 \begin{code}
 370 remove_first_column :: Pat Id                -- Constructor
 371                     -> [(EqnNo, EquationInfo)]
 372                     -> [(EqnNo, EquationInfo)]
 373 remove_first_column (ConPatOut{ pat_con = L _ con, pat_args = PrefixCon con_pats }) qs
 374   = ASSERT2( okGroup qs, pprGroup qs )
 375     [(n, shift_var eqn) | q@(n, eqn) <- qs, is_var_con con (firstPatN q)]
 376   where
 377      new_wilds = [WildPat (hsLPatType arg_pat) | arg_pat <- con_pats]
 378      shift_var eqn@(EqnInfo { eqn_pats = ConPatOut{ pat_args = PrefixCon ps' } : ps})
 379         = eqn { eqn_pats = map unLoc ps' ++ ps }
 380      shift_var eqn@(EqnInfo { eqn_pats = WildPat _ : ps })
 381         = eqn { eqn_pats = new_wilds ++ ps }
 382      shift_var _ = panic "Check.Shift_var:No done"
 383
 384 make_row_vars :: [HsLit] -> (EqnNo, EquationInfo) -> ExhaustivePat
 385 make_row_vars used_lits (_, EqnInfo { eqn_pats = pats})
 386    = (nlVarPat new_var:takeList (tail pats) (repeat nlWildPat),[(new_var,used_lits)])
 387   where
 388      new_var = hash_x
 389
 390 hash_x = mkInternalName unboundKey {- doesn't matter much -}
 391                      (mkVarOccFS FSLIT("#x"))
 392                      noSrcSpan
 393
 394 make_row_vars_for_constructor :: (EqnNo, EquationInfo) -> [WarningPat]
 395 make_row_vars_for_constructor (_, EqnInfo { eqn_pats = pats})
 396   = takeList (tail pats) (repeat nlWildPat)
 397
 398 compare_cons :: Pat Id -> Pat Id -> Bool
 399 compare_cons (ConPatOut{ pat_con = L _ id1 }) (ConPatOut { pat_con = L _ id2 }) = id1 == id2
 400
 401 remove_dups :: [Pat Id] -> [Pat Id]
 402 remove_dups []     = []
 403 remove_dups (x:xs) | or (map (\y -> compare_cons x y) xs) = remove_dups  xs
 404                    | otherwise                            = x : remove_dups xs
 405
 406 get_used_cons :: [(EqnNo, EquationInfo)] -> [Pat Id]
 407 get_used_cons qs = remove_dups [pat | q <- qs, let pat = firstPatN q,
 408                                       isConPatOut pat]
 409
 410 isConPatOut (ConPatOut {}) = True
 411 isConPatOut other          = False
 412
 413 remove_dups' :: [HsLit] -> [HsLit]
 414 remove_dups' []                   = []
 415 remove_dups' (x:xs) | x `elem` xs = remove_dups' xs
 416                     | otherwise   = x : remove_dups' xs
 417
 418
 419 get_used_lits :: [(EqnNo, EquationInfo)] -> [HsLit]
 420 get_used_lits qs = remove_dups' all_literals
 421                  where
 422                    all_literals = get_used_lits' qs
 423
 424 get_used_lits' :: [(EqnNo, EquationInfo)] -> [HsLit]
 425 get_used_lits' [] = []
 426 get_used_lits' (q:qs)
 427   | Just lit <- get_lit (firstPatN q) = lit : get_used_lits' qs
 428   | otherwise                         = get_used_lits qs
 429
 430 get_lit :: Pat id -> Maybe HsLit
 431 -- Get a representative HsLit to stand for the OverLit
 432 -- It doesn't matter which one, because they will only be compared
 433 -- with other HsLits gotten in the same way
 434 get_lit (LitPat lit)                     = Just lit
 435 get_lit (NPat (HsIntegral i   _ _) mb _) = Just (HsIntPrim   (mb_neg mb i))
 436 get_lit (NPat (HsFractional f _ _) mb _) = Just (HsFloatPrim (mb_neg mb f))
 437 get_lit (NPat (HsIsString s   _ _)  _ _) = Just (HsStringPrim s)
 438 get_lit other_pat                        = Nothing
 439
 440 mb_neg :: Num a => Maybe b -> a -> a
 441 mb_neg Nothing  v = v
 442 mb_neg (Just _) v = -v
 443
 444 get_unused_cons :: [Pat Id] -> [DataCon]
 445 get_unused_cons used_cons = ASSERT( not (null used_cons) ) unused_cons
 446      where
 447        (ConPatOut { pat_con = l_con, pat_ty = ty }) = head used_cons
 448        ty_con          = dataConTyCon (unLoc l_con)     -- Newtype observable
 449        all_cons        = tyConDataCons ty_con
 450        used_cons_as_id = map (\ (ConPatOut{ pat_con = L _ d}) -> d) used_cons
 451        unused_cons     = uniqSetToList
 452                          (mkUniqSet all_cons `minusUniqSet` mkUniqSet used_cons_as_id)
 453
 454 all_vars :: [Pat Id] -> Bool
 455 all_vars []             = True
 456 all_vars (WildPat _:ps) = all_vars ps
 457 all_vars _              = False
 458
 459 remove_var :: (EqnNo, EquationInfo) -> (EqnNo, EquationInfo)
 460 remove_var (n, eqn@(EqnInfo { eqn_pats = WildPat _ : ps})) = (n, eqn { eqn_pats = ps })
 461 remove_var _  = panic "Check.remove_var: equation does not begin with a variable"
 462
 463 -----------------------
 464 eqnPats :: (EqnNo, EquationInfo) -> [Pat Id]
 465 eqnPats (_, eqn) = eqn_pats eqn
 466
 467 okGroup :: [(EqnNo, EquationInfo)] -> Bool
 468 -- True if all equations have at least one pattern, and
 469 -- all have the same number of patterns
 470 okGroup [] = True
 471 okGroup (e:es) = n_pats > 0 && and [length (eqnPats e) == n_pats | e <- es]
 472                where
 473                  n_pats = length (eqnPats e)
 474
 475 -- Half-baked print
 476 pprGroup es = vcat (map pprEqnInfo es)
 477 pprEqnInfo e = ppr (eqnPats e)
 478
 479
 480 firstPatN :: (EqnNo, EquationInfo) -> Pat Id
 481 firstPatN (_, eqn) = firstPat eqn
 482
 483 is_con :: Pat Id -> Bool
 484 is_con (ConPatOut {}) = True
 485 is_con _              = False
 486
 487 is_lit :: Pat Id -> Bool
 488 is_lit (LitPat _)      = True
 489 is_lit (NPat _ _ _)  = True
 490 is_lit _               = False
 491
 492 is_var :: Pat Id -> Bool
 493 is_var (WildPat _) = True
 494 is_var _           = False
 495
 496 is_var_con :: DataCon -> Pat Id -> Bool
 497 is_var_con con (WildPat _)                                 = True
 498 is_var_con con (ConPatOut{ pat_con = L _ id }) | id == con = True
 499 is_var_con con _                                           = False
 500
 501 is_var_lit :: HsLit -> Pat Id -> Bool
 502 is_var_lit lit (WildPat _)   = True
 503 is_var_lit lit pat
 504   | Just lit' <- get_lit pat = lit == lit'
 505   | otherwise                = False
 506 \end{code}
 507
 508 The difference beteewn @make_con@ and @make_whole_con@ is that
 509 @make_wole_con@ creates a new constructor with all their arguments, and
 510 @make_con@ takes a list of argumntes, creates the contructor getting their
 511 arguments from the list. See where \fbox{\ ???\ } are used for details.
 512
 513 We need to reconstruct the patterns (make the constructors infix and
 514 similar) at the same time that we create the constructors.
 515
 516 You can tell tuple constructors using
 517 \begin{verbatim}
 518         Id.isTupleCon
 519 \end{verbatim}
 520 You can see if one constructor is infix with this clearer code :-))))))))))
 521 \begin{verbatim}
 522         Lex.isLexConSym (Name.occNameString (Name.getOccName con))
 523 \end{verbatim}
 524
 525        Rather clumsy but it works. (Simon Peyton Jones)
 526
 527
 528 We don't mind the @nilDataCon@ because it doesn't change the way to
 529 print the messsage, we are searching only for things like: @[1,2,3]@,
 530 not @x:xs@ ....
 531
 532 In @reconstruct_pat@ we want to ``undo'' the work
 533 that we have done in @simplify_pat@.
 534 In particular:
 535 \begin{tabular}{lll}
 536         @((,) x y)@   & returns to be & @(x, y)@
 537 \\      @((:) x xs)@  & returns to be & @(x:xs)@
 538 \\      @(x:(...:[])@ & returns to be & @[x,...]@
 539 \end{tabular}
 540 %
 541 The difficult case is the third one becouse we need to follow all the
 542 contructors until the @[]@ to know that we need to use the second case,
 543 not the second. \fbox{\ ???\ }
 544 %
 545 \begin{code}
 546 isInfixCon con = isDataSymOcc (getOccName con)
 547
 548 is_nil (ConPatIn con (PrefixCon [])) = unLoc con == getName nilDataCon
 549 is_nil _                             = False
 550
 551 is_list (ListPat _ _) = True
 552 is_list _             = False
 553
 554 return_list id q = id == consDataCon && (is_nil q || is_list q)
 555
 556 make_list p q | is_nil q    = ListPat [p] placeHolderType
 557 make_list p (ListPat ps ty) = ListPat (p:ps) ty
 558 make_list _ _               = panic "Check.make_list: Invalid argument"
 559
 560 make_con :: Pat Id -> ExhaustivePat -> ExhaustivePat
 561 make_con (ConPatOut{ pat_con = L _ id }) (lp:lq:ps, constraints)
 562      | return_list id q = (noLoc (make_list lp q) : ps, constraints)
 563      | isInfixCon id    = (nlInfixConPat (getName id) lp lq : ps, constraints)
 564    where q  = unLoc lq
 565
 566 make_con (ConPatOut{ pat_con = L _ id, pat_args = PrefixCon pats, pat_ty = ty }) (ps, constraints)
 567       | isTupleTyCon tc  = (noLoc (TuplePat pats_con (tupleTyConBoxity tc) ty) : rest_pats, constraints)
 568       | isPArrFakeCon id = (noLoc (PArrPat pats_con placeHolderType)           : rest_pats, constraints)
 569       | otherwise        = (nlConPat name pats_con      : rest_pats, constraints)
 570     where
 571         name                  = getName id
 572         (pats_con, rest_pats) = splitAtList pats ps
 573         tc                    = dataConTyCon id
 574
 575 -- reconstruct parallel array pattern
 576 --
 577 --  * don't check for the type only; we need to make sure that we are really
 578 --   dealing with one of the fake constructors and not with the real
 579 --   representation
 580
 581 make_whole_con :: DataCon -> WarningPat
 582 make_whole_con con | isInfixCon con = nlInfixConPat name nlWildPat nlWildPat
 583                    | otherwise      = nlConPat name pats
 584                 where
 585                   name   = getName con
 586                   pats   = [nlWildPat | t <- dataConOrigArgTys con]
 587 \end{code}
 588
 589 This equation makes the same thing as @tidy@ in @Match.lhs@, the
 590 difference is that here we can do all the tidy in one place and in the
 591 @Match@ tidy it must be done one column each time due to bookkeeping
 592 constraints.
 593
 594 \begin{code}
 595
 596 simplify_eqn :: EquationInfo -> EquationInfo
 597 simplify_eqn eqn = eqn { eqn_pats = map simplify_pat (eqn_pats eqn),
 598                          eqn_rhs  = simplify_rhs (eqn_rhs eqn) }
 599   where
 600         -- Horrible hack.  The simplify_pat stuff converts NPlusK pats to WildPats
 601         -- which of course loses the info that they can fail to match.  So we
 602         -- stick in a CanFail as if it were a guard.
 603         -- The Right Thing to do is for the whole system to treat NPlusK pats properly
 604     simplify_rhs (MatchResult can_fail body)
 605         | any has_nplusk_pat (eqn_pats eqn) = MatchResult CanFail body
 606         | otherwise                         = MatchResult can_fail body
 607
 608 has_nplusk_lpat :: LPat Id -> Bool
 609 has_nplusk_lpat (L _ p) = has_nplusk_pat p
 610
 611 has_nplusk_pat :: Pat Id -> Bool
 612 has_nplusk_pat (NPlusKPat _ _ _ _)           = True
 613 has_nplusk_pat (ParPat p)                    = has_nplusk_lpat p
 614 has_nplusk_pat (AsPat _ p)                   = has_nplusk_lpat p
 615 has_nplusk_pat (ViewPat _ p _)           = has_nplusk_lpat p
 616 has_nplusk_pat (SigPatOut p _ )              = has_nplusk_lpat p
 617 has_nplusk_pat (ListPat ps _)                = any has_nplusk_lpat ps
 618 has_nplusk_pat (TuplePat ps _ _)             = any has_nplusk_lpat ps
 619 has_nplusk_pat (PArrPat ps _)                = any has_nplusk_lpat ps
 620 has_nplusk_pat (LazyPat p)                   = False    -- Why?
 621 has_nplusk_pat (BangPat p)                   = has_nplusk_lpat p        -- I think
 622 has_nplusk_pat (ConPatOut { pat_args = ps }) = any has_nplusk_lpat (hsConPatArgs ps)
 623 has_nplusk_pat p = False        -- VarPat, VarPatOut, WildPat, LitPat, NPat, TypePat
 624
 625 simplify_lpat :: LPat Id -> LPat Id
 626 simplify_lpat p = fmap simplify_pat p
 627
 628 simplify_pat :: Pat Id -> Pat Id
 629 simplify_pat pat@(WildPat gt) = pat
 630 simplify_pat (VarPat id)      = WildPat (idType id)
 631 simplify_pat (VarPatOut id _) = WildPat (idType id)     -- Ignore the bindings
 632 simplify_pat (ParPat p)       = unLoc (simplify_lpat p)
 633 simplify_pat (LazyPat p)      = WildPat (hsLPatType p)  -- For overlap and exhaustiveness checking
 634                                                         -- purposes, a ~pat is like a wildcard
 635 simplify_pat (BangPat p)      = unLoc (simplify_lpat p)
 636 simplify_pat (AsPat id p)     = unLoc (simplify_lpat p)
 637
 638 simplify_pat (ViewPat expr p ty)     = ViewPat expr (simplify_lpat p) ty
 639
 640 simplify_pat (SigPatOut p _)  = unLoc (simplify_lpat p) -- I'm not sure this is right
 641
 642 simplify_pat pat@(ConPatOut { pat_con = L loc id, pat_args = ps })
 643   = pat { pat_args = simplify_con id ps }
 644
 645 simplify_pat (ListPat ps ty) =
 646   unLoc $ foldr (\ x y -> mkPrefixConPat consDataCon [x,y] list_ty)
 647                                   (mkNilPat list_ty)
 648                                   (map simplify_lpat ps)
 649          where list_ty = mkListTy ty
 650
 651 -- introduce fake parallel array constructors to be able to handle parallel
 652 -- arrays with the existing machinery for constructor pattern
 653 --
 654 simplify_pat (PArrPat ps ty)
 655   = unLoc $ mkPrefixConPat (parrFakeCon (length ps))
 656                            (map simplify_lpat ps)
 657                            (mkPArrTy ty)
 658
 659 simplify_pat (TuplePat ps boxity ty)
 660   = unLoc $ mkPrefixConPat (tupleCon boxity arity)
 661                            (map simplify_lpat ps) ty
 662   where
 663     arity = length ps
 664
 665 -- unpack string patterns fully, so we can see when they overlap with
 666 -- each other, or even explicit lists of Chars.
 667 simplify_pat pat@(LitPat (HsString s)) =
 668    unLoc $ foldr (\c pat -> mkPrefixConPat consDataCon [mk_char_lit c, pat] stringTy)
 669                  (mkPrefixConPat nilDataCon [] stringTy) (unpackFS s)
 670   where
 671     mk_char_lit c = mkPrefixConPat charDataCon [nlLitPat (HsCharPrim c)] charTy
 672
 673 simplify_pat (LitPat lit)                = tidyLitPat lit
 674 simplify_pat (NPat lit mb_neg eq) = tidyNPat lit mb_neg eq
 675
 676 simplify_pat (NPlusKPat id hslit hsexpr1 hsexpr2)
 677    = WildPat (idType (unLoc id))
 678
 679 simplify_pat (CoPat co pat ty) = simplify_pat pat
 680
 681 -----------------
 682 simplify_con con (PrefixCon ps)   = PrefixCon (map simplify_lpat ps)
 683 simplify_con con (InfixCon p1 p2) = PrefixCon [simplify_lpat p1, simplify_lpat p2]
 684 simplify_con con (RecCon (HsRecFields fs _))
 685   | null fs   = PrefixCon [nlWildPat | t <- dataConOrigArgTys con]
 686                 -- Special case for null patterns; maybe not a record at all
 687   | otherwise = PrefixCon (map (simplify_lpat.snd) all_pats)
 688   where
 689      -- pad out all the missing fields with WildPats.
 690     field_pats = map (\ f -> (f, nlWildPat)) (dataConFieldLabels con)
 691     all_pats = foldr (\(HsRecField id p _) acc -> insertNm (getName (unLoc id)) p acc)
 692                      field_pats fs
 693
 694     insertNm nm p [] = [(nm,p)]
 695     insertNm nm p (x@(n,_):xs)
 696       | nm == n    = (nm,p):xs
 697       | otherwise  = x : insertNm nm p xs
 698 \end{code}