compiler/deSugar/DsExpr.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Desugaring exporessions.
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 module DsExpr ( dsExpr, dsLExpr, dsLocalBinds, dsValBinds, dsLit ) where
  17
  18 #include "HsVersions.h"
  19
  20 import Match
  21 import MatchLit
  22 import DsBinds
  23 import DsGRHSs
  24 import DsListComp
  25 import DsUtils
  26 import DsArrows
  27 import DsMonad
  28 import Name
  29 import NameEnv
  30
  31 #ifdef GHCI
  32         -- Template Haskell stuff iff bootstrapped
  33 import DsMeta
  34 #endif
  35
  36 import HsSyn
  37 import TcHsSyn
  38
  39 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  40 --     needs to see source types
  41 import TcType
  42 import Type
  43 import Coercion
  44 import CoreSyn
  45 import CoreUtils
  46 import CoreFVs
  47 import MkCore
  48
  49 import DynFlags
  50 import StaticFlags
  51 import CostCentre
  52 import Id
  53 import Var
  54 import VarSet
  55 import DataCon
  56 import TysWiredIn
  57 import BasicTypes
  58 import PrelNames
  59 import Maybes
  60 import SrcLoc
  61 import Util
  62 import Bag
  63 import Outputable
  64 import FastString
  65
  66 import Control.Monad
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72                 dsLocalBinds, dsValBinds
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 dsLocalBinds :: HsLocalBinds Id -> CoreExpr -> DsM CoreExpr
  78 dsLocalBinds EmptyLocalBinds    body = return body
  79 dsLocalBinds (HsValBinds binds) body = dsValBinds binds body
  80 dsLocalBinds (HsIPBinds binds)  body = dsIPBinds  binds body
  81
  82 -------------------------
  83 dsValBinds :: HsValBinds Id -> CoreExpr -> DsM CoreExpr
  84 dsValBinds (ValBindsOut binds _) body = foldrM ds_val_bind body binds
  85
  86 -------------------------
  87 dsIPBinds :: HsIPBinds Id -> CoreExpr -> DsM CoreExpr
  88 dsIPBinds (IPBinds ip_binds ev_binds) body
  89   = do  { ds_ev_binds <- dsTcEvBinds ev_binds
  90         ; let inner = wrapDsEvBinds ds_ev_binds body
  91                 -- The dict bindings may not be in
  92                 -- dependency order; hence Rec
  93         ; foldrM ds_ip_bind inner ip_binds }
  94   where
  95     ds_ip_bind (L _ (IPBind n e)) body
  96       = do e' <- dsLExpr e
  97            return (Let (NonRec (ipNameName n) e') body)
  98
  99 -------------------------
 100 ds_val_bind :: (RecFlag, LHsBinds Id) -> CoreExpr -> DsM CoreExpr
 101 -- Special case for bindings which bind unlifted variables
 102 -- We need to do a case right away, rather than building
 103 -- a tuple and doing selections.
 104 -- Silently ignore INLINE and SPECIALISE pragmas...
 105 ds_val_bind (NonRecursive, hsbinds) body
 106   | [L loc bind] <- bagToList hsbinds,
 107         -- Non-recursive, non-overloaded bindings only come in ones
 108         -- ToDo: in some bizarre case it's conceivable that there
 109         --       could be dict binds in the 'binds'.  (See the notes
 110         --       below.  Then pattern-match would fail.  Urk.)
 111     strictMatchOnly bind
 112   = putSrcSpanDs loc (dsStrictBind bind body)
 113
 114 -- Ordinary case for bindings; none should be unlifted
 115 ds_val_bind (_is_rec, binds) body
 116   = do  { prs <- dsLHsBinds binds
 117         ; ASSERT2( not (any (isUnLiftedType . idType . fst) prs), ppr _is_rec $$ ppr binds )
 118           case prs of
 119             [] -> return body
 120             _  -> return (Let (Rec prs) body) }
 121         -- Use a Rec regardless of is_rec.
 122         -- Why? Because it allows the binds to be all
 123         -- mixed up, which is what happens in one rare case
 124         -- Namely, for an AbsBind with no tyvars and no dicts,
 125         --         but which does have dictionary bindings.
 126         -- See notes with TcSimplify.inferLoop [NO TYVARS]
 127         -- It turned out that wrapping a Rec here was the easiest solution
 128         --
 129         -- NB The previous case dealt with unlifted bindings, so we
 130         --    only have to deal with lifted ones now; so Rec is ok
 131
 132 ------------------
 133 dsStrictBind :: HsBind Id -> CoreExpr -> DsM CoreExpr
 134 dsStrictBind (AbsBinds { abs_tvs = [], abs_ev_vars = []
 135                , abs_exports = exports
 136                , abs_ev_binds = ev_binds
 137                , abs_binds = binds }) body
 138   = do { ds_ev_binds <- dsTcEvBinds ev_binds
 139        ; let body1 = foldr bind_export body exports
 140              bind_export (_, g, l, _) b = bindNonRec g (Var l) b
 141        ; body2 <- foldlBagM (\body bind -> dsStrictBind (unLoc bind) body)
 142                             body1 binds
 143        ; return (wrapDsEvBinds ds_ev_binds body2) }
 144
 145 dsStrictBind (FunBind { fun_id = L _ fun, fun_matches = matches, fun_co_fn = co_fn
 146                       , fun_tick = tick, fun_infix = inf }) body
 147                 -- Can't be a bang pattern (that looks like a PatBind)
 148                 -- so must be simply unboxed
 149   = do { (args, rhs) <- matchWrapper (FunRhs (idName fun ) inf) matches
 150        ; MASSERT( null args ) -- Functions aren't lifted
 151        ; MASSERT( isIdHsWrapper co_fn )
 152        ; rhs' <- mkOptTickBox tick rhs
 153        ; return (bindNonRec fun rhs' body) }
 154
 155 dsStrictBind (PatBind {pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty }) body
 156   =     -- let C x# y# = rhs in body
 157         -- ==> case rhs of C x# y# -> body
 158     do { rhs <- dsGuarded grhss ty
 159        ; let upat = unLoc pat
 160              eqn = EqnInfo { eqn_pats = [upat],
 161                              eqn_rhs = cantFailMatchResult body }
 162        ; var    <- selectMatchVar upat
 163        ; result <- matchEquations PatBindRhs [var] [eqn] (exprType body)
 164        ; return (scrungleMatch var rhs result) }
 165
 166 dsStrictBind bind body = pprPanic "dsLet: unlifted" (ppr bind $$ ppr body)
 167
 168 ----------------------
 169 strictMatchOnly :: HsBind Id -> Bool
 170 strictMatchOnly (AbsBinds { abs_binds = binds })
 171   = anyBag (strictMatchOnly . unLoc) binds
 172 strictMatchOnly (PatBind { pat_lhs = lpat, pat_rhs_ty = ty })
 173   =  isUnboxedTupleType ty
 174   || isBangLPat lpat
 175   || any (isUnLiftedType . idType) (collectPatBinders lpat)
 176 strictMatchOnly (FunBind { fun_id = L _ id })
 177   = isUnLiftedType (idType id)
 178 strictMatchOnly _ = False -- I hope!  Checked immediately by caller in fact
 179
 180 scrungleMatch :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 181 -- Returns something like (let var = scrut in body)
 182 -- but if var is an unboxed-tuple type, it inlines it in a fragile way
 183 -- Special case to handle unboxed tuple patterns; they can't appear nested
 184 -- The idea is that
 185 --      case e of (# p1, p2 #) -> rhs
 186 -- should desugar to
 187 --      case e of (# x1, x2 #) -> ... match p1, p2 ...
 188 -- NOT
 189 --      let x = e in case x of ....
 190 --
 191 -- But there may be a big
 192 --      let fail = ... in case e of ...
 193 -- wrapping the whole case, which complicates matters slightly
 194 -- It all seems a bit fragile.  Test is dsrun013.
 195
 196 scrungleMatch var scrut body
 197   | isUnboxedTupleType (idType var) = scrungle body
 198   | otherwise                       = bindNonRec var scrut body
 199   where
 200     scrungle (Case (Var x) bndr ty alts)
 201                     | x == var = Case scrut bndr ty alts
 202     scrungle (Let binds body)  = Let binds (scrungle body)
 203     scrungle other = panic ("scrungleMatch: tuple pattern:\n" ++ showSDoc (ppr other))
 204
 205 \end{code}
 206
 207 %************************************************************************
 208 %*                                                                      *
 209 \subsection[DsExpr-vars-and-cons]{Variables, constructors, literals}
 210 %*                                                                      *
 211 %************************************************************************
 212
 213 \begin{code}
 214 dsLExpr :: LHsExpr Id -> DsM CoreExpr
 215
 216 dsLExpr (L loc e) = putSrcSpanDs loc $ dsExpr e
 217
 218 dsExpr :: HsExpr Id -> DsM CoreExpr
 219 dsExpr (HsPar e)              = dsLExpr e
 220 dsExpr (ExprWithTySigOut e _) = dsLExpr e
 221 dsExpr (HsVar var)            = return (Var var)
 222 dsExpr (HsIPVar ip)           = return (Var (ipNameName ip))
 223 dsExpr (HsLit lit)            = dsLit lit
 224 dsExpr (HsOverLit lit)        = dsOverLit lit
 225
 226 dsExpr (HsWrap co_fn e)
 227   = do { co_fn' <- dsHsWrapper co_fn
 228        ; e' <- dsExpr e
 229        ; warn_id <- doptDs Opt_WarnIdentities
 230        ; when warn_id $ warnAboutIdentities e' co_fn'
 231        ; return (co_fn' e') }
 232
 233 dsExpr (NegApp expr neg_expr)
 234   = App <$> dsExpr neg_expr <*> dsLExpr expr
 235
 236 dsExpr (HsLam a_Match)
 237   = uncurry mkLams <$> matchWrapper LambdaExpr a_Match
 238
 239 dsExpr (HsApp fun arg)
 240   = mkCoreAppDs <$> dsLExpr fun <*>  dsLExpr arg
 241 \end{code}
 242
 243 Operator sections.  At first it looks as if we can convert
 244 \begin{verbatim}
 245         (expr op)
 246 \end{verbatim}
 247 to
 248 \begin{verbatim}
 249         \x -> op expr x
 250 \end{verbatim}
 251
 252 But no!  expr might be a redex, and we can lose laziness badly this
 253 way.  Consider
 254 \begin{verbatim}
 255         map (expr op) xs
 256 \end{verbatim}
 257 for example.  So we convert instead to
 258 \begin{verbatim}
 259         let y = expr in \x -> op y x
 260 \end{verbatim}
 261 If \tr{expr} is actually just a variable, say, then the simplifier
 262 will sort it out.
 263
 264 \begin{code}
 265 dsExpr (OpApp e1 op _ e2)
 266   = -- for the type of y, we need the type of op's 2nd argument
 267     mkCoreAppsDs <$> dsLExpr op <*> mapM dsLExpr [e1, e2]
 268
 269 dsExpr (SectionL expr op)       -- Desugar (e !) to ((!) e)
 270   = mkCoreAppDs <$> dsLExpr op <*> dsLExpr expr
 271
 272 -- dsLExpr (SectionR op expr)   -- \ x -> op x expr
 273 dsExpr (SectionR op expr) = do
 274     core_op <- dsLExpr op
 275     -- for the type of x, we need the type of op's 2nd argument
 276     let (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 277         -- See comment with SectionL
 278     y_core <- dsLExpr expr
 279     x_id <- newSysLocalDs x_ty
 280     y_id <- newSysLocalDs y_ty
 281     return (bindNonRec y_id y_core $
 282             Lam x_id (mkCoreAppsDs core_op [Var x_id, Var y_id]))
 283
 284 dsExpr (ExplicitTuple tup_args boxity)
 285   = do { let go (lam_vars, args) (Missing ty)
 286                     -- For every missing expression, we need
 287                     -- another lambda in the desugaring.
 288                = do { lam_var <- newSysLocalDs ty
 289                     ; return (lam_var : lam_vars, Var lam_var : args) }
 290              go (lam_vars, args) (Present expr)
 291                     -- Expressions that are present don't generate
 292                     -- lambdas, just arguments.
 293                = do { core_expr <- dsLExpr expr
 294                     ; return (lam_vars, core_expr : args) }
 295
 296        ; (lam_vars, args) <- foldM go ([], []) (reverse tup_args)
 297                 -- The reverse is because foldM goes left-to-right
 298
 299        ; return $ mkCoreLams lam_vars $
 300                   mkConApp (tupleCon boxity (length tup_args))
 301                            (map (Type . exprType) args ++ args) }
 302
 303 dsExpr (HsSCC cc expr) = do
 304     mod_name <- getModuleDs
 305     Note (SCC (mkUserCC cc mod_name)) <$> dsLExpr expr
 306
 307 dsExpr (HsCoreAnn fs expr)
 308   = Note (CoreNote $ unpackFS fs) <$> dsLExpr expr
 309
 310 dsExpr (HsCase discrim matches@(MatchGroup _ rhs_ty))
 311   | isEmptyMatchGroup matches   -- A Core 'case' is always non-empty
 312   =                             -- So desugar empty HsCase to error call
 313     mkErrorAppDs pAT_ERROR_ID (funResultTy rhs_ty) (ptext (sLit "case"))
 314
 315   | otherwise
 316   = do { core_discrim <- dsLExpr discrim
 317        ; ([discrim_var], matching_code) <- matchWrapper CaseAlt matches
 318        ; return (scrungleMatch discrim_var core_discrim matching_code) }
 319
 320 -- Pepe: The binds are in scope in the body but NOT in the binding group
 321 --       This is to avoid silliness in breakpoints
 322 dsExpr (HsLet binds body) = do
 323     body' <- dsLExpr body
 324     dsLocalBinds binds body'
 325
 326 -- We need the `ListComp' form to use `deListComp' (rather than the "do" form)
 327 -- because the interpretation of `stmts' depends on what sort of thing it is.
 328 --
 329 dsExpr (HsDo ListComp stmts body result_ty)
 330   =     -- Special case for list comprehensions
 331     dsListComp stmts body elt_ty
 332   where
 333     [elt_ty] = tcTyConAppArgs result_ty
 334
 335 dsExpr (HsDo DoExpr stmts body result_ty)
 336   = dsDo stmts body result_ty
 337
 338 dsExpr (HsDo GhciStmt stmts body result_ty)
 339   = dsDo stmts body result_ty
 340
 341 dsExpr (HsDo ctxt@(MDoExpr tbl) stmts body result_ty)
 342   = do { (meth_binds, tbl') <- dsSyntaxTable tbl
 343        ; core_expr <- dsMDo ctxt tbl' stmts body result_ty
 344        ; return (mkLets meth_binds core_expr) }
 345
 346 dsExpr (HsDo PArrComp stmts body result_ty)
 347   =     -- Special case for array comprehensions
 348     dsPArrComp (map unLoc stmts) body elt_ty
 349   where
 350     [elt_ty] = tcTyConAppArgs result_ty
 351
 352 dsExpr (HsIf mb_fun guard_expr then_expr else_expr)
 353   = do { pred <- dsLExpr guard_expr
 354        ; b1 <- dsLExpr then_expr
 355        ; b2 <- dsLExpr else_expr
 356        ; case mb_fun of
 357            Just fun -> do { core_fun <- dsExpr fun
 358                           ; return (mkCoreApps core_fun [pred,b1,b2]) }
 359            Nothing  -> return $ mkIfThenElse pred b1 b2 }
 360 \end{code}
 361
 362
 363 \noindent
 364 \underline{\bf Various data construction things}
 365 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 366 \begin{code}
 367 dsExpr (ExplicitList elt_ty xs)
 368   = dsExplicitList elt_ty xs
 369
 370 -- We desugar [:x1, ..., xn:] as
 371 --   singletonP x1 +:+ ... +:+ singletonP xn
 372 --
 373 dsExpr (ExplicitPArr ty []) = do
 374     emptyP <- dsLookupGlobalId emptyPName
 375     return (Var emptyP `App` Type ty)
 376 dsExpr (ExplicitPArr ty xs) = do
 377     singletonP <- dsLookupGlobalId singletonPName
 378     appP       <- dsLookupGlobalId appPName
 379     xs'        <- mapM dsLExpr xs
 380     return . foldr1 (binary appP) $ map (unary singletonP) xs'
 381   where
 382     unary  fn x   = mkApps (Var fn) [Type ty, x]
 383     binary fn x y = mkApps (Var fn) [Type ty, x, y]
 384
 385 dsExpr (ArithSeq expr (From from))
 386   = App <$> dsExpr expr <*> dsLExpr from
 387
 388 dsExpr (ArithSeq expr (FromTo from to))
 389   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, to]
 390
 391 dsExpr (ArithSeq expr (FromThen from thn))
 392   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, thn]
 393
 394 dsExpr (ArithSeq expr (FromThenTo from thn to))
 395   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, thn, to]
 396
 397 dsExpr (PArrSeq expr (FromTo from to))
 398   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, to]
 399
 400 dsExpr (PArrSeq expr (FromThenTo from thn to))
 401   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, thn, to]
 402
 403 dsExpr (PArrSeq _ _)
 404   = panic "DsExpr.dsExpr: Infinite parallel array!"
 405     -- the parser shouldn't have generated it and the renamer and typechecker
 406     -- shouldn't have let it through
 407 \end{code}
 408
 409 \noindent
 410 \underline{\bf Record construction and update}
 411 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 412 For record construction we do this (assuming T has three arguments)
 413 \begin{verbatim}
 414         T { op2 = e }
 415 ==>
 416         let err = /\a -> recConErr a
 417         T (recConErr t1 "M.lhs/230/op1")
 418           e
 419           (recConErr t1 "M.lhs/230/op3")
 420 \end{verbatim}
 421 @recConErr@ then converts its arugment string into a proper message
 422 before printing it as
 423 \begin{verbatim}
 424         M.lhs, line 230: missing field op1 was evaluated
 425 \end{verbatim}
 426
 427 We also handle @C{}@ as valid construction syntax for an unlabelled
 428 constructor @C@, setting all of @C@'s fields to bottom.
 429
 430 \begin{code}
 431 dsExpr (RecordCon (L _ data_con_id) con_expr rbinds) = do
 432     con_expr' <- dsExpr con_expr
 433     let
 434         (arg_tys, _) = tcSplitFunTys (exprType con_expr')
 435         -- A newtype in the corner should be opaque;
 436         -- hence TcType.tcSplitFunTys
 437
 438         mk_arg (arg_ty, lbl)    -- Selector id has the field label as its name
 439           = case findField (rec_flds rbinds) lbl of
 440               (rhs:rhss) -> ASSERT( null rhss )
 441                             dsLExpr rhs
 442               []         -> mkErrorAppDs rEC_CON_ERROR_ID arg_ty (ppr lbl)
 443         unlabelled_bottom arg_ty = mkErrorAppDs rEC_CON_ERROR_ID arg_ty empty
 444
 445         labels = dataConFieldLabels (idDataCon data_con_id)
 446         -- The data_con_id is guaranteed to be the wrapper id of the constructor
 447
 448     con_args <- if null labels
 449                 then mapM unlabelled_bottom arg_tys
 450                 else mapM mk_arg (zipEqual "dsExpr:RecordCon" arg_tys labels)
 451
 452     return (mkApps con_expr' con_args)
 453 \end{code}
 454
 455 Record update is a little harder. Suppose we have the decl:
 456 \begin{verbatim}
 457         data T = T1 {op1, op2, op3 :: Int}
 458                | T2 {op4, op2 :: Int}
 459                | T3
 460 \end{verbatim}
 461 Then we translate as follows:
 462 \begin{verbatim}
 463         r { op2 = e }
 464 ===>
 465         let op2 = e in
 466         case r of
 467           T1 op1 _ op3 -> T1 op1 op2 op3
 468           T2 op4 _     -> T2 op4 op2
 469           other        -> recUpdError "M.lhs/230"
 470 \end{verbatim}
 471 It's important that we use the constructor Ids for @T1@, @T2@ etc on the
 472 RHSs, and do not generate a Core constructor application directly, because the constructor
 473 might do some argument-evaluation first; and may have to throw away some
 474 dictionaries.
 475
 476 Note [Update for GADTs]
 477 ~~~~~~~~~~~~~~~~~~~~~~~
 478 Consider
 479    data T a b where
 480      T1 { f1 :: a } :: T a Int
 481
 482 Then the wrapper function for T1 has type
 483    $WT1 :: a -> T a Int
 484 But if x::T a b, then
 485    x { f1 = v } :: T a b   (not T a Int!)
 486 So we need to cast (T a Int) to (T a b).  Sigh.
 487
 488 \begin{code}
 489 dsExpr expr@(RecordUpd record_expr (HsRecFields { rec_flds = fields })
 490                        cons_to_upd in_inst_tys out_inst_tys)
 491   | null fields
 492   = dsLExpr record_expr
 493   | otherwise
 494   = ASSERT2( notNull cons_to_upd, ppr expr )
 495
 496     do  { record_expr' <- dsLExpr record_expr
 497         ; field_binds' <- mapM ds_field fields
 498         ; let upd_fld_env :: NameEnv Id -- Maps field name to the LocalId of the field binding
 499               upd_fld_env = mkNameEnv [(f,l) | (f,l,_) <- field_binds']
 500
 501         -- It's important to generate the match with matchWrapper,
 502         -- and the right hand sides with applications of the wrapper Id
 503         -- so that everything works when we are doing fancy unboxing on the
 504         -- constructor aguments.
 505         ; alts <- mapM (mk_alt upd_fld_env) cons_to_upd
 506         ; ([discrim_var], matching_code)
 507                 <- matchWrapper RecUpd (MatchGroup alts in_out_ty)
 508
 509         ; return (add_field_binds field_binds' $
 510                   bindNonRec discrim_var record_expr' matching_code) }
 511   where
 512     ds_field :: HsRecField Id (LHsExpr Id) -> DsM (Name, Id, CoreExpr)
 513       -- Clone the Id in the HsRecField, because its Name is that
 514       -- of the record selector, and we must not make that a lcoal binder
 515       -- else we shadow other uses of the record selector
 516       -- Hence 'lcl_id'.  Cf Trac #2735
 517     ds_field rec_field = do { rhs <- dsLExpr (hsRecFieldArg rec_field)
 518                             ; let fld_id = unLoc (hsRecFieldId rec_field)
 519                             ; lcl_id <- newSysLocalDs (idType fld_id)
 520                             ; return (idName fld_id, lcl_id, rhs) }
 521
 522     add_field_binds [] expr = expr
 523     add_field_binds ((_,b,r):bs) expr = bindNonRec b r (add_field_binds bs expr)
 524
 525         -- Awkwardly, for families, the match goes
 526         -- from instance type to family type
 527     tycon     = dataConTyCon (head cons_to_upd)
 528     in_ty     = mkTyConApp tycon in_inst_tys
 529     in_out_ty = mkFunTy in_ty (mkFamilyTyConApp tycon out_inst_tys)
 530
 531     mk_alt upd_fld_env con
 532       = do { let (univ_tvs, ex_tvs, eq_spec,
 533                   eq_theta, dict_theta, arg_tys, _) = dataConFullSig con
 534                  subst = mkTopTvSubst (univ_tvs `zip` in_inst_tys)
 535
 536                 -- I'm not bothering to clone the ex_tvs
 537            ; eqs_vars   <- mapM newPredVarDs (substTheta subst (eqSpecPreds eq_spec))
 538            ; theta_vars <- mapM newPredVarDs (substTheta subst (eq_theta ++ dict_theta))
 539            ; arg_ids    <- newSysLocalsDs (substTys subst arg_tys)
 540            ; let val_args = zipWithEqual "dsExpr:RecordUpd" mk_val_arg
 541                                          (dataConFieldLabels con) arg_ids
 542                  mk_val_arg field_name pat_arg_id
 543                      = nlHsVar (lookupNameEnv upd_fld_env field_name `orElse` pat_arg_id)
 544                  inst_con = noLoc $ HsWrap wrap (HsVar (dataConWrapId con))
 545                         -- Reconstruct with the WrapId so that unpacking happens
 546                  wrap = mkWpEvVarApps theta_vars          `WpCompose`
 547                         mkWpTyApps    (mkTyVarTys ex_tvs) `WpCompose`
 548                         mkWpTyApps [ty | (tv, ty) <- univ_tvs `zip` out_inst_tys
 549                                        , isNothing (lookupTyVar wrap_subst tv) ]
 550                  rhs = foldl (\a b -> nlHsApp a b) inst_con val_args
 551
 552                         -- Tediously wrap the application in a cast
 553                         -- Note [Update for GADTs]
 554                  wrapped_rhs | null eq_spec = rhs
 555                              | otherwise    = mkLHsWrap (WpCast wrap_co) rhs
 556                  wrap_co = mkTyConApp tycon [ lookup tv ty
 557                                             | (tv,ty) <- univ_tvs `zip` out_inst_tys]
 558                  lookup univ_tv ty = case lookupTyVar wrap_subst univ_tv of
 559                                         Just ty' -> ty'
 560                                         Nothing  -> ty
 561                  wrap_subst = mkTopTvSubst [ (tv,mkSymCoercion (mkTyVarTy co_var))
 562                                            | ((tv,_),co_var) <- eq_spec `zip` eqs_vars ]
 563
 564                  pat = noLoc $ ConPatOut { pat_con = noLoc con, pat_tvs = ex_tvs
 565                                          , pat_dicts = eqs_vars ++ theta_vars
 566                                          , pat_binds = emptyTcEvBinds
 567                                          , pat_args = PrefixCon $ map nlVarPat arg_ids
 568                                          , pat_ty = in_ty }
 569            ; return (mkSimpleMatch [pat] wrapped_rhs) }
 570
 571 \end{code}
 572
 573 Here is where we desugar the Template Haskell brackets and escapes
 574
 575 \begin{code}
 576 -- Template Haskell stuff
 577
 578 #ifdef GHCI     /* Only if bootstrapping */
 579 dsExpr (HsBracketOut x ps) = dsBracket x ps
 580 dsExpr (HsSpliceE s)       = pprPanic "dsExpr:splice" (ppr s)
 581 #endif
 582
 583 -- Arrow notation extension
 584 dsExpr (HsProc pat cmd) = dsProcExpr pat cmd
 585 \end{code}
 586
 587 Hpc Support
 588
 589 \begin{code}
 590 dsExpr (HsTick ix vars e) = do
 591   e' <- dsLExpr e
 592   mkTickBox ix vars e'
 593
 594 -- There is a problem here. The then and else branches
 595 -- have no free variables, so they are open to lifting.
 596 -- We need someway of stopping this.
 597 -- This will make no difference to binary coverage
 598 -- (did you go here: YES or NO), but will effect accurate
 599 -- tick counting.
 600
 601 dsExpr (HsBinTick ixT ixF e) = do
 602   e2 <- dsLExpr e
 603   do { ASSERT(exprType e2 `coreEqType` boolTy)
 604        mkBinaryTickBox ixT ixF e2
 605      }
 606 \end{code}
 607
 608 \begin{code}
 609
 610 -- HsSyn constructs that just shouldn't be here:
 611 dsExpr (ExprWithTySig _ _)  = panic "dsExpr:ExprWithTySig"
 612
 613
 614 findField :: [HsRecField Id arg] -> Name -> [arg]
 615 findField rbinds lbl
 616   = [rhs | HsRecField { hsRecFieldId = id, hsRecFieldArg = rhs } <- rbinds
 617          , lbl == idName (unLoc id) ]
 618 \end{code}
 619
 620 %--------------------------------------------------------------------
 621
 622 Note [Desugaring explicit lists]
 623 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 624 Explicit lists are desugared in a cleverer way to prevent some
 625 fruitless allocations.  Essentially, whenever we see a list literal
 626 [x_1, ..., x_n] we:
 627
 628 1. Find the tail of the list that can be allocated statically (say
 629    [x_k, ..., x_n]) by later stages and ensure we desugar that
 630    normally: this makes sure that we don't cause a code size increase
 631    by having the cons in that expression fused (see later) and hence
 632    being unable to statically allocate any more
 633
 634 2. For the prefix of the list which cannot be allocated statically,
 635    say [x_1, ..., x_(k-1)], we turn it into an expression involving
 636    build so that if we find any foldrs over it it will fuse away
 637    entirely!
 638
 639    So in this example we will desugar to:
 640    build (\c n -> x_1 `c` x_2 `c` .... `c` foldr c n [x_k, ..., x_n]
 641
 642    If fusion fails to occur then build will get inlined and (since we
 643    defined a RULE for foldr (:) []) we will get back exactly the
 644    normal desugaring for an explicit list.
 645
 646 This optimisation can be worth a lot: up to 25% of the total
 647 allocation in some nofib programs. Specifically
 648
 649         Program           Size    Allocs   Runtime  CompTime
 650         rewrite          +0.0%    -26.3%      0.02     -1.8%
 651            ansi          -0.3%    -13.8%      0.00     +0.0%
 652            lift          +0.0%     -8.7%      0.00     -2.3%
 653
 654 Of course, if rules aren't turned on then there is pretty much no
 655 point doing this fancy stuff, and it may even be harmful.
 656
 657 =======>  Note by SLPJ Dec 08.
 658
 659 I'm unconvinced that we should *ever* generate a build for an explicit
 660 list.  See the comments in GHC.Base about the foldr/cons rule, which
 661 points out that (foldr k z [a,b,c]) may generate *much* less code than
 662 (a `k` b `k` c `k` z).
 663
 664 Furthermore generating builds messes up the LHS of RULES.
 665 Example: the foldr/single rule in GHC.Base
 666    foldr k z [x] = ...
 667 We do not want to generate a build invocation on the LHS of this RULE!
 668
 669 We fix this by disabling rules in rule LHSs, and testing that
 670 flag here; see Note [Desugaring RULE left hand sides] in Desugar
 671
 672 To test this I've added a (static) flag -fsimple-list-literals, which
 673 makes all list literals be generated via the simple route.
 674
 675
 676 \begin{code}
 677 dsExplicitList :: PostTcType -> [LHsExpr Id] -> DsM CoreExpr
 678 -- See Note [Desugaring explicit lists]
 679 dsExplicitList elt_ty xs
 680   = do { dflags <- getDOptsDs
 681        ; xs' <- mapM dsLExpr xs
 682        ; let (dynamic_prefix, static_suffix) = spanTail is_static xs'
 683        ; if opt_SimpleListLiterals                      -- -fsimple-list-literals
 684          || not (dopt Opt_EnableRewriteRules dflags)    -- Rewrite rules off
 685                 -- Don't generate a build if there are no rules to eliminate it!
 686                 -- See Note [Desugaring RULE left hand sides] in Desugar
 687          || null dynamic_prefix   -- Avoid build (\c n. foldr c n xs)!
 688          then return $ mkListExpr elt_ty xs'
 689          else mkBuildExpr elt_ty (mkSplitExplicitList dynamic_prefix static_suffix) }
 690   where
 691     is_static :: CoreExpr -> Bool
 692     is_static e = all is_static_var (varSetElems (exprFreeVars e))
 693
 694     is_static_var :: Var -> Bool
 695     is_static_var v
 696       | isId v = isExternalName (idName v)  -- Top-level things are given external names
 697       | otherwise = False                   -- Type variables
 698
 699     mkSplitExplicitList prefix suffix (c, _) (n, n_ty)
 700       = do { let suffix' = mkListExpr elt_ty suffix
 701            ; folded_suffix <- mkFoldrExpr elt_ty n_ty (Var c) (Var n) suffix'
 702            ; return (foldr (App . App (Var c)) folded_suffix prefix) }
 703
 704 spanTail :: (a -> Bool) -> [a] -> ([a], [a])
 705 spanTail f xs = (reverse rejected, reverse satisfying)
 706     where (satisfying, rejected) = span f $ reverse xs
 707 \end{code}
 708
 709 Desugar 'do' and 'mdo' expressions (NOT list comprehensions, they're
 710 handled in DsListComp).  Basically does the translation given in the
 711 Haskell 98 report:
 712
 713 \begin{code}
 714 dsDo    :: [LStmt Id]
 715         -> LHsExpr Id
 716         -> Type                 -- Type of the whole expression
 717         -> DsM CoreExpr
 718
 719 dsDo stmts body result_ty
 720   = goL stmts
 721   where
 722     -- result_ty must be of the form (m b)
 723     (m_ty, _b_ty) = tcSplitAppTy result_ty
 724
 725     goL [] = dsLExpr body
 726     goL ((L loc stmt):lstmts) = putSrcSpanDs loc (go loc stmt lstmts)
 727
 728     go _ (ExprStmt rhs then_expr _) stmts
 729       = do { rhs2 <- dsLExpr rhs
 730            ; case tcSplitAppTy_maybe (exprType rhs2) of
 731                 Just (container_ty, returning_ty) -> warnDiscardedDoBindings rhs container_ty returning_ty
 732                 _                                 -> return ()
 733            ; then_expr2 <- dsExpr then_expr
 734            ; rest <- goL stmts
 735            ; return (mkApps then_expr2 [rhs2, rest]) }
 736
 737     go _ (LetStmt binds) stmts
 738       = do { rest <- goL stmts
 739            ; dsLocalBinds binds rest }
 740
 741     go _ (BindStmt pat rhs bind_op fail_op) stmts
 742       = do  { body     <- goL stmts
 743             ; rhs'     <- dsLExpr rhs
 744             ; bind_op' <- dsExpr bind_op
 745             ; var   <- selectSimpleMatchVarL pat
 746             ; let bind_ty = exprType bind_op'   -- rhs -> (pat -> res1) -> res2
 747                   res1_ty = funResultTy (funArgTy (funResultTy bind_ty))
 748             ; match <- matchSinglePat (Var var) (StmtCtxt DoExpr) pat
 749                                       res1_ty (cantFailMatchResult body)
 750             ; match_code <- handle_failure pat match fail_op
 751             ; return (mkApps bind_op' [rhs', Lam var match_code]) }
 752
 753     go loc (RecStmt { recS_stmts = rec_stmts, recS_later_ids = later_ids
 754                     , recS_rec_ids = rec_ids, recS_ret_fn = return_op
 755                     , recS_mfix_fn = mfix_op, recS_bind_fn = bind_op
 756                     , recS_rec_rets = rec_rets, recS_dicts = _ev_binds }) stmts
 757       = ASSERT( length rec_ids > 0 )
 758         ASSERT( isEmptyTcEvBinds _ev_binds )   -- No method binds
 759         goL (new_bind_stmt : stmts)
 760       where
 761         -- returnE <- dsExpr return_id
 762         -- mfixE <- dsExpr mfix_id
 763         new_bind_stmt = L loc $ BindStmt (mkLHsPatTup later_pats) mfix_app
 764                                          bind_op
 765                                              noSyntaxExpr  -- Tuple cannot fail
 766
 767         tup_ids      = rec_ids ++ filterOut (`elem` rec_ids) later_ids
 768         rec_tup_pats = map nlVarPat tup_ids
 769         later_pats   = rec_tup_pats
 770         rets         = map noLoc rec_rets
 771
 772         mfix_app   = nlHsApp (noLoc mfix_op) mfix_arg
 773         mfix_arg   = noLoc $ HsLam (MatchGroup [mkSimpleMatch [mfix_pat] body]
 774                                              (mkFunTy tup_ty body_ty))
 775         mfix_pat   = noLoc $ LazyPat $ mkLHsPatTup rec_tup_pats
 776         body       = noLoc $ HsDo DoExpr rec_stmts return_app body_ty
 777         return_app = nlHsApp (noLoc return_op) (mkLHsTupleExpr rets)
 778         body_ty    = mkAppTy m_ty tup_ty
 779         tup_ty     = mkBoxedTupleTy (map idType tup_ids) -- Deals with singleton case
 780
 781     -- In a do expression, pattern-match failure just calls
 782     -- the monadic 'fail' rather than throwing an exception
 783     handle_failure pat match fail_op
 784       | matchCanFail match
 785       = do { fail_op' <- dsExpr fail_op
 786            ; fail_msg <- mkStringExpr (mk_fail_msg pat)
 787            ; extractMatchResult match (App fail_op' fail_msg) }
 788       | otherwise
 789       = extractMatchResult match (error "It can't fail")
 790
 791 mk_fail_msg :: Located e -> String
 792 mk_fail_msg pat = "Pattern match failure in do expression at " ++
 793                   showSDoc (ppr (getLoc pat))
 794 \end{code}
 795
 796 Translation for RecStmt's:
 797 -----------------------------
 798 We turn (RecStmt [v1,..vn] stmts) into:
 799
 800   (v1,..,vn) <- mfix (\~(v1,..vn). do stmts
 801                                       return (v1,..vn))
 802
 803 \begin{code}
 804 dsMDo   :: HsStmtContext Name
 805         -> [(Name,Id)]
 806         -> [LStmt Id]
 807         -> LHsExpr Id
 808         -> Type                 -- Type of the whole expression
 809         -> DsM CoreExpr
 810
 811 dsMDo ctxt tbl stmts body result_ty
 812   = goL stmts
 813   where
 814     goL [] = dsLExpr body
 815     goL ((L loc stmt):lstmts) = putSrcSpanDs loc (go loc stmt lstmts)
 816
 817     (m_ty, b_ty) = tcSplitAppTy result_ty       -- result_ty must be of the form (m b)
 818     mfix_id   = lookupEvidence tbl mfixName
 819     return_id = lookupEvidence tbl returnMName
 820     bind_id   = lookupEvidence tbl bindMName
 821     then_id   = lookupEvidence tbl thenMName
 822     fail_id   = lookupEvidence tbl failMName
 823
 824     go _ (LetStmt binds) stmts
 825       = do { rest <- goL stmts
 826            ; dsLocalBinds binds rest }
 827
 828     go _ (ExprStmt rhs _ rhs_ty) stmts
 829       = do { rhs2 <- dsLExpr rhs
 830            ; warnDiscardedDoBindings rhs m_ty rhs_ty
 831            ; rest <- goL stmts
 832            ; return (mkApps (Var then_id) [Type rhs_ty, Type b_ty, rhs2, rest]) }
 833
 834     go _ (BindStmt pat rhs _ _) stmts
 835       = do { body  <- goL stmts
 836            ; var   <- selectSimpleMatchVarL pat
 837            ; match <- matchSinglePat (Var var) (StmtCtxt ctxt) pat
 838                                   result_ty (cantFailMatchResult body)
 839            ; fail_msg   <- mkStringExpr (mk_fail_msg pat)
 840            ; let fail_expr = mkApps (Var fail_id) [Type b_ty, fail_msg]
 841            ; match_code <- extractMatchResult match fail_expr
 842
 843            ; rhs'       <- dsLExpr rhs
 844            ; return (mkApps (Var bind_id) [Type (hsLPatType pat), Type b_ty,
 845                                              rhs', Lam var match_code]) }
 846
 847     go loc (RecStmt { recS_stmts = rec_stmts, recS_later_ids = later_ids
 848                     , recS_rec_ids = rec_ids, recS_rec_rets = rec_rets
 849                     , recS_dicts = _ev_binds }) stmts
 850       = ASSERT( length rec_ids > 0 )
 851         ASSERT( length rec_ids == length rec_rets )
 852         ASSERT( isEmptyTcEvBinds _ev_binds )
 853         pprTrace "dsMDo" (ppr later_ids) $
 854          goL (new_bind_stmt : stmts)
 855       where
 856         new_bind_stmt = L loc $ mkBindStmt (mk_tup_pat later_pats) mfix_app
 857
 858                 -- Remove the later_ids that appear (without fancy coercions)
 859                 -- in rec_rets, because there's no need to knot-tie them separately
 860                 -- See Note [RecStmt] in HsExpr
 861         later_ids'   = filter (`notElem` mono_rec_ids) later_ids
 862         mono_rec_ids = [ id | HsVar id <- rec_rets ]
 863
 864         mfix_app = nlHsApp (nlHsTyApp mfix_id [tup_ty]) mfix_arg
 865         mfix_arg = noLoc $ HsLam (MatchGroup [mkSimpleMatch [mfix_pat] body]
 866                                              (mkFunTy tup_ty body_ty))
 867
 868         -- The rec_tup_pat must bind the rec_ids only; remember that the
 869         --      trimmed_laters may share the same Names
 870         -- Meanwhile, the later_pats must bind the later_vars
 871         rec_tup_pats = map mk_wild_pat later_ids' ++ map nlVarPat rec_ids
 872         later_pats   = map nlVarPat    later_ids' ++ map mk_later_pat rec_ids
 873         rets         = map nlHsVar     later_ids' ++ map noLoc rec_rets
 874
 875         mfix_pat = noLoc $ LazyPat $ mk_tup_pat rec_tup_pats
 876         body     = noLoc $ HsDo ctxt rec_stmts return_app body_ty
 877         body_ty = mkAppTy m_ty tup_ty
 878         tup_ty  = mkBoxedTupleTy (map idType (later_ids' ++ rec_ids))  -- Deals with singleton case
 879
 880         return_app  = nlHsApp (nlHsTyApp return_id [tup_ty])
 881                               (mkLHsTupleExpr rets)
 882
 883         mk_wild_pat :: Id -> LPat Id
 884         mk_wild_pat v = noLoc $ WildPat $ idType v
 885
 886         mk_later_pat :: Id -> LPat Id
 887         mk_later_pat v | v `elem` later_ids' = mk_wild_pat v
 888                        | otherwise           = nlVarPat v
 889
 890         mk_tup_pat :: [LPat Id] -> LPat Id
 891         mk_tup_pat [p] = p
 892         mk_tup_pat ps  = noLoc $ mkVanillaTuplePat ps Boxed
 893 \end{code}
 894
 895
 896 %************************************************************************
 897 %*                                                                      *
 898                  Warning about identities
 899 %*                                                                      *
 900 %************************************************************************
 901
 902 Warn about functions that convert between one type and another
 903 when the to- and from- types are the same.  Then it's probably
 904 (albeit not definitely) the identity
 905 \begin{code}
 906 warnAboutIdentities :: CoreExpr -> (CoreExpr -> CoreExpr) -> DsM ()
 907 warnAboutIdentities (Var v) co_fn
 908   | idName v `elem` conversionNames
 909   , let fun_ty = exprType (co_fn (Var v))
 910   , Just (arg_ty, res_ty) <- splitFunTy_maybe fun_ty
 911   , arg_ty `tcEqType` res_ty  -- So we are converting  ty -> ty
 912   = warnDs (vcat [ ptext (sLit "Call of") <+> ppr v <+> dcolon <+> ppr fun_ty
 913                  , nest 2 $ ptext (sLit "can probably be omitted")
 914                  , parens (ptext (sLit "Use -fno-warn-identities to suppress this messsage)"))
 915            ])
 916 warnAboutIdentities _ _ = return ()
 917
 918 conversionNames :: [Name]
 919 conversionNames
 920   = [ toIntegerName, toRationalName
 921     , fromIntegralName, realToFracName ]
 922  -- We can't easily add fromIntegerName, fromRationalName,
 923  -- becuase they are generated by literals
 924 \end{code}
 925
 926 %************************************************************************
 927 %*                                                                      *
 928 \subsection{Errors and contexts}
 929 %*                                                                      *
 930 %************************************************************************
 931
 932 \begin{code}
 933 -- Warn about certain types of values discarded in monadic bindings (#3263)
 934 warnDiscardedDoBindings :: LHsExpr Id -> Type -> Type -> DsM ()
 935 warnDiscardedDoBindings rhs container_ty returning_ty = do {
 936           -- Warn about discarding non-() things in 'monadic' binding
 937         ; warn_unused <- doptDs Opt_WarnUnusedDoBind
 938         ; if warn_unused && not (returning_ty `tcEqType` unitTy)
 939            then warnDs (unusedMonadBind rhs returning_ty)
 940            else do {
 941           -- Warn about discarding m a things in 'monadic' binding of the same type,
 942           -- but only if we didn't already warn due to Opt_WarnUnusedDoBind
 943         ; warn_wrong <- doptDs Opt_WarnWrongDoBind
 944         ; case tcSplitAppTy_maybe returning_ty of
 945                   Just (returning_container_ty, _) -> when (warn_wrong && container_ty `tcEqType` returning_container_ty) $
 946                                                             warnDs (wrongMonadBind rhs returning_ty)
 947                   _ -> return () } }
 948
 949 unusedMonadBind :: LHsExpr Id -> Type -> SDoc
 950 unusedMonadBind rhs returning_ty
 951   = ptext (sLit "A do-notation statement discarded a result of type") <+> ppr returning_ty <> dot $$
 952     ptext (sLit "Suppress this warning by saying \"_ <- ") <> ppr rhs <> ptext (sLit "\",") $$
 953     ptext (sLit "or by using the flag -fno-warn-unused-do-bind")
 954
 955 wrongMonadBind :: LHsExpr Id -> Type -> SDoc
 956 wrongMonadBind rhs returning_ty
 957   = ptext (sLit "A do-notation statement discarded a result of type") <+> ppr returning_ty <> dot $$
 958     ptext (sLit "Suppress this warning by saying \"_ <- ") <> ppr rhs <> ptext (sLit "\",") $$
 959     ptext (sLit "or by using the flag -fno-warn-wrong-do-bind")
 960 \end{code}