compiler/deSugar/Desugar.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Desugar]{@deSugar@: the main function}
   5
   6 \begin{code}
   7 module Desugar ( deSugar, deSugarExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  12 import StaticFlags      ( opt_SccProfilingOn )
  13 import DriverPhases     ( isHsBoot )
  14 import HscTypes         ( ModGuts(..), HscEnv(..),
  15                           Dependencies(..), ForeignStubs(..), TypeEnv, IsBootInterface )
  16 import HsSyn            ( RuleDecl(..), RuleBndr(..), LHsExpr, LRuleDecl )
  17 import TcRnTypes        ( TcGblEnv(..), ImportAvails(..) )
  18 import MkIface          ( mkUsageInfo )
  19 import Id               ( Id, setIdExported, idName )
  20 import Name             ( Name, isExternalName, nameIsLocalOrFrom, nameOccName )
  21 import CoreSyn
  22 import PprCore          ( pprRules, pprCoreExpr )
  23 import DsMonad
  24 import DsExpr           ( dsLExpr )
  25 import DsBinds          ( dsTopLHsBinds, decomposeRuleLhs, AutoScc(..) )
  26 import DsForeign        ( dsForeigns )
  27 import DsExpr           ()      -- Forces DsExpr to be compiled; DsBinds only
  28                                 -- depends on DsExpr.hi-boot.
  29 import Module
  30 import UniqFM           ( eltsUFM, delFromUFM )
  31 import PackageConfig    ( thPackageId )
  32 import RdrName          ( GlobalRdrEnv )
  33 import NameSet
  34 import VarSet
  35 import Bag              ( Bag, isEmptyBag, emptyBag )
  36 import Rules            ( roughTopNames )
  37 import CoreLint         ( showPass, endPass )
  38 import CoreFVs          ( ruleRhsFreeVars, exprsFreeNames )
  39 import ErrUtils         ( doIfSet, dumpIfSet_dyn, printBagOfWarnings,
  40                           errorsFound, WarnMsg )
  41 import ListSetOps       ( insertList )
  42 import Outputable
  43 import UniqSupply       ( mkSplitUniqSupply )
  44 import SrcLoc           ( Located(..) )
  45 import DATA_IOREF       ( readIORef )
  46 import Maybes           ( catMaybes )
  47 import FastString
  48 import Util             ( sortLe )
  49 \end{code}
  50
  51 %************************************************************************
  52 %*                                                                      *
  53 %*              The main function: deSugar
  54 %*                                                                      *
  55 %************************************************************************
  56
  57 \begin{code}
  58 deSugar :: HscEnv -> TcGblEnv -> IO (Bag WarnMsg, Maybe ModGuts)
  59 -- Can modify PCS by faulting in more declarations
  60
  61 deSugar hsc_env
  62         tcg_env@(TcGblEnv { tcg_mod       = mod,
  63                             tcg_src       = hsc_src,
  64                             tcg_type_env  = type_env,
  65                             tcg_imports   = imports,
  66                             tcg_exports   = exports,
  67                             tcg_dus       = dus,
  68                             tcg_inst_uses = dfun_uses_var,
  69                             tcg_th_used   = th_var,
  70                             tcg_keep      = keep_var,
  71                             tcg_rdr_env   = rdr_env,
  72                             tcg_fix_env   = fix_env,
  73                             tcg_deprecs   = deprecs,
  74                             tcg_binds     = binds,
  75                             tcg_fords     = fords,
  76                             tcg_rules     = rules,
  77                             tcg_insts     = insts })
  78   = do  { showPass dflags "Desugar"
  79
  80         -- Desugar the program
  81         ; ((all_prs, ds_rules, ds_fords), warns)
  82                 <- case ghcMode (hsc_dflags hsc_env) of
  83                      JustTypecheck -> return (([], [], NoStubs), emptyBag)
  84                      _             -> initDs hsc_env mod rdr_env type_env $ do
  85                                         { core_prs <- dsTopLHsBinds auto_scc binds
  86                                         ; (ds_fords, foreign_prs) <- dsForeigns fords
  87                                         ; let all_prs = foreign_prs ++ core_prs
  88                                               local_bndrs = mkVarSet (map fst all_prs)
  89                                         ; ds_rules <- mappM (dsRule mod local_bndrs) rules
  90                                         ; return (all_prs, catMaybes ds_rules, ds_fords)
  91                                         }
  92
  93         -- If warnings are considered errors, leave.
  94         ; if errorsFound dflags (warns, emptyBag)
  95            then return (warns, Nothing)
  96            else do
  97
  98         {       -- Add export flags to bindings
  99           keep_alive <- readIORef keep_var
 100         ; let final_prs = addExportFlags ghci_mode exports keep_alive
 101                                          all_prs ds_rules
 102               ds_binds  = [Rec final_prs]
 103         -- Notice that we put the whole lot in a big Rec, even the foreign binds
 104         -- When compiling PrelFloat, which defines data Float = F# Float#
 105         -- we want F# to be in scope in the foreign marshalling code!
 106         -- You might think it doesn't matter, but the simplifier brings all top-level
 107         -- things into the in-scope set before simplifying; so we get no unfolding for F#!
 108
 109         -- Lint result if necessary
 110         ; endPass dflags "Desugar" Opt_D_dump_ds ds_binds
 111
 112         -- Dump output
 113         ; doIfSet (dopt Opt_D_dump_ds dflags)
 114                   (printDump (ppr_ds_rules ds_rules))
 115
 116         ; dfun_uses <- readIORef dfun_uses_var          -- What dfuns are used
 117         ; th_used   <- readIORef th_var                 -- Whether TH is used
 118         ; let used_names = allUses dus `unionNameSets` dfun_uses
 119               pkgs | th_used   = insertList thPackageId (imp_dep_pkgs imports)
 120                    | otherwise = imp_dep_pkgs imports
 121
 122               dep_mods = eltsUFM (delFromUFM (imp_dep_mods imports) (moduleName mod))
 123                 -- M.hi-boot can be in the imp_dep_mods, but we must remove
 124                 -- it before recording the modules on which this one depends!
 125                 -- (We want to retain M.hi-boot in imp_dep_mods so that
 126                 --  loadHiBootInterface can see if M's direct imports depend
 127                 --  on M.hi-boot, and hence that we should do the hi-boot consistency
 128                 --  check.)
 129
 130               dir_imp_mods = imp_mods imports
 131
 132         ; usages <- mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 133
 134         ; let
 135                 -- Modules don't compare lexicographically usually,
 136                 -- but we want them to do so here.
 137              le_mod :: Module -> Module -> Bool
 138              le_mod m1 m2 = moduleNameFS (moduleName m1)
 139                                 <= moduleNameFS (moduleName m2)
 140              le_dep_mod :: (ModuleName, IsBootInterface) -> (ModuleName, IsBootInterface) -> Bool
 141              le_dep_mod (m1,_) (m2,_) = moduleNameFS m1 <= moduleNameFS m2
 142
 143              deps = Deps { dep_mods  = sortLe le_dep_mod dep_mods,
 144                            dep_pkgs  = sortLe (<=)   pkgs,
 145                            dep_orphs = sortLe le_mod (imp_orphs imports) }
 146                 -- sort to get into canonical order
 147
 148              mod_guts = ModGuts {
 149                 mg_module   = mod,
 150                 mg_boot     = isHsBoot hsc_src,
 151                 mg_exports  = exports,
 152                 mg_deps     = deps,
 153                 mg_usages   = usages,
 154                 mg_dir_imps = [m | (m,_,_) <- moduleEnvElts dir_imp_mods],
 155                 mg_rdr_env  = rdr_env,
 156                 mg_fix_env  = fix_env,
 157                 mg_deprecs  = deprecs,
 158                 mg_types    = type_env,
 159                 mg_insts    = insts,
 160                 mg_rules    = ds_rules,
 161                 mg_binds    = ds_binds,
 162                 mg_foreign  = ds_fords }
 163
 164         ; return (warns, Just mod_guts)
 165         }}
 166
 167   where
 168     dflags       = hsc_dflags hsc_env
 169     ghci_mode    = ghcMode (hsc_dflags hsc_env)
 170     auto_scc | opt_SccProfilingOn = TopLevel
 171              | otherwise          = NoSccs
 172
 173 deSugarExpr :: HscEnv
 174             -> Module -> GlobalRdrEnv -> TypeEnv
 175             -> LHsExpr Id
 176             -> IO CoreExpr
 177 deSugarExpr hsc_env this_mod rdr_env type_env tc_expr
 178   = do  { showPass dflags "Desugar"
 179         ; us <- mkSplitUniqSupply 'd'
 180
 181         -- Do desugaring
 182         ; (core_expr, ds_warns) <- initDs hsc_env this_mod rdr_env type_env $
 183                                    dsLExpr tc_expr
 184
 185         -- Display any warnings
 186         -- Note: if -Werror is used, we don't signal an error here.
 187         ; doIfSet (not (isEmptyBag ds_warns))
 188                   (printBagOfWarnings dflags ds_warns)
 189
 190         -- Dump output
 191         ; dumpIfSet_dyn dflags Opt_D_dump_ds "Desugared" (pprCoreExpr core_expr)
 192
 193         ; return core_expr
 194         }
 195   where
 196     dflags       = hsc_dflags hsc_env
 197
 198
 199 --              addExportFlags
 200 -- Set the no-discard flag if either
 201 --      a) the Id is exported
 202 --      b) it's mentioned in the RHS of an orphan rule
 203 --      c) it's in the keep-alive set
 204 --
 205 -- It means that the binding won't be discarded EVEN if the binding
 206 -- ends up being trivial (v = w) -- the simplifier would usually just
 207 -- substitute w for v throughout, but we don't apply the substitution to
 208 -- the rules (maybe we should?), so this substitution would make the rule
 209 -- bogus.
 210
 211 -- You might wonder why exported Ids aren't already marked as such;
 212 -- it's just because the type checker is rather busy already and
 213 -- I didn't want to pass in yet another mapping.
 214
 215 addExportFlags ghci_mode exports keep_alive prs rules
 216   = [(add_export bndr, rhs) | (bndr,rhs) <- prs]
 217   where
 218     add_export bndr
 219         | dont_discard bndr = setIdExported bndr
 220         | otherwise         = bndr
 221
 222     orph_rhs_fvs = unionVarSets [ ruleRhsFreeVars rule
 223                                 | rule <- rules,
 224                                   not (isLocalRule rule) ]
 225         -- A non-local rule keeps alive the free vars of its right-hand side.
 226         -- (A "non-local" is one whose head function is not locally defined.)
 227         -- Local rules are (later, after gentle simplification)
 228         -- attached to the Id, and that keeps the rhs free vars alive.
 229
 230     dont_discard bndr = is_exported name
 231                      || name `elemNameSet` keep_alive
 232                      || bndr `elemVarSet` orph_rhs_fvs
 233                      where
 234                         name = idName bndr
 235
 236         -- In interactive mode, we don't want to discard any top-level
 237         -- entities at all (eg. do not inline them away during
 238         -- simplification), and retain them all in the TypeEnv so they are
 239         -- available from the command line.
 240         --
 241         -- isExternalName separates the user-defined top-level names from those
 242         -- introduced by the type checker.
 243     is_exported :: Name -> Bool
 244     is_exported | ghci_mode == Interactive = isExternalName
 245                 | otherwise                = (`elemNameSet` exports)
 246
 247 ppr_ds_rules [] = empty
 248 ppr_ds_rules rules
 249   = text "" $$ text "-------------- DESUGARED RULES -----------------" $$
 250     pprRules rules
 251 \end{code}
 252
 253
 254
 255 %************************************************************************
 256 %*                                                                      *
 257 %*              Desugaring transformation rules
 258 %*                                                                      *
 259 %************************************************************************
 260
 261 \begin{code}
 262 dsRule :: Module -> IdSet -> LRuleDecl Id -> DsM (Maybe CoreRule)
 263 dsRule mod in_scope (L loc (HsRule name act vars lhs tv_lhs rhs fv_rhs))
 264   = putSrcSpanDs loc $
 265     do  { let bndrs     = [var | RuleBndr (L _ var) <- vars]
 266         ; lhs'  <- dsLExpr lhs
 267         ; rhs'  <- dsLExpr rhs
 268
 269         ; case decomposeRuleLhs bndrs lhs' of {
 270                 Nothing -> do { dsWarn msg; return Nothing } ;
 271                 Just (bndrs', fn_id, args) -> do
 272
 273         -- Substitute the dict bindings eagerly,
 274         -- and take the body apart into a (f args) form
 275         { let local_rule = nameIsLocalOrFrom mod fn_name
 276                 -- NB we can't use isLocalId in the orphan test,
 277                 -- because isLocalId isn't true of class methods
 278               fn_name   = idName fn_id
 279               lhs_names = fn_name : nameSetToList (exprsFreeNames args)
 280                 -- No need to delete bndrs, because
 281                 -- exprsFreeNames finds only External names
 282               orph = case filter (nameIsLocalOrFrom mod) lhs_names of
 283                         (n:ns) -> Just (nameOccName n)
 284                         []     -> Nothing
 285
 286               rule = Rule { ru_name = name, ru_fn = fn_name, ru_act = act,
 287                             ru_bndrs = bndrs', ru_args = args, ru_rhs = rhs',
 288                             ru_rough = roughTopNames args,
 289                             ru_local = local_rule, ru_orph = orph }
 290         ; return (Just rule)
 291         } } }
 292   where
 293     msg = hang (ptext SLIT("RULE left-hand side too complicated to desugar; ignored"))
 294              2 (ppr lhs)
 295 \end{code}