compiler/deSugar/Check.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1997-1998
   4 %
   5 % Author: Juan J. Quintela    <quintela@krilin.dc.fi.udc.es>
   6
   7 \begin{code}
   8 {-# OPTIONS -fno-warn-incomplete-patterns #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module Check ( check , ExhaustivePat ) where
  16
  17 #include "HsVersions.h"
  18
  19 import HsSyn
  20 import TcHsSyn
  21 import DsUtils
  22 import MatchLit
  23 import Id
  24 import DataCon
  25 import Name
  26 import TysWiredIn
  27 import PrelNames
  28 import TyCon
  29 import Type
  30 import Unify( dataConCannotMatch )
  31 import SrcLoc
  32 import UniqSet
  33 import Util
  34 import Outputable
  35 import FastString
  36 \end{code}
  37
  38 This module performs checks about if one list of equations are:
  39 \begin{itemize}
  40 \item Overlapped
  41 \item Non exhaustive
  42 \end{itemize}
  43 To discover that we go through the list of equations in a tree-like fashion.
  44
  45 If you like theory, a similar algorithm is described in:
  46 \begin{quotation}
  47         {\em Two Techniques for Compiling Lazy Pattern Matching},
  48         Luc Maranguet,
  49         INRIA Rocquencourt (RR-2385, 1994)
  50 \end{quotation}
  51 The algorithm is based on the first technique, but there are some differences:
  52 \begin{itemize}
  53 \item We don't generate code
  54 \item We have constructors and literals (not only literals as in the
  55           article)
  56 \item We don't use directions, we must select the columns from
  57           left-to-right
  58 \end{itemize}
  59 (By the way the second technique is really similar to the one used in
  60  @Match.lhs@ to generate code)
  61
  62 This function takes the equations of a pattern and returns:
  63 \begin{itemize}
  64 \item The patterns that are not recognized
  65 \item The equations that are not overlapped
  66 \end{itemize}
  67 It simplify the patterns and then call @check'@ (the same semantics), and it
  68 needs to reconstruct the patterns again ....
  69
  70 The problem appear with things like:
  71 \begin{verbatim}
  72   f [x,y]   = ....
  73   f (x:xs)  = .....
  74 \end{verbatim}
  75 We want to put the two patterns with the same syntax, (prefix form) and
  76 then all the constructors are equal:
  77 \begin{verbatim}
  78   f (: x (: y []))   = ....
  79   f (: x xs)         = .....
  80 \end{verbatim}
  81 (more about that in @tidy_eqns@)
  82
  83 We would prefer to have a @WarningPat@ of type @String@, but Strings and the
  84 Pretty Printer are not friends.
  85
  86 We use @InPat@ in @WarningPat@ instead of @OutPat@
  87 because we need to print the
  88 warning messages in the same way they are introduced, i.e. if the user
  89 wrote:
  90 \begin{verbatim}
  91         f [x,y] = ..
  92 \end{verbatim}
  93 He don't want a warning message written:
  94 \begin{verbatim}
  95         f (: x (: y [])) ........
  96 \end{verbatim}
  97 Then we need to use InPats.
  98 \begin{quotation}
  99      Juan Quintela 5 JUL 1998\\
 100           User-friendliness and compiler writers are no friends.
 101 \end{quotation}
 102
 103 \begin{code}
 104 type WarningPat = InPat Name
 105 type ExhaustivePat = ([WarningPat], [(Name, [HsLit])])
 106 type EqnNo  = Int
 107 type EqnSet = UniqSet EqnNo
 108
 109
 110 check :: [EquationInfo] -> ([ExhaustivePat], [EquationInfo])
 111   -- Second result is the shadowed equations
 112   -- if there are view patterns, just give up - don't know what the function is
 113 check qs = pprTrace "check" (ppr tidy_qs) $
 114            (untidy_warns, shadowed_eqns)
 115       where
 116         tidy_qs = map tidy_eqn qs
 117         (warns, used_nos) = check' ([1..] `zip` tidy_qs)
 118         untidy_warns = map untidy_exhaustive warns
 119         shadowed_eqns = [eqn | (eqn,i) <- qs `zip` [1..],
 120                                 not (i `elementOfUniqSet` used_nos)]
 121
 122 untidy_exhaustive :: ExhaustivePat -> ExhaustivePat
 123 untidy_exhaustive ([pat], messages) =
 124                   ([untidy_no_pars pat], map untidy_message messages)
 125 untidy_exhaustive (pats, messages) =
 126                   (map untidy_pars pats, map untidy_message messages)
 127
 128 untidy_message :: (Name, [HsLit]) -> (Name, [HsLit])
 129 untidy_message (string, lits) = (string, map untidy_lit lits)
 130 \end{code}
 131
 132 The function @untidy@ does the reverse work of the @tidy_pat@ funcion.
 133
 134 \begin{code}
 135
 136 type NeedPars = Bool
 137
 138 untidy_no_pars :: WarningPat -> WarningPat
 139 untidy_no_pars p = untidy False p
 140
 141 untidy_pars :: WarningPat -> WarningPat
 142 untidy_pars p = untidy True p
 143
 144 untidy :: NeedPars -> WarningPat -> WarningPat
 145 untidy b (L loc p) = L loc (untidy' b p)
 146   where
 147     untidy' _ p@(WildPat _)          = p
 148     untidy' _ p@(VarPat _)           = p
 149     untidy' _ (LitPat lit)           = LitPat (untidy_lit lit)
 150     untidy' _ p@(ConPatIn _ (PrefixCon [])) = p
 151     untidy' b (ConPatIn name ps)     = pars b (L loc (ConPatIn name (untidy_con ps)))
 152     untidy' _ (ListPat pats ty)      = ListPat (map untidy_no_pars pats) ty
 153     untidy' _ (TuplePat pats box ty) = TuplePat (map untidy_no_pars pats) box ty
 154     untidy' _ (PArrPat _ _)          = panic "Check.untidy: Shouldn't get a parallel array here!"
 155     untidy' _ (SigPatIn _ _)         = panic "Check.untidy: SigPat"
 156
 157 untidy_con :: HsConPatDetails Name -> HsConPatDetails Name
 158 untidy_con (PrefixCon pats) = PrefixCon (map untidy_pars pats)
 159 untidy_con (InfixCon p1 p2) = InfixCon  (untidy_pars p1) (untidy_pars p2)
 160 untidy_con (RecCon (HsRecFields flds dd))
 161   = RecCon (HsRecFields [ fld { hsRecFieldArg = untidy_pars (hsRecFieldArg fld) }
 162                         | fld <- flds ] dd)
 163
 164 pars :: NeedPars -> WarningPat -> Pat Name
 165 pars True p = ParPat p
 166 pars _    p = unLoc p
 167
 168 untidy_lit :: HsLit -> HsLit
 169 untidy_lit (HsCharPrim c) = HsChar c
 170 untidy_lit lit            = lit
 171 \end{code}
 172
 173 This equation is the same that check, the only difference is that the
 174 boring work is done, that work needs to be done only once, this is
 175 the reason top have two functions, check is the external interface,
 176 @check'@ is called recursively.
 177
 178 There are several cases:
 179
 180 \begin{itemize}
 181 \item There are no equations: Everything is OK.
 182 \item There are only one equation, that can fail, and all the patterns are
 183       variables. Then that equation is used and the same equation is
 184       non-exhaustive.
 185 \item All the patterns are variables, and the match can fail, there are
 186       more equations then the results is the result of the rest of equations
 187       and this equation is used also.
 188
 189 \item The general case, if all the patterns are variables (here the match
 190       can't fail) then the result is that this equation is used and this
 191       equation doesn't generate non-exhaustive cases.
 192
 193 \item In the general case, there can exist literals ,constructors or only
 194       vars in the first column, we actuate in consequence.
 195
 196 \end{itemize}
 197
 198
 199 \begin{code}
 200
 201 check' :: [(EqnNo, EquationInfo)]
 202         -> ([ExhaustivePat],    -- Pattern scheme that might not be matched at all
 203             EqnSet)             -- Eqns that are used (others are overlapped)
 204
 205 check' [] = ([([],[])],emptyUniqSet)
 206
 207 check' ((n, EqnInfo { eqn_pats = ps, eqn_rhs = MatchResult can_fail _ }) : rs)
 208    | first_eqn_all_vars && case can_fail of { CantFail -> True; CanFail -> False }
 209    = ([], unitUniqSet n)        -- One eqn, which can't fail
 210
 211    | first_eqn_all_vars && null rs      -- One eqn, but it can fail
 212    = ([(takeList ps (repeat nlWildPat),[])], unitUniqSet n)
 213
 214    | first_eqn_all_vars         -- Several eqns, first can fail
 215    = (pats, addOneToUniqSet indexs n)
 216   where
 217     first_eqn_all_vars = all_vars ps
 218     (pats,indexs) = check' rs
 219
 220 check' qs
 221    | some_literals     = split_by_literals qs
 222    | some_constructors = split_by_constructor qs
 223    | only_vars         = first_column_only_vars qs
 224    | otherwise = pprPanic "Check.check': Not implemented :-(" (ppr first_pats)
 225                  -- Shouldn't happen
 226   where
 227      -- Note: RecPats will have been simplified to ConPats
 228      --       at this stage.
 229     first_pats        = ASSERT2( okGroup qs, pprGroup qs ) map firstPatN qs
 230     some_constructors = any is_con first_pats
 231     some_literals     = any is_lit first_pats
 232     only_vars         = all is_var first_pats
 233 \end{code}
 234
 235 Here begins the code to deal with literals, we need to split the matrix
 236 in different matrix beginning by each literal and a last matrix with the
 237 rest of values.
 238
 239 \begin{code}
 240 split_by_literals :: [(EqnNo, EquationInfo)] -> ([ExhaustivePat], EqnSet)
 241 split_by_literals qs = process_literals used_lits qs
 242            where
 243              used_lits = get_used_lits qs
 244 \end{code}
 245
 246 @process_explicit_literals@ is a function that process each literal that appears
 247 in the column of the matrix.
 248
 249 \begin{code}
 250 process_explicit_literals :: [HsLit] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 251 process_explicit_literals lits qs = (concat pats, unionManyUniqSets indexs)
 252     where
 253       pats_indexs   = map (\x -> construct_literal_matrix x qs) lits
 254       (pats,indexs) = unzip pats_indexs
 255 \end{code}
 256
 257
 258 @process_literals@ calls @process_explicit_literals@ to deal with the literals
 259 that appears in the matrix and deal also with the rest of the cases. It
 260 must be one Variable to be complete.
 261
 262 \begin{code}
 263
 264 process_literals :: [HsLit] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 265 process_literals used_lits qs
 266   | null default_eqns  = ASSERT( not (null qs) ) ([make_row_vars used_lits (head qs)] ++ pats,indexs)
 267   | otherwise          = (pats_default,indexs_default)
 268      where
 269        (pats,indexs)   = process_explicit_literals used_lits qs
 270        default_eqns    = ASSERT2( okGroup qs, pprGroup qs )
 271                          [remove_var q | q <- qs, is_var (firstPatN q)]
 272        (pats',indexs') = check' default_eqns
 273        pats_default    = [(nlWildPat:ps,constraints) | (ps,constraints) <- (pats')] ++ pats
 274        indexs_default  = unionUniqSets indexs' indexs
 275 \end{code}
 276
 277 Here we have selected the literal and we will select all the equations that
 278 begins for that literal and create a new matrix.
 279
 280 \begin{code}
 281 construct_literal_matrix :: HsLit -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 282 construct_literal_matrix lit qs =
 283     (map (\ (xs,ys) -> (new_lit:xs,ys)) pats,indexs)
 284   where
 285     (pats,indexs) = (check' (remove_first_column_lit lit qs))
 286     new_lit = nlLitPat lit
 287
 288 remove_first_column_lit :: HsLit
 289                         -> [(EqnNo, EquationInfo)]
 290                         -> [(EqnNo, EquationInfo)]
 291 remove_first_column_lit lit qs
 292   = ASSERT2( okGroup qs, pprGroup qs )
 293     [(n, shift_pat eqn) | q@(n,eqn) <- qs, is_var_lit lit (firstPatN q)]
 294   where
 295      shift_pat eqn@(EqnInfo { eqn_pats = _:ps}) = eqn { eqn_pats = ps }
 296      shift_pat _                                = panic "Check.shift_var: no patterns"
 297 \end{code}
 298
 299 This function splits the equations @qs@ in groups that deal with the
 300 same constructor.
 301
 302 \begin{code}
 303 split_by_constructor :: [(EqnNo, EquationInfo)] -> ([ExhaustivePat], EqnSet)
 304 split_by_constructor qs
 305   | notNull unused_cons = need_default_case used_cons unused_cons qs
 306   | otherwise           = no_need_default_case used_cons qs
 307                        where
 308                           used_cons   = get_used_cons qs
 309                           unused_cons = get_unused_cons used_cons
 310 \end{code}
 311
 312 The first column of the patterns matrix only have vars, then there is
 313 nothing to do.
 314
 315 \begin{code}
 316 first_column_only_vars :: [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 317 first_column_only_vars qs = (map (\ (xs,ys) -> (nlWildPat:xs,ys)) pats,indexs)
 318                           where
 319                             (pats, indexs) = check' (map remove_var qs)
 320 \end{code}
 321
 322 This equation takes a matrix of patterns and split the equations by
 323 constructor, using all the constructors that appears in the first column
 324 of the pattern matching.
 325
 326 We can need a default clause or not ...., it depends if we used all the
 327 constructors or not explicitly. The reasoning is similar to @process_literals@,
 328 the difference is that here the default case is not always needed.
 329
 330 \begin{code}
 331 no_need_default_case :: [Pat Id] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 332 no_need_default_case cons qs = (concat pats, unionManyUniqSets indexs)
 333     where
 334       pats_indexs   = map (\x -> construct_matrix x qs) cons
 335       (pats,indexs) = unzip pats_indexs
 336
 337 need_default_case :: [Pat Id] -> [DataCon] -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 338 need_default_case used_cons unused_cons qs
 339   | null default_eqns  = (pats_default_no_eqns,indexs)
 340   | otherwise          = (pats_default,indexs_default)
 341      where
 342        (pats,indexs)   = no_need_default_case used_cons qs
 343        default_eqns    = ASSERT2( okGroup qs, pprGroup qs )
 344                          [remove_var q | q <- qs, is_var (firstPatN q)]
 345        (pats',indexs') = check' default_eqns
 346        pats_default    = [(make_whole_con c:ps,constraints) |
 347                           c <- unused_cons, (ps,constraints) <- pats'] ++ pats
 348        new_wilds       = ASSERT( not (null qs) ) make_row_vars_for_constructor (head qs)
 349        pats_default_no_eqns =  [(make_whole_con c:new_wilds,[]) | c <- unused_cons] ++ pats
 350        indexs_default  = unionUniqSets indexs' indexs
 351
 352 construct_matrix :: Pat Id -> [(EqnNo, EquationInfo)] -> ([ExhaustivePat],EqnSet)
 353 construct_matrix con qs =
 354     (map (make_con con) pats,indexs)
 355   where
 356     (pats,indexs) = (check' (remove_first_column con qs))
 357 \end{code}
 358
 359 Here remove first column is more difficult that with literals due to the fact
 360 that constructors can have arguments.
 361
 362 For instance, the matrix
 363 \begin{verbatim}
 364  (: x xs) y
 365  z        y
 366 \end{verbatim}
 367 is transformed in:
 368 \begin{verbatim}
 369  x xs y
 370  _ _  y
 371 \end{verbatim}
 372
 373 \begin{code}
 374 remove_first_column :: Pat Id                -- Constructor
 375                     -> [(EqnNo, EquationInfo)]
 376                     -> [(EqnNo, EquationInfo)]
 377 remove_first_column (ConPatOut{ pat_con = L _ con, pat_args = PrefixCon con_pats }) qs
 378   = ASSERT2( okGroup qs, pprGroup qs )
 379     [(n, shift_var eqn) | q@(n, eqn) <- qs, is_var_con con (firstPatN q)]
 380   where
 381      new_wilds = [WildPat (hsLPatType arg_pat) | arg_pat <- con_pats]
 382      shift_var eqn@(EqnInfo { eqn_pats = ConPatOut{ pat_args = PrefixCon ps' } : ps})
 383         = eqn { eqn_pats = map unLoc ps' ++ ps }
 384      shift_var eqn@(EqnInfo { eqn_pats = WildPat _ : ps })
 385         = eqn { eqn_pats = new_wilds ++ ps }
 386      shift_var _ = panic "Check.Shift_var:No done"
 387
 388 make_row_vars :: [HsLit] -> (EqnNo, EquationInfo) -> ExhaustivePat
 389 make_row_vars used_lits (_, EqnInfo { eqn_pats = pats})
 390    = (nlVarPat new_var:takeList (tail pats) (repeat nlWildPat),[(new_var,used_lits)])
 391   where
 392      new_var = hash_x
 393
 394 hash_x :: Name
 395 hash_x = mkInternalName unboundKey {- doesn't matter much -}
 396                      (mkVarOccFS (fsLit "#x"))
 397                      noSrcSpan
 398
 399 make_row_vars_for_constructor :: (EqnNo, EquationInfo) -> [WarningPat]
 400 make_row_vars_for_constructor (_, EqnInfo { eqn_pats = pats})
 401   = takeList (tail pats) (repeat nlWildPat)
 402
 403 compare_cons :: Pat Id -> Pat Id -> Bool
 404 compare_cons (ConPatOut{ pat_con = L _ id1 }) (ConPatOut { pat_con = L _ id2 }) = id1 == id2
 405
 406 remove_dups :: [Pat Id] -> [Pat Id]
 407 remove_dups []     = []
 408 remove_dups (x:xs) | or (map (\y -> compare_cons x y) xs) = remove_dups  xs
 409                    | otherwise                            = x : remove_dups xs
 410
 411 get_used_cons :: [(EqnNo, EquationInfo)] -> [Pat Id]
 412 get_used_cons qs = remove_dups [pat | q <- qs, let pat = firstPatN q,
 413                                       isConPatOut pat]
 414
 415 isConPatOut :: Pat Id -> Bool
 416 isConPatOut (ConPatOut {}) = True
 417 isConPatOut _              = False
 418
 419 remove_dups' :: [HsLit] -> [HsLit]
 420 remove_dups' []                   = []
 421 remove_dups' (x:xs) | x `elem` xs = remove_dups' xs
 422                     | otherwise   = x : remove_dups' xs
 423
 424
 425 get_used_lits :: [(EqnNo, EquationInfo)] -> [HsLit]
 426 get_used_lits qs = remove_dups' all_literals
 427                  where
 428                    all_literals = get_used_lits' qs
 429
 430 get_used_lits' :: [(EqnNo, EquationInfo)] -> [HsLit]
 431 get_used_lits' [] = []
 432 get_used_lits' (q:qs)
 433   | Just lit <- get_lit (firstPatN q) = lit : get_used_lits' qs
 434   | otherwise                         = get_used_lits qs
 435
 436 get_lit :: Pat id -> Maybe HsLit
 437 -- Get a representative HsLit to stand for the OverLit
 438 -- It doesn't matter which one, because they will only be compared
 439 -- with other HsLits gotten in the same way
 440 get_lit (LitPat lit)                                      = Just lit
 441 get_lit (NPat (OverLit { ol_val = HsIntegral i})    mb _) = Just (HsIntPrim   (mb_neg mb i))
 442 get_lit (NPat (OverLit { ol_val = HsFractional f }) mb _) = Just (HsFloatPrim (mb_neg mb f))
 443 get_lit (NPat (OverLit { ol_val = HsIsString s })   _  _) = Just (HsStringPrim s)
 444 get_lit _                                                 = Nothing
 445
 446 mb_neg :: Num a => Maybe b -> a -> a
 447 mb_neg Nothing  v = v
 448 mb_neg (Just _) v = -v
 449
 450 get_unused_cons :: [Pat Id] -> [DataCon]
 451 get_unused_cons used_cons = ASSERT( not (null used_cons) ) unused_cons
 452      where
 453        used_set :: UniqSet DataCon
 454        used_set = mkUniqSet [d | ConPatOut{ pat_con = L _ d} <- used_cons]
 455        (ConPatOut { pat_ty = ty }) = head used_cons
 456        Just (ty_con, inst_tys) = splitTyConApp_maybe ty
 457        unused_cons = filterOut is_used (tyConDataCons ty_con)
 458        is_used con = con `elementOfUniqSet` used_set
 459                      || dataConCannotMatch inst_tys con
 460
 461 all_vars :: [Pat Id] -> Bool
 462 all_vars []             = True
 463 all_vars (WildPat _:ps) = all_vars ps
 464 all_vars _              = False
 465
 466 remove_var :: (EqnNo, EquationInfo) -> (EqnNo, EquationInfo)
 467 remove_var (n, eqn@(EqnInfo { eqn_pats = WildPat _ : ps})) = (n, eqn { eqn_pats = ps })
 468 remove_var _  = panic "Check.remove_var: equation does not begin with a variable"
 469
 470 -----------------------
 471 eqnPats :: (EqnNo, EquationInfo) -> [Pat Id]
 472 eqnPats (_, eqn) = eqn_pats eqn
 473
 474 okGroup :: [(EqnNo, EquationInfo)] -> Bool
 475 -- True if all equations have at least one pattern, and
 476 -- all have the same number of patterns
 477 okGroup [] = True
 478 okGroup (e:es) = n_pats > 0 && and [length (eqnPats e) == n_pats | e <- es]
 479                where
 480                  n_pats = length (eqnPats e)
 481
 482 -- Half-baked print
 483 pprGroup :: [(EqnNo, EquationInfo)] -> SDoc
 484 pprEqnInfo :: (EqnNo, EquationInfo) -> SDoc
 485 pprGroup es = vcat (map pprEqnInfo es)
 486 pprEqnInfo e = ppr (eqnPats e)
 487
 488
 489 firstPatN :: (EqnNo, EquationInfo) -> Pat Id
 490 firstPatN (_, eqn) = firstPat eqn
 491
 492 is_con :: Pat Id -> Bool
 493 is_con (ConPatOut {}) = True
 494 is_con _              = False
 495
 496 is_lit :: Pat Id -> Bool
 497 is_lit (LitPat _)      = True
 498 is_lit (NPat _ _ _)  = True
 499 is_lit _               = False
 500
 501 is_var :: Pat Id -> Bool
 502 is_var (WildPat _) = True
 503 is_var _           = False
 504
 505 is_var_con :: DataCon -> Pat Id -> Bool
 506 is_var_con _   (WildPat _)                                 = True
 507 is_var_con con (ConPatOut{ pat_con = L _ id }) | id == con = True
 508 is_var_con _   _                                           = False
 509
 510 is_var_lit :: HsLit -> Pat Id -> Bool
 511 is_var_lit _   (WildPat _)   = True
 512 is_var_lit lit pat
 513   | Just lit' <- get_lit pat = lit == lit'
 514   | otherwise                = False
 515 \end{code}
 516
 517 The difference beteewn @make_con@ and @make_whole_con@ is that
 518 @make_wole_con@ creates a new constructor with all their arguments, and
 519 @make_con@ takes a list of argumntes, creates the contructor getting their
 520 arguments from the list. See where \fbox{\ ???\ } are used for details.
 521
 522 We need to reconstruct the patterns (make the constructors infix and
 523 similar) at the same time that we create the constructors.
 524
 525 You can tell tuple constructors using
 526 \begin{verbatim}
 527         Id.isTupleCon
 528 \end{verbatim}
 529 You can see if one constructor is infix with this clearer code :-))))))))))
 530 \begin{verbatim}
 531         Lex.isLexConSym (Name.occNameString (Name.getOccName con))
 532 \end{verbatim}
 533
 534        Rather clumsy but it works. (Simon Peyton Jones)
 535
 536
 537 We don't mind the @nilDataCon@ because it doesn't change the way to
 538 print the messsage, we are searching only for things like: @[1,2,3]@,
 539 not @x:xs@ ....
 540
 541 In @reconstruct_pat@ we want to ``undo'' the work
 542 that we have done in @tidy_pat@.
 543 In particular:
 544 \begin{tabular}{lll}
 545         @((,) x y)@   & returns to be & @(x, y)@
 546 \\      @((:) x xs)@  & returns to be & @(x:xs)@
 547 \\      @(x:(...:[])@ & returns to be & @[x,...]@
 548 \end{tabular}
 549 %
 550 The difficult case is the third one becouse we need to follow all the
 551 contructors until the @[]@ to know that we need to use the second case,
 552 not the second. \fbox{\ ???\ }
 553 %
 554 \begin{code}
 555 isInfixCon :: DataCon -> Bool
 556 isInfixCon con = isDataSymOcc (getOccName con)
 557
 558 is_nil :: Pat Name -> Bool
 559 is_nil (ConPatIn con (PrefixCon [])) = unLoc con == getName nilDataCon
 560 is_nil _                             = False
 561
 562 is_list :: Pat Name -> Bool
 563 is_list (ListPat _ _) = True
 564 is_list _             = False
 565
 566 return_list :: DataCon -> Pat Name -> Bool
 567 return_list id q = id == consDataCon && (is_nil q || is_list q)
 568
 569 make_list :: LPat Name -> Pat Name -> Pat Name
 570 make_list p q | is_nil q    = ListPat [p] placeHolderType
 571 make_list p (ListPat ps ty) = ListPat (p:ps) ty
 572 make_list _ _               = panic "Check.make_list: Invalid argument"
 573
 574 make_con :: Pat Id -> ExhaustivePat -> ExhaustivePat
 575 make_con (ConPatOut{ pat_con = L _ id }) (lp:lq:ps, constraints)
 576      | return_list id q = (noLoc (make_list lp q) : ps, constraints)
 577      | isInfixCon id    = (nlInfixConPat (getName id) lp lq : ps, constraints)
 578    where q  = unLoc lq
 579
 580 make_con (ConPatOut{ pat_con = L _ id, pat_args = PrefixCon pats, pat_ty = ty }) (ps, constraints)
 581       | isTupleTyCon tc  = (noLoc (TuplePat pats_con (tupleTyConBoxity tc) ty) : rest_pats, constraints)
 582       | isPArrFakeCon id = (noLoc (PArrPat pats_con placeHolderType)           : rest_pats, constraints)
 583       | otherwise        = (nlConPat name pats_con      : rest_pats, constraints)
 584     where
 585         name                  = getName id
 586         (pats_con, rest_pats) = splitAtList pats ps
 587         tc                    = dataConTyCon id
 588
 589 -- reconstruct parallel array pattern
 590 --
 591 --  * don't check for the type only; we need to make sure that we are really
 592 --   dealing with one of the fake constructors and not with the real
 593 --   representation
 594
 595 make_whole_con :: DataCon -> WarningPat
 596 make_whole_con con | isInfixCon con = nlInfixConPat name nlWildPat nlWildPat
 597                    | otherwise      = nlConPat name pats
 598                 where
 599                   name   = getName con
 600                   pats   = [nlWildPat | _ <- dataConOrigArgTys con]
 601 \end{code}
 602
 603 ------------------------------------------------------------------------
 604                    Tidying equations
 605 ------------------------------------------------------------------------
 606
 607 tidy_eqn does more or less the same thing as @tidy@ in @Match.lhs@;
 608 that is, it removes syntactic sugar, reducing the number of cases that
 609 must be handled by the main checking algorithm.  One difference is
 610 that here we can do *all* the tidying at once (recursively), rather
 611 than doing it incrementally.
 612
 613 \begin{code}
 614 tidy_eqn :: EquationInfo -> EquationInfo
 615 tidy_eqn eqn = eqn { eqn_pats = map tidy_pat (eqn_pats eqn),
 616                      eqn_rhs  = tidy_rhs (eqn_rhs eqn) }
 617   where
 618         -- Horrible hack.  The tidy_pat stuff converts "might-fail" patterns to
 619         -- WildPats which of course loses the info that they can fail to match.
 620         -- So we stick in a CanFail as if it were a guard.
 621     tidy_rhs (MatchResult can_fail body)
 622         | any might_fail_pat (eqn_pats eqn) = MatchResult CanFail body
 623         | otherwise                         = MatchResult can_fail body
 624
 625 --------------
 626 might_fail_pat :: Pat Id -> Bool
 627 -- Returns True of patterns that might fail (i.e. fall through) in a way
 628 -- that is not covered by the checking algorithm.  Specifically:
 629 --         NPlusKPat
 630 --         ViewPat (if refutable)
 631
 632 -- First the two special cases
 633 might_fail_pat (NPlusKPat {})                = True
 634 might_fail_pat (ViewPat _ p _)               = not (isIrrefutableHsPat p)
 635
 636 -- Now the recursive stuff
 637 might_fail_pat (ParPat p)                    = might_fail_lpat p
 638 might_fail_pat (AsPat _ p)                   = might_fail_lpat p
 639 might_fail_pat (SigPatOut p _ )              = might_fail_lpat p
 640 might_fail_pat (ListPat ps _)                = any might_fail_lpat ps
 641 might_fail_pat (TuplePat ps _ _)             = any might_fail_lpat ps
 642 might_fail_pat (PArrPat ps _)                = any might_fail_lpat ps
 643 might_fail_pat (BangPat p)                   = might_fail_lpat p
 644 might_fail_pat (ConPatOut { pat_args = ps }) = any might_fail_lpat (hsConPatArgs ps)
 645
 646 -- Finally the ones that are sure to succeed, or which are covered by the checking algorithm
 647 might_fail_pat (LazyPat _)                   = False -- Always succeeds
 648 might_fail_pat _                             = False -- VarPat, WildPat, LitPat, NPat
 649
 650 --------------
 651 might_fail_lpat :: LPat Id -> Bool
 652 might_fail_lpat (L _ p) = might_fail_pat p
 653
 654 --------------
 655 tidy_lpat :: LPat Id -> LPat Id
 656 tidy_lpat p = fmap tidy_pat p
 657
 658 --------------
 659 tidy_pat :: Pat Id -> Pat Id
 660 tidy_pat pat@(WildPat _)  = pat
 661 tidy_pat (VarPat id)      = WildPat (idType id)
 662 tidy_pat (ParPat p)       = tidy_pat (unLoc p)
 663 tidy_pat (LazyPat p)      = WildPat (hsLPatType p)      -- For overlap and exhaustiveness checking
 664                                                         -- purposes, a ~pat is like a wildcard
 665 tidy_pat (BangPat p)      = tidy_pat (unLoc p)
 666 tidy_pat (AsPat _ p)      = tidy_pat (unLoc p)
 667 tidy_pat (SigPatOut p _)  = tidy_pat (unLoc p)
 668 tidy_pat (CoPat _ pat _)  = tidy_pat pat
 669
 670 -- These two are might_fail patterns, so we map them to
 671 -- WildPats.  The might_fail_pat stuff arranges that the
 672 -- guard says "this equation might fall through".
 673 tidy_pat (NPlusKPat id _ _ _) = WildPat (idType (unLoc id))
 674 tidy_pat (ViewPat _ _ ty)     = WildPat ty
 675
 676 tidy_pat pat@(ConPatOut { pat_con = L _ id, pat_args = ps })
 677   = pat { pat_args = tidy_con id ps }
 678
 679 tidy_pat (ListPat ps ty)
 680   = unLoc $ foldr (\ x y -> mkPrefixConPat consDataCon [x,y] list_ty)
 681                                   (mkNilPat list_ty)
 682                                   (map tidy_lpat ps)
 683   where list_ty = mkListTy ty
 684
 685 -- introduce fake parallel array constructors to be able to handle parallel
 686 -- arrays with the existing machinery for constructor pattern
 687 --
 688 tidy_pat (PArrPat ps ty)
 689   = unLoc $ mkPrefixConPat (parrFakeCon (length ps))
 690                            (map tidy_lpat ps)
 691                            (mkPArrTy ty)
 692
 693 tidy_pat (TuplePat ps boxity ty)
 694   = unLoc $ mkPrefixConPat (tupleCon boxity arity)
 695                            (map tidy_lpat ps) ty
 696   where
 697     arity = length ps
 698
 699 tidy_pat (NPat lit mb_neg eq) = tidyNPat tidy_lit_pat lit mb_neg eq
 700 tidy_pat (LitPat lit)         = tidy_lit_pat lit
 701
 702 tidy_lit_pat :: HsLit -> Pat Id
 703 -- Unpack string patterns fully, so we can see when they
 704 -- overlap with each other, or even explicit lists of Chars.
 705 tidy_lit_pat lit
 706   | HsString s <- lit
 707   = unLoc $ foldr (\c pat -> mkPrefixConPat consDataCon [mkCharLitPat c, pat] stringTy)
 708                   (mkPrefixConPat nilDataCon [] stringTy) (unpackFS s)
 709   | otherwise
 710   = tidyLitPat lit
 711
 712 -----------------
 713 tidy_con :: DataCon -> HsConPatDetails Id -> HsConPatDetails Id
 714 tidy_con _   (PrefixCon ps)   = PrefixCon (map tidy_lpat ps)
 715 tidy_con _   (InfixCon p1 p2) = PrefixCon [tidy_lpat p1, tidy_lpat p2]
 716 tidy_con con (RecCon (HsRecFields fs _))
 717   | null fs   = PrefixCon [nlWildPat | _ <- dataConOrigArgTys con]
 718                 -- Special case for null patterns; maybe not a record at all
 719   | otherwise = PrefixCon (map (tidy_lpat.snd) all_pats)
 720   where
 721      -- pad out all the missing fields with WildPats.
 722     field_pats = map (\ f -> (f, nlWildPat)) (dataConFieldLabels con)
 723     all_pats = foldr (\(HsRecField id p _) acc -> insertNm (getName (unLoc id)) p acc)
 724                      field_pats fs
 725
 726     insertNm nm p [] = [(nm,p)]
 727     insertNm nm p (x@(n,_):xs)
 728       | nm == n    = (nm,p):xs
 729       | otherwise  = x : insertNm nm p xs
 730 \end{code}